data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 float ValidateMap(string vote);
   3 void(entity e) DropFlag;
   4
   5 void Say(entity source, float teamsay, string msgin)
   6 {
   7         string msgstr, colorstr, cmsgstr;
   8         entity head;
   9
  10         msgin = formatmessage(msgin);
  11
  12         if(msgin == "")
  13                 return;
  14
  15         colorstr = Team_ColorCode(source.team);
  16
  17         if(!teams_matter)
  18                 teamsay = FALSE;
  19
  20         if(source.classname != "player") // observers can't
  21                 teamsay = FALSE;
  22
  23         // how can we prevent the message from appearing in a listen server?
  24         // for now, just give "say" back and only handle say_team
  25         if(!teamsay)
  26         {
  27                 clientcommand(self, strcat("say ", msgin));
  28                 return;
  29         }
  30
  31         if(teamsay)
  32         {
  33                 msgstr = strzone(strcat("\{1}", colorstr, "(^3", source.netname, colorstr, ") ^7", msgin, "\n"));
  34                 cmsgstr = strcat(colorstr, "(^3", source.netname, colorstr, ")\n^7", wordwrap(msgin, 50));
  35         }
  36         else
  37                 msgstr = strzone(strcat("\{1}^3", source.netname, "^7: ", msgin, "\n"));
  38
  39         head = find(world, classname, "player");
  40         while(head)
  41         {
  42                 if(clienttype(head) == CLIENTTYPE_REAL)
  43                         if(!teamsay || (head.team == source.team))
  44                         {
  45                                 sprint(head, msgstr);
  46                                 if(teamsay)
  47                                         centermsg_setfor(head, CENTERMSG_TEAMSAY, cmsgstr);
  48                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  49                         }
  50                 head = find(head, classname, "player");
  51         }
  52
  53         if(!teamsay)
  54         {
  55                 head = find(world, classname, "observer");
  56                 while(head)
  57                 {
  58                         if(clienttype(head) == CLIENTTYPE_REAL)
  59                         {
  60                                 sprint(head, msgstr);
  61                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  62                         }
  63                         head = find(head, classname, "observer");
  64                 }
  65                 head = find(world, classname, "spectator");
  66                 while(head)
  67                 {
  68                         if(clienttype(head) == CLIENTTYPE_REAL)
  69                         {
  70                                 sprint(head, msgstr);
  71                                 //stuffcmd(head, "play2 misc/talk.wav\n");
  72                         }
  73                         head = find(head, classname, "spectator");
  74                 }
  75                 ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
  76         }
  77
  78         strunzone(msgstr);
  79 }
  80
  81 void SV_ParseClientCommand(string s) {
  82         local float index;
  83
  84         tokenize(s);
  85
  86         if(argv(0) == "clogin") {
  87                 if(cvar("sv_clientcommands")) {
  88                         if(self.adminstatus < -5) {
  89                                 sprint(self, "Too many unsuccessful tries.\n");
  90                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  91                                 self.adminstatus = 1;
  92                                 sprint(self, "You now have remote admin status.\n");
  93                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " received admin status"), TRUE);
  94                         } else {
  95                                 sprint(self, "Wrong password.\n");
  96                                 // use of -- produces compiler warning in the if() line???
  97                                 self.adminstatus = self.adminstatus - 1;
  98                                 if(self.adminstatus == 0)
  99                                 {
 100                                         sprint(self, "You lost remote admin status.\n");
 101                                         ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " lost admin status"), TRUE);
 102                                 }
 103                         }
 104                 } else {
 105                         sprint(self, "Clientside commands NOT allowed.\n");
 106                 }
 107         } else if(argv(0) == "ccmd") {
 108                 if(cvar("sv_clientcommands")) {
 109                         if(self.adminstatus > 0) {
 110                                 local string command;
 111                                 command = argv(1);
 112                                 index = 2;
 113                                 while(argv(index) != "") {
 114                                         command = strcat(command, " ", argv(index));
 115                                         index++;
 116                                 }
 117                                 command = strzone(command);
 118                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " issued command '", command, "'"), TRUE);
 119                                 localcmd(strcat(command, "\n"));
 120                                 strunzone(command);
 121                         } else
 122                                 sprint(self, "You don't have remote admin status.\n");
 123                 } else {
 124                         sprint(self, "Clientside commands NOT allowed.\n");
 125                 }
 126         } else if(argv(0) == "vote") {
 127                 if(argv(1) == "help") {
 128                         local string vmasterdis;
 129                         if(!cvar("sv_vote_master")) {
 130                                 vmasterdis = " ^1(disabled)";
 131                         }
 132                         local string vcalldis;
 133                         if(!cvar("sv_vote_call")) {
 134                                 vcalldis = " ^1(disabled)";
 135                         }
 136                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
 137                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
 138                         sprint(self, "^7\"^2help^7\" shows this info.\n");
 139                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
 140                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
 141                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
 142                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
 143                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
 144                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
 145                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
 146                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
 147                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
 148                         sprint(self, "^7You can call a vote for or execute these commands:\n");
 149                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
 150                 } else if(argv(1) == "status") {
 151                         if(votecalled) {
 152                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
 153                         } else {
 154                                 sprint(self, "^1No vote called.\n");
 155                         }
 156                 } else if(argv(1) == "call") {
 157                         if(cvar("sv_vote_call")) {
 158                                 if(votecalled) {
 159                                         sprint(self, "^1There is already a vote called.\n");
 160                                 } else {
 161                                         local string vote;
 162                                         vote = VoteParse();
 163                                         if(vote == "") {
 164                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
 165                                         } else if(time < self.vote_next) {
 166                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
 167                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 168                                                 if(!ValidateMap(vote))
 169                                                         return;
 170                                                 votecalled = TRUE;
 171                                                 votecalledmaster = FALSE;
 172                                                 // remap chmap to gomap (forces intermission)
 173                                                 if(strlen(vote) >= 6)
 174                                                         if(substring(vote, 0, 6) == "chmap ")
 175                                                                 vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
 176                                                 votecalledvote = strzone(vote);
 177                                                 votecaller = self; // remember who called the vote
 178                                                 votefinished = time + cvar("sv_vote_timeout");
 179                                                 votecaller.vote_vote = 1; // of course you vote yes
 180                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
 181                                                 bprint(strcat("^3Vote for \"^1", votecalledvote, "^3\" called by \"^7", votecaller.netname, "^3\".\n"));
 182                                                 VoteCount(); // needed if you are the only one
 183                                         } else {
 184                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 185                                         }
 186                                 }
 187                         } else {
 188                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 189                         }
 190                 } else if(argv(1) == "stop") {
 191                         if(!votecalled) {
 192                                 sprint(self, "^1No vote called.\n");
 193                         } else if(self == votecaller
 194                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 195                                 VoteStop(self);
 196                         } else {
 197                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 198                         }
 199                 } else if(argv(1) == "master") {
 200                         if(cvar("sv_vote_master")) {
 201                                 if(votecalled) {
 202                                         sprint(self, "^1There is already a vote called.\n");
 203                                 } else {
 204                                         votecalled = TRUE;
 205                                         votecalledmaster = TRUE;
 206                                         votecalledvote = strzone("^3master");
 207                                         votecaller = self; // remember who called the vote
 208                                         votefinished = time + cvar("sv_vote_timeout");
 209                                         votecaller.vote_vote = 1; // of course you vote yes
 210                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 211                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 212                                         VoteCount(); // needed if you are the only one
 213                                 }
 214                         } else {
 215                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 216                         }
 217                 } else if(argv(1) == "do") {
 218                         if(self.vote_master) {
 219                                 local string dovote;
 220                                 dovote = VoteParse();
 221                                 if(dovote == "") {
 222                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 223                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 224                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 225                                         localcmd(strcat(dovote, "\n"));
 226                                 } else {
 227                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 228                                 }
 229                         } else {
 230                                 sprint(self, "^1You are NOT a master.\n");
 231                         }
 232                 } else if(argv(1) == "yes") {
 233                         if(!votecalled) {
 234                                 sprint(self, "^1No vote called.\n");
 235                         } else if(self.vote_vote == 0
 236                                   || cvar("sv_vote_change")) {
 237                                 sprint(self, "^1You accepted the vote.\n");
 238                                 self.vote_vote = 1;
 239                                 if(!cvar("sv_vote_singlecount")) {
 240                                         VoteCount();
 241                                 }
 242                         } else {
 243                                 sprint(self, "^1You have already voted.\n");
 244                         }
 245                 } else if(argv(1) == "no") {
 246                         if(!votecalled) {
 247                                 sprint(self, "^1No vote called.\n");
 248                         } else if(self.vote_vote == 0
 249                                   || cvar("sv_vote_change")) {
 250                                 sprint(self, "^1You rejected the vote.\n");
 251                                 self.vote_vote = -1;
 252                                 if(!cvar("sv_vote_singlecount")) {
 253                                         VoteCount();
 254                                 }
 255                         } else {
 256                                 sprint(self, "^1You have already voted.\n");
 257                         }
 258                 } else {
 259                         // ignore this?
 260                         sprint(self, "^1Unknown vote command.\n");
 261                 }
 262         } else if(argv(0) == "autoswitch") {
 263                 // be backwards compatible with older clients (enabled)
 264                 self.autoswitch = ("0" != argv(1));
 265                 local string autoswitchmsg;
 266                 if (self.autoswitch) {
 267                         autoswitchmsg = "on";
 268                 } else {
 269                         autoswitchmsg = "off";
 270                 }
 271                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 272         } else if(argv(0) == "clientversion") {
 273                 if (argv(1) == "$gameversion") {
 274                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 275                         // either that or someone wants to be funny
 276                         self.version = 1;
 277                 } else {
 278                         self.version = stof(argv(1));
 279                 }
 280                 if(self.version != cvar("gameversion"))
 281                 {
 282                         self.classname = "observer";
 283                         self.frags = -2;
 284                         PutClientInServer();
 285                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
 286                         //JoinBestTeam(self, 0);
 287                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 288                         self.classname = "observer";
 289                         stuffcmd(self,"menu_showteamselect\n");
 290                 }
 291         } else if(argv(0) == "reportcvar") {
 292                 GetCvars(1);
 293         } else if(argv(0) == "spectate") {
 294                 if(cvar("g_lms") || cvar("g_arena"))
 295                         return; // don't allow spectating in lms, unless player runs out of lives
 296                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 297                         if(self.flagcarried)
 298                                 DropFlag(self.flagcarried);
 299                         DistributeFragsAmongTeam(self, self.team, 1.0);
 300                         self.classname = "observer";
 301                         PutClientInServer();
 302                 }
 303         } else if(argv(0) == "join") {
 304                 if(!cvar("g_arena"))
 305                 if (self.classname != "player")
 306                 {
 307                         self.classname = "player";
 308                         self.frags = 0;
 309                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 310                         PutClientInServer();
 311                 }
 312         } else if( argv(0) == "selectteam" ) {
 313                 if( !cvar("teamplay") ) {
 314                         sprint( self, "selecteam can only be used in teamgames\n");
 315                 } else if(cvar("g_campaign")) {
 316                         //JoinBestTeam(self, 0);
 317                 } else if( argv(1) == "none" ) {
 318                         SV_ChangeTeam( 0 );
 319                 } else if( argv(1) == "red" ) {
 320                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 321                 } else if( argv(1) == "blue" ) {
 322                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 323                 } else if( argv(1) == "pink" ) {
 324                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 325                 } else if( argv(1) == "yellow" ) {
 326                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 327                 } else if( argv(1) == "auto" ) {
 328                         self.team = -1;
 329                         JoinBestTeam( self, 0 );
 330                 } else {
 331                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 332                 }
 333         } else if(argv(0) == "ready") {
 334                 if(cvar("sv_ready_restart"))
 335                 {
 336                         self.ready = TRUE;
 337                         bprint(self.netname, "^2 is ready\n");
 338                         ReadyCount();
 339                 }
 340         } else if(argv(0) == "say") {
 341                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 342                 //clientcommand(self, formatmessage(s));
 343         } else if(argv(0) == "say_team") {
 344                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 345                 //clientcommand(self, formatmessage(s));
 346         } else {
 347                 string cmd;
 348                 cmd = argv(0);
 349                 if(cmd != "status")
 350                 if(cmd != "name")
 351                 //if(cmd != "say") // handled above
 352                 //if(cmd != "say_team") // handled above
 353                 if(cmd != "tell")
 354                 if(cmd != "color")
 355                 if(cmd != "kill")
 356                 if(cmd != "pause")
 357                 if(cmd != "kick")
 358                 if(cmd != "ping")
 359                 if(cmd != "pings")
 360                 if(cmd != "ban")
 361                 if(cmd != "pmodel")
 362                 if(cmd != "rate")
 363                 if(cmd != "playermodel")
 364                 if(cmd != "playerskin")
 365                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 366                 {
 367                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 368                         return;
 369                 }
 370                 clientcommand(self,s);
 371         }
 372 }
 373
 374 float ValidateMap(string vote)
 375 {
 376         string ext;
 377
 378         tokenize(vote);
 379         if(argv(0) == "map" || argv(0) == "changelevel")
 380                 ext = ".bsp";
 381         else if(argv(0) == "chmap")
 382                 ext = ".mapcfg";
 383         else if(argv(0) == "gotomap")
 384                 ext = ".mapcfg";
 385         else
 386                 return TRUE;
 387
 388         if(!TryFile(strcat("maps/", argv(1), ext)))
 389         {
 390                 sprint(self, strcat("^1Invalid mapname, \"^3", argv(1), "^1\" does not exist on this server.\n"));
 391                 return FALSE;
 392         }
 393         return TRUE;
 394 }
 395
 396
 397 void VoteThink() {
 398         if(votefinished > 0 // a vote was called
 399             && time > votefinished) // time is up
 400         {
 401                 VoteCount();
 402         }
 403 }
 404
 405 string VoteParse() {
 406         local float index;
 407         index = 3;
 408         local string vote;
 409         vote = argv(2);
 410         while(argv(index) != "") {
 411                 vote = strcat(vote, " ", argv(index));
 412                 index++;
 413         }
 414
 415         // necessary for some of the string operations
 416         vote = strzone(vote);
 417
 418         // now we remove some things that could be misused
 419         index = 0;
 420         local float found;
 421         found = FALSE;
 422         local float votelength;
 423         votelength = strlen(vote);
 424         while(!found && index < votelength)
 425         {
 426                 local string badchar;
 427                 badchar = substring(vote, index, 1);
 428                 if(badchar == ";"
 429                    || badchar == "\r"
 430                    || badchar == "\n")
 431                 {
 432                         found = TRUE;
 433                 } else {
 434                         index++;
 435                 }
 436         }
 437         return substring(vote, 0, index);
 438 }
 439
 440 float VoteAllowed(string votecommand) {
 441         tokenize(cvar_string("sv_vote_commands"));
 442         local float index;
 443         index = 0;
 444         while(argv(index) != "") {
 445                 local string allowed;
 446                 allowed = argv(index);
 447                 if(votecommand == allowed) {
 448                         return TRUE;
 449                 }
 450                 index++;
 451         }
 452         return FALSE;
 453 }
 454
 455 void VoteReset() {
 456         local string searchclass;
 457         searchclass = "player";
 458
 459         while (TRUE)
 460         {
 461                 local entity player;
 462                 player = find(player, classname, searchclass);
 463                 while(player)
 464                 {
 465                         player.vote_vote = 0;
 466                         player = find(player, classname, searchclass);
 467                 }
 468
 469                 if("player" == searchclass) {
 470                         searchclass = "observer";
 471                 } else if("observer" == searchclass) {
 472                         searchclass = "spectator";
 473                 } else {
 474                         break;
 475                 }
 476         }
 477
 478         votecalled = FALSE;
 479         votecalledmaster = FALSE;
 480         votefinished = 0;
 481 }
 482
 483 void VoteAccept() {
 484         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was accepted.\n"));
 485         if(votecalledmaster)
 486         {
 487                 votecaller.vote_master = 1;
 488         } else {
 489                 localcmd(strcat(votecalledvote, "\n"));
 490         }
 491         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 492         VoteReset();
 493 }
 494
 495 void VoteReject() {
 496         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was rejected.\n"));
 497         VoteReset();
 498 }
 499
 500 void VoteTimeout() {
 501         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" did timeout.\n"));
 502         VoteReset();
 503 }
 504
 505 void VoteStop(entity stopper) {
 506         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" was stopped by \"^5", stopper.netname, "^5\".\n"));
 507         if(stopper == votecaller) {
 508                 // no wait for next vote so you can correct your vote
 509                 votecaller.vote_next = 0;
 510         }
 511         VoteReset();
 512 }
 513
 514 void VoteCount() {
 515         local float playercount;
 516         playercount = 0;
 517         local float yescount;
 518         yescount = 0;
 519         local float nocount;
 520         nocount = 0;
 521         local string searchclass;
 522         searchclass = "player";
 523
 524         while (TRUE)
 525         {
 526                 local entity player;
 527                 player = find(player, classname, searchclass);
 528
 529                 while(player)
 530                 {
 531                         if(clienttype(player) != CLIENTTYPE_BOT) {
 532                                 if(player.vote_vote < 0) {
 533                                         nocount++;
 534                                 } else if(player.vote_vote > 0) {
 535                                         yescount++;
 536                                 }
 537                                 playercount++;
 538                         }
 539                         player = find(player, classname, searchclass);
 540                 }
 541
 542                 if("player" == searchclass) {
 543                         searchclass = "observer";
 544                 } else if("observer" == searchclass) {
 545                         searchclass = "specator";
 546                 } else {
 547                         break;
 548                 }
 549         }
 550
 551         if((playercount == 1) && votecalledmaster) {
 552                 // if only one player is on the server becoming vote
 553                 // master is not allowed.  This could be used for
 554                 // trolling or worse. 'self' is the user who has
 555                 // called the vote because this function is called
 556                 // by SV_ParseClientCommand. Maybe all voting should
 557                 // be disabled for a single player?
 558                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 559                 votecaller.vote_next = 0;
 560                 VoteReset();
 561         } else if((playercount / 2) < yescount) { // vote accepted
 562                 VoteAccept();
 563         } else if((playercount / 2) < nocount) { // vote rejected
 564                 VoteReject();
 565         } else if(time > votefinished) { // vote timedout
 566                 VoteTimeout();
 567         } // else still running
 568 }
 569
 570
 571 void ReadyCount()
 572 {
 573         local entity e;
 574         local float r, p;
 575
 576         e = find(world, classname, "player");
 577
 578         while(e)
 579         {
 580                 if(clienttype(e) == CLIENTTYPE_REAL)
 581                 {
 582                         p += 1;
 583                         if(e.ready) r += 1;
 584                 }
 585                 e = find(e, classname, "player");
 586         }
 587
 588         if(p && r == p)
 589         {
 590                 bprint("^1Server is restarting...\n");
 591                 localcmd("restart\n");
 592         }
 593 }