data/qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 if(votecalled)
  33                         WriteString(MSG_ENTITY, votecalledvote_display);
  34                 else
  35                         WriteString(MSG_ENTITY, "");
  36         }
  37
  38         if(nags & 1)
  39         {
  40                 for(i = 1; i <= maxclients; i += 8)
  41                 {
  42                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  43                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  44                                         f |= b;
  45                         WriteByte(MSG_ENTITY, f);
  46                 }
  47         }
  48
  49         return TRUE;
  50 }
  51 void Nagger_Init()
  52 {
  53         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  54 }
  55 void Nagger_VoteChanged()
  56 {
  57         if(nagger)
  58                 nagger.SendFlags |= 128;
  59 }
  60 void Nagger_VoteCountChanged()
  61 {
  62         if(nagger)
  63                 nagger.SendFlags |= 1;
  64 }
  65 void Nagger_ReadyCounted()
  66 {
  67         if(nagger)
  68                 nagger.SendFlags |= 1;
  69 }
  70
  71 void ReadyCount();
  72 string MapVote_Suggest(string m);
  73
  74 entity GetPlayer(string name)
  75 {
  76         float num;
  77         entity e;
  78         string ns;
  79
  80         if(substring(name, 0, 1) == "#") {
  81                 num = stof(substring(name, 1, 999));
  82                 if(num >= 1 && num <= maxclients) {
  83                         for((e = world); num > 0; --num, (e = nextent(e)))
  84                                 ;
  85                         //if(clienttype(e) == CLIENTTYPE_REAL)
  86                         if(e.classname == "player")
  87                                 return e;
  88                 }
  89         } else {
  90                 ns = strdecolorize(name);
  91                 FOR_EACH_REALPLAYER(e) {
  92                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  93                                 return e;
  94                         }
  95                 }
  96         }
  97         return world;
  98 }
  99
 100 //float ctf_clientcommand();
 101 float readyrestart_happened;
 102 .float lms_spectate_warning;
 103 void SV_ParseClientCommand(string s) {
 104         local string cmd;
 105         local float tokens, f, effectnum;
 106         local vector start, end;
 107
 108         tokens = tokenize_sane(s);
 109
 110         if(GameCommand_Vote(s, self)) {
 111                 return;
 112         } else if(GameCommand_MapVote(argv(0))) {
 113                 return;
 114         } else if(argv(0) == "autoswitch") {
 115                 // be backwards compatible with older clients (enabled)
 116                 self.autoswitch = ("0" != argv(1));
 117                 local string autoswitchmsg;
 118                 if (self.autoswitch) {
 119                         autoswitchmsg = "on";
 120                 } else {
 121                         autoswitchmsg = "off";
 122                 }
 123                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 124         } else if(argv(0) == "clientversion") {
 125                 if not(self.flags & FL_CLIENT)
 126                         return;
 127                 if (argv(1) == "$gameversion") {
 128                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 129                         // either that or someone wants to be funny
 130                         self.version = 1;
 131                 } else {
 132                         self.version = stof(argv(1));
 133                 }
 134                 if(self.version != cvar("gameversion"))
 135                 {
 136                         self.classname = "observer";
 137                         self.version_mismatch = 1;
 138                         PutClientInServer();
 139                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 140                         //JoinBestTeam(self, FALSE, TRUE);
 141                 } else if(teams_matter && !cvar("sv_spectate")) {
 142                         self.classname = "observer";
 143                         stuffcmd(self,"menu_showteamselect\n");
 144                 }
 145         } else if(argv(0) == "reportcvar") { // old system
 146                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 147                 {
 148                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 149                         tokens = tokenize_sane(s);
 150                 }
 151                 GetCvars(1);
 152         } else if(argv(0) == "sentcvar") { // new system
 153                 if(tokens == 2) // undefined cvar: use the default value on the server then
 154                 {
 155                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 156                         tokens = tokenize_sane(s);
 157                 }
 158                 GetCvars(1);
 159         } else if(argv(0) == "spectate") {
 160                 if not(self.flags & FL_CLIENT)
 161                         return;
 162                 if(g_arena)
 163                         return;
 164                 if(g_lms)
 165                 {
 166                         if(self.lms_spectate_warning)
 167                         {
 168                                 // mark player as spectator
 169                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 170                         }
 171                         else
 172                         {
 173                                 self.lms_spectate_warning = 1;
 174                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 175                                 return;
 176                         }
 177                 }
 178                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 179                         if(self.flagcarried)
 180                                 DropFlag(self.flagcarried, world, world);
 181                         if(self.ballcarried)
 182                                 DropBall(self.ballcarried, self.origin, self.velocity);
 183                         kh_Key_DropAll(self, TRUE);
 184                         WaypointSprite_PlayerDead();
 185                         self.classname = "observer";
 186                         if(blockSpectators)
 187                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 188                         PutClientInServer();
 189                 }
 190         } else if(argv(0) == "join") {
 191                 if not(self.flags & FL_CLIENT)
 192                         return;
 193                 if(!g_arena)
 194                 if (self.classname != "player" && !lockteams)
 195                 {
 196                         if(isJoinAllowed()) {
 197                                 self.classname = "player";
 198                                 PlayerScore_Clear(self);
 199                                 bprint ("^4", self.netname, "^4 is playing now\n");
 200                                 PutClientInServer();
 201                         }
 202                         else {
 203                                 //player may not join because of g_maxplayers is set
 204                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 205                         }
 206                 }
 207         } else if( argv(0) == "selectteam" ) {
 208                 if not(self.flags & FL_CLIENT)
 209                         return;
 210                 if( !teams_matter ) {
 211                         sprint( self, "selecteam can only be used in teamgames\n");
 212                 } else if(cvar("g_campaign")) {
 213                         //JoinBestTeam(self, 0);
 214                 } else if(lockteams) {
 215                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 216                 } else if( argv(1) == "red" ) {
 217                         DoTeamChange(COLOR_TEAM1);
 218                 } else if( argv(1) == "blue" ) {
 219                         DoTeamChange(COLOR_TEAM2);
 220                 } else if( argv(1) == "yellow" ) {
 221                         DoTeamChange(COLOR_TEAM3);
 222                 } else if( argv(1) == "pink" ) {
 223                         DoTeamChange(COLOR_TEAM4);
 224                 } else if( argv(1) == "auto" ) {
 225                         DoTeamChange(-1);
 226                 } else {
 227                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 228                 }
 229         } else if(argv(0) == "ready") {
 230                 if not(self.flags & FL_CLIENT)
 231                         return;
 232
 233                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 234                    || cvar("sv_ready_restart"))
 235                 {
 236                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 237                         {
 238                                 if (self.ready) // toggle
 239                                 {
 240                                         self.ready = FALSE;
 241                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 242                                 }
 243                                 else
 244                                 {
 245                                         self.ready = TRUE;
 246                                         bprint(self.netname, "^2 is ready\n");
 247                                 }
 248
 249                                 // cannot reset the game while a timeout is active!
 250                                 if(!timeoutStatus)
 251                                         ReadyCount();
 252                         } else {
 253                                 sprint(self, "^1Game has already been restarted\n");
 254                         }
 255                 }
 256         } else if(argv(0) == "maplist") {
 257                 sprint(self, maplist_reply);
 258         } else if(argv(0) == "lsmaps") {
 259                 sprint(self, lsmaps_reply);
 260         } else if(argv(0) == "records") {
 261                 sprint(self, records_reply);
 262         } else if(argv(0) == "voice") {
 263                 if(tokens >= 3)
 264                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 265                 else
 266                         VoiceMessage(argv(1), "");
 267         } else if(argv(0) == "say") {
 268                 if(tokens >= 2)
 269                         Say(self, FALSE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 270                 //clientcommand(self, formatmessage(s));
 271         } else if(argv(0) == "say_team") {
 272                 if(tokens >= 2)
 273                         Say(self, TRUE, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 274                 //clientcommand(self, formatmessage(s));
 275         } else if(argv(0) == "info") {
 276                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 277                 if(cmd == "")
 278                         sprint(self, "ERROR: unsupported info command\n");
 279                 else
 280                         wordwrap_sprint(cmd, 1111);
 281         } else if(argv(0) == "suggestmap") {
 282                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 283         } else if(argv(0) == "timeout") {
 284                 if not(self.flags & FL_CLIENT)
 285                         return;
 286                 if(cvar("sv_timeout")) {
 287                         if(self.classname == "player") {
 288                                 if(votecalled)
 289                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 290                                 else
 291                                         evaluateTimeout();
 292                         }
 293                         else
 294                                 sprint(self, "^7Error: only players can call a timeout!\n");
 295                 }
 296         } else if(argv(0) == "timein") {
 297                 if not(self.flags & FL_CLIENT)
 298                         return;
 299                 if(cvar("sv_timeout")) {
 300                         evaluateTimein();
 301                 }
 302         } else if(argv(0) == "teamstatus") {
 303                 Score_NicePrint(self);
 304         } else if(argv(0) == "cvar_changes") {
 305                 sprint(self, cvar_changes);
 306         } else if(argv(0) == "pointparticles") {
 307                 if(sv_cheats && tokens == 5)
 308                 {
 309                         // arguments:
 310                         //   effectname
 311                         //   origin (0..1, on crosshair line)
 312                         //   velocity
 313                         //   howmany
 314                         effectnum = particleeffectnum(argv(1));
 315                         f = stof(argv(2));
 316                         start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 317                         end = stov(argv(3));
 318                         f = stof(argv(4));
 319                         pointparticles(effectnum, start, end, f);
 320                 }
 321                 else
 322                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 323         } else if(argv(0) == "trailparticles") {
 324                 if(sv_cheats && tokens == 2)
 325                 {
 326                         // arguments:
 327                         //   effectname
 328                         effectnum = particleeffectnum(argv(1));
 329                         W_SetupShot(self,  FALSE, FALSE, "");
 330                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 331                         trailparticles(self, effectnum, w_shotorg, trace_endpos);
 332                 }
 333                 else
 334                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 335         } else {
 336                 //if(ctf_clientcommand())
 337                 //      return;
 338                 cmd = argv(0);
 339                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 340                 if(cmd != "status")
 341                 if(cmd != "max")
 342                 if(cmd != "monster")
 343                 if(cmd != "scrag")
 344                 if(cmd != "wraith")
 345                 if(cmd != "gimme")
 346                 if(cmd != "god")
 347                 if(cmd != "notarget")
 348                 if(cmd != "fly")
 349                 if(cmd != "noclip")
 350                 if(cmd != "give")
 351                 //if(cmd != "say") // handled above
 352                 //if(cmd != "say_team") // handled above
 353                 if(cmd != "tell")
 354                 if(cmd != "kill")
 355                 if(cmd != "pause")
 356                 if(cmd != "ping")
 357                 if(cmd != "name")
 358                 if(cmd != "color")
 359                 if(cmd != "rate")
 360                 if(cmd != "pmodel")
 361                 if(cmd != "playermodel")
 362                 if(cmd != "playerskin")
 363                 if(cmd != "prespawn")
 364                 if(cmd != "spawn")
 365                 if(cmd != "begin")
 366                 if(cmd != "pings")
 367                 if(cmd != "sv_startdownload")
 368                 if(cmd != "download")
 369                 {
 370                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 371                         return;
 372                 }
 373                 clientcommand(self,s);
 374         }
 375 }
 376
 377 void ReadyRestartForce()
 378 {
 379         local entity e;
 380
 381         bprint("^1Server is restarting...\n");
 382
 383         VoteReset();
 384
 385         // clear overtime
 386         if (checkrules_overtimesadded > 0) {
 387                 //we have to decrease timelimit to its original value again!!
 388                 float newTL;
 389                 newTL = cvar("timelimit");
 390                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 391                 cvar_set("timelimit", ftos(newTL));
 392         }
 393
 394         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 395
 396
 397         readyrestart_happened = 1;
 398         game_starttime = time + RESTART_COUNTDOWN;
 399         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 400
 401         inWarmupStage = 0; //once the game is restarted the game is in match stage
 402
 403         //reset the .ready status of all players (also spectators)
 404         FOR_EACH_CLIENTSLOT(e)
 405                 e.ready = 0;
 406         readycount = 0;
 407         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 408
 409         if(cvar("teamplay_lockonrestart") && teams_matter) {
 410                 lockteams = 1;
 411                 bprint("^1The teams are now locked.\n");
 412         }
 413
 414         //initiate the restart-countdown-announcer entity
 415         if(cvar("sv_ready_restart_after_countdown"))
 416         {
 417                 restartTimer = spawn();
 418                 restartTimer.think = restartTimer_Think;
 419                 restartTimer.nextthink = game_starttime;
 420         }
 421
 422         //after a restart every players number of allowed timeouts gets reset, too
 423         if(cvar("sv_timeout"))
 424         {
 425                 FOR_EACH_REALPLAYER(e)
 426                         e.allowedTimeouts = cvar("sv_timeout_number");
 427         }
 428
 429         //reset map immediately if this cvar is not set
 430         if (!cvar("sv_ready_restart_after_countdown"))
 431                 reset_map(TRUE);
 432
 433         if(cvar("sv_eventlog"))
 434                 GameLogEcho(":restart");
 435 }
 436
 437 void ReadyRestart()
 438 {
 439         // no arena, assault support yet...
 440         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 441                 localcmd("restart\n");
 442
 443         // reset ALL scores, but only do that at the beginning
 444         //of the countdown if sv_ready_restart_after_countdown is off!
 445         //Otherwise scores could be manipulated during the countdown!
 446         if (!cvar("sv_ready_restart_after_countdown"))
 447                 Score_ClearAll();
 448
 449         ReadyRestartForce();
 450 }
 451
 452 /**
 453  * Counts how many players are ready. If not enough players are ready, the function
 454  * does nothing. If all players are ready, the timelimit will be extended and the
 455  * restart_countdown variable is set to allow other functions like PlayerPostThink
 456  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 457  * is not set the map will be resetted.
 458  *
 459  * Function is called after the server receives a 'ready' sign from a player.
 460  */
 461 void ReadyCount()
 462 {
 463         local entity e;
 464         local float r, p;
 465
 466         r = p = 0;
 467
 468         FOR_EACH_REALPLAYER(e)
 469         {
 470                 p += 1;
 471                 if(e.ready)
 472                         r += 1;
 473         }
 474
 475         readycount = r;
 476
 477         Nagger_ReadyCounted();
 478
 479         if(r) // at least one is ready
 480         if(r == p) // and, everyone is ready
 481                 ReadyRestart();
 482 }
 483
 484 /**
 485  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 486  * is set)
 487  */
 488 void restartTimer_Think() {
 489         restart_mapalreadyrestarted = 1;
 490         Score_ClearAll();
 491         reset_map(TRUE);
 492         remove(self);
 493         return;
 494 }
 495
 496 /**
 497  * Checks whether the player who calls the timeout is allowed to do so.
 498  * If so, it initializes the timeout countdown. It also checks whether another
 499  * timeout was already running at this time and reacts correspondingly.
 500  *
 501  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 502  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 503  *
 504  * This function is called when a player issues the calltimeout command.
 505  */
 506 void evaluateTimeout() {
 507         if (inWarmupStage && !g_warmup_allow_timeout)
 508                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 509         if (time < game_starttime )
 510                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 511         if (timeoutStatus != 2) {
 512                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 513                 if (cvar("timelimit")) {
 514                         //a timelimit was used
 515                         local float myTl;
 516                         myTl = cvar("timelimit");
 517
 518                         local float lastPossibleTimeout;
 519                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 520
 521                         if (lastPossibleTimeout < time - game_starttime)
 522                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 523                 }
 524         }
 525         //player may not call a timeout if he has no calls left
 526         if (self.allowedTimeouts < 1)
 527                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 528         //now all required checks are passed
 529         self.allowedTimeouts -= 1;
 530         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 531         remainingTimeoutTime = cvar("sv_timeout_length");
 532         remainingLeadTime = cvar("sv_timeout_leadtime");
 533         timeoutInitiator = self;
 534         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 535                 timeoutStatus = 1;
 536                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 537                 timeoutHandler = spawn();
 538                 timeoutHandler.think = timeoutHandler_Think;
 539         }
 540         timeoutHandler.nextthink = time; //always let the entity think asap
 541
 542         //inform all connected clients about the timeout call
 543         play2all("announcer/robotic/timeoutcalled.wav");
 544 }
 545
 546 /**
 547  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 548  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 549  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 550  * value of the cvar sv_timeout_resumetime.
 551  *
 552  * This function is called when a player issues the resumegame command.
 553  */
 554 void evaluateTimein() {
 555         if (!timeoutStatus)
 556                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 557         if (self != timeoutInitiator)
 558                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 559         if (timeoutStatus == 1) {
 560                 remainingTimeoutTime = timeoutStatus = 0;
 561                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 562                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 563         }
 564         else if (timeoutStatus == 2) {
 565                 //only shorten the remainingTimeoutTime if it makes sense
 566                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 567                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 568                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 569                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 570                 }
 571                 else
 572                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 573
 574         }
 575 }