data/qcsrc/server/cl_player.qc

   1 $frame die1 die2 draw duck duckwalk duckjump duckidle idle
   2 $frame jump pain1 pain2 shoot taunt run runbackwards
   3 $frame strafeleft straferight dead1 dead2 forwardright
   4 $frame forwardleft backright backleft
   5
   6 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   7 // merged player_run and player_stand to player_anim
   8 // added death animations to player_anim
   9 // can now spawn thrown weapons from anywhere, not just from players
  10 // thrown weapons now fade out after 20 seconds
  11 // created PlayerGib function
  12 // PlayerDie no longer uses hitloc or damage
  13 // PlayerDie now supports dying animations as well as gibbing
  14 // cleaned up PlayerDie a lot
  15 // added CopyBody
  16
  17 .entity pusher;
  18 .float pushltime;
  19
  20 void CopyBody(float keepvelocity)
  21 {
  22         local entity oldself;
  23         if (self.effects & EF_NODRAW)
  24                 return;
  25         oldself = self;
  26         self = spawn();
  27         self.colormap = oldself.colormap;
  28         self.iscreature = oldself.iscreature;
  29         self.angles = oldself.angles;
  30         self.avelocity = oldself.avelocity;
  31         self.classname = "body";
  32         self.damageforcescale = oldself.damageforcescale;
  33         self.effects = oldself.effects;
  34         self.event_damage = oldself.event_damage;
  35         self.frame = oldself.frame;
  36         self.health = oldself.health;
  37         self.armorvalue = oldself.armorvalue;
  38         self.armortype = oldself.armortype;
  39         self.model = oldself.model;
  40         self.modelindex = oldself.modelindex;
  41         self.movetype = oldself.movetype;
  42         self.nextthink = oldself.nextthink;
  43         self.skin = oldself.skin;
  44         self.solid = oldself.solid;
  45         self.takedamage = oldself.takedamage;
  46         self.think = oldself.think;
  47         if (keepvelocity == 1)
  48                 self.velocity = oldself.velocity;
  49         self.oldvelocity = self.velocity;
  50         self.fade_time = oldself.fade_time;
  51         self.fade_rate = oldself.fade_rate;
  52         //self.weapon = oldself.weapon;
  53         setorigin(self, oldself.origin);
  54         setsize(self, oldself.mins, oldself.maxs);
  55         self.oldorigin = oldself.origin;
  56         self = oldself;
  57 }
  58
  59 void player_anim (void)
  60 {
  61         if (self.deadflag != DEAD_NO)
  62         {
  63                 if (time > self.dead_time)
  64                 {
  65                         if (self.maxs_z > 5)
  66                         {
  67                                 self.maxs_z = 5;
  68                                 setsize(self, self.mins, self.maxs);
  69                         }
  70                         self.frame = self.dead_frame;
  71                 }
  72                 else
  73                         self.frame = self.die_frame;
  74                 return;
  75         }
  76
  77
  78         if (self.crouch)
  79         {
  80                 if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
  81                         self.frame = $duckwalk;
  82                 else
  83                         self.frame = $duckidle;
  84         }
  85         else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
  86         {
  87                 if (self.movement_x > 0 && self.movement_y == 0)
  88                         self.frame = $run;
  89                 else if (self.movement_x < 0 && self.movement_y == 0)
  90                         self.frame = $runbackwards;
  91                 else if (self.movement_x == 0 && self.movement_y > 0)
  92                         self.frame = $straferight;
  93                 else if (self.movement_x == 0 && self.movement_y < 0)
  94                         self.frame = $strafeleft;
  95                 else if (self.movement_x > 0 && self.movement_y > 0)
  96                         self.frame = $forwardright;
  97                 else if (self.movement_x > 0 && self.movement_y < 0)
  98                         self.frame = $forwardleft;
  99                 else if (self.movement_x < 0 && self.movement_y > 0)
 100                         self.frame = $backright;
 101                 else if (self.movement_x < 0 && self.movement_y < 0)
 102                         self.frame = $backleft;
 103                 else
 104                         self.frame = $run;
 105         }
 106         else if (self.pain_finished > time)
 107                 self.frame = self.pain_frame;
 108         else if (self.attack_finished > time)
 109                 self.frame = $shoot;
 110         else
 111                 self.frame = $idle;
 112
 113         if (!(self.flags & FL_ONGROUND))
 114         {
 115                 if (self.crouch)
 116                         self.frame = $duckidle;         // if player is crouching while in air, show crouch frame
 117                 else
 118                         self.frame = $jump;
 119         }
 120 }
 121 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 122
 123 void SpawnThrownWeapon (vector org, float w)
 124 {
 125         if (!cvar("g_pickup_items"))
 126         if (!cvar("g_minstagib"))
 127                 return;
 128         if (!w)
 129                 return;
 130         if (w == IT_LASER)
 131                 return;
 132
 133         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 134 }
 135
 136 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 137 {
 138         local float take, save;
 139         te_blood (hitloc, force, damage);
 140         // damage resistance (ignore most of the damage from a bullet or similar)
 141         damage = max(damage - 5, 1);
 142
 143         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 144         take = bound(0, damage - save, damage);
 145
 146         if (save > 10)
 147                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 148         else if (take > 30)
 149                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 150         else if (take > 10)
 151                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 152
 153         if (take > 50)
 154                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 155         if (take > 100)
 156                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 157
 158         if (!(self.flags & FL_GODMODE))
 159         {
 160                 self.armorvalue = self.armorvalue - save;
 161                 self.health = self.health - take;
 162                 // pause regeneration for 5 seconds
 163                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 164         }
 165         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 166         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 167         self.dmg_inflictor = inflictor;
 168
 169         if (self.health <= -50)
 170         {
 171                 // don't use any animations as a gib
 172                 self.frame = 0;
 173                 self.dead_frame = 0;
 174                 self.die_frame = 0;
 175                 // view just above the floor
 176                 self.view_ofs = '0 0 4';
 177
 178                 // make a juicy mess
 179                 local float multiplier;
 180                 multiplier = 1;
 181                 if (cvar("ekg"))
 182                         multiplier = 5;
 183                 te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 184
 185                 // make a meaty mess
 186                 TossGib (self, "models/gibs/eye.md3", self.origin, self.velocity,0);
 187                 TossGib (world, "models/gibs/bloodyskull.md3", self.origin, '0 0 600',0);
 188
 189                 local float c;
 190                 c = 0;
 191                 while (c < multiplier)
 192                 {
 193                         c = c + 1;
 194                         TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity,0);
 195                         //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity,0);
 196                         TossGib (world, "models/gibs/gib1.mdl", self.origin, self.velocity,0);
 197                         //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity,0);
 198                         TossGib (world, "models/gibs/gib2.mdl", self.origin, self.velocity,0);
 199                         //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity,0);
 200                         TossGib (world, "models/gibs/gib3.mdl", self.origin, self.velocity,0);
 201
 202                         // these destory on impact
 203                         TossGib (world, "models/gibs/gib5.md3", self.origin, '-500 0 450',1);
 204                         //TossGib (world, "models/gibs/gib6.md3", self.origin, '0 500 450',1);
 205                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 -500 450',1);
 206                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '500 0 450',1);
 207                         TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity,1);
 208                         TossGib (world, "models/gibs/chunk.mdl", self.origin, '0 0 450',1);
 209                 }
 210
 211                 sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 212         }
 213 }
 214
 215 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 216 {
 217         local float take, save, waves, sdelay;
 218
 219         te_blood (hitloc, force, damage);
 220         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 221         {
 222                 if (random() > 0.5)
 223                         self.pain_frame = $pain1;
 224                 else
 225                         self.pain_frame = $pain2;
 226                 self.pain_finished = time + 0.5;        //Supajoe
 227
 228                 // throw off bot aim temporarily
 229                 local float shake;
 230                 shake = damage * 5 / (bound(0,skill,100) + 1);
 231                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 232                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 233         }
 234
 235         if(cvar("g_arena"))
 236         if(numspawned < 2)
 237                 return;
 238
 239         if (!cvar("g_minstagib"))
 240         {
 241                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 242                 take = bound(0, damage - save, damage);
 243         }
 244         else
 245         {
 246                 save = 0;
 247                 take = damage;
 248         }
 249
 250         if (save > 10)
 251                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 252         else if (take > 30)
 253                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 254         else if (take > 10)
 255                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 256
 257         if (take > 50)
 258                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 259         if (take > 100)
 260                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 261
 262         if (!(self.flags & FL_GODMODE))
 263         if (time > self.spawnshieldtime)
 264         {
 265                 self.armorvalue = self.armorvalue - save;
 266                 self.health = self.health - take;
 267                 // pause regeneration for 5 seconds
 268                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 269         }
 270         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 271         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 272         self.dmg_inflictor = inflictor;
 273
 274         if(attacker == self)
 275         {
 276                 // don't reset pushltime for self damage as it may be an attempt to
 277                 // escape a lava pit or similar
 278                 //self.pushltime = 0;
 279         }
 280         else if(attacker.classname == "player" || attacker.classname == "gib")
 281         {
 282                 self.pusher = attacker;
 283                 self.pushltime = time + cvar("g_maxpushtime");
 284         }
 285         else if(time < self.pushltime)
 286         {
 287                 attacker = self.pusher;
 288                 self.pushltime = max(self.pushltime, time + 0.6);
 289         }
 290         else
 291                 self.pushltime = 0;
 292
 293         if (self.health < 1)
 294         {
 295                 self.deaths += 1;
 296
 297                 // become fully visible
 298                 self.alpha = 1;
 299                 // clear selected player display
 300                 ClearSelectedPlayer();
 301                 // throw a weapon
 302                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 303                 // print an obituary message
 304                 Obituary (attacker, self, deathtype);
 305                 DropAllRunes(self);
 306                 kh_Key_DropAll(self);
 307                 if(self.flagcarried)
 308                         DropFlag(self.flagcarried);
 309                 // clear waypoints
 310                 WaypointSprite_PlayerDead();
 311                 // make the corpse upright (not tilted)
 312                 self.angles_x = 0;
 313                 self.angles_z = 0;
 314                 // don't spin
 315                 self.avelocity = '0 0 0';
 316                 // view from the floor
 317                 self.view_ofs = '0 0 -8';
 318                 // toss the corpse
 319                 self.movetype = MOVETYPE_TOSS;
 320                 // shootable corpse
 321                 self.solid = SOLID_CORPSE;
 322                 // don't stick to the floor
 323                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 324                 // dying animation
 325                 self.deadflag = DEAD_DYING;
 326                 // when to allow respawn
 327                 sdelay = 0;
 328                 waves = 0;
 329                 if(cvar("g_respawn_mapsettings"))
 330                 {
 331                         sdelay = cvar("g_respawn_mapsettings_delay");
 332                         waves = cvar("g_respawn_mapsettings_waves");
 333                 }
 334                 if(!sdelay)
 335                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 336                 if(!sdelay)
 337                         sdelay = cvar("g_respawn_delay");
 338                 if(!waves)
 339                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 340                 if(!waves)
 341                         waves = cvar("g_respawn_waves");
 342                 if(waves)
 343                         self.death_time = ceil((time + sdelay) / waves) * waves;
 344                 else
 345                         self.death_time = time + sdelay;
 346                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 347                         self.respawn_countdown = 10; // first number to count down from is 10
 348                 else
 349                         self.respawn_countdown = -1; // do not count down
 350                 // when to switch to the dead_frame
 351                 self.dead_time = time + 2;
 352                 if (random() < 0.5)
 353                 {
 354                         self.die_frame = $die1;
 355                         self.dead_frame = $dead1;
 356                 }
 357                 else
 358                 {
 359                         self.die_frame = $die2;
 360                         self.dead_frame = $dead2;
 361                 }
 362                 // start the animation
 363                 player_anim();
 364                 // set damage function to corpse damage
 365                 self.event_damage = PlayerCorpseDamage;
 366                 // call the corpse damage function just in case it wants to gib
 367                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 368                 // set up to fade out later
 369                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 370
 371                 // remove laserdot
 372                 if(self.weaponentity)
 373                         if(self.weaponentity.lasertarget)
 374                                 remove(self.weaponentity.lasertarget);
 375
 376                 if(clienttype(self) == CLIENTTYPE_REAL)
 377                 {
 378                         self.fixangle = TRUE;
 379                         //msg_entity = self;
 380                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 381                         //WriteAngle (MSG_ONE, self.v_angle_x);
 382                         //WriteAngle (MSG_ONE, self.v_angle_y);
 383                         //WriteAngle (MSG_ONE, 80);
 384                 }
 385
 386                 if(cvar("g_arena"))
 387                         Spawnqueue_Unmark(self);
 388         }
 389 }
 390
 391 float UpdateSelectedPlayer_countvalue(float v)
 392 {
 393         return max(0, (v - 1.0) / 0.5);
 394 }
 395
 396 // returns: -2 if no hit, otherwise cos of the angle
 397 // uses the global v_angle
 398 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 399 {
 400         vector so, d;
 401         float c;
 402
 403         if(p == self)
 404                 return -2;
 405
 406         if(p.deadflag)
 407                 return -2;
 408
 409         so = self.origin + self.view_ofs;
 410         d = p.origin - so;
 411
 412         // misaimed?
 413         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 414                 return -2;
 415
 416         // now find the cos of the angle...
 417         c = normalize(d) * v_forward;
 418
 419         if(c <= mincosangle)
 420                 return -2;
 421
 422         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 423         if(trace_fraction < 1)
 424                 return -2;
 425
 426         return c;
 427 }
 428
 429 void ClearSelectedPlayer()
 430 {
 431         if(self.selected_player)
 432         {
 433                 centerprint_expire(self, CENTERPRIO_POINT);
 434                 self.selected_player = world;
 435                 self.selected_player_display_needs_update = FALSE;
 436         }
 437 }
 438
 439 void UpdateSelectedPlayer()
 440 {
 441         entity selected;
 442         float selected_score;
 443         selected = world;
 444         selected_score = 0.95; // 18 degrees
 445
 446         if(!cvar("sv_allow_shownames"))
 447                 return;
 448
 449         if(clienttype(self) != CLIENTTYPE_REAL)
 450                 return;
 451
 452         if(self.cvar_cl_shownames == 0)
 453                 return;
 454
 455         if(self.cvar_cl_shownames == 1 && !teams_matter)
 456                 return;
 457
 458         makevectors(self.v_angle); // sets v_forward
 459
 460         // 1. cursor trace is always right
 461         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 462         {
 463                 selected = self.cursor_trace_ent;
 464         }
 465         else
 466         {
 467                 // 2. if we don't have a cursor trace, find the player which is least
 468                 //    mis-aimed at
 469                 entity p;
 470                 FOR_EACH_PLAYER(p)
 471                 {
 472                         float c;
 473                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 474                         if(c >= -1)
 475                         {
 476                                 selected = p;
 477                                 selected_score = c;
 478                         }
 479                 }
 480         }
 481
 482         if(selected)
 483         {
 484                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 485         }
 486         else
 487         {
 488                 if(time < self.selected_player_display_timeout)
 489                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 490                                 selected = self.selected_player;
 491         }
 492
 493         if(selected)
 494         {
 495                 if(selected == self.selected_player)
 496                 {
 497                         float save;
 498                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 499                         self.selected_player_count = self.selected_player_count + frametime;
 500                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 501                         {
 502                                 string namestr, healthstr;
 503                                 namestr = playername(selected);
 504                                 if(teams_matter)
 505                                 {
 506                                         healthstr = ftos(floor(selected.health));
 507                                         if(self.team == selected.team)
 508                                         {
 509                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 510                                                 self.selected_player_display_needs_update = TRUE;
 511                                         }
 512                                 }
 513                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 514                         }
 515                 }
 516                 else
 517                 {
 518                         ClearSelectedPlayer();
 519                         self.selected_player = selected;
 520                         self.selected_player_time = time;
 521                         self.selected_player_count = 0;
 522                         self.selected_player_display_needs_update = FALSE;
 523                 }
 524         }
 525         else
 526         {
 527                 ClearSelectedPlayer();
 528         }
 529
 530         if(self.selected_player)
 531                 self.last_selected_player = self.selected_player;
 532 }