data/qcsrc/server/clientcommands.qc

   1 void ReadyCount();
   2 void(entity e) DropFlag;
   3 string MapVote_Suggest(string m);
   4
   5 .float floodcontrol_chat;
   6 .float floodcontrol_team;
   7 void Say(entity source, float teamsay, string msgin)
   8 {
   9         string msgstr, colorstr, cmsgstr, namestr;
  10         float flood;
  11         entity head;
  12
  13         if(!teamsay)
  14                 if(substring(msgin, 0, 1) == " ")
  15                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
  16
  17         msgin = formatmessage(msgin);
  18
  19         if(msgin == "")
  20                 return;
  21
  22         if(source.classname != "player")
  23                 colorstr = "^0"; // black for spectators
  24         else if(teams_matter)
  25                 colorstr = Team_ColorCode(source.team);
  26         else
  27                 teamsay = FALSE;
  28
  29         if(intermission_running)
  30                 teamsay = FALSE;
  31
  32         /*
  33          * using bprint solves this... me stupid
  34         // how can we prevent the message from appearing in a listen server?
  35         // for now, just give "say" back and only handle say_team
  36         if(!teamsay)
  37         {
  38                 clientcommand(self, strcat("say ", msgin));
  39                 return;
  40         }
  41         */
  42
  43         if(cvar("g_chat_teamcolors"))
  44                 namestr = playername(source);
  45         else
  46                 namestr = source.netname;
  47         if(teamsay)
  48         {
  49                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
  50                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
  51         }
  52         else
  53                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
  54
  55         // FLOOD CONTROL
  56         flood = 0;
  57         {
  58                 float flood_spl;
  59                 float flood_burst;
  60                 float flood_lmax;
  61                 var .float flood_field;
  62                 float lines;
  63                 if(teamsay)
  64                 {
  65                         flood_spl = cvar("g_chat_flood_spl_team");
  66                         flood_burst = cvar("g_chat_flood_burst_team");
  67                         flood_lmax = cvar("g_chat_flood_lmax_team");
  68                         flood_field = floodcontrol_team;
  69                 }
  70                 else
  71                 {
  72                         flood_spl = cvar("g_chat_flood_spl");
  73                         flood_burst = cvar("g_chat_flood_burst");
  74                         flood_lmax = cvar("g_chat_flood_lmax");
  75                         flood_field = floodcontrol_chat;
  76                 }
  77                 flood_burst = max(0, flood_burst - 1);
  78                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
  79                 lines = ceil(strlennocol(msgstr) / 75);
  80                 if(flood_lmax && lines > flood_lmax)
  81                         flood = 2;
  82                 else if(time >= self.flood_field)
  83                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
  84                 else
  85                         flood = 1;
  86         }
  87
  88         if(flood)
  89         {
  90                 if(cvar("g_chat_flood_notify_flooder"))
  91                 {
  92                         if(flood == 1)
  93                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
  94                         else if(flood == 2)
  95                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
  96                 }
  97                 else
  98                         sprint(self, msgstr);
  99                 ServerConsoleEcho(strcat("NOTE: ", playername(self), "^7 is flooding."), TRUE);
 100         }
 101         else if(teamsay)
 102         {
 103                 if(source.classname == "player")
 104                 {
 105                         FOR_EACH_REALPLAYER(head)
 106                         {
 107                                 if(head.team == source.team)
 108                                 {
 109                                         sprint(head, msgstr);
 110                                         centerprint(head, cmsgstr);
 111                                 }
 112                         }
 113                 }
 114                 else
 115                 {
 116                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 117                         {
 118                                 sprint(head, msgstr);
 119                                 centerprint(head, cmsgstr);
 120                         }
 121                 }
 122         }
 123         else
 124         {
 125                 //when g_tourney is active and g_tourney_disable_spec_chat is set and game is in matchstage
 126                 //don't print the text from specs/observers to the players but only the other spectators
 127                 if(g_tourney && cvar("g_tourney_disable_spec_chat") && tourneyInMatchStage && source.classname != "player") {
 128                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 129                                 sprint(head, msgstr);
 130                         }
 131                 }
 132                 else
 133                         bprint(msgstr);
 134                 //ServerConsoleEcho(substring(msgstr, 1, strlen(msgstr) - 2), TRUE);
 135         }
 136
 137         strunzone(msgstr);
 138 }
 139
 140 entity GetPlayer(string name)
 141 {
 142         float num;
 143         entity e;
 144         string ns;
 145
 146         if(substring(name, 0, 1) == "#") {
 147                 num = stof(substring(name, 1, 999));
 148                 if(num >= 1 && num <= maxclients) {
 149                         for((e = world); num > 0; --num, (e = nextent(e)))
 150                                 ;
 151                         //if(clienttype(e) == CLIENTTYPE_REAL)
 152                         if(e.classname == "player")
 153                                 return e;
 154                 }
 155         } else {
 156                 ns = strdecolorize(name);
 157                 FOR_EACH_REALPLAYER(e) {
 158                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
 159                                 return e;
 160                         }
 161                 }
 162         }
 163         return world;
 164 }
 165
 166 //float ctf_clientcommand();
 167 void SV_ParseClientCommand(string s) {
 168         local string cmd;
 169         local float i;
 170
 171         tokenize(s);
 172
 173         if(GameCommand_Vote(s, self)) {
 174                 return;
 175         } else if(GameCommand_MapVote(argv(0))) {
 176                 return;
 177         } else if(argv(0) == "autoswitch") {
 178                 // be backwards compatible with older clients (enabled)
 179                 self.autoswitch = ("0" != argv(1));
 180                 local string autoswitchmsg;
 181                 if (self.autoswitch) {
 182                         autoswitchmsg = "on";
 183                 } else {
 184                         autoswitchmsg = "off";
 185                 }
 186                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 187         } else if(argv(0) == "clientversion") {
 188                 if not(self.flags & FL_CLIENT)
 189                         return;
 190                 if (argv(1) == "$gameversion") {
 191                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 192                         // either that or someone wants to be funny
 193                         self.version = 1;
 194                 } else {
 195                         self.version = stof(argv(1));
 196                 }
 197                 if(self.version != cvar("gameversion"))
 198                 {
 199                         self.classname = "observer";
 200                         self.frags = -2;
 201                         PutClientInServer();
 202                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 203                         //JoinBestTeam(self, FALSE, TRUE);
 204                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 205                         self.classname = "observer";
 206                         stuffcmd(self,"menu_showteamselect\n");
 207                 }
 208         } else if(argv(0) == "reportcvar") { // old system
 209                 GetCvars(1);
 210         } else if(argv(0) == "sentcvar") { // new system
 211                 GetCvars(1);
 212         } else if(argv(0) == "spectate") {
 213                 if not(self.flags & FL_CLIENT)
 214                         return;
 215                 if(g_lms || g_arena)
 216                         return; // don't allow spectating in lms, unless player runs out of lives
 217                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 218                         if(self.flagcarried)
 219                                 DropFlag(self.flagcarried);
 220                         kh_Key_DropAll(self, TRUE);
 221                         WaypointSprite_PlayerDead();
 222                         self.classname = "observer";
 223                         if(blockSpectators)
 224                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 225                         PutClientInServer();
 226                 }
 227         } else if(argv(0) == "join") {
 228                 if not(self.flags & FL_CLIENT)
 229                         return;
 230                 if(!g_arena)
 231                 if (self.classname != "player" && !lockteams)
 232                 {
 233                         if(isJoinAllowed()) {
 234                                 self.classname = "player";
 235                                 PlayerScore_Clear(self);
 236                                 bprint ("^4", self.netname, "^4 is playing now\n");
 237                                 PutClientInServer();
 238                         }
 239                         else {
 240                                 //player may not join because of g_maxplayers is set
 241                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 242                         }
 243                 }
 244         } else if( argv(0) == "selectteam" ) {
 245                 if not(self.flags & FL_CLIENT)
 246                         return;
 247                 if( !cvar("teamplay") ) {
 248                         sprint( self, "selecteam can only be used in teamgames\n");
 249                 } else if(cvar("g_campaign")) {
 250                         //JoinBestTeam(self, 0);
 251                 } else if(lockteams) {
 252                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 253                 } else if( argv(1) == "red" ) {
 254                         DoTeamChange(COLOR_TEAM1);
 255                 } else if( argv(1) == "blue" ) {
 256                         DoTeamChange(COLOR_TEAM2);
 257                 } else if( argv(1) == "yellow" ) {
 258                         DoTeamChange(COLOR_TEAM3);
 259                 } else if( argv(1) == "pink" ) {
 260                         DoTeamChange(COLOR_TEAM4);
 261                 } else if( argv(1) == "auto" ) {
 262                         DoTeamChange(-1);
 263                 } else {
 264                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 265                 }
 266         } else if(argv(0) == "ready") {
 267                 if not(self.flags & FL_CLIENT)
 268                         return;
 269                 if(cvar("sv_ready_restart"))
 270                 {
 271                         if(timeoutStatus) {
 272                                 return sprint(self, "^1You cannot reset the game while a timeout is active!\n");
 273                         }
 274
 275                         if(!restart_countdown || cvar("sv_ready_restart_repeatable"))
 276                         {
 277                                 self.ready = TRUE;
 278                                 bprint(self.netname, "^2 is ready\n");
 279                                 ReadyCount();
 280                         } else {
 281                                 sprint(self, "^1game has already been restarted\n");
 282                         }
 283                 }
 284         } else if(argv(0) == "maplist") {
 285                 local float n;
 286                 local string col;
 287                 n = tokenize(cvar_string("g_maplist"));
 288                 sprint(self, "^7Maps in list: ");
 289                 for(i = 0; i < n; ++i)
 290                 {
 291                         if(mod(i, 2))
 292                                 col = "^2";
 293                         else
 294                                 col = "^3";
 295                         sprint(self, strcat(col, argv(i), " "));
 296                 }
 297                 sprint(self, "\n");
 298 #ifdef MAPINFO
 299         } else if(argv(0) == "lsmaps") {
 300                 sprint(self, "^7Maps available: ");
 301                 for(i = 0; i < MapInfo_count; ++i)
 302                 {
 303                         if(mod(i, 2))
 304                                 col = "^2";
 305                         else
 306                                 col = "^3";
 307                         sprint(self, strcat(col, MapInfo_BSPName_ByID(i), " "));
 308                 }
 309                 sprint(self, "\n");
 310 #endif
 311         } else if(argv(0) == "voice") {
 312                 VoiceMessage(argv(1));
 313         } else if(argv(0) == "say") {
 314                 Say(self, FALSE, substring(s, 4, strlen(s) - 4));
 315                 //clientcommand(self, formatmessage(s));
 316         } else if(argv(0) == "say_team") {
 317                 Say(self, TRUE, substring(s, 9, strlen(s) - 9));
 318                 //clientcommand(self, formatmessage(s));
 319         } else if(argv(0) == "info") {
 320                 cmd = cvar_string(strcat("sv_info_", argv(1)));
 321                 if(cmd == "")
 322                         sprint(self, "ERROR: unsupported info command\n");
 323                 else
 324                         wordwrap_sprint(cmd, 1111);
 325         } else if(argv(0) == "suggestmap") {
 326                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 327         } else if(argv(0) == "calltimeout") {
 328                 if not(self.flags & FL_CLIENT)
 329                         return;
 330                 if(cvar("sv_timeout")) {
 331                         if(self.classname == "player") {
 332                                 if(votecalled)
 333                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 334                                 else
 335                                         evaluateTimeoutCall();
 336                         }
 337                         else
 338                                 sprint(self, "^7Error: only players can call a timeout!\n");
 339                 }
 340         } else if(argv(0) == "resumegame") {
 341                 if not(self.flags & FL_CLIENT)
 342                         return;
 343                 if(cvar("sv_timeout")) {
 344                         evaluateResumeGame();
 345                 }
 346         } else {
 347                 //if(ctf_clientcommand())
 348                 //      return;
 349                 cmd = argv(0);
 350                 /* checks not needed any more since DP has separated clientcommands and regular commands
 351                 if(cmd != "status")
 352                 if(cmd != "name")
 353                 //if(cmd != "say") // handled above
 354                 //if(cmd != "say_team") // handled above
 355                 if(cmd != "tell")
 356                 if(cmd != "color")
 357                 if(cmd != "kill")
 358                 if(cmd != "pause")
 359                 if(cmd != "kick")
 360                 if(cmd != "ping")
 361                 if(cmd != "pings")
 362                 if(cmd != "ban")
 363                 if(cmd != "pmodel")
 364                 if(cmd != "rate")
 365                 if(cmd != "playermodel")
 366                 if(cmd != "playerskin")
 367                 if(cmd != "god") if(cmd != "notarget") if(cmd != "fly") if(cmd != "give") if(cmd != "noclip")
 368                 {
 369                         ServerConsoleEcho(strcat("WARNING: Invalid clientcommand by ", self.netname, ": ", s), TRUE);
 370                         return;
 371                 }
 372                 */
 373                 clientcommand(self,s);
 374         }
 375 }
 376
 377 /**
 378  * Counts how many players are ready. If not enough players are ready, the function
 379  * does nothing. If all players are ready, the timelimit will be extended and the
 380  * restart_countdown variable is set to allow other functions like PlayerPostThink
 381  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 382  * is not set the map will be resetted.
 383  *
 384  * Function is called after the server receives a 'ready' sign from a player.
 385  */
 386 void ReadyCount()
 387 {
 388         local entity e;
 389         local float r, p;
 390
 391         FOR_EACH_REALPLAYER(e)
 392         {
 393                 p += 1;
 394                 if(e.ready)
 395                         r += 1;
 396         }
 397
 398         if(cvar("sv_ready_restart_nag")) {
 399                 if(!readyNagActive) {
 400                         readyNagger = spawn();
 401                         readyNagger.think = readyNagger_Think;
 402                         readyNagger.cnt = cvar("sv_ready_restart_nag_duration");
 403                         readyNagger.nextthink = time;
 404                         readyNagActive = 1;
 405                 }
 406         }
 407
 408         if(!p || r < p)
 409                 return;
 410
 411         bprint("^1Server is restarting...\n");
 412
 413         // no arena, assault support yet...
 414         if(g_arena | g_assault | gameover | intermission_running)
 415                 localcmd("restart\n");
 416
 417         if(readyNagActive) { //if every player is ready, remove the ready-nagger again
 418                 readyNagActive = 0;
 419                 remove(readyNagger);
 420         }
 421
 422         if(g_tourney) {
 423                 tourneyInMatchStage = 1; //once the game is restarted the game is in match stage
 424                 //reset weapons and ammo, health and armor to default:
 425                 start_items = IT_LASER | IT_SHOTGUN;
 426                 start_switchweapon = WEP_SHOTGUN;
 427                 start_ammo_shells = cvar("g_start_ammo_shells");
 428                 start_ammo_nails = cvar("g_start_ammo_nails");
 429                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 430                 start_ammo_cells = cvar("g_start_ammo_cells");
 431                 start_health = cvar("g_balance_health_start");
 432                 start_armorvalue = cvar("g_balance_armor_start");
 433         }
 434
 435         restart_countdown = time + RESTART_COUNTDOWN;
 436         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 437         //reset the .ready status of all players (also spectators)
 438         FOR_EACH_CLIENT(e)
 439         {
 440                 e.ready = 0;
 441         }
 442         if(0<cvar("timelimit") || (g_tourney && cvar("g_tourney_warmup_unlimited_time")) )
 443         {
 444                 // remember original timelimit on first restart
 445                 if(!timelimit_orig)
 446                         timelimit_orig = cvar("timelimit");
 447                 //only set the new timelimit if, when loading the map, a timelimit was really set
 448                 if(timelimit_orig)
 449                         cvar_set("timelimit", ftos(timelimit_orig + ceil(restart_countdown)/60));
 450         }
 451         if(cvar("teamplay_lockonrestart") && teams_matter) {
 452                 lockteams = 1;
 453                 bprint("^1The teams are now locked.\n");
 454         }
 455
 456         //initiate the restart-countdown-announcer entity
 457         restartAnnouncer = spawn();
 458         restartAnnouncer.think = restartAnnouncer_Think;
 459         restartAnnouncer.nextthink = time;
 460         restartAnnouncer.cnt = RESTART_COUNTDOWN;
 461
 462         //after a restart every players number of allowed timeouts gets reset, too
 463         if(cvar("sv_timeout"))
 464         {
 465                 FOR_EACH_REALPLAYER(e)
 466                 {
 467                         e.allowedTimeouts = cvar("sv_timeout_number");
 468                 }
 469         }
 470
 471         //play the prepareforbattle sound to everyone
 472         sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", 1, ATTN_NONE);
 473
 474         //reset map immediately if this cvar is not set
 475         if (!cvar("sv_ready_restart_after_countdown"))
 476                 reset_map();
 477
 478         if(cvar("sv_eventlog"))
 479                 GameLogEcho(":restart", FALSE);
 480 }
 481
 482 /**
 483  * Centerprints the information to all players who didn't ready up yet to do so.
 484  */
 485 void readyNagger_Think() {
 486         local entity plr;
 487         if(self.cnt <= 0) { //have a break showing the ready nag
 488                 //make sure that the old ready-nag-centerprint isn't shown too long:
 489                 FOR_EACH_REALCLIENT(plr) {
 490                         if(plr.classname == "player") {
 491                                 if (!plr.ready)
 492                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 493                         }
 494                 }
 495                 self.cnt = cvar("sv_ready_restart_nag_duration");
 496                 self.nextthink = time + cvar("sv_ready_restart_nag_interval");
 497         }
 498         else {
 499                 //show the ready nagging to all players who aren't ready yet
 500                 FOR_EACH_REALCLIENT(plr) {
 501                         if(plr.classname == "player") {
 502                                 if (!plr.ready) {
 503                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "^2Please ready up (F4 by default)!");
 504                                         //play reminder sound once the centerprint appears for the first time after the pause:
 505                                         if (self.cnt == cvar("sv_ready_restart_nag_duration"))
 506                                                 play2(plr, "misc/talk2.wav");
 507                                 }
 508                         }
 509                 }
 510
 511                 self.nextthink = time + 1;
 512                 self.cnt -= 1;
 513         }
 514 }
 515
 516 /**
 517  * Shows the restart countdown for all players.
 518  * Plays the countdown sounds for the seconds 3, 2 1, begin for everyone.
 519  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 520  * is set to 1).
 521  */
 522 void restartAnnouncer_Think() {
 523         local entity plr;
 524         local string s;
 525         if(self.cnt <= 0) { //show the "Begin" message and
 526                 if (cvar("sv_ready_restart_after_countdown")) {
 527                         restart_mapalreadyrestarted = 1;
 528                         reset_map();
 529                 }
 530
 531                 FOR_EACH_REALCLIENT(plr) {
 532                         if(plr.classname == "player") {
 533                                 s = strcat(NEWLINES, "^1Begin!");
 534                                 centerprint(plr, s);
 535                         }
 536                 }
 537                 sound(world, CHAN_AUTO, "announcer/robotic/begin.wav", 1, ATTN_NONE);
 538
 539                 remove(self);
 540                 return;
 541         }
 542         else {
 543                 FOR_EACH_REALCLIENT(plr) {
 544                         if(plr.classname == "player") {
 545                                 s = strcat(NEWLINES, "^1Game starts in ", ftos(self.cnt), " seconds");
 546                                 centerprint(plr, s);
 547                         }
 548                 }
 549
 550                 if(self.cnt <= 3) {
 551                         sound(world, CHAN_AUTO, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"), 1, ATTN_NONE);
 552                 }
 553                 self.nextthink = time + 1;
 554                 self.cnt -= 1;
 555         }
 556 }
 557
 558 /**
 559  * Checks whether the player who calls the timeout is allowed to do so.
 560  * If so, it initializes the timeout countdown. It also checks whether another
 561  * timeout was already running at this time and reacts correspondingly.
 562  *
 563  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 564  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 565  *
 566  * This function is called when a player issues the calltimeout command.
 567  */
 568 void evaluateTimeoutCall() {
 569         if (g_tourney && !tourneyInMatchStage && !cvar("g_tourney_warmup_allow_timeout"))
 570                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 571         if (time < restart_countdown )
 572                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 573         if (timeoutStatus != 2) {
 574                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 575                 if (cvar("timelimit")) {
 576                         //a timelimit was used
 577                         local float myTl;
 578                         if (cvar("timelimit"))
 579                                 myTl = cvar("timelimit");
 580                         else
 581                                 myTl = timelimit_orig;
 582
 583                         local float lastPossibleTimeout;
 584                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 585
 586                         if (lastPossibleTimeout < time)
 587                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 588                 }
 589         }
 590         //player may not call a timeout if he has no calls left
 591         if (self.allowedTimeouts < 1)
 592                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 593         //now all required checks are passed
 594         self.allowedTimeouts -= 1;
 595         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 596         remainingTimeoutTime = cvar("sv_timeout_length");
 597         remainingLeadTime = cvar("sv_timeout_leadtime");
 598         timeoutInitiator = self;
 599         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 600                 timeoutStatus = 1;
 601                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 602                 timeoutHandler = spawn();
 603                 timeoutHandler.think = timeoutHandler_Think;
 604         }
 605         timeoutHandler.nextthink = time; //always let the entity think asap
 606
 607         //inform all connected clients about the timeout call
 608         sound(world, CHAN_AUTO, "announcer/robotic/timeoutcalled.wav", 1, ATTN_NONE);
 609 }
 610
 611 /**
 612  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 613  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 614  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 615  * value of the cvar sv_timeout_resumetime.
 616  *
 617  * This function is called when a player issues the resumegame command.
 618  */
 619 void evaluateResumeGame() {
 620         if (!timeoutStatus)
 621                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 622         if (self != timeoutInitiator)
 623                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 624         if (timeoutStatus == 1) {
 625                 remainingTimeoutTime = timeoutStatus = 0;
 626                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 627                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 628         }
 629         else if (timeoutStatus == 2) {
 630                 //only shorten the remainingTimeoutTime if it makes sense
 631                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 632                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 633                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 634                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 635                 }
 636                 else
 637                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 638
 639         }
 640 }