data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39 }
  40
  41 .float antilag_debug;
  42
  43 // VorteX: static frame globals
  44 float WFRAME_DONTCHANGE = -1;
  45 float WFRAME_FIRE1 = 0;
  46 float WFRAME_FIRE2 = 1;
  47 float WFRAME_IDLE = 2;
  48 float WFRAME_RELOAD = 3;
  49 .float wframe;
  50
  51 void(float fr, float t, void() func) weapon_thinkf;
  52
  53 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  54 {
  55         vector ret;
  56         ret_x = screenright * v;
  57         ret_y = screenup * v;
  58         ret_z = screenforward * v;
  59         return ret;
  60 }
  61
  62 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  63 {
  64         float i, j, k;
  65         vector mi, ma, thisv, myv, ret;
  66
  67         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  68
  69         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  70
  71         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  72         {
  73                 thisv = targ.origin;
  74                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  75                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  76                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  77                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  78                 if(i || j || k)
  79                 {
  80                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  81                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  82                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  83                 }
  84                 else
  85                 {
  86                         // first run
  87                         mi = ma = thisv;
  88                 }
  89         }
  90
  91         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  92         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  93         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  94         ret_z = thisv_z - myv_z;
  95         return ret;
  96 }
  97
  98 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  99 {
 100         vector hitplot;
 101         vector org;
 102         float lag;
 103
 104         if(player.hitplotfh >= 0)
 105         {
 106                 lag = ANTILAG_LATENCY(player);
 107                 if(lag < 0.001)
 108                         lag = 0;
 109                 if(clienttype(player) != CLIENTTYPE_REAL)
 110                         lag = 0; // only antilag for clients
 111
 112                 org = player.origin + player.view_ofs;
 113                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 114                 if(trace_ent.flags & FL_CLIENT)
 115                 {
 116                         antilag_takeback(trace_ent, time - lag);
 117                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 118                         antilag_restore(trace_ent);
 119                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 120                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 121                 }
 122         }
 123 }
 124
 125 vector w_shotorg;
 126 vector w_shotdir;
 127
 128 // this function calculates w_shotorg and w_shotdir based on the weapon model
 129 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 130 // make sure you call makevectors first (FIXME?)
 131 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
 132 {
 133         float nudge = 1; // added to traceline target and subtracted from result
 134         local vector trueaimpoint;
 135         local float oldsolid;
 136         vector vecs, dv;
 137         oldsolid = ent.dphitcontentsmask;
 138         if(ent.weapon == WEP_CAMPINGRIFLE)
 139                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 140         else
 141                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 142         if(antilag)
 143                 traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 144                 // passing world, because we do NOT want it to touch dphitcontentsmask
 145         else
 146                 traceline(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
 147         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 148         trueaimpoint = trace_endpos;
 149
 150         // Track max damage and set the stat to be sent later in g_world.qc
 151         if not(inWarmupStage)
 152         {
 153                 ent.max_damage[ent.weapon] += maxdamage;
 154                 ent.maxdamage_fired = ent.weapon + 64 * rint(ent.max_damage[ent.weapon]);
 155         }
 156
 157         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 158
 159         if(ent.weaponentity.movedir_x > 0)
 160         {
 161                 vecs = ent.weaponentity.movedir;
 162                 vecs_y = -vecs_y;
 163         }
 164         else
 165                 vecs = '0 0 0';
 166
 167         if(debug_shotorg != '0 0 0')
 168                 vecs = debug_shotorg;
 169
 170         dv = v_right * vecs_y + v_up * vecs_z;
 171         w_shotorg = ent.origin + ent.view_ofs + dv;
 172
 173         // now move the shotorg forward as much as requested if possible
 174         if(antilag)
 175         {
 176                 if(ent.antilag_debug)
 177                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 178                 else
 179                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 180         }
 181         else
 182                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 183         w_shotorg = trace_endpos - v_forward * nudge;
 184         // calculate the shotdir from the chosen shotorg
 185         w_shotdir = normalize(trueaimpoint - w_shotorg);
 186
 187         if (antilag)
 188         if (!ent.cvar_cl_noantilag)
 189         {
 190                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 191                 {
 192                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 193                         if (!trace_ent.takedamage)
 194                         {
 195                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 196                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 197                                 {
 198                                         entity e;
 199                                         e = trace_ent;
 200                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 201                                         if(trace_ent == e)
 202                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 203                                 }
 204                         }
 205                 }
 206                 else if(cvar("g_antilag") == 3) // client side hitscan
 207                 {
 208                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 209                         if (ent.cursor_trace_ent != ent)         // just to make sure
 210                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 211                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 212                         {
 213                                 // verify that the shot would miss without antilag
 214                                 // (avoids an issue where guns would always shoot at their origin)
 215                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 216                                 if (!trace_ent.takedamage)
 217                                 {
 218                                         // verify that the shot would hit if altered
 219                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 220                                         if (trace_ent == ent.cursor_trace_ent)
 221                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 222                                         else
 223                                                 print("antilag fail\n");
 224                                 }
 225                         }
 226                 }
 227         }
 228
 229         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 230
 231         if (!g_norecoil)
 232                 ent.punchangle_x = recoil * -1;
 233
 234         if (snd != "")
 235         {
 236                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 237         }
 238
 239         if (ent.items & IT_STRENGTH)
 240         if (!g_minstagib)
 241                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 242 };
 243
 244 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 245 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 246 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 247
 248 void LaserTarget_Think()
 249 {
 250         entity e;
 251         vector offset;
 252         float uselaser;
 253         uselaser = 0;
 254
 255         // list of weapons that will use the laser, and the options that enable it
 256         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 257                 uselaser = 1;
 258         // example
 259         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 260         //      uselaser = 1;
 261
 262
 263
 264         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 265         if(!uselaser)
 266         {
 267                 // rocket launcher isn't selected, so no laser target.
 268                 if(self.lasertarget != world)
 269                 {
 270                         remove(self.lasertarget);
 271                         self.lasertarget = world;
 272                 }
 273                 return;
 274         }
 275
 276         if(!self.lasertarget)
 277         {
 278                 // we don't have a lasertarget entity, so spawn one
 279                 //bprint("create laser target\n");
 280                 e = self.lasertarget = spawn();
 281                 e.owner = self.owner;                   // Its owner is my owner
 282                 e.classname = "laser_target";
 283                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 284                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 285                 e.scale = 1.25;                         // make it larger
 286                 e.alpha = 0.25;                         // transparency
 287                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 288                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 289                 // make it dynamically glow
 290                 // you should avoid over-using this, as it can slow down the player's computer.
 291                 e.glow_color = 251; // red color
 292                 e.glow_size = 12;
 293         }
 294         else
 295                 e = self.lasertarget;
 296
 297         // move the laser dot to where the player is looking
 298
 299         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 300         offset = '0 0 26' + v_right*3;
 301         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 302         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 303         if(trace_plane_normal != '0 0 0')
 304                 e.angles = vectoangles(trace_plane_normal);
 305         else
 306                 e.angles = vectoangles(v_forward);
 307 }
 308
 309 float CL_Weaponentity_CustomizeEntityForClient()
 310 {
 311         self.viewmodelforclient = self.owner;
 312         if(other.classname == "spectator")
 313                 if(other.enemy == self.owner)
 314                         self.viewmodelforclient = other;
 315         return TRUE;
 316 }
 317
 318 float qcweaponanimation;
 319 vector weapon_offset = '0 -10 0';
 320 vector weapon_adjust = '10 0 -15';
 321 .vector weapon_morph0origin;
 322 .vector weapon_morph0angles;
 323 .float  weapon_morph0time;
 324 .vector weapon_morph1origin;
 325 .vector weapon_morph1angles;
 326 .float  weapon_morph1time;
 327 .vector weapon_morph2origin;
 328 .vector weapon_morph2angles;
 329 .float  weapon_morph2time;
 330 .vector weapon_morph3origin;
 331 .vector weapon_morph3angles;
 332 .float  weapon_morph3time;
 333 .vector weapon_morph4origin;
 334 .vector weapon_morph4angles;
 335 .float  weapon_morph4time;
 336 .string weaponname;
 337 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 338
 339 /*
 340  * supported formats:
 341  *
 342  * 1. simple animated model, muzzlr flash handling on h_ model:
 343  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 344  *      tags:
 345  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 346  *        shell = casings ejection point (must be on the right hand side of the gun)
 347  *        weapon = attachment for v_tuba.md3
 348  *    v_tuba.md3 - first and third person model
 349  *    g_tuba.md3 - pickup model
 350  *
 351  * 2. fully animated model, muzzle flash handling on h_ model:
 352  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 353  *      tags:
 354  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 355  *        shell = casings ejection point (must be on the right hand side of the gun)
 356  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 357  *    v_tuba.md3 - third person model
 358  *    g_tuba.md3 - pickup model
 359  *
 360  * 3. fully animated model, muzzle flash handling on v_ model:
 361  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 362  *      tags:
 363  *        shot = muzzle end (shot origin)
 364  *        shell = casings ejection point (must be on the right hand side of the gun)
 365  *    v_tuba.md3 - third person model
 366  *      tags:
 367  *        shot = muzzle end (for muzzle flashes)
 368  *    g_tuba.md3 - pickup model
 369  */
 370
 371 void CL_Weaponentity_Think()
 372 {
 373         float tb, v_shot_idx;
 374         self.nextthink = time;
 375         if (intermission_running)
 376                 self.frame = self.anim_idle_x;
 377         if (self.owner.weaponentity != self)
 378         {
 379                 if (self.weaponentity)
 380                         remove(self.weaponentity);
 381                 remove(self);
 382                 return;
 383         }
 384         if (self.owner.deadflag != DEAD_NO)
 385         {
 386                 self.model = "";
 387                 if (self.weaponentity)
 388                         self.weaponentity.model = "";
 389                 return;
 390         }
 391         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 392         {
 393                 self.cnt = self.owner.weapon;
 394                 self.dmg = self.owner.modelindex;
 395                 self.deadflag = self.owner.deadflag;
 396
 397                 string animfilename;
 398                 float animfile;
 399                 if (self.owner.weaponname != "")
 400                 {
 401                         // if there is a child entity, hide it until we're sure we use it
 402                         if (self.weaponentity)
 403                                 self.weaponentity.model = "";
 404                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 405                         v_shot_idx = gettagindex(self, "shot"); // used later
 406
 407                         if(qcweaponanimation)
 408                         {
 409                                 self.angles = '0 0 0';
 410                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 411                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 412                                 self.movedir_x += 32;
 413                                 self.spawnorigin = self.movedir;
 414                                 // oldorigin - not calculated here
 415                         }
 416                         else
 417                         {
 418                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 419                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 420                                 animfile = fopen(animfilename, FILE_READ);
 421                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 422                                 self.anim_fire1  = '0 1 0.01';
 423                                 self.anim_fire2  = '1 1 0.01';
 424                                 self.anim_idle   = '2 1 0.01';
 425                                 self.anim_reload = '3 1 0.01';
 426                                 if (animfile >= 0)
 427                                 {
 428                                         animparseerror = FALSE;
 429                                         self.anim_fire1  = animparseline(animfile);
 430                                         self.anim_fire2  = animparseline(animfile);
 431                                         self.anim_idle   = animparseline(animfile);
 432                                         self.anim_reload = animparseline(animfile);
 433                                         fclose(animfile);
 434                                         if (animparseerror)
 435                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 436                                 }
 437
 438                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 439                                 // if we don't, this is a "real" animated model
 440                                 if(gettagindex(self, "weapon"))
 441                                 {
 442                                         if (!self.weaponentity)
 443                                                 self.weaponentity = spawn();
 444                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 445                                         setattachment(self.weaponentity, self, "weapon");
 446                                 }
 447                                 else
 448                                 {
 449                                         if(self.weaponentity)
 450                                                 remove(self.weaponentity);
 451                                         self.weaponentity = world;
 452                                 }
 453
 454                                 setorigin(self,'0 0 0');
 455                                 self.angles = '0 0 0';
 456                                 self.frame = 0;
 457                                 self.viewmodelforclient = world;
 458
 459                                 float idx;
 460                                 idx = gettagindex(self, "shot");
 461                                 if(idx)
 462                                 {
 463                                         self.movedir = gettaginfo(self, idx);
 464                                 }
 465                                 else
 466                                 {
 467                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 468                                         self.movedir = '0 0 0';
 469                                 }
 470
 471                                 idx = gettagindex(self, "shell");
 472                                 if(idx)
 473                                 {
 474                                         self.spawnorigin = gettaginfo(self, idx);
 475                                 }
 476                                 else
 477                                 {
 478                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 479                                         self.spawnorigin = self.movedir;
 480                                 }
 481
 482                                 if(v_shot_idx)
 483                                 {
 484                                         self.oldorigin = '0 0 0';
 485                                 }
 486                                 else
 487                                 {
 488                                         if(self.weaponentity)
 489                                                 idx = gettagindex(self, "weapon");
 490                                         else
 491                                                 idx = gettagindex(self, "handle");
 492                                         if(idx)
 493                                         {
 494                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 495                                         }
 496                                         else
 497                                         {
 498                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 499                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 500                                         }
 501                                 }
 502
 503                                 self.viewmodelforclient = self.owner;
 504                         }
 505                 }
 506                 else
 507                 {
 508                         self.model = "";
 509                         if(self.weaponentity)
 510                                 remove(self.weaponentity);
 511                         self.weaponentity = world;
 512                         self.movedir = '0 0 0';
 513                         self.spawnorigin = '0 0 0';
 514                         self.oldorigin = '0 0 0';
 515                         self.anim_fire1  = '0 1 0.01';
 516                         self.anim_fire2  = '0 1 0.01';
 517                         self.anim_idle   = '0 1 0.01';
 518                         self.anim_reload = '0 1 0.01';
 519                 }
 520
 521                 self.view_ofs = '0 0 0';
 522
 523                 if(self.movedir_x >= 0)
 524                 {
 525                         vector v0;
 526                         v0 = self.movedir;
 527                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 528                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 529                 }
 530                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 531                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 532
 533                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 534
 535                 // check if an instant weapon switch occurred
 536                 if (qcweaponanimation)
 537                 {
 538                         if (self.state == WS_READY)
 539                         {
 540                                 self.angles = '0 0 0';
 541                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 542                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 543                         }
 544                 }
 545                 else
 546                         setorigin(self, self.view_ofs);
 547                 // reset animstate now
 548                 self.wframe = WFRAME_IDLE;
 549                 self.weapon_morph0time = 0;
 550                 self.weapon_morph1time = 0;
 551                 self.weapon_morph2time = 0;
 552                 self.weapon_morph3time = 0;
 553                 self.weapon_morph4time = 0;
 554                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 555         }
 556
 557         tb = (self.effects & EF_TELEPORT_BIT);
 558         self.effects = self.owner.effects & EFMASK_CHEAP;
 559         self.effects &~= EF_LOWPRECISION;
 560         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 561         self.effects &~= EF_TELEPORT_BIT;
 562         self.effects |= tb;
 563
 564         if(self.owner.alpha == default_player_alpha)
 565                 self.alpha = default_weapon_alpha;
 566         else if(self.owner.alpha != 0)
 567                 self.alpha = self.owner.alpha;
 568         else
 569                 self.alpha = 1;
 570
 571         self.colormap = self.owner.colormap;
 572         if (self.weaponentity)
 573         {
 574                 self.weaponentity.effects = self.effects;
 575                 self.weaponentity.alpha = self.alpha;
 576                 self.weaponentity.colormap = self.colormap;
 577         }
 578
 579         self.angles = '0 0 0';
 580         local float f;
 581         f = 0;
 582         if (self.state == WS_RAISE && !intermission_running)
 583         {
 584                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 585                 self.angles_x = -90 * f * f;
 586                 if (qcweaponanimation)
 587                 {
 588                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 589                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 590                 }
 591         }
 592         else if (self.state == WS_DROP && !intermission_running)
 593         {
 594                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 595                 self.angles_x = -90 * f * f;
 596                 if (qcweaponanimation)
 597                 {
 598                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 599                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 600                 }
 601         }
 602         else if (self.state == WS_CLEAR)
 603         {
 604                 f = 1;
 605                 self.angles_x = -90 * f * f;
 606                 if (qcweaponanimation)
 607                 {
 608                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 609                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 610                 }
 611         }
 612         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 613         {
 614                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 615                 f = 1 - pow(1 - f, 3);
 616                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 617                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 618         }
 619         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 620         {
 621                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 622                 f = 1 - pow(1 - f, 3);
 623                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 624                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 625         }
 626         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 627         {
 628                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 629                 f = 1 - pow(1 - f, 3);
 630                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 631                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 632         }
 633         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 634         {
 635                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 636                 f = 1 - pow(1 - f, 3);
 637                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 638                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 639         }
 640         else if (qcweaponanimation)
 641         {
 642                 // begin a new idle morph
 643                 self.owner.weapon_morph0time   = time;
 644                 self.owner.weapon_morph0angles = self.angles;
 645                 self.owner.weapon_morph0origin = self.origin;
 646
 647                 float r;
 648                 float t;
 649
 650                 r = random();
 651                 if (r < 0.1)
 652                 {
 653                         // turn gun to the left to look at it
 654                         t = 2;
 655                         self.owner.weapon_morph1time   = time + t * 0.2;
 656                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 657                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 658                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 659
 660                         self.owner.weapon_morph2time   = time + t * 0.6;
 661                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 662                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 663                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 664
 665                         self.owner.weapon_morph3time   = time + t;
 666                         self.owner.weapon_morph3angles = '0 0 0';
 667                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 668                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 669                 }
 670                 else if (r < 0.2)
 671                 {
 672                         // raise the gun a bit
 673                         t = 2;
 674                         self.owner.weapon_morph1time   = time + t * 0.2;
 675                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 676                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 677                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 678
 679                         self.owner.weapon_morph2time   = time + t * 0.5;
 680                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 681                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 682                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 683
 684                         self.owner.weapon_morph3time   = time + t;
 685                         self.owner.weapon_morph3angles = '0 0 0';
 686                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 687                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 688                 }
 689                 else if (r < 0.3)
 690                 {
 691                         // tweak it a bit
 692                         t = 5;
 693                         self.owner.weapon_morph1time   = time + t * 0.3;
 694                         self.owner.weapon_morph1angles = randomvec() * 6;
 695                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 696                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 697
 698                         self.owner.weapon_morph2time   = time + t * 0.7;
 699                         self.owner.weapon_morph2angles = randomvec() * 6;
 700                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 701                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 702
 703                         self.owner.weapon_morph3time   = time + t;
 704                         self.owner.weapon_morph3angles = '0 0 0';
 705                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 706                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 707                 }
 708                 else
 709                 {
 710                         // hold it mostly steady
 711                         t = random() * 6 + 4;
 712                         self.owner.weapon_morph1time   = time + t * 0.2;
 713                         self.owner.weapon_morph1angles = randomvec() * 1;
 714                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 715                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 716
 717                         self.owner.weapon_morph2time   = time + t * 0.5;
 718                         self.owner.weapon_morph2angles = randomvec() * 1;
 719                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 720                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 721
 722                         self.owner.weapon_morph3time   = time + t * 0.7;
 723                         self.owner.weapon_morph3angles = randomvec() * 1;
 724                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 725                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 726                 }
 727
 728                 self.owner.weapon_morph4time   = time + t;
 729                 self.owner.weapon_morph4angles = '0 0 0';
 730                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 731                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 732
 733         }
 734
 735         // create or update the lasertarget entity
 736         LaserTarget_Think();
 737 };
 738
 739 void CL_ExteriorWeaponentity_Think()
 740 {
 741         float tag_found;
 742         vector ang;
 743         self.nextthink = time;
 744         if (self.owner.exteriorweaponentity != self)
 745         {
 746                 remove(self);
 747                 return;
 748         }
 749         if (self.owner.deadflag != DEAD_NO)
 750         {
 751                 self.model = "";
 752                 return;
 753         }
 754         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 755         {
 756                 self.cnt = self.owner.weapon;
 757                 self.dmg = self.owner.modelindex;
 758                 self.deadflag = self.owner.deadflag;
 759                 if (self.owner.weaponname != "")
 760                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 761                 else
 762                         self.model = "";
 763
 764                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 765                 {
 766                         self.tag_index = tag_found;
 767                         self.tag_entity = self.owner;
 768                 }
 769                 else
 770                         setattachment(self, self.owner, "bip01 r hand");
 771
 772                 // if that didn't find a tag, hide the exterior weapon model
 773                 if (!self.tag_index)
 774                         self.model = "";
 775         }
 776         self.effects = self.owner.effects | EF_LOWPRECISION;
 777         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 778         if(self.owner.alpha == default_player_alpha)
 779                 self.alpha = default_weapon_alpha;
 780         else if(self.owner.alpha != 0)
 781                 self.alpha = self.owner.alpha;
 782         else
 783                 self.alpha = 1;
 784
 785         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 786         ang_y = 0;
 787         ang_z = 0;
 788
 789         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 790         {
 791                 ang_y = self.owner.v_angle_y;
 792                 makevectors(ang);
 793                 var vector v = v_forward;
 794                 gettaginfo(self.tag_entity, self.tag_index);
 795                 // untransform v according to this coordinate space
 796                 vector w;
 797                 w_x = v_forward * v;
 798                 w_y = -v_right * v;
 799                 w_z = v_up * v;
 800                 self.angles = vectoangles(w);
 801         }
 802         else
 803         {
 804                 ang_x = -/* don't ask */ang_x;
 805                 self.angles = ang;
 806         }
 807
 808         self.colormap = self.owner.colormap;
 809 };
 810
 811 // spawning weaponentity for client
 812 void CL_SpawnWeaponentity()
 813 {
 814         self.weaponentity = spawn();
 815         self.weaponentity.classname = "weaponentity";
 816         self.weaponentity.solid = SOLID_NOT;
 817         self.weaponentity.owner = self;
 818         setmodel(self.weaponentity, ""); // precision set when changed
 819         setorigin(self.weaponentity, '0 0 0');
 820         self.weaponentity.angles = '0 0 0';
 821         self.weaponentity.viewmodelforclient = self;
 822         self.weaponentity.flags = 0;
 823         self.weaponentity.think = CL_Weaponentity_Think;
 824         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 825         self.weaponentity.nextthink = time;
 826
 827         self.exteriorweaponentity = spawn();
 828         self.exteriorweaponentity.classname = "exteriorweaponentity";
 829         self.exteriorweaponentity.solid = SOLID_NOT;
 830         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 831         self.exteriorweaponentity.owner = self;
 832         setorigin(self.exteriorweaponentity, '0 0 0');
 833         self.exteriorweaponentity.angles = '0 0 0';
 834         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 835         self.exteriorweaponentity.nextthink = time;
 836 };
 837
 838 .float hasweapon_complain_spam;
 839
 840 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 841 {
 842         local float weaponbit, f;
 843         local entity oldself;
 844
 845         if(time < self.hasweapon_complain_spam)
 846                 complain = 0;
 847         if(complain)
 848                 self.hasweapon_complain_spam = time + 0.2;
 849
 850         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 851         {
 852                 if (complain)
 853                         sprint(self, "Invalid weapon\n");
 854                 return FALSE;
 855         }
 856         weaponbit = W_WeaponBit(wpn);
 857         if (cl.weapons & weaponbit)
 858         {
 859                 if (andammo)
 860                 {
 861                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 862                         {
 863                                 f = 1;
 864                         }
 865                         else
 866                         {
 867                                 oldself = self;
 868                                 self = cl;
 869                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 870                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 871                                 self = oldself;
 872                         }
 873                         if (!f)
 874                         {
 875                                 if (complain)
 876                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 877                                 {
 878                                         play2(cl, "weapons/unavailable.wav");
 879                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 880                                 }
 881                                 return FALSE;
 882                         }
 883                 }
 884                 return TRUE;
 885         }
 886         if (complain)
 887         {
 888                 // DRESK - 3/16/07
 889                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 890                 if(weaponsInMap & weaponbit)
 891                 {
 892                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 893
 894                         if(cvar("g_showweaponspawns"))
 895                         {
 896                                 entity e;
 897                                 string s;
 898
 899                                 e = get_weaponinfo(wpn);
 900                                 s = e.model2;
 901
 902                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 903                                 {
 904                                         if(e.classname == "droppedweapon")
 905                                                 continue;
 906                                         if not(e.flags & FL_ITEM)
 907                                                 continue;
 908                                         WaypointSprite_Spawn(
 909                                                 s,
 910                                                 1, 0,
 911                                                 world, e.origin,
 912                                                 self, 0,
 913                                                 world, enemy,
 914                                                 0
 915                                         );
 916                                 }
 917                         }
 918                 }
 919                 else
 920                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 921
 922                 play2(cl, "weapons/unavailable.wav");
 923         }
 924         return FALSE;
 925 };
 926
 927 // Weapon subs
 928 void w_clear()
 929 {
 930         if (self.weapon != -1)
 931                 self.weapon = 0;
 932         if (self.weaponentity)
 933         {
 934                 self.weaponentity.state = WS_CLEAR;
 935                 self.weaponentity.effects = 0;
 936         }
 937 };
 938
 939 void w_ready()
 940 {
 941         if (self.weaponentity)
 942                 self.weaponentity.state = WS_READY;
 943         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 944 };
 945
 946 // Setup weapon for client (after this raise frame will be launched)
 947 void weapon_setup(float windex)
 948 {
 949         entity e;
 950         qcweaponanimation = cvar("sv_qcweaponanimation");
 951         e = get_weaponinfo(windex);
 952         self.items &~= IT_AMMO;
 953         self.items = self.items | e.items;
 954
 955         // the two weapon entities will notice this has changed and update their models
 956         self.weapon = windex;
 957         self.weaponname = e.mdl;
 958         self.bulletcounter = 0;
 959 };
 960
 961 // perform weapon to attack (weaponstate and attack_finished check is here)
 962 .float race_penalty;
 963 float weapon_prepareattack(float secondary, float attacktime)
 964 {
 965         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 966         //if all players readied up and the countdown is running
 967         if(time < game_starttime || time < self.race_penalty) {
 968                 return FALSE;
 969         }
 970
 971         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 972         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 973         {
 974                 // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 975                 float w, ww;
 976                 w = W_WeaponBit(self.weapon);
 977                 self.weapons &~= w;
 978                 ww = w_getbestweapon(self);
 979                 self.weapons |= w;
 980                 if(ww)
 981                         W_SwitchWeapon_Force(self, ww);
 982                 return FALSE;
 983         }
 984
 985         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 986                 return FALSE;
 987
 988         // do not even think about shooting if switching
 989         if(self.switchweapon != self.weapon)
 990                 return FALSE;
 991
 992         if(attacktime >= 0)
 993         {
 994                 // don't fire if previous attack is not finished
 995                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 996                         return FALSE;
 997                 // don't fire while changing weapon
 998                 if (self.weaponentity.state != WS_READY)
 999                         return FALSE;
1000         }
1001         self.weaponentity.state = WS_INUSE;
1002
1003         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1004
1005         // if the weapon hasn't been firing continuously, reset the timer
1006         if(attacktime >= 0)
1007         {
1008                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1009                 {
1010                         ATTACK_FINISHED(self) = time;
1011                         //dprint("resetting attack finished to ", ftos(time), "\n");
1012                 }
1013                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1014         }
1015         self.bulletcounter += 1;
1016         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1017         return TRUE;
1018 };
1019
1020 void weapon_thinkf(float fr, float t, void() func)
1021 {
1022         vector a;
1023         vector of, or, ou;
1024         float restartanim;
1025
1026         if(fr == WFRAME_DONTCHANGE)
1027         {
1028                 fr = self.weaponentity.wframe;
1029                 restartanim = FALSE;
1030         }
1031         else if (fr == WFRAME_IDLE)
1032                 restartanim = FALSE;
1033         else
1034                 restartanim = TRUE;
1035
1036         of = v_forward;
1037         or = v_right;
1038         ou = v_up;
1039
1040         if (self.weaponentity)
1041         {
1042                 self.weaponentity.wframe = fr;
1043                 if (qcweaponanimation)
1044                 {
1045                         if (fr != WFRAME_IDLE)
1046                         {
1047                                 self.weapon_morph0time = time;
1048                                 self.weapon_morph0angles = self.weaponentity.angles;
1049                                 self.weapon_morph0origin = self.weaponentity.origin;
1050
1051                                 self.weapon_morph1angles = '0 0 0';
1052                                 self.weapon_morph1time = time + t;
1053                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1054                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1055
1056                                 self.weapon_morph2angles = '0 0 0';
1057                                 self.weapon_morph2time = time + t;
1058                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1059                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1060
1061                                 self.weapon_morph3angles = '0 0 0';
1062                                 self.weapon_morph3time = time + t;
1063                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1064                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1065
1066                                 self.weapon_morph4angles = '0 0 0';
1067                                 self.weapon_morph4time = time + t;
1068                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1069                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1070
1071                                 if (fr == WFRAME_FIRE1)
1072                                 {
1073                                         self.weapon_morph1angles = '5 0 0';
1074                                         self.weapon_morph1time = time + t * 0.1;
1075                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1076                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1077                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1078                                 }
1079                                 else if (fr == WFRAME_FIRE2)
1080                                 {
1081                                         self.weapon_morph1angles = '10 0 0';
1082                                         self.weapon_morph1time = time + t * 0.1;
1083                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1084                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1085                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1086                                 }
1087                                 else if (fr == WFRAME_RELOAD)
1088                                 {
1089                                         self.weapon_morph1time = time + t * 0.05;
1090                                         self.weapon_morph1angles = '-10 40 0';
1091                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1092                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1093
1094                                         self.weapon_morph2time = time + t * 0.15;
1095                                         self.weapon_morph2angles = '-10 40 5';
1096                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1097                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1098
1099                                         self.weapon_morph3time = time + t * 0.25;
1100                                         self.weapon_morph3angles = '-10 40 0';
1101                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1102                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1103                                 }
1104                         }
1105                 }
1106                 else
1107                 {
1108                         if (fr == WFRAME_IDLE)
1109                                 a = self.weaponentity.anim_idle;
1110                         else if (fr == WFRAME_FIRE1)
1111                                 a = self.weaponentity.anim_fire1;
1112                         else if (fr == WFRAME_FIRE2)
1113                                 a = self.weaponentity.anim_fire2;
1114                         else if (fr == WFRAME_RELOAD)
1115                                 a = self.weaponentity.anim_reload;
1116                         a_z *= g_weaponratefactor;
1117                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1118                 }
1119         }
1120
1121         v_forward = of;
1122         v_right = or;
1123         v_up = ou;
1124
1125         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1126         {
1127                 backtrace("Tried to override initial weapon think function - should this really happen?");
1128         }
1129
1130         t *= W_WeaponRateFactor();
1131
1132         // VorteX: haste can be added here
1133         if (self.weapon_think == w_ready)
1134         {
1135                 self.weapon_nextthink = time;
1136                 //dprint("started firing at ", ftos(time), "\n");
1137         }
1138         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1139         {
1140                 self.weapon_nextthink = time;
1141                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1142         }
1143         self.weapon_nextthink = self.weapon_nextthink + t;
1144         self.weapon_think = func;
1145         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1146
1147         if (restartanim)
1148         if (t)
1149         if (!self.crouch) // shoot anim stands up, this looks bad
1150         {
1151                 local vector anim;
1152                 anim = self.anim_shoot;
1153                 anim_z = anim_y / t;
1154                 setanim(self, anim, FALSE, TRUE, TRUE);
1155         }
1156 };
1157
1158 void weapon_boblayer1(float spd, vector org)
1159 {
1160         // VorteX: haste can be added here
1161 };
1162
1163 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1164 {
1165         vector mdirection;
1166         float mspeed;
1167         float outspeed;
1168         float nstyle;
1169         vector outvelocity;
1170
1171         mvelocity = mvelocity * g_weaponspeedfactor;
1172
1173         mdirection = normalize(mvelocity);
1174         mspeed = vlen(mvelocity);
1175
1176         nstyle = cvar("g_projectiles_newton_style");
1177         if(nstyle == 0)
1178         {
1179                 // absolute velocity
1180                 outvelocity = mvelocity;
1181         }
1182         else if(nstyle == 1)
1183         {
1184                 // true Newtonian projectiles
1185                 outvelocity = pvelocity + mvelocity;
1186         }
1187         else if(nstyle == 2)
1188         {
1189                 // true Newtonian projectiles with automatic aim adjustment
1190                 //
1191                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1192                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1193                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1194                 // PLUS SIGN!
1195                 // not defined?
1196                 // then...
1197                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1198                 // velocity without mdirection component > mspeed
1199                 // fire at smallest possible mspeed that works?
1200                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1201
1202                 vector solution;
1203                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1204                 if(solution_z)
1205                         outspeed = solution_y; // the larger one
1206                 else
1207                 {
1208                         //outspeed = 0; // slowest possible shot
1209                         outspeed = solution_x; // the real part (that is, the average!)
1210                         //dprint("impossible shot, adjusting\n");
1211                 }
1212
1213                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1214                 outvelocity = mdirection * outspeed;
1215         }
1216         else if(nstyle == 3)
1217         {
1218                 // pseudo-Newtonian:
1219                 outspeed = mspeed + mdirection * pvelocity;
1220                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1221                 outvelocity = mdirection * outspeed;
1222         }
1223         else if(nstyle == 4)
1224         {
1225                 // tZorkian:
1226                 outspeed = mspeed + vlen(pvelocity);
1227                 outvelocity = mdirection * outspeed;
1228         }
1229         else
1230                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1231
1232         return outvelocity;
1233 }
1234
1235 void W_AttachToShotorg(entity flash, vector offset)
1236 {
1237         entity xflash;
1238         flash.owner = self;
1239         flash.angles_z = random() * 360;
1240         if(qcweaponanimation)
1241         {
1242                 setorigin(flash, w_shotorg + w_shotdir * 50);
1243                 flash.angles = vectoangles(w_shotdir);
1244                 flash.angles_z = random() * 360;
1245         }
1246         else
1247         {
1248                 setattachment(flash, self.weaponentity, "shot");
1249                 setorigin(flash, offset);
1250
1251                 xflash = spawn();
1252                 copyentity(flash, xflash);
1253
1254                 flash.viewmodelforclient = self;
1255
1256                 if(self.weaponentity.oldorigin_x > 0)
1257                 {
1258                         setattachment(xflash, self.exteriorweaponentity, "");
1259                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1260                 }
1261                 else
1262                 {
1263                         setattachment(xflash, self.exteriorweaponentity, "shot");
1264                 }
1265         }
1266 }
1267
1268 vector cliptoplane(vector v, vector p)
1269 {
1270         return v - (v * p) * p;
1271 }
1272
1273 vector solve_cubic_pq(float p, float q)
1274 {
1275         float D, u, v, a;
1276         D = q*q/4.0 + p*p*p/27.0;
1277         if(D < 0)
1278         {
1279                 // irreducibilis
1280                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1281                 u = sqrt(-4.0/3.0 * p);
1282                 // a in range 0..pi/3
1283                 // cos(a)
1284                 // cos(a + 2pi/3)
1285                 // cos(a + 4pi/3)
1286                 return
1287                         u *
1288                         (
1289                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1290                                 +
1291                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1292                                 +
1293                                 '0 0 1' * cos(a)
1294                         );
1295         }
1296         else if(D == 0)
1297         {
1298                 // simple
1299                 if(p == 0)
1300                         return '0 0 0';
1301                 u = 3*q/p;
1302                 v = -u/2;
1303                 if(u >= v)
1304                         return '1 1 0' * v + '0 0 1' * u;
1305                 else
1306                         return '0 1 1' * v + '1 0 0' * u;
1307         }
1308         else
1309         {
1310                 // cardano
1311                 u = cbrt(-q/2.0 + sqrt(D));
1312                 v = cbrt(-q/2.0 - sqrt(D));
1313                 return '1 1 1' * (u + v);
1314         }
1315 }
1316 vector solve_cubic_abcd(float a, float b, float c, float d)
1317 {
1318         // y = 3*a*x + b
1319         // x = (y - b) / 3a
1320         float p, q;
1321         vector v;
1322         p = (9*a*c - 3*b*b);
1323         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1324         v = solve_cubic_pq(p, q);
1325         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1326         if(a < 0)
1327                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1328         return v;
1329 }
1330
1331 vector findperpendicular(vector v)
1332 {
1333         vector p;
1334         p_x = v_z;
1335         p_y = -v_x;
1336         p_z = v_y;
1337         return normalize(cliptoplane(p, v));
1338 }
1339
1340 vector W_CalculateProjectileSpread(vector forward, float spread)
1341 {
1342         float sigma;
1343         vector v1, v2;
1344         float dx, dy, r;
1345         float sstyle;
1346         if(spread <= 0)
1347                 return forward;
1348         sstyle = cvar("g_projectiles_spread_style");
1349
1350         if(sstyle == 0)
1351         {
1352                 // this is the baseline for the spread value!
1353                 // standard deviation: sqrt(2/5)
1354                 // density function: sqrt(1-r^2)
1355                 return forward + randomvec() * spread;
1356         }
1357         else if(sstyle == 1)
1358         {
1359                 // same thing, basically
1360                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1361         }
1362         else if(sstyle == 2)
1363         {
1364                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1365                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1366                 v1 = findperpendicular(forward);
1367                 v2 = cross(forward, v1);
1368                 // random point on unit circle
1369                 dx = random() * 2 * M_PI;
1370                 dy = sin(dx);
1371                 dx = cos(dx);
1372                 // radius in our dist function
1373                 r = random();
1374                 r = sqrt(r);
1375                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1376         }
1377         else if(sstyle == 3) // gauss 3d
1378         {
1379                 sigma = spread * 0.44721359549996; // match baseline stddev
1380                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1381                 v1 = forward;
1382                 v1_x += gsl_ran_gaussian(sigma);
1383                 v1_y += gsl_ran_gaussian(sigma);
1384                 v1_z += gsl_ran_gaussian(sigma);
1385                 return v1;
1386         }
1387         else if(sstyle == 4) // gauss 2d
1388         {
1389                 sigma = spread * 0.44721359549996; // match baseline stddev
1390                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1391                 v1_x = gsl_ran_gaussian(sigma);
1392                 v1_y = gsl_ran_gaussian(sigma);
1393                 v1_z = gsl_ran_gaussian(sigma);
1394                 return normalize(forward + cliptoplane(v1, forward));
1395         }
1396         else if(sstyle == 5) // 1-r
1397         {
1398                 sigma = spread * 1.154700538379252; // match baseline stddev
1399                 v1 = findperpendicular(forward);
1400                 v2 = cross(forward, v1);
1401                 // random point on unit circle
1402                 dx = random() * 2 * M_PI;
1403                 dy = sin(dx);
1404                 dx = cos(dx);
1405                 // radius in our dist function
1406                 r = random();
1407                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1408                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1409         }
1410         else if(sstyle == 6) // 1-r^2
1411         {
1412                 sigma = spread * 1.095445115010332; // match baseline stddev
1413                 v1 = findperpendicular(forward);
1414                 v2 = cross(forward, v1);
1415                 // random point on unit circle
1416                 dx = random() * 2 * M_PI;
1417                 dy = sin(dx);
1418                 dx = cos(dx);
1419                 // radius in our dist function
1420                 r = random();
1421                 r = sqrt(1 - r);
1422                 r = sqrt(1 - r);
1423                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1424         }
1425         else if(sstyle == 7) // (1-r) (2-r)
1426         {
1427                 sigma = spread * 1.224744871391589; // match baseline stddev
1428                 v1 = findperpendicular(forward);
1429                 v2 = cross(forward, v1);
1430                 // random point on unit circle
1431                 dx = random() * 2 * M_PI;
1432                 dy = sin(dx);
1433                 dx = cos(dx);
1434                 // radius in our dist function
1435                 r = random();
1436                 r = 1 - sqrt(r);
1437                 r = 1 - sqrt(r);
1438                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1439         }
1440         else
1441                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1442         return '0 0 0';
1443         /*
1444          * how to derive falloff functions:
1445          * rho(r) := (2-r) * (1-r);
1446          * a : 0;
1447          * b : 1;
1448          * rhor(r) := r * rho(r);
1449          * cr(t) := integrate(rhor(r), r, a, t);
1450          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1451          * variance : scr(b) / cr(b);
1452          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1453          * sqrt(0.4 / variance), numer;
1454          */
1455 }
1456
1457 #if 0
1458 float mspercallsum;
1459 float mspercallsstyle;
1460 float mspercallcount;
1461 #endif
1462 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float spread)
1463 {
1464         if(missile.owner == world)
1465                 error("Unowned missile");
1466
1467         dir = dir + upDir * (pUpSpeed / pSpeed);
1468         pSpeed *= vlen(dir);
1469         dir = normalize(dir);
1470
1471 #if 0
1472         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1473         {
1474                 mspercallsum = mspercallcount = 0;
1475                 mspercallsstyle = cvar("g_projectiles_spread_style");
1476         }
1477         mspercallsum -= gettime(GETTIME_HIRES);
1478         dir = W_CalculateProjectileSpread(dir, spread);
1479         mspercallsum += gettime(GETTIME_HIRES);
1480         mspercallcount += 1;
1481         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1482 #endif
1483
1484         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1485 }
1486
1487 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1488 {
1489         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, spread);
1490 }
1491
1492 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_spread"))
1493 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, cvar(#s "_spread"))