data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 #define SHTEST_DELTA 10
  33 #define SHTEST_THRESHOLD 1.1
  34 .float shtest_next;
  35 .float shtest_accumulator;
  36 .float doublejump_nextjumptime;
  37
  38 /*
  39 =============
  40 PlayerJump
  41
  42 When you press the jump key
  43 =============
  44 */
  45 void PlayerJump (void)
  46 {
  47         float mjumpheight;
  48
  49         mjumpheight = cvar("sv_jumpvelocity");
  50         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  51         {
  52                 if (self.watertype == CONTENT_WATER)
  53                         self.velocity_z = 200;
  54                 else if (self.watertype == CONTENT_SLIME)
  55                         self.velocity_z = 80;
  56                 else
  57                         self.velocity_z = 50;
  58
  59                 return;
  60         }
  61
  62         if (!(self.flags & FL_ONGROUND))
  63                 return;
  64
  65         if(!sv_pogostick)
  66                 if (!(self.flags & FL_JUMPRELEASED))
  67                         return;
  68
  69         if(self.health <= g_bloodloss)
  70                 return;
  71
  72         if(sv_doublejump)
  73                 if(time < self.doublejump_nextjumptime)
  74                         return;
  75
  76         if(g_runematch)
  77         {
  78                 if(self.runes & RUNE_SPEED)
  79                 {
  80                         if(self.runes & CURSE_SLOW)
  81                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  82                         else
  83                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  84                 }
  85                 else if(self.runes & CURSE_SLOW)
  86                 {
  87                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  88                 }
  89         }
  90
  91         if(g_minstagib && (self.items & IT_INVINCIBLE))
  92         {
  93                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  94         }
  95
  96         if(!(self.lastflags & FL_ONGROUND))
  97         {
  98                 if(cvar("speedmeter"))
  99                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 100                 if(self.lastground < time - 0.3)
 101                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 102                 if(self.jumppadcount > 1)
 103                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 104                 self.jumppadcount = 0;
 105         }
 106
 107         self.velocity_z = self.velocity_z + mjumpheight;
 108         self.oldvelocity_z = self.velocity_z;
 109
 110         self.flags &~= FL_ONGROUND;
 111         self.flags &~= FL_JUMPRELEASED;
 112
 113         if (self.crouch)
 114                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 115         else
 116                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 117
 118         if(g_jump_grunt)
 119                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 120
 121         if(sv_doublejump)
 122         {
 123                 // we're moving upwards at self.velocity_z
 124                 // only allow jumping after we got 3 units upwards
 125                 // so we for sure leave the FL_ONGROUND check
 126                 //
 127                 // but as this sucks because of factoring in gravity, we'll just do it
 128                 // for 4 units, and constant velocity
 129                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 130         }
 131
 132         self.restart_jump = TRUE; // restart jump anim next time
 133 }
 134
 135 void CheckWaterJump()
 136 {
 137         local vector start, end;
 138
 139 // check for a jump-out-of-water
 140         makevectors (self.angles);
 141         start = self.origin;
 142         start_z = start_z + 8;
 143         v_forward_z = 0;
 144         normalize(v_forward);
 145         end = start + v_forward*24;
 146         traceline (start, end, TRUE, self);
 147         if (trace_fraction < 1)
 148         {       // solid at waist
 149                 start_z = start_z + self.maxs_z - 8;
 150                 end = start + v_forward*24;
 151                 self.movedir = trace_plane_normal * -50;
 152                 traceline (start, end, TRUE, self);
 153                 if (trace_fraction == 1)
 154                 {       // open at eye level
 155                         self.flags |= FL_WATERJUMP;
 156                         self.velocity_z = 225;
 157                         self.flags &~= FL_JUMPRELEASED;
 158                         self.teleport_time = time + 2;  // safety net
 159                         return;
 160                 }
 161         }
 162 };
 163
 164 float racecar_angle(float forward, float down)
 165 {
 166         float ret, angle_mult;
 167
 168         if(forward < 0)
 169         {
 170                 forward = -forward;
 171                 down = -down;
 172         }
 173
 174         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 175
 176         angle_mult = forward / (800 + forward);
 177
 178         if(ret > 180)
 179                 return ret * angle_mult + 360 * (1 - angle_mult);
 180         else
 181                 return ret * angle_mult;
 182 }
 183
 184 void RaceCarPhysics()
 185 {
 186         // using this move type for "big rigs"
 187         // the engine does not push the entity!
 188
 189         float accel, steer, f;
 190         vector angles_save, rigvel;
 191
 192         angles_save = self.angles;
 193         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 194         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 195
 196         if(g_bugrigs_reverse_speeding)
 197         {
 198                 if(accel < 0)
 199                 {
 200                         // back accel is DIGITAL
 201                         // to prevent speedhack
 202                         if(accel < -0.5)
 203                                 accel = -1;
 204                         else
 205                                 accel = 0;
 206                 }
 207         }
 208
 209         self.angles_x = 0;
 210         self.angles_z = 0;
 211         makevectors(self.angles); // new forward direction!
 212
 213         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 214         {
 215                 float myspeed, upspeed, steerfactor, accelfactor;
 216
 217                 myspeed = self.velocity * v_forward;
 218                 upspeed = self.velocity * v_up;
 219
 220                 // responsiveness factor for steering and acceleration
 221                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 222                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 223
 224                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 225                         steerfactor = -myspeed * g_bugrigs_steer;
 226                 else
 227                         steerfactor = -myspeed * f * g_bugrigs_steer;
 228
 229                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 230                         accelfactor = g_bugrigs_accel;
 231                 else
 232                         accelfactor = f * g_bugrigs_accel;
 233                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 234
 235                 if(accel < 0)
 236                 {
 237                         if(myspeed > 0)
 238                         {
 239                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 240                         }
 241                         else
 242                         {
 243                                 if(!g_bugrigs_reverse_speeding)
 244                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 245                         }
 246                 }
 247                 else
 248                 {
 249                         if(myspeed >= 0)
 250                         {
 251                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 252                         }
 253                         else
 254                         {
 255                                 if(g_bugrigs_reverse_stopping)
 256                                         myspeed = 0;
 257                                 else
 258                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 259                         }
 260                 }
 261                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 262                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 263
 264                 self.angles_y += steer * frametime * steerfactor; // apply steering
 265                 makevectors(self.angles); // new forward direction!
 266
 267                 myspeed += accel * accelfactor * frametime;
 268
 269                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 270         }
 271         else
 272         {
 273                 myspeed = vlen(self.velocity);
 274
 275                 // responsiveness factor for steering and acceleration
 276                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 277                 steerfactor = -myspeed * f;
 278                 self.angles_y += steer * frametime * steerfactor; // apply steering
 279
 280                 rigvel = self.velocity;
 281                 makevectors(self.angles); // new forward direction!
 282         }
 283
 284         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 285         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 286         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 287         //MAXIMA: solve(total_acceleration(v) = 0, v);
 288
 289         if(g_bugrigs_planar_movement)
 290         {
 291                 vector rigvel_xy, neworigin, up;
 292                 float mt;
 293
 294                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 295                 rigvel_xy = rigvel;
 296                 rigvel_xy_z = 0;
 297
 298                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 299                         mt = MOVE_NORMAL;
 300                 else
 301                         mt = MOVE_NOMONSTERS;
 302
 303                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 304                 up = trace_endpos - self.origin;
 305
 306                 // BUG RIGS: align the move to the surface instead of doing collision testing
 307                 // can we move?
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 309
 310                 // align to surface
 311                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 312
 313                 if(trace_fraction < 0.5)
 314                 {
 315                         trace_fraction = 1;
 316                         neworigin = self.origin;
 317                 }
 318                 else
 319                         neworigin = trace_endpos;
 320
 321                 if(trace_fraction < 1)
 322                 {
 323                         // now set angles_x so that the car points parallel to the surface
 324                         self.angles = vectoangles(
 325                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 326                                         +
 327                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 328                                         +
 329                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 330                                         );
 331                         self.flags |= FL_ONGROUND;
 332                 }
 333                 else
 334                 {
 335                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 336                         self.flags &~= FL_ONGROUND;
 337                 }
 338
 339                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 340                 self.movetype = MOVETYPE_NOCLIP;
 341         }
 342         else
 343         {
 344                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 345                 self.velocity = rigvel;
 346                 self.movetype = MOVETYPE_FLY;
 347         }
 348
 349         trace_fraction = 1;
 350         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 351         if(trace_fraction != 1)
 352         {
 353                 self.angles = vectoangles2(
 354                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 355                                 +
 356                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 357                                 +
 358                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 359                                 trace_plane_normal
 360                                 );
 361         }
 362         else
 363         {
 364                 vector vel_local;
 365
 366                 vel_local_x = v_forward * self.velocity;
 367                 vel_local_y = v_right * self.velocity;
 368                 vel_local_z = v_up * self.velocity;
 369
 370                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 371                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 372         }
 373
 374         // smooth the angles
 375         vector vf1, vu1, smoothangles;
 376         makevectors(self.angles);
 377         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 378         if(f == 0)
 379                 f = 1;
 380         vf1 = v_forward * f;
 381         vu1 = v_up * f;
 382         makevectors(angles_save);
 383         vf1 = vf1 + v_forward * (1 - f);
 384         vu1 = vu1 + v_up * (1 - f);
 385         smoothangles = vectoangles2(vf1, vu1);
 386         self.angles_x = -smoothangles_x;
 387         self.angles_z =  smoothangles_z;
 388 }
 389
 390 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 391 {
 392         float zspeed, xyspeed, dot, k;
 393
 394         if(self.movement_x == 0 || self.movement_y != 0)
 395                 return; // can't control movement if not moving forward or backward
 396
 397         zspeed = self.velocity_z;
 398         self.velocity_z = 0;
 399         xyspeed = vlen(self.velocity);
 400         self.velocity = normalize(self.velocity);
 401
 402         dot = self.velocity * wishdir;
 403         k = 32;
 404         k *= sv_aircontrol*dot*dot*frametime;
 405
 406         if(dot > 0) // we can't change direction while slowing down
 407                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 408
 409         self.velocity = self.velocity * xyspeed;
 410         self.velocity_z = zspeed;
 411 }
 412
 413 void PM_Accelerate(vector wishdir, float wishspeed, float accel, float accelqw, float sidefric)
 414 {
 415         float vel_straight;
 416         float vel_z;
 417         vector vel_perpend;
 418         float addspeed;
 419
 420         vel_straight = self.velocity * wishdir;
 421         vel_z = self.velocity_z;
 422         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 423
 424         addspeed = wishspeed - vel_straight;
 425         if(addspeed > 0)
 426                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed) * accelqw;
 427         if(wishspeed > 0)
 428                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed) * (1 - accelqw);
 429
 430         vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 431
 432         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 433 }
 434
 435 void PM_AirAccelerate(vector wishdir, float wishspeed)
 436 {
 437         vector curvel, wishvel, acceldir, curdir;
 438         float addspeed, accelspeed, curspeed, f;
 439         float dot;
 440
 441         if(wishspeed == 0)
 442                 return;
 443
 444         curvel = self.velocity;
 445         curvel_z = 0;
 446         curspeed = vlen(curvel);
 447
 448         if(wishspeed > curspeed * 1.01)
 449         {
 450                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 451         }
 452         else
 453         {
 454                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 455                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 456         }
 457         wishvel = wishdir * wishspeed;
 458         acceldir = wishvel - curvel;
 459         addspeed = vlen(acceldir);
 460         acceldir = normalize(acceldir);
 461
 462         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 463
 464         if(sv_warsowbunny_backtosideratio < 1)
 465         {
 466                 curdir = normalize(curvel);
 467                 dot = acceldir * curdir;
 468                 if(dot < 0)
 469                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 470         }
 471
 472         self.velocity += accelspeed * acceldir;
 473 }
 474
 475 .vector movement_old;
 476 .float buttons_old;
 477 .vector v_angle_old;
 478 .string lastclassname;
 479
 480 void Nixnex_GiveCurrentWeapon();
 481 .float() PlayerPhysplug;
 482
 483 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 484 .float specialcommand_pos;
 485 void SpecialCommand()
 486 {
 487 #ifdef TETRIS
 488         TetrisImpulse();
 489 #else
 490         if(sv_cheats || self.maycheat)
 491                 self.impulse = 99;
 492         else
 493                 print("A hollow voice says \"Plugh\".\n");
 494 #endif
 495 }
 496
 497 void SV_PlayerPhysics()
 498 {
 499         local vector wishvel, wishdir, v;
 500         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 501         string temps;
 502         float buttons_prev;
 503         float not_allowed_to_move;
 504         string c;
 505
 506         if(g_race || g_cts)
 507         {
 508                 // if record times matter
 509                 // ensure nothing EVIL is being done (i.e. strafebot)
 510                 // this hinders joystick users though
 511                 // but it still gives SOME analog control
 512                 // TODO implement this for engine cl_movement code too (basically, clipping to the four axes)
 513                 wishvel_x = fabs(self.movement_x);
 514                 wishvel_y = fabs(self.movement_y);
 515                 if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
 516                 {
 517                         wishvel_z = 0;
 518                         wishspeed = vlen(wishvel);
 519                         if(wishvel_x >= 2 * wishvel_y)
 520                         {
 521                                 // pure X motion
 522                                 if(self.movement_x > 0)
 523                                         self.movement_x = wishspeed;
 524                                 else
 525                                         self.movement_x = -wishspeed;
 526                                 self.movement_y = 0;
 527                         }
 528                         else if(wishvel_y >= 2 * wishvel_x)
 529                         {
 530                                 // pure Y motion
 531                                 self.movement_x = 0;
 532                                 if(self.movement_y > 0)
 533                                         self.movement_y = wishspeed;
 534                                 else
 535                                         self.movement_y = -wishspeed;
 536                         }
 537                         else
 538                         {
 539                                 // diagonal
 540                                 if(self.movement_x > 0)
 541                                         self.movement_x = 0.70710678118654752440 * wishspeed;
 542                                 else
 543                                         self.movement_x = -0.70710678118654752440 * wishspeed;
 544                                 if(self.movement_y > 0)
 545                                         self.movement_y = 0.70710678118654752440 * wishspeed;
 546                                 else
 547                                         self.movement_y = -0.70710678118654752440 * wishspeed;
 548                         }
 549                 }
 550         }
 551
 552         self.race_movetime_frac += frametime;
 553         f = floor(self.race_movetime_frac);
 554         self.race_movetime_frac -= f;
 555         self.race_movetime_count += f;
 556         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 557
 558         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 559
 560         if(!buttons)
 561                 c = "x";
 562         else if(buttons == 1)
 563                 c = "1";
 564         else if(buttons == 2)
 565                 c = " ";
 566         else if(buttons == 128)
 567                 c = "s";
 568         else if(buttons == 256)
 569                 c = "w";
 570         else if(buttons == 512)
 571                 c = "a";
 572         else if(buttons == 1024)
 573                 c = "d";
 574         else
 575                 c = "?";
 576
 577         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 578         {
 579                 self.specialcommand_pos += 1;
 580                 if(self.specialcommand_pos >= strlen(specialcommand))
 581                 {
 582                         self.specialcommand_pos = 0;
 583                         SpecialCommand();
 584                         return;
 585                 }
 586         }
 587         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 588                 self.specialcommand_pos = 0;
 589
 590     if(self.PlayerPhysplug)
 591         if(self.PlayerPhysplug())
 592             return;
 593
 594         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 595         {
 596                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 597                         self.parm_idlesince = time;
 598         }
 599         buttons_prev = self.buttons_old;
 600         self.buttons_old = buttons;
 601         self.movement_old = self.movement;
 602         self.v_angle_old = self.v_angle;
 603
 604         if(time < self.nickspamtime)
 605         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 606         {
 607                 // slight annoyance for nick change scripts
 608                 self.movement = -1 * self.movement;
 609                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 610
 611                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 612                 {
 613                         self.angles_x = random() * 360;
 614                         self.angles_y = random() * 360;
 615                         // at least I'm not forcing retardedview by also assigning to angles_z
 616                         self.fixangle = 1;
 617                 }
 618         }
 619
 620         if(time > self.shtest_next)
 621         {
 622                 if(self.shtest_next > 0)
 623                 {
 624                         // self.shtest_accumulator:
 625                         //   started at time - SHTEST_DELTA
 626                         //   should be at SHTEST_DELTA
 627                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 628                         if(shtest_score > SHTEST_THRESHOLD)
 629                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 630                         else if(cvar("developer_shtest"))
 631                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 632                 }
 633                 self.shtest_next = time + SHTEST_DELTA;
 634                 self.shtest_accumulator = 0;
 635         }
 636         self.shtest_accumulator += frametime;
 637
 638         if (clienttype(self) == CLIENTTYPE_BOT)
 639                 bot_think();
 640
 641         self.items &~= IT_USING_JETPACK;
 642
 643         if(self.classname == "player")
 644         {
 645                 if(self.race_penalty)
 646                         if(time > self.race_penalty)
 647                                 self.race_penalty = 0;
 648
 649                 not_allowed_to_move = 0;
 650                 if(self.race_penalty)
 651                         not_allowed_to_move = 1;
 652                 if(!cvar("sv_ready_restart_after_countdown"))
 653                 if(time < game_starttime)
 654                         not_allowed_to_move = 1;
 655
 656                 if(not_allowed_to_move)
 657                 {
 658                         self.velocity = '0 0 0';
 659                         self.movetype = MOVETYPE_NONE;
 660                         self.disableclientprediction = 2;
 661                 }
 662                 else if(self.disableclientprediction == 2)
 663                 {
 664                         if(self.movetype == MOVETYPE_NONE)
 665                                 self.movetype = MOVETYPE_WALK;
 666                         self.disableclientprediction = 0;
 667                 }
 668         }
 669
 670         if (self.movetype == MOVETYPE_NONE)
 671                 return;
 672
 673         if (self.punchangle != '0 0 0')
 674         {
 675                 f = vlen(self.punchangle) - 10 * frametime;
 676                 if (f > 0)
 677                         self.punchangle = normalize(self.punchangle) * f;
 678                 else
 679                         self.punchangle = '0 0 0';
 680         }
 681
 682         if (self.punchvector != '0 0 0')
 683         {
 684                 f = vlen(self.punchvector) - 30 * frametime;
 685                 if (f > 0)
 686                         self.punchvector = normalize(self.punchvector) * f;
 687                 else
 688                         self.punchvector = '0 0 0';
 689         }
 690
 691         maxspd_mod = 1;
 692
 693         if(g_runematch)
 694         {
 695                 if(self.runes & RUNE_SPEED)
 696                 {
 697                         if(self.runes & CURSE_SLOW)
 698                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 699                         else
 700                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 701                 }
 702                 else if(self.runes & CURSE_SLOW)
 703                 {
 704                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 705                 }
 706         }
 707
 708         if(g_minstagib && (self.items & IT_INVINCIBLE))
 709         {
 710                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 711         }
 712
 713         if(g_nexball && self.ballcarried)
 714         {
 715                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 716         }
 717
 718         swampspd_mod = 1;
 719         if(self.in_swamp) {
 720                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 721         }
 722
 723         if(self.classname != "player")
 724         {
 725                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 726                 if(!self.spectatorspeed)
 727                         self.spectatorspeed = maxspd_mod;
 728                 if(self.impulse && self.impulse <= 19)
 729                 {
 730                         if(self.lastclassname != "player")
 731                         {
 732                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 733                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 734                                 else if(self.impulse == 11)
 735                                         self.spectatorspeed = maxspd_mod;
 736                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 737                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 738                                 else if(self.impulse >= 1 && self.impulse <= 9)
 739                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 740                         } // otherwise just clear
 741                         self.impulse = 0;
 742                 }
 743                 maxspd_mod = self.spectatorspeed;
 744         }
 745
 746         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 747         if(self.speed != spd)
 748         {
 749                 self.speed = spd;
 750                 temps = ftos(spd);
 751                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 752                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 753                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 754                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 755         }
 756
 757         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 758         swampspd_mod = 1;
 759
 760         // if dead, behave differently
 761         if (self.deadflag)
 762                 goto end;
 763
 764         if (!self.fixangle && !g_bugrigs)
 765         {
 766                 self.angles_x = 0;
 767                 self.angles_y = self.v_angle_y;
 768                 self.angles_z = 0;
 769         }
 770
 771         if(self.flags & FL_ONGROUND)
 772         if(self.wasFlying)
 773         {
 774                 self.wasFlying = 0;
 775
 776                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 777                 if(time >= self.ladder_time)
 778                 if not(self.hook)
 779                 {
 780                         self.nextstep = time + 0.3 + random() * 0.1;
 781                         trace_dphitq3surfaceflags = 0;
 782                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 783                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 784                         {
 785                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 786                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 787                                 else
 788                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 789                         }
 790                 }
 791         }
 792
 793         if(IsFlying(self))
 794                 self.wasFlying = 1;
 795
 796         if(self.classname == "player")
 797         {
 798                 if(sv_doublejump)
 799                 {
 800                         self.flags &~= FL_ONGROUND;
 801                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 802                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 803                                 self.flags |= FL_ONGROUND;
 804                 }
 805
 806                 if (self.BUTTON_JUMP)
 807                         PlayerJump ();
 808                 else
 809                         self.flags |= FL_JUMPRELEASED;
 810
 811                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 812                         CheckWaterJump ();
 813         }
 814
 815         if (self.flags & FL_WATERJUMP )
 816         {
 817                 self.velocity_x = self.movedir_x;
 818                 self.velocity_y = self.movedir_y;
 819                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 820                 {
 821                         self.flags &~= FL_WATERJUMP;
 822                         self.teleport_time = 0;
 823                 }
 824         }
 825         else if (g_bugrigs && self.classname == "player")
 826         {
 827                 RaceCarPhysics();
 828         }
 829         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 830         {
 831                 // noclipping or flying
 832                 self.flags &~= FL_ONGROUND;
 833
 834                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 835                 makevectors(self.v_angle);
 836                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 837                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 838                 // acceleration
 839                 wishdir = normalize(wishvel);
 840                 wishspeed = vlen(wishvel);
 841                 if (wishspeed > sv_maxspeed*maxspd_mod)
 842                         wishspeed = sv_maxspeed*maxspd_mod;
 843                 if (time >= self.teleport_time)
 844                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 845         }
 846         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 847         {
 848                 // swimming
 849                 self.flags &~= FL_ONGROUND;
 850
 851                 makevectors(self.v_angle);
 852                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 853                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 854                 if (wishvel == '0 0 0')
 855                         wishvel = '0 0 -60'; // drift towards bottom
 856
 857                 wishdir = normalize(wishvel);
 858                 wishspeed = vlen(wishvel);
 859                 if (wishspeed > sv_maxspeed*maxspd_mod)
 860                         wishspeed = sv_maxspeed*maxspd_mod;
 861                 wishspeed = wishspeed * 0.7;
 862
 863                 // water friction
 864                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 865
 866                 // water acceleration
 867                 PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 868         }
 869         else if (time < self.ladder_time)
 870         {
 871                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 872                 self.flags &~= FL_ONGROUND;
 873
 874                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 875                 makevectors(self.v_angle);
 876                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 877                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 878                 if (self.gravity)
 879                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 880                 else
 881                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 882                 if (self.ladder_entity.classname == "func_water")
 883                 {
 884                         f = vlen(wishvel);
 885                         if (f > self.ladder_entity.speed)
 886                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 887
 888                         self.watertype = self.ladder_entity.skin;
 889                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 890                         if ((self.origin_z + self.view_ofs_z) < f)
 891                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 892                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 893                                 self.waterlevel = WATERLEVEL_SWIMMING;
 894                         else if ((self.origin_z + self.mins_z + 1) < f)
 895                                 self.waterlevel = WATERLEVEL_WETFEET;
 896                         else
 897                         {
 898                                 self.waterlevel = WATERLEVEL_NONE;
 899                                 self.watertype = CONTENT_EMPTY;
 900                         }
 901                 }
 902                 // acceleration
 903                 wishdir = normalize(wishvel);
 904                 wishspeed = vlen(wishvel);
 905                 if (wishspeed > sv_maxspeed*maxspd_mod)
 906                         wishspeed = sv_maxspeed*maxspd_mod;
 907                 if (time >= self.teleport_time)
 908                 {
 909                         // water acceleration
 910                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 911                 }
 912         }
 913         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 914         {
 915                 //makevectors(self.v_angle_y * '0 1 0');
 916                 makevectors(self.v_angle);
 917                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 918                 // add remaining speed as Z component
 919                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 920                 // fix speedhacks :P
 921                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 922                 // add the unused velocity as up component
 923                 wishvel_z = 0;
 924
 925                 // if(self.BUTTON_JUMP)
 926                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 927
 928                 // it is now normalized, so...
 929                 float a_side, a_up, a_add, a_diff;
 930                 a_side = cvar("g_jetpack_acceleration_side");
 931                 a_up = cvar("g_jetpack_acceleration_up");
 932                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 933
 934                 wishvel_x *= a_side;
 935                 wishvel_y *= a_side;
 936                 wishvel_z *= a_up;
 937                 wishvel_z += a_add;
 938
 939                 float best;
 940                 best = 0;
 941                 //////////////////////////////////////////////////////////////////////////////////////
 942                 // finding the maximum over all vectors of above form
 943                 // with wishvel having an absolute value of 1
 944                 //////////////////////////////////////////////////////////////////////////////////////
 945                 // we're finding the maximum over
 946                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 947                 // for z in the range from -1 to 1
 948                 //////////////////////////////////////////////////////////////////////////////////////
 949                 // maximum is EITHER attained at the single extreme point:
 950                 a_diff = a_side * a_side - a_up * a_up;
 951                 if(a_diff != 0)
 952                 {
 953                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 954                         if(f > -1 && f < 1) // can it be attained?
 955                         {
 956                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 957                                 //print("middle\n");
 958                         }
 959                 }
 960                 // OR attained at z = 1:
 961                 f = (a_up + a_add) * (a_up + a_add);
 962                 if(f > best)
 963                 {
 964                         best = f;
 965                         //print("top\n");
 966                 }
 967                 // OR attained at z = -1:
 968                 f = (a_up - a_add) * (a_up - a_add);
 969                 if(f > best)
 970                 {
 971                         best = f;
 972                         //print("bottom\n");
 973                 }
 974                 best = sqrt(best);
 975                 //////////////////////////////////////////////////////////////////////////////////////
 976
 977                 //print("best possible acceleration: ", ftos(best), "\n");
 978
 979                 float fxy, fz;
 980                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 981                 if(wishvel_z - sv_gravity > 0)
 982                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 983                 else
 984                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 985
 986                 float fvel;
 987                 fvel = vlen(wishvel);
 988                 wishvel_x *= fxy;
 989                 wishvel_y *= fxy;
 990                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 991
 992                 fvel = min(1, vlen(wishvel) / best);
 993                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 994                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 995                 else
 996                         f = 1;
 997
 998                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 999
1000                 if (f > 0 && wishvel != '0 0 0')
1001                 {
1002                         self.velocity = self.velocity + wishvel * f * frametime;
1003                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1004                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1005                         self.flags &~= FL_ONGROUND;
1006                         self.items |= IT_USING_JETPACK;
1007
1008                         // jetpack also inhibits health regeneration, but only for 1 second
1009                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1010                 }
1011         }
1012         else if (self.flags & FL_ONGROUND)
1013         {
1014                 // we get here if we ran out of ammo
1015                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1016                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1017
1018                 // walking
1019                 makevectors(self.v_angle_y * '0 1 0');
1020                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1021
1022                 if(!(self.lastflags & FL_ONGROUND))
1023                 {
1024                         if(cvar("speedmeter"))
1025                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1026                         if(self.lastground < time - 0.3)
1027                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1028                         if(self.jumppadcount > 1)
1029                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1030                         self.jumppadcount = 0;
1031                 }
1032
1033 #ifdef LETS_TEST_FTEQCC
1034                 if(self.velocity_x || self.velocity_y)
1035                 {
1036                         // good
1037                 }
1038                 else
1039                 {
1040                         if(self.velocity_x)
1041                                 checkclient();
1042                         if(self.velocity_y)
1043                                 checkclient();
1044                 }
1045 #endif
1046
1047                 v = self.velocity;
1048                 v_z = 0;
1049                 f = vlen(v);
1050                 if(f > 0)
1051                 {
1052                         if (f < sv_stopspeed)
1053                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1054                         else
1055                                 f = 1 - frametime * sv_friction;
1056                         if (f > 0)
1057                                 self.velocity = self.velocity * f;
1058                         else
1059                                 self.velocity = '0 0 0';
1060                 }
1061
1062                 // acceleration
1063                 wishdir = normalize(wishvel);
1064                 wishspeed = vlen(wishvel);
1065                 if (wishspeed > sv_maxspeed*maxspd_mod)
1066                         wishspeed = sv_maxspeed*maxspd_mod;
1067                 if (self.crouch)
1068                         wishspeed = wishspeed * 0.5;
1069                 if (time >= self.teleport_time)
1070                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1071         }
1072         else
1073         {
1074                 // we get here if we ran out of ammo
1075                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1076                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1077
1078                 if(maxspd_mod < 1)
1079                 {
1080                         maxairspd = sv_maxairspeed*maxspd_mod;
1081                         airaccel = sv_airaccelerate*maxspd_mod;
1082                 }
1083                 else
1084                 {
1085                         maxairspd = sv_maxairspeed;
1086                         airaccel = sv_airaccelerate;
1087                 }
1088                 // airborn
1089                 makevectors(self.v_angle_y * '0 1 0');
1090                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1091                 // acceleration
1092                 wishdir = normalize(wishvel);
1093                 wishspeed = vlen(wishvel);
1094                 if (wishspeed > maxairspd)
1095                         wishspeed = maxairspd;
1096                 if (self.crouch)
1097                         wishspeed = wishspeed * 0.5;
1098                 if (time >= self.teleport_time)
1099                 {
1100                         float accelerating;
1101                         float wishspeed2;
1102                         float airaccelqw;
1103
1104                         airaccelqw = sv_airaccel_qw;
1105                         accelerating = (self.velocity * wishdir > 0);
1106                         wishspeed2 = wishspeed;
1107
1108                         // CPM
1109                         if(sv_airstopaccelerate)
1110                                 if(self.velocity * wishdir < 0)
1111                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1112                         if(self.movement_x == 0 && self.movement_y != 0)
1113                         {
1114                                 if(sv_maxairstrafespeed)
1115                                 {
1116                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1117                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1118                                                 airaccelqw = 1;
1119                                 }
1120                                 if(sv_airstrafeaccelerate)
1121                                 {
1122                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1123                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1124                                                 airaccelqw = 1;
1125                                 }
1126                         }
1127                         // !CPM
1128
1129                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1130                                 PM_AirAccelerate(wishdir, wishspeed);
1131                         else
1132                                 PM_Accelerate(wishdir, wishspeed, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1133
1134                         if(sv_aircontrol)
1135                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1136                 }
1137         }
1138
1139 :end
1140         if(self.flags & FL_ONGROUND)
1141                 self.lastground = time;
1142
1143         self.lastflags = self.flags;
1144         self.lastclassname = self.classname;
1145 };