data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 void(entity e) DropFlag;
   3 string MapVote_Suggest(string m);
   4
   5 .float floodcontrol_chat;
   6 .float floodcontrol_team;
   7 void Say(entity source, float teamsay, string msgin)
   8 {
   9         string msgstr, colorstr, cmsgstr, namestr;
  10         float flood;
  11         entity head;
  12
  13         if(!teamsay)
  14                 if(substring(msgin, 0, 1) == " ")
  15                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  16
  17         msgin = formatmessage(msgin);
  18
  19         if(msgin == "")
  20                 return;
  21
  22         if(source.classname != "player")
  23                 colorstr = "^0"; // black for spectators
  24         else if(teams_matter)
  25                 colorstr = Team_ColorCode(source.team);
  26         else
  27                 teamsay = FALSE;
  28
  29         if(intermission_running)
  30                 teamsay = FALSE;
  31
  32         /*
  33          * using bprint solves this... me stupid
  34         // how can we prevent the message from appearing in a listen server?
  35         // for now, just give "say" back and only handle say_team
  36         if(!teamsay)
  37         {
  38                 clientcommand(self, strcat("say ", msgin));
  39                 return;
  40         }
  41         */
  42
  43         if(cvar("g_chat_teamcolors"))
  44                 namestr = playername(source);
  45         else
  46                 namestr = source.netname;
  47         if(teamsay)
  48         {
  49                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  50                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  51         }
  52         else
  53                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  54
  55         // FLOOD CONTROL
  56         flood = 0;
  57         {
  58                 float flood_spl;
  59                 float flood_burst;
  60                 float flood_lmax;
  61                 var .float flood_field;
  62                 float lines;
  63                 if(teamsay)
  64                 {
  65                         flood_spl = cvar("g_chat_flood_spl_team");
  66                         flood_burst = cvar("g_chat_flood_burst_team");
  67                         flood_lmax = cvar("g_chat_flood_lmax_team");
  68                         flood_field = floodcontrol_team;
  69                 }
  70                 else
  71                 {
  72                         flood_spl = cvar("g_chat_flood_spl");
  73                         flood_burst = cvar("g_chat_flood_burst");
  74                         flood_lmax = cvar("g_chat_flood_lmax");
  75                         flood_field = floodcontrol_chat;
  76                 }
  77                 flood_burst = max(0, flood_burst - 1);
  78                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  79                 lines = ceil(strlennocol(msgstr) / 75);
  80                 if(flood_lmax && lines > flood_lmax)
  81                         flood = 2;
  82                 else if(time >= self.flood_field)
  83                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  84                 else
  85                         flood = 1;
  86         }
  87
  88         if(flood)
  89         {
  90                 if(cvar("g_chat_flood_notify_flooder"))
  91                 {
  92                         if(flood == 1)
  93                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  94                         else if(flood == 2)
  95                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  96                 }
  97                 else
  98                         sprint(self, msgstr);
  99                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
 100         }
 101         else if(teamsay)
 102         {
 103                 if(source.classname == "player")
 104                 {
 105                         FOR_EACH_REALPLAYER(head)
 106                         {
 107                                 if(head.team == source.team)
 108                                 {
 109                                         sprint(head, msgstr);
 110                                         centerprint(head, cmsgstr);
 111                                 }
 112                         }
 113                 }
 114                 else
 115                 {
 116                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 117                         {
 118                                 sprint(head, msgstr);
 119                                 centerprint(head, cmsgstr);
 120                         }
 121                 }
 122         }
 123         else
 124         {
 125                 //when g_tourney is active and g_tourney_disable_spec_chat is set and game is in matchstage
 126                 //don't print the text from specs/observers to the players but only the other spectators
 127                 if(g_tourney && cvar("g_tourney_disable_spec_chat") && tourneyInMatchStage && source.classname != "player") {
 128                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 129                                 sprint(head, msgstr);
 130                         }
 131                 }
 132                 else
 133                         bprint(msgstr);
 134                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
 135         }
 136
 137         strunzone(msgstr);
 138 }
 139
 140 entity GetPlayer(string name)
 141 {
 142         float num;
 143         entity e;
 144         string ns;
 145
 146         if(substring(name, 0, 1) == "#") {
 147                 num = stof(substring(name, 1, 999));
 148                 if(num >= 1 && num <= maxclients) {
 149                         for((e = world); num > 0; --num, (e = nextent(e)))
 150                                 ;
 151                         //if(clienttype(e) == CLIENTTYPE_REAL)
 152                         if(e.classname == "player")
 153                                 return e;
 154                 }
 155         } else {
 156                 ns = strdecolorize(name);
 157                 FOR_EACH_REALPLAYER(e) {
 158                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 159                                 return e;
 160                         }
 161                 }
 162         }
 163         return world;
 164 }
 165
 166 //float ctf_clientcommand();
 167 void SV_ParseClientCommand(string s) {
 168         local string cmd;
 169         local float i;
 170
 171         tokenize(s);
 172
 173         if(GameCommand_Vote(s, self)) {
 174                 return;
 175         } else if(GameCommand_MapVote(argv(0))) {
 176                 return;
 177         } else if(argv(0) == "autoswitch") {
 178                 // be backwards compatible with older clients (enabled)
 179                 self.autoswitch = ("0" != argv(1));
 180                 local string autoswitchmsg;
 181                 if (self.autoswitch) {
 182                         autoswitchmsg = "on";
 183                 } else {
 184                         autoswitchmsg = "off";
 185                 }
 186                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 187         } else if(argv(0) == "clientversion") {
 188                 if not(self.flags & FL_CLIENT)
 189                         return;
 190                 if (argv(1) == "$gameversion") {
 191                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 192                         // either that or someone wants to be funny
 193                         self.version = 1;
 194                 } else {
 195                         self.version = stof(argv(1));
 196                 }
 197                 if(self.version != cvar("gameversion"))
 198                 {
 199                         self.classname = "observer";
 200                         self.version_mismatch = 1;
 201                         PutClientInServer();
 202                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 203                         //JoinBestTeam(self, FALSE, TRUE);
 204                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 205                         self.classname = "observer";
 206                         stuffcmd(self,"menu_showteamselect\n");
 207                 }
 208         } else if(argv(0) == "reportcvar") { // old system
 209                 GetCvars(1);
 210         } else if(argv(0) == "sentcvar") { // new system
 211                 GetCvars(1);
 212         } else if(argv(0) == "spectate") {
 213                 if not(self.flags & FL_CLIENT)
 214                         return;
 215                 if(g_lms || g_arena)
 216                         return; // don't allow spectating in lms, unless player runs out of lives
 217                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 218                         if(self.flagcarried)
 219                                 DropFlag(self.flagcarried);
 220                         kh_Key_DropAll(self, TRUE);
 221                         WaypointSprite_PlayerDead();
 222                         self.classname = "observer";
 223                         if(blockSpectators)
 224                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 225                         PutClientInServer();
 226                 }
 227         } else if(argv(0) == "join") {
 228                 if not(self.flags & FL_CLIENT)
 229                         return;
 230                 if(!g_arena)
 231                 if (self.classname != "player" && !lockteams)
 232                 {
 233                         if(isJoinAllowed()) {
 234                                 self.classname = "player";
 235                                 PlayerScore_Clear(self);
 236                                 bprint ("^4", self.netname, "^4 is playing now\n");
 237                                 PutClientInServer();
 238                         }
 239                         else {
 240                                 //player may not join because of g_maxplayers is set
 241                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 242                         }
 243                 }
 244         } else if( argv(0) == "selectteam" ) {
 245                 if not(self.flags & FL_CLIENT)
 246                         return;
 247                 if( !cvar("teamplay") ) {
 248                         sprint( self, "selecteam can only be used in teamgames\n");
 249                 } else if(cvar("g_campaign")) {
 250                         //JoinBestTeam(self, 0);
 251                 } else if(lockteams) {
 252                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 253                 } else if( argv(1) == "red" ) {
 254                         DoTeamChange(COLOR_TEAM1);
 255                 } else if( argv(1) == "blue" ) {
 256                         DoTeamChange(COLOR_TEAM2);
 257                 } else if( argv(1) == "yellow" ) {
 258                         DoTeamChange(COLOR_TEAM3);
 259                 } else if( argv(1) == "pink" ) {
 260                         DoTeamChange(COLOR_TEAM4);
 261                 } else if( argv(1) == "auto" ) {
 262                         DoTeamChange(-1);
 263                 } else {
 264                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 265                 }
 266         } else if(argv(0) == "ready") {
 267                 if not(self.flags & FL_CLIENT)
 268                         return;
 269                 if(cvar("sv_ready_restart"))
 270                 {
 271                         if(timeoutStatus) {
 272                                 return sprint(self, "^1You cannot reset the game while a timeout is active!\n");
 273                         }
 274
 275                         if(!restart_countdown || cvar("sv_ready_restart_repeatable"))
 276                         {
 277                                 self.ready = TRUE;
 278                                 bprint(self.netname, "^2 is ready\n");
 279                                 ReadyCount();
 280                         } else {
 281                                 sprint(self, "^1game has already been restarted\n");
 282                         }
 283                 }
 284         } else if(argv(0) == "maplist") {
 285                 local float n, j;
 286                 local string col;
 287                 n = tokenize(cvar_string("g_maplist"));
 288                 sprint(self, "^7Maps in list: ");
 289                 for(i = 0, j = 0; i < n; ++i)
 290                 {
 291                         if(MapInfo_CheckMap(argv(i)))
 292                         {
 293                                 if(mod(j, 2))
 294                                         col = "^2";
 295                                 else
 296                                         col = "^3";
 297                                 sprint(self, strcat(col, argv(i), " "));
 298                                 ++j;
 299                         }
 300                 }
 301                 sprint(self, "\n");
 302 #ifdef MAPINFO
 303         } else if(argv(0) == "lsmaps") {
 304                 sprint(self, "^7Maps available: ");
 305                 for(i = 0; i < MapInfo_count; ++i)
 306                 {
 307                         if(mod(i, 2))
 308                                 col = "^2";
 309                         else
 310                                 col = "^3";
 311                         sprint(self, strcat(col, MapInfo_BSPName_ByID(i), " "));
 312                 }
 313                 sprint(self, "\n");
 314 #endif
 315         } else if(argv(0) == "voice") {
 316                 VoiceMessage(argv(1));
 317         } else if(argv(0) == "say") {
 318                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 319                 //clientcommand(self, formatmessage(s));
 320         } else if(argv(0) == "say_team") {
 321                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 322                 //clientcommand(self, formatmessage(s));
 323         } else if(argv(0) == "info") {
 324                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 325                 if(cmd == "")
 326                         sprint(self, "ERROR: unsupported info command\n");
 327                 else
 328                         wordwrap_sprint(cmd, 1111);
 329         } else if(argv(0) == "suggestmap") {
 330                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 331         } else if(argv(0) == "calltimeout") {
 332                 if not(self.flags & FL_CLIENT)
 333                         return;
 334                 if(cvar("sv_timeout")) {
 335                         if(self.classname == "player") {
 336                                 if(votecalled)
 337                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 338                                 else
 339                                         evaluateTimeoutCall();
 340                         }
 341                         else
 342                                 sprint(self, "^7Error: only players can call a timeout!\n");
 343                 }
 344         } else if(argv(0) == "resumegame") {
 345                 if not(self.flags & FL_CLIENT)
 346                         return;
 347                 if(cvar("sv_timeout")) {
 348                         evaluateResumeGame();
 349                 }
 350         } else if(argv(0) == "teamstatus") {
 351                 Score_NicePrint(self);
 352         } else {
 353                 //if(ctf_clientcommand())
 354                 //      return;
 355                 cmd = argv(0);
 356                 /* checks not needed any more since DP has separated clientcommands and regular commands
 357                 if(cmd != "status")
 358                 if(cmd != "name")
 359                 //if(cmd != "say") // handled above
 360                 //if(cmd != "say_team") // handled above
 361                 if(cmd != "tell")
 362                 if(cmd != "color")
 363                 if(cmd != "kill")
 364                 if(cmd != "pause")
 365                 if(cmd != "kick")
 366                 if(cmd != "ping")
 367                 if(cmd != "pings")
 368                 if(cmd != "ban")
 369                 if(cmd != "pmodel")
 370                 if(cmd != "rate")
 371                 if(cmd != "playermodel")
 372                 if(cmd != "playerskin")
 373                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 374                 {
 375                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 376                         return;
 377                 }
 378                 */
 379                 clientcommand(self,s);
 380         }
 381 }
 382
 383 void ReadyRestart()
 384 {
 385         local entity e;
 386
 387         bprint("^1Server is restarting...\n");
 388
 389         VoteReset();
 390
 391         // no arena, assault support yet...
 392         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 393                 localcmd("restart\n");
 394
 395         if(readyNagActive) { //if every player is ready, remove the ready-nagger again
 396                 readyNagActive = 0;
 397                 remove(readyNagger);
 398         }
 399
 400         if(g_tourney) {
 401                 tourneyInMatchStage = 1; //once the game is restarted the game is in match stage
 402                 //reset weapons and ammo, health and armor to default:
 403                 start_items = IT_LASER | IT_SHOTGUN;
 404                 start_switchweapon = WEP_SHOTGUN;
 405                 start_ammo_shells = cvar("g_start_ammo_shells");
 406                 start_ammo_nails = cvar("g_start_ammo_nails");
 407                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 408                 start_ammo_cells = cvar("g_start_ammo_cells");
 409                 start_health = cvar("g_balance_health_start");
 410                 start_armorvalue = cvar("g_balance_armor_start");
 411         }
 412         restart_countdown = time + RESTART_COUNTDOWN;
 413         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 414         //reset the .ready status of all players (also spectators)
 415         FOR_EACH_CLIENT(e)
 416         {
 417                 e.ready = 0;
 418         }
 419         if(0<cvar("timelimit") || (g_tourney && cvar("g_tourney_warmup_unlimited_time")) )
 420         {
 421                 // remember original timelimit on first restart
 422                 if(!timelimit_orig)
 423                         timelimit_orig = cvar("timelimit");
 424                 //only set the new timelimit if, when loading the map, a timelimit was really set
 425                 if(timelimit_orig)
 426                         cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
 427         }
 428
 429         if(cvar("teamplay_lockonrestart") && teams_matter) {
 430                 lockteams = 1;
 431                 bprint("^1The teams are now locked.\n");
 432         }
 433
 434         //initiate the restart-countdown-announcer entity
 435         restartAnnouncer = spawn();
 436         restartAnnouncer.think = restartAnnouncer_Think;
 437         restartAnnouncer.nextthink = time;
 438         restartAnnouncer.cnt = RESTART_COUNTDOWN;
 439
 440         //after a restart every players number of allowed timeouts gets reset, too
 441         if(cvar("sv_timeout"))
 442         {
 443                 FOR_EACH_REALPLAYER(e)
 444                 {
 445                         e.allowedTimeouts = cvar("sv_timeout_number");
 446                 }
 447         }
 448
 449         //play the prepareforbattle sound to everyone
 450         play2all("announcer/robotic/prepareforbattle.wav");
 451
 452         //reset map immediately if this cvar is not set
 453         if (!cvar("sv_ready_restart_after_countdown"))
 454                 reset_map();
 455
 456         if(cvar("sv_eventlog"))
 457                 GameLogEcho(":restart", FALSE);
 458 }
 459
 460 /**
 461  * Counts how many players are ready. If not enough players are ready, the function
 462  * does nothing. If all players are ready, the timelimit will be extended and the
 463  * restart_countdown variable is set to allow other functions like PlayerPostThink
 464  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 465  * is not set the map will be resetted.
 466  *
 467  * Function is called after the server receives a 'ready' sign from a player.
 468  */
 469 void ReadyCount()
 470 {
 471         local entity e;
 472         local float r, p;
 473
 474         FOR_EACH_REALPLAYER(e)
 475         {
 476                 p += 1;
 477                 if(e.ready)
 478                         r += 1;
 479         }
 480
 481         if(!r)
 482                 return; // NOTE: this also excludes !p, as r <= p
 483
 484         if(cvar("sv_ready_restart_nag")) {
 485                 if(!readyNagActive) {
 486                         readyNagger = spawn();
 487                         readyNagger.think = readyNagger_Think;
 488                         readyNagger.cnt = cvar("sv_ready_restart_nag_duration");
 489                         readyNagger.nextthink = time;
 490                         readyNagActive = 1;
 491                 }
 492         }
 493
 494         if(r < p)
 495                 return;
 496
 497         ReadyRestart();
 498 }
 499
 500 /**
 501  * Centerprints the information to all players who didn't ready up yet to do so.
 502  */
 503 void readyNagger_Think() {
 504         local entity plr;
 505         if(self.cnt <= 0) { //have a break showing the ready nag
 506                 //make sure that the old ready-nag-centerprint isn't shown too long:
 507                 FOR_EACH_REALCLIENT(plr) {
 508                         if(plr.classname == "player") {
 509                                 if (!plr.ready)
 510                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 511                         }
 512                 }
 513                 self.cnt = cvar("sv_ready_restart_nag_duration");
 514                 self.nextthink = time + cvar("sv_ready_restart_nag_interval");
 515         }
 516         else {
 517                 //show the ready nagging to all players who aren't ready yet
 518                 FOR_EACH_REALCLIENT(plr) {
 519                         if(plr.classname == "player") {
 520                                 if (!plr.ready) {
 521                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "^2Please ready up (F4 by default)!");
 522                                         //play reminder sound once the centerprint appears for the first time after the pause:
 523                                         if (self.cnt == cvar("sv_ready_restart_nag_duration"))
 524                                                 play2(plr, "misc/talk2.wav");
 525                                 }
 526                         }
 527                 }
 528
 529                 self.nextthink = time + 1;
 530                 self.cnt -= 1;
 531         }
 532 }
 533
 534 /**
 535  * Shows the restart countdown for all players.
 536  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 537  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 538  * is set to 1).
 539  */
 540 void restartAnnouncer_Think() {
 541         local entity plr;
 542         local string s;
 543         if(self.cnt <= 0) { //show the "Begin" message and
 544                 if (cvar("sv_ready_restart_after_countdown")) {
 545                         restart_mapalreadyrestarted = 1;
 546                         reset_map();
 547                 }
 548
 549                 FOR_EACH_REALCLIENT(plr) {
 550                         if(plr.classname == "player") {
 551                                 s = strcat(NEWLINES, "^1Begin!");
 552                                 centerprint(plr, s);
 553                         }
 554                 }
 555                 play2all("announcer/robotic/begin.wav");
 556
 557                 remove(self);
 558                 return;
 559         }
 560         else {
 561                 FOR_EACH_REALCLIENT(plr) {
 562                         if(plr.classname == "player") {
 563                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(self.cnt), " seconds");
 564                                 centerprint(plr, s);
 565                         }
 566                 }
 567
 568                 if(self.cnt <= 3) {
 569                         play2all(strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 570                 }
 571                 self.nextthink = time + 1;
 572                 self.cnt -= 1;
 573         }
 574 }
 575
 576 /**
 577  * Checks whether the player who calls the timeout is allowed to do so.
 578  * If so, it initializes the timeout countdown. It also checks whether another
 579  * timeout was already running at this time and reacts correspondingly.
 580  *
 581  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 582  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 583  *
 584  * This function is called when a player issues the calltimeout command.
 585  */
 586 void evaluateTimeoutCall() {
 587         if (g_tourney && !tourneyInMatchStage && !cvar("g_tourney_warmup_allow_timeout"))
 588                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 589         if (time < restart_countdown )
 590                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 591         if (timeoutStatus != 2) {
 592                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 593                 if (cvar("timelimit")) {
 594                         //a timelimit was used
 595                         local float myTl;
 596                         if (cvar("timelimit"))
 597                                 myTl = cvar("timelimit");
 598                         else
 599                                 myTl = timelimit_orig;
 600
 601                         local float lastPossibleTimeout;
 602                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 603
 604                         if (lastPossibleTimeout < time)
 605                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 606                 }
 607         }
 608         //player may not call a timeout if he has no calls left
 609         if (self.allowedTimeouts < 1)
 610                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 611         //now all required checks are passed
 612         self.allowedTimeouts -= 1;
 613         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 614         remainingTimeoutTime = cvar("sv_timeout_length");
 615         remainingLeadTime = cvar("sv_timeout_leadtime");
 616         timeoutInitiator = self;
 617         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 618                 timeoutStatus = 1;
 619                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 620                 timeoutHandler = spawn();
 621                 timeoutHandler.think = timeoutHandler_Think;
 622         }
 623         timeoutHandler.nextthink = time; //always let the entity think asap
 624
 625         //inform all connected clients about the timeout call
 626         play2all("announcer/robotic/timeoutcalled.wav");
 627 }
 628
 629 /**
 630  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 631  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 632  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 633  * value of the cvar sv_timeout_resumetime.
 634  *
 635  * This function is called when a player issues the resumegame command.
 636  */
 637 void evaluateResumeGame() {
 638         if (!timeoutStatus)
 639                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 640         if (self != timeoutInitiator)
 641                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 642         if (timeoutStatus == 1) {
 643                 remainingTimeoutTime = timeoutStatus = 0;
 644                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 645                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 646         }
 647         else if (timeoutStatus == 2) {
 648                 //only shorten the remainingTimeoutTime if it makes sense
 649                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 650                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 651                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 652                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 653                 }
 654                 else
 655                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 656
 657         }
 658 }