data/qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 float sv_accelerate;
   5 float sv_friction;
   6 float sv_maxspeed;
   7 float sv_airaccelerate;
   8 float sv_maxairspeed;
   9 float sv_stopspeed;
  10 float sv_gravity;
  11 float sv_airaccel_sideways_friction;
  12 float sv_airaccel_qw;
  13 float sv_airstopaccelerate;
  14 float sv_airstrafeaccelerate;
  15 float sv_maxairstrafespeed;
  16 float sv_aircontrol;
  17 float sv_warsowbunny_airforwardaccel;
  18 float sv_warsowbunny_accel;
  19 float sv_warsowbunny_topspeed;
  20 float sv_warsowbunny_turnaccel;
  21 float sv_warsowbunny_backtosideratio;
  22
  23 .float ladder_time;
  24 .entity ladder_entity;
  25 .float gravity;
  26 .float swamp_slowdown;
  27 .float lastflags;
  28 .float lastground;
  29 .float wasFlying;
  30 .float spectatorspeed;
  31
  32 #define SHTEST_DELTA 10
  33 #define SHTEST_THRESHOLD 1.1
  34 .float shtest_next;
  35 .float shtest_accumulator;
  36 .float doublejump_nextjumptime;
  37
  38 /*
  39 =============
  40 PlayerJump
  41
  42 When you press the jump key
  43 =============
  44 */
  45 void PlayerJump (void)
  46 {
  47         float mjumpheight;
  48
  49         mjumpheight = cvar("sv_jumpvelocity");
  50         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  51         {
  52                 if (self.watertype == CONTENT_WATER)
  53                         self.velocity_z = 200;
  54                 else if (self.watertype == CONTENT_SLIME)
  55                         self.velocity_z = 80;
  56                 else
  57                         self.velocity_z = 50;
  58
  59                 return;
  60         }
  61
  62         if (!(self.flags & FL_ONGROUND))
  63                 return;
  64
  65         if(!sv_pogostick)
  66                 if (!(self.flags & FL_JUMPRELEASED))
  67                         return;
  68
  69         if(self.health <= g_bloodloss)
  70                 return;
  71
  72         if(sv_doublejump)
  73                 if(time < self.doublejump_nextjumptime)
  74                         return;
  75
  76         if(g_runematch)
  77         {
  78                 if(self.runes & RUNE_SPEED)
  79                 {
  80                         if(self.runes & CURSE_SLOW)
  81                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  82                         else
  83                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  84                 }
  85                 else if(self.runes & CURSE_SLOW)
  86                 {
  87                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  88                 }
  89         }
  90
  91         if(g_minstagib && (self.items & IT_INVINCIBLE))
  92         {
  93                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  94         }
  95
  96         if(!(self.lastflags & FL_ONGROUND))
  97         {
  98                 if(cvar("speedmeter"))
  99                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 100                 if(self.lastground < time - 0.3)
 101                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 102                 if(self.jumppadcount > 1)
 103                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 104                 self.jumppadcount = 0;
 105         }
 106
 107         self.velocity_z = self.velocity_z + mjumpheight;
 108         self.oldvelocity_z = self.velocity_z;
 109
 110         self.flags &~= FL_ONGROUND;
 111         self.flags &~= FL_JUMPRELEASED;
 112
 113         if (self.crouch)
 114                 setanim(self, self.anim_duckjump, FALSE, TRUE, TRUE);
 115         else
 116                 setanim(self, self.anim_jump, FALSE, TRUE, TRUE);
 117
 118         if(g_jump_grunt)
 119                 PlayerSound(playersound_jump, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 120
 121         if(sv_doublejump)
 122         {
 123                 // we're moving upwards at self.velocity_z
 124                 // only allow jumping after we got 3 units upwards
 125                 // so we for sure leave the FL_ONGROUND check
 126                 //
 127                 // but as this sucks because of factoring in gravity, we'll just do it
 128                 // for 4 units, and constant velocity
 129                 self.doublejump_nextjumptime = time + 4 / max(40, self.velocity_z); // max 0.1s blocking of jumps
 130         }
 131
 132         self.restart_jump = -1; // restart jump anim next time
 133         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 134 }
 135
 136 void CheckWaterJump()
 137 {
 138         local vector start, end;
 139
 140 // check for a jump-out-of-water
 141         makevectors (self.angles);
 142         start = self.origin;
 143         start_z = start_z + 8;
 144         v_forward_z = 0;
 145         normalize(v_forward);
 146         end = start + v_forward*24;
 147         traceline (start, end, TRUE, self);
 148         if (trace_fraction < 1)
 149         {       // solid at waist
 150                 start_z = start_z + self.maxs_z - 8;
 151                 end = start + v_forward*24;
 152                 self.movedir = trace_plane_normal * -50;
 153                 traceline (start, end, TRUE, self);
 154                 if (trace_fraction == 1)
 155                 {       // open at eye level
 156                         self.flags |= FL_WATERJUMP;
 157                         self.velocity_z = 225;
 158                         self.flags &~= FL_JUMPRELEASED;
 159                         self.teleport_time = time + 2;  // safety net
 160                         return;
 161                 }
 162         }
 163 };
 164
 165 float racecar_angle(float forward, float down)
 166 {
 167         float ret, angle_mult;
 168
 169         if(forward < 0)
 170         {
 171                 forward = -forward;
 172                 down = -down;
 173         }
 174
 175         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 176
 177         angle_mult = forward / (800 + forward);
 178
 179         if(ret > 180)
 180                 return ret * angle_mult + 360 * (1 - angle_mult);
 181         else
 182                 return ret * angle_mult;
 183 }
 184
 185 void RaceCarPhysics()
 186 {
 187         // using this move type for "big rigs"
 188         // the engine does not push the entity!
 189
 190         float accel, steer, f;
 191         vector angles_save, rigvel;
 192
 193         angles_save = self.angles;
 194         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 195         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 196
 197         if(g_bugrigs_reverse_speeding)
 198         {
 199                 if(accel < 0)
 200                 {
 201                         // back accel is DIGITAL
 202                         // to prevent speedhack
 203                         if(accel < -0.5)
 204                                 accel = -1;
 205                         else
 206                                 accel = 0;
 207                 }
 208         }
 209
 210         self.angles_x = 0;
 211         self.angles_z = 0;
 212         makevectors(self.angles); // new forward direction!
 213
 214         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 215         {
 216                 float myspeed, upspeed, steerfactor, accelfactor;
 217
 218                 myspeed = self.velocity * v_forward;
 219                 upspeed = self.velocity * v_up;
 220
 221                 // responsiveness factor for steering and acceleration
 222                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 223                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 224
 225                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 226                         steerfactor = -myspeed * g_bugrigs_steer;
 227                 else
 228                         steerfactor = -myspeed * f * g_bugrigs_steer;
 229
 230                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 231                         accelfactor = g_bugrigs_accel;
 232                 else
 233                         accelfactor = f * g_bugrigs_accel;
 234                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 235
 236                 if(accel < 0)
 237                 {
 238                         if(myspeed > 0)
 239                         {
 240                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 241                         }
 242                         else
 243                         {
 244                                 if(!g_bugrigs_reverse_speeding)
 245                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 246                         }
 247                 }
 248                 else
 249                 {
 250                         if(myspeed >= 0)
 251                         {
 252                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 253                         }
 254                         else
 255                         {
 256                                 if(g_bugrigs_reverse_stopping)
 257                                         myspeed = 0;
 258                                 else
 259                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 260                         }
 261                 }
 262                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 263                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 264
 265                 self.angles_y += steer * frametime * steerfactor; // apply steering
 266                 makevectors(self.angles); // new forward direction!
 267
 268                 myspeed += accel * accelfactor * frametime;
 269
 270                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 271         }
 272         else
 273         {
 274                 myspeed = vlen(self.velocity);
 275
 276                 // responsiveness factor for steering and acceleration
 277                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 278                 steerfactor = -myspeed * f;
 279                 self.angles_y += steer * frametime * steerfactor; // apply steering
 280
 281                 rigvel = self.velocity;
 282                 makevectors(self.angles); // new forward direction!
 283         }
 284
 285         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 286         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 287         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 288         //MAXIMA: solve(total_acceleration(v) = 0, v);
 289
 290         if(g_bugrigs_planar_movement)
 291         {
 292                 vector rigvel_xy, neworigin, up;
 293                 float mt;
 294
 295                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 296                 rigvel_xy = rigvel;
 297                 rigvel_xy_z = 0;
 298
 299                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 300                         mt = MOVE_NORMAL;
 301                 else
 302                         mt = MOVE_NOMONSTERS;
 303
 304                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 305                 up = trace_endpos - self.origin;
 306
 307                 // BUG RIGS: align the move to the surface instead of doing collision testing
 308                 // can we move?
 309                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 310
 311                 // align to surface
 312                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 313
 314                 if(trace_fraction < 0.5)
 315                 {
 316                         trace_fraction = 1;
 317                         neworigin = self.origin;
 318                 }
 319                 else
 320                         neworigin = trace_endpos;
 321
 322                 if(trace_fraction < 1)
 323                 {
 324                         // now set angles_x so that the car points parallel to the surface
 325                         self.angles = vectoangles(
 326                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 327                                         +
 328                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 329                                         +
 330                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 331                                         );
 332                         self.flags |= FL_ONGROUND;
 333                 }
 334                 else
 335                 {
 336                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 337                         self.flags &~= FL_ONGROUND;
 338                 }
 339
 340                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 341                 self.movetype = MOVETYPE_NOCLIP;
 342         }
 343         else
 344         {
 345                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 346                 self.velocity = rigvel;
 347                 self.movetype = MOVETYPE_FLY;
 348         }
 349
 350         trace_fraction = 1;
 351         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 352         if(trace_fraction != 1)
 353         {
 354                 self.angles = vectoangles2(
 355                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 356                                 +
 357                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 358                                 +
 359                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 360                                 trace_plane_normal
 361                                 );
 362         }
 363         else
 364         {
 365                 vector vel_local;
 366
 367                 vel_local_x = v_forward * self.velocity;
 368                 vel_local_y = v_right * self.velocity;
 369                 vel_local_z = v_up * self.velocity;
 370
 371                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 372                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 373         }
 374
 375         // smooth the angles
 376         vector vf1, vu1, smoothangles;
 377         makevectors(self.angles);
 378         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 379         if(f == 0)
 380                 f = 1;
 381         vf1 = v_forward * f;
 382         vu1 = v_up * f;
 383         makevectors(angles_save);
 384         vf1 = vf1 + v_forward * (1 - f);
 385         vu1 = vu1 + v_up * (1 - f);
 386         smoothangles = vectoangles2(vf1, vu1);
 387         self.angles_x = -smoothangles_x;
 388         self.angles_z =  smoothangles_z;
 389 }
 390
 391 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 392 {
 393         float zspeed, xyspeed, dot, k;
 394
 395         if(self.movement_x == 0 || self.movement_y != 0)
 396                 return; // can't control movement if not moving forward or backward
 397
 398         zspeed = self.velocity_z;
 399         self.velocity_z = 0;
 400         xyspeed = vlen(self.velocity);
 401         self.velocity = normalize(self.velocity);
 402
 403         dot = self.velocity * wishdir;
 404         k = 32;
 405         k *= sv_aircontrol*dot*dot*frametime;
 406
 407         if(dot > 0) // we can't change direction while slowing down
 408                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 409
 410         self.velocity = self.velocity * xyspeed;
 411         self.velocity_z = zspeed;
 412 }
 413
 414 void PM_Accelerate(vector wishdir, float wishspeed, float accel, float accelqw, float sidefric)
 415 {
 416         float vel_straight;
 417         float vel_z;
 418         vector vel_perpend;
 419         float addspeed;
 420
 421         vel_straight = self.velocity * wishdir;
 422         vel_z = self.velocity_z;
 423         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 424
 425         addspeed = wishspeed - vel_straight;
 426         if(addspeed > 0)
 427                 vel_straight = vel_straight + min(addspeed, accel * frametime * wishspeed) * accelqw;
 428         if(wishspeed > 0)
 429                 vel_straight = vel_straight + min(wishspeed, accel * frametime * wishspeed) * (1 - accelqw);
 430
 431         vel_perpend = vel_perpend * (1 - frametime * wishspeed * sidefric);
 432
 433         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 434 }
 435
 436 void PM_AirAccelerate(vector wishdir, float wishspeed)
 437 {
 438         vector curvel, wishvel, acceldir, curdir;
 439         float addspeed, accelspeed, curspeed, f;
 440         float dot;
 441
 442         if(wishspeed == 0)
 443                 return;
 444
 445         curvel = self.velocity;
 446         curvel_z = 0;
 447         curspeed = vlen(curvel);
 448
 449         if(wishspeed > curspeed * 1.01)
 450         {
 451                 wishspeed = min(wishspeed, curspeed + sv_warsowbunny_airforwardaccel * sv_maxspeed * frametime);
 452         }
 453         else
 454         {
 455                 f = max(0, (sv_warsowbunny_topspeed - curspeed) / (sv_warsowbunny_topspeed - sv_maxspeed));
 456                 wishspeed = max(curspeed, sv_maxspeed) + sv_warsowbunny_accel * f * sv_maxspeed * frametime;
 457         }
 458         wishvel = wishdir * wishspeed;
 459         acceldir = wishvel - curvel;
 460         addspeed = vlen(acceldir);
 461         acceldir = normalize(acceldir);
 462
 463         accelspeed = min(addspeed, sv_warsowbunny_turnaccel * sv_maxspeed * frametime);
 464
 465         if(sv_warsowbunny_backtosideratio < 1)
 466         {
 467                 curdir = normalize(curvel);
 468                 dot = acceldir * curdir;
 469                 if(dot < 0)
 470                         acceldir = acceldir - (1 - sv_warsowbunny_backtosideratio) * dot * curdir;
 471         }
 472
 473         self.velocity += accelspeed * acceldir;
 474 }
 475
 476 .vector movement_old;
 477 .float buttons_old;
 478 .vector v_angle_old;
 479 .string lastclassname;
 480
 481 void Nixnex_GiveCurrentWeapon();
 482 .float() PlayerPhysplug;
 483
 484 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 485 .float specialcommand_pos;
 486 void SpecialCommand()
 487 {
 488 #ifdef TETRIS
 489         TetrisImpulse();
 490 #else
 491         if(sv_cheats || self.maycheat)
 492                 self.impulse = 99;
 493         else
 494                 print("A hollow voice says \"Plugh\".\n");
 495 #endif
 496 }
 497
 498 void SV_PlayerPhysics()
 499 {
 500         local vector wishvel, wishdir, v;
 501         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 502         string temps;
 503         float buttons_prev;
 504         float not_allowed_to_move;
 505         string c;
 506
 507         if(g_race || g_cts)
 508         {
 509                 // if record times matter
 510                 // ensure nothing EVIL is being done (i.e. strafebot)
 511                 // this hinders joystick users though
 512                 // but it still gives SOME analog control
 513                 // TODO implement this for engine cl_movement code too (basically, clipping to the four axes)
 514                 wishvel_x = fabs(self.movement_x);
 515                 wishvel_y = fabs(self.movement_y);
 516                 if(wishvel_x != 0 && wishvel_y != 0 && wishvel_x != wishvel_y)
 517                 {
 518                         wishvel_z = 0;
 519                         wishspeed = vlen(wishvel);
 520                         if(wishvel_x >= 2 * wishvel_y)
 521                         {
 522                                 // pure X motion
 523                                 if(self.movement_x > 0)
 524                                         self.movement_x = wishspeed;
 525                                 else
 526                                         self.movement_x = -wishspeed;
 527                                 self.movement_y = 0;
 528                         }
 529                         else if(wishvel_y >= 2 * wishvel_x)
 530                         {
 531                                 // pure Y motion
 532                                 self.movement_x = 0;
 533                                 if(self.movement_y > 0)
 534                                         self.movement_y = wishspeed;
 535                                 else
 536                                         self.movement_y = -wishspeed;
 537                         }
 538                         else
 539                         {
 540                                 // diagonal
 541                                 if(self.movement_x > 0)
 542                                         self.movement_x = 0.70710678118654752440 * wishspeed;
 543                                 else
 544                                         self.movement_x = -0.70710678118654752440 * wishspeed;
 545                                 if(self.movement_y > 0)
 546                                         self.movement_y = 0.70710678118654752440 * wishspeed;
 547                                 else
 548                                         self.movement_y = -0.70710678118654752440 * wishspeed;
 549                         }
 550                 }
 551         }
 552
 553         self.race_movetime_frac += frametime;
 554         f = floor(self.race_movetime_frac);
 555         self.race_movetime_frac -= f;
 556         self.race_movetime_count += f;
 557         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 558
 559         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 560
 561         if(!buttons)
 562                 c = "x";
 563         else if(buttons == 1)
 564                 c = "1";
 565         else if(buttons == 2)
 566                 c = " ";
 567         else if(buttons == 128)
 568                 c = "s";
 569         else if(buttons == 256)
 570                 c = "w";
 571         else if(buttons == 512)
 572                 c = "a";
 573         else if(buttons == 1024)
 574                 c = "d";
 575         else
 576                 c = "?";
 577
 578         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 579         {
 580                 self.specialcommand_pos += 1;
 581                 if(self.specialcommand_pos >= strlen(specialcommand))
 582                 {
 583                         self.specialcommand_pos = 0;
 584                         SpecialCommand();
 585                         return;
 586                 }
 587         }
 588         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 589                 self.specialcommand_pos = 0;
 590
 591     if(self.PlayerPhysplug)
 592         if(self.PlayerPhysplug())
 593             return;
 594
 595         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 596         {
 597                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 598                         self.parm_idlesince = time;
 599         }
 600         buttons_prev = self.buttons_old;
 601         self.buttons_old = buttons;
 602         self.movement_old = self.movement;
 603         self.v_angle_old = self.v_angle;
 604
 605         if(time < self.nickspamtime)
 606         if(self.nickspamcount >= cvar("g_nick_flood_penalty_yellow"))
 607         {
 608                 // slight annoyance for nick change scripts
 609                 self.movement = -1 * self.movement;
 610                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 611
 612                 if(self.nickspamcount >= cvar("g_nick_flood_penalty_red")) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 613                 {
 614                         self.angles_x = random() * 360;
 615                         self.angles_y = random() * 360;
 616                         // at least I'm not forcing retardedview by also assigning to angles_z
 617                         self.fixangle = 1;
 618                 }
 619         }
 620
 621         if(time > self.shtest_next)
 622         {
 623                 if(self.shtest_next > 0)
 624                 {
 625                         // self.shtest_accumulator:
 626                         //   started at time - SHTEST_DELTA
 627                         //   should be at SHTEST_DELTA
 628                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 629                         if(shtest_score > SHTEST_THRESHOLD)
 630                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 631                         else if(cvar("developer_shtest"))
 632                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 633                 }
 634                 self.shtest_next = time + SHTEST_DELTA;
 635                 self.shtest_accumulator = 0;
 636         }
 637         self.shtest_accumulator += frametime;
 638
 639         if (clienttype(self) == CLIENTTYPE_BOT)
 640                 bot_think();
 641
 642         self.items &~= IT_USING_JETPACK;
 643
 644         if(self.classname == "player")
 645         {
 646                 if(self.race_penalty)
 647                         if(time > self.race_penalty)
 648                                 self.race_penalty = 0;
 649
 650                 not_allowed_to_move = 0;
 651                 if(self.race_penalty)
 652                         not_allowed_to_move = 1;
 653                 if(!cvar("sv_ready_restart_after_countdown"))
 654                 if(time < game_starttime)
 655                         not_allowed_to_move = 1;
 656
 657                 if(not_allowed_to_move)
 658                 {
 659                         self.velocity = '0 0 0';
 660                         self.movetype = MOVETYPE_NONE;
 661                         self.disableclientprediction = 2;
 662                 }
 663                 else if(self.disableclientprediction == 2)
 664                 {
 665                         if(self.movetype == MOVETYPE_NONE)
 666                                 self.movetype = MOVETYPE_WALK;
 667                         self.disableclientprediction = 0;
 668                 }
 669         }
 670
 671         if (self.movetype == MOVETYPE_NONE)
 672                 return;
 673
 674         if (self.punchangle != '0 0 0')
 675         {
 676                 f = vlen(self.punchangle) - 10 * frametime;
 677                 if (f > 0)
 678                         self.punchangle = normalize(self.punchangle) * f;
 679                 else
 680                         self.punchangle = '0 0 0';
 681         }
 682
 683         if (self.punchvector != '0 0 0')
 684         {
 685                 f = vlen(self.punchvector) - 30 * frametime;
 686                 if (f > 0)
 687                         self.punchvector = normalize(self.punchvector) * f;
 688                 else
 689                         self.punchvector = '0 0 0';
 690         }
 691
 692         maxspd_mod = 1;
 693
 694         if(g_runematch)
 695         {
 696                 if(self.runes & RUNE_SPEED)
 697                 {
 698                         if(self.runes & CURSE_SLOW)
 699                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 700                         else
 701                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 702                 }
 703                 else if(self.runes & CURSE_SLOW)
 704                 {
 705                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 706                 }
 707         }
 708
 709         if(g_minstagib && (self.items & IT_INVINCIBLE))
 710         {
 711                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 712         }
 713
 714         if(g_nexball && self.ballcarried)
 715         {
 716                 maxspd_mod = cvar("g_nexball_basketball_carrier_speed");
 717         }
 718
 719         swampspd_mod = 1;
 720         if(self.in_swamp) {
 721                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 722         }
 723
 724         if(self.classname != "player")
 725         {
 726                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 727                 if(!self.spectatorspeed)
 728                         self.spectatorspeed = maxspd_mod;
 729                 if(self.impulse && self.impulse <= 19)
 730                 {
 731                         if(self.lastclassname != "player")
 732                         {
 733                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 734                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 735                                 else if(self.impulse == 11)
 736                                         self.spectatorspeed = maxspd_mod;
 737                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 738                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 739                                 else if(self.impulse >= 1 && self.impulse <= 9)
 740                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 741                         } // otherwise just clear
 742                         self.impulse = 0;
 743                 }
 744                 maxspd_mod = self.spectatorspeed;
 745         }
 746
 747         spd = max(sv_maxspeed, sv_maxairspeed) * maxspd_mod * swampspd_mod;
 748         if(self.speed != spd)
 749         {
 750                 self.speed = spd;
 751                 temps = ftos(spd);
 752                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 753                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 754                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 755                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 756         }
 757
 758         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 759         swampspd_mod = 1;
 760
 761         // if dead, behave differently
 762         if (self.deadflag)
 763                 goto end;
 764
 765         if (!self.fixangle && !g_bugrigs)
 766         {
 767                 self.angles_x = 0;
 768                 self.angles_y = self.v_angle_y;
 769                 self.angles_z = 0;
 770         }
 771
 772         if(self.flags & FL_ONGROUND)
 773         if(self.wasFlying)
 774         {
 775                 self.wasFlying = 0;
 776
 777                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 778                 if(time >= self.ladder_time)
 779                 if not(self.hook)
 780                 {
 781                         self.nextstep = time + 0.3 + random() * 0.1;
 782                         trace_dphitq3surfaceflags = 0;
 783                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 784                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 785                         {
 786                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 787                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 788                                 else
 789                                         GlobalSound(globalsound_fall, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);
 790                         }
 791                 }
 792         }
 793
 794         if(IsFlying(self))
 795                 self.wasFlying = 1;
 796
 797         if(self.classname == "player")
 798         {
 799                 if(sv_doublejump)
 800                 {
 801                         self.flags &~= FL_ONGROUND;
 802                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 1', MOVE_NORMAL, self);
 803                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 804                                 self.flags |= FL_ONGROUND;
 805                 }
 806
 807                 if (self.BUTTON_JUMP)
 808                         PlayerJump ();
 809                 else
 810                         self.flags |= FL_JUMPRELEASED;
 811
 812                 if (self.waterlevel == WATERLEVEL_SWIMMING)
 813                         CheckWaterJump ();
 814         }
 815
 816         if (self.flags & FL_WATERJUMP )
 817         {
 818                 self.velocity_x = self.movedir_x;
 819                 self.velocity_y = self.movedir_y;
 820                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 821                 {
 822                         self.flags &~= FL_WATERJUMP;
 823                         self.teleport_time = 0;
 824                 }
 825         }
 826         else if (g_bugrigs && self.classname == "player")
 827         {
 828                 RaceCarPhysics();
 829         }
 830         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 831         {
 832                 // noclipping or flying
 833                 self.flags &~= FL_ONGROUND;
 834
 835                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 836                 makevectors(self.v_angle);
 837                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 838                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 839                 // acceleration
 840                 wishdir = normalize(wishvel);
 841                 wishspeed = vlen(wishvel);
 842                 if (wishspeed > sv_maxspeed*maxspd_mod)
 843                         wishspeed = sv_maxspeed*maxspd_mod;
 844                 if (time >= self.teleport_time)
 845                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 846         }
 847         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 848         {
 849                 // swimming
 850                 self.flags &~= FL_ONGROUND;
 851
 852                 makevectors(self.v_angle);
 853                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 854                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 855                 if (wishvel == '0 0 0')
 856                         wishvel = '0 0 -60'; // drift towards bottom
 857
 858                 wishdir = normalize(wishvel);
 859                 wishspeed = vlen(wishvel);
 860                 if (wishspeed > sv_maxspeed*maxspd_mod)
 861                         wishspeed = sv_maxspeed*maxspd_mod;
 862                 wishspeed = wishspeed * 0.7;
 863
 864                 // water friction
 865                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 866
 867                 // water acceleration
 868                 PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 869         }
 870         else if (time < self.ladder_time)
 871         {
 872                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 873                 self.flags &~= FL_ONGROUND;
 874
 875                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 876                 makevectors(self.v_angle);
 877                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 878                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 879                 if (self.gravity)
 880                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 881                 else
 882                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 883                 if (self.ladder_entity.classname == "func_water")
 884                 {
 885                         f = vlen(wishvel);
 886                         if (f > self.ladder_entity.speed)
 887                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 888
 889                         self.watertype = self.ladder_entity.skin;
 890                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 891                         if ((self.origin_z + self.view_ofs_z) < f)
 892                                 self.waterlevel = WATERLEVEL_SUBMERGED;
 893                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 894                                 self.waterlevel = WATERLEVEL_SWIMMING;
 895                         else if ((self.origin_z + self.mins_z + 1) < f)
 896                                 self.waterlevel = WATERLEVEL_WETFEET;
 897                         else
 898                         {
 899                                 self.waterlevel = WATERLEVEL_NONE;
 900                                 self.watertype = CONTENT_EMPTY;
 901                         }
 902                 }
 903                 // acceleration
 904                 wishdir = normalize(wishvel);
 905                 wishspeed = vlen(wishvel);
 906                 if (wishspeed > sv_maxspeed*maxspd_mod)
 907                         wishspeed = sv_maxspeed*maxspd_mod;
 908                 if (time >= self.teleport_time)
 909                 {
 910                         // water acceleration
 911                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
 912                 }
 913         }
 914         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!cvar("g_jetpack_fuel") || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO))
 915         {
 916                 //makevectors(self.v_angle_y * '0 1 0');
 917                 makevectors(self.v_angle);
 918                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 919                 // add remaining speed as Z component
 920                 maxairspd = sv_maxairspeed*max(1, maxspd_mod);
 921                 // fix speedhacks :P
 922                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
 923                 // add the unused velocity as up component
 924                 wishvel_z = 0;
 925
 926                 // if(self.BUTTON_JUMP)
 927                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 928
 929                 // it is now normalized, so...
 930                 float a_side, a_up, a_add, a_diff;
 931                 a_side = cvar("g_jetpack_acceleration_side");
 932                 a_up = cvar("g_jetpack_acceleration_up");
 933                 a_add = cvar("g_jetpack_antigravity") * sv_gravity;
 934
 935                 wishvel_x *= a_side;
 936                 wishvel_y *= a_side;
 937                 wishvel_z *= a_up;
 938                 wishvel_z += a_add;
 939
 940                 float best;
 941                 best = 0;
 942                 //////////////////////////////////////////////////////////////////////////////////////
 943                 // finding the maximum over all vectors of above form
 944                 // with wishvel having an absolute value of 1
 945                 //////////////////////////////////////////////////////////////////////////////////////
 946                 // we're finding the maximum over
 947                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 948                 // for z in the range from -1 to 1
 949                 //////////////////////////////////////////////////////////////////////////////////////
 950                 // maximum is EITHER attained at the single extreme point:
 951                 a_diff = a_side * a_side - a_up * a_up;
 952                 if(a_diff != 0)
 953                 {
 954                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 955                         if(f > -1 && f < 1) // can it be attained?
 956                         {
 957                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 958                                 //print("middle\n");
 959                         }
 960                 }
 961                 // OR attained at z = 1:
 962                 f = (a_up + a_add) * (a_up + a_add);
 963                 if(f > best)
 964                 {
 965                         best = f;
 966                         //print("top\n");
 967                 }
 968                 // OR attained at z = -1:
 969                 f = (a_up - a_add) * (a_up - a_add);
 970                 if(f > best)
 971                 {
 972                         best = f;
 973                         //print("bottom\n");
 974                 }
 975                 best = sqrt(best);
 976                 //////////////////////////////////////////////////////////////////////////////////////
 977
 978                 //print("best possible acceleration: ", ftos(best), "\n");
 979
 980                 float fxy, fz;
 981                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / cvar("g_jetpack_maxspeed_side"), 1);
 982                 if(wishvel_z - sv_gravity > 0)
 983                         fz = bound(0, 1 - self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 984                 else
 985                         fz = bound(0, 1 + self.velocity_z / cvar("g_jetpack_maxspeed_up"), 1);
 986
 987                 float fvel;
 988                 fvel = vlen(wishvel);
 989                 wishvel_x *= fxy;
 990                 wishvel_y *= fxy;
 991                 wishvel_z = (wishvel_z - sv_gravity) * fz + sv_gravity;
 992
 993                 fvel = min(1, vlen(wishvel) / best);
 994                 if(cvar("g_jetpack_fuel") && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
 995                         f = min(1, self.ammo_fuel / (cvar("g_jetpack_fuel") * frametime * fvel));
 996                 else
 997                         f = 1;
 998
 999                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1000
1001                 if (f > 0 && wishvel != '0 0 0')
1002                 {
1003                         self.velocity = self.velocity + wishvel * f * frametime;
1004                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1005                                 self.ammo_fuel -= cvar("g_jetpack_fuel") * frametime * fvel * f;
1006                         self.flags &~= FL_ONGROUND;
1007                         self.items |= IT_USING_JETPACK;
1008
1009                         // jetpack also inhibits health regeneration, but only for 1 second
1010                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1011                 }
1012         }
1013         else if (self.flags & FL_ONGROUND)
1014         {
1015                 // we get here if we ran out of ammo
1016                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1017                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1018
1019                 // walking
1020                 makevectors(self.v_angle_y * '0 1 0');
1021                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1022
1023                 if(!(self.lastflags & FL_ONGROUND))
1024                 {
1025                         if(cvar("speedmeter"))
1026                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1027                         if(self.lastground < time - 0.3)
1028                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
1029                         if(self.jumppadcount > 1)
1030                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1031                         self.jumppadcount = 0;
1032                 }
1033
1034 #ifdef LETS_TEST_FTEQCC
1035                 if(self.velocity_x || self.velocity_y)
1036                 {
1037                         // good
1038                 }
1039                 else
1040                 {
1041                         if(self.velocity_x)
1042                                 checkclient();
1043                         if(self.velocity_y)
1044                                 checkclient();
1045                 }
1046 #endif
1047
1048                 v = self.velocity;
1049                 v_z = 0;
1050                 f = vlen(v);
1051                 if(f > 0)
1052                 {
1053                         if (f < sv_stopspeed)
1054                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
1055                         else
1056                                 f = 1 - frametime * sv_friction;
1057                         if (f > 0)
1058                                 self.velocity = self.velocity * f;
1059                         else
1060                                 self.velocity = '0 0 0';
1061                 }
1062
1063                 // acceleration
1064                 wishdir = normalize(wishvel);
1065                 wishspeed = vlen(wishvel);
1066                 if (wishspeed > sv_maxspeed*maxspd_mod)
1067                         wishspeed = sv_maxspeed*maxspd_mod;
1068                 if (self.crouch)
1069                         wishspeed = wishspeed * 0.5;
1070                 if (time >= self.teleport_time)
1071                         PM_Accelerate(wishdir, wishspeed, sv_accelerate*maxspd_mod, 1, 0);
1072         }
1073         else
1074         {
1075                 // we get here if we ran out of ammo
1076                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32))
1077                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1078
1079                 if(maxspd_mod < 1)
1080                 {
1081                         maxairspd = sv_maxairspeed*maxspd_mod;
1082                         airaccel = sv_airaccelerate*maxspd_mod;
1083                 }
1084                 else
1085                 {
1086                         maxairspd = sv_maxairspeed;
1087                         airaccel = sv_airaccelerate;
1088                 }
1089                 // airborn
1090                 makevectors(self.v_angle_y * '0 1 0');
1091                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1092                 // acceleration
1093                 wishdir = normalize(wishvel);
1094                 wishspeed = vlen(wishvel);
1095                 if (wishspeed > maxairspd)
1096                         wishspeed = maxairspd;
1097                 if (self.crouch)
1098                         wishspeed = wishspeed * 0.5;
1099                 if (time >= self.teleport_time)
1100                 {
1101                         float accelerating;
1102                         float wishspeed2;
1103                         float airaccelqw;
1104
1105                         airaccelqw = sv_airaccel_qw;
1106                         accelerating = (self.velocity * wishdir > 0);
1107                         wishspeed2 = wishspeed;
1108
1109                         // CPM
1110                         if(sv_airstopaccelerate)
1111                                 if(self.velocity * wishdir < 0)
1112                                         airaccel = sv_airstopaccelerate*maxspd_mod;
1113                         if(self.movement_x == 0 && self.movement_y != 0)
1114                         {
1115                                 if(sv_maxairstrafespeed)
1116                                 {
1117                                         wishspeed = min(wishspeed, sv_maxairstrafespeed*maxspd_mod);
1118                                         if(sv_maxairstrafespeed < sv_maxairspeed)
1119                                                 airaccelqw = 1;
1120                                 }
1121                                 if(sv_airstrafeaccelerate)
1122                                 {
1123                                         airaccel = sv_airstrafeaccelerate*maxspd_mod;
1124                                         if(sv_airstrafeaccelerate > sv_airaccelerate)
1125                                                 airaccelqw = 1;
1126                                 }
1127                         }
1128                         // !CPM
1129
1130                         if(sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1131                                 PM_AirAccelerate(wishdir, wishspeed);
1132                         else
1133                                 PM_Accelerate(wishdir, wishspeed, airaccel, airaccelqw, sv_airaccel_sideways_friction / maxairspd);
1134
1135                         if(sv_aircontrol)
1136                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1137                 }
1138         }
1139
1140 :end
1141         if(self.flags & FL_ONGROUND)
1142                 self.lastground = time;
1143
1144         self.lastflags = self.flags;
1145         self.lastclassname = self.classname;
1146 };