data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.colormap = oldself.colormap;
  24         self.iscreature = oldself.iscreature;
  25         self.angles = oldself.angles;
  26         self.avelocity = oldself.avelocity;
  27         self.classname = "body";
  28         self.damageforcescale = oldself.damageforcescale;
  29         self.effects = oldself.effects;
  30         self.event_damage = oldself.event_damage;
  31         self.animstate_startframe = oldself.animstate_startframe;
  32         self.animstate_numframes = oldself.animstate_numframes;
  33         self.animstate_framerate = oldself.animstate_framerate;
  34         self.animstate_starttime = oldself.animstate_starttime;
  35         self.animstate_endtime = oldself.animstate_endtime;
  36         self.animstate_override = oldself.animstate_override;
  37         self.animstate_looping = oldself.animstate_looping;
  38         self.frame = oldself.frame;
  39         self.dead_frame = oldself.dead_frame;
  40         self.pain_finished = oldself.pain_finished;
  41         self.health = oldself.health;
  42         self.armorvalue = oldself.armorvalue;
  43         self.armortype = oldself.armortype;
  44         self.model = oldself.model;
  45         self.modelindex = oldself.modelindex;
  46         self.movetype = oldself.movetype;
  47         self.nextthink = oldself.nextthink;
  48         self.skin = oldself.skin;
  49         self.solid = oldself.solid;
  50         self.takedamage = oldself.takedamage;
  51         self.think = oldself.think;
  52         self.gibrandom = oldself.gibrandom;
  53         self.customizeentityforclient = oldself.customizeentityforclient;
  54         if (keepvelocity == 1)
  55                 self.velocity = oldself.velocity;
  56         self.oldvelocity = self.velocity;
  57         self.fade_time = oldself.fade_time;
  58         self.fade_rate = oldself.fade_rate;
  59         //self.weapon = oldself.weapon;
  60         setorigin(self, oldself.origin);
  61         setsize(self, oldself.mins, oldself.maxs);
  62         self.oldorigin = oldself.origin;
  63         self = oldself;
  64 }
  65
  66 float animparseerror;
  67 vector(float animfile) animparseline =
  68 {
  69         local string line;
  70         local float c;
  71         local vector anim;
  72         if (animfile < 0)
  73                 return '0 1 2';
  74         line = fgets(animfile);
  75         c = tokenize(line);
  76         if (c != 3)
  77         {
  78                 animparseerror = TRUE;
  79                 return '0 1 2';
  80         }
  81         anim_x = stof(argv(0));
  82         anim_y = stof(argv(1));
  83         anim_z = stof(argv(2));
  84         // don't allow completely bogus values
  85         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  86                 anim = '0 1 2';
  87         return anim;
  88 };
  89
  90 void() player_setupanimsformodel =
  91 {
  92         local string animfilename;
  93         local float animfile;
  94         // defaults for legacy .zym models without animinfo files
  95         self.anim_die1 = '0 1 0.5'; // 2 seconds
  96         self.anim_die2 = '1 1 0.5'; // 2 seconds
  97         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  98         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
  99         self.anim_duckwalk = '4 1 1';
 100         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 101         self.anim_duckidle = '6 1 1';
 102         self.anim_idle = '7 1 1';
 103         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 104         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 105         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 106         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 107         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 108         self.anim_run = '13 1 1';
 109         self.anim_runbackwards = '14 1 1';
 110         self.anim_strafeleft = '15 1 1';
 111         self.anim_straferight = '16 1 1';
 112         self.anim_dead1 = '17 1 1';
 113         self.anim_dead2 = '18 1 1';
 114         self.anim_forwardright = '19 1 1';
 115         self.anim_forwardleft = '20 1 1';
 116         self.anim_backright = '21 1 1';
 117         self.anim_backleft  = '22 1 1';
 118         animparseerror = FALSE;
 119         animfilename = strcat(self.model, ".animinfo");
 120         animfile = fopen(animfilename, FILE_READ);
 121         if (animfile >= 0)
 122         {
 123                 self.anim_die1         = animparseline(animfile);
 124                 self.anim_die2         = animparseline(animfile);
 125                 self.anim_draw         = animparseline(animfile);
 126                 self.anim_duck         = animparseline(animfile);
 127                 self.anim_duckwalk     = animparseline(animfile);
 128                 self.anim_duckjump     = animparseline(animfile);
 129                 self.anim_duckidle     = animparseline(animfile);
 130                 self.anim_idle         = animparseline(animfile);
 131                 self.anim_jump         = animparseline(animfile);
 132                 self.anim_pain1        = animparseline(animfile);
 133                 self.anim_pain2        = animparseline(animfile);
 134                 self.anim_shoot        = animparseline(animfile);
 135                 self.anim_taunt        = animparseline(animfile);
 136                 self.anim_run          = animparseline(animfile);
 137                 self.anim_runbackwards = animparseline(animfile);
 138                 self.anim_strafeleft   = animparseline(animfile);
 139                 self.anim_straferight  = animparseline(animfile);
 140                 self.anim_forwardright = animparseline(animfile);
 141                 self.anim_forwardleft  = animparseline(animfile);
 142                 self.anim_backright    = animparseline(animfile);
 143                 self.anim_backleft     = animparseline(animfile);
 144                 fclose(animfile);
 145
 146                 // derived anims
 147                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 148                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 149
 150                 if (animparseerror)
 151                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 152         }
 153         else
 154                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 155         // reset animstate now
 156         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 157 };
 158
 159 void(vector anim, float looping, float override, float restart) player_setanim =
 160 {
 161         if (!restart)
 162         if (anim_x == self.animstate_startframe)
 163         if (anim_y == self.animstate_numframes)
 164         if (anim_z == self.animstate_framerate)
 165                 return;
 166         self.animstate_startframe = anim_x;
 167         self.animstate_numframes = anim_y;
 168         self.animstate_framerate = anim_z;
 169         self.animstate_starttime = time;
 170         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 171         self.animstate_looping = looping;
 172         self.animstate_override = override;
 173         self.frame = self.animstate_startframe;
 174 };
 175
 176 void() player_updateframe =
 177 {
 178         if (time >= self.animstate_endtime)
 179         {
 180                 if (self.animstate_looping)
 181                 {
 182                         self.animstate_starttime = self.animstate_endtime;
 183                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 184                 }
 185                 self.animstate_override = FALSE;
 186         }
 187         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 188 };
 189
 190 void player_anim (void)
 191 {
 192         player_updateframe();
 193
 194         if (self.deadflag != DEAD_NO)
 195         {
 196                 if (time > self.animstate_endtime)
 197                 {
 198                         if (self.maxs_z > 5)
 199                         {
 200                                 self.maxs_z = 5;
 201                                 setsize(self, self.mins, self.maxs);
 202                         }
 203                         self.frame = self.dead_frame;
 204                 }
 205                 return;
 206         }
 207
 208         if (!self.animstate_override)
 209         {
 210                 if (!(self.flags & FL_ONGROUND))
 211                 {
 212                         if (self.crouch)
 213                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 214                         else
 215                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 216                 }
 217                 else if (self.crouch)
 218                 {
 219                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 220                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 221                         else
 222                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 223                 }
 224                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 225                 {
 226                         if (self.movement_x > 0 && self.movement_y == 0)
 227                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 228                         else if (self.movement_x < 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x == 0 && self.movement_y > 0)
 231                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y < 0)
 233                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x > 0 && self.movement_y > 0)
 235                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y < 0)
 237                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x < 0 && self.movement_y > 0)
 239                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y < 0)
 241                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 242                         else
 243                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 244                 }
 245                 else
 246                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 247         }
 248 }
 249 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 250
 251 void SpawnThrownWeapon (vector org, float w)
 252 {
 253         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 254 }
 255
 256 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 257 {
 258         local float take, save;
 259         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 260         // damage resistance (ignore most of the damage from a bullet or similar)
 261         damage = max(damage - 5, 1);
 262
 263         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 264         take = bound(0, damage - save, damage);
 265
 266         if (save > 10)
 267                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 268         else if (take > 30)
 269                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 270         else if (take > 10)
 271                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 272
 273         if (take > 50)
 274                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 275         if (take > 100)
 276                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 277
 278         if (!(self.flags & FL_GODMODE))
 279         {
 280                 self.armorvalue = self.armorvalue - save;
 281                 self.health = self.health - take;
 282                 // pause regeneration for 5 seconds
 283                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 284         }
 285         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 286         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 287         self.dmg_inflictor = inflictor;
 288
 289         if (self.health <= -50)
 290         {
 291                 // don't use any animations as a gib
 292                 self.frame = 0;
 293                 self.dead_frame = 0;
 294                 // view just above the floor
 295                 self.view_ofs = '0 0 4';
 296
 297                 // make a juicy mess
 298                 local float multiplier;
 299                 multiplier = 1;
 300                 if (cvar("ekg"))
 301                         multiplier = 5;
 302                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 303
 304                 // make a meaty mess
 305                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 306                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 307
 308                 local float c;
 309                 c = 0;
 310                 while (c < multiplier)
 311                 {
 312                         c = c + 1;
 313                         //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 314                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 315                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 316                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 317                         //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 318                         //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 319
 320                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 321                         TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 322                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 323                         //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 324                         TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 325                         //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 326                         TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 327                         TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 328                         TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 329                         //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 330                         //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 331
 332                         // these splat on impact
 333                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 334                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 335                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 336                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 337                 }
 338
 339                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 340         }
 341 }
 342
 343 void ClientKill_Now_TeamChange();
 344
 345 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 346 {
 347         local float take, save, waves, sdelay;
 348
 349         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 350
 351         pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 352         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 353         {
 354                 if (random() > 0.5)
 355                         player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 356                 else
 357                         player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 358                 self.pain_finished = time + 0.5;        //Supajoe
 359
 360                 // throw off bot aim temporarily
 361                 local float shake;
 362                 shake = damage * 5 / (bound(0,skill,100) + 1);
 363                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 364                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 365         }
 366
 367         if(g_arena)
 368         if(numspawned < 2)
 369                 return;
 370
 371         if (!g_minstagib)
 372         {
 373                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 374                 take = bound(0, damage - save, damage);
 375         }
 376         else
 377         {
 378                 save = 0;
 379                 take = damage;
 380         }
 381
 382         if (save > 10)
 383                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 384         else if (take > 30)
 385                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 386         else if (take > 10)
 387                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 388
 389         if (take > 50)
 390                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 391         if (take > 100)
 392                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 393
 394         if (time > self.spawnshieldtime)
 395         {
 396                 if (!(self.flags & FL_GODMODE))
 397                 {
 398                         self.armorvalue = self.armorvalue - save;
 399                         self.health = self.health - take;
 400                         // pause regeneration for 5 seconds
 401                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 402                 }
 403                 else
 404                         self.max_armorvalue += (save + take);
 405         }
 406         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 407         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 408         self.dmg_inflictor = inflictor;
 409
 410         if(attacker == self)
 411         {
 412                 // don't reset pushltime for self damage as it may be an attempt to
 413                 // escape a lava pit or similar
 414                 //self.pushltime = 0;
 415         }
 416         else if(attacker.classname == "player" || attacker.classname == "gib")
 417         {
 418                 self.pusher = attacker;
 419                 self.pushltime = time + cvar("g_maxpushtime");
 420         }
 421         else if(time < self.pushltime)
 422         {
 423                 attacker = self.pusher;
 424                 self.pushltime = max(self.pushltime, time + 0.6);
 425         }
 426         else
 427                 self.pushltime = 0;
 428
 429         if (self.health < 1)
 430         {
 431                 float defer_ClientKill_Now_TeamChange;
 432                 defer_ClientKill_Now_TeamChange = FALSE;
 433
 434                 self.deaths += 1;
 435
 436                 // get rid of kill indicator
 437                 if(self.killindicator)
 438                 {
 439                         remove(self.killindicator);
 440                         self.killindicator = world;
 441                         if(self.killindicator_teamchange)
 442                                 defer_ClientKill_Now_TeamChange = TRUE;
 443                 }
 444
 445                 // become fully visible
 446                 self.alpha = 1;
 447                 // clear selected player display
 448                 ClearSelectedPlayer();
 449                 // throw a weapon
 450                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 451                 // print an obituary message
 452                 Obituary (attacker, self, deathtype);
 453                 DropAllRunes(self);
 454                 if(self == attacker)
 455                         kh_Key_DropAll(self, TRUE);
 456                 else if(attacker.classname == "player" || attacker.classname == "gib")
 457                         kh_Key_DropAll(self, FALSE);
 458                 else
 459                         kh_Key_DropAll(self, TRUE);
 460                 if(self.flagcarried)
 461                         DropFlag(self.flagcarried);
 462                 // clear waypoints
 463                 WaypointSprite_PlayerDead();
 464                 // make the corpse upright (not tilted)
 465                 self.angles_x = 0;
 466                 self.angles_z = 0;
 467                 // don't spin
 468                 self.avelocity = '0 0 0';
 469                 // view from the floor
 470                 self.view_ofs = '0 0 -8';
 471                 // toss the corpse
 472                 self.movetype = MOVETYPE_TOSS;
 473                 // shootable corpse
 474                 self.solid = SOLID_CORPSE;
 475                 // don't stick to the floor
 476                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 477                 // dying animation
 478                 self.deadflag = DEAD_DYING;
 479                 // when to allow respawn
 480                 sdelay = 0;
 481                 waves = 0;
 482                 if(cvar("g_respawn_mapsettings"))
 483                 {
 484                         sdelay = cvar("g_respawn_mapsettings_delay");
 485                         waves = cvar("g_respawn_mapsettings_waves");
 486                 }
 487                 if(!sdelay)
 488                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 489                 if(!sdelay)
 490                         sdelay = cvar("g_respawn_delay");
 491                 if(!waves)
 492                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 493                 if(!waves)
 494                         waves = cvar("g_respawn_waves");
 495                 if(waves)
 496                         self.death_time = ceil((time + sdelay) / waves) * waves;
 497                 else
 498                         self.death_time = time + sdelay;
 499                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 500                         self.respawn_countdown = 10; // first number to count down from is 10
 501                 else
 502                         self.respawn_countdown = -1; // do not count down
 503                 if (random() < 0.5)
 504                 {
 505                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 506                         self.dead_frame = self.anim_dead1_x;
 507                 }
 508                 else
 509                 {
 510                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 511                         self.dead_frame = self.anim_dead2_x;
 512                 }
 513                 // set damage function to corpse damage
 514                 self.event_damage = PlayerCorpseDamage;
 515                 // call the corpse damage function just in case it wants to gib
 516                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 517                 // set up to fade out later
 518                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 519
 520                 // remove laserdot
 521                 if(self.weaponentity)
 522                         if(self.weaponentity.lasertarget)
 523                                 remove(self.weaponentity.lasertarget);
 524
 525                 if(clienttype(self) == CLIENTTYPE_REAL)
 526                 {
 527                         self.fixangle = TRUE;
 528                         //msg_entity = self;
 529                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 530                         //WriteAngle (MSG_ONE, self.v_angle_x);
 531                         //WriteAngle (MSG_ONE, self.v_angle_y);
 532                         //WriteAngle (MSG_ONE, 80);
 533                 }
 534
 535                 if(g_arena)
 536                         Spawnqueue_Unmark(self);
 537
 538                 if(defer_ClientKill_Now_TeamChange)
 539                         ClientKill_Now_TeamChange();
 540         }
 541 }
 542
 543 float UpdateSelectedPlayer_countvalue(float v)
 544 {
 545         return max(0, (v - 1.0) / 0.5);
 546 }
 547
 548 // returns: -2 if no hit, otherwise cos of the angle
 549 // uses the global v_angle
 550 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 551 {
 552         vector so, d;
 553         float c;
 554
 555         if(p == self)
 556                 return -2;
 557
 558         if(p.deadflag)
 559                 return -2;
 560
 561         so = self.origin + self.view_ofs;
 562         d = p.origin - so;
 563
 564         // misaimed?
 565         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 566                 return -2;
 567
 568         // now find the cos of the angle...
 569         c = normalize(d) * v_forward;
 570
 571         if(c <= mincosangle)
 572                 return -2;
 573
 574         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 575         if(trace_fraction < 1)
 576                 return -2;
 577
 578         return c;
 579 }
 580
 581 void ClearSelectedPlayer()
 582 {
 583         if(self.selected_player)
 584         {
 585                 centerprint_expire(self, CENTERPRIO_POINT);
 586                 self.selected_player = world;
 587                 self.selected_player_display_needs_update = FALSE;
 588         }
 589 }
 590
 591 void UpdateSelectedPlayer()
 592 {
 593         entity selected;
 594         float selected_score;
 595         selected = world;
 596         selected_score = 0.95; // 18 degrees
 597
 598         if(!cvar("sv_allow_shownames"))
 599                 return;
 600
 601         if(clienttype(self) != CLIENTTYPE_REAL)
 602                 return;
 603
 604         if(self.cvar_cl_shownames == 0)
 605                 return;
 606
 607         if(self.cvar_cl_shownames == 1 && !teams_matter)
 608                 return;
 609
 610         makevectors(self.v_angle); // sets v_forward
 611
 612         // 1. cursor trace is always right
 613         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 614         {
 615                 selected = self.cursor_trace_ent;
 616         }
 617         else
 618         {
 619                 // 2. if we don't have a cursor trace, find the player which is least
 620                 //    mis-aimed at
 621                 entity p;
 622                 FOR_EACH_PLAYER(p)
 623                 {
 624                         float c;
 625                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 626                         if(c >= -1)
 627                         {
 628                                 selected = p;
 629                                 selected_score = c;
 630                         }
 631                 }
 632         }
 633
 634         if(selected)
 635         {
 636                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 637         }
 638         else
 639         {
 640                 if(time < self.selected_player_display_timeout)
 641                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 642                                 selected = self.selected_player;
 643         }
 644
 645         if(selected)
 646         {
 647                 if(selected == self.selected_player)
 648                 {
 649                         float save;
 650                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 651                         self.selected_player_count = self.selected_player_count + frametime;
 652                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 653                         {
 654                                 string namestr, healthstr;
 655                                 namestr = playername(selected);
 656                                 if(teams_matter)
 657                                 {
 658                                         healthstr = ftos(floor(selected.health));
 659                                         if(self.team == selected.team)
 660                                         {
 661                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 662                                                 self.selected_player_display_needs_update = TRUE;
 663                                         }
 664                                 }
 665                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 666                         }
 667                 }
 668                 else
 669                 {
 670                         ClearSelectedPlayer();
 671                         self.selected_player = selected;
 672                         self.selected_player_time = time;
 673                         self.selected_player_count = 0;
 674                         self.selected_player_display_needs_update = FALSE;
 675                 }
 676         }
 677         else
 678         {
 679                 ClearSelectedPlayer();
 680         }
 681
 682         if(self.selected_player)
 683                 self.last_selected_player = self.selected_player;
 684 }
 685
 686 float precache_sound_index (string s) = #19;
 687 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 688 {
 689         vector o;
 690         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 691                 return;
 692         o = e.origin + 0.5 * (e.mins + e.maxs);
 693         msg_entity = sounddest;
 694         WriteByte(MSG_ONE, 6);
 695         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 696         WriteByte(MSG_ONE, vol * 255);
 697         WriteByte(MSG_ONE, atten * 64);
 698         WriteEntity(MSG_ONE, e);
 699         WriteByte(MSG_ONE, chan);
 700         WriteShort(MSG_ONE, precache_sound_index(samp));
 701         WriteCoord(MSG_ONE, o_x);
 702         WriteCoord(MSG_ONE, o_y);
 703         WriteCoord(MSG_ONE, o_z);
 704 }
 705
 706 #if 0
 707 .string playersound_attack;
 708 .string playersound_attackinfive;
 709 .string playersound_coverme;
 710 .string playersound_defend;
 711 .string playersound_freelance;
 712 .string playersound_incoming;
 713 .string playersound_meet;
 714 .string playersound_needhelp;
 715 .string playersound_seenflag;
 716 .string playersound_taunt;
 717 .string playersound_teamshoot;
 718 .float modelindex_for_playersound;
 719
 720 float GetVoiceMessageTeamsayType(string type)
 721 {
 722         if(type == "taunt")
 723                 return 0;
 724         if(type == "teamshoot")
 725                 return 2;
 726         return 1;
 727 }
 728
 729 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 730 float GetPlayerSoundSampleField_notFound;
 731 .string GetVoiceMessageSampleField(string type)
 732 {
 733         GetPlayerSoundSampleField_notFound = 0;
 734         switch(type)
 735         {
 736                 case "attack":       return playersound_attack;
 737                 case "attackinfive": return playersound_attackinfive;
 738                 case "coverme":      return playersound_coverme;
 739                 case "defend":       return playersound_defend;
 740                 case "freelance":    return playersound_freelance;
 741                 case "incoming":     return playersound_incoming;
 742                 case "meet":         return playersound_meet;
 743                 case "needhelp":     return playersound_needhelp;
 744                 case "seenflag":     return playersound_seenflag;
 745                 case "taunt":        return playersound_taunt;
 746                 case "teamshoot":    return playersound_teamshoot;
 747         }
 748         GetPlayerSoundSampleField_notFound = 1;
 749         return playersound_taunt;
 750 }
 751
 752 .string GetPlayerSoundSampleField(string type)
 753 {
 754         GetPlayerSoundSampleField_notFound = 0;
 755         switch(type)
 756         {
 757                 case "attack":       return playersound_attack;
 758                 default:             return GetVoiceMessageSampleField(type);
 759         }
 760 }
 761
 762 void PrecachePlayerSounds(string f)
 763 {
 764         float fh;
 765         float i, n;
 766         string s;
 767         fh = fopen(f, FILE_READ);
 768         if(fh < 0)
 769                 return;
 770         while((s = fgets(fh)))
 771         {
 772                 if(tokenize(s) != 3)
 773                 {
 774                         dprint("Invalid sound info line: ", s, "\n");
 775                         continue;
 776                 }
 777                 n = stof(argv(2));
 778                 for(i = 1; i <= n; ++i)
 779                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 780         }
 781         fclose(fh);
 782 }
 783
 784 void LoadPlayerSounds(string f)
 785 {
 786         float fh;
 787         string s;
 788         var .string field;
 789         fh = fopen(f, FILE_READ);
 790         if(fh < 0)
 791                 return;
 792         while((s = fgets(fh)))
 793         {
 794                 if(tokenize(s) != 3)
 795                         continue;
 796                 field = GetPlayerSoundSampleField(argv(0));
 797                 if(GetPlayerSoundSampleField_notFound)
 798                         continue;
 799                 if(self.field)
 800                         strunzone(self.field);
 801                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 802         }
 803         fclose(fh);
 804 }
 805
 806 void UpdatePlayerSounds()
 807 {
 808         if(self.modelindex == self.modelindex_for_playersound)
 809                 return;
 810         self.modelindex_for_playersound = self.modelindex;
 811         LoadPlayerSounds("sound/player/default.sounds");
 812         LoadPlayerSounds(strcat(self.model, ".sounds"));
 813 }
 814
 815 void VoiceMessage(string type)
 816 {
 817         // TODO precache voice messages?
 818         var string sample;
 819         var float teamsay;
 820         sample = self.(GetPlayerSoundSampleField(type));
 821
 822         if(GetPlayerSoundSampleField_notFound)
 823         {
 824                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 825                 return;
 826         }
 827
 828         if(!sample)
 829                 return;
 830
 831         teamsay = GetVoiceMessageTeamsayType(type);
 832
 833         tokenize(sample);
 834         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 835
 836         if(teamsay == 2)
 837         {
 838                 if(teams_matter)
 839                         if(self.pusher)
 840                                 if(self.pusher.team == self.team)
 841                                 {
 842                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 843                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 844                                 }
 845         }
 846         else if(teamsay == 0 || !teams_matter)
 847         {
 848                 // broadcast the sound, but it's directional
 849                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 850         }
 851         else if(teamsay == 1)
 852         {
 853                 entity e;
 854                 FOR_EACH_REALCLIENT(e)
 855                         if(e.team == self.team)
 856                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 857         }
 858 }
 859 #else
 860 void PrecachePlayerSounds(string f) { }
 861 void UpdatePlayerSounds() { }
 862 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 863 #endif