data/qcsrc/server/ctf.qc

   1 .entity sprite;
   2 entity ctf_worldflaglist; // CTF flags in the map
   3 .entity ctf_worldflagnext;
   4
   5 .float next_take_time;                  // the next time a player can pick up a flag (time + blah)
   6                                                                 /// I used this, in part, to fix the looping score bug. - avirox
   7 //float FLAGSCORE_PICKUP        =  1;
   8 //float FLAGSCORE_RETURN        =  5; // returned by owner team
   9 //float FLAGSCORE_RETURNROGUE   = 10; // returned by rogue team
  10 //float FLAGSCORE_CAPTURE       =  5;
  11
  12 #define FLAG_CARRY_POS '-15 0 7'
  13
  14 void FakeTimeLimit(entity e, float t)
  15 {
  16         msg_entity = e;
  17         WriteByte(MSG_ONE, 3); // svc_updatestat
  18         WriteByte(MSG_ONE, 236); // STAT_TIMELIMIT
  19         if(t < 0)
  20                 WriteCoord(MSG_ONE, cvar("timelimit"));
  21         else
  22                 WriteCoord(MSG_ONE, (t + 1) / 60);
  23 }
  24
  25 float   flagcaptimerecord;
  26 .float  flagpickuptime;
  27 //.float  iscommander;
  28 //.float  ctf_state;
  29
  30 void() FlagThink;
  31 void() FlagTouch;
  32
  33 void place_flag()
  34 {
  35         if(!self.t_width)
  36                 self.t_width = 0.1; // frame animation rate
  37         if(!self.t_length)
  38                 self.t_length = 119; // maximum frame
  39
  40         setattachment(self, world, "");
  41         self.mdl = self.model;
  42         self.flags = FL_ITEM;
  43         self.solid = SOLID_TRIGGER;
  44         self.movetype = MOVETYPE_NONE;
  45         self.velocity = '0 0 0';
  46         self.origin_z = self.origin_z + 6;
  47         self.think = FlagThink;
  48         self.touch = FlagTouch;
  49         self.nextthink = time + 0.1;
  50         self.cnt = FLAG_BASE;
  51         self.mangle = self.angles;
  52         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  53         //self.effects = self.effects | EF_DIMLIGHT;
  54         if(!self.noalign)
  55         {
  56                 self.movetype = MOVETYPE_TOSS;
  57                 if (!droptofloor())
  58                 {
  59                         dprint("Flag fell out of level at ", vtos(self.origin), "\n");
  60                         remove(self);
  61                         return;
  62                 }
  63         }
  64         self.oldorigin = self.origin;
  65 };
  66
  67 void LogCTF(string mode, float flagteam, entity actor)
  68 {
  69         string s;
  70         if(!cvar("sv_eventlog"))
  71                 return;
  72         s = strcat(":ctf:", mode);
  73         s = strcat(s, ":", ftos(flagteam));
  74         if(actor != world)
  75                 s = strcat(s, ":", ftos(actor.playerid));
  76         GameLogEcho(s);
  77 }
  78
  79 void RegenFlag(entity e)
  80 {
  81         setattachment(e, world, "");
  82         e.movetype = MOVETYPE_NONE;
  83         if(!self.noalign)
  84                 e.movetype = MOVETYPE_TOSS;
  85         e.solid = SOLID_TRIGGER;
  86         // TODO: play a sound here
  87         setorigin(e, e.oldorigin);
  88         e.angles = e.mangle;
  89         e.cnt = FLAG_BASE;
  90         e.owner = world;
  91         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
  92 };
  93
  94 void ReturnFlag(entity e)
  95 {
  96         if (e.owner)
  97         if (e.owner.flagcarried == e)
  98         {
  99                 WaypointSprite_DetachCarrier(e.owner);
 100                 e.owner.flagcarried = world;
 101
 102                 if(e.speedrunning)
 103                         FakeTimeLimit(e.owner, -1);
 104         }
 105         e.owner = world;
 106         RegenFlag(e);
 107 };
 108
 109 void DropFlag(entity e, entity penalty_receiver, entity attacker)
 110 {
 111         local entity p;
 112
 113         if(e.speedrunning)
 114         {
 115                 ReturnFlag(e);
 116                 return;
 117         }
 118
 119         if (!e.owner)
 120         {
 121                 dprint("FLAG: drop - no owner?!?!\n");
 122                 return;
 123         }
 124         p = e.owner;
 125         if (p.flagcarried != e)
 126         {
 127                 dprint("FLAG: drop - owner is not carrying this flag??\n");
 128                 return;
 129         }
 130         bprint(p.netname, "^7 lost the ", e.netname, "\n");
 131
 132         if(penalty_receiver)
 133                 UpdateFrags(penalty_receiver, -cvar("g_ctf_flagpenalty_suicidedrop"));
 134         else
 135                 UpdateFrags(p, -cvar("g_ctf_flagpenalty_drop"));
 136         PlayerScore_Add(p, SP_CTF_DROPS, +1);
 137         e.playerid = attacker.playerid;
 138
 139         WaypointSprite_DetachCarrier(p);
 140         LogCTF("dropped", p.team, p);
 141
 142         setattachment(e, world, "");
 143
 144         if (p.flagcarried == e)
 145                 p.flagcarried = world;
 146         e.owner = world;
 147
 148         e.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 149         e.solid = SOLID_TRIGGER;
 150         e.movetype = MOVETYPE_TOSS;
 151         // setsize(e, '-16 -16 0', '16 16 74');
 152         setorigin(e, p.origin - '0 0 24' + '0 0 37');
 153         e.cnt = FLAG_DROPPED;
 154         e.velocity = '0 0 300';
 155         e.pain_finished = time + cvar("g_ctf_flag_returntime");//30;
 156
 157         trace_startsolid = FALSE;
 158         tracebox(e.origin, e.mins, e.maxs, e.origin, TRUE, e);
 159         if(trace_startsolid)
 160                 dprint("FLAG FALLTHROUGH will happen SOON\n");
 161 };
 162
 163 void AnimateFlag()
 164 {
 165         if(self.delay > time)
 166                 return;
 167         self.delay = time + self.t_width;
 168         if(self.nextthink > self.delay)
 169                 self.nextthink = self.delay;
 170
 171         self.frame = self.frame + 1;
 172         if(self.frame > self.t_length)
 173                 self.frame = 0;
 174 }
 175
 176 void FlagThink()
 177 {
 178         local entity e;
 179
 180         self.nextthink = time + 0.1;
 181
 182         AnimateFlag();
 183
 184         if(self.speedrunning)
 185         if(self.cnt == FLAG_CARRY)
 186         {
 187                 if(self.owner)
 188                 if(flagcaptimerecord)
 189                 if(time >= self.flagpickuptime + flagcaptimerecord)
 190                 {
 191                         bprint("The ", self.netname, " became impatient after ", ftos_decimals(flagcaptimerecord, 2), " seconds and returned itself\n");
 192
 193                         self.owner.impulse = 77; // returning!
 194                         e = self;
 195                         self = self.owner;
 196                         ReturnFlag(e);
 197                         ImpulseCommands();
 198                         self = e;
 199                         return;
 200                 }
 201         }
 202
 203         if (self.cnt == FLAG_BASE)
 204                 return;
 205
 206         if (self.cnt == FLAG_DROPPED)
 207         {
 208                 // flag fallthrough? FIXME remove this if bug is really fixed now
 209                 if(self.origin_z < -131072)
 210                 {
 211                         dprint("FLAG FALLTHROUGH just happened\n");
 212                         self.pain_finished = 0;
 213                 }
 214                 setattachment(self, world, "");
 215                 if (time > self.pain_finished)
 216                 {
 217                         bprint("The ", self.netname, " has returned to base\n");
 218                         sound (self, CHAN_TRIGGER, self.noise3, VOL_BASE, ATTN_NONE);
 219                         LogCTF("returned", self.team, world);
 220                         ReturnFlag(self);
 221                 }
 222                 return;
 223         }
 224
 225         e = self.owner;
 226         if (e.classname != "player" || (e.deadflag) || (e.flagcarried != self))
 227         {
 228                 dprint("CANNOT HAPPEN - player dead and STILL had a flag!\n");
 229                 DropFlag(self, world, world);
 230                 return;
 231         }
 232 };
 233
 234 void FlagTouch()
 235 {
 236         if(gameover) return;
 237
 238         local float t;
 239         local entity player;
 240         local string s, s0, h0, h1;
 241         if (other.classname != "player")
 242                 return;
 243         if (other.health < 1) // ignore dead players
 244                 return;
 245
 246         if (self.cnt == FLAG_CARRY)
 247                 return;
 248
 249         if (self.cnt == FLAG_BASE)
 250         if (other.team == self.team)
 251         if (other.flagcarried) // he's got a flag
 252         if (other.flagcarried.team != self.team) // capture
 253         {
 254                 if (other.flagcarried == world)
 255                 {
 256                         return;
 257                 }
 258                 t = time - other.flagcarried.flagpickuptime;
 259                 s = ftos_decimals(t, 2);
 260                 s0 = ftos_decimals(flagcaptimerecord, 2);
 261                 h0 = db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"));
 262                 h1 = other.netname;
 263                 if(h0 == h1)
 264                         h0 = "his";
 265                 else
 266                         h0 = strcat(h0, "^7's"); // h0: display text for previous netname
 267                 if (flagcaptimerecord == 0)
 268                 {
 269                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, " seconds\n");
 270                         flagcaptimerecord = t;
 271                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 272                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 273                         GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 274                 }
 275                 else if (t < flagcaptimerecord)
 276                 {
 277                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", breaking ", strcat(h0, " previous record of ", s0, " seconds\n"));
 278                         flagcaptimerecord = t;
 279                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time"), ftos(t));
 280                         db_put(ServerProgsDB, strcat(GetMapname(), "/captimerecord/netname"), h1);
 281                         GameLogEcho(strcat(":recordset:", ftos(other.playerid), ":", ftos(t)));
 282                 }
 283                 else
 284                 {
 285                         bprint(other.netname, "^7 captured the ", other.flagcarried.netname, " in ", s, ", failing to break ", strcat(h0, " record of ", s0, " seconds\n"));
 286                 }
 287
 288                 PlayerTeamScore_Add(other, SP_CTF_CAPS, ST_CTF_CAPS, 1);
 289                 LogCTF("capture", other.flagcarried.team, other);
 290                 // give credit to the individual player
 291                 UpdateFrags(other, cvar("g_ctf_flagscore_capture"));
 292
 293                 sound (other, CHAN_AUTO, self.noise2, VOL_BASE, ATTN_NONE);
 294                 WaypointSprite_DetachCarrier(other);
 295                 if(self.speedrunning)
 296                         FakeTimeLimit(other, -1);
 297                 RegenFlag (other.flagcarried);
 298                 other.flagcarried = world;
 299                 other.next_take_time = time + 1;
 300         }
 301         if (self.cnt == FLAG_BASE)
 302         if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2) // only red and blue team can steal flags
 303         if (other.team != self.team)
 304         if (!other.flagcarried)
 305         {
 306                 if (other.next_take_time > time)
 307                         return;
 308                 // pick up
 309                 self.flagpickuptime = time; // used for timing runs
 310                 self.speedrunning = other.speedrunning; // if speedrunning, flag will self-return and teleport the owner back after the record
 311                 if(other.speedrunning)
 312                 if(flagcaptimerecord)
 313                         FakeTimeLimit(other, time + flagcaptimerecord);
 314                 self.solid = SOLID_NOT;
 315                 setorigin(self, self.origin); // relink
 316                 self.owner = other;
 317                 other.flagcarried = self;
 318                 self.cnt = FLAG_CARRY;
 319                 self.angles = '0 0 0';
 320                 bprint(other.netname, "^7 got the ", self.netname, "\n");
 321                 UpdateFrags(other, cvar("g_ctf_flagscore_pickup_base"));
 322                 PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 323                 LogCTF("steal", self.team, other);
 324                 sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 325
 326                 FOR_EACH_PLAYER(player)
 327                         if(player.team == self.team)
 328                                 centerprint(player, "The enemy got your flag! Retrieve it!");
 329
 330                 self.movetype = MOVETYPE_NONE;
 331                 setorigin(self, FLAG_CARRY_POS);
 332                 setattachment(self, other, "");
 333                 WaypointSprite_AttachCarrier("flagcarrier", other);
 334
 335                 return;
 336         }
 337
 338         if (self.cnt == FLAG_DROPPED)
 339         {
 340                 self.flags = FL_ITEM; // clear FL_ONGROUND and any other junk
 341                 if (other.team == self.team || (other.team != COLOR_TEAM1 && other.team != COLOR_TEAM2))
 342                 {
 343                         // return flag
 344                         bprint(other.netname, "^7 returned the ", self.netname, "\n");
 345                         if(other.playerid == self.playerid) // is this the guy who killed the FC last?
 346                         {
 347                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 348                                         UpdateFrags(other, cvar("g_ctf_flagscore_return_by_killer"));
 349                                 else
 350                                         UpdateFrags(other, cvar("g_ctf_flagscore_return_rogue_by_killer"));
 351                         }
 352                         else
 353                         {
 354                                 if (other.team == COLOR_TEAM1 || other.team == COLOR_TEAM2)
 355                                         UpdateFrags(other, cvar("g_ctf_flagscore_return"));
 356                                 else
 357                                         UpdateFrags(other, cvar("g_ctf_flagscore_return_rogue"));
 358                         }
 359                         PlayerScore_Add(other, SP_CTF_RETURNS, 1);
 360                         LogCTF("return", self.team, other);
 361                         sound (other, CHAN_AUTO, self.noise1, VOL_BASE, ATTN_NONE);
 362                         ReturnFlag(self);
 363                 }
 364                 else if (!other.flagcarried)
 365                 {
 366                         // pick up
 367                         self.solid = SOLID_NOT;
 368                         setorigin(self, self.origin); // relink
 369                         self.owner = other;
 370                         other.flagcarried = self;
 371                         self.cnt = FLAG_CARRY;
 372                         bprint(other.netname, "^7 picked up the ", self.netname, "\n");
 373
 374                         float f;
 375                         f = bound(0, (self.pain_finished - time) / cvar("g_ctf_flag_returntime"), 1);
 376                         //print("factor is ", ftos(f), "\n");
 377                         f = cvar("g_ctf_flagscore_pickup_dropped_late") * (1-f)
 378                           + cvar("g_ctf_flagscore_pickup_dropped_early") * f;
 379                         f = floor(f + 0.5);
 380                         //print("score is ", ftos(f), "\n");
 381
 382                         UpdateFrags(other, f);
 383                         PlayerScore_Add(other, SP_CTF_PICKUPS, 1);
 384                         LogCTF("pickup", self.team, other);
 385                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 386
 387                         FOR_EACH_PLAYER(player)
 388                                 if(player.team == self.team)
 389                                         centerprint(player, "The enemy got your flag! Retrieve it!");
 390
 391                         self.movetype = MOVETYPE_NONE;  // flag must have MOVETYPE_NONE here, otherwise it will drop through the floor...
 392                         setorigin(self, FLAG_CARRY_POS);
 393                         setattachment(self, other, "");
 394                         WaypointSprite_AttachCarrier("flagcarrier", other);
 395                 }
 396         }
 397 };
 398
 399 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 400 CTF Starting point for a player
 401 in team one (Red).
 402
 403 Keys:
 404 "angle"
 405  viewing angle when spawning
 406 */
 407 void spawnfunc_info_player_team1()
 408 {
 409         self.team = COLOR_TEAM1; // red
 410         spawnfunc_info_player_deathmatch();
 411 };
 412 //self.team = 4;self.classname = "info_player_start";spawnfunc_info_player_start();};
 413
 414 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 415 CTF Starting point for a player in
 416 team two (Blue).
 417
 418 Keys:
 419 "angle"
 420  viewing angle when spawning
 421 */
 422 void spawnfunc_info_player_team2()
 423 {
 424         self.team = COLOR_TEAM2; // blue
 425         spawnfunc_info_player_deathmatch();
 426 };
 427 //self.team = 13;self.classname = "info_player_start";spawnfunc_info_player_start();};
 428
 429 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 430 CTF Starting point for a player in
 431 team three (Magenta).
 432
 433 Keys:
 434 "angle"
 435  viewing angle when spawning
 436 */
 437 void spawnfunc_info_player_team3()
 438 {
 439         self.team = COLOR_TEAM3; // purple
 440         spawnfunc_info_player_deathmatch();
 441 };
 442
 443
 444 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 445 CTF Starting point for a player in
 446 team four (Yellow).
 447
 448 Keys:
 449 "angle"
 450  viewing angle when spawning
 451 */
 452 void spawnfunc_info_player_team4()
 453 {
 454         self.team = COLOR_TEAM4; // yellow
 455         spawnfunc_info_player_deathmatch();
 456 };
 457
 458
 459
 460
 461 /*QUAKED spawnfunc_item_flag_team1 (0 0.5 0.8) (-48 -48 -37) (48 48 37)
 462 CTF flag for team one (Red).
 463 Multiple are allowed.
 464
 465 Keys:
 466 "angle"
 467  Angle the flag will point
 468 (minus 90 degrees)
 469 "model"
 470  model to use, note this needs red and blue as skins 0 and 1
 471  (default models/ctf/flag.md3)
 472 "noise"
 473  sound played when flag is picked up
 474  (default ctf/take.wav)
 475 "noise1"
 476  sound played when flag is returned by a teammate
 477  (default ctf/return.wav)
 478 "noise2"
 479  sound played when flag is captured
 480  (default ctf/redcapture.wav)
 481 "noise3"
 482  sound played when flag is lost in the field and respawns itself
 483  (default ctf/respawn.wav)
 484 */
 485
 486 void spawnfunc_item_flag_team1()
 487 {
 488         if (!g_ctf)
 489         {
 490                 remove(self);
 491                 return;
 492         }
 493
 494         //if(!cvar("teamplay"))
 495         //      cvar_set("teamplay", "3");
 496
 497         // link flag into ctf_worldflaglist
 498         self.ctf_worldflagnext = ctf_worldflaglist;
 499         ctf_worldflaglist = self;
 500
 501         self.classname = "item_flag_team";
 502         self.team = COLOR_TEAM1; // color 4 team (red)
 503         self.items = IT_KEY2; // gold key (redish enough)
 504         self.netname = "^1RED^7 flag";
 505         self.target = "###item###";
 506         self.skin = 0;
 507         if(self.spawnflags & 1)
 508                 self.noalign = 1;
 509         if (!self.model)
 510                 self.model = "models/ctf/flag_red.md3";
 511         if (!self.noise)
 512                 self.noise = "ctf/take.wav";
 513         if (!self.noise1)
 514                 self.noise1 = "ctf/return.wav";
 515         if (!self.noise2)
 516                 self.noise2 = "ctf/redcapture.wav"; // blue team scores by capturing the red flag
 517         if (!self.noise3)
 518                 self.noise3 = "ctf/respawn.wav";
 519         precache_model (self.model);
 520         setmodel (self, self.model); // precision set below
 521         precache_sound (self.noise);
 522         precache_sound (self.noise1);
 523         precache_sound (self.noise2);
 524         precache_sound (self.noise3);
 525         setsize(self, '-16 -16 -37', '16 16 37');
 526         setorigin(self, self.origin + '0 0 37');
 527         self.nextthink = time + 0.2; // start after doors etc
 528         self.think = place_flag;
 529
 530         if(!self.scale)
 531                 self.scale = 0.6;
 532         //if(!self.glow_size)
 533         //      self.glow_size = 50;
 534
 535         self.effects = self.effects | EF_FULLBRIGHT | EF_LOWPRECISION;
 536         if(!self.noalign)
 537                 droptofloor();
 538
 539         waypoint_spawnforitem(self);
 540
 541         WaypointSprite_SpawnFixed("redbase", self.origin + '0 0 37', self, sprite);
 542 };
 543
 544 /*QUAKED spawnfunc_item_flag_team2 (0 0.5 0.8) (-48 -48 -24) (48 48 64)
 545 CTF flag for team two (Blue).
 546 Multiple are allowed.
 547
 548 Keys:
 549 "angle"
 550  Angle the flag will point
 551 (minus 90 degrees)
 552 "model"
 553  model to use, note this needs red and blue as skins 0 and 1
 554  (default models/ctf/flag.md3)
 555 "noise"
 556  sound played when flag is picked up
 557  (default ctf/take.wav)
 558 "noise1"
 559  sound played when flag is returned by a teammate
 560  (default ctf/return.wav)
 561 "noise2"
 562  sound played when flag is captured
 563  (default ctf/bluecapture.wav)
 564 "noise3"
 565  sound played when flag is lost in the field and respawns itself
 566  (default ctf/respawn.wav)
 567 */
 568
 569 void spawnfunc_item_flag_team2()
 570 {
 571         if (!g_ctf)
 572         {
 573                 remove(self);
 574                 return;
 575         }
 576         //if(!cvar("teamplay"))
 577         //      cvar_set("teamplay", "3");
 578
 579         // link flag into ctf_worldflaglist
 580         self.ctf_worldflagnext = ctf_worldflaglist;
 581         ctf_worldflaglist = self;
 582
 583         self.classname = "item_flag_team";
 584         self.team = COLOR_TEAM2; // color 13 team (blue)
 585         self.items = IT_KEY1; // silver key (bluish enough)
 586         self.netname = "^4BLUE^7 flag";
 587         self.target = "###item###";
 588         self.skin = 0;
 589         if(self.spawnflags & 1)
 590                 self.noalign = 1;
 591         if (!self.model)
 592                 self.model = "models/ctf/flag_blue.md3";
 593         if (!self.noise)
 594                 self.noise = "ctf/take.wav";
 595         if (!self.noise1)
 596                 self.noise1 = "ctf/return.wav";
 597         if (!self.noise2)
 598                 self.noise2 = "ctf/bluecapture.wav"; // red team scores by capturing the blue flag
 599         if (!self.noise3)
 600                 self.noise3 = "ctf/respawn.wav";
 601         precache_model (self.model);
 602         setmodel (self, self.model); // precision set below
 603         precache_sound (self.noise);
 604         precache_sound (self.noise1);
 605         precache_sound (self.noise2);
 606         precache_sound (self.noise3);
 607         setsize(self, '-16 -16 -37', '16 16 37');
 608         setorigin(self, self.origin + '0 0 37');
 609         self.nextthink = time + 0.2; // start after doors etc
 610         self.think = place_flag;
 611
 612         if(!self.scale)
 613                 self.scale = 0.6;
 614         //if(!self.glow_size)
 615         //      self.glow_size = 50;
 616
 617         self.effects = self.effects | EF_FULLBRIGHT | EF_LOWPRECISION;
 618         if(!self.noalign)
 619                 droptofloor();
 620
 621         waypoint_spawnforitem(self);
 622
 623         WaypointSprite_SpawnFixed("bluebase", self.origin + '0 0 37', self, sprite);
 624 };
 625
 626
 627 /*QUAKED spawnfunc_ctf_team (0 .5 .8) (-16 -16 -24) (16 16 32)
 628 Team declaration for CTF gameplay, this allows you to decide what team
 629 names and control point models are used in your map.
 630
 631 Note: If you use spawnfunc_ctf_team entities you must define at least 2!  However, unlike
 632 domination, you don't need to make a blank one too.
 633
 634 Keys:
 635 "netname"
 636  Name of the team (for example Red, Blue, Green, Yellow, Life, Death, Offense, Defense, etc)
 637 "cnt"
 638  Scoreboard color of the team (for example 4 is red and 13 is blue)
 639
 640 */
 641
 642 void spawnfunc_ctf_team()
 643 {
 644         if (!g_ctf)
 645         {
 646                 remove(self);
 647                 return;
 648         }
 649         self.classname = "ctf_team";
 650         self.team = self.cnt + 1;
 651 };
 652
 653 // code from here on is just to support maps that don't have control point and team entities
 654 void ctf_spawnteam (string teamname, float teamcolor)
 655 {
 656         local entity oldself;
 657         oldself = self;
 658         self = spawn();
 659         self.classname = "ctf_team";
 660         self.netname = teamname;
 661         self.cnt = teamcolor;
 662
 663         spawnfunc_ctf_team();
 664
 665         self = oldself;
 666 };
 667
 668 // spawn some default teams if the map is not set up for ctf
 669 void ctf_spawnteams()
 670 {
 671         float numteams;
 672
 673         numteams = 2;//cvar("g_ctf_default_teams");
 674
 675         ctf_spawnteam("Red", COLOR_TEAM1 - 1);
 676         ctf_spawnteam("Blue", COLOR_TEAM2 - 1);
 677 };
 678
 679 void ctf_delayedinit()
 680 {
 681         // if no teams are found, spawn defaults
 682         if (find(world, classname, "ctf_team") == world)
 683                 ctf_spawnteams();
 684
 685         ScoreRules_ctf();
 686 };
 687
 688 void ctf_init()
 689 {
 690         InitializeEntity(world, ctf_delayedinit, INITPRIO_GAMETYPE);
 691         flagcaptimerecord = stof(db_get(ServerProgsDB, strcat(GetMapname(), "/captimerecord/time")));
 692 };
 693
 694 void ctf_setstatus2(entity flag, float shift)
 695 {
 696         if (flag.cnt == FLAG_CARRY)
 697                 if (flag.owner == self)
 698                         self.items |= shift * 3;
 699                 else
 700                         self.items |= shift * 1;
 701         else if (flag.cnt == FLAG_DROPPED)
 702                 self.items |= shift * 2;
 703         else
 704         {
 705                 // no status bits
 706         }
 707 };
 708
 709 void ctf_setstatus()
 710 {
 711         self.items = self.items - (self.items & IT_RED_FLAG_TAKEN);
 712         self.items = self.items - (self.items & IT_RED_FLAG_LOST);
 713         self.items = self.items - (self.items & IT_BLUE_FLAG_TAKEN);
 714         self.items = self.items - (self.items & IT_BLUE_FLAG_LOST);
 715
 716         if (g_ctf) {
 717                 local entity flag;
 718                 float redflags, blueflags;
 719
 720                 redflags = 0;
 721                 blueflags = 0;
 722
 723                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 724                 {
 725                         if(flag.team == COLOR_TEAM1)
 726                                 ++redflags;
 727                         else if(flag.team == COLOR_TEAM2)
 728                                 ++blueflags;
 729                 }
 730
 731                 // blinking magic: if there is more than one flag, show one of these in a clever way
 732                 if(redflags)
 733                         redflags = mod(floor(time * redflags * 0.75), redflags);
 734                 if(blueflags)
 735                         blueflags = mod(floor(time * blueflags * 0.75), blueflags);
 736
 737                 for (flag = ctf_worldflaglist; flag; flag = flag.ctf_worldflagnext) if(flag.cnt != FLAG_BASE)
 738                 {
 739                         if(flag.team == COLOR_TEAM1)
 740                         {
 741                                 if(--redflags == -1) // happens exactly once (redflags is in 0..count-1, and will --'ed count times)
 742                                         ctf_setstatus2(flag, IT_RED_FLAG_TAKEN);
 743                         }
 744                         else if(flag.team == COLOR_TEAM2)
 745                         {
 746                                 if(--blueflags == -1) // happens exactly once
 747                                         ctf_setstatus2(flag, IT_BLUE_FLAG_TAKEN);
 748                         }
 749                 }
 750         }
 751 };
 752 /*
 753 entity(float cteam) ctf_team_has_commander =
 754 {
 755         entity pl;
 756         if(cteam != COLOR_TEAM1 || cteam != COLOR_TEAM2)
 757                 return world;
 758
 759         FOR_EACH_REALPLAYER(pl) {
 760                 if(pl.team == cteam && pl.iscommander) {
 761                         return pl;
 762                 }
 763         }
 764         return world;
 765 };
 766
 767 void(entity e, float st) ctf_setstate =
 768 {
 769         e.ctf_state = st;
 770         ++e.version;
 771 };
 772
 773 void(float cteam) ctf_new_commander =
 774 {
 775         entity pl, plmax;
 776
 777         plmax = world;
 778         FOR_EACH_REALPLAYER(pl) {
 779                 if(pl.team == cteam) {
 780                         if(pl.iscommander) { // don't reassign if alreay there
 781                                 return;
 782                         }
 783                         if(plmax == world || plmax.frags < pl.frags) <<<<<<<<<<<<<<<<< BROKEN in new scoring system
 784                                 plmax = pl;
 785                 }
 786         }
 787         if(plmax == world) {
 788                 bprint(strcat(ColoredTeamName(cteam), " Team has no Commander!\n"));
 789                 return;
 790         }
 791
 792         plmax.iscommander = TRUE;
 793         ctf_setstate(plmax, 3);
 794         sprint(plmax, "^3You're the commander now!\n");
 795         centerprint(plmax, "^3You're the commander now!\n");
 796 };
 797
 798 void() ctf_clientconnect =
 799 {
 800         self.iscommander = FALSE;
 801
 802         if(!self.team || self.classname != "player") {
 803                 ctf_setstate(self, -1);
 804         } else
 805                 ctf_setstate(self, 0);
 806
 807         self.team_saved = self.team;
 808
 809         if(self.team != 0 && self.classname == "player" && !ctf_team_has_commander(self.team)) {
 810                 ctf_new_commander(self.team);
 811         }
 812 };
 813
 814 void() ctf_playerchanged =
 815 {
 816         if(!self.team || self.classname != "player") {
 817                 ctf_setstate(self, -1);
 818         } else if(self.ctf_state < 0 && self.classname == "player") {
 819                 ctf_setstate(self, 0);
 820         }
 821
 822         if(self.iscommander &&
 823            (self.classname != "player" || self.team != self.team_saved)
 824                 )
 825         {
 826                 self.iscommander = FALSE;
 827                 if(self.classname == "player")
 828                         ctf_setstate(self, 0);
 829                 else
 830                         ctf_setstate(self, -1);
 831                 ctf_new_commander(self.team_saved);
 832         }
 833
 834         self.team_saved = self.team;
 835
 836         ctf_new_commander(self.team);
 837 };
 838
 839 void() ctf_clientdisconnect =
 840 {
 841         if(self.iscommander)
 842         {
 843                 ctf_new_commander(self.team);
 844         }
 845 };
 846
 847 entity GetPlayer(string);
 848 float() ctf_clientcommand =
 849 {
 850         entity e;
 851         if(argv(0) == "order") {
 852                 if(!g_ctf) {
 853                         sprint(self, "This command is not supported in this gamemode.\n");
 854                         return TRUE;
 855                 }
 856                 if(!self.iscommander) {
 857                         sprint(self, "^1You are not the commander!\n");
 858                         return TRUE;
 859                 }
 860                 if(argv(2) == "") {
 861                         sprint(self, "Usage: order #player status   - (playernumber as in status)\n");
 862                         return TRUE;
 863                 }
 864                 e = GetPlayer(argv(1));
 865                 if(e == world) {
 866                         sprint(self, "Invalid player.\nUsage: order #player status   - (playernumber as in status)\n");
 867                         return TRUE;
 868                 }
 869                 if(e.team != self.team) {
 870                         sprint(self, "^3You can only give orders to your own team!\n");
 871                         return TRUE;
 872                 }
 873                 if(argv(2) == "attack") {
 874                         sprint(self, strcat("Ordering ", e.netname, " to attack!\n"));
 875                         sprint(e, "^1Attack!\n");
 876                         centerprint(e, "^7You've been ordered to^9\n^1Attack!\n");
 877                         ctf_setstate(e, 1);
 878                 } else if(argv(2) == "defend") {
 879                         sprint(self, strcat("Ordering ", e.netname, " to defend!\n"));
 880                         sprint(e, "^Defend!\n");
 881                         centerprint(e, "^7You've been ordered to^9\n^2Defend!\n");
 882                         ctf_setstate(e, 2);
 883                 } else {
 884                         sprint(self, "^7Invalid command, use ^3attack^7, or ^3defend^7.\n");
 885                 }
 886                 return TRUE;
 887         }
 888         return FALSE;
 889 };
 890 */