data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 // VorteX: static frame globals
  11 float WFRAME_FIRE1 = 0;
  12 float WFRAME_FIRE2 = 1;
  13 float WFRAME_IDLE = 2;
  14
  15 void(float fr, float t, void() func) weapon_thinkf;
  16
  17 vector w_shotorg;
  18 vector w_shotdir;
  19
  20 // this function calculates w_shotorg and w_shotdir based on the weapon model
  21 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  22 // make sure you call makevectors first (FIXME?)
  23 void(entity ent, vector vecs, float antilag, float recoil, string snd) W_SetupShot =
  24 {
  25         local vector trueaimpoint;
  26
  27         traceline_hitcorpse(self, self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  28         trueaimpoint = trace_endpos;
  29
  30         // if aiming at a player and the original trace won't hit that player
  31         // anymore, try aiming at the player's new position
  32         if (antilag)
  33         if (!trace_ent.takedamage)                 // shot would miss without antilag
  34         if (self.cursor_trace_ent)                 // but it HAD hit on the client
  35         if (self.cursor_trace_ent.takedamage)      //   and even something evil
  36         // if (trace_ent != self.cursor_trace_ent) // and it is different (redundant check, see takedamage)
  37         if (cvar("g_antilag"))
  38                 trueaimpoint = self.cursor_trace_ent.origin;
  39
  40         /*
  41         // don't allow the shot to start inside a wall
  42         local vector startorg;
  43         local vector idealorg;
  44         startorg = ent.origin + ent.view_ofs;// - '0 0 8';
  45         idealorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
  46         traceline_hitcorpse (ent, startorg, idealorg, MOVE_NOMONSTERS, ent);
  47         w_shotorg = trace_endpos;
  48         */
  49         // all positions in the code are now required to be inside the player box
  50         w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
  51
  52         w_shotdir = normalize(trueaimpoint - w_shotorg);
  53
  54         if (!cvar("g_norecoil"))
  55                 self.punchangle_x = recoil * -1;
  56
  57         if (snd != "")
  58                 sound (self, CHAN_WEAPON, snd, 1, ATTN_NORM);
  59
  60         if (self.items & IT_STRENGTH)
  61         if (!cvar("g_minstagib"))
  62                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
  63 };
  64
  65 void LaserTarget_Think()
  66 {
  67         entity e;
  68         vector offset;
  69         float uselaser;
  70         uselaser = 0;
  71
  72         // list of weapons that will use the laser, and the options that enable it
  73         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && cvar("g_laserguided_missile"))
  74                 uselaser = 1;
  75         // example
  76         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
  77         //      uselaser = 1;
  78
  79
  80
  81         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
  82         if(!uselaser)
  83         {
  84                 // rocket launcher isn't selected, so no laser target.
  85                 if(self.lasertarget != world)
  86                 {
  87                         remove(self.lasertarget);
  88                         self.lasertarget = world;
  89                 }
  90                 return;
  91         }
  92
  93         if(!self.lasertarget)
  94         {
  95                 // we don't have a lasertarget entity, so spawn one
  96                 //bprint("create laser target\n");
  97                 e = self.lasertarget = spawn();
  98                 e.owner = self.owner;                   // Its owner is my owner
  99                 e.classname = "laser_target";
 100                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 101                 setmodel(e, "models/laser_dot.mdl");    // what it looks like
 102                 e.scale = 1.25;                         // make it larger
 103                 e.alpha = 0.25;                         // transparency
 104                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 105                 e.effects = EF_FULLBRIGHT;
 106                 // make it dynamically glow
 107                 // you should avoid over-using this, as it can slow down the player's computer.
 108                 e.glow_color = 251; // red color
 109                 e.glow_size = 12;
 110         }
 111         else
 112                 e = self.lasertarget;
 113
 114         // move the laser dot to where the player is looking
 115
 116         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 117         offset = '0 0 26' + v_right*3;
 118         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 119         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 120         if(trace_plane_normal != '0 0 0')
 121                 e.angles = vectoangles(trace_plane_normal);
 122         else
 123                 e.angles = vectoangles(v_forward);
 124 }
 125
 126 .string weaponname;
 127 void() CL_Weaponentity_Think =
 128 {
 129         self.nextthink = time;
 130         if (intermission_running)
 131                 self.frame = WFRAME_IDLE;
 132         if (self.owner.weaponentity != self)
 133         {
 134                 remove(self);
 135                 return;
 136         }
 137         if (self.owner.deadflag != DEAD_NO)
 138         {
 139                 self.model = "";
 140                 return;
 141         }
 142         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 143         {
 144                 self.cnt = self.owner.weapon;
 145                 self.dmg = self.owner.modelindex;
 146                 self.deadflag = self.owner.deadflag;
 147                 if (self.owner.weaponname != "")
 148                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym"));
 149                 else
 150                         self.model = "";
 151         }
 152         self.effects = self.owner.effects;
 153
 154         if (self.flags & FL_FLY)
 155                 // owner is currently being teleported, so don't apply EF_NODRAW otherwise the viewmodel would "blink"
 156                 self.effects = self.effects - (self.effects & EF_NODRAW);
 157
 158         self.alpha = self.owner.alpha;
 159         self.colormap = self.owner.colormap;
 160
 161         self.angles = '0 0 0';
 162         local float f;
 163         f = 0;
 164         if (self.state == WS_RAISE)
 165                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 166         else if (self.state == WS_DROP)
 167                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 168         else if (self.state == WS_CLEAR)
 169                 f = 1;
 170         self.angles_x = -90 * f * f;
 171
 172         // create or update the lasertarget entity
 173         LaserTarget_Think();
 174 };
 175
 176 void() CL_ExteriorWeaponentity_Think =
 177 {
 178         self.nextthink = time;
 179         if (self.owner.exteriorweaponentity != self)
 180         {
 181                 remove(self);
 182                 return;
 183         }
 184         if (self.owner.deadflag != DEAD_NO)
 185         {
 186                 self.model = "";
 187                 return;
 188         }
 189         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 190         {
 191                 self.cnt = self.owner.weapon;
 192                 self.dmg = self.owner.modelindex;
 193                 self.deadflag = self.owner.deadflag;
 194                 if (self.owner.weaponname != "")
 195                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3"));
 196                 else
 197                         self.model = "";
 198                 setattachment(self, self.owner, "bip01 r hand");
 199                 // if that didn't find a tag, hide the exterior weapon model
 200                 if (!self.tag_index)
 201                         self.model = "";
 202         }
 203         self.effects = self.owner.effects;
 204         self.colormap = self.owner.colormap;
 205 };
 206
 207 // spawning weaponentity for client
 208 void() CL_SpawnWeaponentity =
 209 {
 210         self.weaponentity = spawn();
 211         self.weaponentity.solid = SOLID_NOT;
 212         self.weaponentity.owner = self;
 213         self.weaponentity.weaponentity = self.weaponentity;
 214         setmodel(self.weaponentity, "");
 215         self.weaponentity.origin = '0 0 0';
 216         self.weaponentity.angles = '0 0 0';
 217         self.weaponentity.viewmodelforclient = self;
 218         self.weaponentity.flags = 0;
 219         self.weaponentity.think = CL_Weaponentity_Think;
 220         self.weaponentity.nextthink = time;
 221         self.weaponentity.scale = 0.61;
 222
 223         self.exteriorweaponentity = spawn();
 224         self.exteriorweaponentity.solid = SOLID_NOT;
 225         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 226         self.exteriorweaponentity.owner = self;
 227         self.exteriorweaponentity.origin = '0 0 0';
 228         self.exteriorweaponentity.angles = '0 0 0';
 229         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 230         self.exteriorweaponentity.nextthink = time;
 231 };
 232
 233 float(entity cl, float wpn, float andammo, float complain) client_hasweapon =
 234 {
 235         local float itemcode, f;
 236         local entity oldself;
 237
 238         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 239         {
 240                 if (complain)
 241                         sprint(self, "Invalid weapon\n");
 242                 return FALSE;
 243         }
 244         itemcode = W_ItemCode(wpn);
 245         if (cl.items & itemcode)
 246         {
 247                 if (andammo)
 248                 {
 249                         oldself = self;
 250                         self = cl;
 251                         f = weapon_action(wpn, WR_CHECKAMMO1);
 252                         f = f + weapon_action(wpn, WR_CHECKAMMO2);
 253                         self = oldself;
 254                         if (!f)
 255                         {
 256                                 if (complain)
 257                                         sprint(self, "You don't have any ammo for that weapon\n");
 258                                 return FALSE;
 259                         }
 260                 }
 261                 return TRUE;
 262         }
 263         if (complain)
 264                 sprint(self, "You don't own that weapon\n");
 265         return FALSE;
 266 };
 267
 268 // Weapon subs
 269 void() w_clear =
 270 {
 271         if (self.weapon != -1)
 272                 self.weapon = 0;
 273         if (self.weaponentity)
 274         {
 275                 self.weaponentity.state = WS_CLEAR;
 276                 setmodel(self.weaponentity, "");
 277                 self.weaponentity.effects = 0;
 278         }
 279 };
 280
 281 void() w_ready =
 282 {
 283         if (self.weaponentity)
 284         {
 285                 self.weaponentity.state = WS_READY;
 286                 weapon_thinkf(WFRAME_IDLE, 0.1, w_ready);
 287         }
 288 };
 289
 290 // FIXME: add qw-style client-custom weaponrating (cl_weaponrating)?
 291 float(entity e) w_getbestweapon
 292 {// add new weapons here
 293         if (client_hasweapon(e, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 294                 return WEP_ROCKET_LAUNCHER;
 295         else if (client_hasweapon(e, WEP_NEX, TRUE, FALSE))
 296                 return WEP_NEX;
 297         else if (client_hasweapon(e, WEP_HAGAR, TRUE, FALSE))
 298                 return WEP_HAGAR;
 299         else if (client_hasweapon(e, WEP_GRENADE_LAUNCHER, TRUE, FALSE))
 300                 return WEP_GRENADE_LAUNCHER;
 301         else if (client_hasweapon(e, WEP_ELECTRO, TRUE, FALSE))
 302                 return WEP_ELECTRO;
 303         else if (client_hasweapon(e, WEP_CRYLINK, TRUE, FALSE))
 304                 return WEP_CRYLINK;
 305         else if (client_hasweapon(e, WEP_UZI, TRUE, FALSE))
 306                 return WEP_UZI;
 307         else if (client_hasweapon(e, WEP_SHOTGUN, TRUE, FALSE))
 308                 return WEP_SHOTGUN;
 309         else if (client_hasweapon(e, WEP_LASER, FALSE, FALSE))
 310                 return WEP_LASER;
 311         else
 312                 return 0;
 313 };
 314
 315 // Setup weapon for client (after this raise frame will be launched)
 316 void(float windex, string wname, float hudammo) weapon_setup =
 317 {
 318         self.items = self.items - (self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS));
 319         self.items = self.items | hudammo;
 320
 321         // the two weapon entities will notice this has changed and update their models
 322         self.weapon = windex;
 323         self.weaponname = wname;
 324 };
 325
 326 // perform weapon to attack (weaponstate and attack_finished check is here)
 327 float(float secondary, float attacktime) weapon_prepareattack =
 328 {
 329         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 330         {
 331                 self.switchweapon = w_getbestweapon(self);
 332                 if (self.switchweapon != self.weapon)
 333                         self.cnt = self.weapon;
 334                 return FALSE;
 335         }
 336         // don't fire if previous attack is not finished
 337         if (self.attack_finished > time)
 338                 return FALSE;
 339         // don't fire while changing weapon
 340         if (self.weaponentity.state != WS_READY)
 341                 return FALSE;
 342         self.weaponentity.state = WS_INUSE;
 343         self.attack_finished = max(time, self.attack_finished + attacktime);
 344         return TRUE;
 345 };
 346
 347 void(float fr, float t, void() func) weapon_thinkf =
 348 {
 349         if (fr >= 0)
 350         {
 351                 if (self.weaponentity != world)
 352                         self.weaponentity.frame = fr;
 353         }
 354
 355         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 356         {
 357                 backtrace("Tried to override initial weapon think function - should this really happen?");
 358         }
 359
 360         if(cvar("g_runematch"))
 361         {
 362                 if(self.runes & RUNE_SPEED)
 363                 {
 364                         if(self.runes & CURSE_SLOW)
 365                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 366                         else
 367                                 t = t * cvar("g_balance_rune_speed_atkrate");
 368                 }
 369                 else if(self.runes & CURSE_SLOW)
 370                 {
 371                         t = t * cvar("g_balance_curse_slow_atkrate");
 372                 }
 373         }
 374
 375         // VorteX: haste can be added here
 376         self.weapon_nextthink = max(time, self.weapon_nextthink_lastframe + t);
 377         self.weapon_think = func;
 378 };
 379
 380 void(float spd, vector org) weapon_boblayer1 =
 381 {
 382         // VorteX: haste can be added here
 383 };
 384