data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 // VorteX: static frame globals
  11 float WFRAME_FIRE1 = 0;
  12 float WFRAME_FIRE2 = 1;
  13 float WFRAME_IDLE = 2;
  14
  15 void(float fr, float t, void() func) weapon_thinkf;
  16
  17 vector w_shotorg;
  18 vector w_shotdir;
  19
  20 // this function calculates w_shotorg and w_shotdir based on the weapon model
  21 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  22 // make sure you call makevectors first (FIXME?)
  23 void(entity ent, vector vecs, float antilag, float recoil, string snd) W_SetupShot =
  24 {
  25         local vector trueaimpoint;
  26         traceline_hitcorpse(self, self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  27         trueaimpoint = trace_endpos;
  28
  29         if (cvar("g_shootfromeye"))
  30                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x;
  31         else if (cvar("g_shootfromcenter"))
  32                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + '0 0 1' * vecs_z;
  33         else
  34                 w_shotorg = ent.origin + ent.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
  35         w_shotdir = normalize(trueaimpoint - w_shotorg);
  36
  37         // explanation of g_antilag:
  38         // if client reports it was aiming at a player, and the serverside trace
  39         // says it would miss, change the aim point to the player's new origin,
  40         // but only if the shot at the player's new origin would hit of course
  41         //
  42         // FIXME: a much better method for bullet weapons would be to leave a
  43         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  44         // ghost corresponding to this player's ping time, and if so it would do
  45         // damage to the real player
  46         if (antilag)
  47         if (self.cursor_trace_ent)                 // client was aiming at someone
  48         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  49         if (cvar("g_antilag"))
  50         {
  51                 // verify that the shot would miss without antilag
  52                 // (avoids an issue where guns would always shoot at their origin)
  53                 traceline_hitcorpse(self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  54                 if (!trace_ent.takedamage)
  55                 {
  56                         // verify that the shot would hit if altered
  57                         traceline_hitcorpse(self, w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  58                         if (trace_ent == self.cursor_trace_ent)
  59                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
  60                 }
  61         }
  62
  63         if (!g_norecoil)
  64                 self.punchangle_x = recoil * -1;
  65
  66         if (snd != "")
  67                 sound (self, CHAN_WEAPON, snd, 1, ATTN_NORM);
  68
  69         if (self.items & IT_STRENGTH)
  70         if (!g_minstagib)
  71                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", 1, ATTN_NORM);
  72 };
  73
  74 void LaserTarget_Think()
  75 {
  76         entity e;
  77         vector offset;
  78         float uselaser;
  79         uselaser = 0;
  80
  81         // list of weapons that will use the laser, and the options that enable it
  82         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
  83                 uselaser = 1;
  84         // example
  85         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
  86         //      uselaser = 1;
  87
  88
  89
  90         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
  91         if(!uselaser)
  92         {
  93                 // rocket launcher isn't selected, so no laser target.
  94                 if(self.lasertarget != world)
  95                 {
  96                         remove(self.lasertarget);
  97                         self.lasertarget = world;
  98                 }
  99                 return;
 100         }
 101
 102         if(!self.lasertarget)
 103         {
 104                 // we don't have a lasertarget entity, so spawn one
 105                 //bprint("create laser target\n");
 106                 e = self.lasertarget = spawn();
 107                 e.owner = self.owner;                   // Its owner is my owner
 108                 e.classname = "laser_target";
 109                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 110                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 111                 e.scale = 1.25;                         // make it larger
 112                 e.alpha = 0.25;                         // transparency
 113                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 114                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 115                 // make it dynamically glow
 116                 // you should avoid over-using this, as it can slow down the player's computer.
 117                 e.glow_color = 251; // red color
 118                 e.glow_size = 12;
 119         }
 120         else
 121                 e = self.lasertarget;
 122
 123         // move the laser dot to where the player is looking
 124
 125         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 126         offset = '0 0 26' + v_right*3;
 127         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 128         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 129         if(trace_plane_normal != '0 0 0')
 130                 e.angles = vectoangles(trace_plane_normal);
 131         else
 132                 e.angles = vectoangles(v_forward);
 133 }
 134
 135 float CL_Weaponentity_CustomizeEntityForClient()
 136 {
 137         self.viewmodelforclient = self.owner;
 138         if(other.classname == "spectator")
 139                 if(other.enemy == self.owner)
 140                         self.viewmodelforclient = other;
 141         return TRUE;
 142 }
 143
 144 .string weaponname;
 145 void() CL_Weaponentity_Think =
 146 {
 147         self.nextthink = time;
 148         if (intermission_running)
 149                 self.frame = WFRAME_IDLE;
 150         if (self.owner.weaponentity != self)
 151         {
 152                 remove(self);
 153                 return;
 154         }
 155         if (self.owner.deadflag != DEAD_NO)
 156         {
 157                 self.model = "";
 158                 return;
 159         }
 160         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 161         {
 162                 self.cnt = self.owner.weapon;
 163                 self.dmg = self.owner.modelindex;
 164                 self.deadflag = self.owner.deadflag;
 165                 if (self.owner.weaponname != "")
 166                         setmodel(self, strcat("models/weapons/w_", self.owner.weaponname, ".zym")); // precision set below
 167                 else
 168                         self.model = "";
 169         }
 170         self.effects = self.owner.effects | EF_LOWPRECISION;
 171         self.effects = self.effects - (self.effects & (EF_FULLBRIGHT)); // can mask team color, so get rid of it
 172
 173         if (self.flags & FL_FLY)
 174                 // owner is currently being teleported, so don't apply EF_NODRAW otherwise the viewmodel would "blink"
 175                 self.effects = self.effects - (self.effects & EF_NODRAW);
 176
 177         if(self.owner.alpha >= 0)
 178                 self.alpha = self.owner.alpha;
 179         else
 180                 self.alpha = 1;
 181         self.colormap = self.owner.colormap;
 182
 183         self.angles = '0 0 0';
 184         local float f;
 185         f = 0;
 186         if (self.state == WS_RAISE)
 187                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 188         else if (self.state == WS_DROP)
 189                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 190         else if (self.state == WS_CLEAR)
 191                 f = 1;
 192         self.angles_x = -90 * f * f;
 193
 194         // create or update the lasertarget entity
 195         LaserTarget_Think();
 196 };
 197
 198 void() CL_ExteriorWeaponentity_Think =
 199 {
 200         self.nextthink = time;
 201         if (self.owner.exteriorweaponentity != self)
 202         {
 203                 remove(self);
 204                 return;
 205         }
 206         if (self.owner.deadflag != DEAD_NO)
 207         {
 208                 self.model = "";
 209                 return;
 210         }
 211         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 212         {
 213                 self.cnt = self.owner.weapon;
 214                 self.dmg = self.owner.modelindex;
 215                 self.deadflag = self.owner.deadflag;
 216                 if (self.owner.weaponname != "")
 217                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 218                 else
 219                         self.model = "";
 220                 setattachment(self, self.owner, "bip01 r hand");
 221                 // if that didn't find a tag, hide the exterior weapon model
 222                 if (!self.tag_index)
 223                         self.model = "";
 224         }
 225         self.effects = self.owner.effects | EF_LOWPRECISION;
 226         self.effects = self.effects - (self.effects & (EF_BLUE | EF_RED)); // eat performance
 227         if(self.owner.alpha >= 0)
 228                 self.alpha = self.owner.alpha;
 229         else
 230                 self.alpha = 1;
 231         self.colormap = self.owner.colormap;
 232 };
 233
 234 // spawning weaponentity for client
 235 void() CL_SpawnWeaponentity =
 236 {
 237         self.weaponentity = spawn();
 238         self.weaponentity.solid = SOLID_NOT;
 239         self.weaponentity.owner = self;
 240         self.weaponentity.weaponentity = self.weaponentity;
 241         setmodel(self.weaponentity, ""); // precision set when changed
 242         self.weaponentity.origin = '0 0 0';
 243         self.weaponentity.angles = '0 0 0';
 244         self.weaponentity.viewmodelforclient = self;
 245         self.weaponentity.flags = 0;
 246         self.weaponentity.think = CL_Weaponentity_Think;
 247         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 248         self.weaponentity.nextthink = time;
 249         self.weaponentity.scale = 0.61;
 250
 251         self.exteriorweaponentity = spawn();
 252         self.exteriorweaponentity.solid = SOLID_NOT;
 253         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 254         self.exteriorweaponentity.owner = self;
 255         self.exteriorweaponentity.origin = '0 0 0';
 256         self.exteriorweaponentity.angles = '0 0 0';
 257         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 258         self.exteriorweaponentity.nextthink = time;
 259 };
 260
 261 float(entity cl, float wpn, float andammo, float complain) client_hasweapon =
 262 {
 263         local float itemcode, f;
 264         local entity oldself;
 265
 266         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 267         {
 268                 if (complain)
 269                         sprint(self, "Invalid weapon\n");
 270                 return FALSE;
 271         }
 272         itemcode = W_ItemCode(wpn);
 273         if (cl.items & itemcode)
 274         {
 275                 if (andammo)
 276                 {
 277                         oldself = self;
 278                         self = cl;
 279                         f = weapon_action(wpn, WR_CHECKAMMO1);
 280                         f = f + weapon_action(wpn, WR_CHECKAMMO2);
 281                         self = oldself;
 282                         if (!f)
 283                         {
 284                                 if (complain)
 285                                         sprint(self, "You don't have any ammo for that weapon\n");
 286                                 return FALSE;
 287                         }
 288                 }
 289                 return TRUE;
 290         }
 291         if (complain)
 292         {
 293                 // DRESK - 3/16/07
 294                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 295                 if(itemsInMap & itemcode)
 296                         sprint(self, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 297                 else
 298                         sprint(self, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 299         }
 300         return FALSE;
 301 };
 302
 303 // Weapon subs
 304 void() w_clear =
 305 {
 306         if (self.weapon != -1)
 307                 self.weapon = 0;
 308         if (self.weaponentity)
 309         {
 310                 self.weaponentity.state = WS_CLEAR;
 311                 // self.weaponname = ""; // next frame will setmodel it to "" when needed anyway
 312                 self.weaponentity.effects = 0;
 313         }
 314 };
 315
 316 void() w_ready =
 317 {
 318         if (self.weaponentity)
 319         {
 320                 self.weaponentity.state = WS_READY;
 321                 weapon_thinkf(WFRAME_IDLE, 0.1, w_ready);
 322         }
 323 };
 324
 325 // FIXME: add qw-style client-custom weaponrating (cl_weaponrating)?
 326 float(entity e) w_getbestweapon
 327 {// add new weapons here
 328         if (client_hasweapon(e, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 329                 return WEP_ROCKET_LAUNCHER;
 330         else if (client_hasweapon(e, WEP_NEX, TRUE, FALSE))
 331                 return WEP_NEX;
 332         else if (client_hasweapon(e, WEP_HAGAR, TRUE, FALSE))
 333                 return WEP_HAGAR;
 334         else if (client_hasweapon(e, WEP_GRENADE_LAUNCHER, TRUE, FALSE))
 335                 return WEP_GRENADE_LAUNCHER;
 336         else if (client_hasweapon(e, WEP_ELECTRO, TRUE, FALSE))
 337                 return WEP_ELECTRO;
 338         else if (client_hasweapon(e, WEP_CRYLINK, TRUE, FALSE))
 339                 return WEP_CRYLINK;
 340         else if (client_hasweapon(e, WEP_UZI, TRUE, FALSE))
 341                 return WEP_UZI;
 342         else if (client_hasweapon(e, WEP_SHOTGUN, TRUE, FALSE))
 343                 return WEP_SHOTGUN;
 344         else if (client_hasweapon(e, WEP_LASER, FALSE, FALSE))
 345                 return WEP_LASER;
 346         else
 347                 return 0;
 348 };
 349
 350 // Setup weapon for client (after this raise frame will be launched)
 351 void(float windex, string wname, float hudammo) weapon_setup =
 352 {
 353         self.items = self.items - (self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS));
 354         self.items = self.items | hudammo;
 355
 356         // the two weapon entities will notice this has changed and update their models
 357         self.weapon = windex;
 358         self.weaponname = wname;
 359 };
 360
 361 // perform weapon to attack (weaponstate and attack_finished check is here)
 362 float(float secondary, float attacktime) weapon_prepareattack =
 363 {
 364         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 365         {
 366                 self.switchweapon = w_getbestweapon(self);
 367                 if (self.switchweapon != self.weapon)
 368                         self.cnt = self.weapon;
 369                 return FALSE;
 370         }
 371         // don't fire if previous attack is not finished
 372         if (ATTACK_FINISHED(self) > time)
 373                 return FALSE;
 374         // don't fire while changing weapon
 375         if (self.weaponentity.state != WS_READY)
 376                 return FALSE;
 377         self.weaponentity.state = WS_INUSE;
 378         ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self) + attacktime);
 379         return TRUE;
 380 };
 381
 382 void(float fr, float t, void() func) weapon_thinkf =
 383 {
 384         if (fr >= 0)
 385         {
 386                 if (self.weaponentity != world)
 387                         self.weaponentity.frame = fr;
 388         }
 389
 390         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 391         {
 392                 backtrace("Tried to override initial weapon think function - should this really happen?");
 393         }
 394
 395         if(cvar("g_runematch"))
 396         {
 397                 if(self.runes & RUNE_SPEED)
 398                 {
 399                         if(self.runes & CURSE_SLOW)
 400                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 401                         else
 402                                 t = t * cvar("g_balance_rune_speed_atkrate");
 403                 }
 404                 else if(self.runes & CURSE_SLOW)
 405                 {
 406                         t = t * cvar("g_balance_curse_slow_atkrate");
 407                 }
 408         }
 409
 410         // VorteX: haste can be added here
 411         self.weapon_nextthink = max(time, self.weapon_nextthink_lastframe + t);
 412         self.weapon_think = func;
 413 };
 414
 415 void(float spd, vector org) weapon_boblayer1 =
 416 {
 417         // VorteX: haste can be added here
 418 };
 419
 420 vector(vector pvelocity, vector mvelocity) W_CalculateProjectileVelocity =
 421 {
 422         vector mdirection;
 423         float mspeed;
 424         float outspeed;
 425         float nstyle;
 426         vector outvelocity;
 427
 428         mdirection = normalize(mvelocity);
 429         mspeed = vlen(mvelocity);
 430
 431         nstyle = cvar("g_projectiles_newton_style");
 432         if(nstyle == 0)
 433         {
 434                 // absolute velocity
 435                 outvelocity = mvelocity;
 436         }
 437         else if(nstyle == 1)
 438         {
 439                 // true Newtonian projectiles
 440                 outvelocity = pvelocity + mvelocity;
 441         }
 442         else if(nstyle == 2)
 443         {
 444                 // true Newtonian projectiles with automatic aim adjustment
 445                 //
 446                 // solve: |outspeed * mdirection - pvelocity| = mspeed
 447                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
 448                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
 449                 // PLUS SIGN!
 450                 // not defined?
 451                 // then...
 452                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
 453                 // velocity without mdirection component > mspeed
 454                 // fire at smallest possible mspeed that works?
 455                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
 456
 457                 float D;
 458                 float p;
 459                 float q;
 460                 p = mdirection * pvelocity;
 461                 q = pvelocity * pvelocity - mspeed * mspeed;
 462                 D = p * p - q;
 463                 if(D < 0)
 464                 {
 465                         //dprint("impossible shot, adjusting\n");
 466                         D = 0;
 467                 }
 468                 outspeed = p + sqrt(D);
 469                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 470                 outvelocity = mdirection * outspeed;
 471         }
 472         else if(nstyle == 3)
 473         {
 474                 // pseudo-Newtonian:
 475                 outspeed = mspeed + mdirection * pvelocity;
 476                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
 477                 outvelocity = mdirection * outspeed;
 478         }
 479         else if(nstyle == 4)
 480         {
 481                 // tZorkian:
 482                 outspeed = mspeed + vlen(pvelocity);
 483                 outvelocity = mdirection * outspeed;
 484         }
 485         else
 486                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
 487
 488         return outvelocity;
 489 }
 490
 491 void(entity missile) W_SetupProjectileVelocity =
 492 {
 493         if(missile.owner == world)
 494                 error("Unowned missile");
 495
 496         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
 497 }
 498
 499 void(float wepcode, float minammo) weapon_register =
 500 {
 501         string s;
 502         float itemcode;
 503         s = strcat("register_bestweapon ", ftos(wepcode), " "); // char for bestweapon
 504         s = strcat(s, ftos(wepcode), " "); // impulse
 505         s = strcat(s, ftos(W_ItemCode(wepcode)), " "); // item code
 506         s = strcat(s, ftos(wepcode), " "); // self.weapon code
 507
 508         // ammo stat
 509         itemcode = W_AmmoItemCode(wepcode);
 510         if(itemcode == IT_SHELLS)
 511                 s = strcat(s, "6 ");
 512         else if(itemcode == IT_NAILS)
 513                 s = strcat(s, "7 ");
 514         else if(itemcode == IT_ROCKETS)
 515                 s = strcat(s, "8 ");
 516         else // if(itemcode == IT_CELLS)
 517                 s = strcat(s, "9 ");
 518
 519         s = strcat(s, ftos(minammo), "\n");
 520         //dprint(s);
 521         stuffcmd(self, s);
 522 }