data/qcsrc/server/cl_impulse.qc

   1 .vector personal_v_angle; // view angles to restore on impulse 77
   2 .vector personal_velocity; // velocity to restore on impulse 77
   3
   4 void CopyBody(float keepvelocity);
   5
   6 // changes by LordHavoc on 03/30/04
   7 // cleaned up dummy code
   8 // dummies are now removed eventually after being gibbed (norespawn = TRUE)
   9 // dummy impulse now checks sv_cheats to prevent players from overwhelming server with dummies
  10 // dummies now use player code where possible
  11
  12 void player_anim (void);
  13 void DummyThink(void)
  14 {
  15         self.think = DummyThink;
  16         self.nextthink = time;
  17         SV_PlayerPhysics();
  18         PlayerPreThink();
  19         //player_anim();
  20         PlayerPostThink();
  21 }
  22
  23 // from dpmod
  24 void printsurfaceinfo(entity e, vector v)
  25 {
  26         local float surfnum, numpoints, vnum;
  27         local string s;
  28         local vector n;
  29         surfnum = getsurfacenearpoint(e, v);
  30         if (surfnum >= 0)
  31         {
  32                 sprint(self, "texture: ");
  33                 s = getsurfacetexture(e, surfnum);
  34                 sprint(self, s);
  35                 sprint(self, " normal: ");
  36                 n = getsurfacenormal(e, surfnum);
  37                 sprint(self, vtos(n));
  38                 sprint(self, " ");
  39                 numpoints = getsurfacenumpoints(e, surfnum);
  40                 sprint(self, ftos(numpoints));
  41                 sprint(self, " verts:");
  42                 vnum = 0;
  43                 while (vnum < numpoints)
  44                 {
  45                         sprint(self, " ");
  46                         n = getsurfacepoint(e, surfnum, vnum);
  47                         sprint(self, vtos(n));
  48                         vnum = vnum + 1;
  49                 }
  50                 sprint(self, " point tested: ");
  51                 sprint(self, vtos(v));
  52                 sprint(self, " nearest point on surface: ");
  53                 n = getsurfaceclippedpoint(e, surfnum, v);
  54                 sprint(self, vtos(n));
  55                 sprint(self, "\n");
  56         }
  57 };
  58
  59 /*
  60  * Impulse map:
  61  *
  62  * 0 reserved (no input)
  63  * 1 to 9, 14: weapon shortcuts
  64  * 10: next weapon according to linear list
  65  * 11: most recently used weapon
  66  * 12: previous weapon according to linear list
  67  * 13: best weapon according to priority list
  68  * 15: next weapon according to priority list
  69  * 16: previous weapon according to priority list
  70  * 17: throw weapon
  71  * 18: next weapon according to sbar_hudselector 1 list
  72  * 19: previous weapon according to sbar_hudselector 1 list
  73  *
  74  * 30 to 39: create waypoints
  75  * 47: clear personal waypoints
  76  * 48: clear team waypoints
  77  * 49: turn base waypoints on/off
  78  *
  79  * 99: loaded
  80  *
  81  * 140: moving clone
  82  * 141: ctf speedrun
  83  * 142: fixed clone
  84  * 143: emergency teleport
  85  * 144: printsurfaceinfo
  86  * 145: distance
  87  *
  88  * TODO:
  89  * 200 to 209: prev weapon shortcuts
  90  * 210 to 219: best weapon shortcuts
  91  * 220 to 229: next weapon shortcuts
  92  * 230 to 253: individual weapons (up to 24)
  93  */
  94
  95 void ImpulseCommands (void)
  96 {
  97         local float imp;
  98         vector start, end, enddown;
  99         float i;
 100         float m;
 101         float good, evil, evilsurf;
 102         float maxattempts;
 103         vector org, delta;
 104         float wep;
 105         entity e;
 106
 107         imp = self.impulse;
 108         if (!imp || gameover)
 109                 return;
 110         self.impulse = 0;
 111
 112         if (timeoutStatus == 2) //don't allow any impulses while the game is paused
 113                 return;
 114
 115         if (imp >= 1 && imp <= 9)
 116         {
 117                 // weapon switching impulses
 118                 if(self.deadflag == DEAD_NO)
 119                         W_NextWeaponOnImpulse(imp);
 120                 else
 121                         self.impulse = imp; // retry in next frame
 122         }
 123         else if(imp >= 10 && imp <= 19)
 124         {
 125                 if(self.deadflag == DEAD_NO)
 126                 {
 127                         switch(imp)
 128                         {
 129                                 case 10:
 130                                         W_NextWeapon (0);
 131                                         break;
 132                                 case 11:
 133                                         W_SwitchWeapon (self.cnt); // previously used
 134                                         break;
 135                                 case 12:
 136                                         W_PreviousWeapon (0);
 137                                         break;
 138                                 case 13:
 139                                         W_SwitchWeapon (w_getbestweapon(self));
 140                                         break;
 141                                 case 14:
 142                                         W_NextWeaponOnImpulse(0);
 143                                         break;
 144                                 case 15:
 145                                         W_NextWeapon (2);
 146                                         break;
 147                                 case 16:
 148                                         W_PreviousWeapon (2);
 149                                         break;
 150                                 case 17:
 151                                         if (!g_minstagib)
 152                                                 W_ThrowWeapon(W_CalculateProjectileVelocity(self.velocity, v_forward * 750), '0 0 0', TRUE);
 153                                         break;
 154                                 case 18:
 155                                         W_NextWeapon (1);
 156                                         break;
 157                                 case 19:
 158                                         W_PreviousWeapon (1);
 159                                         break;
 160                                 }
 161                 }
 162                 else
 163                         self.impulse = imp; // retry in next frame
 164         }
 165         else if(imp >= 200 && imp <= 229)
 166         {
 167                 if(self.deadflag == DEAD_NO)
 168                 {
 169                         // custom order weapon cycling
 170                         i = mod(imp, 10);
 171                         m = (imp - (210 + i)); // <0 for prev, =0 for best, >0 for next
 172                         W_CycleWeapon(self.(cvar_cl_weaponpriorities[i]), m);
 173                 }
 174                 else
 175                         self.impulse = imp; // retry in next frame
 176         }
 177         else if(imp >= 230 && imp <= 253)
 178         {
 179                 if(self.deadflag == DEAD_NO)
 180                         W_SwitchWeapon (imp - 230 + WEP_FIRST);
 181                 else
 182                         self.impulse = imp; // retry in next frame
 183         }
 184         // deploy waypoints
 185         else if (imp >= 30 && imp <= 49)
 186         {
 187                 entity wp;
 188                 switch(imp)
 189                 {
 190                         case 30:
 191                                 wp = WaypointSprite_DeployPersonal("waypoint", self.origin);
 192                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_WAYPOINT, '0 1 1');
 193                                 WaypointSprite_Ping(wp);
 194                                 self.personal_v_angle = self.v_angle;
 195                                 self.personal_velocity = self.velocity;
 196                                 sprint(self, "personal waypoint spawned at location\n");
 197                                 break;
 198                         case 31:
 199                                 wp = WaypointSprite_DeployPersonal("waypoint", self.cursor_trace_endpos);
 200                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_WAYPOINT, '0 1 1');
 201                                 WaypointSprite_Ping(wp);
 202                                 self.personal_v_angle = self.v_angle;
 203                                 self.personal_velocity = '0 0 0';
 204                                 sprint(self, "personal waypoint spawned at crosshair\n");
 205                                 break;
 206                         case 32:
 207                                 if(vlen(self.death_origin))
 208                                 {
 209                                         wp = WaypointSprite_DeployPersonal("waypoint", self.death_origin);
 210                                         WaypointSprite_UpdateTeamRadar(wp, RADARICON_WAYPOINT, '0 1 1');
 211                                         WaypointSprite_Ping(wp);
 212                                         self.personal_v_angle = self.v_angle;
 213                                         self.personal_velocity = '0 0 0';
 214                                         sprint(self, "personal waypoint spawned at death location\n");
 215                                 }
 216                                 break;
 217                         case 33:
 218                                 if(self.deadflag == DEAD_NO && teams_matter)
 219                                 {
 220                                         wp = WaypointSprite_Attach("helpme", TRUE);
 221                                         WaypointSprite_UpdateTeamRadar(wp, RADARICON_HELPME, '1 1 0');
 222                                         WaypointSprite_Ping(wp);
 223                                         sprint(self, "HELP ME attached\n");
 224                                 }
 225                                 break;
 226                         case 34:
 227                                 wp = WaypointSprite_DeployFixed("here", FALSE, self.origin);
 228                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_HERE, '0 1 0');
 229                                 WaypointSprite_Ping(wp);
 230                                 sprint(self, "HERE spawned at location\n");
 231                                 break;
 232                         case 35:
 233                                 wp = WaypointSprite_DeployFixed("here", FALSE, self.cursor_trace_endpos);
 234                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_HERE, '0 1 0');
 235                                 WaypointSprite_Ping(wp);
 236                                 sprint(self, "HERE spawned at crosshair\n");
 237                                 break;
 238                         case 36:
 239                                 if(vlen(self.death_origin))
 240                                 {
 241                                         wp = WaypointSprite_DeployFixed("here", FALSE, self.death_origin);
 242                                         sprint(self, "HERE spawned at death location\n");
 243                                         WaypointSprite_UpdateTeamRadar(wp, RADARICON_HERE, '0 1 0');
 244                                         WaypointSprite_Ping(wp);
 245                                 }
 246                                 break;
 247                         case 37:
 248                                 wp = WaypointSprite_DeployFixed("danger", FALSE, self.origin);
 249                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_DANGER, '1 0.5 0');
 250                                 WaypointSprite_Ping(wp);
 251                                 sprint(self, "DANGER spawned at location\n");
 252                                 break;
 253                         case 38:
 254                                 wp = WaypointSprite_DeployFixed("danger", FALSE, self.cursor_trace_endpos);
 255                                 WaypointSprite_UpdateTeamRadar(wp, RADARICON_DANGER, '1 0.5 0');
 256                                 WaypointSprite_Ping(wp);
 257                                 sprint(self, "DANGER spawned at crosshair\n");
 258                                 break;
 259                         case 39:
 260                                 if(vlen(self.death_origin))
 261                                 {
 262                                         wp = WaypointSprite_DeployFixed("danger", FALSE, self.death_origin);
 263                                         WaypointSprite_UpdateTeamRadar(wp, RADARICON_DANGER, '1 0.5 0');
 264                                         WaypointSprite_Ping(wp);
 265                                         sprint(self, "DANGER spawned at death location\n");
 266                                 }
 267                                 break;
 268                         case 47:
 269                                 WaypointSprite_ClearPersonal();
 270                                 sprint(self, "personal waypoint cleared\n");
 271                                 break;
 272                         case 48:
 273                                 WaypointSprite_ClearOwned();
 274                                 sprint(self, "all waypoints cleared\n");
 275                                 break;
 276                         case 49:
 277                                 self.cvar_cl_hidewaypoints = !(self.cvar_cl_hidewaypoints);
 278                                 sprint(self, "fixed waypoints now ");
 279                                 if(self.cvar_cl_hidewaypoints)
 280                                         sprint(self, "OFF\n");
 281                                 else
 282                                         sprint(self, "ON\n");
 283                                 break;
 284                 }
 285         }
 286         else if(imp >= 140 && imp <= 149 || imp == 99) // 10 cheats ought to be enough for anyone
 287         {
 288                 if(sv_cheats)
 289                 if(self.deadflag == DEAD_NO)
 290                 {
 291                         switch(imp)
 292                         {
 293                                 case 99:
 294                                         self.weapons |= WEPBIT_ALL;
 295                                         self.items |= IT_UNLIMITED_AMMO;
 296                                         self.ammo_shells = g_pickup_shells_max;
 297                                         self.ammo_nails = g_pickup_nails_max;
 298                                         self.ammo_rockets = g_pickup_rockets_max;
 299                                         self.ammo_cells = g_pickup_cells_max;
 300                                         self.health = g_pickup_healthsmall_max;
 301                                         self.armorvalue = g_pickup_armorsmall_max;
 302                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 303                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 304                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 305                                         // precache weapon models/sounds
 306                                         wep = WEP_FIRST;
 307                                         while (wep <= WEP_LAST)
 308                                         {
 309                                                 weapon_action(wep, WR_PRECACHE);
 310                                                 wep = wep + 1;
 311                                         }
 312                                         break;
 313                                 case 140:
 314                                         makevectors (self.v_angle);
 315                                         self.velocity = self.velocity + v_forward * 300;
 316                                         CopyBody(1);
 317                                         self.lip += 1;
 318                                         self.velocity = self.velocity - v_forward * 300;
 319                                         break;
 320                                 case 141:
 321                                         if(self.waypointsprite_deployed_personal)
 322                                         {
 323                                                 self.speedrunning = TRUE;
 324                                                 tracebox(self.waypointsprite_deployed_personal.origin, self.mins, self.maxs, self.waypointsprite_deployed_personal.origin, MOVE_WORLDONLY, self);
 325                                                 if(trace_startsolid)
 326                                                 {
 327                                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 328                                                 }
 329                                                 else
 330                                                 {
 331                                                         // Abort speedrun, teleport back
 332                                                         setorigin(self, self.waypointsprite_deployed_personal.origin);
 333                                                         self.oldvelocity = self.velocity = self.personal_velocity;
 334                                                         self.angles = self.personal_v_angle;
 335                                                         self.fixangle = TRUE;
 336                                                         if(self.flagcarried)
 337                                                         {
 338                                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 339                                                                 ReturnFlag(self.flagcarried);
 340                                                         }
 341                                                 }
 342                                                 self.ammo_rockets = 999;
 343                                                 self.ammo_nails = 999;
 344                                                 self.ammo_cells = 999;
 345                                                 self.ammo_shells = 999;
 346                                                 self.health = start_health;
 347                                                 self.armorvalue = start_armorvalue;
 348                                                 self.weapons |= weaponsInMap;
 349                                                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 350                                                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 351                                                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 352                                         }
 353                                         else if(self.deadflag != DEAD_NO)
 354                                                 sprint(self, "UR DEAD AHAHAH))\n");
 355                                         else
 356                                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 357                                         break;
 358                                 case 142:
 359                                         CopyBody(0);
 360                                         self.lip += 1;
 361                                         break;
 362                                 case 143:
 363                                         good = DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP;
 364                                         evil = DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER;
 365                                         evilsurf = Q3SURFACEFLAG_SKY;
 366
 367                                         m = self.dphitcontentsmask;
 368                                         self.dphitcontentsmask = good | evil;
 369
 370                                         org = world.mins;
 371                                         delta = world.maxs - world.mins;
 372
 373                                         maxattempts = ((sv_cheats >= 2) ? 100000 : 100);
 374
 375                                         for(i = 0; i < maxattempts; ++i)
 376                                         {
 377                                                 start_x = org_x + random() * delta_x;
 378                                                 start_y = org_y + random() * delta_y;
 379                                                 start_z = org_z + random() * delta_z;
 380
 381                                                 // rule 1: start inside world bounds, and outside
 382                                                 // solid, and don't start from somewhere where you can
 383                                                 // fall down to evil
 384                                                 tracebox(start, self.mins, self.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, self);
 385                                                 if(trace_fraction >= 1)
 386                                                         continue;
 387                                                 if(trace_startsolid)
 388                                                         continue;
 389                                                 dprint("hit contents ", ftos(trace_dphitcontents), "\n");
 390                                                 if(trace_dphitcontents & evil)
 391                                                         continue;
 392                                                 if(trace_dphitq3surfaceflags & evilsurf)
 393                                                         continue;
 394
 395                                                 // rule 2: if we are too high, lower the point
 396                                                 if(trace_fraction * delta_z > 1024)
 397                                                         start = trace_endpos + '0 0 1024';
 398                                                 enddown = trace_endpos;
 399
 400                                                 // these can be traceLINES as we already verified the starting box
 401                                                 traceline(start, start + '1 0 0' * delta_x, MOVE_NORMAL, self);
 402                                                 if(trace_fraction >= 1)
 403                                                         continue;
 404                                                 traceline(start, start - '1 0 0' * delta_x, MOVE_NORMAL, self);
 405                                                 if(trace_fraction >= 1)
 406                                                         continue;
 407                                                 traceline(start, start + '0 1 0' * delta_y, MOVE_NORMAL, self);
 408                                                 if(trace_fraction >= 1)
 409                                                         continue;
 410                                                 traceline(start, start - '0 1 0' * delta_y, MOVE_NORMAL, self);
 411                                                 if(trace_fraction >= 1)
 412                                                         continue;
 413                                                 traceline(start, start + '0 0 1' * delta_z, MOVE_NORMAL, self);
 414                                                 if(trace_fraction >= 1)
 415                                                         continue;
 416
 417                                                 end_x = org_x + random() * delta_x;
 418                                                 end_y = org_y + random() * delta_y;
 419                                                 end_z = org_z + random() * delta_z;
 420                                                 end = start + normalize(end - start) * vlen(delta);
 421
 422                                                 // rule 3: start TO end must not be too short
 423                                                 tracebox(start, self.mins, self.maxs, end, MOVE_NORMAL, self);
 424                                                 if(trace_startsolid)
 425                                                         continue;
 426                                                 if(trace_fraction < 256 / vlen(delta))
 427                                                         continue;
 428
 429                                                 // rule 4: don't want to look at sky
 430                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 431                                                         continue;
 432
 433                                                 // rule 5: we must not end up in trigger_hurt
 434                                                 if(tracebox_hits_trigger_hurt(start, self.mins, self.maxs, enddown))
 435                                                 {
 436                                                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
 437                                                         continue;
 438                                                 }
 439
 440                                                 break;
 441                                         }
 442
 443                                         if(i < maxattempts)
 444                                         {
 445                                                 self.origin = start;
 446                                                 self.angles = vectoangles(end - start);
 447                                                 self.angles_x = -self.angles_x;
 448                                                 self.fixangle = TRUE;
 449                                                 self.velocity = '0 0 0';
 450                                                 dprint("Needed ", ftos(i + 1), " attempts\n");
 451                                         }
 452                                         else
 453                                                 sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 454
 455                                         self.dphitcontentsmask = m;
 456                                         break;
 457                                 case 144:
 458                                         makevectors(self.v_angle);
 459                                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * MAX_SHOT_DISTANCE, FALSE, self);
 460                                         if (trace_fraction < 1)
 461                                                 printsurfaceinfo(trace_ent, trace_endpos);
 462                                         break;
 463                                 case 145:
 464                                         makevectors(self.v_angle);
 465                                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 65536, FALSE, self);
 466                                         sprint(self, strcat("distance: ", ftos(fabs(vlen(trace_endpos - (self.origin + self.view_ofs)))), "\n"));
 467                                         break;
 468                         }
 469                 }
 470         }
 471         else if(imp >= 103 && imp <= 106)
 472         {
 473                 if(cvar("g_waypointeditor"))
 474                 {
 475                         switch(imp)
 476                         {
 477                                 case 103:
 478                                         waypoint_schedulerelink(waypoint_spawn(self.origin, self.origin, 0));
 479                                         break;
 480                                 case 104:
 481                                         e = navigation_findnearestwaypoint(self, FALSE);
 482                                         if (e)
 483                                                 waypoint_remove(e);
 484                                         break;
 485                                 case 105:
 486                                         waypoint_schedulerelinkall();
 487                                         break;
 488                                 case 106:
 489                                         waypoint_saveall();
 490                                         break;
 491                         }
 492                 }
 493         }
 494
 495         //TetrisImpulses(imp);
 496 }