data/qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 if(votecalled)
  33                         WriteString(MSG_ENTITY, votecalledvote_display);
  34                 else
  35                         WriteString(MSG_ENTITY, "");
  36         }
  37
  38         if(nags & 1)
  39         {
  40                 for(i = 1; i <= maxclients; i += 8)
  41                 {
  42                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  43                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  44                                         f |= b;
  45                         WriteByte(MSG_ENTITY, f);
  46                 }
  47         }
  48
  49         return TRUE;
  50 }
  51 void Nagger_Init()
  52 {
  53         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  54 }
  55 void Nagger_VoteChanged()
  56 {
  57         if(nagger)
  58                 nagger.SendFlags |= 128;
  59 }
  60 void Nagger_VoteCountChanged()
  61 {
  62         if(nagger)
  63                 nagger.SendFlags |= 1;
  64 }
  65 void Nagger_ReadyCounted()
  66 {
  67         if(nagger)
  68                 nagger.SendFlags |= 1;
  69 }
  70
  71 void ReadyCount();
  72 string MapVote_Suggest(string m);
  73
  74 entity GetPlayer(string name)
  75 {
  76         float num;
  77         entity e;
  78         string ns;
  79
  80         if(substring(name, 0, 1) == "#") {
  81                 num = stof(substring(name, 1, 999));
  82                 if(num >= 1 && num <= maxclients) {
  83                         for((e = world); num > 0; --num, (e = nextent(e)))
  84                                 ;
  85                         //if(clienttype(e) == CLIENTTYPE_REAL)
  86                         if(e.classname == "player")
  87                                 return e;
  88                 }
  89         } else {
  90                 ns = strdecolorize(name);
  91                 FOR_EACH_REALPLAYER(e) {
  92                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  93                                 return e;
  94                         }
  95                 }
  96         }
  97         return world;
  98 }
  99
 100 float drag_lastcnt;
 101 void DragBox_Think()
 102 {
 103         if(self.aiment && self.enemy)
 104         {
 105                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
 106                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
 107                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
 108                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
 109                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
 110                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
 111                 self.mins = -1 * self.maxs;
 112                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
 113         }
 114
 115         if(self.cnt == -1) // actually race_place -1
 116         {
 117                 // show "10 10" for qualifying spawns
 118                 setmodel(self.killindicator, "models/sprites/10.spr32");
 119                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
 120         }
 121         else if(self.cnt == -2) // actually race_place 0
 122         {
 123                 // show "10 0" for loser spawns
 124                 setmodel(self.killindicator, "models/sprites/10.spr32");
 125                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
 126         }
 127         else
 128         {
 129                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
 130                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
 131         }
 132
 133         self.nextthink = time;
 134 }
 135
 136 //float ctf_clientcommand();
 137 float readyrestart_happened;
 138 .float lms_spectate_warning;
 139 void spawnfunc_func_breakable();
 140
 141 .float cmd_floodtime;
 142 .float cmd_floodcount;
 143 float cmd_floodcheck()
 144 {
 145         if (timeoutStatus != 2)
 146         {
 147                 if(time == self.cmd_floodtime)
 148                 {
 149                         self.cmd_floodcount += 1;
 150                         if(self.cmd_floodcount > 8)
 151                                 return TRUE;
 152                 }
 153                 else
 154                 {
 155                         self.cmd_floodtime = time;
 156                         self.cmd_floodcount = 1;
 157                 }
 158         }
 159         return FALSE;
 160 }
 161
 162 void SV_ParseClientCommand(string s) {
 163         string cmd;
 164         float tokens, f, effectnum;
 165         vector start, end;
 166         entity e, oldself;
 167
 168         tokens = tokenize_console(s);
 169
 170         cmd = argv(0);
 171         if(cmd != "reportcvar")
 172         if(cmd != "sentcvar")
 173         if(cmd != "pause")
 174         if(cmd != "prespawn")
 175         if(cmd != "spawn")
 176         if(cmd != "begin")
 177         {
 178                 if(cmd_floodcheck())
 179                         return;
 180         }
 181
 182         if(GameCommand_Vote(s, self)) {
 183                 return;
 184         } else if(GameCommand_MapVote(argv(0))) {
 185                 return;
 186         } else if(cmd == "autoswitch") {
 187                 // be backwards compatible with older clients (enabled)
 188                 self.autoswitch = ("0" != argv(1));
 189                 local string autoswitchmsg;
 190                 if (self.autoswitch) {
 191                         autoswitchmsg = "on";
 192                 } else {
 193                         autoswitchmsg = "off";
 194                 }
 195                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 196         } else if(cmd == "clientversion") {
 197                 if not(self.flags & FL_CLIENT)
 198                         return;
 199                 if (argv(1) == "$gameversion") {
 200                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 201                         // either that or someone wants to be funny
 202                         self.version = 1;
 203                 } else {
 204                         self.version = stof(argv(1));
 205                 }
 206                 if(self.version != cvar("gameversion"))
 207                 {
 208                         self.classname = "observer";
 209                         self.version_mismatch = 1;
 210                         PutClientInServer();
 211                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 212                         //JoinBestTeam(self, FALSE, TRUE);
 213                 } else if(teams_matter && !cvar("sv_spectate")) {
 214                         self.classname = "observer";
 215                         stuffcmd(self,"menu_showteamselect\n");
 216                 }
 217         } else if(cmd == "reportcvar") { // old system
 218                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 219                 {
 220                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 221                         tokens = tokenize_console(s);
 222                 }
 223                 GetCvars(1);
 224         } else if(cmd == "sentcvar") { // new system
 225                 if(tokens == 2) // undefined cvar: use the default value on the server then
 226                 {
 227                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 228                         tokens = tokenize_console(s);
 229                 }
 230                 GetCvars(1);
 231         } else if(cmd == "spectate") {
 232                 if(cmd_floodcheck())
 233                         return;
 234                 if not(self.flags & FL_CLIENT)
 235                         return;
 236                 if(g_arena)
 237                         return;
 238                 if(g_lms)
 239                 {
 240                         if(self.lms_spectate_warning)
 241                         {
 242                                 // mark player as spectator
 243                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 244                         }
 245                         else
 246                         {
 247                                 self.lms_spectate_warning = 1;
 248                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 249                                 return;
 250                         }
 251                 }
 252                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 253                         if(self.flagcarried)
 254                                 DropFlag(self.flagcarried, world, world);
 255                         if(self.ballcarried)
 256                                 DropBall(self.ballcarried, self.origin, self.velocity);
 257                         kh_Key_DropAll(self, TRUE);
 258                         WaypointSprite_PlayerDead();
 259                         self.classname = "observer";
 260                         if(g_ca)
 261                                 self.caplayer = 0;
 262                         if(blockSpectators)
 263                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 264                         PutClientInServer();
 265                 }
 266         } else if(cmd == "join") {
 267                 if not(self.flags & FL_CLIENT)
 268                         return;
 269                 if(!g_arena)
 270                 if (self.classname != "player" && !lockteams)
 271                 {
 272                         if(isJoinAllowed()) {
 273                                 self.classname = "player";
 274                                 if(g_ca)
 275                                         self.caplayer = 1;
 276                                 PlayerScore_Clear(self);
 277                                 bprint ("^4", self.netname, "^4 is playing now\n");
 278                                 PutClientInServer();
 279                                 if(cvar("g_campaign"))
 280                                         campaign_bots_may_start = 1;
 281                         }
 282                         else {
 283                                 //player may not join because of g_maxplayers is set
 284                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 285                         }
 286                 }
 287         } else if( cmd == "selectteam" ) {
 288                 if not(self.flags & FL_CLIENT)
 289                         return;
 290                 if( !teams_matter ) {
 291                         sprint( self, "selecteam can only be used in teamgames\n");
 292                 } else if(cvar("g_campaign")) {
 293                         //JoinBestTeam(self, 0);
 294                 } else if(lockteams) {
 295                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 296                 } else if( argv(1) == "red" ) {
 297                         DoTeamChange(COLOR_TEAM1);
 298                 } else if( argv(1) == "blue" ) {
 299                         DoTeamChange(COLOR_TEAM2);
 300                 } else if( argv(1) == "yellow" ) {
 301                         DoTeamChange(COLOR_TEAM3);
 302                 } else if( argv(1) == "pink" ) {
 303                         DoTeamChange(COLOR_TEAM4);
 304                 } else if( argv(1) == "auto" ) {
 305                         DoTeamChange(-1);
 306                 } else {
 307                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 308                 }
 309         } else if(cmd == "ready") {
 310                 if not(self.flags & FL_CLIENT)
 311                         return;
 312
 313                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 314                    || cvar("sv_ready_restart") || g_race_qualifying == 2)
 315                 {
 316                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 317                         {
 318                                 if (self.ready) // toggle
 319                                 {
 320                                         self.ready = FALSE;
 321                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 322                                 }
 323                                 else
 324                                 {
 325                                         self.ready = TRUE;
 326                                         bprint(self.netname, "^2 is ready\n");
 327                                 }
 328
 329                                 // cannot reset the game while a timeout is active!
 330                                 if(!timeoutStatus)
 331                                         ReadyCount();
 332                         } else {
 333                                 sprint(self, "^1Game has already been restarted\n");
 334                         }
 335                 }
 336         } else if(cmd == "maplist") {
 337                 sprint(self, maplist_reply);
 338         } else if(cmd == "lsmaps") {
 339                 sprint(self, lsmaps_reply);
 340         } else if(cmd == "records") {
 341                 sprint(self, records_reply);
 342         } else if(cmd == "voice") {
 343                 if(tokens >= 3)
 344                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 345                 else
 346                         VoiceMessage(argv(1), "");
 347         } else if(cmd == "say") {
 348                 if(tokens >= 2)
 349                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 350                 //clientcommand(self, formatmessage(s));
 351         } else if(cmd == "say_team") {
 352                 if(tokens >= 2)
 353                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 354                 //clientcommand(self, formatmessage(s));
 355         } else if(cmd == "tell") {
 356                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
 357                 if(e && tokens > ParseCommandPlayerSlotTarget_firsttoken)
 358                 {
 359                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
 360                 }
 361                 else
 362                 {
 363                         if(tokens > ParseCommandPlayerSlotTarget_firsttoken)
 364                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
 365                         sprint(self, "ERROR: usage: tell # playerid text...\n");
 366                 }
 367                 //clientcommand(self, formatmessage(s));
 368         } else if(cmd == "info") {
 369                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 370                 if(cmd == "")
 371                         sprint(self, "ERROR: unsupported info command\n");
 372                 else
 373                         wordwrap_sprint(cmd, 1111);
 374         } else if(cmd == "suggestmap") {
 375                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 376         } else if(cmd == "timeout") {
 377                 if not(self.flags & FL_CLIENT)
 378                         return;
 379                 if(cvar("sv_timeout")) {
 380                         if(self.classname == "player") {
 381                                 if(votecalled)
 382                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 383                                 else
 384                                         evaluateTimeout();
 385                         }
 386                         else
 387                                 sprint(self, "^7Error: only players can call a timeout!\n");
 388                 }
 389         } else if(cmd == "timein") {
 390                 if not(self.flags & FL_CLIENT)
 391                         return;
 392                 if(cvar("sv_timeout")) {
 393                         evaluateTimein();
 394                 }
 395         } else if(cmd == "teamstatus") {
 396                 Score_NicePrint(self);
 397         } else if(cmd == "cvar_changes") {
 398                 sprint(self, cvar_changes);
 399         } else if(cmd == "pointparticles") {
 400                 if((sv_cheats || self.maycheat) && tokens == 5)
 401                 {
 402                         // arguments:
 403                         //   effectname
 404                         //   origin (0..1, on crosshair line)
 405                         //   velocity
 406                         //   howmany
 407                         effectnum = particleeffectnum(argv(1));
 408                         f = stof(argv(2));
 409                         start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 410                         end = stov(argv(3));
 411                         f = stof(argv(4));
 412                         pointparticles(effectnum, start, end, f);
 413                 }
 414                 else
 415                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 416         } else if(cmd == "trailparticles") {
 417                 if((sv_cheats || self.maycheat) && tokens == 2)
 418                 {
 419                         // arguments:
 420                         //   effectname
 421                         effectnum = particleeffectnum(argv(1));
 422                         W_SetupShot(self, FALSE, FALSE, "",0);
 423                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 424                         trailparticles(self, effectnum, w_shotorg, trace_endpos);
 425                 }
 426                 else
 427                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 428         } else if(cmd == "make") {
 429                 if((sv_cheats || self.maycheat) && tokens == 3)
 430                 {
 431                         // arguments:
 432                         //   modelname mode
 433                         f = stof(argv(2));
 434                         W_SetupShot(self, FALSE, FALSE, "", 0);
 435                         traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 436                         if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 437                         {
 438                                 sprint(self, "cannot make stuff there (bad surface)\n");
 439                         }
 440                         else
 441                         {
 442                                 oldself = self;
 443                                 self = spawn();
 444                                 self.model = strzone(argv(1));
 445                                 self.mdl = "rocket_explode";
 446                                 self.health = 1000;
 447                                 setorigin(self, trace_endpos);
 448                                 self.effects = EF_NOMODELFLAGS;
 449                                 if(f == 1)
 450                                 {
 451                                         self.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 452                                         self.angles = AnglesTransform_Multiply(self.angles, '-90 0 0'); // so unrotated models work
 453                                 }
 454                                 spawnfunc_func_breakable();
 455                                 // now, is it valid?
 456                                 if(f == 0)
 457                                 {
 458                                         tracebox(self.origin, self.mins, self.maxs, self.origin, MOVE_NORMAL, self);
 459                                         if(trace_startsolid)
 460                                         {
 461                                                 sprint(oldself, "cannot make stuff there (no space)\n");
 462                                                 remove(self);
 463                                         }
 464                                 }
 465                                 self = oldself;
 466                         }
 467                 }
 468                 else
 469                         sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 470         } else if(cmd == "penalty") {
 471                 if((sv_cheats || self.maycheat) && tokens == 3)
 472                         race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 473                 else
 474                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 475         } else if(cmd == "dragbox_spawn") {
 476                 if(sv_cheats || self.maycheat)
 477                 {
 478                         e = spawn();
 479                         e.classname = "dragbox_box";
 480                         e.think = DragBox_Think;
 481                         e.nextthink = time;
 482                         e.solid = -1; // black
 483                         setmodel(e, "null"); // network it
 484                         if(tokens == 4)
 485                                 e.cnt = stof(argv(1));
 486                         else
 487                                 e.cnt = max(0, drag_lastcnt);
 488
 489                         e.aiment = spawn();
 490                         e.aiment.classname = "dragbox_corner_1";
 491                         e.aiment.owner = e;
 492                         setmodel(e.aiment, "models/marker.md3");
 493                         e.aiment.skin = 0;
 494                         setsize(e.aiment, '0 0 0', '0 0 0');
 495                         if(tokens == 4)
 496                                 setorigin(e.aiment, stov(argv(2)));
 497                         else
 498                                 setorigin(e.aiment, self.cursor_trace_endpos);
 499
 500                         e.enemy = spawn();
 501                         e.enemy.classname = "dragbox_corner_2";
 502                         e.enemy.owner = e;
 503                         setmodel(e.enemy, "models/marker.md3");
 504                         e.enemy.skin = 1;
 505                         setsize(e.enemy, '0 0 0', '0 0 0');
 506                         end = normalize(self.cursor_trace_start - e.aiment.origin);
 507                         end_x = (end_x > 0) * 2 - 1;
 508                         end_y = (end_y > 0) * 2 - 1;
 509                         end_z = (end_z > 0) * 2 - 1;
 510                         if(tokens == 4)
 511                                 setorigin(e.enemy, stov(argv(3)));
 512                         else
 513                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 514
 515                         e.killindicator = spawn();
 516                         e.killindicator.classname = "drag_digit";
 517                         e.killindicator.owner = e;
 518                         setattachment(e.killindicator, e, "");
 519                         setorigin(e.killindicator, '0 0 -8');
 520                         e.killindicator.killindicator = spawn();
 521                         e.killindicator.killindicator.classname = "drag_digit";
 522                         e.killindicator.killindicator.owner = e;
 523                         setattachment(e.killindicator.killindicator, e, "");
 524                         setorigin(e.killindicator.killindicator, '0 0 8');
 525                 }
 526                 else
 527                         sprint(self, "Usage: sv_cheats 1; r_showbboxes 1.5; restart; cmd dragbox_spawn\n");
 528         } else if(cmd == "dragpoint_spawn") {
 529                 if(sv_cheats || self.maycheat)
 530                 {
 531                         e = spawn();
 532                         e.classname = "dragpoint";
 533                         e.think = DragBox_Think;
 534                         e.nextthink = time;
 535                         e.solid = 0; // nothing special
 536                         setmodel(e, "models/marker.md3");
 537                         setsize(e, PL_MIN, PL_MAX);
 538                         e.skin = 2;
 539                         if(tokens == 3)
 540                                 e.cnt = stof(argv(1));
 541                         else
 542                                 e.cnt = drag_lastcnt;
 543                         if(tokens == 3)
 544                                 setorigin(e, stov(argv(2)));
 545                         else
 546                         {
 547                                 setorigin(e, self.cursor_trace_endpos + normalize(self.cursor_trace_start - self.cursor_trace_endpos));
 548                                 move_out_of_solid(e);
 549                         }
 550
 551                         e.killindicator = spawn();
 552                         e.killindicator.classname = "drag_digit";
 553                         e.killindicator.owner = e;
 554                         setattachment(e.killindicator, e, "");
 555                         setorigin(e.killindicator, '0 0 40');
 556                         e.killindicator.killindicator = spawn();
 557                         e.killindicator.killindicator.classname = "drag_digit";
 558                         e.killindicator.killindicator.owner = e;
 559                         setattachment(e.killindicator.killindicator, e, "");
 560                         setorigin(e.killindicator.killindicator, '0 0 56');
 561                 }
 562                 else
 563                         sprint(self, "Usage: sv_cheats 1; r_showbboxes 1.5; restart; cmd dragbox_spawn\n");
 564         } else if(cmd == "drag_remove") {
 565                 if(sv_cheats || self.maycheat)
 566                 {
 567                         RandomSelection_Init();
 568                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 569                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 570                         for(e = world; (e = find(e, classname, "dragpoint")); )
 571                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 572                         if(RandomSelection_chosen_ent)
 573                         {
 574                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 575                                 remove(RandomSelection_chosen_ent.killindicator);
 576                                 if(RandomSelection_chosen_ent.aiment)
 577                                         remove(RandomSelection_chosen_ent.aiment);
 578                                 if(RandomSelection_chosen_ent.enemy)
 579                                         remove(RandomSelection_chosen_ent.enemy);
 580                                 remove(RandomSelection_chosen_ent);
 581                         }
 582                 }
 583                 else
 584                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_remove\n");
 585         } else if(cmd == "drag_setcnt") {
 586                 if((sv_cheats || self.maycheat) && tokens >= 2)
 587                 {
 588                         RandomSelection_Init();
 589                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 590                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 591                         for(e = world; (e = find(e, classname, "dragpoint")); )
 592                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 593                         if(RandomSelection_chosen_ent)
 594                         {
 595                                 if(substring(argv(1), 0, 1) == "*")
 596                                         RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 597                                 else
 598                                         RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 599                         }
 600                 }
 601                 else
 602                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 603         } else if(cmd == "drag_save") {
 604                 if((sv_cheats || self.maycheat) && tokens >= 2)
 605                 {
 606                         f = fopen(argv(1), FILE_WRITE);
 607                         fputs(f, "cmd drag_clear\n");
 608                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 609                         {
 610                                 fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 611                         }
 612                         for(e = world; (e = find(e, classname, "dragpoint")); )
 613                         {
 614                                 fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 615                         }
 616                         fclose(f);
 617                 }
 618                 else
 619                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 620         } else if(cmd == "drag_saveraceent") {
 621                 if((sv_cheats || self.maycheat) && tokens >= 2)
 622                 {
 623                         f = fopen(argv(1), FILE_WRITE);
 624                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 625                         {
 626                                 fputs(f, "{\n");
 627                                 fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 628                                 fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 629                                 fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 630                                 fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 631                                 fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 632                                 fputs(f, "}\n");
 633                         }
 634                         for(e = world; (e = find(e, classname, "dragpoint")); )
 635                         {
 636                                 start = '0 0 0';
 637                                 effectnum = 0;
 638                                 for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 639                                 {
 640                                         if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 641                                         {
 642                                                 start = start + oldself.origin;
 643                                                 ++effectnum;
 644                                         }
 645                                 }
 646                                 start *= 1 / effectnum;
 647                                 fputs(f, "{\n");
 648                                 fputs(f, "\"classname\" \"info_player_race\"\n");
 649                                 fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 650                                 fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 651                                 if(e.cnt == -2)
 652                                 {
 653                                         fputs(f, "\"target\" \"checkpoint0\"\n");
 654                                         fputs(f, "\"race_place\" \"0\"\n");
 655                                 }
 656                                 else if(e.cnt == -1)
 657                                 {
 658                                         fputs(f, "\"target\" \"checkpoint0\"\n");
 659                                         fputs(f, "\"race_place\" \"-1\"\n");
 660                                 }
 661                                 else
 662                                 {
 663                                         fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 664                                         if(e.cnt == 0)
 665                                         {
 666                                                 // these need race_place
 667                                                 // counting...
 668                                                 effectnum = 1;
 669                                                 for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 670                                                 if(oldself.cnt == 0)
 671                                                 {
 672                                                         if(vlen(oldself.origin - start) < vlen(e.origin - start))
 673                                                                 ++effectnum;
 674                                                         else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 675                                                                 ++effectnum;
 676                                                 }
 677                                                 fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 678                                         }
 679                                 }
 680                                 fputs(f, "}\n");
 681                         }
 682                         fclose(f);
 683                 }
 684                 else
 685                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 686         } else if(cmd == "drag_clear") {
 687                 if(sv_cheats || self.maycheat)
 688                 {
 689                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 690                                 remove(e);
 691                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 692                                 remove(e);
 693                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 694                                 remove(e);
 695                         for(e = world; (e = find(e, classname, "dragpoint")); )
 696                                 remove(e);
 697                         for(e = world; (e = find(e, classname, "drag_digit")); )
 698                                 remove(e);
 699                 }
 700                 else
 701                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_clear\n");
 702         } else {
 703                 //if(ctf_clientcommand())
 704                 //      return;
 705                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 706                 if(cmd != "status")
 707                 if(cmd != "max")
 708                 if(cmd != "monster")
 709                 if(cmd != "scrag")
 710                 if(cmd != "wraith")
 711                 if(cmd != "gimme")
 712                 if(cmd != "god")
 713                 if(cmd != "notarget")
 714                 if(cmd != "fly")
 715                 if(cmd != "noclip")
 716                 if(cmd != "give")
 717                 //if(cmd != "say") // handled above
 718                 //if(cmd != "say_team") // handled above
 719                 if(cmd != "kill")
 720                 if(cmd != "pause")
 721                 if(cmd != "ping")
 722                 if(cmd != "name")
 723                 if(cmd != "color")
 724                 if(cmd != "rate")
 725                 if(cmd != "pmodel")
 726                 if(cmd != "playermodel")
 727                 if(cmd != "playerskin")
 728                 if(cmd != "prespawn")
 729                 if(cmd != "spawn")
 730                 if(cmd != "begin")
 731                 if(cmd != "pings")
 732                 if(cmd != "sv_startdownload")
 733                 if(cmd != "download")
 734                 {
 735                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 736                         return;
 737                 }
 738
 739                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
 740                 if(cmd == "name" || cmd == "playermodel") // TODO also playerskin and color?
 741                 {
 742                         if(self.nickspamtime == 0 || time > self.nickspamtime + cvar("g_nick_flood_timeout"))
 743                                 // good, no serious flood
 744                                 self.nickspamcount = 1;
 745                         else
 746                                 self.nickspamcount += 1;
 747                         self.nickspamtime = time + cvar("g_nick_flood_penalty");
 748
 749                         if (timeoutStatus == 2) //when game is paused, no flood protection
 750                                 self.nickspamcount = self.nickspamtime = 0;
 751                 }
 752
 753                 clientcommand(self,s);
 754         }
 755 }
 756
 757 void ReadyRestartForce()
 758 {
 759         local entity e;
 760
 761         bprint("^1Server is restarting...\n");
 762
 763         VoteReset();
 764
 765         // clear overtime
 766         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
 767                 //we have to decrease timelimit to its original value again!!
 768                 float newTL;
 769                 newTL = cvar("timelimit");
 770                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 771                 cvar_set("timelimit", ftos(newTL));
 772         }
 773
 774         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 775
 776
 777         readyrestart_happened = 1;
 778         game_starttime = time + RESTART_COUNTDOWN;
 779         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 780
 781         inWarmupStage = 0; //once the game is restarted the game is in match stage
 782
 783         //reset the .ready status of all players (also spectators)
 784         FOR_EACH_CLIENTSLOT(e)
 785                 e.ready = 0;
 786         readycount = 0;
 787         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 788
 789         if(cvar("teamplay_lockonrestart") && teams_matter) {
 790                 lockteams = 1;
 791                 bprint("^1The teams are now locked.\n");
 792         }
 793
 794         //initiate the restart-countdown-announcer entity
 795         if(cvar("sv_ready_restart_after_countdown"))
 796         {
 797                 restartTimer = spawn();
 798                 restartTimer.think = restartTimer_Think;
 799                 restartTimer.nextthink = game_starttime;
 800         }
 801
 802         //after a restart every players number of allowed timeouts gets reset, too
 803         if(cvar("sv_timeout"))
 804         {
 805                 FOR_EACH_REALPLAYER(e)
 806                         e.allowedTimeouts = cvar("sv_timeout_number");
 807         }
 808
 809         //reset map immediately if this cvar is not set
 810         if (!cvar("sv_ready_restart_after_countdown"))
 811                 reset_map(TRUE);
 812
 813         if(cvar("sv_eventlog"))
 814                 GameLogEcho(":restart");
 815 }
 816
 817 void ReadyRestart()
 818 {
 819         // no arena, assault support yet...
 820         // TODO: CA support
 821         if(g_arena | g_ca | g_assault | gameover | intermission_running | race_completing)
 822                 localcmd("restart\n");
 823         else
 824                 localcmd("\nsv_hook_gamerestart;");
 825
 826         ReadyRestartForce();
 827
 828         // reset ALL scores, but only do that at the beginning
 829         //of the countdown if sv_ready_restart_after_countdown is off!
 830         //Otherwise scores could be manipulated during the countdown!
 831         if (!cvar("sv_ready_restart_after_countdown"))
 832                 Score_ClearAll();
 833 }
 834
 835 /**
 836  * Counts how many players are ready. If not enough players are ready, the function
 837  * does nothing. If all players are ready, the timelimit will be extended and the
 838  * restart_countdown variable is set to allow other functions like PlayerPostThink
 839  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 840  * is not set the map will be resetted.
 841  *
 842  * Function is called after the server receives a 'ready' sign from a player.
 843  */
 844 void ReadyCount()
 845 {
 846         local entity e;
 847         local float r, p;
 848
 849         r = p = 0;
 850
 851         FOR_EACH_REALPLAYER(e)
 852         {
 853                 p += 1;
 854                 if(e.ready)
 855                         r += 1;
 856         }
 857
 858         readycount = r;
 859
 860         Nagger_ReadyCounted();
 861
 862         if(r) // at least one is ready
 863         if(r == p) // and, everyone is ready
 864                 ReadyRestart();
 865 }
 866
 867 /**
 868  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 869  * is set)
 870  */
 871 void restartTimer_Think() {
 872         restart_mapalreadyrestarted = 1;
 873         reset_map(TRUE);
 874         Score_ClearAll();
 875         remove(self);
 876         return;
 877 }
 878
 879 /**
 880  * Checks whether the player who calls the timeout is allowed to do so.
 881  * If so, it initializes the timeout countdown. It also checks whether another
 882  * timeout was already running at this time and reacts correspondingly.
 883  *
 884  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 885  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 886  *
 887  * This function is called when a player issues the calltimeout command.
 888  */
 889 void evaluateTimeout() {
 890         if (inWarmupStage && !g_warmup_allow_timeout)
 891                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 892         if (time < game_starttime )
 893                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 894         if (timeoutStatus != 2) {
 895                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 896                 if (cvar("timelimit")) {
 897                         //a timelimit was used
 898                         local float myTl;
 899                         myTl = cvar("timelimit");
 900
 901                         local float lastPossibleTimeout;
 902                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 903
 904                         if (lastPossibleTimeout < time - game_starttime)
 905                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 906                 }
 907         }
 908         //player may not call a timeout if he has no calls left
 909         if (self.allowedTimeouts < 1)
 910                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 911         //now all required checks are passed
 912         self.allowedTimeouts -= 1;
 913         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 914         remainingTimeoutTime = cvar("sv_timeout_length");
 915         remainingLeadTime = cvar("sv_timeout_leadtime");
 916         timeoutInitiator = self;
 917         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 918                 timeoutStatus = 1;
 919                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 920                 timeoutHandler = spawn();
 921                 timeoutHandler.think = timeoutHandler_Think;
 922         }
 923         timeoutHandler.nextthink = time; //always let the entity think asap
 924
 925         //inform all connected clients about the timeout call
 926         play2all("announcer/robotic/timeoutcalled.wav");
 927 }
 928
 929 /**
 930  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 931  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 932  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 933  * value of the cvar sv_timeout_resumetime.
 934  *
 935  * This function is called when a player issues the resumegame command.
 936  */
 937 void evaluateTimein() {
 938         if (!timeoutStatus)
 939                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 940         if (self != timeoutInitiator)
 941                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 942         if (timeoutStatus == 1) {
 943                 remainingTimeoutTime = timeoutStatus = 0;
 944                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 945                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 946         }
 947         else if (timeoutStatus == 2) {
 948                 //only shorten the remainingTimeoutTime if it makes sense
 949                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 950                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 951                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 952                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 953                 }
 954                 else
 955                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 956
 957         }
 958 }