data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         float mjumpheight;
  27
  28         mjumpheight = cvar("g_balance_jumpheight");
  29         if (self.waterlevel >= 2)
  30         {
  31                 if (self.watertype == CONTENT_WATER)
  32                         self.velocity_z = 200;
  33                 else if (self.watertype == CONTENT_SLIME)
  34                         self.velocity_z = 80;
  35                 else
  36                         self.velocity_z = 50;
  37
  38                 return;
  39         }
  40
  41
  42         if (!(self.flags & FL_ONGROUND))
  43                 return;
  44
  45         if (!(self.flags & FL_JUMPRELEASED))
  46                 return;
  47
  48         if(cvar("g_runematch"))
  49         {
  50                 if(self.runes & RUNE_SPEED)
  51                 {
  52                         if(self.runes & CURSE_SLOW)
  53                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  54                         else
  55                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  56                 }
  57                 else if(self.runes & CURSE_SLOW)
  58                 {
  59                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  60                 }
  61         }
  62
  63         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  64         {
  65                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  66         }
  67
  68         self.velocity_z = self.velocity_z + mjumpheight;
  69         self.oldvelocity_z = self.velocity_z;
  70
  71         self.flags = self.flags - FL_ONGROUND;
  72         self.flags = self.flags - FL_JUMPRELEASED;
  73 }
  74
  75 void() CheckWaterJump =
  76 {
  77         local vector start, end;
  78
  79 // check for a jump-out-of-water
  80         makevectors (self.angles);
  81         start = self.origin;
  82         start_z = start_z + 8;
  83         v_forward_z = 0;
  84         normalize(v_forward);
  85         end = start + v_forward*24;
  86         traceline (start, end, TRUE, self);
  87         if (trace_fraction < 1)
  88         {       // solid at waist
  89                 start_z = start_z + self.maxs_z - 8;
  90                 end = start + v_forward*24;
  91                 self.movedir = trace_plane_normal * -50;
  92                 traceline (start, end, TRUE, self);
  93                 if (trace_fraction == 1)
  94                 {       // open at eye level
  95                         self.flags = self.flags | FL_WATERJUMP;
  96                         self.velocity_z = 225;
  97                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
  98                         self.teleport_time = time + 2;  // safety net
  99                         return;
 100                 }
 101         }
 102 };
 103
 104
 105 void Nixnex_GiveCurrentWeapon();
 106 void SV_PlayerPhysics()
 107 {
 108         local vector wishvel, wishdir, v;
 109         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod;
 110         string temps;
 111
 112         if (clienttype(self) == CLIENTTYPE_BOT)
 113                 bot_think();
 114
 115         if (self.movetype == MOVETYPE_NONE)
 116                 return;
 117
 118         if (self.punchangle != '0 0 0')
 119         {
 120                 f = vlen(self.punchangle) - 10 * frametime;
 121                 if (f > 0)
 122                         self.punchangle = normalize(self.punchangle) * f;
 123                 else
 124                         self.punchangle = '0 0 0';
 125         }
 126
 127         if (self.punchvector != '0 0 0')
 128         {
 129                 f = vlen(self.punchvector) - 30 * frametime;
 130                 if (f > 0)
 131                         self.punchvector = normalize(self.punchvector) * f;
 132                 else
 133                         self.punchvector = '0 0 0';
 134         }
 135
 136         maxspd_mod = 1;
 137
 138         if(cvar("g_runematch"))
 139         {
 140                 if(self.runes & RUNE_SPEED)
 141                 {
 142                         if(self.runes & CURSE_SLOW)
 143                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 144                         else
 145                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 146                 }
 147                 else if(self.runes & CURSE_SLOW)
 148                 {
 149                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 150                 }
 151         }
 152
 153         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 154         {
 155                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
 156         }
 157
 158         swampspd_mod = 1;
 159         if(self.in_swamp) {
 160                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 161         }
 162
 163         if(self.flags & FL_NOTARGET)
 164                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 165
 166         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 167
 168         if(self.speed != spd)
 169         {
 170                 self.speed = spd;
 171                 temps = ftos(spd);
 172                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 173                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 174                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 175                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 176
 177                 temps = ftos(sv_accelerate * maxspd_mod);
 178                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 179         }
 180
 181         // if dead, behave differently
 182         if (self.deadflag)
 183                 return;
 184
 185         UpdateSelectedPlayer();
 186
 187         if (!self.fixangle)
 188         {
 189                 self.angles_x = 0;
 190                 self.angles_y = self.v_angle_y;
 191                 self.angles_z = 0;
 192         }
 193
 194         if(self.classname == "player")
 195         {
 196                 if (self.button2)
 197                         PlayerJump ();
 198                 else
 199                         self.flags = self.flags | FL_JUMPRELEASED;
 200         }
 201
 202         if (self.flags & FL_WATERJUMP )
 203         {
 204                 self.velocity_x = self.movedir_x;
 205                 self.velocity_y = self.movedir_y;
 206                 if (time > self.teleport_time || self.waterlevel == 0)
 207                 {
 208                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 209                         self.teleport_time = 0;
 210                 }
 211         }
 212         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 213         {
 214                 // noclipping or flying
 215                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 216
 217                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 218                 makevectors(self.v_angle);
 219                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 220                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 221                 // acceleration
 222                 wishdir = normalize(wishvel);
 223                 wishspeed = vlen(wishvel);
 224                 if (wishspeed > sv_maxspeed*maxspd_mod)
 225                         wishspeed = sv_maxspeed*maxspd_mod;
 226                 if (time >= self.teleport_time)
 227                 {
 228                         f = wishspeed - (self.velocity * wishdir);
 229                         if (f > 0)
 230                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 231                 }
 232         }
 233         else if (self.waterlevel >= 2)
 234         {
 235                 // swimming
 236                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 237
 238                 makevectors(self.v_angle);
 239                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 240                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 241                 if (wishvel == '0 0 0')
 242                         wishvel = '0 0 -60'; // drift towards bottom
 243
 244                 wishdir = normalize(wishvel);
 245                 wishspeed = vlen(wishvel);
 246                 if (wishspeed > sv_maxspeed*maxspd_mod)
 247                         wishspeed = sv_maxspeed*maxspd_mod;
 248                 wishspeed = wishspeed * 0.7;
 249
 250                 // water friction
 251                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 252
 253                 // water acceleration
 254                 f = wishspeed - (self.velocity * wishdir);
 255                 if (f > 0)
 256                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 257         }
 258         else if (time < self.ladder_time)
 259         {
 260                 // on a func_ladder or swimming in func_water
 261                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 262
 263                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 264                 makevectors(self.v_angle);
 265                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 266                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 267                 if (self.gravity)
 268                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 269                 else
 270                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 271                 if (self.ladder_entity.classname == "func_water")
 272                 {
 273                         f = vlen(wishvel);
 274                         if (f > self.ladder_entity.speed)
 275                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 276
 277                         self.watertype = self.ladder_entity.skin;
 278                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 279                         if ((self.origin_z + self.view_ofs_z) < f)
 280                                 self.waterlevel = 3;
 281                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 282                                 self.waterlevel = 2;
 283                         else if ((self.origin_z + self.mins_z + 1) < f)
 284                                 self.waterlevel = 1;
 285                         else
 286                         {
 287                                 self.waterlevel = 0;
 288                                 self.watertype = CONTENT_EMPTY;
 289                         }
 290                 }
 291                 // acceleration
 292                 wishdir = normalize(wishvel);
 293                 wishspeed = vlen(wishvel);
 294                 if (wishspeed > sv_maxspeed)
 295                         wishspeed = sv_maxspeed;
 296                 if (time >= self.teleport_time)
 297                 {
 298                         f = wishspeed - (self.velocity * wishdir);
 299                         if (f > 0)
 300                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 301                 }
 302         }
 303         else if (self.flags & FL_ONGROUND)
 304         {
 305                 // walking
 306                 makevectors(self.v_angle_y * '0 1 0');
 307                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 308
 309                 if(!(self.lastflags & FL_ONGROUND))
 310                 {
 311                         if(cvar("speedmeter"))
 312                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 313                         if(self.lastground < time - 0.3)
 314                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 315                         if(self.jumppadcount > 1)
 316                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 317                         self.jumppadcount = 0;
 318                 }
 319
 320                 if (self.velocity_x || self.velocity_y)
 321                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 322                 {
 323                         v = self.velocity;
 324                         v_z = 0;
 325                         f = vlen(v);
 326                         if (f < sv_stopspeed)
 327                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 328                         else
 329                                 f = 1 - frametime * sv_friction;
 330                         if (f > 0)
 331                                 self.velocity = self.velocity * f;
 332                         else
 333                                 self.velocity = '0 0 0';
 334                 }
 335                 // acceleration
 336                 wishdir = normalize(wishvel);
 337                 wishspeed = vlen(wishvel);
 338                 if (wishspeed > sv_maxspeed*maxspd_mod)
 339                         wishspeed = sv_maxspeed*maxspd_mod;
 340                 if (self.crouch)
 341                         wishspeed = wishspeed * 0.5;
 342                 if (time >= self.teleport_time)
 343                 {
 344                         f = wishspeed - (self.velocity * wishdir);
 345                         if (f > 0)
 346                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 347                 }
 348         }
 349         else
 350         {
 351                 if(maxspd_mod < 1)
 352                 {
 353                         maxairspd = sv_maxairspeed*maxspd_mod;
 354                         airaccel = sv_airaccelerate*maxspd_mod;
 355                 }
 356                 else
 357                 {
 358                         maxairspd = sv_maxairspeed;
 359                         airaccel = sv_airaccelerate;
 360                 }
 361                 // airborn
 362                 makevectors(self.v_angle_y * '0 1 0');
 363                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 364                 // acceleration
 365                 wishdir = normalize(wishvel);
 366                 wishspeed = vlen(wishvel);
 367                 if (wishspeed > maxairspd)
 368                         wishspeed = maxairspd;
 369                 if (self.crouch)
 370                         wishspeed = wishspeed * 0.5;
 371                 if (time >= self.teleport_time)
 372                 {
 373                         // NOTE: this does the same as the commented out old code if:
 374                         //   sv_airaccel_qw 0
 375                         //   sv_airaccel_sideways_friction 0
 376
 377                         float vel_straight;
 378                         float vel_z;
 379                         vector vel_perpend;
 380                         vel_straight = self.velocity * wishdir;
 381                         vel_z = self.velocity_z;
 382                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 383
 384                         f = wishspeed - vel_straight;
 385                         if(f > 0)
 386                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 387                         if(wishspeed > 0)
 388                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 389
 390                         // anti-sideways friction to fix QW-style bunnyhopping
 391                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 392
 393                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 394
 395                         /*
 396                         f = wishspeed;// - (self.velocity * wishdir);
 397                         if (f > 0)
 398                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 399                         */
 400                 }
 401         }
 402
 403         if(self.flags & FL_ONGROUND)
 404                 self.lastground = time;
 405
 406         self.lastflags = self.flags;
 407 };