data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 float racecar_angle(float forward, float down)
 121 {
 122         float ret, angle_mult;
 123
 124         if(forward < 0)
 125         {
 126                 forward = -forward;
 127                 down = -down;
 128         }
 129
 130         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 131
 132         angle_mult = forward / (800 + forward);
 133
 134         if(ret > 180)
 135                 return ret * angle_mult + 360 * (1 - angle_mult);
 136         else
 137                 return ret * angle_mult;
 138 }
 139
 140 .vector movement_old;
 141 .float buttons_old;
 142 .vector v_angle_old;
 143
 144 void Nixnex_GiveCurrentWeapon();
 145 void SV_PlayerPhysics()
 146 {
 147         local vector wishvel, wishdir, v;
 148         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 149         string temps;
 150
 151         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 152         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 153         {
 154                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 155                         self.parm_idlesince = time;
 156         }
 157         self.buttons_old = buttons;
 158         self.movement_old = self.movement;
 159         self.v_angle_old = self.v_angle;
 160
 161         if(time > self.shtest_next)
 162         {
 163                 if(self.shtest_next > 0)
 164                 {
 165                         // self.shtest_accumulator:
 166                         //   started at time - SHTEST_DELTA
 167                         //   should be at SHTEST_DELTA
 168                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 169                         if(shtest_score > SHTEST_THRESHOLD)
 170                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 171                         else if(cvar("developer_shtest"))
 172                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 173                 }
 174                 self.shtest_next = time + SHTEST_DELTA;
 175                 self.shtest_accumulator = 0;
 176         }
 177         self.shtest_accumulator += frametime;
 178
 179         if (clienttype(self) == CLIENTTYPE_BOT)
 180                 bot_think();
 181
 182         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 183                 return;
 184
 185         if(g_bugrigs && self.movetype == MOVETYPE_WALK)
 186         {
 187                 self.disableclientprediction = 1;
 188                 self.movetype = MOVETYPE_NOCLIP;
 189         }
 190
 191         if (self.punchangle != '0 0 0')
 192         {
 193                 f = vlen(self.punchangle) - 10 * frametime;
 194                 if (f > 0)
 195                         self.punchangle = normalize(self.punchangle) * f;
 196                 else
 197                         self.punchangle = '0 0 0';
 198         }
 199
 200         if (self.punchvector != '0 0 0')
 201         {
 202                 f = vlen(self.punchvector) - 30 * frametime;
 203                 if (f > 0)
 204                         self.punchvector = normalize(self.punchvector) * f;
 205                 else
 206                         self.punchvector = '0 0 0';
 207         }
 208
 209         maxspd_mod = 1;
 210
 211         if(g_runematch)
 212         {
 213                 if(self.runes & RUNE_SPEED)
 214                 {
 215                         if(self.runes & CURSE_SLOW)
 216                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 217                         else
 218                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 219                 }
 220                 else if(self.runes & CURSE_SLOW)
 221                 {
 222                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 223                 }
 224         }
 225
 226         if(g_minstagib && (self.items & IT_INVINCIBLE))
 227         {
 228                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 229         }
 230
 231         swampspd_mod = 1;
 232         if(self.in_swamp) {
 233                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 234         }
 235
 236         if(self.flags & FL_NOTARGET)
 237         {
 238                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 239                 if(!self.spectatorspeed)
 240                         self.spectatorspeed = maxspd_mod;
 241                 if(self.impulse && self.impulse <= 19)
 242                 {
 243                         if(self.lastflags & FL_NOTARGET)
 244                         {
 245                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 246                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 247                                 else if(self.impulse == 11)
 248                                         self.spectatorspeed = maxspd_mod;
 249                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 250                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 251                                 else if(self.impulse >= 1 && self.impulse <= 9)
 252                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 253                         } // otherwise just clear
 254                         self.impulse = 0;
 255                 }
 256                 maxspd_mod = self.spectatorspeed;
 257         }
 258
 259         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 260
 261         if(self.speed != spd)
 262         {
 263                 self.speed = spd;
 264                 temps = ftos(spd);
 265                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 266                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 267                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 268                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 269
 270                 temps = ftos(sv_accelerate * maxspd_mod);
 271                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 272         }
 273
 274         // if dead, behave differently
 275         if (self.deadflag)
 276                 return;
 277
 278         if (!self.fixangle && !g_bugrigs)
 279         {
 280                 self.angles_x = 0;
 281                 self.angles_y = self.v_angle_y;
 282                 self.angles_z = 0;
 283         }
 284
 285         if(self.flags & FL_ONGROUND)
 286         if(self.wasFlying)
 287         {
 288                 self.wasFlying = 0;
 289
 290                 if(self.waterlevel < 2)
 291                 if(time >= self.ladder_time)
 292                 if not(self.hook)
 293                 {
 294                         self.nextstep = time + 0.3 + random() * 0.1;
 295                         trace_dphitq3surfaceflags = 0;
 296                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 297                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 298                         {
 299                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 300                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 301                                 else
 302                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 303                         }
 304                 }
 305         }
 306
 307         if(IsFlying(self))
 308                 self.wasFlying = 1;
 309
 310         if(self.classname == "player")
 311         {
 312                 if(sv_doublejump)
 313                 {
 314                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 315                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 316                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 317                                 self.flags = self.flags | FL_ONGROUND;
 318                 }
 319
 320                 if (self.BUTTON_JUMP)
 321                         PlayerJump ();
 322                 else
 323                         self.flags = self.flags | FL_JUMPRELEASED;
 324
 325                 if (self.waterlevel == 2)
 326                         CheckWaterJump ();
 327         }
 328
 329         if (self.flags & FL_WATERJUMP )
 330         {
 331                 self.velocity_x = self.movedir_x;
 332                 self.velocity_y = self.movedir_y;
 333                 if (time > self.teleport_time || self.waterlevel == 0)
 334                 {
 335                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 336                         self.teleport_time = 0;
 337                 }
 338         }
 339         else if (g_bugrigs && self.classname == "player")
 340         {
 341                 // using this move type for "big rigs"
 342                 // the engine does not push the entity!
 343
 344                 float accel, steer, myspeed, steerfactor, accelfactor, upspeed, friction;
 345                 vector neworigin, up, angles_save, rigvel, rigvel_xy;
 346
 347                 angles_save = self.angles;
 348                 accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 349                 steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 350
 351                 if(accel < 0)
 352                 {
 353                         // back accel is DIGITAL
 354                         if(accel < -0.5)
 355                                 accel = -1;
 356                         else
 357                                 accel = 0;
 358                 }
 359
 360                 self.angles_x = 0;
 361                 self.angles_z = 0;
 362                 makevectors(self.angles); // new forward direction!
 363
 364                 if(self.flags & FL_ONGROUND || g_bugrigs == 1)
 365                 // BUG RIGS: responsive to movement while in air (matches big rigs better where the car is NEVER in air)
 366                 // g_bugrigs 2 turns off that bug
 367                 {
 368                         myspeed = self.velocity * v_forward;
 369                         upspeed = self.velocity * v_up;
 370
 371                         // responsiveness factor for steering and acceleration
 372                         f = 1 / (1 + pow(max(0, myspeed / 400), 2));
 373
 374                         steerfactor = -myspeed * f;
 375                         accelfactor = f * 800;
 376
 377                         // BUG RIGS: make friction FAIL if reversing
 378                         if(accel < 0)
 379                         {
 380                                 if(myspeed <= 0)
 381                                         friction = 0;
 382                                 else
 383                                         myspeed = max(0, myspeed - frametime * 1000);
 384                         }
 385                         else
 386                                 myspeed = max(0, myspeed - frametime * 50);
 387                                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 388
 389                         // BUG RIGS: stop when reversing and releasing the button
 390                         if(myspeed < 0 && accel >= 0)
 391                                 myspeed = 0;
 392
 393                         self.angles_y += steer * frametime * steerfactor; // apply steering
 394                         makevectors(self.angles); // new forward direction!
 395
 396                         myspeed += accel * accelfactor * frametime;
 397
 398                         rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 399                 }
 400                 else
 401                 {
 402                         myspeed = vlen(self.velocity);
 403
 404                         // responsiveness factor for steering and acceleration
 405                         f = 1 / (1 + pow(max(0, myspeed / 400), 2));
 406                         steerfactor = -myspeed * f;
 407                         self.angles_y += steer * frametime * steerfactor; // apply steering
 408
 409                         rigvel = self.velocity;
 410                         makevectors(self.angles); // new forward direction!
 411                 }
 412
 413                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 414                 rigvel_xy = rigvel;
 415                 rigvel_xy_z = 0;
 416
 417                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', MOVE_NORMAL, self);
 418                 up = trace_endpos - self.origin;
 419
 420                 // BUG RIGS: align the move to the surface instead of doing collision testing
 421                 // can we move?
 422                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, MOVE_NORMAL, self);
 423
 424                 // align to surface
 425                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, MOVE_NORMAL, self);
 426
 427                 if(trace_fraction < 0.5)
 428                 {
 429                         trace_fraction = 1;
 430                         neworigin = self.origin;
 431                 }
 432                 else
 433                         neworigin = trace_endpos;
 434
 435                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 436
 437                 if(trace_fraction < 1)
 438                 {
 439                         // now set angles_x so that the car points parallel to the surface
 440                         self.angles = vectoangles(
 441                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 442                                 +
 443                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 444                                 +
 445                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 446                         );
 447                         self.flags |= FL_ONGROUND;
 448                 }
 449                 else
 450                 {
 451                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 452                         vector vel_local;
 453
 454                         vel_local_x = v_forward * self.velocity;
 455                         vel_local_y = v_right * self.velocity;
 456                         vel_local_z = v_up * self.velocity;
 457
 458                         self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 459                         self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 460
 461                         self.flags (-) FL_ONGROUND;
 462                 }
 463
 464                 // smooth the angles
 465                 vector vf1, vu1, smoothangles;
 466                 makevectors(self.angles);
 467                 f = frametime * 5;
 468                 vf1 = v_forward * f;
 469                 vu1 = v_up * f;
 470                 makevectors(angles_save);
 471                 vf1 = vf1 + v_forward * (1 - f);
 472                 vu1 = vu1 + v_up * (1 - f);
 473                 smoothangles = vectoangles2(vf1, vu1);
 474                 self.angles_x = -smoothangles_x;
 475                 self.angles_z =  smoothangles_z;
 476         }
 477         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 478         {
 479                 // noclipping or flying
 480                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 481
 482                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 483                 makevectors(self.v_angle);
 484                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 485                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 486                 // acceleration
 487                 wishdir = normalize(wishvel);
 488                 wishspeed = vlen(wishvel);
 489                 if (wishspeed > sv_maxspeed*maxspd_mod)
 490                         wishspeed = sv_maxspeed*maxspd_mod;
 491                 if (time >= self.teleport_time)
 492                 {
 493                         f = wishspeed - (self.velocity * wishdir);
 494                         if (f > 0)
 495                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 496                 }
 497         }
 498         else if (self.waterlevel >= 2)
 499         {
 500                 // swimming
 501                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 502
 503                 makevectors(self.v_angle);
 504                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 505                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 506                 if (wishvel == '0 0 0')
 507                         wishvel = '0 0 -60'; // drift towards bottom
 508
 509                 wishdir = normalize(wishvel);
 510                 wishspeed = vlen(wishvel);
 511                 if (wishspeed > sv_maxspeed*maxspd_mod)
 512                         wishspeed = sv_maxspeed*maxspd_mod;
 513                 wishspeed = wishspeed * 0.7;
 514
 515                 // water friction
 516                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 517
 518                 // water acceleration
 519                 f = wishspeed - (self.velocity * wishdir);
 520                 if (f > 0)
 521                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 522         }
 523         else if (time < self.ladder_time)
 524         {
 525                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 526                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 527
 528                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 529                 makevectors(self.v_angle);
 530                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 531                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 532                 if (self.gravity)
 533                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 534                 else
 535                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 536                 if (self.ladder_entity.classname == "func_water")
 537                 {
 538                         f = vlen(wishvel);
 539                         if (f > self.ladder_entity.speed)
 540                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 541
 542                         self.watertype = self.ladder_entity.skin;
 543                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 544                         if ((self.origin_z + self.view_ofs_z) < f)
 545                                 self.waterlevel = 3;
 546                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 547                                 self.waterlevel = 2;
 548                         else if ((self.origin_z + self.mins_z + 1) < f)
 549                                 self.waterlevel = 1;
 550                         else
 551                         {
 552                                 self.waterlevel = 0;
 553                                 self.watertype = CONTENT_EMPTY;
 554                         }
 555                 }
 556                 // acceleration
 557                 wishdir = normalize(wishvel);
 558                 wishspeed = vlen(wishvel);
 559                 if (wishspeed > sv_maxspeed)
 560                         wishspeed = sv_maxspeed;
 561                 if (time >= self.teleport_time)
 562                 {
 563                         f = wishspeed - (self.velocity * wishdir);
 564                         if (f > 0)
 565                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 566                 }
 567         }
 568         else if (self.flags & FL_ONGROUND)
 569         {
 570                 // walking
 571                 makevectors(self.v_angle_y * '0 1 0');
 572                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 573
 574                 if(!(self.lastflags & FL_ONGROUND))
 575                 {
 576                         if(cvar("speedmeter"))
 577                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 578                         if(self.lastground < time - 0.3)
 579                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 580                         if(self.jumppadcount > 1)
 581                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 582                         self.jumppadcount = 0;
 583                 }
 584
 585                 if (self.velocity_x || self.velocity_y)
 586                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 587                 {
 588                         v = self.velocity;
 589                         v_z = 0;
 590                         f = vlen(v);
 591                         if (f < sv_stopspeed)
 592                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 593                         else
 594                                 f = 1 - frametime * sv_friction;
 595                         if (f > 0)
 596                                 self.velocity = self.velocity * f;
 597                         else
 598                                 self.velocity = '0 0 0';
 599                 }
 600                 // acceleration
 601                 wishdir = normalize(wishvel);
 602                 wishspeed = vlen(wishvel);
 603                 if (wishspeed > sv_maxspeed*maxspd_mod)
 604                         wishspeed = sv_maxspeed*maxspd_mod;
 605                 if (self.crouch)
 606                         wishspeed = wishspeed * 0.5;
 607                 if (time >= self.teleport_time)
 608                 {
 609                         f = wishspeed - (self.velocity * wishdir);
 610                         if (f > 0)
 611                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 612                 }
 613         }
 614         else
 615         {
 616                 if(maxspd_mod < 1)
 617                 {
 618                         maxairspd = sv_maxairspeed*maxspd_mod;
 619                         airaccel = sv_airaccelerate*maxspd_mod;
 620                 }
 621                 else
 622                 {
 623                         maxairspd = sv_maxairspeed;
 624                         airaccel = sv_airaccelerate;
 625                 }
 626                 // airborn
 627                 makevectors(self.v_angle_y * '0 1 0');
 628                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 629                 // acceleration
 630                 wishdir = normalize(wishvel);
 631                 wishspeed = vlen(wishvel);
 632                 if (wishspeed > maxairspd)
 633                         wishspeed = maxairspd;
 634                 if (self.crouch)
 635                         wishspeed = wishspeed * 0.5;
 636                 if (time >= self.teleport_time)
 637                 {
 638                         // NOTE: this does the same as the commented out old code if:
 639                         //   sv_airaccel_qw 0
 640                         //   sv_airaccel_sideways_friction 0
 641
 642                         float vel_straight;
 643                         float vel_z;
 644                         vector vel_perpend;
 645                         vel_straight = self.velocity * wishdir;
 646                         vel_z = self.velocity_z;
 647                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 648
 649                         f = wishspeed - vel_straight;
 650                         if(f > 0)
 651                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 652                         if(wishspeed > 0)
 653                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 654
 655                         // anti-sideways friction to fix QW-style bunnyhopping
 656                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 657
 658                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 659
 660                         /*
 661                         f = wishspeed;// - (self.velocity * wishdir);
 662                         if (f > 0)
 663                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 664                         */
 665                 }
 666         }
 667
 668         if(self.flags & FL_ONGROUND)
 669                 self.lastground = time;
 670
 671         self.lastflags = self.flags;
 672 };