data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         Portal_ClearAll(self);
 405
 406         if(self.flagcarried)
 407                 DropFlag(self.flagcarried);
 408
 409         WaypointSprite_PlayerDead();
 410
 411         if(self.killcount != -666)
 412         {
 413                 if(g_lms)
 414                 {
 415                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 416                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 417                         else
 418                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 419                 }
 420                 else
 421                         bprint ("^4", self.netname, "^4 is spectating now\n");
 422         }
 423
 424         PlayerScore_Clear(self); // clear scores when needed
 425
 426         self.spectatortime = time;
 427
 428         self.classname = "observer";
 429         self.health = -666;
 430         self.takedamage = DAMAGE_NO;
 431         self.solid = SOLID_NOT;
 432         self.movetype = MOVETYPE_NOCLIP;
 433         self.flags = FL_CLIENT | FL_NOTARGET;
 434         self.armorvalue = 666;
 435         self.effects = 0;
 436         self.armorvalue = cvar("g_balance_armor_start");
 437         self.pauserotarmor_finished = 0;
 438         self.pauserothealth_finished = 0;
 439         self.pauseregen_finished = 0;
 440         self.damageforcescale = 0;
 441         self.death_time = 0;
 442         self.dead_frame = 0;
 443         self.alpha = 0;
 444         self.scale = 0;
 445         self.fade_time = 0;
 446         self.pain_frame = 0;
 447         self.pain_finished = 0;
 448         self.strength_finished = 0;
 449         self.invincible_finished = 0;
 450         self.pushltime = 0;
 451         self.think = SUB_Null;
 452         self.nextthink = 0;
 453         self.hook_time = 0;
 454         self.runes = 0;
 455         self.deadflag = DEAD_NO;
 456         self.angles = spot.angles;
 457         self.angles_z = 0;
 458         self.fixangle = TRUE;
 459         self.crouch = FALSE;
 460
 461         self.view_ofs = PL_VIEW_OFS;
 462         setorigin (self, spot.origin);
 463         setsize (self, '0 0 0', '0 0 0');
 464         self.oldorigin = self.origin;
 465         self.items = 0;
 466         self.weapons = 0;
 467         self.model = "";
 468         self.modelindex = 0;
 469         self.weapon = 0;
 470         self.weaponmodel = "";
 471         self.weaponentity = world;
 472         self.killcount = -666;
 473         self.velocity = '0 0 0';
 474         self.avelocity = '0 0 0';
 475         self.punchangle = '0 0 0';
 476         self.punchvector = '0 0 0';
 477         self.oldvelocity = self.velocity;
 478         self.customizeentityforclient = Client_customizeentityforclient;
 479         self.wantswelcomemessage = 1;
 480
 481         if(g_arena)
 482         {
 483                 if(self.version_mismatch)
 484                 {
 485                         Spawnqueue_Unmark(self);
 486                         Spawnqueue_Remove(self);
 487                 }
 488                 else
 489                 {
 490                         Spawnqueue_Insert(self);
 491                 }
 492         }
 493         else if(g_lms)
 494         {
 495                 // Only if the player cannot play at all
 496                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 497                         self.frags = -666;
 498                 else
 499                         self.frags = -667;
 500         }
 501         else
 502                 self.frags = -666;
 503 }
 504
 505 float RestrictSkin(float s)
 506 {
 507         if(!teams_matter)
 508                 return s;
 509         if(s == 6)
 510                 return 6;
 511         return mod(s, 3);
 512 }
 513
 514 void FixPlayermodel()
 515 {
 516         local string defaultmodel;
 517         local float defaultskin;
 518         local vector m1, m2;
 519
 520         defaultmodel = "";
 521
 522         if(cvar("sv_defaultcharacter") == 1) {
 523                 defaultskin = 0;
 524
 525                 if(teams_matter)
 526                 {
 527                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 528                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 529                 }
 530
 531                 if(defaultmodel == "")
 532                 {
 533                         defaultmodel = cvar_string("sv_defaultplayermodel");
 534                         defaultskin = cvar("sv_defaultplayerskin");
 535                 }
 536         }
 537
 538         if(defaultmodel != "")
 539         {
 540                 if (defaultmodel != self.model)
 541                 {
 542                         m1 = self.mins;
 543                         m2 = self.maxs;
 544                         setmodel_lod (self, defaultmodel);
 545                         setsize (self, m1, m2);
 546                 }
 547
 548                 self.skin = defaultskin;
 549         } else {
 550                 if (self.playermodel != self.model)
 551                 {
 552                         self.playermodel = CheckPlayerModel(self.playermodel);
 553                         m1 = self.mins;
 554                         m2 = self.maxs;
 555                         setmodel_lod (self, self.playermodel);
 556                         setsize (self, m1, m2);
 557                 }
 558
 559                 self.skin = RestrictSkin(stof(self.playerskin));
 560         }
 561
 562         if(!teams_matter)
 563                 if(strlen(cvar_string("sv_defaultplayercolors")))
 564                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 565                                 setcolor(self, cvar("sv_defaultplayercolors"));
 566 }
 567
 568 /*
 569 =============
 570 PutClientInServer
 571
 572 Called when a client spawns in the server
 573 =============
 574 */
 575 //void() ctf_playerchanged;
 576 void PutClientInServer (void)
 577 {
 578         if(clienttype(self) == CLIENTTYPE_BOT)
 579         {
 580                 self.classname = "player";
 581         }
 582         else if(clienttype(self) == CLIENTTYPE_REAL)
 583         {
 584                 msg_entity = self;
 585                 WriteByte(MSG_ONE, SVC_SETVIEW);
 586                 WriteEntity(MSG_ONE, self);
 587         }
 588
 589         // player is dead and becomes observer
 590         // FIXME fix LMS scoring for new system
 591         if(g_lms)
 592         {
 593                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 594                         self.classname = "observer";
 595         }
 596
 597         if(g_arena)
 598         if(!self.spawned)
 599                 self.classname = "observer";
 600
 601         if(self.classname == "player") {
 602                 entity  spot;
 603
 604                 race_PreSpawn();
 605
 606                 spot = SelectSpawnPoint (FALSE);
 607                 if(!spot)
 608                 {
 609                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 610                         return; // spawn failed
 611                 }
 612
 613                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 614
 615                 self.classname = "player";
 616                 self.iscreature = TRUE;
 617                 self.movetype = MOVETYPE_WALK;
 618                 self.solid = SOLID_SLIDEBOX;
 619                 if(independent_players)
 620                         MAKE_INDEPENDENT_PLAYER(self);
 621                 self.flags = FL_CLIENT;
 622                 self.takedamage = DAMAGE_AIM;
 623                 if(g_minstagib)
 624                         self.effects = EF_FULLBRIGHT;
 625                 else
 626                         self.effects = 0;
 627                 self.air_finished = time + 12;
 628                 self.dmg = 2;
 629
 630                 self.ammo_shells = start_ammo_shells;
 631                 self.ammo_nails = start_ammo_nails;
 632                 self.ammo_rockets = start_ammo_rockets;
 633                 self.ammo_cells = start_ammo_cells;
 634                 self.health = start_health;
 635                 self.armorvalue = start_armorvalue;
 636                 self.items = 0;
 637                 self.weapons = start_weapons;
 638                 self.switchweapon = start_switchweapon;
 639                 self.cnt = start_switchweapon;
 640                 self.weapon = 0;
 641                 self.jump_interval = time;
 642
 643                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 644                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 645                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 646                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 647                 //extend the pause of rotting if client was reset at the beginning of the countdown
 648                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 649                         self.spawnshieldtime += RESTART_COUNTDOWN;
 650                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 651                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 652                         self.pauseregen_finished += RESTART_COUNTDOWN;
 653                 }
 654                 self.damageforcescale = 2;
 655                 self.death_time = 0;
 656                 self.dead_frame = 0;
 657                 self.alpha = 0;
 658                 self.scale = 0;
 659                 self.fade_time = 0;
 660                 self.pain_frame = 0;
 661                 self.pain_finished = 0;
 662                 self.strength_finished = 0;
 663                 self.invincible_finished = 0;
 664                 self.pushltime = 0;
 665                 //self.speed_finished = 0;
 666                 //self.slowmo_finished = 0;
 667                 // players have no think function
 668                 self.think = SUB_Null;
 669                 self.nextthink = 0;
 670                 self.hook_time = 0;
 671
 672                 self.runes = 0;
 673
 674                 self.deadflag = DEAD_NO;
 675
 676                 self.angles = spot.angles;
 677
 678                 self.angles_z = 0; // never spawn tilted even if the spot says to
 679                 self.fixangle = TRUE; // turn this way immediately
 680                 self.velocity = '0 0 0';
 681                 self.avelocity = '0 0 0';
 682                 self.punchangle = '0 0 0';
 683                 self.punchvector = '0 0 0';
 684                 self.oldvelocity = self.velocity;
 685
 686                 msg_entity = self;
 687                 WRITESPECTATABLE_MSG_ONE({
 688                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 689                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 690                 });
 691
 692                 self.customizeentityforclient = Client_customizeentityforclient;
 693
 694                 self.model = "";
 695                 FixPlayermodel();
 696
 697                 self.crouch = FALSE;
 698                 self.view_ofs = PL_VIEW_OFS;
 699                 setsize (self, PL_MIN, PL_MAX);
 700                 self.spawnorigin = spot.origin;
 701                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 702                 // don't reset back to last position, even if new position is stuck in solid
 703                 self.oldorigin = self.origin;
 704
 705                 if(g_arena)
 706                 {
 707                         Spawnqueue_Remove(self);
 708                         Spawnqueue_Mark(self);
 709                 }
 710
 711                 self.event_damage = PlayerDamage;
 712
 713                 self.bot_attack = TRUE;
 714
 715                 self.statdraintime = time + 5;
 716                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 717
 718                 if(self.killcount == -666) {
 719                         PlayerScore_Clear(self);
 720                         self.killcount = 0;
 721                         self.frags = 0;
 722                 }
 723
 724                 self.cnt = WEP_LASER;
 725                 self.nixnex_lastchange_id = -1;
 726
 727                 CL_SpawnWeaponentity();
 728                 self.alpha = default_player_alpha;
 729                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 730                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 731
 732                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 733                 self.lms_traveled_distance = 0;
 734                 self.speedrunning = FALSE;
 735
 736                 race_PostSpawn(spot);
 737
 738                 if(cvar("spawn_debug"))
 739                 {
 740                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 741                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 742                 }
 743
 744                 //stuffcmd(self, "chase_active 0");
 745                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 746
 747                 if (cvar("g_spawnsound"))
 748                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 749
 750                 if(g_assault) {
 751                         if(self.team == assault_attacker_team)
 752                                 centerprint(self, "You are attacking!\n");
 753                         else
 754                                 centerprint(self, "You are defending!\n");
 755                 }
 756
 757         } else if(self.classname == "observer") {
 758                 PutObserverInServer ();
 759         }
 760
 761         //if(g_ctf)
 762         //      ctf_playerchanged();
 763 }
 764
 765 /*
 766 =============
 767 SendCSQCInfo
 768
 769 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 770 =============
 771 */
 772 void SendCSQCInfo(void)
 773 {
 774         if(clienttype(self) != CLIENTTYPE_REAL)
 775                 return;
 776         msg_entity = self;
 777         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 778         WriteByte(MSG_ONE, TE_CSQC_INIT);
 779         WriteShort(MSG_ONE, CSQC_REVISION);
 780         WriteByte(MSG_ONE, maxclients);
 781         WriteByte(MSG_ONE, g_minstagib);
 782 }
 783
 784 /*
 785 =============
 786 SetNewParms
 787 =============
 788 */
 789 void SetNewParms (void)
 790 {
 791         // initialize parms for a new player
 792         parm1 = -(86400 * 366);
 793 }
 794
 795 /*
 796 =============
 797 SetChangeParms
 798 =============
 799 */
 800 void SetChangeParms (void)
 801 {
 802         // save parms for level change
 803         parm1 = self.parm_idlesince - time;
 804 }
 805
 806 /*
 807 =============
 808 DecodeLevelParms
 809 =============
 810 */
 811 void DecodeLevelParms (void)
 812 {
 813         // load parms
 814         self.parm_idlesince = parm1;
 815         if(self.parm_idlesince == -(86400 * 366))
 816                 self.parm_idlesince = time;
 817 }
 818
 819 /*
 820 =============
 821 ClientKill
 822
 823 Called when a client types 'kill' in the console
 824 =============
 825 */
 826
 827 void ClientKill_Now_TeamChange()
 828 {
 829         if(self.killindicator_teamchange == -1)
 830         {
 831                 self.team = -1;
 832                 JoinBestTeam( self, FALSE, FALSE );
 833         }
 834         else
 835         {
 836                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 837         }
 838 }
 839
 840 void ClientKill_Now()
 841 {
 842         if(self.killindicator_teamchange)
 843                 ClientKill_Now_TeamChange();
 844
 845         // in any case:
 846         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 847
 848         if(self.killindicator)
 849         {
 850                 dprint("Cleaned up after a leaked kill indicator.\n");
 851                 remove(self.killindicator);
 852                 self.killindicator = world;
 853         }
 854 }
 855 void KillIndicator_Think()
 856 {
 857         if (!self.owner.modelindex)
 858         {
 859                 self.owner.killindicator = world;
 860                 remove(self);
 861                 return;
 862         }
 863
 864         if(self.cnt <= 0)
 865         {
 866                 self = self.owner;
 867                 ClientKill_Now(); // no oldself needed
 868                 return;
 869         }
 870         else
 871         {
 872                 if(self.cnt <= 10)
 873                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 874                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 875                 {
 876                         if(self.cnt <= 10)
 877                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 878                         if(self.owner.killindicator_teamchange)
 879                         {
 880                                 if(self.owner.killindicator_teamchange == -1)
 881                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 882                                 else
 883                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 884                         }
 885                         else
 886                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 887                 }
 888                 self.nextthink = time + 1;
 889                 self.cnt -= 1;
 890         }
 891 }
 892
 893 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 894 {
 895         float killtime;
 896         entity e;
 897         killtime = cvar("g_balance_kill_delay");
 898
 899         self.killindicator_teamchange = targetteam;
 900
 901         if(!self.killindicator)
 902         {
 903                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 904                 {
 905                         ClientKill_Now();
 906                 }
 907                 else
 908                 {
 909                         self.killindicator = spawn();
 910                         self.killindicator.owner = self;
 911                         self.killindicator.scale = 0.5;
 912                         setattachment(self.killindicator, self, "");
 913                         setorigin(self.killindicator, '0 0 52');
 914                         self.killindicator.think = KillIndicator_Think;
 915                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 916                         self.killindicator.cnt = ceil(killtime);
 917                         self.killindicator.count = bound(0, ceil(killtime), 10);
 918                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 919
 920                         for(e = world; (e = find(e, classname, "body")) != world; )
 921                         {
 922                                 if(e.enemy != self)
 923                                         continue;
 924                                 e.killindicator = spawn();
 925                                 e.killindicator.owner = e;
 926                                 e.killindicator.scale = 0.5;
 927                                 setattachment(e.killindicator, e, "");
 928                                 setorigin(e.killindicator, '0 0 52');
 929                                 e.killindicator.think = KillIndicator_Think;
 930                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 931                                 e.killindicator.cnt = ceil(killtime);
 932                         }
 933                         self.lip = 0;
 934                 }
 935         }
 936         if(self.killindicator)
 937         {
 938                 if(targetteam)
 939                         self.killindicator.colormod = TeamColor(targetteam);
 940                 else
 941                         self.killindicator.colormod = '0 0 0';
 942         }
 943 }
 944
 945 void ClientKill (void)
 946 {
 947         ClientKill_TeamChange(0);
 948 }
 949
 950 void DoTeamChange(float destteam)
 951 {
 952         float t, c0;
 953         if(!cvar("teamplay"))
 954         {
 955                 if(destteam >= 0)
 956                         SetPlayerColors(self, destteam);
 957                 return;
 958         }
 959         if(self.classname == "player")
 960         if(destteam == -1)
 961         {
 962                 CheckAllowedTeams(self);
 963                 t = FindSmallestTeam(self, TRUE);
 964                 switch(self.team)
 965                 {
 966                         case COLOR_TEAM1: c0 = c1; break;
 967                         case COLOR_TEAM2: c0 = c2; break;
 968                         case COLOR_TEAM3: c0 = c3; break;
 969                         case COLOR_TEAM4: c0 = c4; break;
 970                         default:          c0 = 999;
 971                 }
 972                 switch(t)
 973                 {
 974                         case 1:
 975                                 if(c0 > c1)
 976                                         destteam = COLOR_TEAM1;
 977                                 break;
 978                         case 2:
 979                                 if(c0 > c2)
 980                                         destteam = COLOR_TEAM2;
 981                                 break;
 982                         case 3:
 983                                 if(c0 > c3)
 984                                         destteam = COLOR_TEAM3;
 985                                 break;
 986                         case 4:
 987                                 if(c0 > c4)
 988                                         destteam = COLOR_TEAM4;
 989                                 break;
 990                 }
 991                 if(destteam == -1)
 992                         return;
 993         }
 994         if(destteam == self.team && !self.killindicator)
 995                 return;
 996         ClientKill_TeamChange(destteam);
 997 }
 998
 999 void FixClientCvars(entity e)
