data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 .vector movement_old;
 121 .float buttons_old;
 122 .vector v_angle_old;
 123
 124 void Nixnex_GiveCurrentWeapon();
 125 void SV_PlayerPhysics()
 126 {
 127         local vector wishvel, wishdir, v;
 128         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 129         string temps;
 130
 131         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 132         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 133         {
 134                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 135                         self.parm_idlesince = time;
 136         }
 137         self.buttons_old = buttons;
 138         self.movement_old = self.movement;
 139         self.v_angle_old = self.v_angle;
 140
 141         if(time > self.shtest_next)
 142         {
 143                 if(self.shtest_next > 0)
 144                 {
 145                         // self.shtest_accumulator:
 146                         //   started at time - SHTEST_DELTA
 147                         //   should be at SHTEST_DELTA
 148                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 149                         if(shtest_score > SHTEST_THRESHOLD)
 150                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 151                         else if(cvar("developer_shtest"))
 152                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 153                 }
 154                 self.shtest_next = time + SHTEST_DELTA;
 155                 self.shtest_accumulator = 0;
 156         }
 157         self.shtest_accumulator += frametime;
 158
 159         if (clienttype(self) == CLIENTTYPE_BOT)
 160                 bot_think();
 161
 162         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 163                 return;
 164
 165         if(g_bigrigs && self.movetype == MOVETYPE_WALK)
 166         {
 167                 self.disableclientprediction = 1;
 168                 self.movetype = MOVETYPE_NONE;
 169         }
 170
 171         if (self.punchangle != '0 0 0')
 172         {
 173                 f = vlen(self.punchangle) - 10 * frametime;
 174                 if (f > 0)
 175                         self.punchangle = normalize(self.punchangle) * f;
 176                 else
 177                         self.punchangle = '0 0 0';
 178         }
 179
 180         if (self.punchvector != '0 0 0')
 181         {
 182                 f = vlen(self.punchvector) - 30 * frametime;
 183                 if (f > 0)
 184                         self.punchvector = normalize(self.punchvector) * f;
 185                 else
 186                         self.punchvector = '0 0 0';
 187         }
 188
 189         maxspd_mod = 1;
 190
 191         if(g_runematch)
 192         {
 193                 if(self.runes & RUNE_SPEED)
 194                 {
 195                         if(self.runes & CURSE_SLOW)
 196                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 197                         else
 198                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 199                 }
 200                 else if(self.runes & CURSE_SLOW)
 201                 {
 202                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 203                 }
 204         }
 205
 206         if(g_minstagib && (self.items & IT_INVINCIBLE))
 207         {
 208                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 209         }
 210
 211         swampspd_mod = 1;
 212         if(self.in_swamp) {
 213                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 214         }
 215
 216         if(self.flags & FL_NOTARGET)
 217         {
 218                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 219                 if(!self.spectatorspeed)
 220                         self.spectatorspeed = maxspd_mod;
 221                 if(self.impulse && self.impulse <= 19)
 222                 {
 223                         if(self.lastflags & FL_NOTARGET)
 224                         {
 225                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 226                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 227                                 else if(self.impulse == 11)
 228                                         self.spectatorspeed = maxspd_mod;
 229                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 230                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 231                                 else if(self.impulse >= 1 && self.impulse <= 9)
 232                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 233                         } // otherwise just clear
 234                         self.impulse = 0;
 235                 }
 236                 maxspd_mod = self.spectatorspeed;
 237         }
 238
 239         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 240
 241         if(self.speed != spd)
 242         {
 243                 self.speed = spd;
 244                 temps = ftos(spd);
 245                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 246                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 247                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 248                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 249
 250                 temps = ftos(sv_accelerate * maxspd_mod);
 251                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 252         }
 253
 254         // if dead, behave differently
 255         if (self.deadflag)
 256                 return;
 257
 258         if (!self.fixangle && !g_bigrigs)
 259         {
 260                 self.angles_x = 0;
 261                 self.angles_y = self.v_angle_y;
 262                 self.angles_z = 0;
 263         }
 264
 265         if(self.flags & FL_ONGROUND)
 266         if(self.wasFlying)
 267         {
 268                 self.wasFlying = 0;
 269
 270                 if(self.waterlevel < 2)
 271                 if(time >= self.ladder_time)
 272                 if not(self.hook)
 273                 {
 274                         self.nextstep = time + 0.3 + random() * 0.1;
 275                         trace_dphitq3surfaceflags = 0;
 276                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 277                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 278                         {
 279                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 280                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 281                                 else
 282                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 283                         }
 284                 }
 285         }
 286
 287         if(IsFlying(self))
 288                 self.wasFlying = 1;
 289
 290         if(self.classname == "player")
 291         {
 292                 if(sv_doublejump)
 293                 {
 294                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 295                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 296                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 297                                 self.flags = self.flags | FL_ONGROUND;
 298                 }
 299
 300                 if (self.BUTTON_JUMP)
 301                         PlayerJump ();
 302                 else
 303                         self.flags = self.flags | FL_JUMPRELEASED;
 304
 305                 if (self.waterlevel == 2)
 306                         CheckWaterJump ();
 307         }
 308
 309         if (self.flags & FL_WATERJUMP )
 310         {
 311                 self.velocity_x = self.movedir_x;
 312                 self.velocity_y = self.movedir_y;
 313                 if (time > self.teleport_time || self.waterlevel == 0)
 314                 {
 315                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 316                         self.teleport_time = 0;
 317                 }
 318         }
 319         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 320         {
 321                 // noclipping or flying
 322                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 323
 324                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 325                 makevectors(self.v_angle);
 326                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 327                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 328                 // acceleration
 329                 wishdir = normalize(wishvel);
 330                 wishspeed = vlen(wishvel);
 331                 if (wishspeed > sv_maxspeed*maxspd_mod)
 332                         wishspeed = sv_maxspeed*maxspd_mod;
 333                 if (time >= self.teleport_time)
 334                 {
 335                         f = wishspeed - (self.velocity * wishdir);
 336                         if (f > 0)
 337                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 338                 }
 339         }
 340         else if (g_bigrigs)
 341         {
 342                 // using this move type for "big rigs"
 343                 // the engine does not push the entity!
 344
 345                 float accel, steer, myspeed, steerfactor, accelfactor, upspeed, friction;
 346                 vector neworigin, up, angles_save;
 347
 348                 accel = self.movement_x / sv_maxspeed;
 349                 steer = self.movement_y / sv_maxspeed;
 350
 351                 angles_save = self.angles;
 352                 self.angles_x = 0;
 353                 self.angles_z = 0;
 354                 makevectors(self.angles); // new forward direction!
 355                 myspeed = self.velocity * v_forward;
 356                 upspeed = self.velocity * v_up;
 357                 if(myspeed <= 0 && accel < 0)
 358                         steerfactor = -5000; // LOL
 359                 else
 360                         steerfactor = -400 * 400 / (400 + myspeed);
 361                 accelfactor = 2000 * 400 / (400 + max(myspeed, -myspeed));
 362                 friction = 5 * 100 / (100 + max(myspeed, -myspeed));
 363
 364                 self.angles_y += steer * frametime * steerfactor; // apply steering
 365                 makevectors(self.angles); // new forward direction!
 366
 367                 myspeed = myspeed * (1 - frametime * friction);
 368                 myspeed += accel * accelfactor * frametime;
 369                 if(myspeed < 0)
 370                         myspeed = 0;
 371
 372                 self.velocity = v_forward * myspeed;
 373                 upspeed -= frametime * sv_gravity;
 374
 375                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', MOVE_NORMAL, self);
 376                 up = trace_endpos - self.origin;
 377
 378                 // can we move?
 379                 neworigin = trace_endpos + self.velocity * frametime;
 380                 tracebox(trace_endpos, self.mins, self.maxs, neworigin, MOVE_NORMAL, self);
 381
 382                 // align to surface
 383                 tracebox(trace_endpos, self.mins, self.maxs, neworigin - up + '0 0 1' * upspeed * frametime, MOVE_NORMAL, self);
 384
 385                 if(trace_fraction >= 0.5)
 386                         self.origin = trace_endpos;
 387                 else
 388                         trace_fraction = 1;
 389
 390                 // now set angles_x so that the car points parallel to the surface
 391                 if(trace_fraction < 1)
 392                 {
 393                         self.angles = vectoangles(normalize(
 394                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 395                                 +
 396                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 397                                 +
 398                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 399                         ));
 400                         self.flags |= FL_ONGROUND;
 401                 }
 402                 else
 403                 {
 404                         self.angles_x = angles_save_x;
 405                         self.angles_z = angles_save_z;
 406                         self.velocity += '0 0 1' * upspeed;
 407                         self.flags (-) FL_ONGROUND;
 408                 }
 409
 410                 // relink
 411                 setorigin(self, self.origin);
 412         }
 413         else if (self.waterlevel >= 2)
 414         {
 415                 // swimming
 416                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 417
 418                 makevectors(self.v_angle);
 419                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 420                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 421                 if (wishvel == '0 0 0')
 422                         wishvel = '0 0 -60'; // drift towards bottom
 423
 424                 wishdir = normalize(wishvel);
 425                 wishspeed = vlen(wishvel);
 426                 if (wishspeed > sv_maxspeed*maxspd_mod)
 427                         wishspeed = sv_maxspeed*maxspd_mod;
 428                 wishspeed = wishspeed * 0.7;
 429
 430                 // water friction
 431                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 432
 433                 // water acceleration
 434                 f = wishspeed - (self.velocity * wishdir);
 435                 if (f > 0)
 436                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 437         }
 438         else if (time < self.ladder_time)
 439         {
 440                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 441                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 442
 443                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 444                 makevectors(self.v_angle);
 445                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 446                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 447                 if (self.gravity)
 448                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 449                 else
 450                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 451                 if (self.ladder_entity.classname == "func_water")
 452                 {
 453                         f = vlen(wishvel);
 454                         if (f > self.ladder_entity.speed)
 455                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 456
 457                         self.watertype = self.ladder_entity.skin;
 458                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 459                         if ((self.origin_z + self.view_ofs_z) < f)
 460                                 self.waterlevel = 3;
 461                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 462                                 self.waterlevel = 2;
 463                         else if ((self.origin_z + self.mins_z + 1) < f)
 464                                 self.waterlevel = 1;
 465                         else
 466                         {
 467                                 self.waterlevel = 0;
 468                                 self.watertype = CONTENT_EMPTY;
 469                         }
 470                 }
 471                 // acceleration
 472                 wishdir = normalize(wishvel);
 473                 wishspeed = vlen(wishvel);
 474                 if (wishspeed > sv_maxspeed)
 475                         wishspeed = sv_maxspeed;
 476                 if (time >= self.teleport_time)
 477                 {
 478                         f = wishspeed - (self.velocity * wishdir);
 479                         if (f > 0)
 480                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 481                 }
 482         }
 483         else if (self.flags & FL_ONGROUND)
 484         {
 485                 // walking
 486                 makevectors(self.v_angle_y * '0 1 0');
 487                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 488
 489                 if(!(self.lastflags & FL_ONGROUND))
 490                 {
 491                         if(cvar("speedmeter"))
 492                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 493                         if(self.lastground < time - 0.3)
 494                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 495                         if(self.jumppadcount > 1)
 496                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 497                         self.jumppadcount = 0;
 498                 }
 499
 500                 if (self.velocity_x || self.velocity_y)
 501                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 502                 {
 503                         v = self.velocity;
 504                         v_z = 0;
 505                         f = vlen(v);
 506                         if (f < sv_stopspeed)
 507                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 508                         else
 509                                 f = 1 - frametime * sv_friction;
 510                         if (f > 0)
 511                                 self.velocity = self.velocity * f;
 512                         else
 513                                 self.velocity = '0 0 0';
 514                 }
 515                 // acceleration
 516                 wishdir = normalize(wishvel);
 517                 wishspeed = vlen(wishvel);
 518                 if (wishspeed > sv_maxspeed*maxspd_mod)
 519                         wishspeed = sv_maxspeed*maxspd_mod;
 520                 if (self.crouch)
 521                         wishspeed = wishspeed * 0.5;
 522                 if (time >= self.teleport_time)
 523                 {
 524                         f = wishspeed - (self.velocity * wishdir);
 525                         if (f > 0)
 526                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 527                 }
 528         }
 529         else
 530         {
 531                 if(maxspd_mod < 1)
 532                 {
 533                         maxairspd = sv_maxairspeed*maxspd_mod;
 534                         airaccel = sv_airaccelerate*maxspd_mod;
 535                 }
 536                 else
 537                 {
 538                         maxairspd = sv_maxairspeed;
 539                         airaccel = sv_airaccelerate;
 540                 }
 541                 // airborn
 542                 makevectors(self.v_angle_y * '0 1 0');
 543                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 544                 // acceleration
 545                 wishdir = normalize(wishvel);
 546                 wishspeed = vlen(wishvel);
 547                 if (wishspeed > maxairspd)
 548                         wishspeed = maxairspd;
 549                 if (self.crouch)
 550                         wishspeed = wishspeed * 0.5;
 551                 if (time >= self.teleport_time)
 552                 {
 553                         // NOTE: this does the same as the commented out old code if:
 554                         //   sv_airaccel_qw 0
 555                         //   sv_airaccel_sideways_friction 0
 556
 557                         float vel_straight;
 558                         float vel_z;
 559                         vector vel_perpend;
 560                         vel_straight = self.velocity * wishdir;
 561                         vel_z = self.velocity_z;
 562                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 563
 564                         f = wishspeed - vel_straight;
 565                         if(f > 0)
 566                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 567                         if(wishspeed > 0)
 568                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 569
 570                         // anti-sideways friction to fix QW-style bunnyhopping
 571                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 572
 573                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 574
 575                         /*
 576                         f = wishspeed;// - (self.velocity * wishdir);
 577                         if (f > 0)
 578                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 579                         */
 580                 }
 581         }
 582
 583         if(self.flags & FL_ONGROUND)
 584                 self.lastground = time;
 585
 586         self.lastflags = self.flags;
 587 };