data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 if(!ent)
  51                         return -1;
  52                 while(ent) {
  53                         if(ent.classname == "target_objective")
  54                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  55                                         return -1;
  56                         else if(ent.classname == "trigger_race_checkpoint")
  57                                 if(self.race_checkpoint != -1 && self.race_checkpoint != ent.cnt)
  58                                         return -1;
  59                         ent = find(ent, targetname, spot.target);
  60                 }
  61         }
  62
  63         player = playerlist;
  64         shortest = vlen(world.maxs - world.mins);
  65         for(player = playerlist; player; player = player.chain)
  66                 if (player != self)
  67                 {
  68                         thisdist = vlen(player.origin - spot.origin);
  69                         if (thisdist < shortest)
  70                                 shortest = thisdist;
  71                 }
  72         return shortest;
  73 }
  74
  75 float spawn_allbad;
  76 float spawn_allgood;
  77 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  78 {
  79         local entity spot, spotlist, spotlistend;
  80         spawn_allgood = TRUE;
  81         spawn_allbad = TRUE;
  82
  83         spotlist = world;
  84         spotlistend = world;
  85
  86         for(spot = firstspot; spot; spot = spot.chain)
  87         {
  88                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  89
  90                 if(cvar("spawn_debugview"))
  91                 {
  92                         setmodel(spot, "models/runematch/rune.mdl");
  93                         if(spot.SPAWNPOINT_SCORE < mindist)
  94                         {
  95                                 spot.colormod = '1 0 0';
  96                                 spot.scale = 1;
  97                         }
  98                         else
  99                         {
 100                                 spot.colormod = '0 1 0';
 101                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 102                         }
 103                 }
 104
 105                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 106                 {
 107                         if(spot.SPAWNPOINT_SCORE < mindist)
 108                         {
 109                                 // too short distance
 110                                 spawn_allgood = FALSE;
 111                         }
 112                         else
 113                         {
 114                                 // perfect
 115                                 spawn_allbad = FALSE;
 116
 117                                 if(spotlistend)
 118                                         spotlistend.chain = spot;
 119                                 spotlistend = spot;
 120                                 if(!spotlist)
 121                                         spotlist = spot;
 122
 123                                 /*
 124                                 if(teamcheck)
 125                                 if(spot.team != teamcheck)
 126                                         error("invalid spawn added");
 127
 128                                 print("added ", etos(spot), "\n");
 129                                 */
 130                         }
 131                 }
 132         }
 133         if(spotlistend)
 134                 spotlistend.chain = world;
 135
 136         /*
 137                 entity e;
 138                 if(teamcheck)
 139                         for(e = spotlist; e; e = e.chain)
 140                         {
 141                                 print("seen ", etos(e), "\n");
 142                                 if(e.team != teamcheck)
 143                                         error("invalid spawn found");
 144                         }
 145         */
 146
 147         return spotlist;
 148 }
 149
 150 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 151 {
 152         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 153         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 154         local entity spot;
 155
 156         RandomSelection_Init();
 157         for(spot = firstspot; spot; spot = spot.chain)
 158                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 159
 160         return RandomSelection_chosen_ent;
 161 }
 162
 163 /*
 164 =============
 165 SelectSpawnPoint
 166
 167 Finds a point to respawn
 168 =============
 169 */
 170 entity SelectSpawnPoint (float anypoint)
 171 {
 172         local float teamcheck;
 173         local entity firstspot_new;
 174         local entity spot, firstspot, playerlist;
 175
 176         spot = find (world, classname, "testplayerstart");
 177         if (spot)
 178                 return spot;
 179
 180         teamcheck = 0;
 181
 182         if(!anypoint && have_team_spawns)
 183                 teamcheck = self.team;
 184
 185         // get the list of players
 186         playerlist = findchain(classname, "player");
 187         // get the entire list of spots
 188         firstspot = findchain(classname, "info_player_deathmatch");
 189         // filter out the bad ones
 190         // (note this returns the original list if none survived)
 191         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 192         if(!firstspot_new)
 193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 194         firstspot = firstspot_new;
 195
 196         // there is 50/50 chance of choosing a random spot or the furthest spot
 197         // (this means that roughly every other spawn will be furthest, so you
 198         // usually won't get fragged at spawn twice in a row)
 199         if (arena_roundbased)
 200         {
 201                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 202                 if(firstspot_new)
 203                         firstspot = firstspot_new;
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 205         }
 206         else if (random() > cvar("g_spawn_furthest"))
 207                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 208         else
 209                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 210
 211         if(cvar("spawn_debugview"))
 212         {
 213                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 214
 215                 entity e;
 216                 if(teamcheck)
 217                         for(e = firstspot; e; e = e.chain)
 218                                 if(e.team != teamcheck)
 219                                         error("invalid spawn found");
 220         }
 221
 222         if (!spot)
 223         {
 224                 if(cvar("spawn_debug"))
 225                         GotoNextMap();
 226                 else
 227                 {
 228                         if(some_spawn_has_been_used)
 229                                 return world; // team can't spawn any more, because of actions of other team
 230                         else
 231                                 error("Cannot find a spawn point - please fix the map!");
 232                 }
 233         }
 234
 235         return spot;
 236 }
 237
 238 /*
 239 =============
 240 CheckPlayerModel
 241
 242 Checks if the argument string can be a valid playermodel.
 243 Returns a valid one in doubt.
 244 =============
 245 */
 246 string FallbackPlayerModel = "models/player/marine.zym";
 247 string CheckPlayerModel(string plyermodel) {
 248         if(strlen(plyermodel) < 4)
 249                 return FallbackPlayerModel;
 250         if( substring(plyermodel,0,14) != "models/player/")
 251                 return FallbackPlayerModel;
 252         else if(cvar("sv_servermodelsonly"))
 253         {
 254                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 255                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 256                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 257                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 258                         return FallbackPlayerModel;
 259                 if(!fexists(plyermodel))
 260                         return FallbackPlayerModel;
 261         }
 262         return plyermodel;
 263 }
 264
 265 /*
 266 =============
 267 Client_customizeentityforclient
 268
 269 LOD reduction
 270 =============
 271 */
 272 float Client_customizeentityforclient()
 273 {
 274 #ifdef ALLOW_VARIABLE_LOD
 275         // self: me
 276         // other: the player viewing me
 277         float distance;
 278         float f;
 279
 280         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 281                 return TRUE;
 282
 283         if(other.cvar_cl_playerdetailreduction <= 0)
 284         {
 285                 if(other.cvar_cl_playerdetailreduction <= -2)
 286                         self.modelindex = self.modelindex_lod2;
 287                 else if(other.cvar_cl_playerdetailreduction <= -1)
 288                         self.modelindex = self.modelindex_lod1;
 289                 else
 290                         self.modelindex = self.modelindex_lod0;
 291         }
 292         else
 293         {
 294                 distance = vlen(self.origin - other.origin);
 295                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 296                 if(f > 10000)
 297                         self.modelindex = self.modelindex_lod2;
 298                 else if(f > 5000)
 299                         self.modelindex = self.modelindex_lod1;
 300                 else
 301                         self.modelindex = self.modelindex_lod0;
 302         }
 303 #endif
 304
 305         return TRUE;
 306 }
 307
 308 void UpdatePlayerSounds();
 309 void setmodel_lod(entity e, string modelname)
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         string s;
 313
 314         // FIXME: this only supports 3-letter extensions
 315         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 316         if(fexists(s))
 317         {
 318                 precache_model(s);
 319                 setmodel(e, s); // players have high precision
 320                 self.modelindex_lod1 = self.modelindex;
 321         }
 322         else
 323                 self.modelindex_lod1 = -1;
 324
 325         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 326         if(fexists(s))
 327         {
 328                 precache_model(s);
 329                 setmodel(e, s); // players have high precision
 330                 self.modelindex_lod2 = self.modelindex;
 331         }
 332         else
 333                 self.modelindex_lod2 = -1;
 334
 335         precache_model(modelname);
 336         setmodel(e, modelname); // players have high precision
 337         self.modelindex_lod0 = self.modelindex;
 338
 339         if(self.modelindex_lod1 < 0)
 340                 self.modelindex_lod1 = self.modelindex;
 341
 342         if(self.modelindex_lod2 < 0)
 343                 self.modelindex_lod2 = self.modelindex;
 344 #else
 345         precache_model(modelname);
 346         setmodel(e, modelname); // players have high precision
 347 #endif
 348         player_setupanimsformodel();
 349         UpdatePlayerSounds();
 350 }
 351
 352 /*
 353 =============
 354 PutObserverInServer
 355
 356 putting a client as observer in the server
 357 =============
 358 */
 359 void PutObserverInServer (void)
 360 {
 361         entity  spot;
 362         spot = SelectSpawnPoint (TRUE);
 363         if(!spot)
 364                 error("No spawnpoints for observers?!?\n");
 365         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 366
 367         if(clienttype(self) == CLIENTTYPE_REAL)
 368         {
 369                 msg_entity = self;
 370                 WriteByte(MSG_ONE, SVC_SETVIEW);
 371                 WriteEntity(MSG_ONE, self);
 372         }
 373
 374         DropAllRunes(self);
 375         kh_Key_DropAll(self, TRUE);
 376
 377         if(self.flagcarried)
 378                 DropFlag(self.flagcarried);
 379
 380         WaypointSprite_PlayerDead();
 381
 382         if(self.killcount != -666)
 383         {
 384                 if(g_lms)
 385                 {
 386                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 387                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 388                         else
 389                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 390                 }
 391                 else
 392                         bprint ("^4", self.netname, "^4 is spectating now\n");
 393         }
 394
 395         PlayerScore_Clear(self); // clear scores when needed
 396
 397         self.spectatortime = time;
 398
 399         self.classname = "observer";
 400         self.health = -666;
 401         self.takedamage = DAMAGE_NO;
 402         self.solid = SOLID_NOT;
 403         self.movetype = MOVETYPE_NOCLIP;
 404         self.flags = FL_CLIENT | FL_NOTARGET;
 405         self.armorvalue = 666;
 406         self.effects = 0;
 407         self.armorvalue = cvar("g_balance_armor_start");
 408         self.pauserotarmor_finished = 0;
 409         self.pauserothealth_finished = 0;
 410         self.pauseregen_finished = 0;
 411         self.damageforcescale = 0;
 412         self.death_time = 0;
 413         self.dead_frame = 0;
 414         self.alpha = 0;
 415         self.scale = 0;
 416         self.fade_time = 0;
 417         self.pain_frame = 0;
 418         self.pain_finished = 0;
 419         self.strength_finished = 0;
 420         self.invincible_finished = 0;
 421         self.pushltime = 0;
 422         self.think = SUB_Null;
 423         self.nextthink = 0;
 424         self.hook_time = 0;
 425         self.runes = 0;
 426         self.deadflag = DEAD_NO;
 427         self.angles = spot.angles;
 428         self.angles_z = 0;
 429         self.fixangle = TRUE;
 430         self.crouch = FALSE;
 431
 432         self.view_ofs = PL_VIEW_OFS;
 433         setorigin (self, spot.origin);
 434         setsize (self, '0 0 0', '0 0 0');
 435         self.oldorigin = self.origin;
 436         self.items = 0;
 437         self.model = "";
 438         self.modelindex = 0;
 439         self.weapon = 0;
 440         self.weaponmodel = "";
 441         self.weaponentity = world;
 442         self.killcount = -666;
 443         self.velocity = '0 0 0';
 444         self.avelocity = '0 0 0';
 445         self.punchangle = '0 0 0';
 446         self.punchvector = '0 0 0';
 447         self.oldvelocity = self.velocity;
 448         self.customizeentityforclient = Client_customizeentityforclient;
 449         self.viewzoom = 1;
 450         self.wantswelcomemessage = 1;
 451
 452         if(g_race)
 453                 race_PreparePlayer();
 454
 455         if(g_arena)
 456         {
 457                 if(self.version_mismatch)
 458                 {
 459                         Spawnqueue_Unmark(self);
 460                         Spawnqueue_Remove(self);
 461                 }
 462                 else
 463                 {
 464                         Spawnqueue_Insert(self);
 465                 }
 466         }
 467         else if(g_lms)
 468         {
 469                 // Only if the player cannot play at all
 470                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 471                         self.frags = -666;
 472                 else
 473                         self.frags = -667;
 474         }
 475         else
 476                 self.frags = -666;
 477 }
 478
 479 float RestrictSkin(float s)
 480 {
 481         if(!teams_matter)
 482                 return s;
 483         if(s == 6)
 484                 return 6;
 485         return mod(s, 3);
 486 }
 487
 488 void FixPlayermodel()
 489 {
 490         local string defaultmodel;
 491         local float defaultskin;
 492         local vector m1, m2;
 493
 494         defaultmodel = "";
 495
 496         if(cvar("sv_defaultcharacter") == 1) {
 497                 defaultskin = 0;
 498
 499                 if(teams_matter)
 500                 {
 501                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 502                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 503                 }
 504
 505                 if(defaultmodel == "")
 506                 {
 507                         defaultmodel = cvar_string("sv_defaultplayermodel");
 508                         defaultskin = cvar("sv_defaultplayerskin");
 509                 }
 510         }
 511
 512         if(defaultmodel != "")
 513         {
 514                 if (defaultmodel != self.model)
 515                 {
 516                         m1 = self.mins;
 517                         m2 = self.maxs;
 518                         setmodel_lod (self, defaultmodel);
 519                         setsize (self, m1, m2);
 520                 }
 521
 522                 self.skin = defaultskin;
 523         } else {
 524                 if (self.playermodel != self.model)
 525                 {
 526                         self.playermodel = CheckPlayerModel(self.playermodel);
 527                         m1 = self.mins;
 528                         m2 = self.maxs;
 529                         setmodel_lod (self, self.playermodel);
 530                         setsize (self, m1, m2);
 531                 }
 532
 533                 self.skin = RestrictSkin(stof(self.playerskin));
 534         }
 535
 536         if(!teams_matter)
 537                 if(strlen(cvar_string("sv_defaultplayercolors")))
 538                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 539                                 setcolor(self, cvar("sv_defaultplayercolors"));
 540 }
 541
 542 /*
 543 =============
 544 PutClientInServer
 545
 546 Called when a client spawns in the server
 547 =============
 548 */
 549 //void() ctf_playerchanged;
 550 void PutClientInServer (void)
 551 {
 552         if(clienttype(self) == CLIENTTYPE_BOT)
 553         {
 554                 self.classname = "player";
 555         }
 556         else if(clienttype(self) == CLIENTTYPE_REAL)
 557         {
 558                 msg_entity = self;
 559                 WriteByte(MSG_ONE, SVC_SETVIEW);
 560                 WriteEntity(MSG_ONE, self);
 561         }
 562
 563         // player is dead and becomes observer
 564         // FIXME fix LMS scoring for new system
 565         if(g_lms)
 566         {
 567                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 568                         self.classname = "observer";
 569         }
 570
 571         if(g_arena)
 572         if(!self.spawned)
 573                 self.classname = "observer";
 574
 575         if(self.classname == "player") {
 576                 entity  spot;
 577
 578                 if(g_race)
 579                         if(self.killcount == -666)
 580                                 race_PreparePlayer();
 581
 582                 spot = SelectSpawnPoint (FALSE);
 583                 if(!spot)
 584                 {
 585                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 586                         return; // spawn failed
 587                 }
 588
 589                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 590
 591                 self.classname = "player";
 592                 self.iscreature = TRUE;
 593                 self.movetype = MOVETYPE_WALK;
 594                 self.solid = SOLID_SLIDEBOX;
 595                 self.flags = FL_CLIENT;
 596                 self.takedamage = DAMAGE_AIM;
 597                 if(g_minstagib)
 598                         self.effects = EF_FULLBRIGHT;
 599                 else
 600                         self.effects = 0;
 601                 self.air_finished = time + 12;
 602                 self.dmg = 2;
 603
 604                 self.ammo_shells = start_ammo_shells;
 605                 self.ammo_nails = start_ammo_nails;
 606                 self.ammo_rockets = start_ammo_rockets;
 607                 self.ammo_cells = start_ammo_cells;
 608                 self.health = start_health;
 609                 self.armorvalue = start_armorvalue;
 610                 self.items = start_items;
 611                 self.switchweapon = start_switchweapon;
 612                 self.cnt = start_switchweapon;
 613                 self.weapon = 0;
 614                 self.jump_interval = time;
 615
 616                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 617                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 618                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 619                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 620                 //extend the pause of rotting if client was reset at the beginning of the countdown
 621                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 622                         self.spawnshieldtime += RESTART_COUNTDOWN;
 623                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 624                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 625                         self.pauseregen_finished += RESTART_COUNTDOWN;
 626                 }
 627                 self.damageforcescale = 2;
 628                 self.death_time = 0;
 629                 self.dead_frame = 0;
 630                 self.alpha = 0;
 631                 self.scale = 0;
 632                 self.fade_time = 0;
 633                 self.pain_frame = 0;
 634                 self.pain_finished = 0;
 635                 self.strength_finished = 0;
 636                 self.invincible_finished = 0;
 637                 self.pushltime = 0;
 638                 //self.speed_finished = 0;
 639                 //self.slowmo_finished = 0;
 640                 // players have no think function
 641                 self.think = SUB_Null;
 642                 self.nextthink = 0;
 643                 self.hook_time = 0;
 644
 645                 self.runes = 0;
 646
 647                 self.deadflag = DEAD_NO;
 648
 649                 self.angles = spot.angles;
 650
 651                 self.angles_z = 0; // never spawn tilted even if the spot says to
 652                 self.fixangle = TRUE; // turn this way immediately
 653                 self.velocity = '0 0 0';
 654                 self.avelocity = '0 0 0';
 655                 self.punchangle = '0 0 0';
 656                 self.punchvector = '0 0 0';
 657                 self.oldvelocity = self.velocity;
 658
 659                 self.viewzoom = 0.6;
 660                 self.has_zoomed = 0;
 661
 662                 self.customizeentityforclient = Client_customizeentityforclient;
 663
 664                 self.model = "";
 665                 FixPlayermodel();
 666
 667                 self.crouch = FALSE;
 668                 self.view_ofs = PL_VIEW_OFS;
 669                 setsize (self, PL_MIN, PL_MAX);
 670                 self.spawnorigin = spot.origin;
 671                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 672                 // don't reset back to last position, even if new position is stuck in solid
 673                 self.oldorigin = self.origin;
 674
 675                 if(g_arena)
 676                 {
 677                         Spawnqueue_Remove(self);
 678                         Spawnqueue_Mark(self);
 679                 }
 680
 681                 self.event_damage = PlayerDamage;
 682
 683                 self.bot_attack = TRUE;
 684
 685                 self.statdraintime = time + 5;
 686                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 687
 688                 if(g_race)
 689                         if(self.killcount != -666)
 690                                 if(spot.target == "")
 691                                         // let the player run without timing, if he did not spawn at a targetting spawnpoint
 692                                         race_PreparePlayer();
 693
 694                 if(self.killcount == -666) {
 695                         PlayerScore_Clear(self);
 696                         self.killcount = 0;
 697                         self.frags = 0;
 698                 }
 699
 700                 self.cnt = WEP_LASER;
 701                 self.nixnex_lastchange_id = -1;
 702
 703                 CL_SpawnWeaponentity();
 704                 self.alpha = default_player_alpha;
 705                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 706                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 707
 708                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 709                 self.lms_traveled_distance = 0;
 710                 self.speedrunning = FALSE;
 711
 712                 if(cvar("spawn_debug"))
 713                 {
 714                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 715                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 716                 }
 717
 718                 //stuffcmd(self, "chase_active 0");
 719                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 720
 721                 if (cvar("g_spawnsound"))
 722                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 723
 724                 if(g_assault) {
 725                         if(self.team == assault_attacker_team)
 726                                 centerprint(self, "You are attacking!\n");
 727                         else
 728                                 centerprint(self, "You are defending!\n");
 729                 }
 730
 731         } else if(self.classname == "observer") {
 732                 PutObserverInServer ();
 733         }
 734
 735         //if(g_ctf)
 736         //      ctf_playerchanged();
 737 }
 738
 739 /*
 740 =============
 741 SendCSQCInfo
 742
 743 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 744 =============
 745 */
 746 void SendCSQCInfo(void)
 747 {
 748         if(clienttype(self) != CLIENTTYPE_REAL)
 749                 return;
 750         msg_entity = self;
 751         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 752         WriteByte(MSG_ONE, TE_CSQC_INIT);
 753         WriteShort(MSG_ONE, CSQC_REVISION);
 754         WriteByte(MSG_ONE, maxclients);
 755 }
 756
 757 /*
 758 =============
 759 SetNewParms
 760 =============
 761 */
 762 void SetNewParms (void)
 763 {
 764         // initialize parms for a new player
 765         parm1 = -(86400 * 366);
 766 }
 767
 768 /*
 769 =============
 770 SetChangeParms
 771 =============
 772 */
 773 void SetChangeParms (void)
 774 {
 775         // save parms for level change
 776         parm1 = self.parm_idlesince - time;
 777 }
 778
 779 /*
 780 =============
 781 DecodeLevelParms
 782 =============
 783 */
 784 void DecodeLevelParms (void)
 785 {
 786         // load parms
 787         self.parm_idlesince = parm1;
 788         if(self.parm_idlesince == -(86400 * 366))
 789                 self.parm_idlesince = time;
 790 }
 791
 792 /*
 793 =============
 794 ClientKill
 795
 796 Called when a client types 'kill' in the console
 797 =============
 798 */
 799
 800 void ClientKill_Now_TeamChange()
 801 {
 802         if(self.killindicator_teamchange == -1)
 803         {
 804                 self.team = -1;
 805                 JoinBestTeam( self, FALSE, FALSE );
 806         }
 807         else
 808         {
 809                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 810         }
 811 }
 812
 813 void ClientKill_Now()
 814 {
 815         if(self.killindicator_teamchange)
 816                 ClientKill_Now_TeamChange();
 817
 818         // in any case:
 819         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 820
 821         if(self.killindicator)
 822         {
 823                 dprint("Cleaned up after a leaked kill indicator.\n");
 824                 remove(self.killindicator);
 825                 self.killindicator = world;
 826         }
 827 }
 828 void KillIndicator_Think()
 829 {
 830         if (!self.owner.modelindex)
 831         {
 832                 self.owner.killindicator = world;
 833                 remove(self);
 834                 return;
 835         }
 836
 837         if(self.cnt <= 0)
 838         {
 839                 self = self.owner;
 840                 ClientKill_Now(); // no oldself needed
 841                 return;
 842         }
 843         else
 844         {
 845                 if(self.cnt <= 10)
 846                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 847                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 848                 {
 849                         if(self.cnt <= 10)
 850                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 851                         if(self.owner.killindicator_teamchange)
 852                         {
 853                                 if(self.owner.killindicator_teamchange == -1)
 854                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 855                                 else
 856                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 857                         }
 858                         else
 859                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 860                 }
 861                 self.nextthink = time + 1;
 862                 self.cnt -= 1;
 863         }
 864 }
 865
 866 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 867 {
 868         float killtime;
 869         entity e;
 870         killtime = cvar("g_balance_kill_delay");
 871
 872         self.killindicator_teamchange = targetteam;
 873
 874         if(!self.killindicator)
 875         {
 876                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 877                 {
 878                         ClientKill_Now();
 879                 }
 880                 else
 881                 {
 882                         self.killindicator = spawn();
 883                         self.killindicator.owner = self;
 884                         self.killindicator.scale = 0.5;
 885                         setattachment(self.killindicator, self, "");
 886                         setorigin(self.killindicator, '0 0 52');
 887                         self.killindicator.think = KillIndicator_Think;
 888                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 889                         self.killindicator.cnt = ceil(killtime);
 890                         self.killindicator.count = bound(0, ceil(killtime), 10);
 891                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 892
 893                         for(e = world; (e = find(e, classname, "body")) != world; )
 894                         {
 895                                 if(e.enemy != self)
 896                                         continue;
 897                                 e.killindicator = spawn();
 898                                 e.killindicator.owner = e;
 899                                 e.killindicator.scale = 0.5;
 900                                 setattachment(e.killindicator, e, "");
 901                                 setorigin(e.killindicator, '0 0 52');
 902                                 e.killindicator.think = KillIndicator_Think;
 903                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 904                                 e.killindicator.cnt = ceil(killtime);
 905                         }
 906                         self.lip = 0;
 907                 }
 908         }
 909         if(self.killindicator)
 910         {
 911                 if(targetteam)
 912                         self.killindicator.colormod = TeamColor(targetteam);
 913                 else
 914                         self.killindicator.colormod = '0 0 0';
 915         }
 916 }
 917
 918 void ClientKill (void)
 919 {
 920         ClientKill_TeamChange(0);
 921 }
 922
 923 void DoTeamChange(float destteam)
 924 {
 925         float t, c0;
 926         if(!cvar("teamplay"))
 927         {
 928                 if(destteam >= 0)
 929                         SetPlayerColors(self, destteam);
 930                 return;
 931         }
 932         if(self.classname == "player")
 933         if(destteam == -1)
 934         {
 935                 CheckAllowedTeams(self);
 936                 t = FindSmallestTeam(self, TRUE);
 937                 switch(self.team)
 938                 {
 939                         case COLOR_TEAM1: c0 = c1; break;
 940                         case COLOR_TEAM2: c0 = c2; break;
 941                         case COLOR_TEAM3: c0 = c3; break;
 942                         case COLOR_TEAM4: c0 = c4; break;
 943                         default:          c0 = 999;
 944                 }
 945                 switch(t)
 946                 {
 947                         case 1:
 948                                 if(c0 > c1)
 949                                         destteam = COLOR_TEAM1;
 950                                 break;
 951                         case 2:
 952                                 if(c0 > c2)
 953                                         destteam = COLOR_TEAM2;
 954                                 break;
 955                         case 3:
 956                                 if(c0 > c3)
 957                                         destteam = COLOR_TEAM3;
 958                                 break;
 959                         case 4:
 960                                 if(c0 > c4)
 961                                         destteam = COLOR_TEAM4;
 962                                 break;
 963                 }
 964                 if(destteam == -1)
 965                         return;
 966         }
 967         if(destteam == self.team && !self.killindicator)
 968                 return;
 969         ClientKill_TeamChange(destteam);
 970 }
 971
 972 void FixClientCvars(entity e)
 973 {
 974         // send prediction settings to the client
 975         stuffcmd(e, "\nin_bindmap 0 0\n");
 976         /*
 977          * we no longer need to stuff this. Remove this comment block if you feel
 978          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 979         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 980         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 981         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 982         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 983         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 984         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 985         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 986         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 987         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 988         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 989         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 990         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 991         stuffcmd(e, "cl_movement_edgefriction 1\n");
 992          */
 993 }
 994
 995 /*
 996 =============
 997 ClientConnect
 998
 999 Called when a client connects to the server
1000 =============
1001 */
1002 //void ctf_clientconnect();
1003 string ColoredTeamName(float t);
1004 void DecodeLevelParms (void);
1005 //void dom_player_join_team(entity pl);
1006 void ClientConnect (void)
1007 {
1008         local string s;
1009         float wep;
1010
1011         if(self.flags & FL_CLIENT)
1012         {
1013                 print("Warning: ClientConnect, but already connected!\n");
1014                 return;
1015         }
1016
1017         if(Ban_IsClientBanned(self))
1018         {
1019                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1020                 dropclient(self);
1021                 bprint(s);
1022                 return;
1023         }
1024
1025         DecodeLevelParms();
1026
1027         self.classname = "player_joining";
1028
1029         self.flags = self.flags | FL_CLIENT;
1030         self.version_nagtime = time + 10 + random() * 10;
1031
1032         if(player_count<0)
1033         {
1034                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1035                 player_count = 0;
1036         }
1037
1038         PlayerScore_Attach(self);
1039
1040         bot_clientconnect();
1041
1042         //if(g_domination)
1043         //      dom_player_join_team(self);
1044
1045         //JoinBestTeam(self, FALSE, FALSE);
1046
1047         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1048                 self.classname = "observer";
1049         } else {
1050                 self.classname = "player";
1051                 campaign_bots_may_start = 1;
1052         }
1053
1054         self.playerid = (playerid_last = playerid_last + 1);
1055         if(cvar("sv_eventlog"))
1056         {
1057                 if(clienttype(self) == CLIENTTYPE_REAL)
1058                         s = "player";
1059                 else
1060                         s = "bot";
1061                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1062                 s = strcat(":team:", ftos(self.playerid), ":");
1063                 s = strcat(s, ftos(self.team));
1064                 GameLogEcho(s, FALSE);
1065         }
1066         self.netname_previous = strzone(self.netname);
1067
1068         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1069
1070         bprint ("^4",self.netname);
1071         bprint ("^4 connected");
1072
1073         if(g_domination || g_ctf)
1074         {
1075                 bprint(" and joined the ");
1076                 bprint(ColoredTeamName(self.team));
1077         }
1078
1079         bprint("\n");
1080
1081         self.welcomemessage_time = 0;
1082
1083         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1084         // TODO: is this being used for anything else than cd tracks?
1085         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1086         //
1087         stuffcmd(self, "cl_particles_reloadeffects\n");
1088
1089         FixClientCvars(self);
1090
1091         // spawnfunc_waypoint sprites
1092         WaypointSprite_InitClient(self);
1093
1094         // Wazat's grappling hook
1095         SetGrappleHookBindings();
1096
1097         // get autoswitch state from player when he toggles it
1098         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1099
1100         // get version info from player
1101         stuffcmd(self, "cmd clientversion $gameversion\n");
1102
1103         // send all weapon info strings
1104         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1105         wep = WEP_FIRST;
1106         while (wep <= WEP_LAST)
1107         {
1108                 weapon_action(wep, WR_REGISTER);
1109                 wep = wep + 1;
1110         }
1111
1112         // get other cvars from player
1113         GetCvars(0);
1114
1115         // set cvar for team scoreboard
1116         if (teams_matter)
1117         {
1118                 local float t;
1119                 t = cvar("teamplay");
1120                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1121                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1122         }
1123         else
1124                 stuffcmd(self, "set teamplay 0\n");
1125
1126         // notify about available teams
1127         if(teamplay)
1128         {
1129                 CheckAllowedTeams(self);
1130                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1131                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1132         }
1133         else
1134                 stuffcmd(self, "set _teams_available 0\n");
1135
1136         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1137
1138         if(g_arena)
1139         {
1140                 self.classname = "observer";
1141                 Spawnqueue_Insert(self);
1142         }
1143         /*else if(g_ctf)
1144         {
1145                 ctf_clientconnect();
1146         }*/
1147
1148         if(entcs_start)
1149                 attach_entcs();
1150
1151         bot_relinkplayerlist();
1152
1153         self.spectatortime = time;
1154         if(blockSpectators)
1155         {
1156                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1157         }
1158
1159         self.jointime = time;
1160         self.allowedTimeouts = cvar("sv_timeout_number");
1161
1162         if(clienttype(self) == CLIENTTYPE_REAL)
1163         {
1164                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1165                 SendCSQCInfo();
1166                 msg_entity = self;
1167                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1168                 {
1169                         MapVote_SendData(MSG_ONE);
1170                         MapVote_UpdateData(MSG_ONE);
1171                 }
1172                 ScoreInfo_Write(MSG_ONE);
1173         }
1174
1175         if(g_lms)
1176         {
1177                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1178                 {
1179                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1180                         self.frags = -666; // FIXME do we still need this?
1181                 }
1182         }
1183 }
1184
1185 /*
1186 =============
1187 ClientDisconnect
1188
1189 Called when a client disconnects from the server
1190 =============
1191 */
1192 void(entity e) DropFlag;
1193 .entity chatbubbleentity;
1194 .entity teambubbleentity;
1195 //void() ctf_clientdisconnect;
1196 void ClientDisconnect (void)
1197 {
1198         float save;
1199
1200         if not(self.flags & FL_CLIENT)
1201         {
1202                 print("Warning: ClientDisconnect without ClientConnect\n");
1203                 return;
1204         }
1205
1206         bot_clientdisconnect();
1207
1208         if(entcs_start)
1209                 detach_entcs();
1210
1211         if(cvar("sv_eventlog"))
1212                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1213         bprint ("^4",self.netname);
1214         bprint ("^4 disconnected\n");
1215
1216         if (self.chatbubbleentity)
1217         {
1218                 remove (self.chatbubbleentity);
1219                 self.chatbubbleentity = world;
1220         }
1221
1222         if (self.teambubbleentity)
1223         {
1224                 remove (self.teambubbleentity);
1225                 self.teambubbleentity = world;
1226         }
1227
1228         if (self.killindicator)
1229         {
1230                 remove (self.killindicator);
1231                 self.killindicator = world;
1232         }
1233
1234         WaypointSprite_PlayerGone();
1235
1236         DropAllRunes(self);
1237         kh_Key_DropAll(self, TRUE);
1238
1239         if(self.flagcarried)
1240                 DropFlag(self.flagcarried);
1241
1242         save = self.flags;
1243         self.flags = self.flags - (self.flags & FL_CLIENT);
1244         bot_relinkplayerlist();
1245         self.flags = save;
1246
1247         // remove laserdot
1248         if(self.weaponentity)
1249                 if(self.weaponentity.lasertarget)
1250                         remove(self.weaponentity.lasertarget);
1251
1252         if(g_arena)
1253         {
1254                 Spawnqueue_Unmark(self);
1255                 Spawnqueue_Remove(self);
1256         }
1257         /*if(g_ctf)
1258         {
1259                 ctf_clientdisconnect();
1260         }
1261         */
1262
1263         PlayerScore_Detach(self);
1264
1265         if(self.netname_previous)
1266                 strunzone(self.netname_previous);
1267
1268         ClearPlayerSounds();
1269
1270         // free cvars
1271         GetCvars(-1);
1272         self.playerid = 0;
1273 }
1274
1275 .float BUTTON_CHAT;
1276 void ChatBubbleThink()
1277 {
1278         self.nextthink = time;
1279         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1280         {
1281                 self.owner.chatbubbleentity = world;
1282                 remove(self);
1283                 return;
1284         }
1285         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1286         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1287                 self.model = self.mdl;
1288         else
1289                 self.model = "";
1290 };
1291
1292 void UpdateChatBubble()
1293 {
1294         if (!self.modelindex)
1295                 return;
1296         // spawn a chatbubble entity if needed
1297         if (!self.chatbubbleentity)
1298         {
1299                 self.chatbubbleentity = spawn();
1300                 self.chatbubbleentity.owner = self;
1301                 self.chatbubbleentity.exteriormodeltoclient = self;
1302                 self.chatbubbleentity.think = ChatBubbleThink;
1303                 self.chatbubbleentity.nextthink = time;
1304                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1305                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1306                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1307                 self.chatbubbleentity.model = "";
1308                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1309         }
1310 }
1311
1312
1313 void TeamBubbleThink()
1314 {
1315         self.nextthink = time;
1316         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1317         {
1318                 self.owner.teambubbleentity = world;
1319                 remove(self);
1320                 return;
1321         }
1322 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1323         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1324                 self.model = "";
1325         else
1326                 self.model = self.mdl;
1327
1328 };
1329
1330 float TeamBubble_customizeentityforclient()
1331 {
1332         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1333 }
1334
1335 void UpdateTeamBubble()
1336 {
1337         if (!self.modelindex || !cvar("teamplay"))
1338                 return;
1339         // spawn a teambubble entity if needed
1340         if (!self.teambubbleentity && cvar("teamplay"))
1341         {
1342                 self.teambubbleentity = spawn();
1343                 self.teambubbleentity.owner = self;
1344                 self.teambubbleentity.exteriormodeltoclient = self;
1345                 self.teambubbleentity.think = TeamBubbleThink;
1346                 self.teambubbleentity.nextthink = time;
1347                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1348 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1349                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1350                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1351                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1352                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1353                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1354                 self.teambubbleentity.effects = EF_LOWPRECISION;
1355         }
1356 }
1357
1358 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1359 // added to the model skins
1360 /*void UpdateColorModHack()
1361 {
1362         local float c;
1363         c = self.clientcolors & 15;
1364         // LordHavoc: only bothering to support white, green, red, yellow, blue
1365              if (teamplay == 0) self.colormod = '0 0 0';
1366         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1367         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1368         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1369         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1370         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1371         else self.colormod = '1 1 1';
1372 };*/
1373
1374 void respawn(void)
1375 {
1376         CopyBody(1);
1377         self.effects |= EF_NODRAW; // prevent another CopyBody
1378         PutClientInServer();
1379 }
1380
1381 /**
1382  * When sv_timeout is used this function returs strings like
1383  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1384  * Called by centerprint functions
1385  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1386  */
1387 string getTimeoutText(float addOneSecond) {
1388         if (!cvar("sv_timeout") || !timeoutStatus)
1389                 return "";
1390
1391         local string retStr;
1392         if (timeoutStatus == 1) {
1393                 if (addOneSecond == 1) {
1394                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1395                 }
1396                 else {
1397                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1398                 }
1399                 return retStr;
1400         }
1401         else if (timeoutStatus == 2) {
1402                 if (addOneSecond) {
1403                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1404                         //don't show messages like "Timeout ends in 0 seconds"...
1405                         if ((remainingTimeoutTime + 1) > 0)
1406                                 return retStr;
1407                         else
1408                                 return "";
1409                 }
1410                 else {
1411                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1412                         //don't show messages like "Timeout ends in 0 seconds"...
1413                         if (remainingTimeoutTime > 0)
1414                                 return retStr;
1415                         else
1416                                 return "";
1417                 }
1418         }
1419         else return "";
1420 }
1421
1422 void player_powerups (void)
1423 {
1424         if (g_minstagib)
1425         {
1426                 if (self.items & IT_STRENGTH)
1427                 {
1428                         if (time > self.strength_finished)
1429                         {
1430                                 if (g_minstagib_invis_alpha > 0)
1431                                 {
1432                                         self.alpha = default_player_alpha;
1433                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1434                                         self.effects = self.effects | EF_FULLBRIGHT;
1435                                 }
1436                                 else
1437                                 {
1438                                         self.effects -= self.effects & EF_NODRAW;
1439                                 }
1440                                 self.items = self.items - (self.items & IT_STRENGTH);
1441                                 sprint(self, "^3Invisibility has worn off\n");
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < self.strength_finished)
1447                         {
1448                                 if (g_minstagib_invis_alpha > 0)
1449                                 {
1450                                         self.alpha = g_minstagib_invis_alpha;
1451                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1452                                         self.effects -= self.effects & EF_FULLBRIGHT;
1453                                 }
1454                                 else
1455                                 {
1456                                         self.effects = self.effects | EF_NODRAW;
1457                                 }
1458                                 self.items = self.items | IT_STRENGTH;
1459                                 sprint(self, "^3You are invisible\n");
1460                         }
1461                 }
1462
1463                 if (self.items & IT_INVINCIBLE)
1464                 {
1465                         if (time > self.invincible_finished)
1466                         {
1467                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1468                                 sprint(self, "^3Speed has worn off\n");
1469                         }
1470                 }
1471                 else
1472                 {
1473                         if (time < self.invincible_finished)
1474                         {
1475                                 self.items = self.items | IT_INVINCIBLE;
1476                                 sprint(self, "^3You are on speed\n");
1477                         }
1478                 }
1479                 return;
1480         }
1481
1482         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1483         if (self.items & IT_STRENGTH)
1484         {
1485                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1486                 if (time > self.strength_finished)
1487                 {
1488                         self.items = self.items - (self.items & IT_STRENGTH);
1489                         sprint(self, "^3Strength has worn off\n");
1490                 }
1491         }
1492         else
1493         {
1494                 if (time < self.strength_finished)
1495                 {
1496                         self.items = self.items | IT_STRENGTH;
1497                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1498                 }
1499         }
1500         if (self.items & IT_INVINCIBLE)
1501         {
1502                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1503                 if (time > self.invincible_finished)
1504                 {
1505                         self.items = self.items - (self.items & IT_INVINCIBLE);
1506                         sprint(self, "^3Shield has worn off\n");
1507                 }
1508         }
1509         else
1510         {
1511                 if (time < self.invincible_finished)
1512                 {
1513                         self.items = self.items | IT_INVINCIBLE;
1514                         sprint(self, "^3Shield surrounds you\n");
1515                 }
1516         }
1517
1518         if (cvar("g_fullbrightplayers"))
1519                 self.effects = self.effects | EF_FULLBRIGHT;
1520
1521         // midair gamemode: damage only while in the air
1522         // if in midair mode, being on ground grants temporary invulnerability
1523         // (this is so that multishot weapon don't clear the ground flag on the
1524         // first damage in the frame, leaving the player vulnerable to the
1525         // remaining hits in the same frame)
1526         if (self.flags & FL_ONGROUND)
1527         if (g_midair)
1528                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1529
1530         if (time < self.spawnshieldtime)
1531                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1532 }
1533
1534 float CalcRegen(float current, float stable, float regenfactor)
1535 {
1536         if(current > stable)
1537                 return current;
1538         else if(current > stable - 0.25) // when close enough, "snap"
1539                 return stable;
1540         else
1541                 return min(stable, current + (stable - current) * regenfactor * frametime);
1542 }
1543
1544 void player_regen (void)
1545 {
1546         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1547         maxh = cvar("g_balance_health_stable");
1548         maxa = cvar("g_balance_armor_stable");
1549         limith = cvar("g_balance_health_limit");
1550         limita = cvar("g_balance_armor_limit");
1551
1552         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1553                 return;
1554
1555         max_mod = regen_mod = rot_mod = limit_mod = 1;
1556
1557         if (self.runes & RUNE_REGEN)
1558         {
1559                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1560                 {
1561                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1562                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1563                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1564                 }
1565                 else
1566                 {
1567                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1568                         max_mod = cvar("g_balance_rune_regen_hpmod");
1569                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1570                 }
1571         }
1572         else if (self.runes & CURSE_VENOM)
1573         {
1574                 max_mod = cvar("g_balance_curse_venom_hpmod");
1575                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1576                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1577                 else
1578                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1579                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1580                 //if (!self.runes & RUNE_REGEN)
1581                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1582         }
1583         maxh = maxh * max_mod;
1584         //maxa = maxa * max_mod;
1585         limith = limith * limit_mod;
1586         limita = limita * limit_mod;
1587
1588         if (self.armorvalue > maxa)
1589         {
1590                 if (time > self.pauserotarmor_finished)
1591                 {
1592                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1593                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1594                 }
1595         }
1596         else if (self.armorvalue < maxa)
1597         {
1598                 if (time > self.pauseregen_finished)
1599                 {
1600                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1601                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1602                 }
1603         }
1604         if (self.health > maxh)
1605         {
1606                 if (time > self.pauserothealth_finished)
1607                 {
1608                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1609                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1610                 }
1611         }
1612         else if (self.health < maxh)
1613         {
1614                 if (time > self.pauseregen_finished)
1615                 {
1616                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1617                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1618                 }
1619         }
1620
1621         if (self.health > limith)
1622                 self.health = limith;
1623         if (self.armorvalue > limita)
1624                 self.armorvalue = limita;
1625
1626         // if player rotted to death...  die!
1627         if(self.health < 1)
1628                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1629 }
1630
1631 /*
1632 ======================
1633 spectate mode routines
1634 ======================
1635 */
1636 void SpectateCopy(entity spectatee) {
1637         self.armortype = spectatee.armortype;
1638         self.armorvalue = spectatee.armorvalue;
1639         self.currentammo = spectatee.currentammo;
1640         self.effects = spectatee.effects;
1641         self.health = spectatee.health;
1642         self.impulse = 0;
1643         self.items = spectatee.items;
1644         self.punchangle = spectatee.punchangle;
1645         self.view_ofs = spectatee.view_ofs;
1646         self.v_angle = spectatee.v_angle;
1647         self.viewzoom = spectatee.viewzoom;
1648         self.velocity = spectatee.velocity;
1649         self.dmg_take = spectatee.dmg_take;
1650         self.dmg_save = spectatee.dmg_save;
1651         self.dmg_inflictor = spectatee.dmg_inflictor;
1652         self.angles = spectatee.v_angle;
1653         self.fixangle = TRUE;
1654         setorigin(self, spectatee.origin);
1655         setsize(self, spectatee.mins, spectatee.maxs);
1656 }
1657
1658 float SpectateUpdate() {
1659         if(!self.enemy)
1660                 return 0;
1661
1662         if (self == self.enemy)
1663                 return 0;
1664
1665         if(self.enemy.flags & FL_NOTARGET)
1666                 return 0;
1667
1668         SpectateCopy(self.enemy);
1669
1670         return 1;
1671 }
1672
1673 float SpectateNext() {
1674         other = find(self.enemy, classname, "player");
1675         if (!other) {
1676                 other = find(other, classname, "player");
1677         }
1678         if (other) {
1679                 self.enemy = other;
1680         }
1681         if(self.enemy.classname == "player") {
1682                 msg_entity = self;
1683                 WriteByte(MSG_ONE, SVC_SETVIEW);
1684                 WriteEntity(MSG_ONE, self.enemy);
1685                 self.wantswelcomemessage = 1;
1686                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1687                 if(!SpectateUpdate())
1688                         PutObserverInServer();
1689                 return 1;
1690         } else {
1691                 return 0;
1692         }
1693 }
1694
1695 /*
1696 =============
1697 ShowRespawnCountdown()
1698
1699 Update a respawn countdown display.
1700 =============
1701 */
1702 void ShowRespawnCountdown()
1703 {
1704         float number;
1705         if(self.deadflag == DEAD_NO) // just respawned?
1706                 return;
1707         else
1708         {
1709                 number = ceil(self.death_time - time);
1710                 if(number <= 0)
1711                         return;
1712                 if(number <= self.respawn_countdown)
1713                 {
1714                         self.respawn_countdown = number - 1;
1715                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1716                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1717                 }
1718         }
1719 }
1720
1721 void LeaveSpectatorMode()
1722 {
1723         if(isJoinAllowed()) {
1724                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1725                         self.classname = "player";
1726                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1727                                 JoinBestTeam(self, FALSE, TRUE);
1728                         if(cvar("g_campaign"))
1729                                 campaign_bots_may_start = 1;
1730                         PutClientInServer();
1731                         if(!(self.flags & FL_NOTARGET))
1732                                 bprint ("^4", self.netname, "^4 is playing now\n");
1733                         centerprint(self,"");
1734                         return;
1735                 } else {
1736                         stuffcmd(self,"menu_showteamselect\n");
1737                         return;
1738                 }
1739         }
1740         else {
1741                 //player may not join because of g_maxplayers is set
1742                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1743         }
1744 }
1745
1746 /**
1747  * Determines whether the player is allowed to join. This depends on cvar
1748  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1749  * it checks whether the number of currently playing players exceeds g_maxplayers.
1750  * @return bool TRUE if the player is allowed to join, false otherwise
1751  */
1752 float isJoinAllowed() {
1753         if (!cvar("g_maxplayers"))
1754                 return TRUE;
1755
1756         local entity e;
1757         local float currentlyPlaying;
1758         FOR_EACH_REALPLAYER(e) {
1759                 if(e.classname == "player")
1760                         currentlyPlaying += 1;
1761         }
1762         if(currentlyPlaying < cvar("g_maxplayers"))
1763                 return TRUE;
1764
1765         return FALSE;
1766 }
1767
1768 /**
1769  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1770  * g_maxplayers_spectator_blocktime seconds
1771  */
1772 void checkSpectatorBlock() {
1773         if(self.classname == "spectator" || self.classname == "observer") {
1774                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1775                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1776                         dropclient(self);
1777                 }
1778         }
1779 }
1780
1781 float vercmp_recursive(string v1, string v2)
1782 {
1783         float dot1, dot2;
1784         string s1, s2;
1785         float r;
1786
1787         dot1 = strstrofs(v1, ".", 0);
1788         dot2 = strstrofs(v2, ".", 0);
1789         if(dot1 == -1)
1790                 s1 = v1;
1791         else
1792                 s1 = substring(v1, 0, dot1);
1793         if(dot2 == -1)
1794                 s2 = v2;
1795         else
1796                 s2 = substring(v2, 0, dot2);
1797
1798         r = stof(s1) - stof(s2);
1799         if(r != 0)
1800                 return r;
1801
1802         r = strcasecmp(s1, s2);
1803         if(r != 0)
1804                 return r;
1805
1806         if(dot1 == -1)
1807                 if(dot2 == -1)
1808                         return 0;
1809                 else
1810                         return -1;
1811         else
1812                 if(dot2 == -1)
1813                         return 1;
1814                 else
1815                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1816 }
1817
1818 float vercmp(string v1, string v2)
1819 {
1820         if(strcasecmp(v1, v2) == 0) // early out check
1821                 return 0;
1822         return vercmp_recursive(v1, v2);
1823 }
1824
1825 void ObserverThink()
1826 {
1827         if (self.flags & FL_JUMPRELEASED) {
1828                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1829                         self.welcomemessage_time = 0;
1830                         self.flags = self.flags - FL_JUMPRELEASED;
1831                         LeaveSpectatorMode();
1832                         return;
1833                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1834                         self.welcomemessage_time = 0;
1835                         self.flags = self.flags - FL_JUMPRELEASED;
1836                         if(SpectateNext() == 1) {
1837                                 self.classname = "spectator";
1838                         }
1839                 }
1840         } else {
1841                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1842                         self.flags = self.flags | FL_JUMPRELEASED;
1843                 }
1844         }
1845         if(self.BUTTON_ZOOM)
1846                 self.wantswelcomemessage = 0;
1847         if(self.wantswelcomemessage)
1848                 PrintWelcomeMessage(self);
1849 }
1850
1851 void SpectatorThink()
1852 {
1853         if (self.flags & FL_JUMPRELEASED) {
1854                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1855                         self.welcomemessage_time = 0;
1856                         self.flags = self.flags - FL_JUMPRELEASED;
1857                         LeaveSpectatorMode();
1858                         return;
1859                 } else if(self.BUTTON_ATCK) {
1860                         self.welcomemessage_time = 0;
1861                         self.flags = self.flags - FL_JUMPRELEASED;
1862                         if(SpectateNext() == 1) {
1863                                 self.classname = "spectator";
1864                         } else {
1865                                 self.classname = "observer";
1866                                 PutClientInServer();
1867                         }
1868                 } else if (self.BUTTON_ATCK2) {
1869                         self.welcomemessage_time = 0;
1870                         self.flags = self.flags - FL_JUMPRELEASED;
1871                         self.classname = "observer";
1872                         PutClientInServer();
1873                 } else {
1874                         if(!SpectateUpdate())
1875                                 PutObserverInServer();
1876                 }
1877         } else {
1878                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1879                         self.flags = self.flags | FL_JUMPRELEASED;
1880                 }
1881         }
1882         if(self.BUTTON_ZOOM)
1883                 self.wantswelcomemessage = 0;
1884         if(self.wantswelcomemessage)
1885                 PrintWelcomeMessage(self);
1886         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1887 }
1888
1889 /*
1890 =============
1891 PlayerPreThink
1892
1893 Called every frame for each client before the physics are run
1894 =============
1895 */
1896 void() ctf_setstatus;
1897 .float vote_nagtime;
1898 void PlayerPreThink (void)
1899 {
1900         if(blockSpectators)
1901                 checkSpectatorBlock();
1902
1903         if(self.netname_previous != self.netname)
1904         {
1905                 if(cvar("sv_eventlog"))
1906                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1907                 if(self.netname_previous)
1908                         strunzone(self.netname_previous);
1909                 self.netname_previous = strzone(self.netname);
1910         }
1911
1912         // version nagging
1913         if(self.version_nagtime)
1914                 if(self.cvar_g_nexuizversion)
1915                         if(time > self.version_nagtime)
1916                         {
1917                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1918                                 {
1919                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1920                                         {
1921                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1922                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1923                                         }
1924                                         else
1925                                         {
1926                                                 float r;
1927                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1928                                                 if(r < 0)
1929                                                 {
1930                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1931                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1932                                                 }
1933                                                 else if(r > 0)
1934                                                 {
1935                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1936                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1937                                                 }
1938                                         }
1939                                 }
1940                                 self.version_nagtime = 0;
1941                         }
1942
1943         // vote nagging
1944         if(self.cvar_scr_centertime)
1945                 if(time > self.vote_nagtime)
1946                 {
1947                         VoteNag();
1948                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1949                 }
1950
1951         // GOD MODE info
1952         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1953         {
1954                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1955                 self.max_armorvalue = 0;
1956         }
1957
1958         if(frametime)
1959                 antilag_record(self);
1960
1961         if(self.classname == "player") {
1962 //              if(self.netname == "Wazat")
1963 //                      bprint(self.classname, "\n");
1964
1965                 CheckRules_Player();
1966
1967                 if(self.BUTTON_INFO)
1968                         PrintWelcomeMessage(self);
1969
1970                 if(g_lms || !cvar("sv_spectate"))
1971                 if((time - self.jointime) <= cvar("welcome_message_time"))
1972                         PrintWelcomeMessage(self);
1973
1974                 if (intermission_running)
1975                 {
1976                         IntermissionThink ();   // otherwise a button could be missed between
1977                         return;                                 // the think tics
1978                 }
1979
1980                 if(self.teleport_time)
1981                 if(time > self.teleport_time)
1982                 {
1983                         self.teleport_time = 0;
1984                         self.effects = self.effects - (self.effects & EF_NODRAW);
1985                         if(self.weaponentity)
1986                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1987                 }
1988
1989                 Nixnex_GiveCurrentWeapon();
1990
1991                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1992                         UpdateSelectedPlayer();
1993
1994                 //don't allow the player to turn around while game is paused!
1995                 if(timeoutStatus == 2) {
1996                         self.v_angle = self.lastV_angle;
1997                         self.angles = self.lastV_angle;
1998                         self.fixangle = TRUE;
1999                 }
2000
2001                 if (self.deadflag != DEAD_NO)
2002                 {
2003                         float button_pressed, force_respawn;
2004                         player_anim();
2005                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2006                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2007                         if (self.deadflag == DEAD_DYING)
2008                         {
2009                                 if(force_respawn)
2010                                         self.deadflag = DEAD_RESPAWNING;
2011                                 else if(!button_pressed)
2012                                         self.deadflag = DEAD_DEAD;
2013                         }
2014                         else if (self.deadflag == DEAD_DEAD)
2015                         {
2016                                 if(button_pressed)
2017                                         self.deadflag = DEAD_RESPAWNABLE;
2018                         }
2019                         else if (self.deadflag == DEAD_RESPAWNABLE)
2020                         {
2021                                 if(!button_pressed)
2022                                         self.deadflag = DEAD_RESPAWNING;
2023                         }
2024                         else if (self.deadflag == DEAD_RESPAWNING)
2025                         {
2026                                 if(time > self.death_time)
2027                                 {
2028                                         self.death_time = time + 1; // only retry once a second
2029                                         respawn();
2030                                 }
2031                         }
2032                         ShowRespawnCountdown();
2033                         return;
2034                 }
2035
2036                 if((g_race || g_lms) && !self.deadflag && cvar("g_lms_campcheck_interval"))
2037                 {
2038                         vector dist;
2039
2040                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2041                         dist = self.oldorigin - self.origin;
2042                         dist_z = 0;
2043                         self.lms_traveled_distance += fabs(vlen(dist));
2044
2045                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2046                         {
2047                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2048                                 self.lms_traveled_distance = 0;
2049                         }
2050
2051                         if(time > self.lms_nextcheck)
2052                         {
2053                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2054                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2055                                 {
2056                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2057                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2058                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2059                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2060                                 }
2061                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2062                                 self.lms_traveled_distance = 0;
2063                         }
2064                 }
2065
2066                 if (self.BUTTON_CROUCH && !self.hook.state)
2067                 {
2068                         if (!self.crouch)
2069                         {
2070                                 self.crouch = TRUE;
2071                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2072                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2073                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2074                         }
2075                 }
2076                 else
2077                 {
2078                         if (self.crouch)
2079                         {
2080                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2081                                 if (!trace_startsolid)
2082                                 {
2083                                         self.crouch = FALSE;
2084                                         self.view_ofs = PL_VIEW_OFS;
2085                                         setsize (self, PL_MIN, PL_MAX);
2086                                 }
2087                         }
2088                 }
2089
2090                 FixPlayermodel();
2091
2092                 GrapplingHookFrame();
2093
2094                 W_WeaponFrame();
2095
2096                 {
2097                         float zoomfactor, zoomspeed, zoomdir;
2098                         zoomfactor = self.cvar_cl_zoomfactor;
2099                         if(zoomfactor < 1 || zoomfactor > 16)
2100                                 zoomfactor = 2.5;
2101                         zoomspeed = self.cvar_cl_zoomspeed;
2102                         if(zoomspeed >= 0) // < 0 is instant zoom
2103                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2104                                         zoomspeed = 3.5;
2105
2106                         zoomdir = self.BUTTON_ZOOM;
2107                         if(self.BUTTON_ATCK2)
2108                                 if(self.weapon == WEP_NEX)
2109                                         if(!g_minstagib)
2110                                                 zoomdir = 1;
2111
2112                         if(zoomdir)
2113                                 self.has_zoomed = 1;
2114
2115                         if(self.has_zoomed)
2116                         {
2117                                 if(zoomspeed <= 0) // instant zoom
2118                                 {
2119                                         if(zoomdir)
2120                                                 self.viewzoom = 1 / zoomfactor;
2121                                         else
2122                                                 self.viewzoom = 1;
2123                                 }
2124                                 else
2125                                 {
2126                                         // geometric zoom would be:
2127                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2128                                         // however, testing showed that arithmetic/harmonic zoom works better
2129                                         if(zoomdir)
2130                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2131                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2132                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2133                                         else
2134                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2135                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2136                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2137                                 }
2138                         }
2139                         else
2140                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2141                 }
2142
2143                 player_powerups();
2144                 player_regen();
2145                 player_anim();
2146
2147                 if (g_minstagib)
2148                         minstagib_ammocheck();
2149
2150                 ctf_setstatus();
2151                 kh_setstatus();
2152
2153                 //self.angles_y=self.v_angle_y + 90;   // temp
2154
2155                 //if (TetrisPreFrame()) return;
2156         } else if(gameover) {
2157                 if (intermission_running)
2158                         IntermissionThink ();   // otherwise a button could be missed between
2159                 return;
2160         } else if(self.classname == "observer") {
2161                 ObserverThink();
2162         } else if(self.classname == "spectator") {
2163                 SpectatorThink();
2164         }
2165 }
2166
2167
2168 /*
2169 =============
2170 PlayerPostThink
2171
2172 Called every frame for each client after the physics are run
2173 =============
2174 */
2175 .float idlekick_lasttimeleft;
2176 void PlayerPostThink (void)
2177 {
2178         // Savage: Check for nameless players
2179         if (strlen(self.netname) < 1) {
2180                 self.netname = "Player";
2181                 stuffcmd(self, "seta _cl_name Player\n");
2182         }
2183
2184         if(sv_maxidle)
2185         {
2186                 float timeleft;
2187                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2188                 if(timeleft <= 0)
2189                 {
2190                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2191                         announce(self, "announcer/robotic/terminated.ogg");
2192                         dropclient(self);
2193                         return;
2194                 }
2195                 else if(timeleft <= 10)
2196                 {
2197                         if(timeleft != self.idlekick_lasttimeleft)
2198                         {
2199                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2200                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2201                         }
2202                 }
2203                 else
2204                 {
2205                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2206                 }
2207                 self.idlekick_lasttimeleft = timeleft;
2208         }
2209
2210         if(self.classname == "player") {
2211                 CheckRules_Player();
2212                 UpdateChatBubble();
2213                 UpdateTeamBubble();
2214                 if (self.impulse)
2215                         ImpulseCommands();
2216                 if (intermission_running)
2217                         return;         // intermission or finale
2218
2219                 //PrintWelcomeMessage(self);
2220                 //if (TetrisPostFrame()) return;
2221
2222                 // restart countdown
2223                 if (restart_countdown) {
2224                         if(time < restart_countdown) {
2225                                 if (!cvar("sv_ready_restart_after_countdown"))
2226                                 {
2227                                         self.movetype = MOVETYPE_NONE;
2228                                         self.velocity = '0 0 0';
2229                                         self.avelocity = '0 0 0';
2230                                         self.movement = '0 0 0';
2231                                 }
2232                         }
2233                         else
2234                         {
2235                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2236                                 if (!cvar("sv_ready_restart_after_countdown"))
2237                                 {
2238                                         if(self.movetype == MOVETYPE_NONE)
2239                                         {
2240                                                 self.movetype = MOVETYPE_WALK;
2241                                         }
2242                                 }
2243                         }
2244                 }
2245
2246         } else if (self.classname == "observer") {
2247                 //do nothing
2248         } else if (self.classname == "spectator") {
2249                 //do nothing
2250         }
2251
2252         /*
2253         float i;
2254         for(i = 0; i < 1000; ++i)
2255         {
2256                 vector end;
2257                 end = self.origin + '0 0 1024' + 512 * randomvec();
2258                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2259                 if(trace_fraction < 1)
2260                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2261                 {
2262                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2263                         break;
2264                 }
2265         }
2266         */
2267
2268         Arena_Warmup();
2269 }