1000 {
1001         // send prediction settings to the client
1002         stuffcmd(e, "\nin_bindmap 0 0\n");
1003         /*
1004          * we no longer need to stuff this. Remove this comment block if you feel
1005          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1006         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1008         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1009         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1010         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1011         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1012         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1013         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1014         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1015         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1016         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1017         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1018         stuffcmd(e, "cl_movement_edgefriction 1\n");
1019          */
1020 }
1021
1022 /*
1023 =============
1024 ClientConnect
1025
1026 Called when a client connects to the server
1027 =============
1028 */
1029 //void ctf_clientconnect();
1030 string ColoredTeamName(float t);
1031 void DecodeLevelParms (void);
1032 //void dom_player_join_team(entity pl);
1033 void ClientConnect (void)
1034 {
1035         local string s;
1036
1037         if(self.flags & FL_CLIENT)
1038         {
1039                 print("Warning: ClientConnect, but already connected!\n");
1040                 return;
1041         }
1042
1043         if(Ban_IsClientBanned(self))
1044         {
1045                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1046                 dropclient(self);
1047                 bprint(s);
1048                 return;
1049         }
1050
1051         DecodeLevelParms();
1052
1053         self.classname = "player_joining";
1054
1055         self.flags = self.flags | FL_CLIENT;
1056         self.version_nagtime = time + 10 + random() * 10;
1057
1058         if(player_count<0)
1059         {
1060                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1061                 player_count = 0;
1062         }
1063
1064         PlayerScore_Attach(self);
1065
1066         bot_clientconnect();
1067
1068         race_PreSpawnObserver();
1069
1070         //if(g_domination)
1071         //      dom_player_join_team(self);
1072
1073         //JoinBestTeam(self, FALSE, FALSE);
1074
1075         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1076                 self.classname = "observer";
1077         } else {
1078                 self.classname = "player";
1079                 campaign_bots_may_start = 1;
1080         }
1081
1082         self.playerid = (playerid_last = playerid_last + 1);
1083         if(cvar("sv_eventlog"))
1084         {
1085                 if(clienttype(self) == CLIENTTYPE_REAL)
1086                         s = "player";
1087                 else
1088                         s = "bot";
1089                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname));
1090                 s = strcat(":team:", ftos(self.playerid), ":");
1091                 s = strcat(s, ftos(self.team));
1092                 GameLogEcho(s);
1093         }
1094         self.netname_previous = strzone(self.netname);
1095
1096         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1097
1098         bprint ("^4",self.netname);
1099         bprint ("^4 connected");
1100
1101         if(g_domination || g_ctf)
1102         {
1103                 bprint(" and joined the ");
1104                 bprint(ColoredTeamName(self.team));
1105         }
1106
1107         bprint("\n");
1108
1109         self.welcomemessage_time = 0;
1110
1111         stuffcmd(self, strcat(clientstuff, "\n"));
1112         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1113         stuffcmd(self, "cl_particles_reloadeffects\n");
1114
1115         FixClientCvars(self);
1116
1117         // spawnfunc_waypoint sprites
1118         WaypointSprite_InitClient(self);
1119
1120         // Wazat's grappling hook
1121         SetGrappleHookBindings();
1122
1123         // get autoswitch state from player when he toggles it
1124         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1125
1126         // get version info from player
1127         stuffcmd(self, "cmd clientversion $gameversion\n");
1128
1129         // get other cvars from player
1130         GetCvars(0);
1131
1132         // set cvar for team scoreboard
1133         if (teams_matter)
1134         {
1135                 local float t;
1136                 t = cvar("teamplay");
1137                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1138                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1139         }
1140         else
1141                 stuffcmd(self, "set teamplay 0\n");
1142
1143         // notify about available teams
1144         if(teamplay)
1145         {
1146                 CheckAllowedTeams(self);
1147                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1148                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1149         }
1150         else
1151                 stuffcmd(self, "set _teams_available 0\n");
1152
1153         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1154
1155         if(g_arena)
1156         {
1157                 self.classname = "observer";
1158                 Spawnqueue_Insert(self);
1159         }
1160         /*else if(g_ctf)
1161         {
1162                 ctf_clientconnect();
1163         }*/
1164
1165         if(entcs_start)
1166                 attach_entcs();
1167
1168         bot_relinkplayerlist();
1169
1170         self.spectatortime = time;
1171         if(blockSpectators)
1172         {
1173                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1174         }
1175
1176         self.jointime = time;
1177         self.allowedTimeouts = cvar("sv_timeout_number");
1178
1179         if(clienttype(self) == CLIENTTYPE_REAL)
1180         {
1181                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1182                 SendCSQCInfo();
1183                 msg_entity = self;
1184                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1185                 {
1186                         MapVote_SendData(MSG_ONE);
1187                         MapVote_UpdateData(MSG_ONE);
1188                 }
1189                 ScoreInfo_Write(MSG_ONE);
1190         }
1191
1192         if(g_lms)
1193         {
1194                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1195                 {
1196                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1197                         self.frags = -666; // FIXME do we still need this?
1198                 }
1199         }
1200 }
1201
1202 /*
1203 =============
1204 ClientDisconnect
1205
1206 Called when a client disconnects from the server
1207 =============
1208 */
1209 void(entity e) DropFlag;
1210 .entity chatbubbleentity;
1211 .entity teambubbleentity;
1212 void ReadyCount();
1213 //void() ctf_clientdisconnect;
1214 void ClientDisconnect (void)
1215 {
1216         float save;
1217
1218         if not(self.flags & FL_CLIENT)
1219         {
1220                 print("Warning: ClientDisconnect without ClientConnect\n");
1221                 return;
1222         }
1223
1224         bot_clientdisconnect();
1225
1226         if(entcs_start)
1227                 detach_entcs();
1228
1229         if(cvar("sv_eventlog"))
1230                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1231         bprint ("^4",self.netname);
1232         bprint ("^4 disconnected\n");
1233
1234         if (self.chatbubbleentity)
1235         {
1236                 remove (self.chatbubbleentity);
1237                 self.chatbubbleentity = world;
1238         }
1239
1240         if (self.teambubbleentity)
1241         {
1242                 remove (self.teambubbleentity);
1243                 self.teambubbleentity = world;
1244         }
1245
1246         if (self.killindicator)
1247         {
1248                 remove (self.killindicator);
1249                 self.killindicator = world;
1250         }
1251
1252         WaypointSprite_PlayerGone();
1253
1254         DropAllRunes(self);
1255         kh_Key_DropAll(self, TRUE);
1256
1257         Portal_ClearAll(self);
1258
1259         if(self.flagcarried)
1260                 DropFlag(self.flagcarried);
1261
1262         save = self.flags;
1263         self.flags = self.flags - (self.flags & FL_CLIENT);
1264         bot_relinkplayerlist();
1265         self.flags = save;
1266
1267         // remove laserdot
1268         if(self.weaponentity)
1269                 if(self.weaponentity.lasertarget)
1270                         remove(self.weaponentity.lasertarget);
1271
1272         if(g_arena)
1273         {
1274                 Spawnqueue_Unmark(self);
1275                 Spawnqueue_Remove(self);
1276         }
1277         /*if(g_ctf)
1278         {
1279                 ctf_clientdisconnect();
1280         }
1281         */
1282
1283         PlayerScore_Detach(self);
1284
1285         if(self.netname_previous)
1286                 strunzone(self.netname_previous);
1287
1288         ClearPlayerSounds();
1289
1290         // free cvars
1291         GetCvars(-1);
1292         self.playerid = 0;
1293
1294         ReadyCount();
1295 }
1296
1297 .float BUTTON_CHAT;
1298 void ChatBubbleThink()
1299 {
1300         self.nextthink = time;
1301         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1302         {
1303                 self.owner.chatbubbleentity = world;
1304                 remove(self);
1305                 return;
1306         }
1307         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1308         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1309                 self.model = self.mdl;
1310         else
1311                 self.model = "";
1312 };
1313
1314 void UpdateChatBubble()
1315 {
1316         if (!self.modelindex)
1317                 return;
1318         // spawn a chatbubble entity if needed
1319         if (!self.chatbubbleentity)
1320         {
1321                 self.chatbubbleentity = spawn();
1322                 self.chatbubbleentity.owner = self;
1323                 self.chatbubbleentity.exteriormodeltoclient = self;
1324                 self.chatbubbleentity.think = ChatBubbleThink;
1325                 self.chatbubbleentity.nextthink = time;
1326                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1327                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1328                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1329                 self.chatbubbleentity.model = "";
1330                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1331         }
1332 }
1333
1334
1335 void TeamBubbleThink()
1336 {
1337         self.nextthink = time;
1338         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1339         {
1340                 self.owner.teambubbleentity = world;
1341                 remove(self);
1342                 return;
1343         }
1344 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1345         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1346                 self.model = "";
1347         else
1348                 self.model = self.mdl;
1349
1350 };
1351
1352 float TeamBubble_customizeentityforclient()
1353 {
1354         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1355 }
1356
1357 void UpdateTeamBubble()
1358 {
1359         if (!self.modelindex || !cvar("teamplay"))
1360                 return;
1361         // spawn a teambubble entity if needed
1362         if (!self.teambubbleentity && cvar("teamplay"))
1363         {
1364                 self.teambubbleentity = spawn();
1365                 self.teambubbleentity.owner = self;
1366                 self.teambubbleentity.exteriormodeltoclient = self;
1367                 self.teambubbleentity.think = TeamBubbleThink;
1368                 self.teambubbleentity.nextthink = time;
1369                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1370 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1371                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1372                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1373                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1374                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1375                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1376                 self.teambubbleentity.effects = EF_LOWPRECISION;
1377         }
1378 }
1379
1380 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1381 // added to the model skins
1382 /*void UpdateColorModHack()
1383 {
1384         local float c;
1385         c = self.clientcolors & 15;
1386         // LordHavoc: only bothering to support white, green, red, yellow, blue
1387              if (teamplay == 0) self.colormod = '0 0 0';
1388         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1389         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1390         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1391         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1392         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1393         else self.colormod = '1 1 1';
1394 };*/
1395
1396 void respawn(void)
1397 {
1398         CopyBody(1);
1399         self.effects |= EF_NODRAW; // prevent another CopyBody
1400         PutClientInServer();
1401 }
1402
1403 /**
1404  * When sv_timeout is used this function returs strings like
1405  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1406  * Called by centerprint functions
1407  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1408  */
1409 string getTimeoutText(float addOneSecond) {
1410         if (!cvar("sv_timeout") || !timeoutStatus)
1411                 return "";
1412
1413         local string retStr;
1414         if (timeoutStatus == 1) {
1415                 if (addOneSecond == 1) {
1416                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1417                 }
1418                 else {
1419                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1420                 }
1421                 return retStr;
1422         }
1423         else if (timeoutStatus == 2) {
1424                 if (addOneSecond) {
1425                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1426                         //don't show messages like "Timeout ends in 0 seconds"...
1427                         if ((remainingTimeoutTime + 1) > 0)
1428                                 return retStr;
1429                         else
1430                                 return "";
1431                 }
1432                 else {
1433                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1434                         //don't show messages like "Timeout ends in 0 seconds"...
1435                         if (remainingTimeoutTime > 0)
1436                                 return retStr;
1437                         else
1438                                 return "";
1439                 }
1440         }
1441         else return "";
1442 }
1443
1444 void player_powerups (void)
1445 {
1446         if (g_minstagib)
1447         {
1448                 if (self.items & IT_STRENGTH)
1449                 {
1450                         if (time > self.strength_finished)
1451                         {
1452                                 if (g_minstagib_invis_alpha > 0)
1453                                 {
1454                                         self.alpha = default_player_alpha;
1455                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1456                                         self.effects = self.effects | EF_FULLBRIGHT;
1457                                 }
1458                                 else
1459                                 {
1460                                         self.effects -= self.effects & EF_NODRAW;
1461                                 }
1462                                 self.items = self.items - (self.items & IT_STRENGTH);
1463                                 sprint(self, "^3Invisibility has worn off\n");
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < self.strength_finished)
1469                         {
1470                                 if (g_minstagib_invis_alpha > 0)
1471                                 {
1472                                         self.alpha = g_minstagib_invis_alpha;
1473                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1474                                         self.effects -= self.effects & EF_FULLBRIGHT;
1475                                 }
1476                                 else
1477                                 {
1478                                         self.effects = self.effects | EF_NODRAW;
1479                                 }
1480                                 self.items = self.items | IT_STRENGTH;
1481                                 sprint(self, "^3You are invisible\n");
1482                         }
1483                 }
1484
1485                 if (self.items & IT_INVINCIBLE)
1486                 {
1487                         if (time > self.invincible_finished)
1488                         {
1489                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1490                                 sprint(self, "^3Speed has worn off\n");
1491                         }
1492                 }
1493                 else
1494                 {
1495                         if (time < self.invincible_finished)
1496                         {
1497                                 self.items = self.items | IT_INVINCIBLE;
1498                                 sprint(self, "^3You are on speed\n");
1499                         }
1500                 }
1501                 return;
1502         }
1503
1504         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1505         if (self.items & IT_STRENGTH)
1506         {
1507                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1508                 if (time > self.strength_finished)
1509                 {
1510                         self.items = self.items - (self.items & IT_STRENGTH);
1511                         sprint(self, "^3Strength has worn off\n");
1512                 }
1513         }
1514         else
1515         {
1516                 if (time < self.strength_finished)
1517                 {
1518                         self.items = self.items | IT_STRENGTH;
1519                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1520                 }
1521         }
1522         if (self.items & IT_INVINCIBLE)
1523         {
1524                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1525                 if (time > self.invincible_finished)
1526                 {
1527                         self.items = self.items - (self.items & IT_INVINCIBLE);
1528                         sprint(self, "^3Shield has worn off\n");
1529                 }
1530         }
1531         else
1532         {
1533                 if (time < self.invincible_finished)
1534                 {
1535                         self.items = self.items | IT_INVINCIBLE;
1536                         sprint(self, "^3Shield surrounds you\n");
1537                 }
1538         }
1539
1540         if (cvar("g_fullbrightplayers"))
1541                 self.effects = self.effects | EF_FULLBRIGHT;
1542
1543         // midair gamemode: damage only while in the air
1544         // if in midair mode, being on ground grants temporary invulnerability
1545         // (this is so that multishot weapon don't clear the ground flag on the
1546         // first damage in the frame, leaving the player vulnerable to the
1547         // remaining hits in the same frame)
1548         if (self.flags & FL_ONGROUND)
1549         if (g_midair)
1550                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1551
1552         if (time > restart_countdown)
1553         if (time < self.spawnshieldtime)
1554                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1555 }
1556
1557 float CalcRegen(float current, float stable, float regenfactor)
1558 {
1559         if(current > stable)
1560                 return current;
1561         else if(current > stable - 0.25) // when close enough, "snap"
1562                 return stable;
1563         else
1564                 return min(stable, current + (stable - current) * regenfactor * frametime);
1565 }
1566
1567 void player_regen (void)
1568 {
1569         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1570         maxh = cvar("g_balance_health_stable");
1571         maxa = cvar("g_balance_armor_stable");
1572         limith = cvar("g_balance_health_limit");
1573         limita = cvar("g_balance_armor_limit");
1574
1575         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1576                 return;
1577
1578         max_mod = regen_mod = rot_mod = limit_mod = 1;
1579
1580         if (self.runes & RUNE_REGEN)
1581         {
1582                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1583                 {
1584                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1585                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1586                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1587                 }
1588                 else
1589                 {
1590                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1591                         max_mod = cvar("g_balance_rune_regen_hpmod");
1592                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1593                 }
1594         }
1595         else if (self.runes & CURSE_VENOM)
1596         {
1597                 max_mod = cvar("g_balance_curse_venom_hpmod");
1598                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1599                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1600                 else
1601                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1602                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1603                 //if (!self.runes & RUNE_REGEN)
1604                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1605         }
1606         maxh = maxh * max_mod;
1607         //maxa = maxa * max_mod;
1608         limith = limith * limit_mod;
1609         limita = limita * limit_mod;
1610
1611         if (self.armorvalue > maxa)
1612         {
1613                 if (time > self.pauserotarmor_finished)
1614                 {
1615                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1616                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1617                 }
1618         }
1619         else if (self.armorvalue < maxa)
1620         {
1621                 if (time > self.pauseregen_finished)
1622                 {
1623                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1624                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1625                 }
1626         }
1627         if (self.health > maxh)
1628         {
1629                 if (time > self.pauserothealth_finished)
1630                 {
1631                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1632                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1633                 }
1634         }
1635         else if (self.health < maxh)
1636         {
1637                 if (time > self.pauseregen_finished)
1638                 {
1639                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1640                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1641                 }
1642         }
1643
1644         if (self.health > limith)
1645                 self.health = limith;
1646         if (self.armorvalue > limita)
1647                 self.armorvalue = limita;
1648
1649         // if player rotted to death...  die!
1650         if(self.health < 1)
1651                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1652 }
1653
1654 .float zoomstate;
1655 float zoomstate_set;
1656 void SetZoomState(float z)
1657 {
1658         if(z != self.zoomstate)
1659         {
1660                 msg_entity = self;
1661                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1662                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1663                 WriteByte(MSG_ONE, z);
1664                 self.zoomstate = z;
1665         }
1666         zoomstate_set = 1;
1667 }
1668
1669 /*
1670 ======================
1671 spectate mode routines
1672 ======================
1673 */
1674 void SpectateCopy(entity spectatee) {
1675         self.armortype = spectatee.armortype;
1676         self.armorvalue = spectatee.armorvalue;
1677         self.currentammo = spectatee.currentammo;
1678         self.effects = spectatee.effects;
1679         self.health = spectatee.health;
1680         self.impulse = 0;
1681         self.items = spectatee.items;
1682         self.weapons = spectatee.weapons;
1683         self.punchangle = spectatee.punchangle;
1684         self.view_ofs = spectatee.view_ofs;
1685         self.v_angle = spectatee.v_angle;
1686         self.velocity = spectatee.velocity;
1687         self.dmg_take = spectatee.dmg_take;
1688         self.dmg_save = spectatee.dmg_save;
1689         self.dmg_inflictor = spectatee.dmg_inflictor;
1690         self.angles = spectatee.v_angle;
1691         self.fixangle = TRUE;
1692         setorigin(self, spectatee.origin);
1693         setsize(self, spectatee.mins, spectatee.maxs);
1694         SetZoomState(spectatee.zoomstate);
1695 }
1696
1697 float SpectateUpdate() {
1698         if(!self.enemy)
1699                 return 0;
1700
1701         if (self == self.enemy)
1702                 return 0;
1703
1704         if(self.enemy.flags & FL_NOTARGET)
1705                 return 0;
1706
1707         SpectateCopy(self.enemy);
1708
1709         return 1;
1710 }
1711
1712 float SpectateNext() {
1713         other = find(self.enemy, classname, "player");
1714         if (!other) {
1715                 other = find(other, classname, "player");
1716         }
1717         if (other) {
1718                 self.enemy = other;
1719         }
1720         if(self.enemy.classname == "player") {
1721                 msg_entity = self;
1722                 WriteByte(MSG_ONE, SVC_SETVIEW);
1723                 WriteEntity(MSG_ONE, self.enemy);
1724                 self.wantswelcomemessage = 1;
1725                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1726                 if(!SpectateUpdate())
1727                         PutObserverInServer();
1728                 return 1;
1729         } else {
1730                 return 0;
1731         }
1732 }
1733
1734 /*
1735 =============
1736 ShowRespawnCountdown()
1737
1738 Update a respawn countdown display.
1739 =============
1740 */
1741 void ShowRespawnCountdown()
1742 {
1743         float number;
1744         if(self.deadflag == DEAD_NO) // just respawned?
1745                 return;
1746         else
1747         {
1748                 number = ceil(self.death_time - time);
1749                 if(number <= 0)
1750                         return;
1751                 if(number <= self.respawn_countdown)
1752                 {
1753                         self.respawn_countdown = number - 1;
1754                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1755                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1756                 }
1757         }
1758 }
1759
1760 void LeaveSpectatorMode()
1761 {
1762         if(isJoinAllowed()) {
1763                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1764                         self.classname = "player";
1765                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1766                                 JoinBestTeam(self, FALSE, TRUE);
1767                         if(cvar("g_campaign"))
1768                                 campaign_bots_may_start = 1;
1769                         PutClientInServer();
1770                         if(!(self.flags & FL_NOTARGET))
1771                                 bprint ("^4", self.netname, "^4 is playing now\n");
1772                         centerprint(self,"");
1773                         return;
1774                 } else {
1775                         stuffcmd(self,"menu_showteamselect\n");
1776                         return;
1777                 }
1778         }
1779         else {
1780                 //player may not join because of g_maxplayers is set
1781                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1782         }
1783 }
1784
1785 /**
1786  * Determines whether the player is allowed to join. This depends on cvar
1787  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1788  * it checks whether the number of currently playing players exceeds g_maxplayers.
1789  * @return bool TRUE if the player is allowed to join, false otherwise
1790  */
1791 float isJoinAllowed() {
1792         if (!cvar("g_maxplayers"))
1793                 return TRUE;
1794
1795         local entity e;
1796         local float currentlyPlaying;
1797         FOR_EACH_REALPLAYER(e) {
1798                 if(e.classname == "player")
1799                         currentlyPlaying += 1;
1800         }
1801         if(currentlyPlaying < cvar("g_maxplayers"))
1802                 return TRUE;
1803
1804         return FALSE;
1805 }
1806
1807 /**
1808  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1809  * g_maxplayers_spectator_blocktime seconds
1810  */
1811 void checkSpectatorBlock() {
1812         if(self.classname == "spectator" || self.classname == "observer") {
1813                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1814                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1815                         dropclient(self);
1816                 }
1817         }
1818 }
1819
1820 float vercmp_recursive(string v1, string v2)
1821 {
1822         float dot1, dot2;
1823         string s1, s2;
1824         float r;
1825
1826         dot1 = strstrofs(v1, ".", 0);
1827         dot2 = strstrofs(v2, ".", 0);
1828         if(dot1 == -1)
1829                 s1 = v1;
1830         else
1831                 s1 = substring(v1, 0, dot1);
1832         if(dot2 == -1)
1833                 s2 = v2;
1834         else
1835                 s2 = substring(v2, 0, dot2);
1836
1837         r = stof(s1) - stof(s2);
1838         if(r != 0)
1839                 return r;
1840
1841         r = strcasecmp(s1, s2);
1842         if(r != 0)
1843                 return r;
1844
1845         if(dot1 == -1)
1846                 if(dot2 == -1)
1847                         return 0;
1848                 else
1849                         return -1;
1850         else
1851                 if(dot2 == -1)
1852                         return 1;
1853                 else
1854                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1855 }
1856
1857 float vercmp(string v1, string v2)
1858 {
1859         if(strcasecmp(v1, v2) == 0) // early out check
1860                 return 0;
1861         return vercmp_recursive(v1, v2);
1862 }
1863
1864 void ObserverThink()
1865 {
1866         if (self.flags & FL_JUMPRELEASED) {
1867                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1868                         self.welcomemessage_time = 0;
1869                         self.flags = self.flags - FL_JUMPRELEASED;
1870                         LeaveSpectatorMode();
1871                         return;
1872                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1873                         self.welcomemessage_time = 0;
1874                         self.flags = self.flags - FL_JUMPRELEASED;
1875                         if(SpectateNext() == 1) {
1876                                 self.classname = "spectator";
1877                         }
1878                 }
1879         } else {
1880                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1881                         self.flags = self.flags | FL_JUMPRELEASED;
1882                 }
1883         }
1884         if(self.BUTTON_ZOOM)
1885                 self.wantswelcomemessage = 0;
1886         if(self.wantswelcomemessage)
1887                 PrintWelcomeMessage(self);
1888 }
1889
1890 void SpectatorThink()
1891 {
1892         if (self.flags & FL_JUMPRELEASED) {
1893                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1894                         self.welcomemessage_time = 0;
1895                         self.flags = self.flags - FL_JUMPRELEASED;
1896                         LeaveSpectatorMode();
1897                         return;
1898                 } else if(self.BUTTON_ATCK) {
1899                         self.welcomemessage_time = 0;
1900                         self.flags = self.flags - FL_JUMPRELEASED;
1901                         if(SpectateNext() == 1) {
1902                                 self.classname = "spectator";
1903                         } else {
1904                                 self.classname = "observer";
1905                                 PutClientInServer();
1906                         }
1907                 } else if (self.BUTTON_ATCK2) {
1908                         self.welcomemessage_time = 0;
1909                         self.flags = self.flags - FL_JUMPRELEASED;
1910                         self.classname = "observer";
1911                         PutClientInServer();
1912                 } else {
1913                         if(!SpectateUpdate())
1914                                 PutObserverInServer();
1915                 }
1916         } else {
1917                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1918                         self.flags = self.flags | FL_JUMPRELEASED;
1919                 }
1920         }
1921         if(self.BUTTON_ZOOM)
1922                 self.wantswelcomemessage = 0;
1923         if(self.wantswelcomemessage)
1924                 PrintWelcomeMessage(self);
1925         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1926 }
1927
1928 /*
1929 =============
1930 PlayerPreThink
1931
1932 Called every frame for each client before the physics are run
1933 =============
1934 */
1935 void() ctf_setstatus;
1936 .float vote_nagtime;
1937 .float spectatee_status;
1938 void PlayerPreThink (void)
1939 {
1940         self.stat_sys_ticrate = cvar("sys_ticrate");
1941         if(blockSpectators)
1942                 checkSpectatorBlock();
1943
1944         zoomstate_set = 0;
1945
1946         if(self.netname_previous != self.netname)
1947         {
1948                 if(cvar("sv_eventlog"))
1949                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
1950                 if(self.netname_previous)
1951                         strunzone(self.netname_previous);
1952                 self.netname_previous = strzone(self.netname);
1953         }
1954
1955         // version nagging
1956         if(self.version_nagtime)
1957                 if(self.cvar_g_nexuizversion)
1958                         if(time > self.version_nagtime)
1959                         {
1960                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1961                                 {
1962                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1963                                         {
1964                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1965                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1966                                         }
1967                                         else
1968                                         {
1969                                                 float r;
1970                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1971                                                 if(r < 0)
1972                                                 {
1973                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1974                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1975                                                 }
1976                                                 else if(r > 0)
1977                                                 {
1978                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1979                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1980                                                 }
1981                                         }
1982                                 }
1983                                 self.version_nagtime = 0;
1984                         }
1985
1986         // vote nagging
1987         if(self.cvar_scr_centertime)
1988                 if(time > self.vote_nagtime)
1989                 {
1990                         VoteNag();
1991                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1992                 }
1993
1994         // GOD MODE info
1995         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1996         {
1997                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1998                 self.max_armorvalue = 0;
1999         }
2000
2001         if(frametime)
2002                 antilag_record(self);
2003
2004         if(self.classname == "player") {
2005 //              if(self.netname == "Wazat")
2006 //                      bprint(self.classname, "\n");
2007
2008                 CheckRules_Player();
2009
2010                 if(self.BUTTON_INFO)
2011                         PrintWelcomeMessage(self);
2012
2013                 if(g_lms || !cvar("sv_spectate"))
2014                 if((time - self.jointime) <= cvar("welcome_message_time"))
2015                         PrintWelcomeMessage(self);
2016
2017                 if (intermission_running)
2018                 {
2019                         IntermissionThink ();   // otherwise a button could be missed between
2020                         return;                                 // the think tics
2021                 }
2022
2023                 if(self.teleport_time)
2024                 if(time > self.teleport_time)
2025                 {
2026                         self.teleport_time = 0;
2027                         self.effects = self.effects - (self.effects & EF_NODRAW);
2028                         if(self.weaponentity)
2029                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2030                 }
2031
2032                 Nixnex_GiveCurrentWeapon();
2033
2034                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2035                         UpdateSelectedPlayer();
2036
2037                 //don't allow the player to turn around while game is paused!
2038                 if(timeoutStatus == 2) {
2039                         self.v_angle = self.lastV_angle;
2040                         self.angles = self.lastV_angle;
2041                         self.fixangle = TRUE;
2042                 }
2043
2044                 if (self.deadflag != DEAD_NO)
2045                 {
2046                         float button_pressed, force_respawn;
2047                         player_anim();
2048                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2049                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2050                         if (self.deadflag == DEAD_DYING)
2051                         {
2052                                 if(force_respawn)
2053                                         self.deadflag = DEAD_RESPAWNING;
2054                                 else if(!button_pressed)
2055                                         self.deadflag = DEAD_DEAD;
2056                         }
2057                         else if (self.deadflag == DEAD_DEAD)
2058                         {
2059                                 if(button_pressed)
2060                                         self.deadflag = DEAD_RESPAWNABLE;
2061                         }
2062                         else if (self.deadflag == DEAD_RESPAWNABLE)
2063                         {
2064                                 if(!button_pressed)
2065                                         self.deadflag = DEAD_RESPAWNING;
2066                         }
2067                         else if (self.deadflag == DEAD_RESPAWNING)
2068                         {
2069                                 if(time > self.death_time)
2070                                 {
2071                                         self.death_time = time + 1; // only retry once a second
2072                                         respawn();
2073                                 }
2074                         }
2075                         ShowRespawnCountdown();
2076                         return;
2077                 }
2078
2079                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2080                 {
2081                         vector dist;
2082
2083                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2084                         dist = self.oldorigin - self.origin;
2085                         dist_z = 0;
2086                         self.lms_traveled_distance += fabs(vlen(dist));
2087
2088                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2089                         {
2090                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2091                                 self.lms_traveled_distance = 0;
2092                         }
2093
2094                         if(time > self.lms_nextcheck)
2095                         {
2096                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2097                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2098                                 {
2099                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2100                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2101                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2102                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2103                                 }
2104                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2105                                 self.lms_traveled_distance = 0;
2106                         }
2107                 }
2108
2109                 if (self.BUTTON_CROUCH && !self.hook.state)
2110                 {
2111                         if (!self.crouch)
2112                         {
2113                                 self.crouch = TRUE;
2114                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2115                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2116                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2117                         }
2118                 }
2119                 else
2120                 {
2121                         if (self.crouch)
2122                         {
2123                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2124                                 if (!trace_startsolid)
2125                                 {
2126                                         self.crouch = FALSE;
2127                                         self.view_ofs = PL_VIEW_OFS;
2128                                         setsize (self, PL_MIN, PL_MAX);
2129                                 }
2130                         }
2131                 }
2132
2133                 FixPlayermodel();
2134
2135                 GrapplingHookFrame();
2136
2137                 W_WeaponFrame();
2138
2139                 player_powerups();
2140                 player_regen();
2141                 player_anim();
2142
2143                 if (g_minstagib)
2144                         minstagib_ammocheck();
2145
2146                 ctf_setstatus();
2147                 kh_setstatus();
2148
2149                 //self.angles_y=self.v_angle_y + 90;   // temp
2150
2151                 //if (TetrisPreFrame()) return;
2152         } else if(gameover) {
2153                 if (intermission_running)
2154                         IntermissionThink ();   // otherwise a button could be missed between
2155                 return;
2156         } else if(self.classname == "observer") {
2157                 ObserverThink();
2158         } else if(self.classname == "spectator") {
2159                 SpectatorThink();
2160         }
2161
2162         if(!zoomstate_set)
2163                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2164
2165         float oldspectatee_status;
2166         oldspectatee_status = self.spectatee_status;
2167         if(self.classname == "spectator")
2168                 self.spectatee_status = num_for_edict(self.enemy);
2169         else if(self.classname == "observer")
2170                 self.spectatee_status = num_for_edict(self);
2171         else
2172                 self.spectatee_status = 0;
2173         if(self.spectatee_status != oldspectatee_status)
2174         {
2175                 msg_entity = self;
2176                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2177                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2178                 WriteByte(MSG_ONE, self.spectatee_status);
2179                 if(g_race)
2180                         race_InitSpectator();
2181         }
2182 }
2183
2184
2185 /*
2186 =============
2187 PlayerPostThink
2188
2189 Called every frame for each client after the physics are run
2190 =============
2191 */
2192 .float idlekick_lasttimeleft;
2193 .float race_penalty;
2194 .float race_penalty_nagged;
2195 void PlayerPostThink (void)
2196 {
2197         // Savage: Check for nameless players
2198         if (strlen(self.netname) < 1) {
2199                 self.netname = "Player";
2200                 stuffcmd(self, "seta _cl_name Player\n");
2201         }
2202
2203         if(sv_maxidle)
2204         {
2205                 float timeleft;
2206                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2207                 if(timeleft <= 0)
2208                 {
2209                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2210                         announce(self, "announcer/robotic/terminated.ogg");
2211                         dropclient(self);
2212                         return;
2213                 }
2214                 else if(timeleft <= 10)
2215                 {
2216                         if(timeleft != self.idlekick_lasttimeleft)
2217                         {
2218                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2219                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2220                         }
2221                 }
2222                 else
2223                 {
2224                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2225                 }
2226                 self.idlekick_lasttimeleft = timeleft;
2227         }
2228
2229         if(self.classname == "player") {
2230                 CheckRules_Player();
2231                 UpdateChatBubble();
2232                 UpdateTeamBubble();
2233                 if (self.impulse)
2234                         ImpulseCommands();
2235                 if (intermission_running)
2236                         return;         // intermission or finale
2237
2238                 //PrintWelcomeMessage(self);
2239                 //if (TetrisPostFrame()) return;
2240
2241                 // restart countdown
2242                 if (restart_countdown) {
2243                         if(time < restart_countdown) {
2244                                 if (!cvar("sv_ready_restart_after_countdown"))
2245                                 {
2246                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2247                                         {
2248                                                 if(time < restart_countdown - 2)
2249                                                 {
2250                                                         if(!self.race_penalty_nagged)
2251                                                         {
2252                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2253                                                                 self.race_penalty_nagged = 1;
2254                                                         }
2255                                                 }
2256                                                 else if(!self.race_penalty)
2257                                                 {
2258                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2259                                                         self.race_penalty = time + 5;
2260                                                 }
2261                                         }
2262                                         self.movetype = MOVETYPE_NONE;
2263                                         self.velocity = '0 0 0';
2264                                         self.avelocity = '0 0 0';
2265                                         self.movement = '0 0 0';
2266                                 }
2267                         }
2268                         else if (time < self.race_penalty)
2269                         {
2270                                 self.movetype = MOVETYPE_NONE;
2271                                 self.velocity = '0 0 0';
2272                                 self.avelocity = '0 0 0';
2273                                 self.movement = '0 0 0';
2274                         }
2275                         else
2276                         {
2277                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2278                                 if (!cvar("sv_ready_restart_after_countdown"))
2279                                 {
2280                                         if(self.movetype == MOVETYPE_NONE)
2281                                         {
2282                                                 self.movetype = MOVETYPE_WALK;
2283                                         }
2284                                         self.race_penalty = 0;
2285                                         self.race_penalty_nagged = 0;
2286                                 }
2287                         }
2288                 }
2289
2290         } else if (self.classname == "observer") {
2291                 //do nothing
2292         } else if (self.classname == "spectator") {
2293                 //do nothing
2294         }
2295
2296         /*
2297         float i;
2298         for(i = 0; i < 1000; ++i)
2299         {
2300                 vector end;
2301                 end = self.origin + '0 0 1024' + 512 * randomvec();
2302                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2303                 if(trace_fraction < 1)
2304                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2305                 {
2306                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2307                         break;
2308                 }
2309         }
2310         */
2311
2312         Arena_Warmup();
2313 }