data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 void W_SwitchWeapon_Force(entity e, float w)
  11 {
  12         e.cnt = e.switchweapon;
  13         e.switchweapon = w;
  14 }
  15
  16 .float antilag_debug;
  17
  18 // VorteX: static frame globals
  19 float WFRAME_DONTCHANGE = -1;
  20 float WFRAME_FIRE1 = 0;
  21 float WFRAME_FIRE2 = 1;
  22 float WFRAME_IDLE = 2;
  23 float WFRAME_RELOAD = 3;
  24 .float wframe;
  25
  26 void(float fr, float t, void() func) weapon_thinkf;
  27
  28 vector w_shotorg;
  29 vector w_shotdir;
  30
  31 // this function calculates w_shotorg and w_shotdir based on the weapon model
  32 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  33 // make sure you call makevectors first (FIXME?)
  34 void W_SetupShot(entity ent, float antilag, float recoil, string snd)
  35 {
  36         float nudge = 1; // added to traceline target and subtracted from result
  37         local vector trueaimpoint;
  38         local float oldsolid;
  39         vector vecs;
  40         oldsolid = self.dphitcontentsmask;
  41         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  42         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, self);
  43         trueaimpoint = trace_endpos;
  44
  45         if(ent.weaponentity.movedir_x > 0)
  46         {
  47                 vecs = ent.weaponentity.movedir;
  48                 vecs_y = -vecs_y;
  49         }
  50         else
  51                 vecs = '0 0 0';
  52
  53         if(debug_shotorg != '0 0 0')
  54                 vecs = debug_shotorg;
  55
  56         w_shotorg = ent.origin + ent.view_ofs + v_right * vecs_y + v_up * vecs_z;
  57
  58         // now move the shotorg forward as much as requested if possible
  59         traceline(w_shotorg, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, self);
  60         w_shotorg = trace_endpos - v_forward * nudge;
  61         // calculate the shotdir from the chosen shotorg
  62         w_shotdir = normalize(trueaimpoint - w_shotorg);
  63
  64 #if 0
  65         // explanation of g_antilag:
  66         // if client reports it was aiming at a player, and the serverside trace
  67         // says it would miss, change the aim point to the player's new origin,
  68         // but only if the shot at the player's new origin would hit of course
  69         //
  70         // FIXME: a much better method for bullet weapons would be to leave a
  71         // trail of lagged 'ghosts' behind players, and see if the bullet hits the
  72         // ghost corresponding to this player's ping time, and if so it would do
  73         // damage to the real player
  74         if (antilag)
  75         if (self.cursor_trace_ent)                 // client was aiming at someone
  76         if (self.cursor_trace_ent != self)         // just to make sure
  77         if (self.cursor_trace_ent.takedamage)      // and that person is killable
  78         if (self.cursor_trace_ent.classname == "player") // and actually a player
  79         if (cvar("g_antilag") == 1)
  80         {
  81                 // verify that the shot would miss without antilag
  82                 // (avoids an issue where guns would always shoot at their origin)
  83                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  84                 if (!trace_ent.takedamage)
  85                 {
  86                         // verify that the shot would hit if altered
  87                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
  88                         if (trace_ent == self.cursor_trace_ent)
  89                         {
  90                                 // verify that the shot would hit in the past
  91                                 if(self.antilag_debug)
  92                                         antilag_takeback(self.cursor_trace_ent, time - self.antilag_debug);
  93                                 else
  94                                         antilag_takeback(self.cursor_trace_ent, time - ANTILAG_LATENCY(self));
  95
  96                                 traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
  97                                 antilag_restore(self.cursor_trace_ent);
  98
  99                                 if(trace_ent == self.cursor_trace_ent)
 100                                 {
 101                                         // HIT!
 102                                         w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 103                                         dprint("ANTILAG HIT for ", self.netname, "\n");
 104                                 }
 105                                 else
 106                                 {
 107                                         // prydon cursor aimbot or odd network conditions
 108                                         dprint("WARNING: antilag ghost trace for ", self.netname, " failed!\n");
 109                                 }
 110
 111                                 if(cvar("developer") >= 2)
 112                                 {
 113                                         vector v, vplus, vel;
 114                                         float X;
 115                                         v     = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self)       ));
 116                                         vplus = antilag_takebackorigin(self.cursor_trace_ent, time - (ANTILAG_LATENCY(self) + 0.01));
 117                                         vel = (vplus - v) * (1 / 0.01);
 118                                         // solve: v + X * vel = closest to self.origin + self.view_ofs, v_forward axis
 119                                         v     -= (self.origin + self.view_ofs);
 120                                         // solve: v + X * vel = closest to v_forward axis
 121                                         // project into 2D by subtracting v_forward components:
 122                                         v   -= (v   * v_forward) * v_forward;
 123                                         vel -= (vel * v_forward) * v_forward;
 124                                         // solve: v + X * vel = closest to origin
 125                                         // (v + X * vel)^2 closest to 0
 126                                         // v^2 + 2 * X * (v * vel) + X^2 * vel^2 closest to 0
 127                                         X = -(v * vel) / (vel * vel);
 128                                         dprint("dead center needs adjustment of ", ftos(X), " (that is, ", ftos(ANTILAG_LATENCY(self) + X), " instead of ", ftos(ANTILAG_LATENCY(self)), "\n");
 129                                 }
 130                         }
 131                 }
 132         }
 133 #else
 134         if (antilag)
 135         {
 136                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 137                 {
 138                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 139                         if (!trace_ent.takedamage)
 140                         {
 141                                 traceline_antilag_force (self, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self, ANTILAG_LATENCY(self));
 142                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 143                                 {
 144                                         entity e;
 145                                         e = trace_ent;
 146                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, self);
 147                                         if(trace_ent == e)
 148                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 149                                 }
 150                         }
 151                 }
 152                 else if(cvar("g_antilag") == 3) // client side hitscan
 153                 {
 154                         if (self.cursor_trace_ent)                 // client was aiming at someone
 155                         if (self.cursor_trace_ent != self)         // just to make sure
 156                         if (self.cursor_trace_ent.takedamage)      // and that person is killable
 157                         if (self.cursor_trace_ent.classname == "player") // and actually a player
 158                         {
 159                                 // verify that the shot would miss without antilag
 160                                 // (avoids an issue where guns would always shoot at their origin)
 161                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 162                                 if (!trace_ent.takedamage)
 163                                 {
 164                                         // verify that the shot would hit if altered
 165                                         traceline(w_shotorg, self.cursor_trace_ent.origin, MOVE_NORMAL, self);
 166                                         if (trace_ent == self.cursor_trace_ent)
 167                                                 w_shotdir = normalize(self.cursor_trace_ent.origin - w_shotorg);
 168                                         else
 169                                                 print("antilag fail\n");
 170                                 }
 171                         }
 172                 }
 173         }
 174 #endif
 175
 176         self.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 177
 178         if (!g_norecoil)
 179                 self.punchangle_x = recoil * -1;
 180
 181         if (snd != "")
 182         {
 183                 sound (self, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 184         }
 185
 186         if (self.items & IT_STRENGTH)
 187         if (!g_minstagib)
 188                 sound (self, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 189 };
 190
 191 void LaserTarget_Think()
 192 {
 193         entity e;
 194         vector offset;
 195         float uselaser;
 196         uselaser = 0;
 197
 198         // list of weapons that will use the laser, and the options that enable it
 199         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 200                 uselaser = 1;
 201         // example
 202         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 203         //      uselaser = 1;
 204
 205
 206
 207         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 208         if(!uselaser)
 209         {
 210                 // rocket launcher isn't selected, so no laser target.
 211                 if(self.lasertarget != world)
 212                 {
 213                         remove(self.lasertarget);
 214                         self.lasertarget = world;
 215                 }
 216                 return;
 217         }
 218
 219         if(!self.lasertarget)
 220         {
 221                 // we don't have a lasertarget entity, so spawn one
 222                 //bprint("create laser target\n");
 223                 e = self.lasertarget = spawn();
 224                 e.owner = self.owner;                   // Its owner is my owner
 225                 e.classname = "laser_target";
 226                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 227                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 228                 e.scale = 1.25;                         // make it larger
 229                 e.alpha = 0.25;                         // transparency
 230                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 231                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 232                 // make it dynamically glow
 233                 // you should avoid over-using this, as it can slow down the player's computer.
 234                 e.glow_color = 251; // red color
 235                 e.glow_size = 12;
 236         }
 237         else
 238                 e = self.lasertarget;
 239
 240         // move the laser dot to where the player is looking
 241
 242         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 243         offset = '0 0 26' + v_right*3;
 244         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 245         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 246         if(trace_plane_normal != '0 0 0')
 247                 e.angles = vectoangles(trace_plane_normal);
 248         else
 249                 e.angles = vectoangles(v_forward);
 250 }
 251
 252 float CL_Weaponentity_CustomizeEntityForClient()
 253 {
 254         self.viewmodelforclient = self.owner;
 255         if(other.classname == "spectator")
 256                 if(other.enemy == self.owner)
 257                         self.viewmodelforclient = other;
 258         return TRUE;
 259 }
 260
 261 float qcweaponanimation;
 262 vector weapon_offset = '0 -10 0';
 263 vector weapon_adjust = '10 0 -15';
 264 .vector weapon_morph0origin;
 265 .vector weapon_morph0angles;
 266 .float  weapon_morph0time;
 267 .vector weapon_morph1origin;
 268 .vector weapon_morph1angles;
 269 .float  weapon_morph1time;
 270 .vector weapon_morph2origin;
 271 .vector weapon_morph2angles;
 272 .float  weapon_morph2time;
 273 .vector weapon_morph3origin;
 274 .vector weapon_morph3angles;
 275 .float  weapon_morph3time;
 276 .vector weapon_morph4origin;
 277 .vector weapon_morph4angles;
 278 .float  weapon_morph4time;
 279 .string weaponname;
 280 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 281
 282 void CL_Weaponentity_Think()
 283 {
 284         float tb;
 285         self.nextthink = time;
 286         if (intermission_running)
 287                 self.frame = self.anim_idle_x;
 288         if (self.owner.weaponentity != self)
 289         {
 290                 if (self.weaponentity)
 291                         remove(self.weaponentity);
 292                 remove(self);
 293                 return;
 294         }
 295         if (self.owner.deadflag != DEAD_NO)
 296         {
 297                 self.model = "";
 298                 if (self.weaponentity)
 299                         self.weaponentity.model = "";
 300                 return;
 301         }
 302         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 303         {
 304                 self.cnt = self.owner.weapon;
 305                 self.dmg = self.owner.modelindex;
 306                 self.deadflag = self.owner.deadflag;
 307
 308                 string animfilename;
 309                 float animfile;
 310                 if (self.owner.weaponname != "")
 311                 {
 312                         // if there is a child entity, hide it until we're sure we use it
 313                         if (self.weaponentity)
 314                                 self.weaponentity.model = "";
 315                         if (qcweaponanimation)
 316                                 setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 317                         else
 318                         {
 319                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 320                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 321                                 animfile = fopen(animfilename, FILE_READ);
 322                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 323                                 self.anim_fire1  = '0 1 0.01';
 324                                 self.anim_fire2  = '1 1 0.01';
 325                                 self.anim_idle   = '2 1 0.01';
 326                                 self.anim_reload = '3 1 0.01';
 327                                 if (animfile >= 0)
 328                                 {
 329                                         if (!self.weaponentity)
 330                                                 self.weaponentity = spawn();
 331                                         animparseerror = FALSE;
 332                                         self.anim_fire1  = animparseline(animfile);
 333                                         self.anim_fire2  = animparseline(animfile);
 334                                         self.anim_idle   = animparseline(animfile);
 335                                         self.anim_reload = animparseline(animfile);
 336                                         fclose(animfile);
 337                                         if (animparseerror)
 338                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 339                                 }
 340
 341                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 342                                 // if we don't, this is a "real" animated model
 343                                 if(gettagindex(self, "weapon"))
 344                                 {
 345                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 346                                         setattachment(self.weaponentity, self, "weapon");
 347                                 }
 348                         }
 349                 }
 350                 else
 351                         self.model = "";
 352
 353                 if(qcweaponanimation)
 354                 {
 355                         self.angles = '0 0 0';
 356                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 357                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 358                         self.movedir_x += 32;
 359                         self.spawnorigin = self.movedir;
 360                         // oldorigin - not calculated here
 361                 }
 362                 else
 363                 {
 364                         self.origin = '0 0 0';
 365                         self.angles = '0 0 0';
 366                         self.frame = 0;
 367                         self.viewmodelforclient = world;
 368
 369                         float idx;
 370                         idx = gettagindex(self, "shot");
 371                         if(idx)
 372                         {
 373                                 self.movedir = gettaginfo(self, idx);
 374                         }
 375                         else
 376                         {
 377                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag\n");
 378                                 self.movedir = '0 0 0';
 379                         }
 380
 381                         idx = gettagindex(self, "shell");
 382                         if(idx)
 383                         {
 384                                 self.spawnorigin = gettaginfo(self, idx);
 385                         }
 386                         else
 387                         {
 388                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag\n");
 389                                 self.spawnorigin = self.movedir;
 390                         }
 391
 392                         float idx;
 393                         idx = gettagindex(self, "weapon");
 394                         if(idx)
 395                         {
 396                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 397                         }
 398                         else
 399                         {
 400                                 self.oldorigin = self.movedir;
 401                         }
 402
 403                         self.viewmodelforclient = self.owner;
 404                 }
 405
 406                 self.view_ofs = '0 0 0';
 407
 408                 if(self.movedir_x >= 0)
 409                 {
 410                         vector v0;
 411                         v0 = self.movedir;
 412                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 413                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 414                 }
 415
 416                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 417
 418                 // check if an instant weapon switch occurred
 419                 if (qcweaponanimation)
 420                 {
 421                         if (self.state == WS_READY)
 422                         {
 423                                 self.angles = '0 0 0';
 424                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 425                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 426                         }
 427                 }
 428                 else
 429                         setorigin(self, self.view_ofs);
 430                 // reset animstate now
 431                 self.wframe = WFRAME_IDLE;
 432                 self.weapon_morph0time = 0;
 433                 self.weapon_morph1time = 0;
 434                 self.weapon_morph2time = 0;
 435                 self.weapon_morph3time = 0;
 436                 self.weapon_morph4time = 0;
 437                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 438         }
 439
 440         tb = (self.effects & EF_TELEPORT_BIT);
 441         self.effects = self.owner.effects & EFMASK_CHEAP;
 442         self.effects &~= EF_LOWPRECISION;
 443         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 444         self.effects &~= EF_TELEPORT_BIT;
 445         self.effects |= tb;
 446
 447         if(self.owner.alpha != 0)
 448                 self.alpha = self.owner.alpha;
 449         else
 450                 self.alpha = 1;
 451
 452         self.colormap = self.owner.colormap;
 453         if (self.weaponentity)
 454         {
 455                 self.weaponentity.effects = self.effects;
 456                 self.weaponentity.alpha = self.alpha;
 457                 self.weaponentity.colormap = self.colormap;
 458         }
 459
 460         self.angles = '0 0 0';
 461         local float f;
 462         f = 0;
 463         if (self.state == WS_RAISE)
 464         {
 465                 f = (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 466                 self.angles_x = -90 * f * f;
 467                 if (qcweaponanimation)
 468                 {
 469                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 470                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 471                 }
 472         }
 473         else if (self.state == WS_DROP)
 474         {
 475                 f = 1 - (self.owner.weapon_nextthink - time) / cvar("g_balance_weaponswitchdelay");
 476                 self.angles_x = -90 * f * f;
 477                 if (qcweaponanimation)
 478                 {
 479                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 480                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 481                 }
 482         }
 483         else if (self.state == WS_CLEAR)
 484         {
 485                 f = 1;
 486                 self.angles_x = -90 * f * f;
 487                 if (qcweaponanimation)
 488                 {
 489                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 490                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 491                 }
 492         }
 493         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 494         {
 495                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 496                 f = 1 - pow(1 - f, 3);
 497                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 498                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 499         }
 500         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 501         {
 502                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 503                 f = 1 - pow(1 - f, 3);
 504                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 505                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 506         }
 507         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 508         {
 509                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 510                 f = 1 - pow(1 - f, 3);
 511                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 512                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 513         }
 514         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 515         {
 516                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 517                 f = 1 - pow(1 - f, 3);
 518                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 519                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 520         }
 521         else if (qcweaponanimation)
 522         {
 523                 // begin a new idle morph
 524                 self.owner.weapon_morph0time   = time;
 525                 self.owner.weapon_morph0angles = self.angles;
 526                 self.owner.weapon_morph0origin = self.origin;
 527
 528                 float r;
 529                 float t;
 530
 531                 r = random();
 532                 if (r < 0.1)
 533                 {
 534                         // turn gun to the left to look at it
 535                         t = 2;
 536                         self.owner.weapon_morph1time   = time + t * 0.2;
 537                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 538                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 539                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 540
 541                         self.owner.weapon_morph2time   = time + t * 0.6;
 542                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 543                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 544                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 545
 546                         self.owner.weapon_morph3time   = time + t;
 547                         self.owner.weapon_morph3angles = '0 0 0';
 548                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 549                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 550                 }
 551                 else if (r < 0.2)
 552                 {
 553                         // raise the gun a bit
 554                         t = 2;
 555                         self.owner.weapon_morph1time   = time + t * 0.2;
 556                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 557                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 558                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 559
 560                         self.owner.weapon_morph2time   = time + t * 0.5;
 561                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 562                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 563                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 564
 565                         self.owner.weapon_morph3time   = time + t;
 566                         self.owner.weapon_morph3angles = '0 0 0';
 567                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 568                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 569                 }
 570                 else if (r < 0.3)
 571                 {
 572                         // tweak it a bit
 573                         t = 5;
 574                         self.owner.weapon_morph1time   = time + t * 0.3;
 575                         self.owner.weapon_morph1angles = randomvec() * 6;
 576                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 577                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 578
 579                         self.owner.weapon_morph2time   = time + t * 0.7;
 580                         self.owner.weapon_morph2angles = randomvec() * 6;
 581                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 582                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 583
 584                         self.owner.weapon_morph3time   = time + t;
 585                         self.owner.weapon_morph3angles = '0 0 0';
 586                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 587                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 588                 }
 589                 else
 590                 {
 591                         // hold it mostly steady
 592                         t = random() * 6 + 4;
 593                         self.owner.weapon_morph1time   = time + t * 0.2;
 594                         self.owner.weapon_morph1angles = randomvec() * 1;
 595                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 596                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 597
 598                         self.owner.weapon_morph2time   = time + t * 0.5;
 599                         self.owner.weapon_morph2angles = randomvec() * 1;
 600                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 601                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 602
 603                         self.owner.weapon_morph3time   = time + t * 0.7;
 604                         self.owner.weapon_morph3angles = randomvec() * 1;
 605                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 606                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 607                 }
 608
 609                 self.owner.weapon_morph4time   = time + t;
 610                 self.owner.weapon_morph4angles = '0 0 0';
 611                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 612                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 613
 614         }
 615
 616         // create or update the lasertarget entity
 617         LaserTarget_Think();
 618 };
 619
 620 void CL_ExteriorWeaponentity_Think()
 621 {
 622         float tag_found;
 623         self.nextthink = time;
 624         if (self.owner.exteriorweaponentity != self)
 625         {
 626                 remove(self);
 627                 return;
 628         }
 629         if (self.owner.deadflag != DEAD_NO)
 630         {
 631                 self.model = "";
 632                 return;
 633         }
 634         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 635         {
 636                 self.cnt = self.owner.weapon;
 637                 self.dmg = self.owner.modelindex;
 638                 self.deadflag = self.owner.deadflag;
 639                 if (self.owner.weaponname != "")
 640                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 641                 else
 642                         self.model = "";
 643
 644                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 645                 {
 646                         self.tag_index = tag_found;
 647                         self.tag_entity = self.owner;
 648                 }
 649                 else
 650                         setattachment(self, self.owner, "bip01 r hand");
 651
 652                 // if that didn't find a tag, hide the exterior weapon model
 653                 if (!self.tag_index)
 654                         self.model = "";
 655         }
 656         self.effects = self.owner.effects | EF_LOWPRECISION;
 657         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 658         if(self.owner.alpha != 0)
 659                 self.alpha = self.owner.alpha;
 660         else
 661                 self.alpha = 1;
 662
 663         self.colormap = self.owner.colormap;
 664 };
 665
 666 // spawning weaponentity for client
 667 void CL_SpawnWeaponentity()
 668 {
 669         self.weaponentity = spawn();
 670         self.weaponentity.classname = "weaponentity";
 671         self.weaponentity.solid = SOLID_NOT;
 672         self.weaponentity.owner = self;
 673         setmodel(self.weaponentity, ""); // precision set when changed
 674         self.weaponentity.origin = '0 0 0';
 675         self.weaponentity.angles = '0 0 0';
 676         self.weaponentity.viewmodelforclient = self;
 677         self.weaponentity.flags = 0;
 678         self.weaponentity.think = CL_Weaponentity_Think;
 679         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 680         self.weaponentity.nextthink = time;
 681
 682         self.exteriorweaponentity = spawn();
 683         self.exteriorweaponentity.classname = "exteriorweaponentity";
 684         self.exteriorweaponentity.solid = SOLID_NOT;
 685         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 686         self.exteriorweaponentity.owner = self;
 687         self.exteriorweaponentity.origin = '0 0 0';
 688         self.exteriorweaponentity.angles = '0 0 0';
 689         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 690         self.exteriorweaponentity.nextthink = time;
 691 };
 692
 693 .float hasweapon_complain_spam;
 694
 695 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 696 {
 697         local float weaponbit, f;
 698         local entity oldself;
 699
 700         if(time < self.hasweapon_complain_spam)
 701                 complain = 0;
 702         if(complain)
 703                 self.hasweapon_complain_spam = time + 0.2;
 704
 705         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 706         {
 707                 if (complain)
 708                         sprint(self, "Invalid weapon\n");
 709                 return FALSE;
 710         }
 711         weaponbit = W_WeaponBit(wpn);
 712         if (cl.weapons & weaponbit)
 713         {
 714                 if (andammo)
 715                 {
 716                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 717                         {
 718                                 f = 1;
 719                         }
 720                         else
 721                         {
 722                                 oldself = self;
 723                                 self = cl;
 724                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 725                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 726                                 self = oldself;
 727                         }
 728                         if (!f)
 729                         {
 730                                 if (complain)
 731                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 732                                 return FALSE;
 733                         }
 734                 }
 735                 return TRUE;
 736         }
 737         if (complain)
 738         {
 739                 // DRESK - 3/16/07
 740                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 741                 if(weaponsInMap & weaponbit)
 742                 {
 743                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 744
 745                         if(cvar("g_showweaponspawns"))
 746                         {
 747                                 entity e;
 748                                 string s;
 749
 750                                 e = get_weaponinfo(wpn);
 751                                 s = e.model2;
 752
 753                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 754                                 {
 755                                         if(e.classname == "droppedweapon")
 756                                                 continue;
 757                                         if not(e.flags & FL_ITEM)
 758                                                 continue;
 759                                         WaypointSprite_Spawn(
 760                                                 s,
 761                                                 1, 0,
 762                                                 world, e.origin,
 763                                                 self, 0,
 764                                                 world, enemy,
 765                                                 0
 766                                         );
 767                                 }
 768                         }
 769                 }
 770                 else
 771                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 772         }
 773         return FALSE;
 774 };
 775
 776 // Weapon subs
 777 void w_clear()
 778 {
 779         if (self.weapon != -1)
 780                 self.weapon = 0;
 781         if (self.weaponentity)
 782         {
 783                 self.weaponentity.state = WS_CLEAR;
 784                 self.weaponentity.effects = 0;
 785         }
 786 };
 787
 788 void w_ready()
 789 {
 790         if (self.weaponentity)
 791                 self.weaponentity.state = WS_READY;
 792         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 793 };
 794
 795 // Setup weapon for client (after this raise frame will be launched)
 796 void weapon_setup(float windex)
 797 {
 798         entity e;
 799         qcweaponanimation = cvar("sv_qcweaponanimation");
 800         e = get_weaponinfo(windex);
 801         self.items &~= IT_AMMO;
 802         self.items = self.items | e.items;
 803
 804         // the two weapon entities will notice this has changed and update their models
 805         self.weapon = windex;
 806         self.weaponname = e.mdl;
 807         self.bulletcounter = 0;
 808 };
 809
 810 // perform weapon to attack (weaponstate and attack_finished check is here)
 811 .float race_penalty;
 812 float weapon_prepareattack(float secondary, float attacktime)
 813 {
 814         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 815         //if all players readied up and the countdown is running
 816         if (cvar("sv_ready_restart_after_countdown"))
 817                 if(time < game_starttime || time < self.race_penalty) {
 818                         return FALSE;
 819                 }
 820
 821         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 822         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 823         {
 824                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 825                 return FALSE;
 826         }
 827
 828         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 829                 return FALSE;
 830
 831         // do not even think about shooting if switching
 832         if(self.switchweapon != self.weapon)
 833                 return FALSE;
 834
 835         // don't fire if previous attack is not finished
 836         if(attacktime >= 0)
 837                 if (ATTACK_FINISHED(self) > time + frametime * 0.5)
 838                         return FALSE;
 839         // don't fire while changing weapon
 840         if (self.weaponentity.state != WS_READY)
 841                 return FALSE;
 842         self.weaponentity.state = WS_INUSE;
 843
 844         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
 845
 846         // if the weapon hasn't been firing continuously, reset the timer
 847         if(attacktime >= 0)
 848         {
 849                 if (ATTACK_FINISHED(self) < time - frametime * 1.5)
 850                 {
 851                         ATTACK_FINISHED(self) = time;
 852                         //dprint("resetting attack finished to ", ftos(time), "\n");
 853                 }
 854                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime;
 855         }
 856         self.bulletcounter += 1;
 857         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
 858         return TRUE;
 859 };
 860
 861 void weapon_thinkf(float fr, float t, void() func)
 862 {
 863         vector a;
 864         vector of, or, ou;
 865         float restartanim;
 866
 867         if(fr == WFRAME_DONTCHANGE)
 868         {
 869                 fr = self.weaponentity.wframe;
 870                 restartanim = FALSE;
 871         }
 872         else if (fr == WFRAME_IDLE)
 873                 restartanim = FALSE;
 874         else
 875                 restartanim = TRUE;
 876
 877         of = v_forward;
 878         or = v_right;
 879         ou = v_up;
 880
 881         if (self.weaponentity)
 882         {
 883                 self.weaponentity.wframe = fr;
 884                 if (qcweaponanimation)
 885                 {
 886                         if (fr != WFRAME_IDLE)
 887                         {
 888                                 self.weapon_morph0time = time;
 889                                 self.weapon_morph0angles = self.weaponentity.angles;
 890                                 self.weapon_morph0origin = self.weaponentity.origin;
 891
 892                                 self.weapon_morph1angles = '0 0 0';
 893                                 self.weapon_morph1time = time + t;
 894                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 895                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 896
 897                                 self.weapon_morph2angles = '0 0 0';
 898                                 self.weapon_morph2time = time + t;
 899                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 900                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 901
 902                                 self.weapon_morph3angles = '0 0 0';
 903                                 self.weapon_morph3time = time + t;
 904                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 905                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 906
 907                                 self.weapon_morph4angles = '0 0 0';
 908                                 self.weapon_morph4time = time + t;
 909                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
 910                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 911
 912                                 if (fr == WFRAME_FIRE1)
 913                                 {
 914                                         self.weapon_morph1angles = '5 0 0';
 915                                         self.weapon_morph1time = time + t * 0.1;
 916                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 917                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 918                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 919                                 }
 920                                 else if (fr == WFRAME_FIRE2)
 921                                 {
 922                                         self.weapon_morph1angles = '10 0 0';
 923                                         self.weapon_morph1time = time + t * 0.1;
 924                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 925                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 926                                         self.weapon_morph4time = time + t + 1; // delay idle effect
 927                                 }
 928                                 else if (fr == WFRAME_RELOAD)
 929                                 {
 930                                         self.weapon_morph1time = time + t * 0.05;
 931                                         self.weapon_morph1angles = '-10 40 0';
 932                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
 933                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 934
 935                                         self.weapon_morph2time = time + t * 0.15;
 936                                         self.weapon_morph2angles = '-10 40 5';
 937                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
 938                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 939
 940                                         self.weapon_morph3time = time + t * 0.25;
 941                                         self.weapon_morph3angles = '-10 40 0';
 942                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
 943                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
 944                                 }
 945                         }
 946                 }
 947                 else
 948                 {
 949                         if (fr == WFRAME_IDLE)
 950                                 a = self.weaponentity.anim_idle;
 951                         else if (fr == WFRAME_FIRE1)
 952                                 a = self.weaponentity.anim_fire1;
 953                         else if (fr == WFRAME_FIRE2)
 954                                 a = self.weaponentity.anim_fire2;
 955                         else if (fr == WFRAME_RELOAD)
 956                                 a = self.weaponentity.anim_reload;
 957                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
 958                 }
 959
 960                 if(restartanim)
 961                 {
 962                         BITXOR_ASSIGN(self.weaponentity.effects, EF_TELEPORT_BIT);
 963                 }
 964         }
 965
 966         v_forward = of;
 967         v_right = or;
 968         v_up = ou;
 969
 970         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
 971         {
 972                 backtrace("Tried to override initial weapon think function - should this really happen?");
 973         }
 974
 975         if(g_runematch)
 976         {
 977                 if(self.runes & RUNE_SPEED)
 978                 {
 979                         if(self.runes & CURSE_SLOW)
 980                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
 981                         else
 982                                 t = t * cvar("g_balance_rune_speed_atkrate");
 983                 }
 984                 else if(self.runes & CURSE_SLOW)
 985                 {
 986                         t = t * cvar("g_balance_curse_slow_atkrate");
 987                 }
 988         }
 989
 990         // VorteX: haste can be added here
 991         if (self.weapon_think == w_ready)
 992         {
 993                 self.weapon_nextthink = time;
 994                 //dprint("started firing at ", ftos(time), "\n");
 995         }
 996         if (self.weapon_nextthink < time - frametime * 1.5 || self.weapon_nextthink > time + frametime * 1.5)
 997         {
 998                 self.weapon_nextthink = time;
 999                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1000         }
1001         self.weapon_nextthink = self.weapon_nextthink + t;
1002         self.weapon_think = func;
1003         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1004
1005         if (restartanim)
1006         if (t)
1007         if (!self.crouch) // shoot anim stands up, this looks bad
1008         {
1009                 local vector anim;
1010                 anim = self.anim_shoot;
1011                 anim_z = anim_y / t;
1012                 setanim(self, anim, FALSE, TRUE, TRUE);
1013         }
1014 };
1015
1016 void weapon_boblayer1(float spd, vector org)
1017 {
1018         // VorteX: haste can be added here
1019 };
1020
1021 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1022 {
1023         vector mdirection;
1024         float mspeed;
1025         float outspeed;
1026         float nstyle;
1027         vector outvelocity;
1028
1029         mdirection = normalize(mvelocity);
1030         mspeed = vlen(mvelocity);
1031
1032         nstyle = cvar("g_projectiles_newton_style");
1033         if(nstyle == 0)
1034         {
1035                 // absolute velocity
1036                 outvelocity = mvelocity;
1037         }
1038         else if(nstyle == 1)
1039         {
1040                 // true Newtonian projectiles
1041                 outvelocity = pvelocity + mvelocity;
1042         }
1043         else if(nstyle == 2)
1044         {
1045                 // true Newtonian projectiles with automatic aim adjustment
1046                 //
1047                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1048                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1049                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1050                 // PLUS SIGN!
1051                 // not defined?
1052                 // then...
1053                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1054                 // velocity without mdirection component > mspeed
1055                 // fire at smallest possible mspeed that works?
1056                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1057
1058                 float D;
1059                 float p;
1060                 float q;
1061                 p = mdirection * pvelocity;
1062                 q = pvelocity * pvelocity - mspeed * mspeed;
1063                 D = p * p - q;
1064                 if(D < 0)
1065                 {
1066                         //dprint("impossible shot, adjusting\n");
1067                         D = 0;
1068                 }
1069                 outspeed = p + sqrt(D);
1070                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1071                 outvelocity = mdirection * outspeed;
1072         }
1073         else if(nstyle == 3)
1074         {
1075                 // pseudo-Newtonian:
1076                 outspeed = mspeed + mdirection * pvelocity;
1077                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1078                 outvelocity = mdirection * outspeed;
1079         }
1080         else if(nstyle == 4)
1081         {
1082                 // tZorkian:
1083                 outspeed = mspeed + vlen(pvelocity);
1084                 outvelocity = mdirection * outspeed;
1085         }
1086         else
1087                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1088
1089         return outvelocity;
1090 }
1091
1092 void W_SetupProjectileVelocity(entity missile)
1093 {
1094         if(missile.owner == world)
1095                 error("Unowned missile");
1096
1097         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, missile.velocity);
1098 }
1099
1100 void W_AttachToShotorg(entity flash, vector offset)
1101 {
1102         entity xflash;
1103         flash.owner = self;
1104         flash.angles_z = random() * 360;
1105         if(qcweaponanimation)
1106         {
1107                 setorigin(flash, w_shotorg + w_shotdir * 50);
1108                 flash.angles = vectoangles(w_shotdir);
1109                 flash.angles_z = random() * 360;
1110         }
1111         else
1112         {
1113                 setattachment(flash, self.weaponentity, "shot");
1114                 setorigin(flash, offset);
1115
1116                 xflash = spawn();
1117                 copyentity(flash, xflash);
1118
1119                 flash.viewmodelforclient = self;
1120
1121                 setattachment(xflash, self.exteriorweaponentity, "");
1122                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1123         }
1124 }