data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 float sv_airstopaccelerate;
  11 float sv_airstrafeaccelerate;
  12 float sv_maxairstrafespeed;
  13 float sv_aircontrol;
  14 .float ladder_time;
  15 .entity ladder_entity;
  16 .float gravity;
  17 .float swamp_slowdown;
  18 .float lastflags;
  19 .float lastground;
  20 .float wasFlying;
  21 .float spectatorspeed;
  22
  23 #define SHTEST_DELTA 10
  24 #define SHTEST_THRESHOLD 1.1
  25 .float shtest_next;
  26 .float shtest_accumulator;
  27
  28 /*
  29 =============
  30 PlayerJump
  31
  32 When you press the jump key
  33 =============
  34 */
  35 void PlayerJump (void)
  36 {
  37         float mjumpheight;
  38
  39         mjumpheight = cvar("sv_jumpvelocity");
  40         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  41         {
  42                 if (self.watertype == CONTENT_WATER)
  43                         self.velocity_z = 200;
  44                 else if (self.watertype == CONTENT_SLIME)
  45                         self.velocity_z = 80;
  46                 else
  47                         self.velocity_z = 50;
  48
  49                 return;
  50         }
  51
  52
  53         if (!(self.flags & FL_ONGROUND))
  54                 return;
  55
  56         if(!sv_pogostick)
  57                 if (!(self.flags & FL_JUMPRELEASED))
  58                         return;
  59
  60         if(self.health <= g_bloodloss)
  61                 return;
  62
  63         if(g_runematch)
  64         {
  65                 if(self.runes & RUNE_SPEED)
  66                 {
  67                         if(self.runes & CURSE_SLOW)
  68                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  69                         else
  70                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  71                 }
  72                 else if(self.runes & CURSE_SLOW)
  73                 {
  74                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  75                 }
  76         }
  77
  78         if(g_minstagib && (self.items & IT_INVINCIBLE))
  79         {
  80                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  81         }
  82
  83         self.velocity_z = self.velocity_z + mjumpheight;
  84         self.oldvelocity_z = self.velocity_z;
  85
  86         self.flags &~= FL_ONGROUND;
  87         self.flags &~= FL_JUMPRELEASED;
  88
  89         if (self.crouch)
  90                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
  91         else
  92                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
  93
  94         if(g_jump_grunt)
  95                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
  96 }
  97
  98 void CheckWaterJump()
  99 {
 100         local vector start, end;
 101
 102 // check for a jump-out-of-water
 103         makevectors (self.angles);
 104         start = self.origin;
 105         start_z = start_z + 8;
 106         v_forward_z = 0;
 107         normalize(v_forward);
 108         end = start + v_forward*24;
 109         traceline (start, end, TRUE, self);
 110         if (trace_fraction < 1)
 111         {       // solid at waist
 112                 start_z = start_z + self.maxs_z - 8;
 113                 end = start + v_forward*24;
 114                 self.movedir = trace_plane_normal * -50;
 115                 traceline (start, end, TRUE, self);
 116                 if (trace_fraction == 1)
 117                 {       // open at eye level
 118                         self.flags |= FL_WATERJUMP;
 119                         self.velocity_z = 225;
 120                         self.flags &~= FL_JUMPRELEASED;
 121                         self.teleport_time = time + 2;  // safety net
 122                         return;
 123                 }
 124         }
 125 };
 126
 127 float racecar_angle(float forward, float down)
 128 {
 129         float ret, angle_mult;
 130
 131         if(forward < 0)
 132         {
 133                 forward = -forward;
 134                 down = -down;
 135         }
 136
 137         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 138
 139         angle_mult = forward / (800 + forward);
 140
 141         if(ret > 180)
 142                 return ret * angle_mult + 360 * (1 - angle_mult);
 143         else
 144                 return ret * angle_mult;
 145 }
 146
 147 void RaceCarPhysics()
 148 {
 149         // using this move type for "big rigs"
 150         // the engine does not push the entity!
 151
 152         float accel, steer, f;
 153         vector angles_save, rigvel;
 154
 155         angles_save = self.angles;
 156         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 157         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 158
 159         if(g_bugrigs_reverse_speeding)
 160         {
 161                 if(accel < 0)
 162                 {
 163                         // back accel is DIGITAL
 164                         // to prevent speedhack
 165                         if(accel < -0.5)
 166                                 accel = -1;
 167                         else
 168                                 accel = 0;
 169                 }
 170         }
 171
 172         self.angles_x = 0;
 173         self.angles_z = 0;
 174         makevectors(self.angles); // new forward direction!
 175
 176         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 177         {
 178                 float myspeed, upspeed, steerfactor, accelfactor;
 179
 180                 myspeed = self.velocity * v_forward;
 181                 upspeed = self.velocity * v_up;
 182
 183                 // responsiveness factor for steering and acceleration
 184                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 185                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 186
 187                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 188                         steerfactor = -myspeed * g_bugrigs_steer;
 189                 else
 190                         steerfactor = -myspeed * f * g_bugrigs_steer;
 191
 192                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 193                         accelfactor = g_bugrigs_accel;
 194                 else
 195                         accelfactor = f * g_bugrigs_accel;
 196                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 197
 198                 if(accel < 0)
 199                 {
 200                         if(myspeed > 0)
 201                         {
 202                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 203                         }
 204                         else
 205                         {
 206                                 if(!g_bugrigs_reverse_speeding)
 207                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 208                         }
 209                 }
 210                 else
 211                 {
 212                         if(myspeed >= 0)
 213                         {
 214                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 215                         }
 216                         else
 217                         {
 218                                 if(g_bugrigs_reverse_stopping)
 219                                         myspeed = 0;
 220                                 else
 221                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 222                         }
 223                 }
 224                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 225                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 226
 227                 self.angles_y += steer * frametime * steerfactor; // apply steering
 228                 makevectors(self.angles); // new forward direction!
 229
 230                 myspeed += accel * accelfactor * frametime;
 231
 232                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 233         }
 234         else
 235         {
 236                 myspeed = vlen(self.velocity);
 237
 238                 // responsiveness factor for steering and acceleration
 239                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 240                 steerfactor = -myspeed * f;
 241                 self.angles_y += steer * frametime * steerfactor; // apply steering
 242
 243                 rigvel = self.velocity;
 244                 makevectors(self.angles); // new forward direction!
 245         }
 246
 247         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 248         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 249         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 250         //MAXIMA: solve(total_acceleration(v) = 0, v);
 251
 252         if(g_bugrigs_planar_movement)
 253         {
 254                 vector rigvel_xy, neworigin, up;
 255                 float mt;
 256
 257                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 258                 rigvel_xy = rigvel;
 259                 rigvel_xy_z = 0;
 260
 261                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 262                         mt = MOVE_NORMAL;
 263                 else
 264                         mt = MOVE_NOMONSTERS;
 265
 266                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 267                 up = trace_endpos - self.origin;
 268
 269                 // BUG RIGS: align the move to the surface instead of doing collision testing
 270                 // can we move?
 271                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 272
 273                 // align to surface
 274                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 275
 276                 if(trace_fraction < 0.5)
 277                 {
 278                         trace_fraction = 1;
 279                         neworigin = self.origin;
 280                 }
 281                 else
 282                         neworigin = trace_endpos;
 283
 284                 if(trace_fraction < 1)
 285                 {
 286                         // now set angles_x so that the car points parallel to the surface
 287                         self.angles = vectoangles(
 288                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 289                                         +
 290                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 291                                         +
 292                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 293                                         );
 294                         self.flags |= FL_ONGROUND;
 295                 }
 296                 else
 297                 {
 298                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 299                         self.flags &~= FL_ONGROUND;
 300                 }
 301
 302                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 303                 self.movetype = MOVETYPE_NOCLIP;
 304         }
 305         else
 306         {
 307                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 308                 self.velocity = rigvel;
 309                 self.movetype = MOVETYPE_FLY;
 310         }
 311
 312         trace_fraction = 1;
 313         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 314         if(trace_fraction != 1)
 315         {
 316                 self.angles = vectoangles2(
 317                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 318                                 +
 319                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 320                                 +
 321                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 322                                 trace_plane_normal
 323                                 );
 324         }
 325         else
 326         {
 327                 vector vel_local;
 328
 329                 vel_local_x = v_forward * self.velocity;
 330                 vel_local_y = v_right * self.velocity;
 331                 vel_local_z = v_up * self.velocity;
 332
 333                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 334                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 335         }
 336
 337         // smooth the angles
 338         vector vf1, vu1, smoothangles;
 339         makevectors(self.angles);
 340         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 341         if(f == 0)
 342                 f = 1;
 343         vf1 = v_forward * f;
 344         vu1 = v_up * f;
 345         makevectors(angles_save);
 346         vf1 = vf1 + v_forward * (1 - f);
 347         vu1 = vu1 + v_up * (1 - f);
 348         smoothangles = vectoangles2(vf1, vu1);
 349         self.angles_x = -smoothangles_x;
 350         self.angles_z =  smoothangles_z;
 351 }
 352
 353 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 354 {
 355         float zspeed, xyspeed, dot, k;
 356
 357         if(self.movement_x == 0 || self.movement_y != 0)
 358                 return; // can't control movement if not moving forward or backward
 359
 360         zspeed = self.velocity_z;
 361         self.velocity_z = 0;
 362         xyspeed = vlen(self.velocity);
 363         self.velocity = normalize(self.velocity);
 364
 365         dot = self.velocity * wishdir;
 366         k = 32;
 367         k *= sv_aircontrol*dot*dot*frametime;
 368
 369         if(dot > 0) // we can't change direction while slowing down
 370                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 371
 372         self.velocity = self.velocity * xyspeed;
 373         self.velocity_z = zspeed;
 374 }
 375
 376 .vector movement_old;
 377 .float buttons_old;
 378 .vector v_angle_old;
 379 .string lastclassname;
 380
 381 void Nixnex_GiveCurrentWeapon();
 382 void SV_PlayerPhysics()
 383 {
 384         local vector wishvel, wishdir, v;
 385         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 386         string temps;
 387         float buttons_prev;
 388
 389         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 390         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 391         {
 392                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 393                         self.parm_idlesince = time;
 394         }
 395         buttons_prev = self.buttons_old;
 396         self.buttons_old = buttons;
 397         self.movement_old = self.movement;
 398         self.v_angle_old = self.v_angle;
 399
 400         if(time < self.nickspamtime)
 401         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 402         {
 403                 // slight annoyance for nick change scripts
 404                 self.movement = -1 * self.movement;
 405                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 406
 407                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 408                 {
 409                         self.angles_x = random() * 360;
 410                         self.angles_y = random() * 360;
 411                         // at least I'm not forcing retardedview by also assigning to angles_z
 412                         self.fixangle = 1;
 413                 }
 414         }
 415
 416         if(time > self.shtest_next)
 417         {
 418                 if(self.shtest_next > 0)
 419                 {
 420                         // self.shtest_accumulator:
 421                         //   started at time - SHTEST_DELTA
 422                         //   should be at SHTEST_DELTA
 423                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 424                         if(shtest_score > SHTEST_THRESHOLD)
 425                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 426                         else if(cvar("developer_shtest"))
 427                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 428                 }
 429                 self.shtest_next = time + SHTEST_DELTA;
 430                 self.shtest_accumulator = 0;
 431         }
 432         self.shtest_accumulator += frametime;
 433
 434         if (clienttype(self) == CLIENTTYPE_BOT)
 435                 bot_think();
 436
 437         self.items &~= IT_USING_JETPACK;
 438
 439         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 440                 return;
 441
 442         if (self.punchangle != '0 0 0')
 443         {
 444                 f = vlen(self.punchangle) - 10 * frametime;
 445                 if (f > 0)
 446                         self.punchangle = normalize(self.punchangle) * f;
 447                 else
 448                         self.punchangle = '0 0 0';
 449         }
 450
 451         if (self.punchvector != '0 0 0')
 452         {
 453                 f = vlen(self.punchvector) - 30 * frametime;
 454                 if (f > 0)
 455                         self.punchvector = normalize(self.punchvector) * f;
 456                 else
 457                         self.punchvector = '0 0 0';
 458         }
 459
 460         maxspd_mod = 1;
 461
 462         if(g_runematch)
 463         {
 464                 if(self.runes & RUNE_SPEED)
 465                 {
 466                         if(self.runes & CURSE_SLOW)
 467                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 468                         else
 469                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 470                 }
 471                 else if(self.runes & CURSE_SLOW)
 472                 {
 473                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 474                 }
 475         }
 476
 477         if(g_minstagib && (self.items & IT_INVINCIBLE))
 478         {
 479                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 480         }
 481
 482         if(g_nexball && self.ballcarried)
 483         {
 484                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 485         }
 486
 487         swampspd_mod = 1;
 488         if(self.in_swamp) {
 489                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 490         }
 491
 492         if(self.classname != "player")
 493         {
 494                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 495                 if(!self.spectatorspeed)
 496                         self.spectatorspeed = maxspd_mod;
 497                 if(self.impulse && self.impulse <= 19)
 498                 {
 499                         if(self.lastclassname != "player")
 500                         {
 501                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 502                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 503                                 else if(self.impulse == 11)
 504                                         self.spectatorspeed = maxspd_mod;
 505                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 506                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 507                                 else if(self.impulse >= 1 && self.impulse <= 9)
 508                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 509                         } // otherwise just clear
 510                         self.impulse = 0;
 511                 }
 512                 maxspd_mod = self.spectatorspeed;
 513         }
 514
 515         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 516
 517         if(self.speed != spd)
 518         {
 519                 self.speed = spd;
 520                 temps = ftos(spd);
 521                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 522                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 523                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 524                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 525         }
 526
 527         // if dead, behave differently
 528         if (self.deadflag)
 529                 goto end;
 530
 531         if (!self.fixangle && !g_bugrigs)
 532         {
 533                 self.angles_x = 0;
 534                 self.angles_y = self.v_angle_y;
 535                 self.angles_z = 0;
 536         }
 537
 538         if(self.flags & FL_ONGROUND)
 539         if(self.wasFlying)
 540         {
 541                 self.wasFlying = 0;
 542
 543                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 544                 if(time >= self.ladder_time)
 545                 if not(self.hook)
 546                 {
 547                         self.nextstep = time + 0.3 + random() * 0.1;
 548                         trace_dphitq3surfaceflags = 0;
 549                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 550                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 551                         {
 552                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 553                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 554                                 else
 555                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 556                         }
 557                 }
 558         }
 559
 560         if(IsFlying(self))
 561                 self.wasFlying = 1;
 562
 563         if(self.classname == "player")
 564         {
 565                 if(sv_doublejump)
 566                 {
 567                         self.flags &~= FL_ONGROUND;
 568                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 569                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 570                                 self.flags |= FL_ONGROUND;
 571                 }
 572
 573                 if (self.BUTTON_JUMP)
 574                         PlayerJump ();
 575                 else
 576                         self.flags |= FL_JUMPRELEASED;
 577
 578                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 579                         CheckWaterJump ();
 580         }
 581
 582         if (self.flags & FL_WATERJUMP )
 583         {
 584                 self.velocity_x = self.movedir_x;
 585                 self.velocity_y = self.movedir_y;
 586                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 587                 {
 588                         self.flags &~= FL_WATERJUMP;
 589                         self.teleport_time = 0;
 590                 }
 591         }
 592         else if (g_bugrigs && self.classname == "player")
 593         {
 594                 RaceCarPhysics();
 595         }
 596         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 597         {
 598                 // noclipping or flying
 599                 self.flags &~= FL_ONGROUND;
 600
 601                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 602                 makevectors(self.v_angle);
 603                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 604                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 605                 // acceleration
 606                 wishdir = normalize(wishvel);
 607                 wishspeed = vlen(wishvel);
 608                 if (wishspeed > spd)
 609                         wishspeed = spd;
 610                 if (time >= self.teleport_time)
 611                 {
 612                         f = wishspeed - (self.velocity * wishdir);
 613                         if (f > 0)
 614                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 615                 }
 616         }
 617         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 618         {
 619                 // swimming
 620                 self.flags &~= FL_ONGROUND;
 621
 622                 makevectors(self.v_angle);
 623                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 624                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 625                 if (wishvel == '0 0 0')
 626                         wishvel = '0 0 -60'; // drift towards bottom
 627
 628                 wishdir = normalize(wishvel);
 629                 wishspeed = vlen(wishvel);
 630                 if (wishspeed > spd)
 631                         wishspeed = spd;
 632                 wishspeed = wishspeed * 0.7;
 633
 634                 // water friction
 635                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 636
 637                 // water acceleration
 638                 f = wishspeed - (self.velocity * wishdir);
 639                 if (f > 0)
 640                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 641         }
 642         else if (time < self.ladder_time)
 643         {
 644                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 645                 self.flags &~= FL_ONGROUND;
 646
 647                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 648                 makevectors(self.v_angle);
 649                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 650                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 651                 if (self.gravity)
 652                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 653                 else
 654                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 655                 if (self.ladder_entity.classname == "func_water")
 656                 {
 657                         f = vlen(wishvel);
 658                         if (f > self.ladder_entity.speed)
 659                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 660
 661                         self.watertype = self.ladder_entity.skin;
 662                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 663                         if ((self.origin_z + self.view_ofs_z) < f)
 664                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 665                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 666                                 self.waterlevel = WATERLEVEL_SWIMMING;
 667                         else if ((self.origin_z + self.mins_z + 1) < f)
 668                                 self.waterlevel = WATERLEVEL_WETFEET;
 669                         else
 670                         {
 671                                 self.waterlevel = WATERLEVEL_NONE;
 672                                 self.watertype = CONTENT_EMPTY;
 673                         }
 674                 }
 675                 // acceleration
 676                 wishdir = normalize(wishvel);
 677                 wishspeed = vlen(wishvel);
 678                 if (wishspeed > spd)
 679                         wishspeed = spd;
 680                 if (time >= self.teleport_time)
 681                 {
 682                         f = wishspeed - (self.velocity * wishdir);
 683                         if (f > 0)
 684                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 685                 }
 686         }
 687         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 688         {
 689                 //makevectors(self.v_angle_y * '0 1 0');
 690                 makevectors(self.v_angle);
 691                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 692                 // add remaining speed as Z component
 693                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 694                 // fix speedhacks :P
 695                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 696                 // add the unused velocity as up component
 697                 wishvel_z = 0;
 698
 699                 // if(self.BUTTON_JUMP)
 700                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 701
 702                 // it is now normalized, so...
 703                 float a_side, a_up, a_add, a_diff;
 704                 a_side = cvar("g_jetpack_acceleration_side");
 705                 a_up = cvar("g_jetpack_acceleration_up");
 706                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 707
 708                 wishvel_x *= a_side;
 709                 wishvel_y *= a_side;
 710                 wishvel_z *= a_up;
 711                 wishvel_z += a_add;
 712
 713                 float best;
 714                 best = 0;
 715                 //////////////////////////////////////////////////////////////////////////////////////
 716                 // finding the maximum over all vectors of above form
 717                 // with wishvel having an absolute value of 1
 718                 //////////////////////////////////////////////////////////////////////////////////////
 719                 // we're finding the maximum over
 720                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 721                 // for z in the range from -1 to 1
 722                 //////////////////////////////////////////////////////////////////////////////////////
 723                 // maximum is EITHER attained at the single extreme point:
 724                 a_diff = a_side * a_side - a_up * a_up;
 725                 if(a_diff != 0)
 726                 {
 727                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 728                         if(f > -1 && f < 1) // can it be attained?
 729                         {
 730                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 731                                 //print("middle\n");
 732                         }
 733                 }
 734                 // OR attained at z = 1:
 735                 f = (a_up + a_add) * (a_up + a_add);
 736                 if(f > best)
 737                 {
 738                         best = f;
 739                         //print("top\n");
 740                 }
 741                 // OR attained at z = -1:
 742                 f = (a_up - a_add) * (a_up - a_add);
 743                 if(f > best)
 744                 {
 745                         best = f;
 746                         //print("bottom\n");
 747                 }
 748                 best = sqrt(best);
 749                 //////////////////////////////////////////////////////////////////////////////////////
 750
 751                 //print("best possible acceleration: ", ftos(best), "\n");
 752
 753                 float fxy, fz;
 754                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 755                 if(wishvel_z - sv_gravity > 0)
 756                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 757                 else
 758                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 759
 760                 float fvel;
 761                 fvel = vlen(wishvel);
 762                 wishvel_x *= fxy;
 763                 wishvel_y *= fxy;
 764                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 765
 766                 fvel = min(1, vlen(wishvel) / best);
 767                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 768                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 769                 else
 770                         f = 1;
 771
 772                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 773
 774                 if (f > 0 && wishvel != '0 0 0')
 775                 {
 776                         self.velocity = self.velocity + wishvel * f * frametime;
 777                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 778                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
 779                         self.flags &~= FL_ONGROUND;
 780                         self.items |= IT_USING_JETPACK;
 781
 782                         // jetpack also inhibits health regeneration, but only for 1 second
 783                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
 784                 }
 785         }
 786         else if (self.flags & FL_ONGROUND)
 787         {
 788                 // we get here if we ran out of ammo
 789                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 790                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 791
 792                 // walking
 793                 makevectors(self.v_angle_y * '0 1 0');
 794                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 795
 796                 if(!(self.lastflags & FL_ONGROUND))
 797                 {
 798                         if(cvar("speedmeter"))
 799                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 800                         if(self.lastground < time - 0.3)
 801                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 802                         if(self.jumppadcount > 1)
 803                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 804                         self.jumppadcount = 0;
 805                 }
 806
 807                 if (self.velocity_x || self.velocity_y)
 808                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 809                 {
 810                         v = self.velocity;
 811                         v_z = 0;
 812                         f = vlen(v);
 813                         if (f < sv_stopspeed)
 814                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 815                         else
 816                                 f = 1 - frametime * sv_friction;
 817                         if (f > 0)
 818                                 self.velocity = self.velocity * f;
 819                         else
 820                                 self.velocity = '0 0 0';
 821                 }
 822                 // acceleration
 823                 wishdir = normalize(wishvel);
 824                 wishspeed = vlen(wishvel);
 825                 if (wishspeed > spd)
 826                         wishspeed = spd;
 827                 if (self.crouch)
 828                         wishspeed = wishspeed * 0.5;
 829                 if (time >= self.teleport_time)
 830                 {
 831                         f = wishspeed - (self.velocity * wishdir);
 832                         if (f > 0)
 833                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 834                 }
 835         }
 836         else
 837         {
 838                 // we get here if we ran out of ammo
 839                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
 840                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
 841
 842                 if(maxspd_mod*swampspd_mod < 1)
 843                 {
 844                         maxairspd = sv_maxairspeed*maxspd_mod*swampspd_mod;
 845                         airaccel = sv_airaccelerate*maxspd_mod*swampspd_mod;
 846                 }
 847                 else
 848                 {
 849                         maxairspd = sv_maxairspeed;
 850                         airaccel = sv_airaccelerate;
 851                 }
 852                 // airborn
 853                 makevectors(self.v_angle_y * '0 1 0');
 854                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 855                 // acceleration
 856                 wishdir = normalize(wishvel);
 857                 wishspeed = vlen(wishvel);
 858                 if (wishspeed > maxairspd)
 859                         wishspeed = maxairspd;
 860                 if (self.crouch)
 861                         wishspeed = wishspeed * 0.5;
 862                 if (time >= self.teleport_time)
 863                 {
 864                         // CPM: air control
 865                         float wishspeed2;
 866                         wishspeed2 = wishspeed;
 867                         if(sv_airstopaccelerate)
 868                                 if(self.velocity * wishdir < 0)
 869                                         airaccel = sv_airstopaccelerate;
 870                         if(self.movement_x == 0 && self.movement_y != 0)
 871                         {
 872                                 if(sv_maxairstrafespeed)
 873                                         wishspeed = min(wishspeed, sv_maxairstrafespeed);
 874                                 if(sv_airstrafeaccelerate)
 875                                         airaccel = sv_airstrafeaccelerate;
 876                         }
 877                         // !CPM
 878
 879                         // NOTE: this does the same as the commented out old code if:
 880                         //   sv_airaccel_qw 0
 881                         //   sv_airaccel_sideways_friction 0
 882
 883                         float vel_straight;
 884                         float vel_z;
 885                         vector vel_perpend;
 886                         vel_straight = self.velocity * wishdir;
 887                         vel_z = self.velocity_z;
 888                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 889
 890                         f = wishspeed - vel_straight;
 891                         if(f > 0)
 892                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 893                         if(wishspeed > 0)
 894                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 895
 896                         // anti-sideways friction to fix QW-style bunnyhopping
 897                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 898
 899                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 900
 901                         if(sv_aircontrol)
 902                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
 903
 904                         /*
 905                         f = wishspeed;// - (self.velocity * wishdir);
 906                         if (f > 0)
 907                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 908                         */
 909                 }
 910         }
 911
 912 :end
 913         if(self.flags & FL_ONGROUND)
 914                 self.lastground = time;
 915
 916         self.lastflags = self.flags;
 917         self.lastclassname = self.classname;
 918 };