data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 #define SHTEST_DELTA 15
  18 .float shtest_next;
  19 .float shtest_accumulator;
  20
  21 /*
  22 =============
  23 PlayerJump
  24
  25 When you press the jump key
  26 =============
  27 */
  28 void PlayerJump (void)
  29 {
  30         float mjumpheight;
  31
  32         mjumpheight = cvar("sv_jumpvelocity");
  33         if (self.waterlevel >= 2)
  34         {
  35                 if (self.watertype == CONTENT_WATER)
  36                         self.velocity_z = 200;
  37                 else if (self.watertype == CONTENT_SLIME)
  38                         self.velocity_z = 80;
  39                 else
  40                         self.velocity_z = 50;
  41
  42                 return;
  43         }
  44
  45
  46         if (!(self.flags & FL_ONGROUND))
  47                 return;
  48
  49         if (!(self.flags & FL_JUMPRELEASED))
  50                 return;
  51
  52         if(cvar("g_runematch"))
  53         {
  54                 if(self.runes & RUNE_SPEED)
  55                 {
  56                         if(self.runes & CURSE_SLOW)
  57                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  58                         else
  59                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  60                 }
  61                 else if(self.runes & CURSE_SLOW)
  62                 {
  63                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  64                 }
  65         }
  66
  67         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  68         {
  69                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  70         }
  71
  72         self.velocity_z = self.velocity_z + mjumpheight;
  73         self.oldvelocity_z = self.velocity_z;
  74
  75         self.flags = self.flags - FL_ONGROUND;
  76         self.flags = self.flags - FL_JUMPRELEASED;
  77 }
  78
  79 void() CheckWaterJump =
  80 {
  81         local vector start, end;
  82
  83 // check for a jump-out-of-water
  84         makevectors (self.angles);
  85         start = self.origin;
  86         start_z = start_z + 8;
  87         v_forward_z = 0;
  88         normalize(v_forward);
  89         end = start + v_forward*24;
  90         traceline (start, end, TRUE, self);
  91         if (trace_fraction < 1)
  92         {       // solid at waist
  93                 start_z = start_z + self.maxs_z - 8;
  94                 end = start + v_forward*24;
  95                 self.movedir = trace_plane_normal * -50;
  96                 traceline (start, end, TRUE, self);
  97                 if (trace_fraction == 1)
  98                 {       // open at eye level
  99                         self.flags = self.flags | FL_WATERJUMP;
 100                         self.velocity_z = 225;
 101                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 102                         self.teleport_time = time + 2;  // safety net
 103                         return;
 104                 }
 105         }
 106 };
 107
 108
 109 void Nixnex_GiveCurrentWeapon();
 110 void SV_PlayerPhysics()
 111 {
 112         local vector wishvel, wishdir, v;
 113         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score;
 114         string temps;
 115
 116         if(time > self.shtest_next)
 117         {
 118                 if(self.shtest_next > 0)
 119                 {
 120                         // self.shtest_accumulator:
 121                         //   started at time - SHTEST_DELTA
 122                         //   should be at SHTEST_DELTA
 123                         shtest_score = self.shtest_accumulator / SHTEST_DELTA;
 124                         if(shtest_score > 1.2)
 125                                 dprint("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 126                 }
 127                 self.shtest_next = time + SHTEST_DELTA;
 128                 self.shtest_accumulator = 0;
 129         }
 130         self.shtest_accumulator += frametime;
 131
 132         if (clienttype(self) == CLIENTTYPE_BOT)
 133                 bot_think();
 134
 135         if (self.movetype == MOVETYPE_NONE)
 136                 return;
 137
 138         if (self.punchangle != '0 0 0')
 139         {
 140                 f = vlen(self.punchangle) - 10 * frametime;
 141                 if (f > 0)
 142                         self.punchangle = normalize(self.punchangle) * f;
 143                 else
 144                         self.punchangle = '0 0 0';
 145         }
 146
 147         if (self.punchvector != '0 0 0')
 148         {
 149                 f = vlen(self.punchvector) - 30 * frametime;
 150                 if (f > 0)
 151                         self.punchvector = normalize(self.punchvector) * f;
 152                 else
 153                         self.punchvector = '0 0 0';
 154         }
 155
 156         maxspd_mod = 1;
 157
 158         if(cvar("g_runematch"))
 159         {
 160                 if(self.runes & RUNE_SPEED)
 161                 {
 162                         if(self.runes & CURSE_SLOW)
 163                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 164                         else
 165                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 166                 }
 167                 else if(self.runes & CURSE_SLOW)
 168                 {
 169                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 170                 }
 171         }
 172
 173         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 174         {
 175                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
 176         }
 177
 178         swampspd_mod = 1;
 179         if(self.in_swamp) {
 180                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 181         }
 182
 183         if(self.flags & FL_NOTARGET)
 184                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 185
 186         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 187
 188         if(self.speed != spd)
 189         {
 190                 self.speed = spd;
 191                 temps = ftos(spd);
 192                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 193                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 194                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 195                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 196
 197                 temps = ftos(sv_accelerate * maxspd_mod);
 198                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 199         }
 200
 201         // if dead, behave differently
 202         if (self.deadflag)
 203                 return;
 204
 205         if (!self.fixangle)
 206         {
 207                 self.angles_x = 0;
 208                 self.angles_y = self.v_angle_y;
 209                 self.angles_z = 0;
 210         }
 211
 212         if(self.classname == "player")
 213         {
 214                 if (self.button2)
 215                         PlayerJump ();
 216                 else
 217                         self.flags = self.flags | FL_JUMPRELEASED;
 218
 219                 if (self.waterlevel == 2)
 220                         CheckWaterJump ();
 221         }
 222
 223         if (self.flags & FL_WATERJUMP )
 224         {
 225                 self.velocity_x = self.movedir_x;
 226                 self.velocity_y = self.movedir_y;
 227                 if (time > self.teleport_time || self.waterlevel == 0)
 228                 {
 229                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 230                         self.teleport_time = 0;
 231                 }
 232         }
 233         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 234         {
 235                 // noclipping or flying
 236                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 237
 238                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 239                 makevectors(self.v_angle);
 240                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 241                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 242                 // acceleration
 243                 wishdir = normalize(wishvel);
 244                 wishspeed = vlen(wishvel);
 245                 if (wishspeed > sv_maxspeed*maxspd_mod)
 246                         wishspeed = sv_maxspeed*maxspd_mod;
 247                 if (time >= self.teleport_time)
 248                 {
 249                         f = wishspeed - (self.velocity * wishdir);
 250                         if (f > 0)
 251                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 252                 }
 253         }
 254         else if (self.waterlevel >= 2)
 255         {
 256                 // swimming
 257                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 258
 259                 makevectors(self.v_angle);
 260                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 261                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 262                 if (wishvel == '0 0 0')
 263                         wishvel = '0 0 -60'; // drift towards bottom
 264
 265                 wishdir = normalize(wishvel);
 266                 wishspeed = vlen(wishvel);
 267                 if (wishspeed > sv_maxspeed*maxspd_mod)
 268                         wishspeed = sv_maxspeed*maxspd_mod;
 269                 wishspeed = wishspeed * 0.7;
 270
 271                 // water friction
 272                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 273
 274                 // water acceleration
 275                 f = wishspeed - (self.velocity * wishdir);
 276                 if (f > 0)
 277                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 278         }
 279         else if (time < self.ladder_time)
 280         {
 281                 // on a func_ladder or swimming in func_water
 282                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 283
 284                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 285                 makevectors(self.v_angle);
 286                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 287                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 288                 if (self.gravity)
 289                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 290                 else
 291                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 292                 if (self.ladder_entity.classname == "func_water")
 293                 {
 294                         f = vlen(wishvel);
 295                         if (f > self.ladder_entity.speed)
 296                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 297
 298                         self.watertype = self.ladder_entity.skin;
 299                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 300                         if ((self.origin_z + self.view_ofs_z) < f)
 301                                 self.waterlevel = 3;
 302                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 303                                 self.waterlevel = 2;
 304                         else if ((self.origin_z + self.mins_z + 1) < f)
 305                                 self.waterlevel = 1;
 306                         else
 307                         {
 308                                 self.waterlevel = 0;
 309                                 self.watertype = CONTENT_EMPTY;
 310                         }
 311                 }
 312                 // acceleration
 313                 wishdir = normalize(wishvel);
 314                 wishspeed = vlen(wishvel);
 315                 if (wishspeed > sv_maxspeed)
 316                         wishspeed = sv_maxspeed;
 317                 if (time >= self.teleport_time)
 318                 {
 319                         f = wishspeed - (self.velocity * wishdir);
 320                         if (f > 0)
 321                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 322                 }
 323         }
 324         else if (self.flags & FL_ONGROUND)
 325         {
 326                 // walking
 327                 makevectors(self.v_angle_y * '0 1 0');
 328                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 329
 330                 if(!(self.lastflags & FL_ONGROUND))
 331                 {
 332                         if(cvar("speedmeter"))
 333                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 334                         if(self.lastground < time - 0.3)
 335                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 336                         if(self.jumppadcount > 1)
 337                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 338                         self.jumppadcount = 0;
 339                 }
 340
 341                 if (self.velocity_x || self.velocity_y)
 342                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 343                 {
 344                         v = self.velocity;
 345                         v_z = 0;
 346                         f = vlen(v);
 347                         if (f < sv_stopspeed)
 348                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 349                         else
 350                                 f = 1 - frametime * sv_friction;
 351                         if (f > 0)
 352                                 self.velocity = self.velocity * f;
 353                         else
 354                                 self.velocity = '0 0 0';
 355                 }
 356                 // acceleration
 357                 wishdir = normalize(wishvel);
 358                 wishspeed = vlen(wishvel);
 359                 if (wishspeed > sv_maxspeed*maxspd_mod)
 360                         wishspeed = sv_maxspeed*maxspd_mod;
 361                 if (self.crouch)
 362                         wishspeed = wishspeed * 0.5;
 363                 if (time >= self.teleport_time)
 364                 {
 365                         f = wishspeed - (self.velocity * wishdir);
 366                         if (f > 0)
 367                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 368                 }
 369         }
 370         else
 371         {
 372                 if(maxspd_mod < 1)
 373                 {
 374                         maxairspd = sv_maxairspeed*maxspd_mod;
 375                         airaccel = sv_airaccelerate*maxspd_mod;
 376                 }
 377                 else
 378                 {
 379                         maxairspd = sv_maxairspeed;
 380                         airaccel = sv_airaccelerate;
 381                 }
 382                 // airborn
 383                 makevectors(self.v_angle_y * '0 1 0');
 384                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 385                 // acceleration
 386                 wishdir = normalize(wishvel);
 387                 wishspeed = vlen(wishvel);
 388                 if (wishspeed > maxairspd)
 389                         wishspeed = maxairspd;
 390                 if (self.crouch)
 391                         wishspeed = wishspeed * 0.5;
 392                 if (time >= self.teleport_time)
 393                 {
 394                         // NOTE: this does the same as the commented out old code if:
 395                         //   sv_airaccel_qw 0
 396                         //   sv_airaccel_sideways_friction 0
 397
 398                         float vel_straight;
 399                         float vel_z;
 400                         vector vel_perpend;
 401                         vel_straight = self.velocity * wishdir;
 402                         vel_z = self.velocity_z;
 403                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 404
 405                         f = wishspeed - vel_straight;
 406                         if(f > 0)
 407                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 408                         if(wishspeed > 0)
 409                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 410
 411                         // anti-sideways friction to fix QW-style bunnyhopping
 412                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 413
 414                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 415
 416                         /*
 417                         f = wishspeed;// - (self.velocity * wishdir);
 418                         if (f > 0)
 419                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 420                         */
 421                 }
 422         }
 423
 424         if(self.flags & FL_ONGROUND)
 425                 self.lastground = time;
 426
 427         self.lastflags = self.flags;
 428 };