data/qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7
   8 .string mdl_dead; // or "" to hide when broken
   9 .string debris; // space separated list of debris models
  10 // other fields:
  11 //   mdl = particle effect name
  12 //   count = particle effect multiplier
  13 //   targetname = target to trigger to unbreak the model
  14 //   target = targets to trigger when broken
  15 //   health = amount of damage it can take
  16 //   spawnflags:
  17 //     1 = start disabled (needs to be triggered to activate)
  18 //     2 = indicate damage
  19 // notes:
  20 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  21 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  22 //   want that!
  23
  24 .vector mins_save, maxs_save;
  25
  26 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  27
  28 //
  29 // func_breakable
  30 // - basically func_assault_destructible for general gameplay use
  31 //
  32 void LaunchDebris (string debrisname) =
  33 {
  34         local   entity dbr;
  35
  36         dbr = spawn();
  37         dbr.origin = self.origin + self.absmin
  38                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  39                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  40                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z);
  41         setmodel (dbr, debrisname );
  42         dbr.movetype = MOVETYPE_BOUNCE;
  43         dbr.solid = SOLID_NOT;
  44         // TODO parametrize this
  45         dbr.velocity_x = 70 * crandom();
  46         dbr.velocity_y = 70 * crandom();
  47         dbr.velocity_z = 140 + 70 * random();
  48         dbr.avelocity_x = random()*600;
  49         dbr.avelocity_y = random()*600;
  50         dbr.avelocity_z = random()*600;
  51         SUB_SetFade(dbr, time + 1 + random() * 5, 1);
  52 };
  53
  54 void func_breakable_colormod()
  55 {
  56         float h;
  57         if not(self.spawnflags & 2)
  58                 return;
  59         h = self.health / self.max_health;
  60         if(h < 0.25)
  61                 self.colormod = '1 0 0';
  62         else if(h <= 0.75)
  63                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  64         else
  65                 self.colormod = '1 1 1';
  66 }
  67
  68 void func_breakable_look_destroyed()
  69 {
  70         if(self.mdl_dead == "")
  71         {
  72                 self.model = "";
  73                 self.solid = SOLID_NOT;
  74         }
  75         else
  76         {
  77                 setmodel(self, self.mdl_dead);
  78                 self.solid = SOLID_BSP;
  79         }
  80 }
  81
  82 void func_breakable_look_restore()
  83 {
  84         setmodel(self, self.mdl);
  85         self.solid = SOLID_BSP;
  86 }
  87
  88 void func_breakable_behave_destroyed()
  89 {
  90         self.health = self.max_health;
  91         self.takedamage = DAMAGE_NO;
  92         self.event_damage = SUB_Null;
  93         self.state = 1;
  94         setsize(self, '0 0 0', '0 0 0');
  95         func_breakable_colormod();
  96 }
  97
  98 void func_breakable_behave_restore()
  99 {
 100         self.health = self.max_health;
 101         self.takedamage = DAMAGE_AIM;
 102         self.event_damage = func_breakable_damage;
 103         self.state = 0;
 104         setsize(self, self.mins_save, self.maxs_save);
 105         func_breakable_colormod();
 106 }
 107
 108 void func_breakable_destroyed()
 109 {
 110         func_breakable_look_destroyed();
 111         func_breakable_behave_destroyed();
 112 }
 113
 114 void func_breakable_restore()
 115 {
 116         func_breakable_look_restore();
 117         func_breakable_behave_restore();
 118 }
 119
 120 void func_breakable_destroy() {
 121         float n, i;
 122
 123         activator = self.owner;
 124
 125         func_breakable_destroyed();
 126
 127         if(self.noise)
 128                 sound (self, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 129
 130         if(self.dmg)
 131                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, self.dmg_force, DEATH_HURTTRIGGER, world);
 132
 133         // now throw around the debris
 134         n = tokenize_sane(self.debris);
 135         for(i = 0; i < n; ++i)
 136                 LaunchDebris(argv(i));
 137
 138         if(self.cnt)
 139                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 140
 141         SUB_UseTargets();
 142 }
 143
 144 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 145 {
 146         if(self.state == 1)
 147                 return;
 148         if(self.team)
 149                 if(attacker.team == self.team)
 150                         return;
 151         if(self.sprite)
 152                 WaypointSprite_Ping(self.sprite);
 153         self.health = self.health - damage;
 154         func_breakable_colormod();
 155
 156         if(self.health < 0)
 157                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 158 }
 159
 160 void func_breakable_reset()
 161 {
 162         func_breakable_look_restore();
 163         if(self.spawnflags & 1)
 164                 func_breakable_behave_destroyed();
 165         else
 166                 func_breakable_behave_restore();
 167 }
 168
 169 // destructible walls that can be used to trigger target_objective_decrease
 170 void spawnfunc_func_breakable() {
 171         float n, i;
 172         if(!self.health)
 173                 self.health = 100;
 174         self.max_health = self.health;
 175
 176         if(self.mdl != "")
 177                 self.cnt = particleeffectnum(self.mdl);
 178         if(self.count == 0)
 179                 self.count = 1;
 180
 181         if(!self.message)
 182                 self.message = "got too close to an explosion";
 183         if(!self.message2)
 184                 self.message2 = "was pushed into an explosion by";
 185         if(!self.dmg_radius)
 186                 self.dmg_radius = 150;
 187         if(!self.dmg_force)
 188                 self.dmg_force = 200;
 189
 190         self.mdl = self.model;
 191         SetBrushEntityModel();
 192         self.mins_save = self.mins;
 193         self.maxs_save = self.maxs;
 194
 195         self.use = func_breakable_restore;
 196
 197         // precache all the models
 198         if (self.mdl_dead)
 199                 precache_model(self.mdl_dead);
 200         n = tokenize_sane(self.debris);
 201         for(i = 0; i < n; ++i)
 202                 precache_model(argv(i));
 203         if(self.noise)
 204                 precache_sound(self.noise);
 205
 206         func_breakable_reset();
 207 }