data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 void(entity e) DropFlag;
   3 string MapVote_Suggest(string m);
   4
   5 .float floodcontrol_chat;
   6 .float floodcontrol_team;
   7 void Say(entity source, float teamsay, string msgin)
   8 {
   9         string msgstr, colorstr, cmsgstr, namestr;
  10         float flood;
  11         entity head;
  12
  13         if(!teamsay)
  14                 if(substring(msgin, 0, 1) == " ")
  15                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  16
  17         msgin = formatmessage(msgin);
  18
  19         if(msgin == "")
  20                 return;
  21
  22         if(source.classname != "player")
  23                 colorstr = "^0"; // black for spectators
  24         else if(teams_matter)
  25                 colorstr = Team_ColorCode(source.team);
  26         else
  27                 teamsay = FALSE;
  28
  29         if(intermission_running)
  30                 teamsay = FALSE;
  31
  32         /*
  33          * using bprint solves this... me stupid
  34         // how can we prevent the message from appearing in a listen server?
  35         // for now, just give "say" back and only handle say_team
  36         if(!teamsay)
  37         {
  38                 clientcommand(self, strcat("say ", msgin));
  39                 return;
  40         }
  41         */
  42
  43         if(cvar("g_chat_teamcolors"))
  44                 namestr = playername(source);
  45         else
  46                 namestr = source.netname;
  47         if(teamsay)
  48         {
  49                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  50                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  51         }
  52         else
  53                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  54
  55         // FLOOD CONTROL
  56         flood = 0;
  57         {
  58                 float flood_spl;
  59                 float flood_burst;
  60                 float flood_lmax;
  61                 var .float flood_field;
  62                 float lines;
  63                 if(teamsay)
  64                 {
  65                         flood_spl = cvar("g_chat_flood_spl_team");
  66                         flood_burst = cvar("g_chat_flood_burst_team");
  67                         flood_lmax = cvar("g_chat_flood_lmax_team");
  68                         flood_field = floodcontrol_team;
  69                 }
  70                 else
  71                 {
  72                         flood_spl = cvar("g_chat_flood_spl");
  73                         flood_burst = cvar("g_chat_flood_burst");
  74                         flood_lmax = cvar("g_chat_flood_lmax");
  75                         flood_field = floodcontrol_chat;
  76                 }
  77                 flood_burst = max(0, flood_burst - 1);
  78                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  79                 lines = ceil(strlennocol(msgstr) / 75);
  80                 if(flood_lmax && lines > flood_lmax)
  81                         flood = 2;
  82                 else if(time >= self.flood_field)
  83                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  84                 else
  85                         flood = 1;
  86         }
  87
  88         if(flood)
  89         {
  90                 if(cvar("g_chat_flood_notify_flooder"))
  91                 {
  92                         if(flood == 1)
  93                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  94                         else if(flood == 2)
  95                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  96                 }
  97                 else
  98                         sprint(self, msgstr);
  99                 print("NOTE: ", playername(self), "^7 is flooding.\n");
 100         }
 101         else if(teamsay)
 102         {
 103                 if(source.classname == "player")
 104                 {
 105                         FOR_EACH_REALPLAYER(head)
 106                         {
 107                                 if(head.team == source.team)
 108                                 {
 109                                         sprint(head, msgstr);
 110                                         centerprint(head, cmsgstr);
 111                                 }
 112                         }
 113                 }
 114                 else
 115                 {
 116                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 117                         {
 118                                 sprint(head, msgstr);
 119                                 centerprint(head, cmsgstr);
 120                         }
 121                 }
 122         }
 123         else
 124         {
 125                 //when g_tourney is active and g_tourney_disable_spec_chat is set and game is in matchstage
 126                 //don't print the text from specs/observers to the players but only the other spectators
 127                 if(g_tourney && cvar("g_tourney_disable_spec_chat") && tourneyInMatchStage && source.classname != "player") {
 128                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 129                                 sprint(head, msgstr);
 130                         }
 131                 }
 132                 else
 133                         bprint(msgstr);
 134         }
 135
 136         strunzone(msgstr);
 137 }
 138
 139 entity GetPlayer(string name)
 140 {
 141         float num;
 142         entity e;
 143         string ns;
 144
 145         if(substring(name, 0, 1) == "#") {
 146                 num = stof(substring(name, 1, 999));
 147                 if(num >= 1 && num <= maxclients) {
 148                         for((e = world); num > 0; --num, (e = nextent(e)))
 149                                 ;
 150                         //if(clienttype(e) == CLIENTTYPE_REAL)
 151                         if(e.classname == "player")
 152                                 return e;
 153                 }
 154         } else {
 155                 ns = strdecolorize(name);
 156                 FOR_EACH_REALPLAYER(e) {
 157                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 158                                 return e;
 159                         }
 160                 }
 161         }
 162         return world;
 163 }
 164
 165 //float ctf_clientcommand();
 166 void SV_ParseClientCommand(string s) {
 167         local string cmd;
 168         local float i;
 169
 170         tokenize(s);
 171
 172         if(GameCommand_Vote(s, self)) {
 173                 return;
 174         } else if(GameCommand_MapVote(argv(0))) {
 175                 return;
 176         } else if(argv(0) == "autoswitch") {
 177                 // be backwards compatible with older clients (enabled)
 178                 self.autoswitch = ("0" != argv(1));
 179                 local string autoswitchmsg;
 180                 if (self.autoswitch) {
 181                         autoswitchmsg = "on";
 182                 } else {
 183                         autoswitchmsg = "off";
 184                 }
 185                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 186         } else if(argv(0) == "clientversion") {
 187                 if not(self.flags & FL_CLIENT)
 188                         return;
 189                 if (argv(1) == "$gameversion") {
 190                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 191                         // either that or someone wants to be funny
 192                         self.version = 1;
 193                 } else {
 194                         self.version = stof(argv(1));
 195                 }
 196                 if(self.version != cvar("gameversion"))
 197                 {
 198                         self.classname = "observer";
 199                         self.version_mismatch = 1;
 200                         PutClientInServer();
 201                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 202                         //JoinBestTeam(self, FALSE, TRUE);
 203                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 204                         self.classname = "observer";
 205                         stuffcmd(self,"menu_showteamselect\n");
 206                 }
 207         } else if(argv(0) == "reportcvar") { // old system
 208                 GetCvars(1);
 209         } else if(argv(0) == "sentcvar") { // new system
 210                 GetCvars(1);
 211         } else if(argv(0) == "spectate") {
 212                 if not(self.flags & FL_CLIENT)
 213                         return;
 214                 if(g_lms || g_arena)
 215                         return; // don't allow spectating in lms, unless player runs out of lives
 216                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 217                         if(self.flagcarried)
 218                                 DropFlag(self.flagcarried);
 219                         kh_Key_DropAll(self, TRUE);
 220                         WaypointSprite_PlayerDead();
 221                         self.classname = "observer";
 222                         if(blockSpectators)
 223                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 224                         PutClientInServer();
 225                 }
 226         } else if(argv(0) == "join") {
 227                 if not(self.flags & FL_CLIENT)
 228                         return;
 229                 if(!g_arena)
 230                 if (self.classname != "player" && !lockteams)
 231                 {
 232                         if(isJoinAllowed()) {
 233                                 self.classname = "player";
 234                                 PlayerScore_Clear(self);
 235                                 bprint ("^4", self.netname, "^4 is playing now\n");
 236                                 PutClientInServer();
 237                         }
 238                         else {
 239                                 //player may not join because of g_maxplayers is set
 240                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 241                         }
 242                 }
 243         } else if( argv(0) == "selectteam" ) {
 244                 if not(self.flags & FL_CLIENT)
 245                         return;
 246                 if( !cvar("teamplay") ) {
 247                         sprint( self, "selecteam can only be used in teamgames\n");
 248                 } else if(cvar("g_campaign")) {
 249                         //JoinBestTeam(self, 0);
 250                 } else if(lockteams) {
 251                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 252                 } else if( argv(1) == "red" ) {
 253                         DoTeamChange(COLOR_TEAM1);
 254                 } else if( argv(1) == "blue" ) {
 255                         DoTeamChange(COLOR_TEAM2);
 256                 } else if( argv(1) == "yellow" ) {
 257                         DoTeamChange(COLOR_TEAM3);
 258                 } else if( argv(1) == "pink" ) {
 259                         DoTeamChange(COLOR_TEAM4);
 260                 } else if( argv(1) == "auto" ) {
 261                         DoTeamChange(-1);
 262                 } else {
 263                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 264                 }
 265         } else if(argv(0) == "ready") {
 266                 if not(self.flags & FL_CLIENT)
 267                         return;
 268                 if(cvar("sv_ready_restart"))
 269                 {
 270                         if(timeoutStatus) {
 271                                 return sprint(self, "^1You cannot reset the game while a timeout is active!\n");
 272                         }
 273
 274                         if(!restart_countdown || cvar("sv_ready_restart_repeatable"))
 275                         {
 276                                 self.ready = TRUE;
 277                                 bprint(self.netname, "^2 is ready\n");
 278                                 ReadyCount();
 279                         } else {
 280                                 sprint(self, "^1game has already been restarted\n");
 281                         }
 282                 }
 283         } else if(argv(0) == "maplist") {
 284                 local float n, j;
 285                 local string col;
 286                 n = tokenize(cvar_string("g_maplist"));
 287                 sprint(self, "^7Maps in list: ");
 288                 for(i = 0, j = 0; i < n; ++i)
 289                 {
 290                         if(MapInfo_CheckMap(argv(i)))
 291                         {
 292                                 if(mod(j, 2))
 293                                         col = "^2";
 294                                 else
 295                                         col = "^3";
 296                                 sprint(self, strcat(col, argv(i), " "));
 297                                 ++j;
 298                         }
 299                 }
 300                 sprint(self, "\n");
 301         } else if(argv(0) == "lsmaps") {
 302                 sprint(self, "^7Maps available: ");
 303                 for(i = 0; i < MapInfo_count; ++i)
 304                 {
 305                         if(mod(i, 2))
 306                                 col = "^2";
 307                         else
 308                                 col = "^3";
 309                         sprint(self, strcat(col, MapInfo_BSPName_ByID(i), " "));
 310                 }
 311                 sprint(self, "\n");
 312         } else if(argv(0) == "voice") {
 313                 VoiceMessage(argv(1));
 314         } else if(argv(0) == "say") {
 315                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 316                 //clientcommand(self, formatmessage(s));
 317         } else if(argv(0) == "say_team") {
 318                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 319                 //clientcommand(self, formatmessage(s));
 320         } else if(argv(0) == "info") {
 321                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 322                 if(cmd == "")
 323                         sprint(self, "ERROR: unsupported info command\n");
 324                 else
 325                         wordwrap_sprint(cmd, 1111);
 326         } else if(argv(0) == "suggestmap") {
 327                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 328         } else if(argv(0) == "calltimeout") {
 329                 if not(self.flags & FL_CLIENT)
 330                         return;
 331                 if(cvar("sv_timeout")) {
 332                         if(self.classname == "player") {
 333                                 if(votecalled)
 334                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 335                                 else
 336                                         evaluateTimeoutCall();
 337                         }
 338                         else
 339                                 sprint(self, "^7Error: only players can call a timeout!\n");
 340                 }
 341         } else if(argv(0) == "resumegame") {
 342                 if not(self.flags & FL_CLIENT)
 343                         return;
 344                 if(cvar("sv_timeout")) {
 345                         evaluateResumeGame();
 346                 }
 347         } else if(argv(0) == "teamstatus") {
 348                 Score_NicePrint(self);
 349         } else {
 350                 //if(ctf_clientcommand())
 351                 //      return;
 352                 cmd = argv(0);
 353                 /* checks not needed any more since DP has separated clientcommands and regular commands
 354                 if(cmd != "status")
 355                 if(cmd != "name")
 356                 //if(cmd != "say") // handled above
 357                 //if(cmd != "say_team") // handled above
 358                 if(cmd != "tell")
 359                 if(cmd != "color")
 360                 if(cmd != "kill")
 361                 if(cmd != "pause")
 362                 if(cmd != "kick")
 363                 if(cmd != "ping")
 364                 if(cmd != "pings")
 365                 if(cmd != "ban")
 366                 if(cmd != "pmodel")
 367                 if(cmd != "rate")
 368                 if(cmd != "playermodel")
 369                 if(cmd != "playerskin")
 370                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 371                 {
 372                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 373                         return;
 374                 }
 375                 */
 376                 clientcommand(self,s);
 377         }
 378 }
 379
 380 void ReadyRestart()
 381 {
 382         local entity e;
 383
 384         bprint("^1Server is restarting...\n");
 385
 386         VoteReset();
 387
 388         // no arena, assault support yet...
 389         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 390                 localcmd("restart\n");
 391
 392         // clear overtime
 393         if(checkrules_overtimeend)
 394                 checkrules_overtimeend = 0;
 395
 396         if(readyNagActive) { //if every player is ready, remove the ready-nagger again
 397                 readyNagActive = 0;
 398                 remove(readyNagger);
 399         }
 400
 401         if(g_tourney) {
 402                 tourneyInMatchStage = 1; //once the game is restarted the game is in match stage
 403                 //reset weapons and ammo, health and armor to default:
 404                 start_items = IT_LASER | IT_SHOTGUN;
 405                 start_switchweapon = WEP_SHOTGUN;
 406                 start_ammo_shells = cvar("g_start_ammo_shells");
 407                 start_ammo_nails = cvar("g_start_ammo_nails");
 408                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 409                 start_ammo_cells = cvar("g_start_ammo_cells");
 410                 start_health = cvar("g_balance_health_start");
 411                 start_armorvalue = cvar("g_balance_armor_start");
 412         }
 413         restart_countdown = time + RESTART_COUNTDOWN;
 414         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 415         //reset the .ready status of all players (also spectators)
 416         FOR_EACH_CLIENT(e)
 417         {
 418                 e.ready = 0;
 419         }
 420         if(0<cvar("timelimit") || (g_tourney && cvar("g_tourney_warmup_unlimited_time")) )
 421         {
 422                 // remember original timelimit on first restart
 423                 if(!timelimit_orig)
 424                         timelimit_orig = cvar("timelimit");
 425                 //only set the new timelimit if, when loading the map, a timelimit was really set
 426                 if(timelimit_orig)
 427                         cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
 428         }
 429
 430         if(cvar("teamplay_lockonrestart") && teams_matter) {
 431                 lockteams = 1;
 432                 bprint("^1The teams are now locked.\n");
 433         }
 434
 435         //initiate the restart-countdown-announcer entity
 436         restartAnnouncer = spawn();
 437         restartAnnouncer.think = restartAnnouncer_Think;
 438         restartAnnouncer.nextthink = time;
 439         restartAnnouncer.cnt = RESTART_COUNTDOWN;
 440
 441         //after a restart every players number of allowed timeouts gets reset, too
 442         if(cvar("sv_timeout"))
 443         {
 444                 FOR_EACH_REALPLAYER(e)
 445                 {
 446                         e.allowedTimeouts = cvar("sv_timeout_number");
 447                 }
 448         }
 449
 450         //play the prepareforbattle sound to everyone
 451         play2all("announcer/robotic/prepareforbattle.wav");
 452
 453         //reset map immediately if this cvar is not set
 454         if (!cvar("sv_ready_restart_after_countdown"))
 455                 reset_map();
 456
 457         if(cvar("sv_eventlog"))
 458                 GameLogEcho(":restart");
 459 }
 460
 461 /**
 462  * Counts how many players are ready. If not enough players are ready, the function
 463  * does nothing. If all players are ready, the timelimit will be extended and the
 464  * restart_countdown variable is set to allow other functions like PlayerPostThink
 465  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 466  * is not set the map will be resetted.
 467  *
 468  * Function is called after the server receives a 'ready' sign from a player.
 469  */
 470 void ReadyCount()
 471 {
 472         local entity e;
 473         local float r, p;
 474
 475         FOR_EACH_REALPLAYER(e)
 476         {
 477                 p += 1;
 478                 if(e.ready)
 479                         r += 1;
 480         }
 481
 482         if(!r)
 483                 return; // NOTE: this also excludes !p, as r <= p
 484
 485         if(cvar("sv_ready_restart_nag")) {
 486                 if(!readyNagActive) {
 487                         readyNagger = spawn();
 488                         readyNagger.think = readyNagger_Think;
 489                         readyNagger.cnt = cvar("sv_ready_restart_nag_duration");
 490                         readyNagger.nextthink = time;
 491                         readyNagActive = 1;
 492                 }
 493         }
 494
 495         if(r < p)
 496                 return;
 497
 498         ReadyRestart();
 499 }
 500
 501 /**
 502  * Centerprints the information to all players who didn't ready up yet to do so.
 503  */
 504 void readyNagger_Think() {
 505         local entity plr;
 506         if(self.cnt <= 0) { //have a break showing the ready nag
 507                 //make sure that the old ready-nag-centerprint isn't shown too long:
 508                 FOR_EACH_REALCLIENT(plr) {
 509                         if(plr.classname == "player") {
 510                                 if (!plr.ready)
 511                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 512                         }
 513                 }
 514                 self.cnt = cvar("sv_ready_restart_nag_duration");
 515                 self.nextthink = time + cvar("sv_ready_restart_nag_interval");
 516         }
 517         else {
 518                 //show the ready nagging to all players who aren't ready yet
 519                 FOR_EACH_REALCLIENT(plr) {
 520                         if(plr.classname == "player") {
 521                                 if (!plr.ready) {
 522                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "^2Please ready up (F4 by default)!");
 523                                         //play reminder sound once the centerprint appears for the first time after the pause:
 524                                         if (self.cnt == cvar("sv_ready_restart_nag_duration"))
 525                                                 play2(plr, "misc/talk2.wav");
 526                                 }
 527                         }
 528                 }
 529
 530                 self.nextthink = time + 1;
 531                 self.cnt -= 1;
 532         }
 533 }
 534
 535 /**
 536  * Shows the restart countdown for all players.
 537  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 538  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 539  * is set to 1).
 540  */
 541 void restartAnnouncer_Think() {
 542         local entity plr;
 543         local string s;
 544         if(self.cnt <= 0) { //show the "Begin" message and
 545                 if (cvar("sv_ready_restart_after_countdown")) {
 546                         restart_mapalreadyrestarted = 1;
 547                         reset_map();
 548                 }
 549
 550                 FOR_EACH_REALCLIENT(plr) {
 551                         if(plr.classname == "player") {
 552                                 s = strcat(NEWLINES, "^1Begin!");
 553                                 centerprint(plr, s);
 554                         }
 555                 }
 556                 play2all("announcer/robotic/begin.wav");
 557
 558                 remove(self);
 559                 return;
 560         }
 561         else {
 562                 FOR_EACH_REALCLIENT(plr) {
 563                         if(plr.classname == "player") {
 564                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(self.cnt), " seconds");
 565                                 centerprint(plr, s);
 566                         }
 567                 }
 568
 569                 if(self.cnt <= 3) {
 570                         play2all(strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 571                 }
 572                 self.nextthink = time + 1;
 573                 self.cnt -= 1;
 574         }
 575 }
 576
 577 /**
 578  * Checks whether the player who calls the timeout is allowed to do so.
 579  * If so, it initializes the timeout countdown. It also checks whether another
 580  * timeout was already running at this time and reacts correspondingly.
 581  *
 582  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 583  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 584  *
 585  * This function is called when a player issues the calltimeout command.
 586  */
 587 void evaluateTimeoutCall() {
 588         if (g_tourney && !tourneyInMatchStage && !cvar("g_tourney_warmup_allow_timeout"))
 589                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 590         if (time < restart_countdown )
 591                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 592         if (timeoutStatus != 2) {
 593                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 594                 if (cvar("timelimit")) {
 595                         //a timelimit was used
 596                         local float myTl;
 597                         if (cvar("timelimit"))
 598                                 myTl = cvar("timelimit");
 599                         else
 600                                 myTl = timelimit_orig;
 601
 602                         local float lastPossibleTimeout;
 603                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 604
 605                         if (lastPossibleTimeout < time)
 606                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 607                 }
 608         }
 609         //player may not call a timeout if he has no calls left
 610         if (self.allowedTimeouts < 1)
 611                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 612         //now all required checks are passed
 613         self.allowedTimeouts -= 1;
 614         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 615         remainingTimeoutTime = cvar("sv_timeout_length");
 616         remainingLeadTime = cvar("sv_timeout_leadtime");
 617         timeoutInitiator = self;
 618         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 619                 timeoutStatus = 1;
 620                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 621                 timeoutHandler = spawn();
 622                 timeoutHandler.think = timeoutHandler_Think;
 623         }
 624         timeoutHandler.nextthink = time; //always let the entity think asap
 625
 626         //inform all connected clients about the timeout call
 627         play2all("announcer/robotic/timeoutcalled.wav");
 628 }
 629
 630 /**
 631  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 632  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 633  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 634  * value of the cvar sv_timeout_resumetime.
 635  *
 636  * This function is called when a player issues the resumegame command.
 637  */
 638 void evaluateResumeGame() {
 639         if (!timeoutStatus)
 640                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 641         if (self != timeoutInitiator)
 642                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 643         if (timeoutStatus == 1) {
 644                 remainingTimeoutTime = timeoutStatus = 0;
 645                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 646                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 647         }
 648         else if (timeoutStatus == 2) {
 649                 //only shorten the remainingTimeoutTime if it makes sense
 650                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 651                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 652                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 653                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 654                 }
 655                 else
 656                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 657
 658         }
 659 }