data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.species = oldself.species;
  49         self.movetype = oldself.movetype;
  50         self.nextthink = oldself.nextthink;
  51         self.skin = oldself.skin;
  52         self.solid = oldself.solid;
  53         self.takedamage = oldself.takedamage;
  54         self.think = oldself.think;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.prevorigin = oldself.origin;
  65         self.reset = SUB_Remove;
  66
  67         Drag_MoveDrag(oldself, self);
  68
  69         self = oldself;
  70 }
  71
  72 float player_getspecies()
  73 {
  74         local float glob, i, j, fh, len, s, sk;
  75         local string fn, l;
  76
  77         s = -1;
  78
  79         glob = search_begin("models/player/*.txt", TRUE, TRUE);
  80         if(glob < 0)
  81                 return s;
  82         for(j = 0; j <= 1; ++j)
  83         {
  84                 for(i = 0; i < search_getsize(glob); ++i)
  85                 {
  86                         fn = search_getfilename(glob, i);
  87                         fh = fopen(fn, FILE_READ);
  88                         if(fh < 0)
  89                                 continue;
  90                         fgets(fh); fgets(fh);
  91                         sk = stof(fgets(fh));
  92                         if(sk == (j ? 0 : self.skin)) // 2nd pass skips the skin test
  93                         if(fgets(fh) == self.model)
  94                         {
  95                                 l = fgets(fh);
  96                                 len = tokenize_console(l);
  97                                 if (len != 2)
  98                                         goto nospecies;
  99                                 if (argv(0) != "species")
 100                                         goto nospecies;
 101                                 switch(argv(1))
 102                                 {
 103                                         case "human":       s = SPECIES_HUMAN;       break;
 104                                         case "alien":       s = SPECIES_ALIEN;       break;
 105                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 106                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 107                                         case "animal":      s = SPECIES_ANIMAL;      break;
 108                                         case "reserved":    s = SPECIES_RESERVED;    break;
 109                                 }
 110                         }
 111 :nospecies
 112                         fclose(fh);
 113                 }
 114                 if (s >= 0)
 115                         break;
 116         }
 117         search_end(glob);
 118
 119         if (s < 0)
 120                 s = SPECIES_HUMAN;
 121
 122         return s;
 123 }
 124
 125 void player_setupanimsformodel()
 126 {
 127         local string animfilename;
 128         local float animfile;
 129         // defaults for legacy .zym models without animinfo files
 130         self.anim_die1 = '0 1 0.5'; // 2 seconds
 131         self.anim_die2 = '1 1 0.5'; // 2 seconds
 132         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 133         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 134         self.anim_duckwalk = '4 1 1';
 135         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 136         self.anim_duckidle = '6 1 1';
 137         self.anim_idle = '7 1 1';
 138         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 139         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 140         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 141         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 142         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 143         self.anim_run = '13 1 1';
 144         self.anim_runbackwards = '14 1 1';
 145         self.anim_strafeleft = '15 1 1';
 146         self.anim_straferight = '16 1 1';
 147         self.anim_dead1 = '17 1 1';
 148         self.anim_dead2 = '18 1 1';
 149         self.anim_forwardright = '19 1 1';
 150         self.anim_forwardleft = '20 1 1';
 151         self.anim_backright = '21 1 1';
 152         self.anim_backleft  = '22 1 1';
 153         animparseerror = FALSE;
 154         animfilename = strcat(self.model, ".animinfo");
 155         animfile = fopen(animfilename, FILE_READ);
 156         if (animfile >= 0)
 157         {
 158                 self.anim_die1         = animparseline(animfile);
 159                 self.anim_die2         = animparseline(animfile);
 160                 self.anim_draw         = animparseline(animfile);
 161                 self.anim_duck         = animparseline(animfile);
 162                 self.anim_duckwalk     = animparseline(animfile);
 163                 self.anim_duckjump     = animparseline(animfile);
 164                 self.anim_duckidle     = animparseline(animfile);
 165                 self.anim_idle         = animparseline(animfile);
 166                 self.anim_jump         = animparseline(animfile);
 167                 self.anim_pain1        = animparseline(animfile);
 168                 self.anim_pain2        = animparseline(animfile);
 169                 self.anim_shoot        = animparseline(animfile);
 170                 self.anim_taunt        = animparseline(animfile);
 171                 self.anim_run          = animparseline(animfile);
 172                 self.anim_runbackwards = animparseline(animfile);
 173                 self.anim_strafeleft   = animparseline(animfile);
 174                 self.anim_straferight  = animparseline(animfile);
 175                 self.anim_forwardright = animparseline(animfile);
 176                 self.anim_forwardleft  = animparseline(animfile);
 177                 self.anim_backright    = animparseline(animfile);
 178                 self.anim_backleft     = animparseline(animfile);
 179                 fclose(animfile);
 180
 181                 // derived anims
 182                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 183                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 184
 185                 if (animparseerror)
 186                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 187         }
 188         else
 189                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 190         // reset animstate now
 191         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 192 };
 193
 194 void player_anim (void)
 195 {
 196         updateanim(self);
 197         if (self.weaponentity)
 198                 updateanim(self.weaponentity);
 199
 200         if (self.deadflag != DEAD_NO)
 201         {
 202                 if (time > self.animstate_endtime)
 203                 {
 204                         if (self.maxs_z > 5)
 205                         {
 206                                 self.maxs_z = 5;
 207                                 setsize(self, self.mins, self.maxs);
 208                         }
 209                         self.frame = self.dead_frame;
 210                 }
 211                 return;
 212         }
 213
 214         if (!self.animstate_override)
 215         {
 216                 if (!(self.flags & FL_ONGROUND))
 217                 {
 218                         if (self.crouch)
 219                                 setanim(self, self.anim_duckjump, FALSE, TRUE, FALSE);
 220                         else
 221                                 setanim(self, self.anim_jump, FALSE, TRUE, FALSE);
 222                 }
 223                 else if (self.crouch)
 224                 {
 225                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 226                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 227                         else
 228                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 229                 }
 230                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 231                 {
 232                         if (self.movement_x > 0 && self.movement_y == 0)
 233                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x < 0 && self.movement_y == 0)
 235                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x == 0 && self.movement_y > 0)
 237                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x == 0 && self.movement_y < 0)
 239                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x > 0 && self.movement_y > 0)
 241                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x > 0 && self.movement_y < 0)
 243                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 244                         else if (self.movement_x < 0 && self.movement_y > 0)
 245                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 246                         else if (self.movement_x < 0 && self.movement_y < 0)
 247                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 248                         else
 249                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 250                 }
 251                 else
 252                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 253         }
 254
 255         if (self.weaponentity)
 256         if (!self.weaponentity.animstate_override)
 257                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 258 }
 259
 260 void SpawnThrownWeapon (vector org, float w)
 261 {
 262         if(g_pinata)
 263         {
 264                 float j;
 265                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 266                 {
 267                         if(self.weapons & W_WeaponBit(j))
 268                                 if(W_IsWeaponThrowable(j))
 269                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 270                 }
 271         }
 272         else
 273                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 274 }
 275
 276 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 277 {
 278         local float take, save;
 279         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16);
 280
 281         // damage resistance (ignore most of the damage from a bullet or similar)
 282         damage = max(damage - 5, 1);
 283
 284         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 285         take = bound(0, damage - save, damage);
 286
 287         if (save > 10)
 288                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 289         else if (take > 30)
 290                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 291         else if (take > 10)
 292                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 293
 294         if (take > 50)
 295                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1);
 296         if (take > 100)
 297                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1);
 298
 299         if (!(self.flags & FL_GODMODE))
 300         {
 301                 self.armorvalue = self.armorvalue - save;
 302                 self.health = self.health - take;
 303                 // pause regeneration for 5 seconds
 304                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 305         }
 306         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 307         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 308         self.dmg_inflictor = inflictor;
 309
 310         if (self.health <= -75 && self.modelindex != 0)
 311         {
 312                 // don't use any animations as a gib
 313                 self.frame = 0;
 314                 self.dead_frame = 0;
 315                 // view just above the floor
 316                 self.view_ofs = '0 0 4';
 317
 318                 Violence_GibSplash(self, 1, 1);
 319                 self.modelindex = 0; // restore later
 320                 self.solid = SOLID_NOT; // restore later
 321         }
 322 }
 323
 324 void ClientKill_Now_TeamChange();
 325
 326 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 327 {
 328         local float take, save, waves, sdelay;
 329
 330         if(!DEATH_ISSPECIAL(deathtype))
 331         {
 332                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 333                 if(self != attacker)
 334                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 335         }
 336
 337         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 338         {
 339                 // tuba causes blood to come out of the ears
 340                 vector ear1, ear2;
 341                 vector d;
 342                 float f;
 343                 ear1 = self.origin;
 344                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 345                 ear2 = ear1;
 346                 makevectors(self.angles);
 347                 ear1 += v_right * -10;
 348                 ear2 += v_right * +10;
 349                 d = inflictor.origin - self.origin;
 350                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 351                 force = v_right * vlen(force);
 352                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f));
 353                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f));
 354                 if(f > 0)
 355                 {
 356                         hitloc = ear1;
 357                         force = force * -1;
 358                 }
 359                 else
 360                 {
 361                         hitloc = ear2;
 362                         // force is already good
 363                 }
 364         }
 365         else
 366                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16);
 367
 368         if(g_arena)
 369         if(numspawned < 2)
 370                 return;
 371
 372         if (!g_minstagib)
 373         {
 374                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 375                 take = bound(0, damage - save, damage);
 376         }
 377         else
 378         {
 379                 save = 0;
 380                 take = damage;
 381         }
 382
 383         if (save > 10)
 384                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 385         else if (take > 30)
 386                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 387         else if (take > 10)
 388                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 389
 390         if (take > 50)
 391                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1);
 392         if (take > 100)
 393                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1);
 394
 395         if (time > self.spawnshieldtime)
 396         {
 397                 if (!(self.flags & FL_GODMODE))
 398                 {
 399                         self.armorvalue = self.armorvalue - save;
 400                         self.health = self.health - take;
 401                         // pause regeneration for 5 seconds
 402                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 403
 404                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 405                         {
 406                                 self.pain_finished = time + 0.5;        //Supajoe
 407
 408                                 if(sv_gentle < 1) {
 409                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 410                                         {
 411                                                 if (random() > 0.5)
 412                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 413                                                 else
 414                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 415                                         }
 416
 417                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 418                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 419                                         {
 420                                                 if(self.health > 75) // TODO make a "gentle" version?
 421                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 422                                                 else if(self.health > 50)
 423                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 424                                                 else if(self.health > 25)
 425                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 426                                                 else if(self.health > 1)
 427                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 428                                         }
 429                                 }
 430
 431                                 // throw off bot aim temporarily
 432                                 local float shake;
 433                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 434                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 435                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 436                         }
 437                 }
 438                 else
 439                         self.max_armorvalue += (save + take);
 440         }
 441         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 442         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 443         self.dmg_inflictor = inflictor;
 444
 445         if(attacker == self)
 446         {
 447                 // don't reset pushltime for self damage as it may be an attempt to
 448                 // escape a lava pit or similar
 449                 //self.pushltime = 0;
 450         }
 451         else if(attacker.classname == "player" || attacker.classname == "gib")
 452         {
 453                 self.pusher = attacker;
 454                 self.pushltime = time + cvar("g_maxpushtime");
 455         }
 456         else if(time < self.pushltime)
 457         {
 458                 attacker = self.pusher;
 459                 self.pushltime = max(self.pushltime, time + 0.6);
 460         }
 461         else
 462                 self.pushltime = 0;
 463
 464         if (self.health < 1)
 465         {
 466                 float defer_ClientKill_Now_TeamChange;
 467                 defer_ClientKill_Now_TeamChange = FALSE;
 468
 469                 if(sv_gentle < 1) // TODO make a "gentle" version?
 470                 {
 471                         if(deathtype == DEATH_DROWN)
 472                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 473                         else
 474                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 475                 }
 476
 477                 // get rid of kill indicator
 478                 if(self.killindicator)
 479                 {
 480                         remove(self.killindicator);
 481                         self.killindicator = world;
 482                         if(self.killindicator_teamchange)
 483                                 defer_ClientKill_Now_TeamChange = TRUE;
 484
 485                         if(self.classname == "body")
 486                         if(deathtype == DEATH_KILL)
 487                         {
 488                                 // for the lemmings fans, a small harmless explosion
 489                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 490                         }
 491                 }
 492
 493                 // become fully visible
 494                 self.alpha = 1;
 495                 // clear selected player display
 496                 ClearSelectedPlayer();
 497                 // throw a weapon
 498                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 499                 // print an obituary message
 500                 Obituary (attacker, inflictor, self, deathtype);
 501                 race_PreDie();
 502                 DropAllRunes(self);
 503                 if(self == attacker)
 504                         kh_Key_DropAll(self, TRUE);
 505                 else if(attacker.classname == "player" || attacker.classname == "gib")
 506                         kh_Key_DropAll(self, FALSE);
 507                 else
 508                         kh_Key_DropAll(self, TRUE);
 509                 if(self.flagcarried)
 510                 {
 511                         if(attacker.classname != "player" && attacker.classname != "gib")
 512                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 513                         else if(attacker.team == self.team)
 514                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 515                         else
 516                                 DropFlag(self.flagcarried, world, attacker);
 517                 }
 518                 if(self.ballcarried)
 519                         DropBall(self.ballcarried, self.origin, self.velocity);
 520                 Portal_ClearAllLater(self);
 521                 // clear waypoints
 522                 WaypointSprite_PlayerDead();
 523                 // make the corpse upright (not tilted)
 524                 self.angles_x = 0;
 525                 self.angles_z = 0;
 526                 // don't spin
 527                 self.avelocity = '0 0 0';
 528                 // view from the floor
 529                 self.view_ofs = '0 0 -8';
 530                 // toss the corpse
 531                 self.movetype = MOVETYPE_TOSS;
 532                 // shootable corpse
 533                 self.solid = SOLID_CORPSE;
 534                 // don't stick to the floor
 535                 self.flags &~= FL_ONGROUND;
 536                 // dying animation
 537                 self.deadflag = DEAD_DYING;
 538                 // when to allow respawn
 539                 sdelay = 0;
 540                 waves = 0;
 541                 if(cvar("g_respawn_mapsettings"))
 542                 {
 543                         sdelay = cvar("g_respawn_mapsettings_delay");
 544                         waves = cvar("g_respawn_mapsettings_waves");
 545                 }
 546                 if(!sdelay)
 547                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 548                 if(!sdelay)
 549                         sdelay = cvar("g_respawn_delay");
 550                 if(!waves)
 551                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 552                 if(!waves)
 553                         waves = cvar("g_respawn_waves");
 554                 if(waves)
 555                         self.death_time = ceil((time + sdelay) / waves) * waves;
 556                 else
 557                         self.death_time = time + sdelay;
 558                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 559                         self.respawn_countdown = 10; // first number to count down from is 10
 560                 else
 561                         self.respawn_countdown = -1; // do not count down
 562                 if (random() < 0.5)
 563                 {
 564                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 565                         self.dead_frame = self.anim_dead1_x;
 566                 }
 567                 else
 568                 {
 569                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 570                         self.dead_frame = self.anim_dead2_x;
 571                 }
 572                 // set damage function to corpse damage
 573                 self.event_damage = PlayerCorpseDamage;
 574                 // call the corpse damage function just in case it wants to gib
 575                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 576                 // set up to fade out later
 577                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 578
 579                 // remove laserdot
 580                 if(self.weaponentity)
 581                         if(self.weaponentity.lasertarget)
 582                                 remove(self.weaponentity.lasertarget);
 583
 584                 if(clienttype(self) == CLIENTTYPE_REAL)
 585                 {
 586                         self.fixangle = TRUE;
 587                         //msg_entity = self;
 588                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 589                         //WriteAngle (MSG_ONE, self.v_angle_x);
 590                         //WriteAngle (MSG_ONE, self.v_angle_y);
 591                         //WriteAngle (MSG_ONE, 80);
 592                 }
 593
 594                 if(g_arena)
 595                         Spawnqueue_Unmark(self);
 596
 597                 if(defer_ClientKill_Now_TeamChange)
 598                         ClientKill_Now_TeamChange();
 599
 600                 if(sv_gentle > 0) {
 601                         // remove corpse
 602                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 603                 }
 604         }
 605 }
 606
 607 float UpdateSelectedPlayer_countvalue(float v)
 608 {
 609         return max(0, (v - 1.0) / 0.5);
 610 }
 611
 612 // returns: -2 if no hit, otherwise cos of the angle
 613 // uses the global v_angle
 614 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 615 {
 616         vector so, d;
 617         float c;
 618
 619         if(p == self)
 620                 return -2;
 621
 622         if(p.deadflag)
 623                 return -2;
 624
 625         so = self.origin + self.view_ofs;
 626         d = p.origin - so;
 627
 628         // misaimed?
 629         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 630                 return -2;
 631
 632         // now find the cos of the angle...
 633         c = normalize(d) * v_forward;
 634
 635         if(c <= mincosangle)
 636                 return -2;
 637
 638         // not visible in any way? forget it
 639         if(!checkpvs(so, p))
 640                 return -2;
 641
 642         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 643         if(trace_fraction < 1)
 644                 return -2;
 645
 646         return c;
 647 }
 648
 649 void ClearSelectedPlayer()
 650 {
 651         if(self.selected_player)
 652         {
 653                 centerprint_expire(self, CENTERPRIO_POINT);
 654                 self.selected_player = world;
 655                 self.selected_player_display_needs_update = FALSE;
 656         }
 657 }
 658
 659 void UpdateSelectedPlayer()
 660 {
 661         entity selected;
 662         float selected_score;
 663         selected = world;
 664         selected_score = 0.95; // 18 degrees
 665
 666         if(!cvar("sv_allow_shownames"))
 667                 return;
 668
 669         if(clienttype(self) != CLIENTTYPE_REAL)
 670                 return;
 671
 672         if(self.cvar_cl_shownames == 0)
 673                 return;
 674
 675         if(self.cvar_cl_shownames == 1 && !teams_matter)
 676                 return;
 677
 678         makevectors(self.v_angle); // sets v_forward
 679
 680         // 1. cursor trace is always right
 681         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 682         {
 683                 selected = self.cursor_trace_ent;
 684         }
 685         else
 686         {
 687                 // 2. if we don't have a cursor trace, find the player which is least
 688                 //    mis-aimed at
 689                 entity p;
 690                 FOR_EACH_PLAYER(p)
 691                 {
 692                         float c;
 693                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 694                         if(c >= -1)
 695                         {
 696                                 selected = p;
 697                                 selected_score = c;
 698                         }
 699                 }
 700         }
 701
 702         if(selected)
 703         {
 704                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 705         }
 706         else
 707         {
 708                 if(time < self.selected_player_display_timeout)
 709                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 710                                 selected = self.selected_player;
 711         }
 712
 713         if(selected)
 714         {
 715                 if(selected == self.selected_player)
 716                 {
 717                         float save;
 718                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 719                         self.selected_player_count = self.selected_player_count + frametime;
 720                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 721                         {
 722                                 string namestr, healthstr;
 723                                 namestr = playername(selected);
 724                                 if(teams_matter)
 725                                 {
 726                                         healthstr = ftos(floor(selected.health));
 727                                         if(self.team == selected.team)
 728                                         {
 729                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 730                                                 self.selected_player_display_needs_update = TRUE;
 731                                         }
 732                                 }
 733                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 734                         }
 735                 }
 736                 else
 737                 {
 738                         ClearSelectedPlayer();
 739                         self.selected_player = selected;
 740                         self.selected_player_time = time;
 741                         self.selected_player_count = 0;
 742                         self.selected_player_display_needs_update = FALSE;
 743                 }
 744         }
 745         else
 746         {
 747                 ClearSelectedPlayer();
 748         }
 749
 750         if(self.selected_player)
 751                 self.last_selected_player = self.selected_player;
 752 }
 753
 754 .float muted; // to be used by prvm_edictset server playernumber muted 1
 755 void Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 756 {
 757         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 758         float flood, privatemsgprefixlen;
 759         entity head;
 760
 761         if(Ban_MaybeEnforceBan(source))
 762                 return;
 763
 764         if(!teamsay && !privatesay)
 765                 if(substring(msgin, 0, 1) == " ")
 766                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 767
 768         msgin = formatmessage(msgin);
 769
 770         if(msgin == "")
 771                 return;
 772
 773         if(source.classname != "player")
 774                 colorstr = "^0"; // black for spectators
 775         else if(teams_matter)
 776                 colorstr = Team_ColorCode(source.team);
 777         else
 778                 teamsay = FALSE;
 779
 780         if(intermission_running)
 781                 teamsay = FALSE;
 782
 783         /*
 784          * using bprint solves this... me stupid
 785         // how can we prevent the message from appearing in a listen server?
 786         // for now, just give "say" back and only handle say_team
 787         if(!teamsay)
 788         {
 789                 clientcommand(self, strcat("say ", msgin));
 790                 return;
 791         }
 792         */
 793
 794         if(cvar("g_chat_teamcolors"))
 795                 namestr = playername(source);
 796         else
 797                 namestr = source.netname;
 798
 799         if(privatesay)
 800         {
 801                 msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 802                 privatemsgprefixlen = strlen(msgstr);
 803                 msgstr = strcat(msgstr, msgin);
 804                 cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 805                 if(cvar("g_chat_teamcolors"))
 806                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 807                 else
 808                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 809         }
 810         else if(teamsay)
 811         {
 812                 msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 813                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 814         }
 815         else
 816         {
 817                 msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 818                 cmsgstr = "";
 819         }
 820
 821         msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 822         fullmsgstr = msgstr;
 823         fullcmsgstr = cmsgstr;
 824
 825         // FLOOD CONTROL
 826         flood = 0;
 827         if(floodcontrol)
 828         {
 829                 float flood_spl;
 830                 float flood_burst;
 831                 float flood_lmax;
 832                 var .float flood_field;
 833                 float lines;
 834                 if(privatesay)
 835                 {
 836                         flood_spl = cvar("g_chat_flood_spl_tell");
 837                         flood_burst = cvar("g_chat_flood_burst_tell");
 838                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 839                         flood_field = floodcontrol_chattell;
 840                 }
 841                 else if(teamsay)
 842                 {
 843                         flood_spl = cvar("g_chat_flood_spl_team");
 844                         flood_burst = cvar("g_chat_flood_burst_team");
 845                         flood_lmax = cvar("g_chat_flood_lmax_team");
 846                         flood_field = floodcontrol_chatteam;
 847                 }
 848                 else
 849                 {
 850                         flood_spl = cvar("g_chat_flood_spl");
 851                         flood_burst = cvar("g_chat_flood_burst");
 852                         flood_lmax = cvar("g_chat_flood_lmax");
 853                         flood_field = floodcontrol_chat;
 854                 }
 855                 flood_burst = max(0, flood_burst - 1);
 856                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 857
 858                 // do flood control for the default line size
 859                 getWrappedLine_remaining = msgstr;
 860                 msgstr = "";
 861                 lines = 0;
 862                 while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 863                 {
 864                         msgstr = strcat(msgstr, " ", getWrappedLine(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 865                         ++lines;
 866                 }
 867                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 868
 869                 if(getWrappedLine_remaining != "")
 870                 {
 871                         msgstr = strcat(msgstr, "\n");
 872                         flood = 2;
 873                 }
 874
 875                 if(time >= source.flood_field)
 876                 {
 877                         source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 878                 }
 879                 else
 880                 {
 881                         flood = 1;
 882                         msgstr = fullmsgstr;
 883                 }
 884         }
 885
 886         if (timeoutStatus == 2) //when game is paused, no flood protection
 887                 source.flood_field = flood = 0;
 888
 889         if(flood == 2)
 890         {
 891                 if(cvar("g_chat_flood_notify_flooder"))
 892                 {
 893                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 894                         sourcecmsgstr = "";
 895                 }
 896                 else
 897                 {
 898                         sourcemsgstr = fullmsgstr;
 899                         sourcecmsgstr = fullcmsgstr;
 900                 }
 901                 cmsgstr = "";
 902         }
 903         else
 904         {
 905                 sourcemsgstr = msgstr;
 906                 sourcecmsgstr = cmsgstr;
 907         }
 908
 909         if(!privatesay)
 910         if(source.classname != "player")
 911         {
 912                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
 913                         teamsay = -1; // spectators
 914         }
 915
 916         if(flood)
 917                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 918
 919         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 920         if(privatesay)
 921                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 922
 923         if(source.muted)
 924         {
 925                 // always fake the message
 926                 sprint(source, sourcemsgstr);
 927                 if(cmsgstr != "" && !privatesay)
 928                         centerprint(source, sourcecmsgstr);
 929         }
 930         else if(flood == 1)
 931         {
 932                 if(cvar("g_chat_flood_notify_flooder"))
 933                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 934                 else
 935                 {
 936                         sprint(source, sourcemsgstr);
 937                         if(cmsgstr != "" && !privatesay)
 938                                 centerprint(source, sourcecmsgstr);
 939                 }
 940         }
 941         else if(privatesay)
 942         {
 943                 sprint(source, sourcemsgstr);
 944                 sprint(privatesay, msgstr);
 945                 if(cmsgstr != "")
 946                         centerprint(privatesay, cmsgstr);
 947         }
 948         else if(teamsay > 0)
 949         {
 950                 sprint(source, sourcemsgstr);
 951                 if(sourcecmsgstr != "")
 952                         centerprint(source, sourcecmsgstr);
 953                 FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 954                         if(head != source)
 955                         {
 956                                 sprint(head, msgstr);
 957                                 if(cmsgstr != "")
 958                                         centerprint(head, cmsgstr);
 959                         }
 960         }
 961         else if(teamsay < 0)
 962         {
 963                 sprint(source, sourcemsgstr);
 964                 FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 965                         if(head != source)
 966                                 sprint(head, msgstr);
 967         }
 968         else if(sourcemsgstr != msgstr)
 969         {
 970                 sprint(source, sourcemsgstr);
 971                 FOR_EACH_REALCLIENT(head)
 972                         if(head != source)
 973                                 sprint(head, msgstr);
 974         }
 975         else
 976                 bprint(msgstr);
 977 }
 978
 979 float GetVoiceMessageVoiceType(string type)
 980 {
 981         if(type == "taunt")
 982                 return VOICETYPE_TAUNT;
 983         if(type == "teamshoot")
 984                 return VOICETYPE_LASTATTACKER;
 985         return VOICETYPE_TEAMRADIO;
 986 }
 987
 988 string allvoicesamples;
 989 float GetPlayerSoundSampleField_notFound;
 990 float GetPlayerSoundSampleField_fixed;
 991 .string GetVoiceMessageSampleField(string type)
 992 {
 993         GetPlayerSoundSampleField_notFound = 0;
 994         GetPlayerSoundSampleField_fixed = 0;
 995         switch(type)
 996         {
 997 #define _VOICEMSG(m) case #m: return playersound_##m;
 998                 ALLVOICEMSGS
 999 #undef _VOICEMSG
1000         }
1001         GetPlayerSoundSampleField_notFound = 1;
1002         return playersound_taunt;
1003 }
1004
1005 .string GetPlayerSoundSampleField(string type)
1006 {
1007         GetPlayerSoundSampleField_notFound = 0;
1008         GetPlayerSoundSampleField_fixed = 0;
1009         switch(type)
1010         {
1011 #define _VOICEMSG(m) case #m: return playersound_##m;
1012                 ALLPLAYERSOUNDS
1013 #undef _VOICEMSG
1014         }
1015         GetPlayerSoundSampleField_notFound = 1;
1016         return playersound_taunt;
1017 }
1018
1019 void PrecacheGlobalSound(string samplestring)
1020 {
1021         float n, i;
1022         tokenize_console(samplestring);
1023         n = stof(argv(1));
1024         if(n > 0)
1025         {
1026                 for(i = 1; i <= n; ++i)
1027                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1028         }
1029         else
1030         {
1031                 precache_sound(strcat(argv(0), ".wav"));
1032         }
1033 }
1034
1035 void PrecachePlayerSounds(string f)
1036 {
1037         float fh;
1038         string s;
1039         fh = fopen(f, FILE_READ);
1040         if(fh < 0)
1041                 return;
1042         while((s = fgets(fh)))
1043         {
1044                 if(tokenize_console(s) != 3)
1045                 {
1046                         dprint("Invalid sound info line: ", s, "\n");
1047                         continue;
1048                 }
1049                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1050         }
1051         fclose(fh);
1052
1053         if not(allvoicesamples)
1054         {
1055 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1056                 ALLVOICEMSGS
1057 #undef _VOICEMSG
1058                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1059         }
1060 }
1061
1062 void ClearPlayerSounds()
1063 {
1064 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1065         ALLPLAYERSOUNDS
1066         ALLVOICEMSGS
1067 #undef _VOICEMSG
1068 }
1069
1070 void LoadPlayerSounds(string f, float first)
1071 {
1072         float fh;
1073         string s;
1074         var .string field;
1075         fh = fopen(f, FILE_READ);
1076         if(fh < 0)
1077                 return;
1078         while((s = fgets(fh)))
1079         {
1080                 if(tokenize_console(s) != 3)
1081                         continue;
1082                 field = GetPlayerSoundSampleField(argv(0));
1083                 if(GetPlayerSoundSampleField_notFound)
1084                         field = GetVoiceMessageSampleField(argv(0));
1085                 if(GetPlayerSoundSampleField_notFound)
1086                         continue;
1087                 if(GetPlayerSoundSampleField_fixed)
1088                         if not(first)
1089                                 continue;
1090                 if(self.field)
1091                         strunzone(self.field);
1092                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1093         }
1094         fclose(fh);
1095 }
1096
1097 .float modelindex_for_playersound;
1098 void UpdatePlayerSounds()
1099 {
1100         if(self.modelindex == self.modelindex_for_playersound)
1101                 return;
1102         self.modelindex_for_playersound = self.modelindex;
1103         ClearPlayerSounds();
1104         LoadPlayerSounds("sound/player/default.sounds", 1);
1105         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
1106 }
1107
1108 void GlobalSound(string sample, float chan, float voicetype)
1109 {
1110         float n;
1111         float tauntrand;
1112
1113         if(sample == "")
1114                 return;
1115
1116         tokenize_console(sample);
1117         n = stof(argv(1));
1118         if(n > 0)
1119                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1120         else
1121                 sample = strcat(argv(0), ".wav"); // randomization
1122
1123         switch(voicetype)
1124         {
1125                 case VOICETYPE_LASTATTACKER_ONLY:
1126                         if(self.pusher)
1127                                 if(self.pusher.team == self.team)
1128                                 {
1129                                         msg_entity = self.pusher;
1130                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1131                                         {
1132                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1133                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1134                                                 else
1135                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1136                                         }
1137                                 }
1138                         break;
1139                 case VOICETYPE_LASTATTACKER:
1140                         if(self.pusher)
1141                                 if(self.pusher.team == self.team)
1142                                 {
1143                                         msg_entity = self.pusher;
1144                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1145                                         {
1146                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1147                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1148                                                 else
1149                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1150                                         }
1151                                         msg_entity = self;
1152                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1153                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1154                                 }
1155                         break;
1156                 case VOICETYPE_TEAMRADIO:
1157                         FOR_EACH_REALCLIENT(msg_entity)
1158                                 if(!teams_matter || msg_entity.team == self.team)
1159                                 {
1160                                         if(msg_entity.cvar_cl_voice_directional == 1)
1161                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1162                                         else
1163                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1164                                 }
1165                         break;
1166                 case VOICETYPE_AUTOTAUNT:
1167                         tauntrand = random();
1168                         FOR_EACH_REALCLIENT(msg_entity)
1169                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1170                                 {
1171                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1172                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1173                                         else
1174                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1175                                 }
1176                         break;
1177                 case VOICETYPE_TAUNT:
1178                         FOR_EACH_REALCLIENT(msg_entity)
1179                         {
1180                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1181                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1182                                 else
1183                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1184                         }
1185                 case VOICETYPE_PLAYERSOUND:
1186                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1187                         break;
1188                 default:
1189                         backtrace("Invalid voice type!");
1190                         break;
1191         }
1192 }
1193
1194 void PlayerSound(.string samplefield, float chan, float voicetype)
1195 {
1196         string sample;
1197         sample = self.samplefield;
1198         GlobalSound(sample, chan, voicetype);
1199 }
1200
1201 void VoiceMessage(string type, string msg)
1202 {
1203         var .string sample;
1204         var float voicetype, ownteam;
1205         sample = GetVoiceMessageSampleField(type);
1206
1207         if(GetPlayerSoundSampleField_notFound)
1208         {
1209                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1210                 return;
1211         }
1212
1213         voicetype = GetVoiceMessageVoiceType(type);
1214         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1215
1216         float flood;
1217         float flood_spv;
1218         var .float flood_field;
1219
1220         flood = 0;
1221         if(ownteam)
1222         {
1223                 flood_spv = cvar("g_voice_flood_spv_team");
1224                 flood_field = floodcontrol_voiceteam;
1225         }
1226         else
1227         {
1228                 flood_spv = cvar("g_voice_flood_spv");
1229                 flood_field = floodcontrol_voice;
1230         }
1231
1232         if(time >= self.flood_field)
1233                 self.flood_field = max(time, self.flood_field) + flood_spv;
1234         else
1235                 flood = 1;
1236
1237         if (timeoutStatus == 2) //when game is paused, no flood protection
1238                 self.flood_field = flood = 0;
1239
1240         if (msg != "")
1241                 Say(self, ownteam, world, msg, 0);
1242
1243         if (!flood)
1244                 PlayerSound(sample, CHAN_VOICE, voicetype);
1245 }