data/qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags;
   6         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   7
   8         nags = 0;
   9         if(readycount)
  10         {
  11                 nags |= 1;
  12                 if(to.ready == 0)
  13                         nags |= 2;
  14         }
  15         if(votecalled)
  16         {
  17                 nags |= 4;
  18                 if(to.vote_vote == 0)
  19                         nags |= 8;
  20         }
  21
  22         if(sendflags & 128)
  23         {
  24                 WriteByte(MSG_ENTITY, nags | 128);
  25                 if(votecalled)
  26                         WriteString(MSG_ENTITY, votecalledvote_display);
  27                 else
  28                         WriteString(MSG_ENTITY, "");
  29         }
  30         else
  31                 WriteByte(MSG_ENTITY, nags);
  32
  33         return TRUE;
  34 }
  35 void Nagger_Init()
  36 {
  37         nagger = spawn();
  38         Net_LinkEntity(nagger);
  39         nagger.SendFlags = 128;
  40         nagger.SendEntity = Nagger_SendEntity;
  41 }
  42 void Nagger_VoteChanged()
  43 {
  44         if(nagger)
  45                 nagger.SendFlags = 128;
  46 }
  47 void Nagger_VoteCountChanged()
  48 {
  49         if(nagger)
  50                 nagger.SendFlags = 1;
  51 }
  52 void Nagger_ReadyCounted()
  53 {
  54         if(nagger)
  55                 nagger.SendFlags = 1;
  56 }
  57
  58 void ReadyCount();
  59 string MapVote_Suggest(string m);
  60
  61 .float floodcontrol_chat;
  62 .float floodcontrol_team;
  63 void Say(entity source, float teamsay, string msgin)
  64 {
  65         string msgstr, colorstr, cmsgstr, namestr;
  66         float flood;
  67         entity head;
  68
  69         if(Ban_MaybeEnforceBan(source))
  70                 return;
  71
  72         if(!teamsay)
  73                 if(substring(msgin, 0, 1) == " ")
  74                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  75
  76         msgin = formatmessage(msgin);
  77
  78         if(msgin == "")
  79                 return;
  80
  81         if(source.classname != "player")
  82                 colorstr = "^0"; // black for spectators
  83         else if(teams_matter)
  84                 colorstr = Team_ColorCode(source.team);
  85         else
  86                 teamsay = FALSE;
  87
  88         if(intermission_running)
  89                 teamsay = FALSE;
  90
  91         /*
  92          * using bprint solves this... me stupid
  93         // how can we prevent the message from appearing in a listen server?
  94         // for now, just give "say" back and only handle say_team
  95         if(!teamsay)
  96         {
  97                 clientcommand(self, strcat("say ", msgin));
  98                 return;
  99         }
 100         */
 101
 102         if(cvar("g_chat_teamcolors"))
 103                 namestr = playername(source);
 104         else
 105                 namestr = source.netname;
 106         if(teamsay)
 107         {
 108                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
 109                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
 110         }
 111         else
 112                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
 113
 114         // FLOOD CONTROL
 115         flood = 0;
 116         {
 117                 float flood_spl;
 118                 float flood_burst;
 119                 float flood_lmax;
 120                 var .float flood_field;
 121                 float lines;
 122                 if(teamsay)
 123                 {
 124                         flood_spl = cvar("g_chat_flood_spl_team");
 125                         flood_burst = cvar("g_chat_flood_burst_team");
 126                         flood_lmax = cvar("g_chat_flood_lmax_team");
 127                         flood_field = floodcontrol_team;
 128                 }
 129                 else
 130                 {
 131                         flood_spl = cvar("g_chat_flood_spl");
 132                         flood_burst = cvar("g_chat_flood_burst");
 133                         flood_lmax = cvar("g_chat_flood_lmax");
 134                         flood_field = floodcontrol_chat;
 135                 }
 136                 flood_burst = max(0, flood_burst - 1);
 137                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 138                 lines = ceil(strlennocol(msgstr) / 75);
 139                 if(flood_lmax && lines > flood_lmax)
 140                         flood = 2;
 141                 else if(time >= self.flood_field)
 142                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
 143                 else
 144                         flood = 1;
 145         }
 146
 147         if(flood)
 148         {
 149                 if(cvar("g_chat_flood_notify_flooder"))
 150                 {
 151                         if(flood == 1)
 152                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
 153                         else if(flood == 2)
 154                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
 155                 }
 156                 else
 157                         sprint(self, msgstr);
 158                 print("NOTE: ", playername(self), "^7 is flooding.\n");
 159         }
 160         else if(teamsay)
 161         {
 162                 if(source.classname == "player")
 163                 {
 164                         FOR_EACH_REALPLAYER(head)
 165                         {
 166                                 if(head.team == source.team)
 167                                 {
 168                                         sprint(head, msgstr);
 169                                         centerprint(head, cmsgstr);
 170                                 }
 171                         }
 172                 }
 173                 else
 174                 {
 175                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 176                         {
 177                                 sprint(head, msgstr);
 178                                 centerprint(head, cmsgstr);
 179                         }
 180                 }
 181         }
 182         else
 183         {
 184                 // TODO invent a cvar name for allowing global chat by spectators during warmup anyway
 185                 if(cvar("g_chat_nospectators") && source.classname != "player") {
 186                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 187                                 sprint(head, msgstr);
 188                         }
 189                 }
 190                 else
 191                         bprint(msgstr);
 192         }
 193
 194         strunzone(msgstr);
 195 }
 196
 197 entity GetPlayer(string name)
 198 {
 199         float num;
 200         entity e;
 201         string ns;
 202
 203         if(substring(name, 0, 1) == "#") {
 204                 num = stof(substring(name, 1, 999));
 205                 if(num >= 1 && num <= maxclients) {
 206                         for((e = world); num > 0; --num, (e = nextent(e)))
 207                                 ;
 208                         //if(clienttype(e) == CLIENTTYPE_REAL)
 209                         if(e.classname == "player")
 210                                 return e;
 211                 }
 212         } else {
 213                 ns = strdecolorize(name);
 214                 FOR_EACH_REALPLAYER(e) {
 215                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 216                                 return e;
 217                         }
 218                 }
 219         }
 220         return world;
 221 }
 222
 223 //float ctf_clientcommand();
 224 float readyrestart_happened;
 225 void SV_ParseClientCommand(string s) {
 226         local string cmd;
 227         local float i, j, tokens, f, effectnum;
 228         local vector start, end;
 229
 230         tokens = tokenize_sane(s);
 231
 232         if(GameCommand_Vote(s, self)) {
 233                 return;
 234         } else if(GameCommand_MapVote(argv(0))) {
 235                 return;
 236         } else if(argv(0) == "autoswitch") {
 237                 // be backwards compatible with older clients (enabled)
 238                 self.autoswitch = ("0" != argv(1));
 239                 local string autoswitchmsg;
 240                 if (self.autoswitch) {
 241                         autoswitchmsg = "on";
 242                 } else {
 243                         autoswitchmsg = "off";
 244                 }
 245                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 246         } else if(argv(0) == "clientversion") {
 247                 if not(self.flags & FL_CLIENT)
 248                         return;
 249                 if (argv(1) == "$gameversion") {
 250                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 251                         // either that or someone wants to be funny
 252                         self.version = 1;
 253                 } else {
 254                         self.version = stof(argv(1));
 255                 }
 256                 if(self.version != cvar("gameversion"))
 257                 {
 258                         self.classname = "observer";
 259                         self.version_mismatch = 1;
 260                         PutClientInServer();
 261                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 262                         //JoinBestTeam(self, FALSE, TRUE);
 263                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 264                         self.classname = "observer";
 265                         stuffcmd(self,"menu_showteamselect\n");
 266                 }
 267         } else if(argv(0) == "reportcvar") { // old system
 268                 GetCvars(1);
 269         } else if(argv(0) == "sentcvar") { // new system
 270                 GetCvars(1);
 271         } else if(argv(0) == "spectate") {
 272                 if not(self.flags & FL_CLIENT)
 273                         return;
 274                 if(g_lms || g_arena)
 275                         return; // don't allow spectating in lms, unless player runs out of lives
 276                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 277                         if(self.flagcarried)
 278                                 DropFlag(self.flagcarried, world, world);
 279                         kh_Key_DropAll(self, TRUE);
 280                         WaypointSprite_PlayerDead();
 281                         self.classname = "observer";
 282                         if(blockSpectators)
 283                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 284                         PutClientInServer();
 285                 }
 286         } else if(argv(0) == "join") {
 287                 if not(self.flags & FL_CLIENT)
 288                         return;
 289                 if(!g_arena)
 290                 if (self.classname != "player" && !lockteams)
 291                 {
 292                         if(isJoinAllowed()) {
 293                                 self.classname = "player";
 294                                 PlayerScore_Clear(self);
 295                                 bprint ("^4", self.netname, "^4 is playing now\n");
 296                                 PutClientInServer();
 297                         }
 298                         else {
 299                                 //player may not join because of g_maxplayers is set
 300                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 301                         }
 302                 }
 303         } else if( argv(0) == "selectteam" ) {
 304                 if not(self.flags & FL_CLIENT)
 305                         return;
 306                 if( !cvar("teamplay") ) {
 307                         sprint( self, "selecteam can only be used in teamgames\n");
 308                 } else if(cvar("g_campaign")) {
 309                         //JoinBestTeam(self, 0);
 310                 } else if(lockteams) {
 311                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 312                 } else if( argv(1) == "red" ) {
 313                         DoTeamChange(COLOR_TEAM1);
 314                 } else if( argv(1) == "blue" ) {
 315                         DoTeamChange(COLOR_TEAM2);
 316                 } else if( argv(1) == "yellow" ) {
 317                         DoTeamChange(COLOR_TEAM3);
 318                 } else if( argv(1) == "pink" ) {
 319                         DoTeamChange(COLOR_TEAM4);
 320                 } else if( argv(1) == "auto" ) {
 321                         DoTeamChange(-1);
 322                 } else {
 323                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 324                 }
 325         } else if(argv(0) == "ready") {
 326                 if not(self.flags & FL_CLIENT)
 327                         return;
 328                 if((inWarmupStage && 0 < g_warmup_limit) // with unlimited warmup players have to be able to restart
 329                    || cvar("sv_ready_restart"))
 330                 {
 331                         if(timeoutStatus) {
 332                                 return sprint(self, "^1You cannot reset the game while a timeout is active!\n");
 333                         }
 334
 335                         //if(!restartAnnouncer)
 336                         {
 337                                 if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 338                                 {
 339                                         self.ready = TRUE;
 340                                         bprint(self.netname, "^2 is ready\n");
 341                                         ReadyCount();
 342                                 } else {
 343                                         sprint(self, "^1game has already been restarted\n");
 344                                 }
 345                         }
 346                 }
 347         } else if(argv(0) == "maplist") {
 348                 local float n;
 349                 local string col;
 350                 n = tokenize_sane(cvar_string("g_maplist"));
 351                 sprint(self, "^7Maps in list: ");
 352                 for(i = 0, j = 0; i < n; ++i)
 353                 {
 354                         if(MapInfo_CheckMap(argv(i)))
 355                         {
 356                                 if(mod(j, 2))
 357                                         col = "^2";
 358                                 else
 359                                         col = "^3";
 360                                 sprint(self, strcat(col, argv(i), " "));
 361                                 ++j;
 362                         }
 363                 }
 364                 sprint(self, "\n");
 365         } else if(argv(0) == "lsmaps") {
 366                 sprint(self, "^7Maps available: ");
 367                 for(i = 0, j = 0; i < MapInfo_count; ++i)
 368                 {
 369                         if(MapInfo_Get_ByID(i))
 370                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 371                         {
 372                                 if(mod(i, 2))
 373                                         col = "^2";
 374                                 else
 375                                         col = "^3";
 376                                 ++j;
 377                                 sprint(self, strcat(col, MapInfo_Map_bspname, " "));
 378                         }
 379                 }
 380                 sprint(self, "\n");
 381         } else if(argv(0) == "voice") {
 382                 VoiceMessage(argv(1));
 383         } else if(argv(0) == "say") {
 384                 if(tokens >= 2)
 385                         Say(self, FALSE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 386                 //clientcommand(self, formatmessage(s));
 387         } else if(argv(0) == "say_team") {
 388                 if(tokens >= 2)
 389                         Say(self, TRUE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 390                 //clientcommand(self, formatmessage(s));
 391         } else if(argv(0) == "info") {
 392                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 393                 if(cmd == "")
 394                         sprint(self, "ERROR: unsupported info command\n");
 395                 else
 396                         wordwrap_sprint(cmd, 1111);
 397         } else if(argv(0) == "suggestmap") {
 398                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 399         } else if(argv(0) == "calltimeout") {
 400                 if not(self.flags & FL_CLIENT)
 401                         return;
 402                 if(cvar("sv_timeout")) {
 403                         if(self.classname == "player") {
 404                                 if(votecalled)
 405                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 406                                 else
 407                                         evaluateTimeoutCall();
 408                         }
 409                         else
 410                                 sprint(self, "^7Error: only players can call a timeout!\n");
 411                 }
 412         } else if(argv(0) == "resumegame") {
 413                 if not(self.flags & FL_CLIENT)
 414                         return;
 415                 if(cvar("sv_timeout")) {
 416                         evaluateResumeGame();
 417                 }
 418         } else if(argv(0) == "teamstatus") {
 419                 Score_NicePrint(self);
 420         } else if(argv(0) == "cvar_changes") {
 421                 sprint(self, cvar_changes);
 422         } else if(argv(0) == "pointparticles") {
 423                 if(sv_cheats && tokens == 5)
 424                 {
 425                         // arguments:
 426                         //   effectname
 427                         //   origin (0..1, on crosshair line)
 428                         //   velocity
 429                         //   howmany
 430                         effectnum = particleeffectnum(argv(1));
 431                         f = stof(argv(2));
 432                         start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 433                         end = stov(argv(3));
 434                         f = stof(argv(4));
 435                         pointparticles(effectnum, start, end, f);
 436                 }
 437                 else
 438                         print("Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 439         } else if(argv(0) == "trailparticles") {
 440                 if(sv_cheats && tokens == 3)
 441                 {
 442                         // arguments:
 443                         //   effectname
 444                         //   shot origin vector
 445                         effectnum = particleeffectnum(argv(1));
 446                         W_SetupShot(self, stov(argv(2)), FALSE, FALSE, "");
 447                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 448                         trailparticles(self, effectnum, w_shotorg, trace_endpos);
 449                 }
 450                 else
 451                         print("Usage: sv_cheats 1; restart; cmd trailparticles effectname shotorigin\n");
 452         } else {
 453                 //if(ctf_clientcommand())
 454                 //      return;
 455                 cmd = argv(0);
 456                 /* checks not needed any more since DP has separated clientcommands and regular commands
 457                 if(cmd != "status")
 458                 if(cmd != "name")
 459                 //if(cmd != "say") // handled above
 460                 //if(cmd != "say_team") // handled above
 461                 if(cmd != "tell")
 462                 if(cmd != "color")
 463                 if(cmd != "kill")
 464                 if(cmd != "pause")
 465                 if(cmd != "kick")
 466                 if(cmd != "ping")
 467                 if(cmd != "pings")
 468                 if(cmd != "ban")
 469                 if(cmd != "pmodel")
 470                 if(cmd != "rate")
 471                 if(cmd != "playermodel")
 472                 if(cmd != "playerskin")
 473                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 474                 {
 475                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 476                         return;
 477                 }
 478                 */
 479                 clientcommand(self,s);
 480         }
 481 }
 482
 483 void ReadyRestart()
 484 {
 485         local entity e;
 486
 487         bprint("^1Server is restarting...\n");
 488
 489         VoteReset();
 490
 491         // no arena, assault support yet...
 492         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 493                 localcmd("restart\n");
 494
 495         // clear overtime
 496         if(checkrules_overtimeend)
 497                 checkrules_overtimeend = 0;
 498
 499         readyrestart_happened = 1;
 500         game_starttime = time + RESTART_COUNTDOWN;
 501         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 502
 503         inWarmupStage = 0; //once the game is restarted the game is in match stage
 504
 505         //reset the .ready status of all players (also spectators)
 506         FOR_EACH_CLIENTSLOT(e)
 507                 e.ready = 0;
 508         readycount = 0;
 509         Nagger_ReadyCounted();
 510         FOR_EACH_REALCLIENT(e)
 511         {
 512                 msg_entity = e;
 513                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
 514                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
 515                 WriteByte(MSG_ONE, 0);
 516         }
 517
 518         if(cvar("teamplay_lockonrestart") && teams_matter) {
 519                 lockteams = 1;
 520                 bprint("^1The teams are now locked.\n");
 521         }
 522
 523         //initiate the restart-countdown-announcer entity
 524         restartAnnouncer = spawn();
 525         restartAnnouncer.think = restartAnnouncer_Think;
 526         restartAnnouncer.nextthink = time;
 527         restartAnnouncer.spawnflags = !!cvar("sv_ready_restart_after_countdown");
 528
 529         //after a restart every players number of allowed timeouts gets reset, too
 530         if(cvar("sv_timeout"))
 531         {
 532                 FOR_EACH_REALPLAYER(e)
 533                         e.allowedTimeouts = cvar("sv_timeout_number");
 534         }
 535
 536         //play the prepareforbattle sound to everyone
 537         play2all("announcer/robotic/prepareforbattle.wav");
 538
 539         //reset map immediately if this cvar is not set
 540         if (!cvar("sv_ready_restart_after_countdown"))
 541                 reset_map();
 542
 543         // reset ALL scores
 544         Score_ClearAll();
 545
 546         if(cvar("sv_eventlog"))
 547                 GameLogEcho(":restart");
 548 }
 549
 550 /**
 551  * Counts how many players are ready. If not enough players are ready, the function
 552  * does nothing. If all players are ready, the timelimit will be extended and the
 553  * restart_countdown variable is set to allow other functions like PlayerPostThink
 554  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 555  * is not set the map will be resetted.
 556  *
 557  * Function is called after the server receives a 'ready' sign from a player.
 558  */
 559 void ReadyCount()
 560 {
 561         local entity e;
 562         local float r, p;
 563
 564         r = p = 0;
 565
 566         FOR_EACH_REALPLAYER(e)
 567         {
 568                 p += 1;
 569                 if(e.ready)
 570                         r += 1;
 571         }
 572
 573         readycount = r;
 574
 575         if(r) // at least one is ready
 576         if(r == p) // and, everyone is ready
 577                 ReadyRestart();
 578
 579         Nagger_ReadyCounted();
 580 }
 581
 582 /**
 583  * Shows the restart countdown for all players.
 584  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 585  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 586  * is set to 1).
 587  */
 588 void restartAnnouncer_Think() {
 589         local entity plr;
 590         local string s;
 591         float f, c;
 592         c = game_starttime - time;
 593         f = floor(0.5 + c);
 594         if(c <= 0) { //show the "Begin" message and
 595                 if(self.spawnflags & 1)
 596                 {
 597                         restart_mapalreadyrestarted = 1;
 598                         reset_map();
 599                 }
 600
 601                 FOR_EACH_REALCLIENT(plr) {
 602                         if(plr.classname == "player") {
 603                                 s = strcat(NEWLINES, "^1Begin!");
 604                                 centerprint(plr, s);
 605                         }
 606                 }
 607                 play2all("announcer/robotic/begin.wav");
 608
 609                 remove(self);
 610                 return;
 611         }
 612         else {
 613                 FOR_EACH_REALCLIENT(plr) {
 614                         if(plr.classname == "player") {
 615                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(f), " seconds");
 616                                 centerprint(plr, s);
 617                         }
 618                 }
 619
 620                 if(f <= 3) {
 621                         play2all(strcat("announcer/robotic/", ftos(f), ".wav"));
 622                 }
 623                 self.nextthink = game_starttime - (f - 1);
 624         }
 625 }
 626
 627 /**
 628  * Checks whether the player who calls the timeout is allowed to do so.
 629  * If so, it initializes the timeout countdown. It also checks whether another
 630  * timeout was already running at this time and reacts correspondingly.
 631  *
 632  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 633  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 634  *
 635  * This function is called when a player issues the calltimeout command.
 636  */
 637 void evaluateTimeoutCall() {
 638         if (inWarmupStage && !g_warmup_allow_timeout)
 639                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 640         if (time < game_starttime )
 641                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 642         if (timeoutStatus != 2) {
 643                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 644                 if (cvar("timelimit")) {
 645                         //a timelimit was used
 646                         local float myTl;
 647                         myTl = cvar("timelimit");
 648
 649                         local float lastPossibleTimeout;
 650                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 651
 652                         if (lastPossibleTimeout < time - game_starttime)
 653                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 654                 }
 655         }
 656         //player may not call a timeout if he has no calls left
 657         if (self.allowedTimeouts < 1)
 658                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 659         //now all required checks are passed
 660         self.allowedTimeouts -= 1;
 661         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 662         remainingTimeoutTime = cvar("sv_timeout_length");
 663         remainingLeadTime = cvar("sv_timeout_leadtime");
 664         timeoutInitiator = self;
 665         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 666                 timeoutStatus = 1;
 667                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 668                 timeoutHandler = spawn();
 669                 timeoutHandler.think = timeoutHandler_Think;
 670         }
 671         timeoutHandler.nextthink = time; //always let the entity think asap
 672
 673         //inform all connected clients about the timeout call
 674         play2all("announcer/robotic/timeoutcalled.wav");
 675 }
 676
 677 /**
 678  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 679  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 680  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 681  * value of the cvar sv_timeout_resumetime.
 682  *
 683  * This function is called when a player issues the resumegame command.
 684  */
 685 void evaluateResumeGame() {
 686         if (!timeoutStatus)
 687                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 688         if (self != timeoutInitiator)
 689                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 690         if (timeoutStatus == 1) {
 691                 remainingTimeoutTime = timeoutStatus = 0;
 692                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 693                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 694         }
 695         else if (timeoutStatus == 2) {
 696                 //only shorten the remainingTimeoutTime if it makes sense
 697                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 698                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 699                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 700                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 701                 }
 702                 else
 703                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 704
 705         }
 706 }