data/qcsrc/server/cl_weapons.qc

   1 void W_Reload()
   2 {
   3         if(self.switchweapon == self.weapon)
   4         if(self.weaponentity.state == WS_READY)
   5                 weapon_action(self.weapon, WR_RELOAD);
   6 }
   7
   8 // switch between weapons
   9 void W_SwitchWeapon(float imp)
  10 {
  11         if (self.switchweapon != imp)
  12         {
  13                 if (client_hasweapon(self, imp, TRUE, TRUE))
  14                         W_SwitchWeapon_Force(self, imp);
  15         }
  16         else
  17         {
  18                 W_Reload();
  19         }
  20 };
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain)
  24 {
  25         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  26         n = tokenize_sane(weaponorder);
  27         switchtonext = switchtolast = 0;
  28         first_valid = prev_valid = 0;
  29
  30         if(dir == 0)
  31                 switchtonext = 1;
  32
  33         c = 0;
  34
  35         for(i = 0; i < n; ++i)
  36         {
  37                 weaponwant = stof(argv(i));
  38                 if(imp >= 0)
  39                         if((get_weaponinfo(weaponwant)).impulse != imp)
  40                                 continue;
  41
  42                 ++c;
  43
  44                 if(client_hasweapon(pl, weaponwant, TRUE, FALSE))
  45                 {
  46                         if(switchtonext)
  47                                 return weaponwant;
  48                         if(!first_valid)
  49                                 first_valid = weaponwant;
  50                         if(weaponwant == pl.switchweapon)
  51                         {
  52                                 if(dir >= 0)
  53                                         switchtonext = 1;
  54                                 else if(prev_valid)
  55                                         return prev_valid;
  56                                 else
  57                                         switchtolast = 1;
  58                         }
  59                         prev_valid = weaponwant;
  60                 }
  61         }
  62         if(first_valid)
  63         {
  64                 if(switchtolast)
  65                         return prev_valid;
  66                 else
  67                         return first_valid;
  68         }
  69         // complain (but only for one weapon on the button that has been pressed)
  70         if(complain)
  71         {
  72                 self.weaponcomplainindex += 1;
  73                 c = mod(self.weaponcomplainindex, c) + 1;
  74                 for(i = 0; i < n; ++i)
  75                 {
  76                         weaponwant = stof(argv(i));
  77                         if(imp >= 0)
  78                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  79                                         continue;
  80
  81                         --c;
  82                         if(c == 0)
  83                         {
  84                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  85                                 break;
  86                         }
  87                 }
  88         }
  89         return 0;
  90 }
  91
  92 void W_CycleWeapon(string weaponorder, float dir)
  93 {
  94         float w;
  95         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1);
  96         if(w > 0)
  97                 W_SwitchWeapon(w);
  98 }
  99
 100 void W_NextWeaponOnImpulse(float imp)
 101 {
 102         float w;
 103         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1);
 104         if(w > 0)
 105                 W_SwitchWeapon(w);
 106 }
 107
 108 // next weapon
 109 void W_NextWeapon(float list)
 110 {
 111         if(list == 0)
 112                 W_CycleWeapon(weaponpriority_hudselector_0, -1);
 113         else if(list == 1)
 114                 W_CycleWeapon(weaponpriority_hudselector_1, -1);
 115         else if(list == 2)
 116                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 117 }
 118
 119 // prev weapon
 120 void W_PreviousWeapon(float list)
 121 {
 122         if(list == 0)
 123                 W_CycleWeapon(weaponpriority_hudselector_0, +1);
 124         else if(list == 1)
 125                 W_CycleWeapon(weaponpriority_hudselector_1, +1);
 126         else if(list == 2)
 127                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 128 }
 129
 130 string W_FixWeaponOrder_AllowIncomplete(string order)
 131 {
 132         return W_FixWeaponOrder(order, 0);
 133 }
 134
 135 string W_FixWeaponOrder_ForceComplete(string order)
 136 {
 137         if(order == "")
 138                 order = cvar_string("cl_weaponpriority");
 139         return W_FixWeaponOrder(order, 1);
 140 }
 141
 142 float w_getbestweapon(entity e)
 143 {
 144         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, 0);
 145 };
 146
 147 // generic weapons table
 148 // TODO should they be macros instead?
 149 float weapon_action(float wpn, float wrequest)
 150 {
 151         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 152 };
 153
 154 string W_Name(float weaponid)
 155 {
 156         return (get_weaponinfo(weaponid)).message;
 157 }
 158
 159 float W_WeaponBit(float wpn)
 160 {
 161         return (get_weaponinfo(wpn)).weapons;
 162 }
 163
 164 float W_AmmoItemCode(float wpn)
 165 {
 166         return (get_weaponinfo(wpn)).items;
 167 }
 168
 169 void thrown_wep_think()
 170 {
 171         self.solid = SOLID_TRIGGER;
 172         self.owner = world;
 173         SUB_SetFade(self, time + 20, 1);
 174 }
 175
 176 // returns amount of ammo used, or -1 for failure, or 0 for no ammo count
 177 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 178 {
 179         entity oldself, wep;
 180         float wa, thisammo;
 181         var .float ammofield;
 182
 183         wep = spawn();
 184
 185         setorigin(wep, org);
 186         wep.classname = "droppedweapon";
 187         wep.velocity = velo;
 188         wep.owner = wep.enemy = own;
 189         wep.classname = "droppedweapon";
 190         wep.flags = wep.flags | FL_TOSSED;
 191         wep.colormap = own.colormap;
 192
 193         wa = W_AmmoItemCode(wpn);
 194         if(wa == IT_SUPERWEAPON || wa == 0)
 195         {
 196                 oldself = self;
 197                 self = wep;
 198                 weapon_defaultspawnfunc(wpn);
 199                 self = oldself;
 200                 if(startitem_failed)
 201                         return -1;
 202                 wep.think = thrown_wep_think;
 203                 wep.nextthink = time + 0.5;
 204                 return 0;
 205         }
 206         else
 207         {
 208                 ammofield = Item_CounterField(wa);
 209                 oldself = self;
 210                 self = wep;
 211                 weapon_defaultspawnfunc(wpn);
 212                 self = oldself;
 213                 if(startitem_failed)
 214                         return -1;
 215                 if(doreduce)
 216                 {
 217                         thisammo = min(own.ammofield, wep.ammofield);
 218                         wep.ammofield = thisammo;
 219                         own.ammofield -= thisammo;
 220                 }
 221                 wep.think = thrown_wep_think;
 222                 wep.nextthink = time + 0.5;
 223                 return wep.ammofield;
 224         }
 225 }
 226
 227 // toss current weapon
 228 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 229 {
 230         local float w, a, wb, wa;
 231
 232         w = self.weapon;
 233         if (w == 0)
 234                 return; // just in case
 235         if (w == WEP_LASER)
 236                 return; // just in case
 237         if (g_weaponarena)
 238                 return;
 239         if (g_lms)
 240                 return;
 241         if (g_nixnex)
 242                 return;
 243         if (!cvar("g_pickup_items"))
 244                 return;
 245
 246         wb = W_WeaponBit(w);
 247         wa = W_AmmoItemCode(w);
 248         if(!wb)
 249                 return;
 250         if(self.weapons & wb != wb)
 251                 return;
 252         if(start_weapons & wb)
 253         {
 254                 if(wa == IT_SUPERWEAPON && start_items & IT_UNLIMITED_SUPERWEAPONS)
 255                         return;
 256                 if(wa != IT_SUPERWEAPON && start_items & IT_UNLIMITED_WEAPON_AMMO)
 257                         return;
 258                 if(wa == 0)
 259                         return;
 260         }
 261
 262         self.weapons = self.weapons - wb;
 263         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 264         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 265         if(a < 0)
 266                 return;
 267         if(self.health >= 1)
 268         {
 269                 if(a == 0)
 270                         sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 271                 else
 272                         sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", ftos(a), " ", Item_CounterFieldName(W_AmmoItemCode(w)), "\n"));
 273         }
 274 };
 275
 276 // Bringed back weapon frame
 277 void W_WeaponFrame()
 278 {
 279         if((arena_roundbased && time < warmup) || ((time < game_starttime) && !cvar("sv_ready_restart_after_countdown")))
 280                 return;
 281
 282         if (!self.weaponentity || self.health < 1)
 283                 return; // Dead player can't use weapons and injure impulse commands
 284
 285         if(!self.switchweapon)
 286         {
 287                 self.weapon = 0;
 288                 self.weaponentity.state = WS_CLEAR;
 289                 return;
 290         }
 291
 292         makevectors(self.v_angle);
 293
 294         // Change weapon
 295         if (self.weapon != self.switchweapon)
 296         {
 297                 if (self.weaponentity.state == WS_CLEAR)
 298                 {
 299                         player_setanim(self.anim_draw, FALSE, TRUE, TRUE);
 300                         self.weaponentity.state = WS_RAISE;
 301                         weapon_action(self.switchweapon, WR_SETUP);
 302                         // VorteX: add player model weapon select frame here
 303                         // setcustomframe(PlayerWeaponRaise);
 304                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 305                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 306                 }
 307                 else if (self.weaponentity.state == WS_READY)
 308                 {
 309 #ifndef INDEPENDENT_ATTACK_FINISHED
 310                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 311                         {
 312 #endif
 313                         // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 314                         sound (self, CHAN_WEAPON2, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 315                         self.weaponentity.state = WS_DROP;
 316                         // set up weapon switch think in the future, and start drop anim
 317                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 318                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 319 #ifndef INDEPENDENT_ATTACK_FINISHED
 320                         }
 321 #endif
 322                 }
 323         }
 324
 325         float wb;
 326         wb = W_WeaponBit(self.weapon);
 327
 328         // call the think code which may fire the weapon
 329         // and do so multiple times to resolve framerate dependency issues if the
 330         // server framerate is very low and the weapon fire rate very high
 331         local float c;
 332         c = 0;
 333         while (c < 5)
 334         {
 335                 c = c + 1;
 336                 if(wb && self.weapons & wb == 0)
 337                 {
 338                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 339                         wb = 0;
 340                 }
 341                 if(wb)
 342                         weapon_action(self.weapon, WR_THINK);
 343                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 344                 {
 345                         if(self.weapon_think)
 346                                 self.weapon_think();
 347                         else
 348                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 349                 }
 350         }
 351
 352         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 353         //if (ATTACK_FINISHED(self) < time)
 354         //      ATTACK_FINISHED(self) = time;
 355
 356         //if (self.weapon_nextthink < time)
 357         //      self.weapon_nextthink = time;
 358
 359         // update currentammo incase it has changed
 360         if (self.items & IT_CELLS)
 361                 self.currentammo = self.ammo_cells;
 362         else if (self.items & IT_ROCKETS)
 363                 self.currentammo = self.ammo_rockets;
 364         else if (self.items & IT_NAILS)
 365                 self.currentammo = self.ammo_nails;
 366         else if (self.items & IT_SHELLS)
 367                 self.currentammo = self.ammo_shells;
 368         else
 369                 self.currentammo = 1;
 370
 371 };
 372
 373 float nixnex_weapon;
 374 float nixnex_nextchange;
 375 float nixnex_nextweapon;
 376 .float nixnex_lastchange_id;
 377 .float nixnex_lastinfotime;
 378 .float nixnex_nextincr;
 379
 380 void Nixnex_ChooseNextWeapon()
 381 {
 382         float numberof, id;
 383         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 384         if(g_nixnex_with_laser)
 385                 numberof = numberof - 1;
 386         id = WEP_FIRST + floor(random() * numberof);
 387
 388         if(g_nixnex_with_laser) // skip the laser if needed
 389                 id = id + 1;
 390
 391         if(id >= nixnex_weapon) // skip the current weapon
 392                 id = id + 1;
 393
 394         if(id < WEP_FIRST) // can't happen, but to be sure...
 395         {
 396                 dprint("Won't happen (id < WEP_FIRST)\n");
 397                 id = WEP_FIRST;
 398         }
 399         if(id > WEP_LAST) // either
 400         {
 401                 dprint("Won't happen (id > WEP_LAST)\n");
 402                 id = WEP_LAST;
 403         }
 404
 405         nixnex_nextweapon = id;
 406 }
 407
 408 void Nixnex_GiveCurrentWeapon()
 409 {
 410         float dt;
 411         if(g_nixnex)
 412         {
 413                 if(!nixnex_nextweapon)
 414                         Nixnex_ChooseNextWeapon();
 415
 416                 dt = ceil(nixnex_nextchange - time);
 417
 418                 if(dt <= 0)
 419                 {
 420                         nixnex_weapon = nixnex_nextweapon;
 421                         nixnex_nextweapon = 0;
 422                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 423                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 424                 }
 425
 426                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 427                 {
 428                         self.nixnex_lastchange_id = nixnex_nextchange;
 429                         if (self.items & IT_UNLIMITED_WEAPON_AMMO)
 430                         {
 431                                 self.ammo_shells = cvar("g_pickup_shells_max");
 432                                 self.ammo_nails = cvar("g_pickup_nails_max");
 433                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 434                                 self.ammo_cells = cvar("g_pickup_cells_max");
 435                         }
 436                         else
 437                         {
 438                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 439                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 440                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 441                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 442                         }
 443                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 444                         if(dt >= 1 && dt <= 5)
 445                                 self.nixnex_lastinfotime = -42;
 446                         else
 447                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 448                 }
 449                 if(self.nixnex_lastinfotime != dt)
 450                 {
 451                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 452                         if(dt >= 1 && dt <= 5)
 453                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 454                 }
 455
 456                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO) && time > self.nixnex_nextincr)
 457                 {
 458                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 459                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 460                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 461                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 462                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 463                 }
 464
 465                 self.weapons = 0;
 466                 if(g_nixnex_with_laser)
 467                         self.weapons = self.weapons | WEPBIT_LASER;
 468                 self.weapons = self.weapons | W_WeaponBit(nixnex_weapon);
 469
 470                 if(self.switchweapon != nixnex_weapon)
 471                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 472                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 473                                         W_SwitchWeapon(nixnex_weapon);
 474         }
 475 }