data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 .float doublejump_nextjumptime;
  33
  34 /*
  35 =============
  36 PlayerJump
  37
  38 When you press the jump key
  39 =============
  40 */
  41 void PlayerJump (void)
  42 {
  43         float mjumpheight;
  44
  45         mjumpheight = cvar("sv_jumpvelocity");
  46         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  47         {
  48                 if (self.watertype == CONTENT_WATER)
  49                         self.velocity_z = 200;
  50                 else if (self.watertype == CONTENT_SLIME)
  51                         self.velocity_z = 80;
  52                 else
  53                         self.velocity_z = 50;
  54
  55                 return;
  56         }
  57
  58         if (!(self.flags & FL_ONGROUND))
  59                 return;
  60
  61         if(!sv_pogostick)
  62                 if (!(self.flags & FL_JUMPRELEASED))
  63                         return;
  64
  65         if(self.health <= g_bloodloss)
  66                 return;
  67
  68         if(sv_doublejump)
  69                 if(time < self.doublejump_nextjumptime)
  70                         return;
  71
  72         if(g_runematch)
  73         {
  74                 if(self.runes & RUNE_SPEED)
  75                 {
  76                         if(self.runes & CURSE_SLOW)
  77                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  78                         else
  79                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  80                 }
  81                 else if(self.runes & CURSE_SLOW)
  82                 {
  83                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  84                 }
  85         }
  86
  87         if(g_minstagib && (self.items & IT_INVINCIBLE))
  88         {
  89                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  90         }
  91
  92         if(!(self.lastflags & FL_ONGROUND))
  93         {
  94                 if(cvar("speedmeter"))
  95                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
  96                 if(self.lastground < time - 0.3)
  97                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
  98                 if(self.jumppadcount > 1)
  99                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 100                 self.jumppadcount = 0;
 101         }
 102
 103         self.velocity_z = self.velocity_z + mjumpheight;
 104         self.oldvelocity_z = self.velocity_z;
 105
 106         self.flags &~= FL_ONGROUND;
 107         self.flags &~= FL_JUMPRELEASED;
 108
 109         if (self.crouch)
 110                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 111         else
 112                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 113
 114         if(g_jump_grunt)
 115                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 116
 117         if(sv_doublejump)
 118         {
 119                 // we're moving upwards at self.velocity_z
 120                 // only allow jumping after we got 3 units upwards
 121                 // so we for sure leave the FL_ONGROUND check
 122                 //
 123                 // but as this sucks because of factoring in gravity, we'll just do it
 124                 // for 4 units, and constant velocity
 125                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 126         }
 127
 128         self.restart_jump = -1; // restart jump anim next time
 129         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 130 }
 131
 132 void CheckWaterJump()
 133 {
 134         local vector start, end;
 135
 136 // check for a jump-out-of-water
 137         makevectors (self.angles);
 138         start = self.origin;
 139         start_z = start_z + 8;
 140         v_forward_z = 0;
 141         normalize(v_forward);
 142         end = start + v_forward*24;
 143         traceline (start, end, TRUE, self);
 144         if (trace_fraction < 1)
 145         {       // solid at waist
 146                 start_z = start_z + self.maxs_z - 8;
 147                 end = start + v_forward*24;
 148                 self.movedir = trace_plane_normal * -50;
 149                 traceline (start, end, TRUE, self);
 150                 if (trace_fraction == 1)
 151                 {       // open at eye level
 152                         self.flags |= FL_WATERJUMP;
 153                         self.velocity_z = 225;
 154                         self.flags &~= FL_JUMPRELEASED;
 155                         self.teleport_time = time + 2;  // safety net
 156                         return;
 157                 }
 158         }
 159 };
 160
 161 float racecar_angle(float forward, float down)
 162 {
 163         float ret, angle_mult;
 164
 165         if(forward < 0)
 166         {
 167                 forward = -forward;
 168                 down = -down;
 169         }
 170
 171         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 172
 173         angle_mult = forward / (800 + forward);
 174
 175         if(ret > 180)
 176                 return ret * angle_mult + 360 * (1 - angle_mult);
 177         else
 178                 return ret * angle_mult;
 179 }
 180
 181 void RaceCarPhysics()
 182 {
 183         // using this move type for "big rigs"
 184         // the engine does not push the entity!
 185
 186         float accel, steer, f;
 187         vector angles_save, rigvel;
 188
 189         angles_save = self.angles;
 190         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 191         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 192
 193         if(g_bugrigs_reverse_speeding)
 194         {
 195                 if(accel < 0)
 196                 {
 197                         // back accel is DIGITAL
 198                         // to prevent speedhack
 199                         if(accel < -0.5)
 200                                 accel = -1;
 201                         else
 202                                 accel = 0;
 203                 }
 204         }
 205
 206         self.angles_x = 0;
 207         self.angles_z = 0;
 208         makevectors(self.angles); // new forward direction!
 209
 210         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 211         {
 212                 float myspeed, upspeed, steerfactor, accelfactor;
 213
 214                 myspeed = self.velocity * v_forward;
 215                 upspeed = self.velocity * v_up;
 216
 217                 // responsiveness factor for steering and acceleration
 218                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 219                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 220
 221                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 222                         steerfactor = -myspeed * g_bugrigs_steer;
 223                 else
 224                         steerfactor = -myspeed * f * g_bugrigs_steer;
 225
 226                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 227                         accelfactor = g_bugrigs_accel;
 228                 else
 229                         accelfactor = f * g_bugrigs_accel;
 230                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 231
 232                 if(accel < 0)
 233                 {
 234                         if(myspeed > 0)
 235                         {
 236                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 237                         }
 238                         else
 239                         {
 240                                 if(!g_bugrigs_reverse_speeding)
 241                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 242                         }
 243                 }
 244                 else
 245                 {
 246                         if(myspeed >= 0)
 247                         {
 248                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 249                         }
 250                         else
 251                         {
 252                                 if(g_bugrigs_reverse_stopping)
 253                                         myspeed = 0;
 254                                 else
 255                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 256                         }
 257                 }
 258                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 259                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 260
 261                 self.angles_y += steer * frametime * steerfactor; // apply steering
 262                 makevectors(self.angles); // new forward direction!
 263
 264                 myspeed += accel * accelfactor * frametime;
 265
 266                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 267         }
 268         else
 269         {
 270                 myspeed = vlen(self.velocity);
 271
 272                 // responsiveness factor for steering and acceleration
 273                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 274                 steerfactor = -myspeed * f;
 275                 self.angles_y += steer * frametime * steerfactor; // apply steering
 276
 277                 rigvel = self.velocity;
 278                 makevectors(self.angles); // new forward direction!
 279         }
 280
 281         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 282         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 283         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 284         //MAXIMA: solve(total_acceleration(v) = 0, v);
 285
 286         if(g_bugrigs_planar_movement)
 287         {
 288                 vector rigvel_xy, neworigin, up;
 289                 float mt;
 290
 291                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 292                 rigvel_xy = rigvel;
 293                 rigvel_xy_z = 0;
 294
 295                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 296                         mt = MOVE_NORMAL;
 297                 else
 298                         mt = MOVE_NOMONSTERS;
 299
 300                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 301                 up = trace_endpos - self.origin;
 302
 303                 // BUG RIGS: align the move to the surface instead of doing collision testing
 304                 // can we move?
 305                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 306
 307                 // align to surface
 308                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 309
 310                 if(trace_fraction < 0.5)
 311                 {
 312                         trace_fraction = 1;
 313                         neworigin = self.origin;
 314                 }
 315                 else
 316                         neworigin = trace_endpos;
 317
 318                 if(trace_fraction < 1)
 319                 {
 320                         // now set angles_x so that the car points parallel to the surface
 321                         self.angles = vectoangles(
 322                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 323                                         +
 324                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 325                                         +
 326                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 327                                         );
 328                         self.flags |= FL_ONGROUND;
 329                 }
 330                 else
 331                 {
 332                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 333                         self.flags &~= FL_ONGROUND;
 334                 }
 335
 336                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 337                 self.movetype = MOVETYPE_NOCLIP;
 338         }
 339         else
 340         {
 341                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 342                 self.velocity = rigvel;
 343                 self.movetype = MOVETYPE_FLY;
 344         }
 345
 346         trace_fraction = 1;
 347         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 348         if(trace_fraction != 1)
 349         {
 350                 self.angles = vectoangles2(
 351                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 352                                 +
 353                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 354                                 +
 355                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 356                                 trace_plane_normal
 357                                 );
 358         }
 359         else
 360         {
 361                 vector vel_local;
 362
 363                 vel_local_x = v_forward * self.velocity;
 364                 vel_local_y = v_right * self.velocity;
 365                 vel_local_z = v_up * self.velocity;
 366
 367                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 368                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 369         }
 370
 371         // smooth the angles
 372         vector vf1, vu1, smoothangles;
 373         makevectors(self.angles);
 374         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 375         if(f == 0)
 376                 f = 1;
 377         vf1 = v_forward * f;
 378         vu1 = v_up * f;
 379         makevectors(angles_save);
 380         vf1 = vf1 + v_forward * (1 - f);
 381         vu1 = vu1 + v_up * (1 - f);
 382         smoothangles = vectoangles2(vf1, vu1);
 383         self.angles_x = -smoothangles_x;
 384         self.angles_z =  smoothangles_z;
 385 }
 386
 387 float IsMoveInDirection(vector mv, float angle) // key mix factor
 388 {
 389         if(mv_x == 0 && mv_y == 0)
 390                 return 0; // avoid division by zero
 391         angle = RAD2DEG * atan2(mv_y, mv_x);
 392         angle = remainder(angle, 360) / 45;
 393         if(angle >  1)
 394                 return 0;
 395         if(angle < -1)
 396                 return 0;
 397         return 1 - fabs(angle);
 398 }
 399
 400 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 401 {
 402         float zspeed, xyspeed, dot, k;
 403
 404 #if 0
 405         // this doesn't play well with analog input
 406         if(self.movement_x == 0 || self.movement_y != 0)
 407                 return; // can't control movement if not moving forward or backward
 408         k = 32;
 409 #else
 410         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 411         if(k <= 0)
 412                 return;
 413 #endif
 414
 415         k *= bound(0, wishspeed / sv_maxairspeed, 1);
 416
 417         zspeed = self.velocity_z;
 418         self.velocity_z = 0;
 419         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 420
 421         dot = self.velocity * wishdir;
 422         k *= sv_aircontrol*dot*dot*frametime;
 423
 424         if(dot > 0) // we can't change direction while slowing down
 425         {
 426                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 427         }
 428
 429         self.velocity = self.velocity * xyspeed;
 430         self.velocity_z = zspeed;
 431 }
 432
 433 // example config for alternate speed clamping:
 434 //   sv_airaccel_qw 0.8
 435 //   sv_airaccel_sideways_friction 0
 436 //   prvm_globalset server speedclamp_mode 1
 437 //     (or 2)
 438 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float sidefric)
 439 {
 440         float vel_straight;
 441         float vel_z;
 442         vector vel_perpend;
 443         float step;
 444
 445         vector vel_xy;
 446         float vel_xy_current;
 447         float vel_xy_backward, vel_xy_forward;
 448         float speedclamp;
 449
 450         speedclamp = (accelqw < 0);
 451         if(speedclamp)
 452                 accelqw = -accelqw;
 453
 454         if(cvar("sv_gameplayfix_q2airaccelerate"))
 455                 wishspeed0 = wishspeed;
 456
 457         vel_straight = self.velocity * wishdir;
 458         vel_z = self.velocity_z;
 459         vel_xy = self.velocity - vel_z * '0 0 1';
 460         vel_perpend = vel_xy - vel_straight * wishdir;
 461
 462         step = accel * frametime * wishspeed0;
 463
 464         vel_xy_current  = vlen(vel_xy);
 465         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 466         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 467         if(vel_xy_backward < 0)
 468                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 469
 470         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 471
 472         if(sidefric < 0 && (vel_perpend*vel_perpend))
 473                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 474         {
 475                 float f, fminimum;
 476                 f = (1 - frametime * wishspeed * sidefric);
 477                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 478                 if(fminimum <= 0)
 479                         vel_perpend = vel_perpend * f;
 480                 else
 481                 {
 482                         fminimum = sqrt(fminimum);
 483                         vel_perpend = vel_perpend * bound(fminimum, f, 1);
 484                 }
 485         }
 486         else
 487                 vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 488
 489         vel_xy = vel_straight * wishdir + vel_perpend;
 490
 491         if(speedclamp)
 492         {
 493                 // ensure we don't get too fast or decelerate faster than we should
 494                 vel_xy_current = min(vlen(vel_xy), vel_xy_forward);
 495                 if(vel_xy_current > 0) // prevent division by zero
 496                         vel_xy = normalize(vel_xy) * vel_xy_current;
 497         }
 498
 499         self.velocity = vel_xy + vel_z * '0 0 1';
 500 }
 501
 502 void PM_AirAccelerate(vector wishdir, float wishspeed)
 503 {
 504         vector curvel, wishvel, acceldir, curdir;
 505         float addspeed, accelspeed, curspeed, f;
 506         float dot;
 507
 508         if(wishspeed == 0)
 509                 return;
 510
 511         curvel = self.velocity;
 512         curvel_z = 0;
 513         curspeed = vlen(curvel);
 514
 515         if(wishspeed > curspeed * 1.01)
 516         {
 517                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 518         }
 519         else
 520         {
 521                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 522                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 523         }
 524         wishvel = wishdir * wishspeed;
 525         acceldir = wishvel - curvel;
 526         addspeed = vlen(acceldir);
 527         acceldir = normalize(acceldir);
 528
 529         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 530
 531         if(sv_warsowbunny_backtosideratio < 1)
 532         {
 533                 curdir = normalize(curvel);
 534                 dot = acceldir * curdir;
 535                 if(dot < 0)
 536                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 537         }
 538
 539         self.velocity += accelspeed * acceldir;
 540 }
 541
 542 .vector movement_old;
 543 .float buttons_old;
 544 .vector v_angle_old;
 545 .string lastclassname;
 546
 547 void Nixnex_GiveCurrentWeapon();
 548 .float() PlayerPhysplug;
 549
 550 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 551 .float specialcommand_pos;
 552 void SpecialCommand()
 553 {
 554 #ifdef TETRIS
 555         TetrisImpulse();
 556 #else
 557         if(!CheatImpulse(99))
 558                 print("A hollow voice says \"Plugh\".\n");
 559 #endif
 560 }
 561
 562 float speedaward_speed;
 563 string speedaward_holder;
 564 void race_send_speedaward(float msg)
 565 {
 566         // send the best speed of the round
 567         WriteByte(msg, SVC_TEMPENTITY);
 568         WriteByte(msg, TE_CSQC_RACE);
 569         WriteByte(msg, RACE_NET_SPEED_AWARD);
 570         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 571         WriteString(msg, speedaward_holder);
 572 }
 573
 574 float speedaward_alltimebest;
 575 string speedaward_alltimebest_holder;
 576 void race_send_speedaward_alltimebest(float msg)
 577 {
 578         // send the best speed
 579         WriteByte(msg, SVC_TEMPENTITY);
 580         WriteByte(msg, TE_CSQC_RACE);
 581         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 582         WriteShort(msg, floor(speedaward_alltimebest+0.5));
 583         WriteString(msg, speedaward_alltimebest_holder);
 584 }
 585
 586 string GetMapname(void);
 587 float speedaward_lastupdate;
 588 float speedaward_lastsent;
 589 void SV_PlayerPhysics()
 590 {
 591         local vector wishvel, wishdir, v;
 592         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 593         string temps;
 594         float buttons_prev;
 595         float not_allowed_to_move;
 596         string c;
 597
 598     if(self.PlayerPhysplug)
 599         if(self.PlayerPhysplug())
 600             return;
 601
 602         self.race_movetime_frac += frametime;
 603         f = floor(self.race_movetime_frac);
 604         self.race_movetime_frac -= f;
 605         self.race_movetime_count += f;
 606         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 607
 608         anticheat_physics();
 609
 610         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 611
 612         if(!buttons)
 613                 c = "x";
 614         else if(buttons == 1)
 615                 c = "1";
 616         else if(buttons == 2)
 617                 c = " ";
 618         else if(buttons == 128)
 619                 c = "s";
 620         else if(buttons == 256)
 621                 c = "w";
 622         else if(buttons == 512)
 623                 c = "a";
 624         else if(buttons == 1024)
 625                 c = "d";
 626         else
 627                 c = "?";
 628
 629         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 630         {
 631                 self.specialcommand_pos += 1;
 632                 if(self.specialcommand_pos >= strlen(specialcommand))
 633                 {
 634                         self.specialcommand_pos = 0;
 635                         SpecialCommand();
 636                         return;
 637                 }
 638         }
 639         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 640                 self.specialcommand_pos = 0;
 641
 642         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 643         {
 644                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 645                         self.parm_idlesince = time;
 646         }
 647         buttons_prev = self.buttons_old;
 648         self.buttons_old = buttons;
 649         self.movement_old = self.movement;
 650         self.v_angle_old = self.v_angle;
 651
 652         if(time < self.nickspamtime)
 653         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 654         {
 655                 // slight annoyance for nick change scripts
 656                 self.movement = -1 * self.movement;
 657                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 658
 659                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 660                 {
 661                         self.angles_x = random() * 360;
 662                         self.angles_y = random() * 360;
 663                         // at least I'm not forcing retardedview by also assigning to angles_z
 664                         self.fixangle = 1;
 665                 }
 666         }
 667
 668         if (self.punchangle != '0 0 0')
 669         {
 670                 f = vlen(self.punchangle) - 10 * frametime;
 671                 if (f > 0)
 672                         self.punchangle = normalize(self.punchangle) * f;
 673                 else
 674                         self.punchangle = '0 0 0';
 675         }
 676
 677         if (self.punchvector != '0 0 0')
 678         {
 679                 f = vlen(self.punchvector) - 30 * frametime;
 680                 if (f > 0)
 681                         self.punchvector = normalize(self.punchvector) * f;
 682                 else
 683                         self.punchvector = '0 0 0';
 684         }
 685
 686         if (clienttype(self) == CLIENTTYPE_BOT)
 687         {
 688                 if(playerdemo_read())
 689                         return;
 690                 bot_think();
 691         }
 692
 693         self.items &~= IT_USING_JETPACK;
 694
 695         if(self.classname == "player")
 696         {
 697                 if(self.race_penalty)
 698                         if(time > self.race_penalty)
 699                                 self.race_penalty = 0;
 700
 701                 not_allowed_to_move = 0;
 702                 if(self.race_penalty)
 703                         not_allowed_to_move = 1;
 704                 if(!cvar("sv_ready_restart_after_countdown"))
 705                 if(time < game_starttime)
 706                         not_allowed_to_move = 1;
 707
 708                 if(not_allowed_to_move)
 709                 {
 710                         self.velocity = '0 0 0';
 711                         self.movetype = MOVETYPE_NONE;
 712                         self.disableclientprediction = 2;
 713                 }
 714                 else if(self.disableclientprediction == 2)
 715                 {
 716                         if(self.movetype == MOVETYPE_NONE)
 717                                 self.movetype = MOVETYPE_WALK;
 718                         self.disableclientprediction = 0;
 719                 }
 720         }
 721
 722         if (self.movetype == MOVETYPE_NONE)
 723                 return;
 724
 725         maxspd_mod = 1;
 726
 727         if(g_runematch)
 728         {
 729                 if(self.runes & RUNE_SPEED)
 730                 {
 731                         if(self.runes & CURSE_SLOW)
 732                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 733                         else
 734                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 735                 }
 736                 else if(self.runes & CURSE_SLOW)
 737                 {
 738                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 739                 }
 740         }
 741
 742         if(g_minstagib && (self.items & IT_INVINCIBLE))
 743         {
 744                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 745         }
 746
 747         if(g_nexball && self.ballcarried)
 748         {
 749                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 750         }
 751
 752         swampspd_mod = 1;
 753         if(self.in_swamp) {
 754                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 755         }
 756
 757         if(self.classname != "player")
 758         {
 759                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 760                 if(!self.spectatorspeed)
 761                         self.spectatorspeed = maxspd_mod;
 762                 if(self.impulse && self.impulse <= 19)
 763                 {
 764                         if(self.lastclassname != "player")
 765                         {
 766                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 767                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 768                                 else if(self.impulse == 11)
 769                                         self.spectatorspeed = maxspd_mod;
 770                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 771                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 772                                 else if(self.impulse >= 1 && self.impulse <= 9)
 773                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 774                         } // otherwise just clear
 775                         self.impulse = 0;
 776                 }
 777                 maxspd_mod = self.spectatorspeed;
 778         }
 779
 780         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 781         if(self.speed != spd)
 782         {
 783                 self.speed = spd;
 784                 temps = ftos(spd);
 785                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 786                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 787                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 788                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 789         }
 790
 791         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 792         swampspd_mod = 1;
 793
 794         // if dead, behave differently
 795         if (self.deadflag)
 796                 goto end;
 797
 798         if (!self.fixangle && !g_bugrigs)
 799         {
 800                 self.angles_x = 0;
 801                 self.angles_y = self.v_angle_y;
 802                 self.angles_z = 0;
 803         }
 804
 805         if(self.flags & FL_ONGROUND)
 806         if(self.wasFlying)
 807         {
 808                 self.wasFlying = 0;
 809
 810                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 811                 if(time >= self.ladder_time)
 812                 if not(self.hook)
 813                 {
 814                         self.nextstep = time + 0.3 + random() * 0.1;
 815                         trace_dphitq3surfaceflags = 0;
 816                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 817                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 818                         {
 819                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 820                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 821                                 else
 822                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 823                         }
 824                 }
 825         }
 826
 827         if(IsFlying(self))
 828                 self.wasFlying = 1;
 829
 830         if(self.classname == "player")
 831         {
 832                 if(sv_doublejump)
 833                 {
 834                         self.flags &~= FL_ONGROUND;
 835                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 836                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 837                                 self.flags |= FL_ONGROUND;
 838                 }
 839
 840                 if (self.BUTTON_JUMP)
 841                         PlayerJump ();
 842                 else
 843                         self.flags |= FL_JUMPRELEASED;
 844
 845                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 846                         CheckWaterJump ();
 847         }
 848
 849         if (self.flags & FL_WATERJUMP )
 850         {
 851                 self.velocity_x = self.movedir_x;
 852                 self.velocity_y = self.movedir_y;
 853                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 854                 {
 855                         self.flags &~= FL_WATERJUMP;
 856                         self.teleport_time = 0;
 857                 }
 858         }
 859         else if (g_bugrigs && self.classname == "player")
 860         {
 861                 RaceCarPhysics();
 862         }
 863         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 864         {
 865                 // noclipping or flying
 866                 self.flags &~= FL_ONGROUND;
 867
 868                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 869                 makevectors(self.v_angle);
 870                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 871                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 872                 // acceleration
 873                 wishdir = normalize(wishvel);
 874                 wishspeed = vlen(wishvel);
 875                 if (wishspeed > sv_maxspeed*maxspd_mod)
 876                         wishspeed = sv_maxspeed*maxspd_mod;
 877                 if (time >= self.teleport_time)
 878                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 879         }
 880         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 881         {
 882                 // swimming
 883                 self.flags &~= FL_ONGROUND;
 884
 885                 makevectors(self.v_angle);
 886                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 887                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 888                 if (wishvel == '0 0 0')
 889                         wishvel = '0 0 -60'; // drift towards bottom
 890
 891                 wishdir = normalize(wishvel);
 892                 wishspeed = vlen(wishvel);
 893                 if (wishspeed > sv_maxspeed*maxspd_mod)
 894                         wishspeed = sv_maxspeed*maxspd_mod;
 895                 wishspeed = wishspeed * 0.7;
 896
 897                 // water friction
 898                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 899
 900                 // water acceleration
 901                 PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 902         }
 903         else if (time < self.ladder_time)
 904         {
 905                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 906                 self.flags &~= FL_ONGROUND;
 907
 908                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 909                 makevectors(self.v_angle);
 910                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 911                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 912                 if (self.gravity)
 913                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 914                 else
 915                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 916                 if (self.ladder_entity.classname == "func_water")
 917                 {
 918                         f = vlen(wishvel);
 919                         if (f > self.ladder_entity.speed)
 920                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 921
 922                         self.watertype = self.ladder_entity.skin;
 923                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 924                         if ((self.origin_z + self.view_ofs_z) < f)
 925                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 926                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 927                                 self.waterlevel = WATERLEVEL_SWIMMING;
 928                         else if ((self.origin_z + self.mins_z + 1) < f)
 929                                 self.waterlevel = WATERLEVEL_WETFEET;
 930                         else
 931                         {
 932                                 self.waterlevel = WATERLEVEL_NONE;
 933                                 self.watertype = CONTENT_EMPTY;
 934                         }
 935                 }
 936                 // acceleration
 937                 wishdir = normalize(wishvel);
 938                 wishspeed = vlen(wishvel);
 939                 if (wishspeed > sv_maxspeed*maxspd_mod)
 940                         wishspeed = sv_maxspeed*maxspd_mod;
 941                 if (time >= self.teleport_time)
 942                 {
 943                         // water acceleration
 944                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 945                 }
 946         }
 947         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 948         {
 949                 //makevectors(self.v_angle_y * '0 1 0');
 950                 makevectors(self.v_angle);
 951                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 952                 // add remaining speed as Z component
 953                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 954                 // fix speedhacks :P
 955                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 956                 // add the unused velocity as up component
 957                 wishvel_z = 0;
 958
 959                 // if(self.BUTTON_JUMP)
 960                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 961
 962                 // it is now normalized, so...
 963                 float a_side, a_up, a_add, a_diff;
 964                 a_side = cvar("g_jetpack_acceleration_side");
 965                 a_up = cvar("g_jetpack_acceleration_up");
 966                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 967
 968                 wishvel_x *= a_side;
 969                 wishvel_y *= a_side;
 970                 wishvel_z *= a_up;
 971                 wishvel_z += a_add;
 972
 973                 float best;
 974                 best = 0;
 975                 //////////////////////////////////////////////////////////////////////////////////////
 976                 // finding the maximum over all vectors of above form
 977                 // with wishvel having an absolute value of 1
 978                 //////////////////////////////////////////////////////////////////////////////////////
 979                 // we're finding the maximum over
 980                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 981                 // for z in the range from -1 to 1
 982                 //////////////////////////////////////////////////////////////////////////////////////
 983                 // maximum is EITHER attained at the single extreme point:
 984                 a_diff = a_side * a_side - a_up * a_up;
 985                 if(a_diff != 0)
 986                 {
 987                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 988                         if(f > -1 && f < 1) // can it be attained?
 989                         {
 990                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 991                                 //print("middle\n");
 992                         }
 993                 }
 994                 // OR attained at z = 1:
 995                 f = (a_up + a_add) * (a_up + a_add);
 996                 if(f > best)
 997                 {
 998                         best = f;
 999                         //print("top\n");
1000                 }
1001                 // OR attained at z = -1:
1002                 f = (a_up - a_add) * (a_up - a_add);
1003                 if(f > best)
1004                 {
1005                         best = f;
1006                         //print("bottom\n");
1007                 }
1008                 best = sqrt(best);
1009                 //////////////////////////////////////////////////////////////////////////////////////
1010
1011                 //print("best possible acceleration: ", ftos(best), "\n");
1012
1013                 float fxy, fz;
1014                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
1015                 if(wishvel_z - sv_gravity > 0)
1016                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1017                 else
1018                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
1019
1020                 float fvel;
1021                 fvel = vlen(wishvel);
1022                 wishvel_x *= fxy;
1023                 wishvel_y *= fxy;
1024                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
1025
1026                 fvel = min(1, vlen(wishvel) / best);
1027                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1028                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
1029                 else
1030                         f = 1;
1031
1032                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1033
1034                 if (f > 0 && wishvel != '0 0 0')
1035                 {
1036                         self.velocity = self.velocity + wishvel * f * frametime;
1037                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1038                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1039                         self.flags &~= FL_ONGROUND;
1040                         self.items |= IT_USING_JETPACK;
1041
1042                         // jetpack also inhibits health regeneration, but only for 1 second
1043                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1044                 }
1045         }
1046         else if (self.flags & FL_ONGROUND)
1047         {
1048                 // we get here if we ran out of ammo
1049                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1050                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1051
1052                 // walking
1053                 makevectors(self.v_angle_y * '0 1 0');
1054                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1055
1056                 if(!(self.lastflags & FL_ONGROUND))
1057                 {
1058                         if(cvar("speedmeter"))
1059                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1060                         if(self.lastground < time - 0.3)
1061                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1062                         if(self.jumppadcount > 1)
1063                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1064                         self.jumppadcount = 0;
1065                 }
1066
1067 #ifdef LETS_TEST_FTEQCC
1068                 if(self.velocity_x || self.velocity_y)
1069                 {
1070                         // good
1071                 }
1072                 else
1073                 {
1074                         if(self.velocity_x)
1075                                 checkclient();
1076                         if(self.velocity_y)
1077                                 checkclient();
1078                 }
1079 #endif
1080
1081                 v = self.velocity;
1082                 v_z = 0;
1083                 f = vlen(v);
1084                 if(f > 0)
1085                 {
1086                         if (f < sv_stopspeed)
1087                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1088                         else
1089                                 f = 1 - frametime * sv_friction;
1090                         if (f > 0)
1091                                 self.velocity = self.velocity * f;
1092                         else
1093                                 self.velocity = '0 0 0';
1094                 }
1095
1096                 // acceleration
1097                 wishdir = normalize(wishvel);
1098                 wishspeed = vlen(wishvel);
1099                 if (wishspeed > sv_maxspeed*maxspd_mod)
1100                         wishspeed = sv_maxspeed*maxspd_mod;
1101                 if (self.crouch)
1102                         wishspeed = wishspeed * 0.5;
1103                 if (time >= self.teleport_time)
1104                         PM_Accelerate(wishdir, wishspeed, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1105         }
1106         else
1107         {
1108                 float wishspeed0;
1109                 // we get here if we ran out of ammo
1110                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1111                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1112
1113                 if(maxspd_mod < 1)
1114                 {
1115                         maxairspd = sv_maxairspeed*maxspd_mod;
1116                         airaccel = sv_airaccelerate*maxspd_mod;
1117                 }
1118                 else
1119                 {
1120                         maxairspd = sv_maxairspeed;
1121                         airaccel = sv_airaccelerate;
1122                 }
1123                 // airborn
1124                 makevectors(self.v_angle_y * '0 1 0');
1125                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1126                 // acceleration
1127                 wishdir = normalize(wishvel);
1128                 wishspeed = wishspeed0 = vlen(wishvel);
1129                 if (wishspeed0 > sv_maxspeed*maxspd_mod)
1130                         wishspeed0 = sv_maxspeed*maxspd_mod;
1131                 if (wishspeed > maxairspd)
1132                         wishspeed = maxairspd;
1133                 if (self.crouch)
1134                         wishspeed = wishspeed * 0.5;
1135                 if (time >= self.teleport_time)
1136                 {
1137                         float accelerating;
1138                         float wishspeed2;
1139                         float airaccelqw;
1140
1141                         airaccelqw = sv_airaccel_qw;
1142                         accelerating = (self.velocity * wishdir > 0);
1143                         wishspeed2 = wishspeed;
1144
1145                         // CPM
1146                         if(sv_airstopaccelerate)
1147                                 if(self.velocity * wishdir < 0)
1148                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1149                         // this doesn't play well with analog input, but can't r
1150                         // fixed like the AirControl can. So, don't set the maxa
1151                         // cvars when you want to support analog input.
1152                         if(self.movement_x == 0 && self.movement_y != 0)
1153                         {
1154                                 if(sv_maxairstrafespeed)
1155                                 {
1156                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1157                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1158                                                 airaccelqw = 1;
1159                                 }
1160                                 if(sv_airstrafeaccelerate)
1161                                 {
1162                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1163                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1164                                                 airaccelqw = 1;
1165                                 }
1166                         }
1167                         // !CPM
1168
1169                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1170                                 PM_AirAccelerate(wishdir, wishspeed);
1171                         else
1172                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1173
1174                         if(sv_aircontrol)
1175                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1176                 }
1177         }
1178
1179         if((g_cts || g_race) && self.classname != "observer") {
1180                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1181                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1182                         speedaward_holder = self.netname;
1183                         speedaward_lastupdate = time;
1184                 }
1185                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1186                         string rr;
1187                         if(g_cts)
1188                                 rr = CTS_RECORD;
1189                         else
1190                                 rr = RACE_RECORD;
1191                         race_send_speedaward(MSG_ALL);
1192                         speedaward_lastsent = speedaward_speed;
1193                         if (speedaward_speed > speedaward_alltimebest) {
1194                                 speedaward_alltimebest = speedaward_speed;
1195                                 speedaward_alltimebest_holder = speedaward_holder;
1196                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1197                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"), speedaward_alltimebest_holder);
1198                                 race_send_speedaward_alltimebest(MSG_ALL);
1199                         }
1200                 }
1201         }
1202 :end
1203         if(self.flags & FL_ONGROUND)
1204                 self.lastground = time;
1205
1206         self.lastflags = self.flags;
1207         self.lastclassname = self.classname;
1208 };