data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 275
 276         if(sv_gentle < 1) {
 277                 if (take > 50)
 278                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 279                 if (take > 100)
 280                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 281         }
 282
 283         if (!(self.flags & FL_GODMODE))
 284         {
 285                 self.armorvalue = self.armorvalue - save;
 286                 self.health = self.health - take;
 287                 // pause regeneration for 5 seconds
 288                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 289         }
 290         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 291         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 292         self.dmg_inflictor = inflictor;
 293
 294         if (self.health <= -50)
 295         {
 296                 // don't use any animations as a gib
 297                 self.frame = 0;
 298                 self.dead_frame = 0;
 299                 // view just above the floor
 300                 self.view_ofs = '0 0 4';
 301
 302                 // make a juicy mess
 303                 local float multiplier;
 304                 multiplier = 1;
 305                 if (cvar("ekg"))
 306                         multiplier = 5;
 307
 308
 309                 // make a meaty mess
 310                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 311
 312                 if(sv_gentle < 1) {
 313                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 314                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 315
 316                         local float c;
 317                         c = 0;
 318
 319                         while (c < multiplier)
 320                         {
 321                                 c = c + 1;
 322                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 323                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 328
 329                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 334                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 335                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 336                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 337                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 339                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 340
 341                                 // these splat on impact
 342                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                         }
 347                         sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 348                 }
 349         }
 350 }
 351
 352 void ClientKill_Now_TeamChange();
 353
 354 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 355 {
 356         local float take, save, waves, sdelay;
 357
 358         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 359         if(sv_gentle > 0) {
 360                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 361         } else {
 362                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 363         }
 364
 365         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 366         {
 367                 if(sv_gentle < 1) {
 368                         if (random() > 0.5)
 369                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 370                         else
 371                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 372                 }
 373                 self.pain_finished = time + 0.5;        //Supajoe
 374
 375                 // throw off bot aim temporarily
 376                 local float shake;
 377                 shake = damage * 5 / (bound(0,skill,100) + 1);
 378                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 379                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 380         }
 381
 382         if(g_arena)
 383         if(numspawned < 2)
 384                 return;
 385
 386         if (!g_minstagib)
 387         {
 388                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 389                 take = bound(0, damage - save, damage);
 390         }
 391         else
 392         {
 393                 save = 0;
 394                 take = damage;
 395         }
 396
 397         if (save > 10)
 398                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 399         else if (take > 30)
 400                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 401         else if (take > 10)
 402                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 403
 404         if (take > 50)
 405                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 406         if (take > 100)
 407                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 408
 409         if (time > self.spawnshieldtime)
 410         {
 411                 if (!(self.flags & FL_GODMODE))
 412                 {
 413                         self.armorvalue = self.armorvalue - save;
 414                         self.health = self.health - take;
 415                         // pause regeneration for 5 seconds
 416                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 417                 }
 418                 else
 419                         self.max_armorvalue += (save + take);
 420         }
 421         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 422         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 423         self.dmg_inflictor = inflictor;
 424
 425         if(attacker == self)
 426         {
 427                 // don't reset pushltime for self damage as it may be an attempt to
 428                 // escape a lava pit or similar
 429                 //self.pushltime = 0;
 430         }
 431         else if(attacker.classname == "player" || attacker.classname == "gib")
 432         {
 433                 self.pusher = attacker;
 434                 self.pushltime = time + cvar("g_maxpushtime");
 435         }
 436         else if(time < self.pushltime)
 437         {
 438                 attacker = self.pusher;
 439                 self.pushltime = max(self.pushltime, time + 0.6);
 440         }
 441         else
 442                 self.pushltime = 0;
 443
 444         if (self.health < 1)
 445         {
 446                 float defer_ClientKill_Now_TeamChange;
 447                 defer_ClientKill_Now_TeamChange = FALSE;
 448
 449                 // get rid of kill indicator
 450                 if(self.killindicator)
 451                 {
 452                         remove(self.killindicator);
 453                         self.killindicator = world;
 454                         if(self.killindicator_teamchange)
 455                                 defer_ClientKill_Now_TeamChange = TRUE;
 456
 457                         if(self.classname == "body")
 458                         if(deathtype == DEATH_KILL)
 459                         {
 460                                 // for the lemmings fans, a small harmless explosion
 461                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 462                         }
 463                 }
 464
 465                 // become fully visible
 466                 self.alpha = 1;
 467                 // clear selected player display
 468                 ClearSelectedPlayer();
 469                 // throw a weapon
 470                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 471                 // print an obituary message
 472                 Obituary (attacker, self, deathtype);
 473                 DropAllRunes(self);
 474                 if(self == attacker)
 475                         kh_Key_DropAll(self, TRUE);
 476                 else if(attacker.classname == "player" || attacker.classname == "gib")
 477                         kh_Key_DropAll(self, FALSE);
 478                 else
 479                         kh_Key_DropAll(self, TRUE);
 480                 if(self.flagcarried)
 481                         DropFlag(self.flagcarried);
 482                 // clear waypoints
 483                 WaypointSprite_PlayerDead();
 484                 // make the corpse upright (not tilted)
 485                 self.angles_x = 0;
 486                 self.angles_z = 0;
 487                 // don't spin
 488                 self.avelocity = '0 0 0';
 489                 // view from the floor
 490                 self.view_ofs = '0 0 -8';
 491                 // toss the corpse
 492                 self.movetype = MOVETYPE_TOSS;
 493                 // shootable corpse
 494                 self.solid = SOLID_CORPSE;
 495                 // don't stick to the floor
 496                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 497                 // dying animation
 498                 self.deadflag = DEAD_DYING;
 499                 // when to allow respawn
 500                 sdelay = 0;
 501                 waves = 0;
 502                 if(cvar("g_respawn_mapsettings"))
 503                 {
 504                         sdelay = cvar("g_respawn_mapsettings_delay");
 505                         waves = cvar("g_respawn_mapsettings_waves");
 506                 }
 507                 if(!sdelay)
 508                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 509                 if(!sdelay)
 510                         sdelay = cvar("g_respawn_delay");
 511                 if(!waves)
 512                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 513                 if(!waves)
 514                         waves = cvar("g_respawn_waves");
 515                 if(waves)
 516                         self.death_time = ceil((time + sdelay) / waves) * waves;
 517                 else
 518                         self.death_time = time + sdelay;
 519                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 520                         self.respawn_countdown = 10; // first number to count down from is 10
 521                 else
 522                         self.respawn_countdown = -1; // do not count down
 523                 if (random() < 0.5)
 524                 {
 525                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 526                         self.dead_frame = self.anim_dead1_x;
 527                 }
 528                 else
 529                 {
 530                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 531                         self.dead_frame = self.anim_dead2_x;
 532                 }
 533                 // set damage function to corpse damage
 534                 self.event_damage = PlayerCorpseDamage;
 535                 // call the corpse damage function just in case it wants to gib
 536                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 537                 // set up to fade out later
 538                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 539
 540                 // remove laserdot
 541                 if(self.weaponentity)
 542                         if(self.weaponentity.lasertarget)
 543                                 remove(self.weaponentity.lasertarget);
 544
 545                 if(clienttype(self) == CLIENTTYPE_REAL)
 546                 {
 547                         self.fixangle = TRUE;
 548                         //msg_entity = self;
 549                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 550                         //WriteAngle (MSG_ONE, self.v_angle_x);
 551                         //WriteAngle (MSG_ONE, self.v_angle_y);
 552                         //WriteAngle (MSG_ONE, 80);
 553                 }
 554
 555                 if(g_arena)
 556                         Spawnqueue_Unmark(self);
 557
 558                 if(defer_ClientKill_Now_TeamChange)
 559                         ClientKill_Now_TeamChange();
 560
 561                 if(sv_gentle > 0) {
 562                         // remove corpse
 563                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 564                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 565                 }
 566         }
 567 }
 568
 569 float UpdateSelectedPlayer_countvalue(float v)
 570 {
 571         return max(0, (v - 1.0) / 0.5);
 572 }
 573
 574 // returns: -2 if no hit, otherwise cos of the angle
 575 // uses the global v_angle
 576 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 577 {
 578         vector so, d;
 579         float c;
 580
 581         if(p == self)
 582                 return -2;
 583
 584         if(p.deadflag)
 585                 return -2;
 586
 587         so = self.origin + self.view_ofs;
 588         d = p.origin - so;
 589
 590         // misaimed?
 591         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 592                 return -2;
 593
 594         // now find the cos of the angle...
 595         c = normalize(d) * v_forward;
 596
 597         if(c <= mincosangle)
 598                 return -2;
 599
 600         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 601         if(trace_fraction < 1)
 602                 return -2;
 603
 604         return c;
 605 }
 606
 607 void ClearSelectedPlayer()
 608 {
 609         if(self.selected_player)
 610         {
 611                 centerprint_expire(self, CENTERPRIO_POINT);
 612                 self.selected_player = world;
 613                 self.selected_player_display_needs_update = FALSE;
 614         }
 615 }
 616
 617 void UpdateSelectedPlayer()
 618 {
 619         entity selected;
 620         float selected_score;
 621         selected = world;
 622         selected_score = 0.95; // 18 degrees
 623
 624         if(!cvar("sv_allow_shownames"))
 625                 return;
 626
 627         if(clienttype(self) != CLIENTTYPE_REAL)
 628                 return;
 629
 630         if(self.cvar_cl_shownames == 0)
 631                 return;
 632
 633         if(self.cvar_cl_shownames == 1 && !teams_matter)
 634                 return;
 635
 636         makevectors(self.v_angle); // sets v_forward
 637
 638         // 1. cursor trace is always right
 639         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 640         {
 641                 selected = self.cursor_trace_ent;
 642         }
 643         else
 644         {
 645                 // 2. if we don't have a cursor trace, find the player which is least
 646                 //    mis-aimed at
 647                 entity p;
 648                 FOR_EACH_PLAYER(p)
 649                 {
 650                         float c;
 651                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 652                         if(c >= -1)
 653                         {
 654                                 selected = p;
 655                                 selected_score = c;
 656                         }
 657                 }
 658         }
 659
 660         if(selected)
 661         {
 662                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 663         }
 664         else
 665         {
 666                 if(time < self.selected_player_display_timeout)
 667                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 668                                 selected = self.selected_player;
 669         }
 670
 671         if(selected)
 672         {
 673                 if(selected == self.selected_player)
 674                 {
 675                         float save;
 676                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 677                         self.selected_player_count = self.selected_player_count + frametime;
 678                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 679                         {
 680                                 string namestr, healthstr;
 681                                 namestr = playername(selected);
 682                                 if(teams_matter)
 683                                 {
 684                                         healthstr = ftos(floor(selected.health));
 685                                         if(self.team == selected.team)
 686                                         {
 687                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 688                                                 self.selected_player_display_needs_update = TRUE;
 689                                         }
 690                                 }
 691                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 692                         }
 693                 }
 694                 else
 695                 {
 696                         ClearSelectedPlayer();
 697                         self.selected_player = selected;
 698                         self.selected_player_time = time;
 699                         self.selected_player_count = 0;
 700                         self.selected_player_display_needs_update = FALSE;
 701                 }
 702         }
 703         else
 704         {
 705                 ClearSelectedPlayer();
 706         }
 707
 708         if(self.selected_player)
 709                 self.last_selected_player = self.selected_player;
 710 }
 711
 712 float precache_sound_index (string s) = #19;
 713 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 714 {
 715         vector o;
 716         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 717                 return;
 718         o = e.origin + 0.5 * (e.mins + e.maxs);
 719         msg_entity = sounddest;
 720         WriteByte(MSG_ONE, 6);
 721         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 722         WriteByte(MSG_ONE, vol * 255);
 723         WriteByte(MSG_ONE, atten * 64);
 724         WriteEntity(MSG_ONE, e);
 725         WriteByte(MSG_ONE, chan);
 726         WriteShort(MSG_ONE, precache_sound_index(samp));
 727         WriteCoord(MSG_ONE, o_x);
 728         WriteCoord(MSG_ONE, o_y);
 729         WriteCoord(MSG_ONE, o_z);
 730 }
 731
 732 #if 0
 733 .string playersound_attack;
 734 .string playersound_attackinfive;
 735 .string playersound_coverme;
 736 .string playersound_defend;
 737 .string playersound_freelance;
 738 .string playersound_incoming;
 739 .string playersound_meet;
 740 .string playersound_needhelp;
 741 .string playersound_seenflag;
 742 .string playersound_taunt;
 743 .string playersound_teamshoot;
 744 .float modelindex_for_playersound;
 745
 746 float GetVoiceMessageTeamsayType(string type)
 747 {
 748         if(type == "taunt")
 749                 return 0;
 750         if(type == "teamshoot")
 751                 return 2;
 752         return 1;
 753 }
 754
 755 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 756 float GetPlayerSoundSampleField_notFound;
 757 .string GetVoiceMessageSampleField(string type)
 758 {
 759         GetPlayerSoundSampleField_notFound = 0;
 760         switch(type)
 761         {
 762                 case "attack":       return playersound_attack;
 763                 case "attackinfive": return playersound_attackinfive;
 764                 case "coverme":      return playersound_coverme;
 765                 case "defend":       return playersound_defend;
 766                 case "freelance":    return playersound_freelance;
 767                 case "incoming":     return playersound_incoming;
 768                 case "meet":         return playersound_meet;
 769                 case "needhelp":     return playersound_needhelp;
 770                 case "seenflag":     return playersound_seenflag;
 771                 case "taunt":        return playersound_taunt;
 772                 case "teamshoot":    return playersound_teamshoot;
 773         }
 774         GetPlayerSoundSampleField_notFound = 1;
 775         return playersound_taunt;
 776 }
 777
 778 .string GetPlayerSoundSampleField(string type)
 779 {
 780         GetPlayerSoundSampleField_notFound = 0;
 781         switch(type)
 782         {
 783                 case "attack":       return playersound_attack;
 784                 default:             return GetVoiceMessageSampleField(type);
 785         }
 786 }
 787
 788 void PrecachePlayerSounds(string f)
 789 {
 790         float fh;
 791         float i, n;
 792         string s;
 793         fh = fopen(f, FILE_READ);
 794         if(fh < 0)
 795                 return;
 796         while((s = fgets(fh)))
 797         {
 798                 if(tokenize(s) != 3)
 799                 {
 800                         dprint("Invalid sound info line: ", s, "\n");
 801                         continue;
 802                 }
 803                 n = stof(argv(2));
 804                 for(i = 1; i <= n; ++i)
 805                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 806         }
 807         fclose(fh);
 808 }
 809
 810 void LoadPlayerSounds(string f)
 811 {
 812         float fh;
 813         string s;
 814         var .string field;
 815         fh = fopen(f, FILE_READ);
 816         if(fh < 0)
 817                 return;
 818         while((s = fgets(fh)))
 819         {
 820                 if(tokenize(s) != 3)
 821                         continue;
 822                 field = GetPlayerSoundSampleField(argv(0));
 823                 if(GetPlayerSoundSampleField_notFound)
 824                         continue;
 825                 if(self.field)
 826                         strunzone(self.field);
 827                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 828         }
 829         fclose(fh);
 830 }
 831
 832 void UpdatePlayerSounds()
 833 {
 834         if(self.modelindex == self.modelindex_for_playersound)
 835                 return;
 836         self.modelindex_for_playersound = self.modelindex;
 837         LoadPlayerSounds("sound/player/default.sounds");
 838         LoadPlayerSounds(strcat(self.model, ".sounds"));
 839 }
 840
 841 void VoiceMessage(string type)
 842 {
 843         // TODO precache voice messages?
 844         var string sample;
 845         var float teamsay;
 846         sample = self.(GetPlayerSoundSampleField(type));
 847
 848         if(GetPlayerSoundSampleField_notFound)
 849         {
 850                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 851                 return;
 852         }
 853
 854         if(!sample)
 855                 return;
 856
 857         teamsay = GetVoiceMessageTeamsayType(type);
 858
 859         tokenize(sample);
 860         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 861
 862         if(teamsay == 2)
 863         {
 864                 if(teams_matter)
 865                         if(self.pusher)
 866                                 if(self.pusher.team == self.team)
 867                                 {
 868                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 869                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 870                                 }
 871         }
 872         else if(teamsay == 0 || !teams_matter)
 873         {
 874                 // broadcast the sound, but it's directional
 875                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 876         }
 877         else if(teamsay == 1)
 878         {
 879                 entity e;
 880                 FOR_EACH_REALCLIENT(e)
 881                         if(e.team == self.team)
 882                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 883         }
 884 }
 885 #else
 886 void PrecachePlayerSounds(string f) { }
 887 void UpdatePlayerSounds() { }
 888 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 889 #endif