new: sv_vote_majority_factor
[divverent/nexuiz.git] / data / qcsrc / server / clientcommands.qc
1 void ReadyCount();
2 string ValidateMap(string vote);
3 void(entity e) DropFlag;
4 string MapVote_Suggest(string m);
5
6 .float floodcontrol_chat;
7 .float floodcontrol_team;
8 void Say(entity source, float teamsay, string msgin)
9 {
10         string msgstr, colorstr, cmsgstr, namestr;
11         float flood;
12         entity head;
13
14         if(!teamsay)
15                 if(substring(msgin, 0, 1) == " ")
16                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
17
18         msgin = formatmessage(msgin);
19
20         if(msgin == "")
21                 return;
22
23         if(source.classname != "player")
24                 colorstr = "^0"; // black for spectators
25         else if(teams_matter)
26                 colorstr = Team_ColorCode(source.team);
27         else
28                 teamsay = FALSE;
29
30         if(intermission_running)
31                 teamsay = FALSE;
32
33         /*
34          * using bprint solves this... me stupid
35         // how can we prevent the message from appearing in a listen server?
36         // for now, just give "say" back and only handle say_team
37         if(!teamsay)
38         {
39                 clientcommand(self, strcat("say ", msgin));
40                 return;
41         }
42         */
43
44         if(cvar("g_chat_teamcolors"))
45                 namestr = playername(source);
46         else
47                 namestr = source.netname;
48         if(teamsay)
49         {
50                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
51                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
52         }
53         else
54                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
55
56         // FLOOD CONTROL
57         flood = 0;
58         {
59                 float flood_spl;
60                 float flood_burst;
61                 float flood_lmax;
62                 var .float flood_field;
63                 float lines;
64                 if(teamsay)
65                 {
66                         flood_spl = cvar("g_chat_flood_spl_team");
67                         flood_burst = cvar("g_chat_flood_burst_team");
68                         flood_lmax = cvar("g_chat_flood_lmax_team");
69                         flood_field = floodcontrol_team;
70                 }
71                 else
72                 {
73                         flood_spl = cvar("g_chat_flood_spl");
74                         flood_burst = cvar("g_chat_flood_burst");
75                         flood_lmax = cvar("g_chat_flood_lmax");
76                         flood_field = floodcontrol_chat;
77                 }
78                 flood_burst = max(0, flood_burst - 1);
79                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
80                 lines = ceil(strlennocol(msgstr) / 75);
81                 if(flood_lmax && lines > flood_lmax)
82                         flood = 2;
83                 else if(time >= self.flood_field)
84                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
85                 else
86                         flood = 1;
87         }
88
89         if(flood)
90         {
91                 if(cvar("g_chat_flood_notify_flooder"))
92                 {
93                         if(flood == 1)
94                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
95                         else if(flood == 2)
96                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
97                 }
98                 else
99                         sprint(self, msgstr);
100                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
101         }
102         else if(teamsay)
103         {
104                 if(source.classname == "player")
105                 {
106                         FOR_EACH_REALPLAYER(head)
107                         {
108                                 if(head.team == source.team)
109                                 {
110                                         sprint(head, msgstr);
111                                         centerprint(head, cmsgstr);
112                                 }
113                         }
114                 }
115                 else
116                 {
117                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
118                         {
119                                 sprint(head, msgstr);
120                                 centerprint(head, cmsgstr);
121                         }
122                 }
123         }
124         else
125         {
126                 bprint(msgstr);
127                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
128         }
129
130         strunzone(msgstr);
131 }
132
133 float VoteCheckNasty(string cmd)
134 {
135         if(strstrofs(cmd, ";", 0) >= 0)
136                 return TRUE;
137         if(strstrofs(cmd, "\n", 0) >= 0)
138                 return TRUE;
139         if(strstrofs(cmd, "\r", 0) >= 0)
140                 return TRUE;
141         return FALSE;
142 }
143
144 string GetKickVoteVictim_newcommand;
145 entity GetKickVoteVictim(string vote, string cmd)
146 {
147         float tokens;
148         float i, n;
149         string ns;
150         entity e;
151
152         tokens = tokenize(vote);
153         ns = "";
154
155         if(tokens == 2)
156                 if(substring(argv(1), 0, 1) == "#")
157                         ns = substring(argv(1), 1, 999);
158         
159         if(tokens == 3)
160                 if(argv(1) == "#")
161                         ns = argv(2);
162
163         if(ns != "")
164         {
165                 n = stof(ns);
166                 if(ns == ftos(n)) if(n >= 1) if(n <= maxclients)
167                 {
168                         for((e = world), (i = 0); i < n; ++i, (e = nextent(e)))
169                                 ;
170                         if(clienttype(e) == CLIENTTYPE_REAL)
171                         {
172                                 GetKickVoteVictim_newcommand = strcat(argv(0), " # ", ns);
173                                 return e;
174                         }
175                 }
176         }
177
178         sprint(self, strcat("Usage: ", cmd, " ", argv(0), " #playernumber (as in \"status\")\n"));
179         return world;
180 }
181
182 void SV_ParseClientCommand(string s) {
183         local string cmd;
184         local entity e;
185         local float i;
186
187         tokenize(s);
188
189         if(argv(0) == "vote") {
190                 if(argv(1) == "help") {
191                         local string vmasterdis;
192                         if(!cvar("sv_vote_master")) {
193                                 vmasterdis = " ^1(disabled)";
194                         }
195                         local string vcalldis;
196                         if(!cvar("sv_vote_call")) {
197                                 vcalldis = " ^1(disabled)";
198                         }
199                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\" \"^2cmd vote dontcare^7\".\n");
200                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\" \"^2vdontcare^7\".\n");
201                         sprint(self, "^7\"^2help^7\" shows this info.\n");
202                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
203                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
204                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
205                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
206                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
207                         sprint(self, "^7\"^2yes^7\", \"^2no^7\" and \"^2dontcare^7\" to make your vote.\n");
208                         sprint(self, "^7If enough of the players vote yes the vote is accepted.\n");
209                         sprint(self, "^7If enough of the players vote no the vote is rejected.\n");
210                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
211                         sprint(self, "^7You can call a vote for or execute these commands:\n");
212                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
213                 } else if(argv(1) == "status") {
214                         if(votecalled) {
215                                 sprint(self, strcat("^7Vote for ", votecalledvote_display, "^7 called by ^7", votecaller.netname, "^7.\n"));
216                         } else {
217                                 sprint(self, "^1No vote called.\n");
218                         }
219                 } else if(argv(1) == "call") {
220                         if(cvar("sv_vote_call")) {
221                                 if(votecalled) {
222                                         sprint(self, "^1There is already a vote called.\n");
223                                 } else {
224                                         local string vote;
225                                         vote = VoteParse();
226                                         if(vote == "") {
227                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
228                                         } else if(time < self.vote_next) {
229                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
230                                         } else if(VoteCheckNasty(vote)) {
231                                                 sprint(self, "Syntax error in command.\n");
232                                         } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
233                                                 // remap chmap to gotomap (forces intermission)
234                                                 if(vote == "chmap" || vote == "gotomap") // won't work without arguments
235                                                         return;
236                                                 if(substring(vote, 0, 6) == "chmap ")
237                                                         vote = strcat("gotomap ", substring(vote, 6, strlen(vote) - 6));
238                                                 if(substring(vote, 0, 8) == "gotomap ")
239                                                 {
240                                                         if(!(vote = ValidateMap(substring(vote, 8, strlen(vote) - 8))))
241                                                                 return;
242                                                         vote = strcat("gotomap ", vote);
243                                                 }
244
245                                                 // make kick and kickban votes a bit nicer (and reject them if formatted badly)
246                                                 if(substring(vote, 0, 5) == "kick " || substring(vote, 0, 8) == "kickban ")
247                                                 {
248                                                         if(!(e = GetKickVoteVictim(vote, "vcall")))
249                                                                 return;
250                                                         votecalledvote_display = strzone(strcat("^1", vote, " (^7", e.netname, "^1)"));
251                                                         vote = GetKickVoteVictim_newcommand;
252                                                 }
253                                                 else
254                                                 {
255                                                         votecalledvote_display = strzone(strcat("^1", vote));
256                                                 }
257                                                 votecalledvote = strzone(vote);
258                                                 votecalled = TRUE;
259                                                 votecalledmaster = FALSE;
260                                                 votecaller = self; // remember who called the vote
261                                                 votefinished = time + cvar("sv_vote_timeout");
262                                                 votecaller.vote_vote = 1; // of course you vote yes
263                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
264                                                 bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote for ", votecalledvote_display, "\n");
265                                                 VoteCount(); // needed if you are the only one
266                                         } else {
267                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
268                                         }
269                                 }
270                         } else {
271                                 sprint(self, "^1Vote calling is NOT allowed.\n");
272                         }
273                 } else if(argv(1) == "stop") {
274                         if(!votecalled) {
275                                 sprint(self, "^1No vote called.\n");
276                         } else if(self == votecaller) { // the votecaller can stop a vote
277                                 VoteStop(self);
278                         } else if(self.vote_master) { // masters can, too
279                                 VoteStop(self);
280                         } else {
281                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
282                         }
283                 } else if(argv(1) == "master") {
284                         if(cvar("sv_vote_master")) {
285                                 if(votecalled) {
286                                         sprint(self, "^1There is already a vote called.\n");
287                                 } else {
288                                         votecalled = TRUE;
289                                         votecalledmaster = TRUE;
290                                         votecalledvote = strzone("XXX");
291                                         votecalledvote_display = strzone("^3master");
292                                         votecaller = self; // remember who called the vote
293                                         votefinished = time + cvar("sv_vote_timeout");
294                                         votecaller.vote_vote = 1; // of course you vote yes
295                                         votecaller.vote_next = time + cvar("sv_vote_wait");
296                                         bprint("\{1}^2* ^3", votecaller.netname, "^2 calls a vote to become ^3master^2.\n");
297                                         VoteCount(); // needed if you are the only one
298                                 }
299                         } else {
300                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
301                         }
302                 } else if(argv(1) == "do") {
303                         if(argv(2) == "login") {
304                                 local string masterpwd;
305                                 masterpwd = cvar_string("sv_vote_master_password");
306                                 if(masterpwd != "") {
307                                         self.vote_master = (masterpwd == argv(3));
308                                         if(self.vote_master) {
309                                                 ServerConsoleEcho(strcat("Accepted master login from ", self.netname), TRUE);
310                                                 bprint("\{1}^2* ^3", self.netname, "^2 logged in as ^3master^2\n");
311                                         }
312                                         else
313                                                 ServerConsoleEcho(strcat("REJECTED master login from ", self.netname), TRUE);
314                                 }
315                                 else
316                                         sprint(self, "^1You are NOT a master.\n");
317                         } else if(self.vote_master) {
318                                 local string dovote, dovote_display;
319                                 dovote = VoteParse();
320                                 if(dovote == "") {
321                                         sprint(self, "^1Your command was empty. See help for more info.\n");
322                                 } else if(VoteCheckNasty(dovote)) {
323                                         sprint(self, "Syntax error in command.\n");
324                                 } else if(VoteAllowed(strcat1(argv(2)))) { // strcat seems to be necessary
325                                         if(dovote == "chmap" || dovote == "gotomap") // won't work without arguments
326                                                 return;
327                                         if(substring(dovote, 0, 6) == "chmap ")
328                                                 dovote = strcat("gotomap ", substring(dovote, 6, strlen(dovote) - 6));
329                                         if(substring(dovote, 0, 8) == "gotomap ")
330                                         {
331                                                 if(!(dovote = ValidateMap(substring(dovote, 8, strlen(dovote) - 8))))
332                                                         return;
333                                                 dovote = strcat("gotomap ", dovote);
334                                         }
335
336                                         dovote_display = dovote;
337                                         if(substring(dovote, 0, 5) == "kick " || substring(dovote, 0, 8) == "kickban ")
338                                         {
339                                                 if(!(e = GetKickVoteVictim(dovote, "vdo")))
340                                                         return;
341                                                 dovote_display = strzone(strcat("^1", dovote, " (^7", e.netname, "^1)"));
342                                                 dovote = GetKickVoteVictim_newcommand;
343                                         }
344                                         bprint("\{1}^2* ^3", self.netname, "^2 used his ^3master^2 status to do \"^2", dovote_display, "^2\".\n");
345                                         localcmd(strcat(dovote, "\n"));
346                                 } else {
347                                         sprint(self, "^1This command is not ok. See help for more info.\n");
348                                 }
349                         } else {
350                                 sprint(self, "^1You are NOT a master.\n");
351                         }
352                 } else if(argv(1) == "yes") {
353                         if(!votecalled) {
354                                 sprint(self, "^1No vote called.\n");
355                         } else if(self.vote_vote == 0
356                                   || cvar("sv_vote_change")) {
357                                 sprint(self, "^1You accepted the vote.\n");
358                                 self.vote_vote = 1;
359                                 centerprint_expire(self, CENTERPRIO_VOTE);
360                                 if(!cvar("sv_vote_singlecount")) {
361                                         VoteCount();
362                                 }
363                         } else {
364                                 sprint(self, "^1You have already voted.\n");
365                         }
366                 } else if(argv(1) == "no") {
367                         if(!votecalled) {
368                                 sprint(self, "^1No vote called.\n");
369                         } else if(self.vote_vote == 0
370                                   || cvar("sv_vote_change")) {
371                                 sprint(self, "^1You rejected the vote.\n");
372                                 self.vote_vote = -1;
373                                 centerprint_expire(self, CENTERPRIO_VOTE);
374                                 if(!cvar("sv_vote_singlecount")) {
375                                         VoteCount();
376                                 }
377                         } else {
378                                 sprint(self, "^1You have already voted.\n");
379                         }
380                 } else if(argv(1) == "abstain" || argv(1) == "dontcare") {
381                         if(!votecalled) {
382                                 sprint(self, "^1No vote called.\n");
383                         } else if(self.vote_vote == 0
384                                   || cvar("sv_vote_change")) {
385                                 sprint(self, "^1You abstained from your vote.\n");
386                                 self.vote_vote = -2;
387                                 centerprint_expire(self, CENTERPRIO_VOTE);
388                                 if(!cvar("sv_vote_singlecount")) {
389                                         VoteCount();
390                                 }
391                         } else {
392                                 sprint(self, "^1You have already voted.\n");
393                         }
394                 } else {
395                         // ignore this?
396                         sprint(self, "^1Unknown vote command.\n");
397                 }
398         } else if(argv(0) == "autoswitch") {
399                 // be backwards compatible with older clients (enabled)
400                 self.autoswitch = ("0" != argv(1));
401                 local string autoswitchmsg;
402                 if (self.autoswitch) {
403                         autoswitchmsg = "on";
404                 } else {
405                         autoswitchmsg = "off";
406                 }
407                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
408         } else if(argv(0) == "clientversion") {
409                 if (argv(1) == "$gameversion") {
410                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
411                         // either that or someone wants to be funny
412                         self.version = 1;
413                 } else {
414                         self.version = stof(argv(1));
415                 }
416                 if(self.version != cvar("gameversion")) 
417                 {
418                         self.classname = "observer";
419                         self.frags = -2;
420                         PutClientInServer();
421                 } else if(cvar("g_campaign") || cvar("g_balance_teams")) {
422                         //JoinBestTeam(self, 0);
423                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
424                         self.classname = "observer";
425                         stuffcmd(self,"menu_showteamselect\n");
426                 }
427         } else if(argv(0) == "reportcvar") { // old system
428                 GetCvars(1);
429         } else if(argv(0) == "sentcvar") { // new system
430                 GetCvars(1);
431         } else if(argv(0) == "spectate") {
432                 if(g_lms || g_arena)
433                         return; // don't allow spectating in lms, unless player runs out of lives
434                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
435                         if(self.flagcarried)
436                                 DropFlag(self.flagcarried);
437                         kh_Key_DropAll(self, TRUE);
438                         WaypointSprite_PlayerDead();
439                         DistributeFragsAmongTeam(self, self.team, 1.0);
440                         self.classname = "observer";
441                         PutClientInServer();
442                 }
443         } else if(argv(0) == "join") {
444                 if(!g_arena)
445                 if (self.classname != "player")
446                 {
447                         self.classname = "player";
448                         self.frags = 0;
449                         bprint ("^4", self.netname, "^4 is playing now\n");
450                         PutClientInServer();
451                 }
452         } else if( argv(0) == "selectteam" ) {
453                 if( !cvar("teamplay") ) {
454                         sprint( self, "selecteam can only be used in teamgames\n");
455                 } else if(cvar("g_campaign")) {
456                         //JoinBestTeam(self, 0);
457                 } else if( argv(1) == "none" ) {
458                         SV_ChangeTeam( 0 );
459                 } else if( argv(1) == "red" ) {
460                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
461                 } else if( argv(1) == "blue" ) {
462                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
463                 } else if( argv(1) == "yellow" ) {
464                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
465                 } else if( argv(1) == "pink" ) {
466                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
467                 } else if( argv(1) == "auto" ) {
468                         self.team = -1;
469                         JoinBestTeam( self, 0 );
470                 } else {
471                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
472                 }
473         } else if(argv(0) == "ready") {
474                 if(cvar("sv_ready_restart"))
475                 {
476                         if(!restart_countdown)
477                         {
478                                 self.ready = TRUE;
479                                 bprint(self.netname, "^2 is ready\n");
480                                 ReadyCount();
481                         } else {
482                                 sprint(self, "^1game has already been restarted\n");
483                         }
484                 }
485         } else if(argv(0) == "maplist") {
486                 local float n;
487                 local string col;
488                 n = tokenize(cvar_string("g_maplist"));
489                 sprint(self, "^7Maps in list: ");
490                 for(i = 0; i < n; ++i)
491                 {
492                         if(mod(i, 2))
493                                 col = "^2";
494                         else
495                                 col = "^3";
496                         sprint(self, strcat(col, argv(i), " "));
497                 }
498                 sprint(self, "\n");
499 #ifdef MAPINFO
500         } else if(argv(0) == "lsmaps") {
501                 sprint(self, "^7Maps available: ");
502                 for(i = 0; i < MapInfo_count; ++i)
503                 {
504                         if(mod(i, 2))
505                                 col = "^2";
506                         else
507                                 col = "^3";
508                         sprint(self, strcat(col, MapInfo_BSPName_ByID(i), " "));
509                 }
510                 sprint(self, "\n");
511 #endif
512         } else if(argv(0) == "teamstatus") {
513                 PrintScoreboard(self);
514         } else if(argv(0) == "voice") {
515                 VoiceMessage(argv(1));
516         } else if(argv(0) == "say") {
517                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
518                 //clientcommand(self, formatmessage(s));
519         } else if(argv(0) == "say_team") {
520                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
521                 //clientcommand(self, formatmessage(s));
522         } else if(argv(0) == "info") {
523                 cmd = cvar_string(strcat("sv_info_", argv(1)));
524                 if(cmd == "")
525                         sprint(self, "ERROR: unsupported info command\n");
526                 else
527                         wordwrap_sprint(cmd, 1111);
528         } else if(argv(0) == "suggestmap") {
529                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
530         } else {
531                 cmd = argv(0);
532                 /* checks not needed any more since DP has separated clientcommands and regular commands
533                 if(cmd != "status")
534                 if(cmd != "name")
535                 //if(cmd != "say") // handled above
536                 //if(cmd != "say_team") // handled above
537                 if(cmd != "tell")
538                 if(cmd != "color")
539                 if(cmd != "kill")
540                 if(cmd != "pause")
541                 if(cmd != "kick")
542                 if(cmd != "ping")
543                 if(cmd != "pings")
544                 if(cmd != "ban")
545                 if(cmd != "pmodel")
546                 if(cmd != "rate")
547                 if(cmd != "playermodel")
548                 if(cmd != "playerskin")
549                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
550                 {
551                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
552                         return;
553                 }
554                 */
555                 clientcommand(self,s);
556         }
557 }
558
559 string ValidateMap(string m)
560 {
561 #ifdef MAPINFO
562         m = MapInfo_FixName(m);
563         if(!m)
564         {
565                 sprint(self, "This map is not available on this server.\n");
566                 return string_null;
567         }
568 #endif
569         if(!cvar("sv_vote_change_gametype"))
570                 if(!IsSameGametype(m))
571                 {
572                         sprint(self, "This server does not allow changing the game type by map votes.\n");
573                         return string_null;
574                 }
575         if(!cvar("sv_vote_override_mostrecent"))
576                 if(Map_IsRecent(m))
577                 {
578                         sprint(self, "This server does not allow for recent maps to be played again. Please be patient for some rounds.\n");
579                         return string_null;
580                 }
581 #ifdef MAPINFO
582         if(!MapInfo_CheckMap(m))
583         {
584                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not support the current game mode.\n"));
585                 return string_null;
586         }
587 #else
588         if(!TryFile(strcat("maps/", m, ".mapcfg")))
589         {
590                 sprint(self, strcat("^1Invalid mapname, \"^3", m, "^1\" does not exist on this server.\n"));
591                 return string_null;
592         }
593 #endif
594
595         return m;
596 }
597
598
599 void VoteThink() {
600         if(votefinished > 0 // a vote was called
601             && time > votefinished) // time is up
602         {
603                 VoteCount();
604         }
605 }
606
607 string VoteParse() {
608         local float index;
609         index = 3;
610         local string vote;
611         vote = argv(2);
612         while(argv(index) != "") {
613                 vote = strcat(vote, " ", argv(index));
614                 index++;
615         }
616
617         // necessary for some of the string operations
618         vote = strzone(vote);
619
620         // now we remove some things that could be misused
621         index = 0;
622         local float found;
623         found = FALSE;
624         local float votelength;
625         votelength = strlen(vote);
626         while(!found && index < votelength)
627         {
628                 local string badchar;
629                 badchar = substring(vote, index, 1);
630                 if(badchar == ";"
631                    || badchar == "\r"
632                    || badchar == "\n")
633                 {
634                         found = TRUE;
635                 } else {
636                         index++;
637                 }
638         }
639         return substring(vote, 0, index);
640 }
641
642 float VoteAllowed(string votecommand) {
643         tokenize(cvar_string("sv_vote_commands"));
644         local float index;
645         index = 0;
646         while(argv(index) != "") {
647                 local string allowed;
648                 allowed = argv(index);
649                 if(votecommand == allowed) {
650                         return TRUE;
651                 }
652                 index++;
653         }
654         return FALSE;
655 }
656
657 void VoteReset() {
658         local entity player;
659
660         FOR_EACH_CLIENT(player)
661         {
662                 player.vote_vote = 0;
663                 centerprint_expire(player, CENTERPRIO_VOTE);
664         }
665
666         if(votecalled)
667         {
668                 strunzone(votecalledvote);
669                 strunzone(votecalledvote_display);
670         }
671
672         votecalled = FALSE;
673         votecalledmaster = FALSE;
674         votefinished = 0;
675 }
676
677 void VoteAccept() {
678         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ^1", votecalledvote_display, "^2 was accepted\n");
679         if(votecalledmaster)
680         {
681                 votecaller.vote_master = 1;
682         } else {
683                 localcmd(strcat(votecalledvote, "\n"));
684         }
685         votecaller.vote_next = 0; // people like your votes, no wait for next vote
686         VoteReset();
687 }
688
689 void VoteReject() {
690         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 was rejected\n");
691         VoteReset();
692 }
693
694 void VoteTimeout() {
695         bprint("\{1}^2* ^3", votecaller.netname, "^2's vote for ", votecalledvote_display, "^2 timed out\n");
696         VoteReset();
697 }
698
699 void VoteStop(entity stopper) {
700         bprint("\{1}^2* ^3", stopper.netname, "^2 stopped ^3", votecaller.netname, "^2's vote\n");
701         if(stopper == votecaller) {
702                 // no wait for next vote so you can correct your vote
703                 votecaller.vote_next = 0;
704         }
705         VoteReset();
706 }
707
708 void VoteNag() {
709         if(votecalled)
710                 if(self.vote_vote == 0)
711                         centerprint_atprio(self, CENTERPRIO_VOTE, strcat("^7^3", votecaller.netname, "^2 called a vote for ", votecalledvote_display, "\n\n^2You have not voted yet!\n^2HINT: By default, F1 is yes and F2 is no."));
712 }
713
714 void VoteCount() {
715         local float playercount;
716         playercount = 0;
717         local float yescount;
718         yescount = 0;
719         local float nocount;
720         nocount = 0;
721         local float abstaincount;
722         abstaincount = 0;
723         local entity player;
724
725         FOR_EACH_REALCLIENT(player)
726         {
727                 if(player.vote_vote == -1) {
728                         nocount++;
729                 } else if(player.vote_vote == 1) {
730                         yescount++;
731                 } else if(player.vote_vote == -2) {
732                         abstaincount++;
733                 }
734                 playercount++;
735         }
736
737         if((playercount == 1) && votecalledmaster) {
738                 // if only one player is on the server becoming vote
739                 // master is not allowed.  This could be used for
740                 // trolling or worse. 'self' is the user who has
741                 // called the vote because this function is called
742                 // by SV_ParseClientCommand. Maybe all voting should
743                 // be disabled for a single player?
744                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
745                 votecaller.vote_next = 0;
746                 VoteReset();
747         } else {
748 #define VOTEDEBUG dprint("yes = ", ftos(yescount), ", "); dprint("no = ", ftos(nocount), ", "); dprint("abstain = ", ftos(abstaincount), ", "); dprint("not voted = ", ftos(playercount - yescount - nocount - abstaincount), "\n");
749                 float votefactor;
750                 votefactor = bound(0.5, cvar("sv_vote_majority_factor"), 0.999);
751                 if(yescount > (playercount - abstaincount) * votefactor)
752                 {
753                         VOTEDEBUG
754                         VoteAccept();
755                 }
756                 else if(nocount >= (playercount - abstaincount) * (1 - votefactor)) // that means, yescount cannot reach minyes any more
757                 {
758                         VOTEDEBUG
759                         VoteReject();
760                 }
761                 else if(time > votefinished)
762                 {
763                         VOTEDEBUG
764                         if(cvar("sv_vote_simple_majority"))
765                                 if(yescount > (yescount + nocount) * votefactor)
766                                         VoteAccept();
767                                 else if(yescount + nocount > 0)
768                                         VoteReject();
769                                 else
770                                         VoteTimeout();
771                         else
772                                 VoteTimeout();
773                 }
774         }
775 }
776
777 float timelimit_orig;
778
779 void ReadyCount()
780 {
781         local entity e;
782         local float r, p;
783
784         FOR_EACH_REALPLAYER(e)
785         {
786                 p += 1;
787                 if(e.ready)
788                         r += 1;
789         }
790
791         if(!p || r < p)
792                 return;
793
794         bprint("^1Server is restarting...\n");
795         
796         // no arena, assault & onslaught support yet...
797         if(g_arena | g_assault | g_onslaught | gameover | intermission_running)
798                 localcmd("restart\n");
799
800         restart_countdown = time + RESTART_COUNTDOWN;
801         if(0<cvar("timelimit"))
802         {
803                 // remember original timelimit on first restart
804                 if(!timelimit_orig)
805                         timelimit_orig = cvar("timelimit");
806                 cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
807         }
808
809         reset_map();
810         
811         if(cvar("sv_eventlog"))
812                 GameLogEcho(":restart", FALSE);
813 }