data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize_sane(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(independent_players)
 277         if(sv_gentle < 1) {
 278                 if (take > 50)
 279                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 280                 if (take > 100)
 281                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 282         }
 283
 284         if (!(self.flags & FL_GODMODE))
 285         {
 286                 self.armorvalue = self.armorvalue - save;
 287                 self.health = self.health - take;
 288                 // pause regeneration for 5 seconds
 289                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 290         }
 291         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 292         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 293         self.dmg_inflictor = inflictor;
 294
 295         if (self.health <= -50)
 296         {
 297                 // don't use any animations as a gib
 298                 self.frame = 0;
 299                 self.dead_frame = 0;
 300                 // view just above the floor
 301                 self.view_ofs = '0 0 4';
 302
 303                 // make a juicy mess
 304                 local float multiplier;
 305                 multiplier = 1;
 306                 if (cvar("ekg"))
 307                         multiplier = 5;
 308
 309
 310                 // make a meaty mess
 311                 if(independent_players)
 312                 {
 313                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 314                         self.solid = SOLID_TRIGGER; // undo SOLID_CORPSE
 315                         self.takedamage = DAMAGE_NO; // can't damage this gib, to prevent better jumps from it
 316                 }
 317                 else
 318                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 319
 320                 if not(independent_players)
 321                 if(sv_gentle < 1) {
 322                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 323                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 324
 325                         local float c;
 326                         c = 0;
 327
 328                         while (c < multiplier)
 329                         {
 330                                 c = c + 1;
 331                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 332                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 333                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 334                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 335                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 336                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 337
 338                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 339                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 340                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 341                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 342                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 343                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 344                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 345                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 346                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 347                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 348                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 349
 350                                 // these splat on impact
 351                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 352                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 353                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 354                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 355                         }
 356                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 357                 }
 358         }
 359 }
 360
 361 void ClientKill_Now_TeamChange();
 362
 363 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 364 {
 365         local float take, save, waves, sdelay;
 366
 367         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 368         if(sv_gentle > 0) {
 369                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 370         } else {
 371                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 372         }
 373
 374         if(g_arena)
 375         if(numspawned < 2)
 376                 return;
 377
 378         if (!g_minstagib)
 379         {
 380                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 381                 take = bound(0, damage - save, damage);
 382         }
 383         else
 384         {
 385                 save = 0;
 386                 take = damage;
 387         }
 388
 389         if (save > 10)
 390                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 391         else if (take > 30)
 392                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 393         else if (take > 10)
 394                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 395
 396         if (take > 50)
 397                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 398         if (take > 100)
 399                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 400
 401         if (time > self.spawnshieldtime)
 402         {
 403                 if (!(self.flags & FL_GODMODE))
 404                 {
 405                         self.armorvalue = self.armorvalue - save;
 406                         self.health = self.health - take;
 407                         // pause regeneration for 5 seconds
 408                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 409
 410                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 411                         {
 412                                 self.pain_finished = time + 0.5;        //Supajoe
 413
 414                                 if(sv_gentle < 1) {
 415                                         if (random() > 0.5)
 416                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 417                                         else
 418                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 419
 420                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 421                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 422                                         {
 423                                                 if(self.health > 75) // TODO make a "gentle" version?
 424                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 425                                                 else if(self.health > 50)
 426                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 427                                                 else if(self.health > 25)
 428                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 429                                                 else if(self.health > 1)
 430                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 431                                         }
 432                                 }
 433
 434                                 // throw off bot aim temporarily
 435                                 local float shake;
 436                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 437                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 438                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 439                         }
 440                 }
 441                 else
 442                         self.max_armorvalue += (save + take);
 443         }
 444         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 445         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 446         self.dmg_inflictor = inflictor;
 447
 448         if(attacker == self)
 449         {
 450                 // don't reset pushltime for self damage as it may be an attempt to
 451                 // escape a lava pit or similar
 452                 //self.pushltime = 0;
 453         }
 454         else if(attacker.classname == "player" || attacker.classname == "gib")
 455         {
 456                 self.pusher = attacker;
 457                 self.pushltime = time + cvar("g_maxpushtime");
 458         }
 459         else if(time < self.pushltime)
 460         {
 461                 attacker = self.pusher;
 462                 self.pushltime = max(self.pushltime, time + 0.6);
 463         }
 464         else
 465                 self.pushltime = 0;
 466
 467         if (self.health < 1)
 468         {
 469                 float defer_ClientKill_Now_TeamChange;
 470                 defer_ClientKill_Now_TeamChange = FALSE;
 471
 472                 if(sv_gentle < 1) // TODO make a "gentle" version?
 473                 {
 474                         if(deathtype == DEATH_DROWN)
 475                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 476                         else
 477                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 478                 }
 479
 480                 // get rid of kill indicator
 481                 if(self.killindicator)
 482                 {
 483                         remove(self.killindicator);
 484                         self.killindicator = world;
 485                         if(self.killindicator_teamchange)
 486                                 defer_ClientKill_Now_TeamChange = TRUE;
 487
 488                         if(self.classname == "body")
 489                         if(deathtype == DEATH_KILL)
 490                         {
 491                                 // for the lemmings fans, a small harmless explosion
 492                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 493                         }
 494                 }
 495
 496                 // become fully visible
 497                 self.alpha = 1;
 498                 // clear selected player display
 499                 ClearSelectedPlayer();
 500                 // throw a weapon
 501                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 502                 // print an obituary message
 503                 Obituary (attacker, inflictor, self, deathtype);
 504                 race_PreDie();
 505                 DropAllRunes(self);
 506                 if(self == attacker)
 507                         kh_Key_DropAll(self, TRUE);
 508                 else if(attacker.classname == "player" || attacker.classname == "gib")
 509                         kh_Key_DropAll(self, FALSE);
 510                 else
 511                         kh_Key_DropAll(self, TRUE);
 512                 if(self.flagcarried)
 513                 {
 514                         if(attacker.classname != "player" && attacker.classname != "gib")
 515                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 516                         else if(attacker.team == self.team)
 517                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 518                         else
 519                                 DropFlag(self.flagcarried, world, attacker);
 520                 }
 521                 Portal_ClearAllLater(self);
 522                 // clear waypoints
 523                 WaypointSprite_PlayerDead();
 524                 // make the corpse upright (not tilted)
 525                 self.angles_x = 0;
 526                 self.angles_z = 0;
 527                 // don't spin
 528                 self.avelocity = '0 0 0';
 529                 // view from the floor
 530                 self.view_ofs = '0 0 -8';
 531                 // toss the corpse
 532                 self.movetype = MOVETYPE_TOSS;
 533                 // shootable corpse
 534                 self.solid = SOLID_CORPSE;
 535                 // don't stick to the floor
 536                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 537                 // dying animation
 538                 self.deadflag = DEAD_DYING;
 539                 // when to allow respawn
 540                 sdelay = 0;
 541                 waves = 0;
 542                 if(cvar("g_respawn_mapsettings"))
 543                 {
 544                         sdelay = cvar("g_respawn_mapsettings_delay");
 545                         waves = cvar("g_respawn_mapsettings_waves");
 546                 }
 547                 if(!sdelay)
 548                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 549                 if(!sdelay)
 550                         sdelay = cvar("g_respawn_delay");
 551                 if(!waves)
 552                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 553                 if(!waves)
 554                         waves = cvar("g_respawn_waves");
 555                 if(waves)
 556                         self.death_time = ceil((time + sdelay) / waves) * waves;
 557                 else
 558                         self.death_time = time + sdelay;
 559                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 560                         self.respawn_countdown = 10; // first number to count down from is 10
 561                 else
 562                         self.respawn_countdown = -1; // do not count down
 563                 if (random() < 0.5)
 564                 {
 565                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 566                         self.dead_frame = self.anim_dead1_x;
 567                 }
 568                 else
 569                 {
 570                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 571                         self.dead_frame = self.anim_dead2_x;
 572                 }
 573                 // set damage function to corpse damage
 574                 self.event_damage = PlayerCorpseDamage;
 575                 // call the corpse damage function just in case it wants to gib
 576                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 577                 // set up to fade out later
 578                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 579
 580                 // remove laserdot
 581                 if(self.weaponentity)
 582                         if(self.weaponentity.lasertarget)
 583                                 remove(self.weaponentity.lasertarget);
 584
 585                 if(clienttype(self) == CLIENTTYPE_REAL)
 586                 {
 587                         self.fixangle = TRUE;
 588                         //msg_entity = self;
 589                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 590                         //WriteAngle (MSG_ONE, self.v_angle_x);
 591                         //WriteAngle (MSG_ONE, self.v_angle_y);
 592                         //WriteAngle (MSG_ONE, 80);
 593                 }
 594
 595                 if(g_arena)
 596                         Spawnqueue_Unmark(self);
 597
 598                 if(defer_ClientKill_Now_TeamChange)
 599                         ClientKill_Now_TeamChange();
 600
 601                 if(sv_gentle > 0) {
 602                         // remove corpse
 603                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 604                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 605                 }
 606         }
 607 }
 608
 609 float UpdateSelectedPlayer_countvalue(float v)
 610 {
 611         return max(0, (v - 1.0) / 0.5);
 612 }
 613
 614 // returns: -2 if no hit, otherwise cos of the angle
 615 // uses the global v_angle
 616 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 617 {
 618         vector so, d;
 619         float c;
 620
 621         if(p == self)
 622                 return -2;
 623
 624         if(p.deadflag)
 625                 return -2;
 626
 627         so = self.origin + self.view_ofs;
 628         d = p.origin - so;
 629
 630         // misaimed?
 631         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 632                 return -2;
 633
 634         // now find the cos of the angle...
 635         c = normalize(d) * v_forward;
 636
 637         if(c <= mincosangle)
 638                 return -2;
 639
 640         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 641         if(trace_fraction < 1)
 642                 return -2;
 643
 644         return c;
 645 }
 646
 647 void ClearSelectedPlayer()
 648 {
 649         if(self.selected_player)
 650         {
 651                 centerprint_expire(self, CENTERPRIO_POINT);
 652                 self.selected_player = world;
 653                 self.selected_player_display_needs_update = FALSE;
 654         }
 655 }
 656
 657 void UpdateSelectedPlayer()
 658 {
 659         entity selected;
 660         float selected_score;
 661         selected = world;
 662         selected_score = 0.95; // 18 degrees
 663
 664         if(!cvar("sv_allow_shownames"))
 665                 return;
 666
 667         if(clienttype(self) != CLIENTTYPE_REAL)
 668                 return;
 669
 670         if(self.cvar_cl_shownames == 0)
 671                 return;
 672
 673         if(self.cvar_cl_shownames == 1 && !teams_matter)
 674                 return;
 675
 676         makevectors(self.v_angle); // sets v_forward
 677
 678         // 1. cursor trace is always right
 679         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 680         {
 681                 selected = self.cursor_trace_ent;
 682         }
 683         else
 684         {
 685                 // 2. if we don't have a cursor trace, find the player which is least
 686                 //    mis-aimed at
 687                 entity p;
 688                 FOR_EACH_PLAYER(p)
 689                 {
 690                         float c;
 691                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 692                         if(c >= -1)
 693                         {
 694                                 selected = p;
 695                                 selected_score = c;
 696                         }
 697                 }
 698         }
 699
 700         if(selected)
 701         {
 702                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 703         }
 704         else
 705         {
 706                 if(time < self.selected_player_display_timeout)
 707                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 708                                 selected = self.selected_player;
 709         }
 710
 711         if(selected)
 712         {
 713                 if(selected == self.selected_player)
 714                 {
 715                         float save;
 716                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 717                         self.selected_player_count = self.selected_player_count + frametime;
 718                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 719                         {
 720                                 string namestr, healthstr;
 721                                 namestr = playername(selected);
 722                                 if(teams_matter)
 723                                 {
 724                                         healthstr = ftos(floor(selected.health));
 725                                         if(self.team == selected.team)
 726                                         {
 727                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 728                                                 self.selected_player_display_needs_update = TRUE;
 729                                         }
 730                                 }
 731                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 732                         }
 733                 }
 734                 else
 735                 {
 736                         ClearSelectedPlayer();
 737                         self.selected_player = selected;
 738                         self.selected_player_time = time;
 739                         self.selected_player_count = 0;
 740                         self.selected_player_display_needs_update = FALSE;
 741                 }
 742         }
 743         else
 744         {
 745                 ClearSelectedPlayer();
 746         }
 747
 748         if(self.selected_player)
 749                 self.last_selected_player = self.selected_player;
 750 }
 751
 752 float GetVoiceMessageTeamsayType(string type)
 753 {
 754         if(type == "taunt")
 755                 return 0;
 756         if(type == "teamshoot")
 757                 return 2;
 758         if(type == "teamshoot_auto")
 759                 return 3;
 760         return 1;
 761 }
 762
 763 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 764 float GetPlayerSoundSampleField_notFound;
 765 float GetPlayerSoundSampleField_fixed;
 766 .string GetVoiceMessageSampleField(string type)
 767 {
 768         GetPlayerSoundSampleField_notFound = 0;
 769         GetPlayerSoundSampleField_fixed = 0;
 770         switch(type)
 771         {
 772                 case "attack":            return playersound_attack;
 773                 case "attackinfive":      return playersound_attackinfive;
 774                 case "coverme":           return playersound_coverme;
 775                 case "defend":            return playersound_defend;
 776                 case "freelance":         return playersound_freelance;
 777                 case "incoming":          return playersound_incoming;
 778                 case "meet":              return playersound_meet;
 779                 case "needhelp":          return playersound_needhelp;
 780                 case "seenflag":          return playersound_seenflag;
 781                 case "taunt":             return playersound_taunt;
 782                 case "teamshoot":         return playersound_teamshoot;
 783                 case "teamshoot_auto":    return playersound_teamshoot;
 784         }
 785         GetPlayerSoundSampleField_notFound = 1;
 786         return playersound_taunt;
 787 }
 788
 789 .string GetPlayerSoundSampleField(string type)
 790 {
 791         GetPlayerSoundSampleField_notFound = 0;
 792         GetPlayerSoundSampleField_fixed = 0;
 793         switch(type)
 794         {
 795                 case "death":        return playersound_death;
 796                 case "drown":        return playersound_drown;
 797                 case "falling":      return playersound_falling;
 798                 case "gasp":         return playersound_gasp;
 799                 case "jump":         return playersound_jump;
 800                 case "pain25":       return playersound_pain25;
 801                 case "pain50":       return playersound_pain50;
 802                 case "pain75":       return playersound_pain75;
 803                 case "pain100":      return playersound_pain100;
 804         }
 805         GetPlayerSoundSampleField_notFound = 1;
 806         return playersound_taunt;
 807 }
 808
 809 void PrecacheGlobalSound(string samplestring)
 810 {
 811         float n, i;
 812         tokenize_sane(samplestring);
 813         n = stof(argv(1));
 814         if(n > 0)
 815         {
 816                 for(i = 1; i <= n; ++i)
 817                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 818         }
 819         else
 820         {
 821                 precache_sound(strcat(argv(0), ".wav"));
 822         }
 823 }
 824
 825 void PrecachePlayerSounds(string f)
 826 {
 827         float fh;
 828         string s;
 829         fh = fopen(f, FILE_READ);
 830         if(fh < 0)
 831                 return;
 832         while((s = fgets(fh)))
 833         {
 834                 if(tokenize_sane(s) != 3)
 835                 {
 836                         dprint("Invalid sound info line: ", s, "\n");
 837                         continue;
 838                 }
 839                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 840         }
 841         fclose(fh);
 842 }
 843
 844 void ClearPlayerSounds()
 845 {
 846         if(self.playersound_attack      ) { strunzone(self.playersound_attack      ); self.playersound_attack = string_null; }
 847         if(self.playersound_attackinfive) { strunzone(self.playersound_attackinfive); self.playersound_attackinfive = string_null; }
 848         if(self.playersound_coverme     ) { strunzone(self.playersound_coverme     ); self.playersound_coverme = string_null; }
 849         if(self.playersound_defend      ) { strunzone(self.playersound_defend      ); self.playersound_defend = string_null; }
 850         if(self.playersound_freelance   ) { strunzone(self.playersound_freelance   ); self.playersound_freelance = string_null; }
 851         if(self.playersound_incoming    ) { strunzone(self.playersound_incoming    ); self.playersound_incoming = string_null; }
 852         if(self.playersound_meet        ) { strunzone(self.playersound_meet        ); self.playersound_meet = string_null; }
 853         if(self.playersound_needhelp    ) { strunzone(self.playersound_needhelp    ); self.playersound_needhelp = string_null; }
 854         if(self.playersound_seenflag    ) { strunzone(self.playersound_seenflag    ); self.playersound_seenflag = string_null; }
 855         if(self.playersound_taunt       ) { strunzone(self.playersound_taunt       ); self.playersound_taunt = string_null; }
 856         if(self.playersound_teamshoot   ) { strunzone(self.playersound_teamshoot   ); self.playersound_teamshoot = string_null; }
 857         if(self.playersound_death       ) { strunzone(self.playersound_death       ); self.playersound_death = string_null; }
 858         if(self.playersound_drown       ) { strunzone(self.playersound_drown       ); self.playersound_drown = string_null; }
 859         if(self.playersound_falling     ) { strunzone(self.playersound_falling     ); self.playersound_falling = string_null; }
 860         if(self.playersound_gasp        ) { strunzone(self.playersound_gasp        ); self.playersound_gasp = string_null; }
 861         if(self.playersound_jump        ) { strunzone(self.playersound_jump        ); self.playersound_jump = string_null; }
 862         if(self.playersound_pain25      ) { strunzone(self.playersound_pain25      ); self.playersound_pain25 = string_null; }
 863         if(self.playersound_pain50      ) { strunzone(self.playersound_pain50      ); self.playersound_pain50 = string_null; }
 864         if(self.playersound_pain75      ) { strunzone(self.playersound_pain75      ); self.playersound_pain75 = string_null; }
 865         if(self.playersound_pain100     ) { strunzone(self.playersound_pain100     ); self.playersound_pain100 = string_null; }
 866 }
 867
 868 void LoadPlayerSounds(string f, float first)
 869 {
 870         float fh;
 871         string s;
 872         var .string field;
 873         fh = fopen(f, FILE_READ);
 874         if(fh < 0)
 875                 return;
 876         while((s = fgets(fh)))
 877         {
 878                 if(tokenize_sane(s) != 3)
 879                         continue;
 880                 field = GetPlayerSoundSampleField(argv(0));
 881                 if(GetPlayerSoundSampleField_notFound)
 882                         field = GetVoiceMessageSampleField(argv(0));
 883                 if(GetPlayerSoundSampleField_notFound)
 884                         continue;
 885                 if(GetPlayerSoundSampleField_fixed)
 886                         if not(first)
 887                                 continue;
 888                 if(self.field)
 889                         strunzone(self.field);
 890                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 891         }
 892         fclose(fh);
 893 }
 894
 895 .float modelindex_for_playersound;
 896 void UpdatePlayerSounds()
 897 {
 898         if(self.modelindex == self.modelindex_for_playersound)
 899                 return;
 900         self.modelindex_for_playersound = self.modelindex;
 901         ClearPlayerSounds();
 902         LoadPlayerSounds("sound/player/default.sounds", 1);
 903         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 904 }
 905
 906 void GlobalSound(string sample, float chan, float teamsay)
 907 {
 908         float n;
 909
 910         if(sample == "")
 911                 return;
 912
 913         tokenize_sane(sample);
 914         n = stof(argv(1));
 915         if(n > 0)
 916                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
 917         else
 918                 sample = strcat(argv(0), ".wav"); // randomization
 919
 920         if(teamsay == 3) // only to last attacker
 921         {
 922                 if(self.pusher)
 923                         if(self.pusher.team == self.team)
 924                         {
 925                                 msg_entity = self.pusher;
 926                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 927                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 928                         }
 929         }
 930         else if(teamsay == 2) // only to last attacker and self
 931         {
 932                 if(self.pusher)
 933                         if(self.pusher.team == self.team)
 934                         {
 935                                 msg_entity = self.pusher;
 936                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 937                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 938                                 msg_entity = self;
 939                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 940                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 941                         }
 942         }
 943         else if(teamsay == 0) // to everyone
 944         {
 945                 // broadcast the sound, but it's directional
 946                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 947         }
 948         else if(teamsay == 1) // to the same team
 949         {
 950                 if(teams_matter)
 951                 {
 952                         entity e;
 953                         FOR_EACH_REALCLIENT(e)
 954                                 if(!teams_matter || e.team == self.team)
 955                                 {
 956                                         msg_entity = e;
 957                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 958                                 }
 959                 }
 960                 else
 961                 {
 962                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 963                 }
 964         }
 965 }
 966
 967 void PlayerSound(.string samplefield, float chan, float teamsay)
 968 {
 969         string sample;
 970         sample = self.samplefield;
 971         GlobalSound(sample, chan, teamsay);
 972 }
 973
 974 void VoiceMessage(string type)
 975 {
 976         var .string sample;
 977         var float teamsay;
 978         sample = GetVoiceMessageSampleField(type);
 979
 980         if(GetPlayerSoundSampleField_notFound)
 981         {
 982                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 983                 return;
 984         }
 985
 986         teamsay = GetVoiceMessageTeamsayType(type);
 987
 988         PlayerSound(sample, CHAN_VOICE, teamsay);
 989 }