data/qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39 }
  40
  41 .float antilag_debug;
  42
  43 // VorteX: static frame globals
  44 float WFRAME_DONTCHANGE = -1;
  45 float WFRAME_FIRE1 = 0;
  46 float WFRAME_FIRE2 = 1;
  47 float WFRAME_IDLE = 2;
  48 float WFRAME_RELOAD = 3;
  49 .float wframe;
  50
  51 void(float fr, float t, void() func) weapon_thinkf;
  52
  53 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  54 {
  55         vector ret;
  56         ret_x = screenright * v;
  57         ret_y = screenup * v;
  58         ret_z = screenforward * v;
  59         return ret;
  60 }
  61
  62 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  63 {
  64         float i, j, k;
  65         vector mi, ma, thisv, myv, ret;
  66
  67         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  68
  69         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  70
  71         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  72         {
  73                 thisv = targ.origin;
  74                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  75                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  76                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  77                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  78                 if(i || j || k)
  79                 {
  80                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  81                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  82                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  83                 }
  84                 else
  85                 {
  86                         // first run
  87                         mi = ma = thisv;
  88                 }
  89         }
  90
  91         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  92         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  93         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  94         ret_z = thisv_z - myv_z;
  95         return ret;
  96 }
  97
  98 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
  99 {
 100         vector hitplot;
 101         vector org;
 102         float lag;
 103
 104         if(player.hitplotfh >= 0)
 105         {
 106                 lag = ANTILAG_LATENCY(player);
 107                 if(lag < 0.001)
 108                         lag = 0;
 109                 if(clienttype(player) != CLIENTTYPE_REAL)
 110                         lag = 0; // only antilag for clients
 111
 112                 org = player.origin + player.view_ofs;
 113                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 114                 if(trace_ent.flags & FL_CLIENT)
 115                 {
 116                         antilag_takeback(trace_ent, time - lag);
 117                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 118                         antilag_restore(trace_ent);
 119                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 120                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 121                 }
 122         }
 123 }
 124
 125 vector w_shotorg;
 126 vector w_shotdir;
 127
 128 // this function calculates w_shotorg and w_shotdir based on the weapon model
 129 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 130 // make sure you call makevectors first (FIXME?)
 131 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
 132 {
 133         float nudge = 1; // added to traceline target and subtracted from result
 134         local vector trueaimpoint;
 135         local float oldsolid;
 136         vector vecs, dv;
 137         oldsolid = ent.dphitcontentsmask;
 138         if(ent.weapon == WEP_CAMPINGRIFLE)
 139                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 140         else
 141                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 142         if(antilag)
 143                 traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 144                 // passing world, because we do NOT want it to touch dphitcontentsmask
 145         else
 146                 traceline(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
 147         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 148         trueaimpoint = trace_endpos;
 149
 150         // track max damage
 151         if not(inWarmupStage) {
 152                 entity w;
 153                 w = get_weaponinfo(ent.weapon);
 154                 if(w.weapon_type == WEP_TYPE_SPLASH) {  // splash damage
 155                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 156                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 157                 }
 158         }
 159
 160         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 161
 162         if(ent.weaponentity.movedir_x > 0)
 163         {
 164                 vecs = ent.weaponentity.movedir;
 165                 vecs_y = -vecs_y;
 166         }
 167         else
 168                 vecs = '0 0 0';
 169
 170         if(debug_shotorg != '0 0 0')
 171                 vecs = debug_shotorg;
 172
 173         dv = v_right * vecs_y + v_up * vecs_z;
 174         w_shotorg = ent.origin + ent.view_ofs + dv;
 175
 176         // now move the shotorg forward as much as requested if possible
 177         if(antilag)
 178         {
 179                 if(ent.antilag_debug)
 180                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 181                 else
 182                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 183         }
 184         else
 185                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 186         w_shotorg = trace_endpos - v_forward * nudge;
 187         // calculate the shotdir from the chosen shotorg
 188         w_shotdir = normalize(trueaimpoint - w_shotorg);
 189
 190         if (antilag)
 191         if (!ent.cvar_cl_noantilag)
 192         {
 193                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 194                 {
 195                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 196                         if (!trace_ent.takedamage)
 197                         {
 198                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 199                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 200                                 {
 201                                         entity e;
 202                                         e = trace_ent;
 203                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 204                                         if(trace_ent == e)
 205                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 206                                 }
 207                         }
 208                 }
 209                 else if(cvar("g_antilag") == 3) // client side hitscan
 210                 {
 211                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 212                         if (ent.cursor_trace_ent != ent)         // just to make sure
 213                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 214                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 215                         {
 216                                 // verify that the shot would miss without antilag
 217                                 // (avoids an issue where guns would always shoot at their origin)
 218                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 219                                 if (!trace_ent.takedamage)
 220                                 {
 221                                         // verify that the shot would hit if altered
 222                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 223                                         if (trace_ent == ent.cursor_trace_ent)
 224                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 225                                         else
 226                                                 print("antilag fail\n");
 227                                 }
 228                         }
 229                 }
 230         }
 231
 232         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 233
 234         if (!g_norecoil)
 235                 ent.punchangle_x = recoil * -1;
 236
 237         if (snd != "")
 238         {
 239                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 240         }
 241
 242         if (ent.items & IT_STRENGTH)
 243         if (!g_minstagib)
 244                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 245 };
 246
 247 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 248 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 249 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 250
 251 void LaserTarget_Think()
 252 {
 253         entity e;
 254         vector offset;
 255         float uselaser;
 256         uselaser = 0;
 257
 258         // list of weapons that will use the laser, and the options that enable it
 259         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 260                 uselaser = 1;
 261         // example
 262         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 263         //      uselaser = 1;
 264
 265
 266
 267         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 268         if(!uselaser)
 269         {
 270                 // rocket launcher isn't selected, so no laser target.
 271                 if(self.lasertarget != world)
 272                 {
 273                         remove(self.lasertarget);
 274                         self.lasertarget = world;
 275                 }
 276                 return;
 277         }
 278
 279         if(!self.lasertarget)
 280         {
 281                 // we don't have a lasertarget entity, so spawn one
 282                 //bprint("create laser target\n");
 283                 e = self.lasertarget = spawn();
 284                 e.owner = self.owner;                   // Its owner is my owner
 285                 e.classname = "laser_target";
 286                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 287                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 288                 e.scale = 1.25;                         // make it larger
 289                 e.alpha = 0.25;                         // transparency
 290                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 291                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 292                 // make it dynamically glow
 293                 // you should avoid over-using this, as it can slow down the player's computer.
 294                 e.glow_color = 251; // red color
 295                 e.glow_size = 12;
 296         }
 297         else
 298                 e = self.lasertarget;
 299
 300         // move the laser dot to where the player is looking
 301
 302         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 303         offset = '0 0 26' + v_right*3;
 304         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 305         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 306         if(trace_plane_normal != '0 0 0')
 307                 e.angles = vectoangles(trace_plane_normal);
 308         else
 309                 e.angles = vectoangles(v_forward);
 310 }
 311
 312 float CL_Weaponentity_CustomizeEntityForClient()
 313 {
 314         self.viewmodelforclient = self.owner;
 315         if(other.classname == "spectator")
 316                 if(other.enemy == self.owner)
 317                         self.viewmodelforclient = other;
 318         return TRUE;
 319 }
 320
 321 float qcweaponanimation;
 322 vector weapon_offset = '0 -10 0';
 323 vector weapon_adjust = '10 0 -15';
 324 .vector weapon_morph0origin;
 325 .vector weapon_morph0angles;
 326 .float  weapon_morph0time;
 327 .vector weapon_morph1origin;
 328 .vector weapon_morph1angles;
 329 .float  weapon_morph1time;
 330 .vector weapon_morph2origin;
 331 .vector weapon_morph2angles;
 332 .float  weapon_morph2time;
 333 .vector weapon_morph3origin;
 334 .vector weapon_morph3angles;
 335 .float  weapon_morph3time;
 336 .vector weapon_morph4origin;
 337 .vector weapon_morph4angles;
 338 .float  weapon_morph4time;
 339 .string weaponname;
 340 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 341
 342 /*
 343  * supported formats:
 344  *
 345  * 1. simple animated model, muzzlr flash handling on h_ model:
 346  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 347  *      tags:
 348  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 349  *        shell = casings ejection point (must be on the right hand side of the gun)
 350  *        weapon = attachment for v_tuba.md3
 351  *    v_tuba.md3 - first and third person model
 352  *    g_tuba.md3 - pickup model
 353  *
 354  * 2. fully animated model, muzzle flash handling on h_ model:
 355  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 360  *    v_tuba.md3 - third person model
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 3. fully animated model, muzzle flash handling on v_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 365  *      tags:
 366  *        shot = muzzle end (shot origin)
 367  *        shell = casings ejection point (must be on the right hand side of the gun)
 368  *    v_tuba.md3 - third person model
 369  *      tags:
 370  *        shot = muzzle end (for muzzle flashes)
 371  *    g_tuba.md3 - pickup model
 372  */
 373
 374 void CL_Weaponentity_Think()
 375 {
 376         float tb, v_shot_idx;
 377         self.nextthink = time;
 378         if (intermission_running)
 379                 self.frame = self.anim_idle_x;
 380         if (self.owner.weaponentity != self)
 381         {
 382                 if (self.weaponentity)
 383                         remove(self.weaponentity);
 384                 remove(self);
 385                 return;
 386         }
 387         if (self.owner.deadflag != DEAD_NO)
 388         {
 389                 self.model = "";
 390                 if (self.weaponentity)
 391                         self.weaponentity.model = "";
 392                 return;
 393         }
 394         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 395         {
 396                 self.cnt = self.owner.weapon;
 397                 self.dmg = self.owner.modelindex;
 398                 self.deadflag = self.owner.deadflag;
 399
 400                 string animfilename;
 401                 float animfile;
 402                 if (self.owner.weaponname != "")
 403                 {
 404                         // if there is a child entity, hide it until we're sure we use it
 405                         if (self.weaponentity)
 406                                 self.weaponentity.model = "";
 407                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 408                         v_shot_idx = gettagindex(self, "shot"); // used later
 409
 410                         if(qcweaponanimation)
 411                         {
 412                                 self.angles = '0 0 0';
 413                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 414                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 415                                 self.movedir_x += 32;
 416                                 self.spawnorigin = self.movedir;
 417                                 // oldorigin - not calculated here
 418                         }
 419                         else
 420                         {
 421                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".dpm")); // precision set below
 422                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".dpm.animinfo");
 423                                 animfile = fopen(animfilename, FILE_READ);
 424                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 425                                 self.anim_fire1  = '0 1 0.01';
 426                                 self.anim_fire2  = '1 1 0.01';
 427                                 self.anim_idle   = '2 1 0.01';
 428                                 self.anim_reload = '3 1 0.01';
 429                                 if (animfile >= 0)
 430                                 {
 431                                         animparseerror = FALSE;
 432                                         self.anim_fire1  = animparseline(animfile);
 433                                         self.anim_fire2  = animparseline(animfile);
 434                                         self.anim_idle   = animparseline(animfile);
 435                                         self.anim_reload = animparseline(animfile);
 436                                         fclose(animfile);
 437                                         if (animparseerror)
 438                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
 439                                 }
 440
 441                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 442                                 // if we don't, this is a "real" animated model
 443                                 if(gettagindex(self, "weapon"))
 444                                 {
 445                                         if (!self.weaponentity)
 446                                                 self.weaponentity = spawn();
 447                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
 448                                         setattachment(self.weaponentity, self, "weapon");
 449                                 }
 450                                 else
 451                                 {
 452                                         if(self.weaponentity)
 453                                                 remove(self.weaponentity);
 454                                         self.weaponentity = world;
 455                                 }
 456
 457                                 setorigin(self,'0 0 0');
 458                                 self.angles = '0 0 0';
 459                                 self.frame = 0;
 460                                 self.viewmodelforclient = world;
 461
 462                                 float idx;
 463                                 idx = gettagindex(self, "shot");
 464                                 if(idx)
 465                                 {
 466                                         self.movedir = gettaginfo(self, idx);
 467                                 }
 468                                 else
 469                                 {
 470                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 471                                         self.movedir = '0 0 0';
 472                                 }
 473
 474                                 idx = gettagindex(self, "shell");
 475                                 if(idx)
 476                                 {
 477                                         self.spawnorigin = gettaginfo(self, idx);
 478                                 }
 479                                 else
 480                                 {
 481                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 482                                         self.spawnorigin = self.movedir;
 483                                 }
 484
 485                                 if(v_shot_idx)
 486                                 {
 487                                         self.oldorigin = '0 0 0';
 488                                 }
 489                                 else
 490                                 {
 491                                         if(self.weaponentity)
 492                                                 idx = gettagindex(self, "weapon");
 493                                         else
 494                                                 idx = gettagindex(self, "handle");
 495                                         if(idx)
 496                                         {
 497                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
 498                                         }
 499                                         else
 500                                         {
 501                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 502                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
 503                                         }
 504                                 }
 505
 506                                 self.viewmodelforclient = self.owner;
 507                         }
 508                 }
 509                 else
 510                 {
 511                         self.model = "";
 512                         if(self.weaponentity)
 513                                 remove(self.weaponentity);
 514                         self.weaponentity = world;
 515                         self.movedir = '0 0 0';
 516                         self.spawnorigin = '0 0 0';
 517                         self.oldorigin = '0 0 0';
 518                         self.anim_fire1  = '0 1 0.01';
 519                         self.anim_fire2  = '0 1 0.01';
 520                         self.anim_idle   = '0 1 0.01';
 521                         self.anim_reload = '0 1 0.01';
 522                 }
 523
 524                 self.view_ofs = '0 0 0';
 525
 526                 if(self.movedir_x >= 0)
 527                 {
 528                         vector v0;
 529                         v0 = self.movedir;
 530                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 531                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 532                 }
 533                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 534                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 535
 536                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 537
 538                 // check if an instant weapon switch occurred
 539                 if (qcweaponanimation)
 540                 {
 541                         if (self.state == WS_READY)
 542                         {
 543                                 self.angles = '0 0 0';
 544                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 545                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 546                         }
 547                 }
 548                 else
 549                         setorigin(self, self.view_ofs);
 550                 // reset animstate now
 551                 self.wframe = WFRAME_IDLE;
 552                 self.weapon_morph0time = 0;
 553                 self.weapon_morph1time = 0;
 554                 self.weapon_morph2time = 0;
 555                 self.weapon_morph3time = 0;
 556                 self.weapon_morph4time = 0;
 557                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 558         }
 559
 560         tb = (self.effects & EF_TELEPORT_BIT);
 561         self.effects = self.owner.effects & EFMASK_CHEAP;
 562         self.effects &~= EF_LOWPRECISION;
 563         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 564         self.effects &~= EF_TELEPORT_BIT;
 565         self.effects |= tb;
 566
 567         if(self.owner.alpha == default_player_alpha)
 568                 self.alpha = default_weapon_alpha;
 569         else if(self.owner.alpha != 0)
 570                 self.alpha = self.owner.alpha;
 571         else
 572                 self.alpha = 1;
 573
 574         self.colormap = self.owner.colormap;
 575         if (self.weaponentity)
 576         {
 577                 self.weaponentity.effects = self.effects;
 578                 self.weaponentity.alpha = self.alpha;
 579                 self.weaponentity.colormap = self.colormap;
 580         }
 581
 582         self.angles = '0 0 0';
 583         local float f;
 584         f = 0;
 585         if (self.state == WS_RAISE && !intermission_running)
 586         {
 587                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 588                 self.angles_x = -90 * f * f;
 589                 if (qcweaponanimation)
 590                 {
 591                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 592                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 593                 }
 594         }
 595         else if (self.state == WS_DROP && !intermission_running)
 596         {
 597                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 598                 self.angles_x = -90 * f * f;
 599                 if (qcweaponanimation)
 600                 {
 601                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 602                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 603                 }
 604         }
 605         else if (self.state == WS_CLEAR)
 606         {
 607                 f = 1;
 608                 self.angles_x = -90 * f * f;
 609                 if (qcweaponanimation)
 610                 {
 611                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 612                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 613                 }
 614         }
 615         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 616         {
 617                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 618                 f = 1 - pow(1 - f, 3);
 619                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 620                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 621         }
 622         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 623         {
 624                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 625                 f = 1 - pow(1 - f, 3);
 626                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 627                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 628         }
 629         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 630         {
 631                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 632                 f = 1 - pow(1 - f, 3);
 633                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 634                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 635         }
 636         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 637         {
 638                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 639                 f = 1 - pow(1 - f, 3);
 640                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 641                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 642         }
 643         else if (qcweaponanimation)
 644         {
 645                 // begin a new idle morph
 646                 self.owner.weapon_morph0time   = time;
 647                 self.owner.weapon_morph0angles = self.angles;
 648                 self.owner.weapon_morph0origin = self.origin;
 649
 650                 float r;
 651                 float t;
 652
 653                 r = random();
 654                 if (r < 0.1)
 655                 {
 656                         // turn gun to the left to look at it
 657                         t = 2;
 658                         self.owner.weapon_morph1time   = time + t * 0.2;
 659                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 660                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 661                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 662
 663                         self.owner.weapon_morph2time   = time + t * 0.6;
 664                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 665                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 666                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 667
 668                         self.owner.weapon_morph3time   = time + t;
 669                         self.owner.weapon_morph3angles = '0 0 0';
 670                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 671                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 672                 }
 673                 else if (r < 0.2)
 674                 {
 675                         // raise the gun a bit
 676                         t = 2;
 677                         self.owner.weapon_morph1time   = time + t * 0.2;
 678                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 679                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 680                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 681
 682                         self.owner.weapon_morph2time   = time + t * 0.5;
 683                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 684                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 685                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 686
 687                         self.owner.weapon_morph3time   = time + t;
 688                         self.owner.weapon_morph3angles = '0 0 0';
 689                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 690                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 691                 }
 692                 else if (r < 0.3)
 693                 {
 694                         // tweak it a bit
 695                         t = 5;
 696                         self.owner.weapon_morph1time   = time + t * 0.3;
 697                         self.owner.weapon_morph1angles = randomvec() * 6;
 698                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 699                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 700
 701                         self.owner.weapon_morph2time   = time + t * 0.7;
 702                         self.owner.weapon_morph2angles = randomvec() * 6;
 703                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 704                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 705
 706                         self.owner.weapon_morph3time   = time + t;
 707                         self.owner.weapon_morph3angles = '0 0 0';
 708                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 709                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 710                 }
 711                 else
 712                 {
 713                         // hold it mostly steady
 714                         t = random() * 6 + 4;
 715                         self.owner.weapon_morph1time   = time + t * 0.2;
 716                         self.owner.weapon_morph1angles = randomvec() * 1;
 717                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 718                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 719
 720                         self.owner.weapon_morph2time   = time + t * 0.5;
 721                         self.owner.weapon_morph2angles = randomvec() * 1;
 722                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 723                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 724
 725                         self.owner.weapon_morph3time   = time + t * 0.7;
 726                         self.owner.weapon_morph3angles = randomvec() * 1;
 727                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 728                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 729                 }
 730
 731                 self.owner.weapon_morph4time   = time + t;
 732                 self.owner.weapon_morph4angles = '0 0 0';
 733                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 734                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 735
 736         }
 737
 738         // create or update the lasertarget entity
 739         LaserTarget_Think();
 740 };
 741
 742 void CL_ExteriorWeaponentity_Think()
 743 {
 744         float tag_found;
 745         vector ang;
 746         self.nextthink = time;
 747         if (self.owner.exteriorweaponentity != self)
 748         {
 749                 remove(self);
 750                 return;
 751         }
 752         if (self.owner.deadflag != DEAD_NO)
 753         {
 754                 self.model = "";
 755                 return;
 756         }
 757         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 758         {
 759                 self.cnt = self.owner.weapon;
 760                 self.dmg = self.owner.modelindex;
 761                 self.deadflag = self.owner.deadflag;
 762                 if (self.owner.weaponname != "")
 763                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 764                 else
 765                         self.model = "";
 766
 767                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 768                 {
 769                         self.tag_index = tag_found;
 770                         self.tag_entity = self.owner;
 771                 }
 772                 else
 773                         setattachment(self, self.owner, "bip01 r hand");
 774
 775                 // if that didn't find a tag, hide the exterior weapon model
 776                 if (!self.tag_index)
 777                         self.model = "";
 778         }
 779         self.effects = self.owner.effects | EF_LOWPRECISION;
 780         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 781         if(self.owner.alpha == default_player_alpha)
 782                 self.alpha = default_weapon_alpha;
 783         else if(self.owner.alpha != 0)
 784                 self.alpha = self.owner.alpha;
 785         else
 786                 self.alpha = 1;
 787
 788         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 789         ang_y = 0;
 790         ang_z = 0;
 791
 792         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 793         {
 794                 ang_y = self.owner.v_angle_y;
 795                 makevectors(ang);
 796                 var vector v = v_forward;
 797                 gettaginfo(self.tag_entity, self.tag_index);
 798                 // untransform v according to this coordinate space
 799                 vector w;
 800                 w_x = v_forward * v;
 801                 w_y = -v_right * v;
 802                 w_z = v_up * v;
 803                 self.angles = vectoangles(w);
 804         }
 805         else
 806         {
 807                 ang_x = -/* don't ask */ang_x;
 808                 self.angles = ang;
 809         }
 810
 811         self.colormap = self.owner.colormap;
 812 };
 813
 814 // spawning weaponentity for client
 815 void CL_SpawnWeaponentity()
 816 {
 817         self.weaponentity = spawn();
 818         self.weaponentity.classname = "weaponentity";
 819         self.weaponentity.solid = SOLID_NOT;
 820         self.weaponentity.owner = self;
 821         setmodel(self.weaponentity, ""); // precision set when changed
 822         setorigin(self.weaponentity, '0 0 0');
 823         self.weaponentity.angles = '0 0 0';
 824         self.weaponentity.viewmodelforclient = self;
 825         self.weaponentity.flags = 0;
 826         self.weaponentity.think = CL_Weaponentity_Think;
 827         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 828         self.weaponentity.nextthink = time;
 829
 830         self.exteriorweaponentity = spawn();
 831         self.exteriorweaponentity.classname = "exteriorweaponentity";
 832         self.exteriorweaponentity.solid = SOLID_NOT;
 833         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 834         self.exteriorweaponentity.owner = self;
 835         setorigin(self.exteriorweaponentity, '0 0 0');
 836         self.exteriorweaponentity.angles = '0 0 0';
 837         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 838         self.exteriorweaponentity.nextthink = time;
 839 };
 840
 841 .float hasweapon_complain_spam;
 842
 843 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 844 {
 845         local float weaponbit, f;
 846         local entity oldself;
 847
 848         if(time < self.hasweapon_complain_spam)
 849                 complain = 0;
 850         if(complain)
 851                 self.hasweapon_complain_spam = time + 0.2;
 852
 853         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 854         {
 855                 if (complain)
 856                         sprint(self, "Invalid weapon\n");
 857                 return FALSE;
 858         }
 859         weaponbit = W_WeaponBit(wpn);
 860         if (cl.weapons & weaponbit)
 861         {
 862                 if (andammo)
 863                 {
 864                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 865                         {
 866                                 f = 1;
 867                         }
 868                         else
 869                         {
 870                                 oldself = self;
 871                                 self = cl;
 872                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 873                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 874                                 self = oldself;
 875                         }
 876                         if (!f)
 877                         {
 878                                 if (complain)
 879                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 880                                 {
 881                                         play2(cl, "weapons/unavailable.wav");
 882                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 883                                 }
 884                                 return FALSE;
 885                         }
 886                 }
 887                 return TRUE;
 888         }
 889         if (complain)
 890         {
 891                 // DRESK - 3/16/07
 892                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 893                 if(weaponsInMap & weaponbit)
 894                 {
 895                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 896
 897                         if(cvar("g_showweaponspawns"))
 898                         {
 899                                 entity e;
 900                                 string s;
 901
 902                                 e = get_weaponinfo(wpn);
 903                                 s = e.model2;
 904
 905                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 906                                 {
 907                                         if(e.classname == "droppedweapon")
 908                                                 continue;
 909                                         if not(e.flags & FL_ITEM)
 910                                                 continue;
 911                                         WaypointSprite_Spawn(
 912                                                 s,
 913                                                 1, 0,
 914                                                 world, e.origin,
 915                                                 self, 0,
 916                                                 world, enemy,
 917                                                 0
 918                                         );
 919                                 }
 920                         }
 921                 }
 922                 else
 923                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 924
 925                 play2(cl, "weapons/unavailable.wav");
 926         }
 927         return FALSE;
 928 };
 929
 930 // Weapon subs
 931 void w_clear()
 932 {
 933         if (self.weapon != -1)
 934                 self.weapon = 0;
 935         if (self.weaponentity)
 936         {
 937                 self.weaponentity.state = WS_CLEAR;
 938                 self.weaponentity.effects = 0;
 939         }
 940 };
 941
 942 void w_ready()
 943 {
 944         if (self.weaponentity)
 945                 self.weaponentity.state = WS_READY;
 946         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
 947 };
 948
 949 // Setup weapon for client (after this raise frame will be launched)
 950 void weapon_setup(float windex)
 951 {
 952         entity e;
 953         qcweaponanimation = cvar("sv_qcweaponanimation");
 954         e = get_weaponinfo(windex);
 955         self.items &~= IT_AMMO;
 956         self.items = self.items | e.items;
 957
 958         // the two weapon entities will notice this has changed and update their models
 959         self.weapon = windex;
 960         self.weaponname = e.mdl;
 961         self.bulletcounter = 0;
 962 };
 963
 964 // perform weapon to attack (weaponstate and attack_finished check is here)
 965 .float race_penalty;
 966 float weapon_prepareattack(float secondary, float attacktime)
 967 {
 968         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 969         //if all players readied up and the countdown is running
 970         if(time < game_starttime || time < self.race_penalty) {
 971                 return FALSE;
 972         }
 973
 974         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 975         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
 976         {
 977                 // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 978                 float w, ww;
 979                 w = W_WeaponBit(self.weapon);
 980                 self.weapons &~= w;
 981                 ww = w_getbestweapon(self);
 982                 self.weapons |= w;
 983                 if(ww)
 984                         W_SwitchWeapon_Force(self, ww);
 985                 return FALSE;
 986         }
 987
 988         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
 989                 return FALSE;
 990
 991         // do not even think about shooting if switching
 992         if(self.switchweapon != self.weapon)
 993                 return FALSE;
 994
 995         if(attacktime >= 0)
 996         {
 997                 // don't fire if previous attack is not finished
 998                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
 999                         return FALSE;
1000                 // don't fire while changing weapon
1001                 if (self.weaponentity.state != WS_READY)
1002                         return FALSE;
1003         }
1004         self.weaponentity.state = WS_INUSE;
1005
1006         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1007
1008         // if the weapon hasn't been firing continuously, reset the timer
1009         if(attacktime >= 0)
1010         {
1011                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1012                 {
1013                         ATTACK_FINISHED(self) = time;
1014                         //dprint("resetting attack finished to ", ftos(time), "\n");
1015                 }
1016                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1017         }
1018         self.bulletcounter += 1;
1019         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1020         return TRUE;
1021 };
1022
1023 void weapon_thinkf(float fr, float t, void() func)
1024 {
1025         vector a;
1026         vector of, or, ou;
1027         float restartanim;
1028
1029         if(fr == WFRAME_DONTCHANGE)
1030         {
1031                 fr = self.weaponentity.wframe;
1032                 restartanim = FALSE;
1033         }
1034         else if (fr == WFRAME_IDLE)
1035                 restartanim = FALSE;
1036         else
1037                 restartanim = TRUE;
1038
1039         of = v_forward;
1040         or = v_right;
1041         ou = v_up;
1042
1043         if (self.weaponentity)
1044         {
1045                 self.weaponentity.wframe = fr;
1046                 if (qcweaponanimation)
1047                 {
1048                         if (fr != WFRAME_IDLE)
1049                         {
1050                                 self.weapon_morph0time = time;
1051                                 self.weapon_morph0angles = self.weaponentity.angles;
1052                                 self.weapon_morph0origin = self.weaponentity.origin;
1053
1054                                 self.weapon_morph1angles = '0 0 0';
1055                                 self.weapon_morph1time = time + t;
1056                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1057                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1058
1059                                 self.weapon_morph2angles = '0 0 0';
1060                                 self.weapon_morph2time = time + t;
1061                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1062                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1063
1064                                 self.weapon_morph3angles = '0 0 0';
1065                                 self.weapon_morph3time = time + t;
1066                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1067                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1068
1069                                 self.weapon_morph4angles = '0 0 0';
1070                                 self.weapon_morph4time = time + t;
1071                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1072                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1073
1074                                 if (fr == WFRAME_FIRE1)
1075                                 {
1076                                         self.weapon_morph1angles = '5 0 0';
1077                                         self.weapon_morph1time = time + t * 0.1;
1078                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1079                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1080                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1081                                 }
1082                                 else if (fr == WFRAME_FIRE2)
1083                                 {
1084                                         self.weapon_morph1angles = '10 0 0';
1085                                         self.weapon_morph1time = time + t * 0.1;
1086                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1087                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1088                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1089                                 }
1090                                 else if (fr == WFRAME_RELOAD)
1091                                 {
1092                                         self.weapon_morph1time = time + t * 0.05;
1093                                         self.weapon_morph1angles = '-10 40 0';
1094                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1095                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1096
1097                                         self.weapon_morph2time = time + t * 0.15;
1098                                         self.weapon_morph2angles = '-10 40 5';
1099                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1100                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1101
1102                                         self.weapon_morph3time = time + t * 0.25;
1103                                         self.weapon_morph3angles = '-10 40 0';
1104                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1105                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1106                                 }
1107                         }
1108                 }
1109                 else
1110                 {
1111                         if (fr == WFRAME_IDLE)
1112                                 a = self.weaponentity.anim_idle;
1113                         else if (fr == WFRAME_FIRE1)
1114                                 a = self.weaponentity.anim_fire1;
1115                         else if (fr == WFRAME_FIRE2)
1116                                 a = self.weaponentity.anim_fire2;
1117                         else if (fr == WFRAME_RELOAD)
1118                                 a = self.weaponentity.anim_reload;
1119                         a_z *= g_weaponratefactor;
1120                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1121                 }
1122         }
1123
1124         v_forward = of;
1125         v_right = or;
1126         v_up = ou;
1127
1128         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1129         {
1130                 backtrace("Tried to override initial weapon think function - should this really happen?");
1131         }
1132
1133         t *= W_WeaponRateFactor();
1134
1135         // VorteX: haste can be added here
1136         if (self.weapon_think == w_ready)
1137         {
1138                 self.weapon_nextthink = time;
1139                 //dprint("started firing at ", ftos(time), "\n");
1140         }
1141         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1142         {
1143                 self.weapon_nextthink = time;
1144                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1145         }
1146         self.weapon_nextthink = self.weapon_nextthink + t;
1147         self.weapon_think = func;
1148         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1149
1150         if (restartanim)
1151         if (t)
1152         if (!self.crouch) // shoot anim stands up, this looks bad
1153         {
1154                 local vector anim;
1155                 anim = self.anim_shoot;
1156                 anim_z = anim_y / t;
1157                 setanim(self, anim, FALSE, TRUE, TRUE);
1158         }
1159 };
1160
1161 void weapon_boblayer1(float spd, vector org)
1162 {
1163         // VorteX: haste can be added here
1164 };
1165
1166 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1167 {
1168         vector mdirection;
1169         float mspeed;
1170         float outspeed;
1171         float nstyle;
1172         vector outvelocity;
1173
1174         mvelocity = mvelocity * g_weaponspeedfactor;
1175
1176         mdirection = normalize(mvelocity);
1177         mspeed = vlen(mvelocity);
1178
1179         nstyle = cvar("g_projectiles_newton_style");
1180         if(nstyle == 0)
1181         {
1182                 // absolute velocity
1183                 outvelocity = mvelocity;
1184         }
1185         else if(nstyle == 1)
1186         {
1187                 // true Newtonian projectiles
1188                 outvelocity = pvelocity + mvelocity;
1189         }
1190         else if(nstyle == 2)
1191         {
1192                 // true Newtonian projectiles with automatic aim adjustment
1193                 //
1194                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1195                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1196                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1197                 // PLUS SIGN!
1198                 // not defined?
1199                 // then...
1200                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1201                 // velocity without mdirection component > mspeed
1202                 // fire at smallest possible mspeed that works?
1203                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1204
1205                 vector solution;
1206                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1207                 if(solution_z)
1208                         outspeed = solution_y; // the larger one
1209                 else
1210                 {
1211                         //outspeed = 0; // slowest possible shot
1212                         outspeed = solution_x; // the real part (that is, the average!)
1213                         //dprint("impossible shot, adjusting\n");
1214                 }
1215
1216                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1217                 outvelocity = mdirection * outspeed;
1218         }
1219         else if(nstyle == 3)
1220         {
1221                 // pseudo-Newtonian:
1222                 outspeed = mspeed + mdirection * pvelocity;
1223                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1224                 outvelocity = mdirection * outspeed;
1225         }
1226         else if(nstyle == 4)
1227         {
1228                 // tZorkian:
1229                 outspeed = mspeed + vlen(pvelocity);
1230                 outvelocity = mdirection * outspeed;
1231         }
1232         else
1233                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1234
1235         return outvelocity;
1236 }
1237
1238 void W_AttachToShotorg(entity flash, vector offset)
1239 {
1240         entity xflash;
1241         flash.owner = self;
1242         flash.angles_z = random() * 360;
1243         if(qcweaponanimation)
1244         {
1245                 setorigin(flash, w_shotorg + w_shotdir * 50);
1246                 flash.angles = vectoangles(w_shotdir);
1247                 flash.angles_z = random() * 360;
1248         }
1249         else
1250         {
1251                 setattachment(flash, self.weaponentity, "shot");
1252                 setorigin(flash, offset);
1253
1254                 xflash = spawn();
1255                 copyentity(flash, xflash);
1256
1257                 flash.viewmodelforclient = self;
1258
1259                 if(self.weaponentity.oldorigin_x > 0)
1260                 {
1261                         setattachment(xflash, self.exteriorweaponentity, "");
1262                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1263                 }
1264                 else
1265                 {
1266                         setattachment(xflash, self.exteriorweaponentity, "shot");
1267                 }
1268         }
1269 }
1270
1271 vector cliptoplane(vector v, vector p)
1272 {
1273         return v - (v * p) * p;
1274 }
1275
1276 vector solve_cubic_pq(float p, float q)
1277 {
1278         float D, u, v, a;
1279         D = q*q/4.0 + p*p*p/27.0;
1280         if(D < 0)
1281         {
1282                 // irreducibilis
1283                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1284                 u = sqrt(-4.0/3.0 * p);
1285                 // a in range 0..pi/3
1286                 // cos(a)
1287                 // cos(a + 2pi/3)
1288                 // cos(a + 4pi/3)
1289                 return
1290                         u *
1291                         (
1292                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1293                                 +
1294                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1295                                 +
1296                                 '0 0 1' * cos(a)
1297                         );
1298         }
1299         else if(D == 0)
1300         {
1301                 // simple
1302                 if(p == 0)
1303                         return '0 0 0';
1304                 u = 3*q/p;
1305                 v = -u/2;
1306                 if(u >= v)
1307                         return '1 1 0' * v + '0 0 1' * u;
1308                 else
1309                         return '0 1 1' * v + '1 0 0' * u;
1310         }
1311         else
1312         {
1313                 // cardano
1314                 u = cbrt(-q/2.0 + sqrt(D));
1315                 v = cbrt(-q/2.0 - sqrt(D));
1316                 return '1 1 1' * (u + v);
1317         }
1318 }
1319 vector solve_cubic_abcd(float a, float b, float c, float d)
1320 {
1321         // y = 3*a*x + b
1322         // x = (y - b) / 3a
1323         float p, q;
1324         vector v;
1325         p = (9*a*c - 3*b*b);
1326         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1327         v = solve_cubic_pq(p, q);
1328         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1329         if(a < 0)
1330                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1331         return v;
1332 }
1333
1334 vector findperpendicular(vector v)
1335 {
1336         vector p;
1337         p_x = v_z;
1338         p_y = -v_x;
1339         p_z = v_y;
1340         return normalize(cliptoplane(p, v));
1341 }
1342
1343 vector W_CalculateProjectileSpread(vector forward, float spread)
1344 {
1345         float sigma;
1346         vector v1, v2;
1347         float dx, dy, r;
1348         float sstyle;
1349         if(spread <= 0)
1350                 return forward;
1351         sstyle = cvar("g_projectiles_spread_style");
1352
1353         if(sstyle == 0)
1354         {
1355                 // this is the baseline for the spread value!
1356                 // standard deviation: sqrt(2/5)
1357                 // density function: sqrt(1-r^2)
1358                 return forward + randomvec() * spread;
1359         }
1360         else if(sstyle == 1)
1361         {
1362                 // same thing, basically
1363                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1364         }
1365         else if(sstyle == 2)
1366         {
1367                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1368                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1369                 v1 = findperpendicular(forward);
1370                 v2 = cross(forward, v1);
1371                 // random point on unit circle
1372                 dx = random() * 2 * M_PI;
1373                 dy = sin(dx);
1374                 dx = cos(dx);
1375                 // radius in our dist function
1376                 r = random();
1377                 r = sqrt(r);
1378                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1379         }
1380         else if(sstyle == 3) // gauss 3d
1381         {
1382                 sigma = spread * 0.44721359549996; // match baseline stddev
1383                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1384                 v1 = forward;
1385                 v1_x += gsl_ran_gaussian(sigma);
1386                 v1_y += gsl_ran_gaussian(sigma);
1387                 v1_z += gsl_ran_gaussian(sigma);
1388                 return v1;
1389         }
1390         else if(sstyle == 4) // gauss 2d
1391         {
1392                 sigma = spread * 0.44721359549996; // match baseline stddev
1393                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1394                 v1_x = gsl_ran_gaussian(sigma);
1395                 v1_y = gsl_ran_gaussian(sigma);
1396                 v1_z = gsl_ran_gaussian(sigma);
1397                 return normalize(forward + cliptoplane(v1, forward));
1398         }
1399         else if(sstyle == 5) // 1-r
1400         {
1401                 sigma = spread * 1.154700538379252; // match baseline stddev
1402                 v1 = findperpendicular(forward);
1403                 v2 = cross(forward, v1);
1404                 // random point on unit circle
1405                 dx = random() * 2 * M_PI;
1406                 dy = sin(dx);
1407                 dx = cos(dx);
1408                 // radius in our dist function
1409                 r = random();
1410                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1411                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1412         }
1413         else if(sstyle == 6) // 1-r^2
1414         {
1415                 sigma = spread * 1.095445115010332; // match baseline stddev
1416                 v1 = findperpendicular(forward);
1417                 v2 = cross(forward, v1);
1418                 // random point on unit circle
1419                 dx = random() * 2 * M_PI;
1420                 dy = sin(dx);
1421                 dx = cos(dx);
1422                 // radius in our dist function
1423                 r = random();
1424                 r = sqrt(1 - r);
1425                 r = sqrt(1 - r);
1426                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1427         }
1428         else if(sstyle == 7) // (1-r) (2-r)
1429         {
1430                 sigma = spread * 1.224744871391589; // match baseline stddev
1431                 v1 = findperpendicular(forward);
1432                 v2 = cross(forward, v1);
1433                 // random point on unit circle
1434                 dx = random() * 2 * M_PI;
1435                 dy = sin(dx);
1436                 dx = cos(dx);
1437                 // radius in our dist function
1438                 r = random();
1439                 r = 1 - sqrt(r);
1440                 r = 1 - sqrt(r);
1441                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1442         }
1443         else
1444                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1445         return '0 0 0';
1446         /*
1447          * how to derive falloff functions:
1448          * rho(r) := (2-r) * (1-r);
1449          * a : 0;
1450          * b : 1;
1451          * rhor(r) := r * rho(r);
1452          * cr(t) := integrate(rhor(r), r, a, t);
1453          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1454          * variance : scr(b) / cr(b);
1455          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1456          * sqrt(0.4 / variance), numer;
1457          */
1458 }
1459
1460 #if 0
1461 float mspercallsum;
1462 float mspercallsstyle;
1463 float mspercallcount;
1464 #endif
1465 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float spread)
1466 {
1467         if(missile.owner == world)
1468                 error("Unowned missile");
1469
1470         dir = dir + upDir * (pUpSpeed / pSpeed);
1471         pSpeed *= vlen(dir);
1472         dir = normalize(dir);
1473
1474 #if 0
1475         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1476         {
1477                 mspercallsum = mspercallcount = 0;
1478                 mspercallsstyle = cvar("g_projectiles_spread_style");
1479         }
1480         mspercallsum -= gettime(GETTIME_HIRES);
1481 #endif
1482         dir = W_CalculateProjectileSpread(dir, spread);
1483 #if 0
1484         mspercallsum += gettime(GETTIME_HIRES);
1485         mspercallcount += 1;
1486         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1487 #endif
1488
1489         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1490 }
1491
1492 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1493 {
1494         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, spread);
1495 }
1496
1497 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_spread"))
1498 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, cvar(#s "_spread"))