data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 float racecar_angle(float forward, float down)
 121 {
 122         float ret, angle_mult;
 123
 124         if(forward < 0)
 125         {
 126                 forward = -forward;
 127                 down = -down;
 128         }
 129
 130         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 131
 132         angle_mult = forward / (800 + forward);
 133
 134         if(ret > 180)
 135                 return ret * angle_mult + 360 * (1 - angle_mult);
 136         else
 137                 return ret * angle_mult;
 138 }
 139
 140 void RaceCarPhysics()
 141 {
 142         // using this move type for "big rigs"
 143         // the engine does not push the entity!
 144
 145         float accel, steer, f;
 146         vector angles_save, rigvel;
 147
 148         angles_save = self.angles;
 149         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 150         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 151
 152         if(g_bugrigs_reverse_speeding)
 153         {
 154                 if(accel < 0)
 155                 {
 156                         // back accel is DIGITAL
 157                         // to prevent speedhack
 158                         if(accel < -0.5)
 159                                 accel = -1;
 160                         else
 161                                 accel = 0;
 162                 }
 163         }
 164
 165         self.angles_x = 0;
 166         self.angles_z = 0;
 167         makevectors(self.angles); // new forward direction!
 168
 169         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 170         {
 171                 float myspeed, upspeed, steerfactor, accelfactor;
 172
 173                 myspeed = self.velocity * v_forward;
 174                 upspeed = self.velocity * v_up;
 175
 176                 // responsiveness factor for steering and acceleration
 177                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 178
 179                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 180                         steerfactor = -myspeed * g_bugrigs_steer;
 181                 else
 182                         steerfactor = -myspeed * f * g_bugrigs_steer;
 183
 184                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 185                         accelfactor = g_bugrigs_accel;
 186                 else
 187                         accelfactor = f * g_bugrigs_accel;
 188
 189                 if(accel < 0)
 190                 {
 191                         if(myspeed > 0)
 192                         {
 193                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 194                         }
 195                         else
 196                         {
 197                                 if(!g_bugrigs_reverse_speeding)
 198                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 199                         }
 200                 }
 201                 else
 202                 {
 203                         if(myspeed >= 0)
 204                         {
 205                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 206                         }
 207                         else
 208                         {
 209                                 if(g_bugrigs_reverse_stopping)
 210                                         myspeed = 0;
 211                                 else
 212                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 213                         }
 214                 }
 215                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 216
 217                 self.angles_y += steer * frametime * steerfactor; // apply steering
 218                 makevectors(self.angles); // new forward direction!
 219
 220                 myspeed += accel * accelfactor * frametime;
 221
 222                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 223         }
 224         else
 225         {
 226                 myspeed = vlen(self.velocity);
 227
 228                 // responsiveness factor for steering and acceleration
 229                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 230                 steerfactor = -myspeed * f;
 231                 self.angles_y += steer * frametime * steerfactor; // apply steering
 232
 233                 rigvel = self.velocity;
 234                 makevectors(self.angles); // new forward direction!
 235         }
 236
 237         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air);
 238
 239         if(g_bugrigs_planar_movement)
 240         {
 241                 vector rigvel_xy, neworigin, up;
 242                 float mt;
 243
 244                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 245                 rigvel_xy = rigvel;
 246                 rigvel_xy_z = 0;
 247
 248                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 249                         mt = MOVE_NORMAL;
 250                 else
 251                         mt = MOVE_NOMONSTERS;
 252
 253                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 254                 up = trace_endpos - self.origin;
 255
 256                 // BUG RIGS: align the move to the surface instead of doing collision testing
 257                 // can we move?
 258                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 259
 260                 // align to surface
 261                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 262
 263                 if(trace_fraction < 0.5)
 264                 {
 265                         trace_fraction = 1;
 266                         neworigin = self.origin;
 267                 }
 268                 else
 269                         neworigin = trace_endpos;
 270
 271                 if(trace_fraction < 1)
 272                 {
 273                         // now set angles_x so that the car points parallel to the surface
 274                         self.angles = vectoangles(
 275                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 276                                         +
 277                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 278                                         +
 279                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 280                                         );
 281                         self.flags |= FL_ONGROUND;
 282                 }
 283                 else
 284                 {
 285                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 286                         self.flags (-) FL_ONGROUND;
 287                 }
 288
 289                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 290                 self.movetype = MOVETYPE_NOCLIP;
 291         }
 292         else
 293         {
 294                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 295                 self.velocity = rigvel;
 296                 self.movetype = MOVETYPE_FLY;
 297         }
 298
 299         trace_fraction = 1;
 300         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 301         if(trace_fraction != 1)
 302         {
 303                 self.angles = vectoangles2(
 304                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 305                                 +
 306                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 307                                 +
 308                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 309                                 trace_plane_normal
 310                                 );
 311         }
 312         else
 313         {
 314                 vector vel_local;
 315
 316                 vel_local_x = v_forward * self.velocity;
 317                 vel_local_y = v_right * self.velocity;
 318                 vel_local_z = v_up * self.velocity;
 319
 320                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 321                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 322         }
 323
 324         // smooth the angles
 325         vector vf1, vu1, smoothangles;
 326         makevectors(self.angles);
 327         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 328         if(f == 0)
 329                 f = 1;
 330         vf1 = v_forward * f;
 331         vu1 = v_up * f;
 332         makevectors(angles_save);
 333         vf1 = vf1 + v_forward * (1 - f);
 334         vu1 = vu1 + v_up * (1 - f);
 335         smoothangles = vectoangles2(vf1, vu1);
 336         self.angles_x = -smoothangles_x;
 337         self.angles_z =  smoothangles_z;
 338 }
 339
 340 .vector movement_old;
 341 .float buttons_old;
 342 .vector v_angle_old;
 343
 344 void Nixnex_GiveCurrentWeapon();
 345 void SV_PlayerPhysics()
 346 {
 347         local vector wishvel, wishdir, v;
 348         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 349         string temps;
 350
 351         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 352         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 353         {
 354                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 355                         self.parm_idlesince = time;
 356         }
 357         self.buttons_old = buttons;
 358         self.movement_old = self.movement;
 359         self.v_angle_old = self.v_angle;
 360
 361         if(time > self.shtest_next)
 362         {
 363                 if(self.shtest_next > 0)
 364                 {
 365                         // self.shtest_accumulator:
 366                         //   started at time - SHTEST_DELTA
 367                         //   should be at SHTEST_DELTA
 368                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 369                         if(shtest_score > SHTEST_THRESHOLD)
 370                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 371                         else if(cvar("developer_shtest"))
 372                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 373                 }
 374                 self.shtest_next = time + SHTEST_DELTA;
 375                 self.shtest_accumulator = 0;
 376         }
 377         self.shtest_accumulator += frametime;
 378
 379         if (clienttype(self) == CLIENTTYPE_BOT)
 380                 bot_think();
 381
 382         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 383                 return;
 384
 385         if (self.punchangle != '0 0 0')
 386         {
 387                 f = vlen(self.punchangle) - 10 * frametime;
 388                 if (f > 0)
 389                         self.punchangle = normalize(self.punchangle) * f;
 390                 else
 391                         self.punchangle = '0 0 0';
 392         }
 393
 394         if (self.punchvector != '0 0 0')
 395         {
 396                 f = vlen(self.punchvector) - 30 * frametime;
 397                 if (f > 0)
 398                         self.punchvector = normalize(self.punchvector) * f;
 399                 else
 400                         self.punchvector = '0 0 0';
 401         }
 402
 403         maxspd_mod = 1;
 404
 405         if(g_runematch)
 406         {
 407                 if(self.runes & RUNE_SPEED)
 408                 {
 409                         if(self.runes & CURSE_SLOW)
 410                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 411                         else
 412                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 413                 }
 414                 else if(self.runes & CURSE_SLOW)
 415                 {
 416                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 417                 }
 418         }
 419
 420         if(g_minstagib && (self.items & IT_INVINCIBLE))
 421         {
 422                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 423         }
 424
 425         swampspd_mod = 1;
 426         if(self.in_swamp) {
 427                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 428         }
 429
 430         if(self.flags & FL_NOTARGET)
 431         {
 432                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 433                 if(!self.spectatorspeed)
 434                         self.spectatorspeed = maxspd_mod;
 435                 if(self.impulse && self.impulse <= 19)
 436                 {
 437                         if(self.lastflags & FL_NOTARGET)
 438                         {
 439                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 440                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 441                                 else if(self.impulse == 11)
 442                                         self.spectatorspeed = maxspd_mod;
 443                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 444                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 445                                 else if(self.impulse >= 1 && self.impulse <= 9)
 446                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 447                         } // otherwise just clear
 448                         self.impulse = 0;
 449                 }
 450                 maxspd_mod = self.spectatorspeed;
 451         }
 452
 453         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 454
 455         if(self.speed != spd)
 456         {
 457                 self.speed = spd;
 458                 temps = ftos(spd);
 459                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 460                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 461                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 462                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 463
 464                 temps = ftos(sv_accelerate * maxspd_mod);
 465                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 466         }
 467
 468         // if dead, behave differently
 469         if (self.deadflag)
 470                 return;
 471
 472         if (!self.fixangle && !g_bugrigs)
 473         {
 474                 self.angles_x = 0;
 475                 self.angles_y = self.v_angle_y;
 476                 self.angles_z = 0;
 477         }
 478
 479         if(self.flags & FL_ONGROUND)
 480         if(self.wasFlying)
 481         {
 482                 self.wasFlying = 0;
 483
 484                 if(self.waterlevel < 2)
 485                 if(time >= self.ladder_time)
 486                 if not(self.hook)
 487                 {
 488                         self.nextstep = time + 0.3 + random() * 0.1;
 489                         trace_dphitq3surfaceflags = 0;
 490                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 491                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 492                         {
 493                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 494                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 495                                 else
 496                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 497                         }
 498                 }
 499         }
 500
 501         if(IsFlying(self))
 502                 self.wasFlying = 1;
 503
 504         if(self.classname == "player")
 505         {
 506                 if(sv_doublejump)
 507                 {
 508                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 509                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 510                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 511                                 self.flags = self.flags | FL_ONGROUND;
 512                 }
 513
 514                 if (self.BUTTON_JUMP)
 515                         PlayerJump ();
 516                 else
 517                         self.flags = self.flags | FL_JUMPRELEASED;
 518
 519                 if (self.waterlevel == 2)
 520                         CheckWaterJump ();
 521         }
 522
 523         if (self.flags & FL_WATERJUMP )
 524         {
 525                 self.velocity_x = self.movedir_x;
 526                 self.velocity_y = self.movedir_y;
 527                 if (time > self.teleport_time || self.waterlevel == 0)
 528                 {
 529                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 530                         self.teleport_time = 0;
 531                 }
 532         }
 533         else if (g_bugrigs && self.classname == "player")
 534         {
 535                 RaceCarPhysics();
 536         }
 537         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 538         {
 539                 // noclipping or flying
 540                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 541
 542                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 543                 makevectors(self.v_angle);
 544                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 545                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 546                 // acceleration
 547                 wishdir = normalize(wishvel);
 548                 wishspeed = vlen(wishvel);
 549                 if (wishspeed > sv_maxspeed*maxspd_mod)
 550                         wishspeed = sv_maxspeed*maxspd_mod;
 551                 if (time >= self.teleport_time)
 552                 {
 553                         f = wishspeed - (self.velocity * wishdir);
 554                         if (f > 0)
 555                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 556                 }
 557         }
 558         else if (self.waterlevel >= 2)
 559         {
 560                 // swimming
 561                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 562
 563                 makevectors(self.v_angle);
 564                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 565                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 566                 if (wishvel == '0 0 0')
 567                         wishvel = '0 0 -60'; // drift towards bottom
 568
 569                 wishdir = normalize(wishvel);
 570                 wishspeed = vlen(wishvel);
 571                 if (wishspeed > sv_maxspeed*maxspd_mod)
 572                         wishspeed = sv_maxspeed*maxspd_mod;
 573                 wishspeed = wishspeed * 0.7;
 574
 575                 // water friction
 576                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 577
 578                 // water acceleration
 579                 f = wishspeed - (self.velocity * wishdir);
 580                 if (f > 0)
 581                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 582         }
 583         else if (time < self.ladder_time)
 584         {
 585                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 586                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 587
 588                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 589                 makevectors(self.v_angle);
 590                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 591                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 592                 if (self.gravity)
 593                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 594                 else
 595                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 596                 if (self.ladder_entity.classname == "func_water")
 597                 {
 598                         f = vlen(wishvel);
 599                         if (f > self.ladder_entity.speed)
 600                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 601
 602                         self.watertype = self.ladder_entity.skin;
 603                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 604                         if ((self.origin_z + self.view_ofs_z) < f)
 605                                 self.waterlevel = 3;
 606                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 607                                 self.waterlevel = 2;
 608                         else if ((self.origin_z + self.mins_z + 1) < f)
 609                                 self.waterlevel = 1;
 610                         else
 611                         {
 612                                 self.waterlevel = 0;
 613                                 self.watertype = CONTENT_EMPTY;
 614                         }
 615                 }
 616                 // acceleration
 617                 wishdir = normalize(wishvel);
 618                 wishspeed = vlen(wishvel);
 619                 if (wishspeed > sv_maxspeed)
 620                         wishspeed = sv_maxspeed;
 621                 if (time >= self.teleport_time)
 622                 {
 623                         f = wishspeed - (self.velocity * wishdir);
 624                         if (f > 0)
 625                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 626                 }
 627         }
 628         else if (self.flags & FL_ONGROUND)
 629         {
 630                 // walking
 631                 makevectors(self.v_angle_y * '0 1 0');
 632                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 633
 634                 if(!(self.lastflags & FL_ONGROUND))
 635                 {
 636                         if(cvar("speedmeter"))
 637                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 638                         if(self.lastground < time - 0.3)
 639                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 640                         if(self.jumppadcount > 1)
 641                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 642                         self.jumppadcount = 0;
 643                 }
 644
 645                 if (self.velocity_x || self.velocity_y)
 646                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 647                 {
 648                         v = self.velocity;
 649                         v_z = 0;
 650                         f = vlen(v);
 651                         if (f < sv_stopspeed)
 652                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 653                         else
 654                                 f = 1 - frametime * sv_friction;
 655                         if (f > 0)
 656                                 self.velocity = self.velocity * f;
 657                         else
 658                                 self.velocity = '0 0 0';
 659                 }
 660                 // acceleration
 661                 wishdir = normalize(wishvel);
 662                 wishspeed = vlen(wishvel);
 663                 if (wishspeed > sv_maxspeed*maxspd_mod)
 664                         wishspeed = sv_maxspeed*maxspd_mod;
 665                 if (self.crouch)
 666                         wishspeed = wishspeed * 0.5;
 667                 if (time >= self.teleport_time)
 668                 {
 669                         f = wishspeed - (self.velocity * wishdir);
 670                         if (f > 0)
 671                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 672                 }
 673         }
 674         else
 675         {
 676                 if(maxspd_mod < 1)
 677                 {
 678                         maxairspd = sv_maxairspeed*maxspd_mod;
 679                         airaccel = sv_airaccelerate*maxspd_mod;
 680                 }
 681                 else
 682                 {
 683                         maxairspd = sv_maxairspeed;
 684                         airaccel = sv_airaccelerate;
 685                 }
 686                 // airborn
 687                 makevectors(self.v_angle_y * '0 1 0');
 688                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 689                 // acceleration
 690                 wishdir = normalize(wishvel);
 691                 wishspeed = vlen(wishvel);
 692                 if (wishspeed > maxairspd)
 693                         wishspeed = maxairspd;
 694                 if (self.crouch)
 695                         wishspeed = wishspeed * 0.5;
 696                 if (time >= self.teleport_time)
 697                 {
 698                         // NOTE: this does the same as the commented out old code if:
 699                         //   sv_airaccel_qw 0
 700                         //   sv_airaccel_sideways_friction 0
 701
 702                         float vel_straight;
 703                         float vel_z;
 704                         vector vel_perpend;
 705                         vel_straight = self.velocity * wishdir;
 706                         vel_z = self.velocity_z;
 707                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 708
 709                         f = wishspeed - vel_straight;
 710                         if(f > 0)
 711                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 712                         if(wishspeed > 0)
 713                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 714
 715                         // anti-sideways friction to fix QW-style bunnyhopping
 716                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 717
 718                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 719
 720                         /*
 721                         f = wishspeed;// - (self.velocity * wishdir);
 722                         if (f > 0)
 723                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 724                         */
 725                 }
 726         }
 727
 728         if(self.flags & FL_ONGROUND)
 729                 self.lastground = time;
 730
 731         self.lastflags = self.flags;
 732 };