data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         // filter out spots for assault
  47         if(spot.target != "") {
  48                 local entity ent;
  49                 ent = find(world, targetname, spot.target);
  50                 while(ent) {
  51                         if(ent.classname == "target_objective")
  52                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  53                                         return -1;
  54                         ent = find(ent, targetname, spot.target);
  55                 }
  56         }
  57
  58         player = playerlist;
  59         shortest = vlen(world.maxs - world.mins);
  60         for(player = playerlist; player; player = player.chain)
  61                 if (player != self)
  62                 {
  63                         thisdist = vlen(player.origin - spot.origin);
  64                         if (thisdist < shortest)
  65                                 shortest = thisdist;
  66                 }
  67         return shortest;
  68 }
  69
  70 float spawn_allbad;
  71 float spawn_allgood;
  72 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  73 {
  74         local entity spot, spotlist, spotlistend;
  75         spawn_allgood = TRUE;
  76         spawn_allbad = TRUE;
  77
  78         spotlist = world;
  79         spotlistend = world;
  80
  81         for(spot = firstspot; spot; spot = spot.chain)
  82         {
  83                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
  84
  85                 if(cvar("spawn_debugview"))
  86                 {
  87                         setmodel(spot, "models/runematch/rune.mdl");
  88                         if(spot.SPAWNPOINT_SCORE < mindist)
  89                         {
  90                                 spot.colormod = '1 0 0';
  91                                 spot.scale = 1;
  92                         }
  93                         else
  94                         {
  95                                 spot.colormod = '0 1 0';
  96                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
  97                         }
  98                 }
  99
 100                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 101                 {
 102                         if(spot.SPAWNPOINT_SCORE < mindist)
 103                         {
 104                                 // too short distance
 105                                 spawn_allgood = FALSE;
 106                         }
 107                         else
 108                         {
 109                                 // perfect
 110                                 spawn_allbad = FALSE;
 111
 112                                 if(spotlistend)
 113                                         spotlistend.chain = spot;
 114                                 spotlistend = spot;
 115                                 if(!spotlist)
 116                                         spotlist = spot;
 117
 118                                 /*
 119                                 if(teamcheck)
 120                                 if(spot.team != teamcheck)
 121                                         error("invalid spawn added");
 122
 123                                 print("added ", etos(spot), "\n");
 124                                 */
 125                         }
 126                 }
 127         }
 128         if(spotlistend)
 129                 spotlistend.chain = world;
 130
 131         /*
 132                 entity e;
 133                 if(teamcheck)
 134                         for(e = spotlist; e; e = e.chain)
 135                         {
 136                                 print("seen ", etos(e), "\n");
 137                                 if(e.team != teamcheck)
 138                                         error("invalid spawn found");
 139                         }
 140         */
 141
 142         return spotlist;
 143 }
 144
 145 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 146 {
 147         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 148         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 149         local entity spot;
 150
 151         RandomSelection_Init();
 152         for(spot = firstspot; spot; spot = spot.chain)
 153                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 154
 155         return RandomSelection_chosen_ent;
 156 }
 157
 158 /*
 159 =============
 160 SelectSpawnPoint
 161
 162 Finds a point to respawn
 163 =============
 164 */
 165 entity SelectSpawnPoint (float anypoint)
 166 {
 167         local float teamcheck;
 168         local entity firstspot_new;
 169         local entity spot, firstspot, playerlist;
 170
 171         spot = find (world, classname, "testplayerstart");
 172         if (spot)
 173                 return spot;
 174
 175         teamcheck = 0;
 176
 177         if(!anypoint && have_team_spawns)
 178                 teamcheck = self.team;
 179
 180         // get the list of players
 181         playerlist = findchain(classname, "player");
 182         // get the entire list of spots
 183         firstspot = findchain(classname, "info_player_deathmatch");
 184         // filter out the bad ones
 185         // (note this returns the original list if none survived)
 186         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 187         if(!firstspot_new)
 188                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 189         firstspot = firstspot_new;
 190
 191         // there is 50/50 chance of choosing a random spot or the furthest spot
 192         // (this means that roughly every other spawn will be furthest, so you
 193         // usually won't get fragged at spawn twice in a row)
 194         if (arena_roundbased)
 195         {
 196                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 197                 if(firstspot_new)
 198                         firstspot = firstspot_new;
 199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 200         }
 201         else if (random() > cvar("g_spawn_furthest"))
 202                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 203         else
 204                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 205
 206         if(cvar("spawn_debugview"))
 207         {
 208                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 209
 210                 entity e;
 211                 if(teamcheck)
 212                         for(e = firstspot; e; e = e.chain)
 213                                 if(e.team != teamcheck)
 214                                         error("invalid spawn found");
 215         }
 216
 217         if (!spot)
 218         {
 219                 if(cvar("spawn_debug"))
 220                         GotoNextMap();
 221                 else
 222                 {
 223                         if(some_spawn_has_been_used)
 224                                 return world; // team can't spawn any more, because of actions of other team
 225                         else
 226                                 error("Cannot find a spawn point - please fix the map!");
 227                 }
 228         }
 229
 230         return spot;
 231 }
 232
 233 /*
 234 =============
 235 CheckPlayerModel
 236
 237 Checks if the argument string can be a valid playermodel.
 238 Returns a valid one in doubt.
 239 =============
 240 */
 241 string FallbackPlayerModel = "models/player/marine.zym";
 242 string CheckPlayerModel(string plyermodel) {
 243         if(strlen(plyermodel) < 4)
 244                 return FallbackPlayerModel;
 245         if( substring(plyermodel,0,14) != "models/player/")
 246                 return FallbackPlayerModel;
 247         else if(cvar("sv_servermodelsonly"))
 248         {
 249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 250                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 251                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 252                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 253                         return FallbackPlayerModel;
 254                 if(!fexists(plyermodel))
 255                         return FallbackPlayerModel;
 256         }
 257         return plyermodel;
 258 }
 259
 260 /*
 261 =============
 262 Client_customizeentityforclient
 263
 264 LOD reduction
 265 =============
 266 */
 267 float Client_customizeentityforclient()
 268 {
 269 #ifdef ALLOW_VARIABLE_LOD
 270         // self: me
 271         // other: the player viewing me
 272         float distance;
 273         float f;
 274
 275         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 276                 return TRUE;
 277
 278         if(other.cvar_cl_playerdetailreduction <= 0)
 279         {
 280                 if(other.cvar_cl_playerdetailreduction <= -2)
 281                         self.modelindex = self.modelindex_lod2;
 282                 else if(other.cvar_cl_playerdetailreduction <= -1)
 283                         self.modelindex = self.modelindex_lod1;
 284                 else
 285                         self.modelindex = self.modelindex_lod0;
 286         }
 287         else
 288         {
 289                 distance = vlen(self.origin - other.origin);
 290                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 291                 if(f > 10000)
 292                         self.modelindex = self.modelindex_lod2;
 293                 else if(f > 5000)
 294                         self.modelindex = self.modelindex_lod1;
 295                 else
 296                         self.modelindex = self.modelindex_lod0;
 297         }
 298 #endif
 299
 300         return TRUE;
 301 }
 302
 303 void UpdatePlayerSounds();
 304 void setmodel_lod(entity e, string modelname)
 305 {
 306 #ifdef ALLOW_VARIABLE_LOD
 307         string s;
 308
 309         // FIXME: this only supports 3-letter extensions
 310         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 311         if(fexists(s))
 312         {
 313                 precache_model(s);
 314                 setmodel(e, s); // players have high precision
 315                 self.modelindex_lod1 = self.modelindex;
 316         }
 317         else
 318                 self.modelindex_lod1 = -1;
 319
 320         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 321         if(fexists(s))
 322         {
 323                 precache_model(s);
 324                 setmodel(e, s); // players have high precision
 325                 self.modelindex_lod2 = self.modelindex;
 326         }
 327         else
 328                 self.modelindex_lod2 = -1;
 329
 330         precache_model(modelname);
 331         setmodel(e, modelname); // players have high precision
 332         self.modelindex_lod0 = self.modelindex;
 333
 334         if(self.modelindex_lod1 < 0)
 335                 self.modelindex_lod1 = self.modelindex;
 336
 337         if(self.modelindex_lod2 < 0)
 338                 self.modelindex_lod2 = self.modelindex;
 339 #else
 340         precache_model(modelname);
 341         setmodel(e, modelname); // players have high precision
 342 #endif
 343         player_setupanimsformodel();
 344         UpdatePlayerSounds();
 345 }
 346
 347 /*
 348 =============
 349 PutObserverInServer
 350
 351 putting a client as observer in the server
 352 =============
 353 */
 354 void PutObserverInServer (void)
 355 {
 356         entity  spot;
 357         spot = SelectSpawnPoint (TRUE);
 358         if(!spot)
 359                 error("No spawnpoints for observers?!?\n");
 360         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 361
 362         if(clienttype(self) == CLIENTTYPE_REAL)
 363         {
 364                 msg_entity = self;
 365                 WriteByte(MSG_ONE, SVC_SETVIEW);
 366                 WriteEntity(MSG_ONE, self);
 367         }
 368
 369         DropAllRunes(self);
 370         kh_Key_DropAll(self, TRUE);
 371
 372         if(self.flagcarried)
 373                 DropFlag(self.flagcarried);
 374
 375         WaypointSprite_PlayerDead();
 376
 377         if(self.killcount != -666)
 378         {
 379                 if(g_lms)
 380                 {
 381                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 382                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 383                         else
 384                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 385                 }
 386                 else
 387                         bprint ("^4", self.netname, "^4 is spectating now\n");
 388         }
 389
 390         PlayerScore_Clear(self); // clear scores when needed
 391
 392         self.spectatortime = time;
 393
 394         self.classname = "observer";
 395         self.health = -666;
 396         self.takedamage = DAMAGE_NO;
 397         self.solid = SOLID_NOT;
 398         self.movetype = MOVETYPE_NOCLIP;
 399         self.flags = FL_CLIENT | FL_NOTARGET;
 400         self.armorvalue = 666;
 401         self.effects = 0;
 402         self.armorvalue = cvar("g_balance_armor_start");
 403         self.pauserotarmor_finished = 0;
 404         self.pauserothealth_finished = 0;
 405         self.pauseregen_finished = 0;
 406         self.damageforcescale = 0;
 407         self.death_time = 0;
 408         self.dead_frame = 0;
 409         self.alpha = 0;
 410         self.scale = 0;
 411         self.fade_time = 0;
 412         self.pain_frame = 0;
 413         self.pain_finished = 0;
 414         self.strength_finished = 0;
 415         self.invincible_finished = 0;
 416         self.pushltime = 0;
 417         self.think = SUB_Null;
 418         self.nextthink = 0;
 419         self.hook_time = 0;
 420         self.runes = 0;
 421         self.deadflag = DEAD_NO;
 422         self.angles = spot.angles;
 423         self.angles_z = 0;
 424         self.fixangle = TRUE;
 425         self.crouch = FALSE;
 426
 427         self.view_ofs = PL_VIEW_OFS;
 428         setorigin (self, spot.origin);
 429         setsize (self, '0 0 0', '0 0 0');
 430         self.oldorigin = self.origin;
 431         self.items = 0;
 432         self.model = "";
 433         self.modelindex = 0;
 434         self.weapon = 0;
 435         self.weaponmodel = "";
 436         self.weaponentity = world;
 437         self.killcount = -666;
 438         self.velocity = '0 0 0';
 439         self.avelocity = '0 0 0';
 440         self.punchangle = '0 0 0';
 441         self.punchvector = '0 0 0';
 442         self.oldvelocity = self.velocity;
 443         self.customizeentityforclient = Client_customizeentityforclient;
 444         self.viewzoom = 1;
 445         self.wantswelcomemessage = 1;
 446
 447         if(g_arena)
 448         {
 449                 if(self.frags != -2)
 450                 {
 451                         Spawnqueue_Insert(self);
 452                         // FIXME what IS this?
 453                 }
 454                 else
 455                 {
 456                         Spawnqueue_Unmark(self);
 457                         Spawnqueue_Remove(self);
 458                 }
 459         }
 460         else if(g_lms)
 461         {
 462                 // Only if the player cannot play at all
 463                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 464                         self.frags = -666;
 465                 else
 466                         self.frags = -667;
 467         }
 468         else
 469                 self.frags = -666;
 470 }
 471
 472 float RestrictSkin(float s)
 473 {
 474         if(!teams_matter)
 475                 return s;
 476         if(s == 6)
 477                 return 6;
 478         return mod(s, 3);
 479 }
 480
 481 void FixPlayermodel()
 482 {
 483         local string defaultmodel;
 484         local float defaultskin;
 485         local vector m1, m2;
 486
 487         defaultmodel = "";
 488
 489         if(cvar("sv_defaultcharacter") == 1) {
 490                 defaultskin = 0;
 491
 492                 if(teams_matter)
 493                 {
 494                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 495                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 496                 }
 497
 498                 if(defaultmodel == "")
 499                 {
 500                         defaultmodel = cvar_string("sv_defaultplayermodel");
 501                         defaultskin = cvar("sv_defaultplayerskin");
 502                 }
 503         }
 504
 505         if(defaultmodel != "")
 506         {
 507                 if (defaultmodel != self.model)
 508                 {
 509                         m1 = self.mins;
 510                         m2 = self.maxs;
 511                         setmodel_lod (self, defaultmodel);
 512                         setsize (self, m1, m2);
 513                 }
 514
 515                 self.skin = defaultskin;
 516         } else {
 517                 if (self.playermodel != self.model)
 518                 {
 519                         self.playermodel = CheckPlayerModel(self.playermodel);
 520                         m1 = self.mins;
 521                         m2 = self.maxs;
 522                         setmodel_lod (self, self.playermodel);
 523                         setsize (self, m1, m2);
 524                 }
 525
 526                 self.skin = RestrictSkin(stof(self.playerskin));
 527         }
 528
 529         if(!teams_matter)
 530                 if(strlen(cvar_string("sv_defaultplayercolors")))
 531                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 532                                 setcolor(self, cvar("sv_defaultplayercolors"));
 533 }
 534
 535 /*
 536 =============
 537 PutClientInServer
 538
 539 Called when a client spawns in the server
 540 =============
 541 */
 542 //void() ctf_playerchanged;
 543 void PutClientInServer (void)
 544 {
 545         if(clienttype(self) == CLIENTTYPE_BOT)
 546         {
 547                 self.classname = "player";
 548         }
 549         else if(clienttype(self) == CLIENTTYPE_REAL)
 550         {
 551                 msg_entity = self;
 552                 WriteByte(MSG_ONE, SVC_SETVIEW);
 553                 WriteEntity(MSG_ONE, self);
 554         }
 555
 556         // player is dead and becomes observer
 557         // FIXME fix LMS scoring for new system
 558         if(g_lms)
 559         {
 560                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 561                         self.classname = "observer";
 562         }
 563
 564         if(g_arena)
 565         if(!self.spawned)
 566                 self.classname = "observer";
 567
 568         if(self.classname == "player") {
 569                 entity  spot;
 570
 571                 spot = SelectSpawnPoint (FALSE);
 572                 if(!spot)
 573                 {
 574                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 575                         return; // spawn failed
 576                 }
 577
 578                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 579
 580                 self.classname = "player";
 581                 self.iscreature = TRUE;
 582                 self.movetype = MOVETYPE_WALK;
 583                 self.solid = SOLID_SLIDEBOX;
 584                 self.flags = FL_CLIENT;
 585                 self.takedamage = DAMAGE_AIM;
 586                 if(g_minstagib)
 587                         self.effects = EF_FULLBRIGHT;
 588                 else
 589                         self.effects = 0;
 590                 self.air_finished = time + 12;
 591                 self.dmg = 2;
 592
 593                 self.ammo_shells = start_ammo_shells;
 594                 self.ammo_nails = start_ammo_nails;
 595                 self.ammo_rockets = start_ammo_rockets;
 596                 self.ammo_cells = start_ammo_cells;
 597                 self.health = start_health;
 598                 self.armorvalue = start_armorvalue;
 599                 self.items = start_items;
 600                 self.switchweapon = start_switchweapon;
 601                 self.cnt = start_switchweapon;
 602                 self.weapon = 0;
 603                 self.jump_interval = time;
 604
 605                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 606                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 607                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 608                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 609                 //extend the pause of rotting if client was reset at the beginning of the countdown
 610                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 611                         self.spawnshieldtime += RESTART_COUNTDOWN;
 612                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 613                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 614                         self.pauseregen_finished += RESTART_COUNTDOWN;
 615                 }
 616                 self.damageforcescale = 2;
 617                 self.death_time = 0;
 618                 self.dead_frame = 0;
 619                 self.alpha = 0;
 620                 self.scale = 0;
 621                 self.fade_time = 0;
 622                 self.pain_frame = 0;
 623                 self.pain_finished = 0;
 624                 self.strength_finished = 0;
 625                 self.invincible_finished = 0;
 626                 self.pushltime = 0;
 627                 //self.speed_finished = 0;
 628                 //self.slowmo_finished = 0;
 629                 // players have no think function
 630                 self.think = SUB_Null;
 631                 self.nextthink = 0;
 632                 self.hook_time = 0;
 633
 634                 self.runes = 0;
 635
 636                 self.deadflag = DEAD_NO;
 637
 638                 self.angles = spot.angles;
 639
 640                 self.angles_z = 0; // never spawn tilted even if the spot says to
 641                 self.fixangle = TRUE; // turn this way immediately
 642                 self.velocity = '0 0 0';
 643                 self.avelocity = '0 0 0';
 644                 self.punchangle = '0 0 0';
 645                 self.punchvector = '0 0 0';
 646                 self.oldvelocity = self.velocity;
 647
 648                 self.viewzoom = 0.6;
 649                 self.has_zoomed = 0;
 650
 651                 self.customizeentityforclient = Client_customizeentityforclient;
 652
 653                 self.model = "";
 654                 FixPlayermodel();
 655
 656                 self.crouch = FALSE;
 657                 self.view_ofs = PL_VIEW_OFS;
 658                 setsize (self, PL_MIN, PL_MAX);
 659                 self.spawnorigin = spot.origin;
 660                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 661                 // don't reset back to last position, even if new position is stuck in solid
 662                 self.oldorigin = self.origin;
 663
 664                 if(g_arena)
 665                 {
 666                         Spawnqueue_Remove(self);
 667                         Spawnqueue_Mark(self);
 668                 }
 669
 670                 self.event_damage = PlayerDamage;
 671
 672                 self.bot_attack = TRUE;
 673
 674                 self.statdraintime = time + 5;
 675                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 676
 677                 if(self.killcount == -666) {
 678                         PlayerScore_Clear(self);
 679                         self.killcount = 0;
 680                         self.frags = 0;
 681                 }
 682
 683                 self.cnt = WEP_LASER;
 684                 self.nixnex_lastchange_id = -1;
 685
 686                 CL_SpawnWeaponentity();
 687                 self.alpha = default_player_alpha;
 688                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 689                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 690
 691                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 692                 self.lms_traveled_distance = 0;
 693                 self.speedrunning = FALSE;
 694
 695                 if(cvar("spawn_debug"))
 696                 {
 697                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 698                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 699                 }
 700
 701                 //stuffcmd(self, "chase_active 0");
 702                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 703
 704                 if (cvar("g_spawnsound"))
 705                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 706
 707                 if(g_assault) {
 708                         if(self.team == assault_attacker_team)
 709                                 centerprint(self, "You are attacking!\n");
 710                         else
 711                                 centerprint(self, "You are defending!\n");
 712                 }
 713
 714         } else if(self.classname == "observer") {
 715                 PutObserverInServer ();
 716         }
 717
 718         //if(g_ctf)
 719         //      ctf_playerchanged();
 720 }
 721
 722 /*
 723 =============
 724 SendCSQCInfo
 725
 726 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 727 =============
 728 */
 729 void SendCSQCInfo(void)
 730 {
 731         if(clienttype(self) != CLIENTTYPE_REAL)
 732                 return;
 733         msg_entity = self;
 734         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 735         WriteByte(MSG_ONE, TE_CSQC_INIT);
 736         WriteShort(MSG_ONE, CSQC_REVISION);
 737         WriteByte(MSG_ONE, maxclients);
 738 }
 739
 740 /*
 741 =============
 742 SetNewParms
 743 =============
 744 */
 745 void SetNewParms (void)
 746 {
 747         // initialize parms for a new player
 748         parm1 = -(86400 * 366);
 749 }
 750
 751 /*
 752 =============
 753 SetChangeParms
 754 =============
 755 */
 756 void SetChangeParms (void)
 757 {
 758         // save parms for level change
 759         parm1 = self.parm_idlesince - time;
 760 }
 761
 762 /*
 763 =============
 764 DecodeLevelParms
 765 =============
 766 */
 767 void DecodeLevelParms (void)
 768 {
 769         // load parms
 770         self.parm_idlesince = parm1;
 771         if(self.parm_idlesince == -(86400 * 366))
 772                 self.parm_idlesince = time;
 773 }
 774
 775 /*
 776 =============
 777 ClientKill
 778
 779 Called when a client types 'kill' in the console
 780 =============
 781 */
 782
 783 void ClientKill_Now_TeamChange()
 784 {
 785         if(self.killindicator_teamchange == -1)
 786         {
 787                 self.team = -1;
 788                 JoinBestTeam( self, FALSE, FALSE );
 789         }
 790         else
 791         {
 792                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 793         }
 794 }
 795
 796 void ClientKill_Now()
 797 {
 798         if(self.killindicator_teamchange)
 799                 ClientKill_Now_TeamChange();
 800
 801         // in any case:
 802         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 803 }
 804 void KillIndicator_Think()
 805 {
 806         if (!self.owner.modelindex)
 807         {
 808                 self.owner.killindicator = world;
 809                 remove(self);
 810                 return;
 811         }
 812
 813         if(self.cnt <= 0)
 814         {
 815                 self = self.owner;
 816                 ClientKill_Now(); // no oldself needed
 817                 return;
 818         }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 824                 {
 825                         if(self.cnt <= 10)
 826                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 827                         if(self.owner.killindicator_teamchange)
 828                         {
 829                                 if(self.owner.killindicator_teamchange == -1)
 830                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 831                                 else
 832                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 833                         }
 834                         else
 835                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 836                 }
 837                 self.nextthink = time + 1;
 838                 self.cnt -= 1;
 839         }
 840 }
 841
 842 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 843 {
 844         float killtime;
 845         entity e;
 846         killtime = cvar("g_balance_kill_delay");
 847
 848         self.killindicator_teamchange = targetteam;
 849
 850         if(!self.killindicator)
 851         {
 852                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 853                 {
 854                         ClientKill_Now();
 855                 }
 856                 else
 857                 {
 858                         self.killindicator = spawn();
 859                         self.killindicator.owner = self;
 860                         self.killindicator.scale = 0.5;
 861                         setattachment(self.killindicator, self, "");
 862                         setorigin(self.killindicator, '0 0 52');
 863                         self.killindicator.think = KillIndicator_Think;
 864                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 865                         self.killindicator.cnt = ceil(killtime);
 866                         self.killindicator.count = bound(0, ceil(killtime), 10);
 867                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 868
 869                         for(e = world; (e = find(e, classname, "body")) != world; )
 870                         {
 871                                 if(e.enemy != self)
 872                                         continue;
 873                                 e.killindicator = spawn();
 874                                 e.killindicator.owner = e;
 875                                 e.killindicator.scale = 0.5;
 876                                 setattachment(e.killindicator, e, "");
 877                                 setorigin(e.killindicator, '0 0 52');
 878                                 e.killindicator.think = KillIndicator_Think;
 879                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 880                                 e.killindicator.cnt = ceil(killtime);
 881                         }
 882                         self.lip = 0;
 883                 }
 884         }
 885         if(self.killindicator)
 886         {
 887                 if(targetteam)
 888                         self.killindicator.colormod = TeamColor(targetteam);
 889                 else
 890                         self.killindicator.colormod = '0 0 0';
 891         }
 892 }
 893
 894 void ClientKill (void)
 895 {
 896         ClientKill_TeamChange(0);
 897 }
 898
 899 void DoTeamChange(float destteam)
 900 {
 901         float t, c0;
 902         if(!cvar("teamplay"))
 903         {
 904                 if(destteam >= 0)
 905                         SetPlayerColors(self, destteam);
 906                 return;
 907         }
 908         if(self.classname == "player")
 909         if(destteam == -1)
 910         {
 911                 CheckAllowedTeams(self);
 912                 t = FindSmallestTeam(self, TRUE);
 913                 switch(self.team)
 914                 {
 915                         case COLOR_TEAM1: c0 = c1; break;
 916                         case COLOR_TEAM2: c0 = c2; break;
 917                         case COLOR_TEAM3: c0 = c3; break;
 918                         case COLOR_TEAM4: c0 = c4; break;
 919                         default:          c0 = 999;
 920                 }
 921                 switch(t)
 922                 {
 923                         case 1:
 924                                 if(c0 > c1)
 925                                         destteam = COLOR_TEAM1;
 926                                 break;
 927                         case 2:
 928                                 if(c0 > c2)
 929                                         destteam = COLOR_TEAM2;
 930                                 break;
 931                         case 3:
 932                                 if(c0 > c3)
 933                                         destteam = COLOR_TEAM3;
 934                                 break;
 935                         case 4:
 936                                 if(c0 > c4)
 937                                         destteam = COLOR_TEAM4;
 938                                 break;
 939                 }
 940                 if(destteam == -1)
 941                         return;
 942         }
 943         if(destteam == self.team && !self.killindicator)
 944                 return;
 945         ClientKill_TeamChange(destteam);
 946 }
 947
 948 void FixClientCvars(entity e)
 949 {
 950         // send prediction settings to the client
 951         stuffcmd(e, "\nin_bindmap 0 0\n");
 952         /*
 953          * we no longer need to stuff this. Remove this comment block if you feel
 954          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 955         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 956         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 957         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 958         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 959         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 960         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 961         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 962         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 963         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 964         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 965         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 966         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 967         stuffcmd(e, "cl_movement_edgefriction 1\n");
 968          */
 969 }
 970
 971 /*
 972 =============
 973 ClientConnect
 974
 975 Called when a client connects to the server
 976 =============
 977 */
 978 //void ctf_clientconnect();
 979 string ColoredTeamName(float t);
 980 void DecodeLevelParms (void);
 981 //void dom_player_join_team(entity pl);
 982 void ClientConnect (void)
 983 {
 984         local string s;
 985         float wep;
 986
 987         if(self.flags & FL_CLIENT)
 988         {
 989                 print("Warning: ClientConnect, but already connected!\n");
 990                 return;
 991         }
 992
 993         if(Ban_IsClientBanned(self))
 994         {
 995                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 996                 dropclient(self);
 997                 bprint(s);
 998                 return;
 999         }
1000
1001         DecodeLevelParms();
1002
1003         self.classname = "player_joining";
1004
1005         self.flags = self.flags | FL_CLIENT;
1006         self.version_nagtime = time + 10 + random() * 10;
1007
1008         if(player_count<0)
1009         {
1010                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1011                 player_count = 0;
1012         }
1013
1014         PlayerScore_Attach(self);
1015
1016         bot_clientconnect();
1017
1018         //if(g_domination)
1019         //      dom_player_join_team(self);
1020
1021         //JoinBestTeam(self, FALSE, FALSE);
1022
1023         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1024                 self.classname = "observer";
1025         } else {
1026                 self.classname = "player";
1027                 campaign_bots_may_start = 1;
1028         }
1029
1030         self.playerid = (playerid_last = playerid_last + 1);
1031         if(cvar("sv_eventlog"))
1032         {
1033                 if(clienttype(self) == CLIENTTYPE_REAL)
1034                         s = "player";
1035                 else
1036                         s = "bot";
1037                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1038                 s = strcat(":team:", ftos(self.playerid), ":");
1039                 s = strcat(s, ftos(self.team));
1040                 GameLogEcho(s, FALSE);
1041         }
1042         self.netname_previous = strzone(self.netname);
1043
1044         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1045
1046         bprint ("^4",self.netname);
1047         bprint ("^4 connected");
1048
1049         if(g_domination || g_ctf)
1050         {
1051                 bprint(" and joined the ");
1052                 bprint(ColoredTeamName(self.team));
1053         }
1054
1055         bprint("\n");
1056
1057         self.welcomemessage_time = 0;
1058
1059         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1060         // TODO: is this being used for anything else than cd tracks?
1061         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1062         //
1063         stuffcmd(self, "cl_particles_reloadeffects\n");
1064
1065         FixClientCvars(self);
1066
1067         // spawnfunc_waypoint sprites
1068         WaypointSprite_InitClient(self);
1069
1070         // Wazat's grappling hook
1071         SetGrappleHookBindings();
1072
1073         // get autoswitch state from player when he toggles it
1074         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1075
1076         // get version info from player
1077         stuffcmd(self, "cmd clientversion $gameversion\n");
1078
1079         // send all weapon info strings
1080         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1081         wep = WEP_FIRST;
1082         while (wep <= WEP_LAST)
1083         {
1084                 weapon_action(wep, WR_REGISTER);
1085                 wep = wep + 1;
1086         }
1087
1088         // get other cvars from player
1089         GetCvars(0);
1090
1091         // set cvar for team scoreboard
1092         if (teams_matter)
1093         {
1094                 local float t;
1095                 t = cvar("teamplay");
1096                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1097                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1098         }
1099         else
1100                 stuffcmd(self, "set teamplay 0\n");
1101
1102         // notify about available teams
1103         if(teamplay)
1104         {
1105                 CheckAllowedTeams(self);
1106                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1107                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1108         }
1109         else
1110                 stuffcmd(self, "set _teams_available 0\n");
1111
1112         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1113
1114         if(g_arena)
1115         {
1116                 self.classname = "observer";
1117                 Spawnqueue_Insert(self);
1118         }
1119         /*else if(g_ctf)
1120         {
1121                 ctf_clientconnect();
1122         }*/
1123
1124         if(entcs_start)
1125                 attach_entcs();
1126
1127         bot_relinkplayerlist();
1128
1129         self.spectatortime = time;
1130         if(blockSpectators)
1131         {
1132                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1133         }
1134
1135         self.jointime = time;
1136         self.allowedTimeouts = cvar("sv_timeout_number");
1137
1138         if(clienttype(self) == CLIENTTYPE_REAL)
1139         {
1140                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1141                 SendCSQCInfo();
1142                 msg_entity = self;
1143                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1144                 {
1145                         MapVote_SendData(MSG_ONE);
1146                         MapVote_UpdateData(MSG_ONE);
1147                 }
1148                 ScoreInfo_Write(MSG_ONE);
1149         }
1150
1151         if(g_lms)
1152         {
1153                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1154                 {
1155                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1156                         self.frags = -666; // FIXME do we still need this?
1157                 }
1158         }
1159 }
1160
1161 /*
1162 =============
1163 ClientDisconnect
1164
1165 Called when a client disconnects from the server
1166 =============
1167 */
1168 void(entity e) DropFlag;
1169 .entity chatbubbleentity;
1170 .entity teambubbleentity;
1171 //void() ctf_clientdisconnect;
1172 void ClientDisconnect (void)
1173 {
1174         float save;
1175
1176         if not(self.flags & FL_CLIENT)
1177         {
1178                 print("Warning: ClientDisconnect without ClientConnect\n");
1179                 return;
1180         }
1181
1182         bot_clientdisconnect();
1183
1184         if(entcs_start)
1185                 detach_entcs();
1186
1187         if(cvar("sv_eventlog"))
1188                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1189         bprint ("^4",self.netname);
1190         bprint ("^4 disconnected\n");
1191
1192         if (self.chatbubbleentity)
1193         {
1194                 remove (self.chatbubbleentity);
1195                 self.chatbubbleentity = world;
1196         }
1197
1198         if (self.teambubbleentity)
1199         {
1200                 remove (self.teambubbleentity);
1201                 self.teambubbleentity = world;
1202         }
1203
1204         if (self.killindicator)
1205         {
1206                 remove (self.killindicator);
1207                 self.killindicator = world;
1208         }
1209
1210         WaypointSprite_PlayerGone();
1211
1212         DropAllRunes(self);
1213         kh_Key_DropAll(self, TRUE);
1214
1215         if(self.flagcarried)
1216                 DropFlag(self.flagcarried);
1217
1218         save = self.flags;
1219         self.flags = self.flags - (self.flags & FL_CLIENT);
1220         bot_relinkplayerlist();
1221         self.flags = save;
1222
1223         // remove laserdot
1224         if(self.weaponentity)
1225                 if(self.weaponentity.lasertarget)
1226                         remove(self.weaponentity.lasertarget);
1227
1228         if(g_arena)
1229         {
1230                 Spawnqueue_Unmark(self);
1231                 Spawnqueue_Remove(self);
1232         }
1233         /*if(g_ctf)
1234         {
1235                 ctf_clientdisconnect();
1236         }
1237         */
1238
1239         PlayerScore_Detach(self);
1240
1241         if(self.netname_previous)
1242                 strunzone(self.netname_previous);
1243
1244         // free cvars
1245         GetCvars(-1);
1246         self.playerid = 0;
1247 }
1248
1249 .float BUTTON_CHAT;
1250 void ChatBubbleThink()
1251 {
1252         self.nextthink = time;
1253         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1254         {
1255                 self.owner.chatbubbleentity = world;
1256                 remove(self);
1257                 return;
1258         }
1259         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1260         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1261                 self.model = self.mdl;
1262         else
1263                 self.model = "";
1264 };
1265
1266 void UpdateChatBubble()
1267 {
1268         if (!self.modelindex)
1269                 return;
1270         // spawn a chatbubble entity if needed
1271         if (!self.chatbubbleentity)
1272         {
1273                 self.chatbubbleentity = spawn();
1274                 self.chatbubbleentity.owner = self;
1275                 self.chatbubbleentity.exteriormodeltoclient = self;
1276                 self.chatbubbleentity.think = ChatBubbleThink;
1277                 self.chatbubbleentity.nextthink = time;
1278                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1279                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1280                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1281                 self.chatbubbleentity.model = "";
1282                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1283         }
1284 }
1285
1286
1287 void TeamBubbleThink()
1288 {
1289         self.nextthink = time;
1290         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1291         {
1292                 self.owner.teambubbleentity = world;
1293                 remove(self);
1294                 return;
1295         }
1296 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1297         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1298                 self.model = "";
1299         else
1300                 self.model = self.mdl;
1301
1302 };
1303
1304 float TeamBubble_customizeentityforclient()
1305 {
1306         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1307 }
1308
1309 void UpdateTeamBubble()
1310 {
1311         if (!self.modelindex || !cvar("teamplay"))
1312                 return;
1313         // spawn a teambubble entity if needed
1314         if (!self.teambubbleentity && cvar("teamplay"))
1315         {
1316                 self.teambubbleentity = spawn();
1317                 self.teambubbleentity.owner = self;
1318                 self.teambubbleentity.exteriormodeltoclient = self;
1319                 self.teambubbleentity.think = TeamBubbleThink;
1320                 self.teambubbleentity.nextthink = time;
1321                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1322 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1323                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1324                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1325                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1326                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1327                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1328                 self.teambubbleentity.effects = EF_LOWPRECISION;
1329         }
1330 }
1331
1332 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1333 // added to the model skins
1334 /*void UpdateColorModHack()
1335 {
1336         local float c;
1337         c = self.clientcolors & 15;
1338         // LordHavoc: only bothering to support white, green, red, yellow, blue
1339              if (teamplay == 0) self.colormod = '0 0 0';
1340         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1341         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1342         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1343         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1344         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1345         else self.colormod = '1 1 1';
1346 };*/
1347
1348 void respawn(void)
1349 {
1350         CopyBody(1);
1351         self.effects |= EF_NODRAW; // prevent another CopyBody
1352         PutClientInServer();
1353 }
1354
1355 /**
1356  * When sv_timeout is used this function returs strings like
1357  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1358  * Called by centerprint functions
1359  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1360  */
1361 string getTimeoutText(float addOneSecond) {
1362         if (!cvar("sv_timeout") || !timeoutStatus)
1363                 return "";
1364
1365         local string retStr;
1366         if (timeoutStatus == 1) {
1367                 if (addOneSecond == 1) {
1368                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1369                 }
1370                 else {
1371                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1372                 }
1373                 return retStr;
1374         }
1375         else if (timeoutStatus == 2) {
1376                 if (addOneSecond) {
1377                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1378                         //don't show messages like "Timeout ends in 0 seconds"...
1379                         if ((remainingTimeoutTime + 1) > 0)
1380                                 return retStr;
1381                         else
1382                                 return "";
1383                 }
1384                 else {
1385                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1386                         //don't show messages like "Timeout ends in 0 seconds"...
1387                         if (remainingTimeoutTime > 0)
1388                                 return retStr;
1389                         else
1390                                 return "";
1391                 }
1392         }
1393         else return "";
1394 }
1395
1396 void player_powerups (void)
1397 {
1398         if (g_minstagib)
1399         {
1400                 if (self.items & IT_STRENGTH)
1401                 {
1402                         if (time > self.strength_finished)
1403                         {
1404                                 if (g_minstagib_invis_alpha > 0)
1405                                 {
1406                                         self.alpha = default_player_alpha;
1407                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1408                                         self.effects = self.effects | EF_FULLBRIGHT;
1409                                 }
1410                                 else
1411                                 {
1412                                         self.effects -= self.effects & EF_NODRAW;
1413                                 }
1414                                 self.items = self.items - (self.items & IT_STRENGTH);
1415                                 sprint(self, "^3Invisibility has worn off\n");
1416                         }
1417                 }
1418                 else
1419                 {
1420                         if (time < self.strength_finished)
1421                         {
1422                                 if (g_minstagib_invis_alpha > 0)
1423                                 {
1424                                         self.alpha = g_minstagib_invis_alpha;
1425                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1426                                         self.effects -= self.effects & EF_FULLBRIGHT;
1427                                 }
1428                                 else
1429                                 {
1430                                         self.effects = self.effects | EF_NODRAW;
1431                                 }
1432                                 self.items = self.items | IT_STRENGTH;
1433                                 sprint(self, "^3You are invisible\n");
1434                         }
1435                 }
1436
1437                 if (self.items & IT_INVINCIBLE)
1438                 {
1439                         if (time > self.invincible_finished)
1440                         {
1441                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1442                                 sprint(self, "^3Speed has worn off\n");
1443                         }
1444                 }
1445                 else
1446                 {
1447                         if (time < self.invincible_finished)
1448                         {
1449                                 self.items = self.items | IT_INVINCIBLE;
1450                                 sprint(self, "^3You are on speed\n");
1451                         }
1452                 }
1453                 return;
1454         }
1455
1456         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1457         if (self.items & IT_STRENGTH)
1458         {
1459                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1460                 if (time > self.strength_finished)
1461                 {
1462                         self.items = self.items - (self.items & IT_STRENGTH);
1463                         sprint(self, "^3Strength has worn off\n");
1464                 }
1465         }
1466         else
1467         {
1468                 if (time < self.strength_finished)
1469                 {
1470                         self.items = self.items | IT_STRENGTH;
1471                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1472                 }
1473         }
1474         if (self.items & IT_INVINCIBLE)
1475         {
1476                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1477                 if (time > self.invincible_finished)
1478                 {
1479                         self.items = self.items - (self.items & IT_INVINCIBLE);
1480                         sprint(self, "^3Shield has worn off\n");
1481                 }
1482         }
1483         else
1484         {
1485                 if (time < self.invincible_finished)
1486                 {
1487                         self.items = self.items | IT_INVINCIBLE;
1488                         sprint(self, "^3Shield surrounds you\n");
1489                 }
1490         }
1491
1492         if (cvar("g_fullbrightplayers"))
1493                 self.effects = self.effects | EF_FULLBRIGHT;
1494
1495         // midair gamemode: damage only while in the air
1496         // if in midair mode, being on ground grants temporary invulnerability
1497         // (this is so that multishot weapon don't clear the ground flag on the
1498         // first damage in the frame, leaving the player vulnerable to the
1499         // remaining hits in the same frame)
1500         if (self.flags & FL_ONGROUND)
1501         if (g_midair)
1502                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1503
1504         if (time < self.spawnshieldtime)
1505                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1506 }
1507
1508 float CalcRegen(float current, float stable, float regenfactor)
1509 {
1510         if(current > stable)
1511                 return current;
1512         else if(current > stable - 0.25) // when close enough, "snap"
1513                 return stable;
1514         else
1515                 return min(stable, current + (stable - current) * regenfactor * frametime);
1516 }
1517
1518 void player_regen (void)
1519 {
1520         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1521         maxh = cvar("g_balance_health_stable");
1522         maxa = cvar("g_balance_armor_stable");
1523         limith = cvar("g_balance_health_limit");
1524         limita = cvar("g_balance_armor_limit");
1525
1526         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1527                 return;
1528
1529         max_mod = regen_mod = rot_mod = limit_mod = 1;
1530
1531         if (self.runes & RUNE_REGEN)
1532         {
1533                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1534                 {
1535                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1536                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1537                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1538                 }
1539                 else
1540                 {
1541                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1542                         max_mod = cvar("g_balance_rune_regen_hpmod");
1543                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1544                 }
1545         }
1546         else if (self.runes & CURSE_VENOM)
1547         {
1548                 max_mod = cvar("g_balance_curse_venom_hpmod");
1549                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1550                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1551                 else
1552                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1553                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1554                 //if (!self.runes & RUNE_REGEN)
1555                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1556         }
1557         maxh = maxh * max_mod;
1558         //maxa = maxa * max_mod;
1559         limith = limith * limit_mod;
1560         limita = limita * limit_mod;
1561
1562         if (self.armorvalue > maxa)
1563         {
1564                 if (time > self.pauserotarmor_finished)
1565                 {
1566                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1567                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1568                 }
1569         }
1570         else if (self.armorvalue < maxa)
1571         {
1572                 if (time > self.pauseregen_finished)
1573                 {
1574                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1575                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1576                 }
1577         }
1578         if (self.health > maxh)
1579         {
1580                 if (time > self.pauserothealth_finished)
1581                 {
1582                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1583                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1584                 }
1585         }
1586         else if (self.health < maxh)
1587         {
1588                 if (time > self.pauseregen_finished)
1589                 {
1590                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1591                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1592                 }
1593         }
1594
1595         if (self.health > limith)
1596                 self.health = limith;
1597         if (self.armorvalue > limita)
1598                 self.armorvalue = limita;
1599
1600         // if player rotted to death...  die!
1601         if(self.health < 1)
1602                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1603 }
1604
1605 /*
1606 ======================
1607 spectate mode routines
1608 ======================
1609 */
1610 void SpectateCopy(entity spectatee) {
1611         self.armortype = spectatee.armortype;
1612         self.armorvalue = spectatee.armorvalue;
1613         self.currentammo = spectatee.currentammo;
1614         self.effects = spectatee.effects;
1615         self.health = spectatee.health;
1616         self.impulse = 0;
1617         self.items = spectatee.items;
1618         self.punchangle = spectatee.punchangle;
1619         self.view_ofs = spectatee.view_ofs;
1620         self.v_angle = spectatee.v_angle;
1621         self.viewzoom = spectatee.viewzoom;
1622         self.velocity = spectatee.velocity;
1623         self.dmg_take = spectatee.dmg_take;
1624         self.dmg_save = spectatee.dmg_save;
1625         self.dmg_inflictor = spectatee.dmg_inflictor;
1626         self.angles = spectatee.v_angle;
1627         self.fixangle = TRUE;
1628         setorigin(self, spectatee.origin);
1629         setsize(self, spectatee.mins, spectatee.maxs);
1630 }
1631
1632 float SpectateUpdate() {
1633         if(!self.enemy)
1634                 return 0;
1635
1636         if (self == self.enemy)
1637                 return 0;
1638
1639         if(self.enemy.flags & FL_NOTARGET)
1640                 return 0;
1641
1642         SpectateCopy(self.enemy);
1643
1644         return 1;
1645 }
1646
1647 float SpectateNext() {
1648         other = find(self.enemy, classname, "player");
1649         if (!other) {
1650                 other = find(other, classname, "player");
1651         }
1652         if (other) {
1653                 self.enemy = other;
1654         }
1655         if(self.enemy.classname == "player") {
1656                 msg_entity = self;
1657                 WriteByte(MSG_ONE, SVC_SETVIEW);
1658                 WriteEntity(MSG_ONE, self.enemy);
1659                 self.wantswelcomemessage = 1;
1660                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1661                 if(!SpectateUpdate())
1662                         PutObserverInServer();
1663                 return 1;
1664         } else {
1665                 return 0;
1666         }
1667 }
1668
1669 /*
1670 =============
1671 ShowRespawnCountdown()
1672
1673 Update a respawn countdown display.
1674 =============
1675 */
1676 void ShowRespawnCountdown()
1677 {
1678         float number;
1679         if(self.deadflag == DEAD_NO) // just respawned?
1680                 return;
1681         else
1682         {
1683                 number = ceil(self.death_time - time);
1684                 if(number <= 0)
1685                         return;
1686                 if(number <= self.respawn_countdown)
1687                 {
1688                         self.respawn_countdown = number - 1;
1689                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1690                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1691                 }
1692         }
1693 }
1694
1695 void LeaveSpectatorMode()
1696 {
1697         if(isJoinAllowed()) {
1698                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1699                         self.classname = "player";
1700                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1701                                 JoinBestTeam(self, FALSE, TRUE);
1702                         if(cvar("g_campaign"))
1703                                 campaign_bots_may_start = 1;
1704                         PutClientInServer();
1705                         if(!(self.flags & FL_NOTARGET))
1706                                 bprint ("^4", self.netname, "^4 is playing now\n");
1707                         centerprint(self,"");
1708                         return;
1709                 } else {
1710                         stuffcmd(self,"menu_showteamselect\n");
1711                         return;
1712                 }
1713         }
1714         else {
1715                 //player may not join because of g_maxplayers is set
1716                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1717         }
1718 }
1719
1720 /**
1721  * Determines whether the player is allowed to join. This depends on cvar
1722  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1723  * it checks whether the number of currently playing players exceeds g_maxplayers.
1724  * @return bool TRUE if the player is allowed to join, false otherwise
1725  */
1726 float isJoinAllowed() {
1727         if (!cvar("g_maxplayers"))
1728                 return TRUE;
1729
1730         local entity e;
1731         local float currentlyPlaying;
1732         FOR_EACH_REALPLAYER(e) {
1733                 if(e.classname == "player")
1734                         currentlyPlaying += 1;
1735         }
1736         if(currentlyPlaying < cvar("g_maxplayers"))
1737                 return TRUE;
1738
1739         return FALSE;
1740 }
1741
1742 /**
1743  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1744  * g_maxplayers_spectator_blocktime seconds
1745  */
1746 void checkSpectatorBlock() {
1747         if(self.classname == "spectator" || self.classname == "observer") {
1748                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1749                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1750                         dropclient(self);
1751                 }
1752         }
1753 }
1754
1755 float vercmp_recursive(string v1, string v2)
1756 {
1757         float dot1, dot2;
1758         string s1, s2;
1759         float r;
1760
1761         dot1 = strstrofs(v1, ".", 0);
1762         dot2 = strstrofs(v2, ".", 0);
1763         if(dot1 == -1)
1764                 s1 = v1;
1765         else
1766                 s1 = substring(v1, 0, dot1);
1767         if(dot2 == -1)
1768                 s2 = v2;
1769         else
1770                 s2 = substring(v2, 0, dot2);
1771
1772         r = stof(s1) - stof(s2);
1773         if(r != 0)
1774                 return r;
1775
1776         r = strcasecmp(s1, s2);
1777         if(r != 0)
1778                 return r;
1779
1780         if(dot1 == -1)
1781                 if(dot2 == -1)
1782                         return 0;
1783                 else
1784                         return -1;
1785         else
1786                 if(dot2 == -1)
1787                         return 1;
1788                 else
1789                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1790 }
1791
1792 float vercmp(string v1, string v2)
1793 {
1794         if(strcasecmp(v1, v2) == 0) // early out check
1795                 return 0;
1796         return vercmp_recursive(v1, v2);
1797 }
1798
1799 void ObserverThink()
1800 {
1801         if (self.flags & FL_JUMPRELEASED) {
1802                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1803                         self.welcomemessage_time = 0;
1804                         self.flags = self.flags - FL_JUMPRELEASED;
1805                         LeaveSpectatorMode();
1806                         return;
1807                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1808                         self.welcomemessage_time = 0;
1809                         self.flags = self.flags - FL_JUMPRELEASED;
1810                         if(SpectateNext() == 1) {
1811                                 self.classname = "spectator";
1812                         }
1813                 }
1814         } else {
1815                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1816                         self.flags = self.flags | FL_JUMPRELEASED;
1817                 }
1818         }
1819         if(self.BUTTON_ZOOM)
1820                 self.wantswelcomemessage = 0;
1821         if(self.wantswelcomemessage)
1822                 PrintWelcomeMessage(self);
1823 }
1824
1825 void SpectatorThink()
1826 {
1827         if (self.flags & FL_JUMPRELEASED) {
1828                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1829                         self.welcomemessage_time = 0;
1830                         self.flags = self.flags - FL_JUMPRELEASED;
1831                         LeaveSpectatorMode();
1832                         return;
1833                 } else if(self.BUTTON_ATCK) {
1834                         self.welcomemessage_time = 0;
1835                         self.flags = self.flags - FL_JUMPRELEASED;
1836                         if(SpectateNext() == 1) {
1837                                 self.classname = "spectator";
1838                         } else {
1839                                 self.classname = "observer";
1840                                 PutClientInServer();
1841                         }
1842                 } else if (self.BUTTON_ATCK2) {
1843                         self.welcomemessage_time = 0;
1844                         self.flags = self.flags - FL_JUMPRELEASED;
1845                         self.classname = "observer";
1846                         PutClientInServer();
1847                 } else {
1848                         if(!SpectateUpdate())
1849                                 PutObserverInServer();
1850                 }
1851         } else {
1852                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1853                         self.flags = self.flags | FL_JUMPRELEASED;
1854                 }
1855         }
1856         if(self.BUTTON_ZOOM)
1857                 self.wantswelcomemessage = 0;
1858         if(self.wantswelcomemessage)
1859                 PrintWelcomeMessage(self);
1860         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1861 }
1862
1863 /*
1864 =============
1865 PlayerPreThink
1866
1867 Called every frame for each client before the physics are run
1868 =============
1869 */
1870 void() ctf_setstatus;
1871 .float vote_nagtime;
1872 void PlayerPreThink (void)
1873 {
1874         if(blockSpectators)
1875                 checkSpectatorBlock();
1876
1877         if(self.netname_previous != self.netname)
1878         {
1879                 if(cvar("sv_eventlog"))
1880                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1881                 if(self.netname_previous)
1882                         strunzone(self.netname_previous);
1883                 self.netname_previous = strzone(self.netname);
1884         }
1885
1886         // version nagging
1887         if(self.version_nagtime)
1888                 if(self.cvar_g_nexuizversion)
1889                         if(time > self.version_nagtime)
1890                         {
1891                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1892                                 {
1893                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1894                                         {
1895                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1896                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1897                                         }
1898                                         else
1899                                         {
1900                                                 float r;
1901                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1902                                                 if(r < 0)
1903                                                 {
1904                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1905                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1906                                                 }
1907                                                 else if(r > 0)
1908                                                 {
1909                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1910                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1911                                                 }
1912                                         }
1913                                 }
1914                                 self.version_nagtime = 0;
1915                         }
1916
1917         // vote nagging
1918         if(self.cvar_scr_centertime)
1919                 if(time > self.vote_nagtime)
1920                 {
1921                         VoteNag();
1922                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1923                 }
1924
1925         // GOD MODE info
1926         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1927         {
1928                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1929                 self.max_armorvalue = 0;
1930         }
1931
1932         if(frametime)
1933                 antilag_record(self);
1934
1935         if(self.classname == "player") {
1936 //              if(self.netname == "Wazat")
1937 //                      bprint(self.classname, "\n");
1938
1939                 CheckRules_Player();
1940
1941                 if(self.BUTTON_INFO)
1942                         PrintWelcomeMessage(self);
1943
1944                 if(g_lms || !cvar("sv_spectate"))
1945                 if((time - self.jointime) <= cvar("welcome_message_time"))
1946                         PrintWelcomeMessage(self);
1947
1948                 if (intermission_running)
1949                 {
1950                         IntermissionThink ();   // otherwise a button could be missed between
1951                         return;                                 // the think tics
1952                 }
1953
1954                 if(self.teleport_time)
1955                 if(time > self.teleport_time)
1956                 {
1957                         self.teleport_time = 0;
1958                         self.effects = self.effects - (self.effects & EF_NODRAW);
1959                         if(self.weaponentity)
1960                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1961                 }
1962
1963                 Nixnex_GiveCurrentWeapon();
1964
1965                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1966                         UpdateSelectedPlayer();
1967
1968                 //don't allow the player to turn around while game is paused!
1969                 if(timeoutStatus == 2) {
1970                         self.v_angle = self.lastV_angle;
1971                         self.angles = self.lastV_angle;
1972                         self.fixangle = TRUE;
1973                 }
1974
1975                 if (self.deadflag != DEAD_NO)
1976                 {
1977                         float button_pressed, force_respawn;
1978                         player_anim();
1979                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1980                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1981                         if (self.deadflag == DEAD_DYING)
1982                         {
1983                                 if(force_respawn)
1984                                         self.deadflag = DEAD_RESPAWNING;
1985                                 else if(!button_pressed)
1986                                         self.deadflag = DEAD_DEAD;
1987                         }
1988                         else if (self.deadflag == DEAD_DEAD)
1989                         {
1990                                 if(button_pressed)
1991                                         self.deadflag = DEAD_RESPAWNABLE;
1992                         }
1993                         else if (self.deadflag == DEAD_RESPAWNABLE)
1994                         {
1995                                 if(!button_pressed)
1996                                         self.deadflag = DEAD_RESPAWNING;
1997                         }
1998                         else if (self.deadflag == DEAD_RESPAWNING)
1999                         {
2000                                 if(time > self.death_time)
2001                                 {
2002                                         self.death_time = time + 1; // only retry once a second
2003                                         respawn();
2004                                 }
2005                         }
2006                         ShowRespawnCountdown();
2007                         return;
2008                 }
2009
2010                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2011                 {
2012                         vector dist;
2013
2014                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2015                         dist = self.oldorigin - self.origin;
2016                         dist_z = 0;
2017                         self.lms_traveled_distance += fabs(vlen(dist));
2018
2019                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2020                         {
2021                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2022                                 self.lms_traveled_distance = 0;
2023                         }
2024
2025                         if(time > self.lms_nextcheck)
2026                         {
2027                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2028                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2029                                 {
2030                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2031                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2032                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2033                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2034                                 }
2035                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2036                                 self.lms_traveled_distance = 0;
2037                         }
2038                 }
2039
2040                 if (self.BUTTON_CROUCH && !self.hook.state)
2041                 {
2042                         if (!self.crouch)
2043                         {
2044                                 self.crouch = TRUE;
2045                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2046                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2047                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2048                         }
2049                 }
2050                 else
2051                 {
2052                         if (self.crouch)
2053                         {
2054                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2055                                 if (!trace_startsolid)
2056                                 {
2057                                         self.crouch = FALSE;
2058                                         self.view_ofs = PL_VIEW_OFS;
2059                                         setsize (self, PL_MIN, PL_MAX);
2060                                 }
2061                         }
2062                 }
2063
2064                 FixPlayermodel();
2065
2066                 GrapplingHookFrame();
2067
2068                 W_WeaponFrame();
2069
2070                 {
2071                         float zoomfactor, zoomspeed, zoomdir;
2072                         zoomfactor = self.cvar_cl_zoomfactor;
2073                         if(zoomfactor < 1 || zoomfactor > 16)
2074                                 zoomfactor = 2.5;
2075                         zoomspeed = self.cvar_cl_zoomspeed;
2076                         if(zoomspeed >= 0) // < 0 is instant zoom
2077                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2078                                         zoomspeed = 3.5;
2079
2080                         zoomdir = self.BUTTON_ZOOM;
2081                         if(self.BUTTON_ATCK2)
2082                                 if(self.weapon == WEP_NEX)
2083                                         if(!g_minstagib)
2084                                                 zoomdir = 1;
2085
2086                         if(zoomdir)
2087                                 self.has_zoomed = 1;
2088
2089                         if(self.has_zoomed)
2090                         {
2091                                 if(zoomspeed <= 0) // instant zoom
2092                                 {
2093                                         if(zoomdir)
2094                                                 self.viewzoom = 1 / zoomfactor;
2095                                         else
2096                                                 self.viewzoom = 1;
2097                                 }
2098                                 else
2099                                 {
2100                                         // geometric zoom would be:
2101                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2102                                         // however, testing showed that arithmetic/harmonic zoom works better
2103                                         if(zoomdir)
2104                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2105                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2106                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2107                                         else
2108                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2109                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2110                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2111                                 }
2112                         }
2113                         else
2114                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2115                 }
2116
2117                 player_powerups();
2118                 player_regen();
2119                 player_anim();
2120
2121                 if (g_minstagib)
2122                         minstagib_ammocheck();
2123
2124                 ctf_setstatus();
2125                 kh_setstatus();
2126
2127                 //self.angles_y=self.v_angle_y + 90;   // temp
2128
2129                 //if (TetrisPreFrame()) return;
2130         } else if(gameover) {
2131                 if (intermission_running)
2132                         IntermissionThink ();   // otherwise a button could be missed between
2133                 return;
2134         } else if(self.classname == "observer") {
2135                 ObserverThink();
2136         } else if(self.classname == "spectator") {
2137                 SpectatorThink();
2138         }
2139 }
2140
2141
2142 /*
2143 =============
2144 PlayerPostThink
2145
2146 Called every frame for each client after the physics are run
2147 =============
2148 */
2149 .float idlekick_lasttimeleft;
2150 void PlayerPostThink (void)
2151 {
2152         // Savage: Check for nameless players
2153         if (strlen(self.netname) < 1) {
2154                 self.netname = "Player";
2155                 stuffcmd(self, "seta _cl_name Player\n");
2156         }
2157
2158         if(sv_maxidle)
2159         {
2160                 float timeleft;
2161                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2162                 if(timeleft <= 0)
2163                 {
2164                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2165                         play2(self, "announcer/robotic/terminated.ogg");
2166                         dropclient(self);
2167                         return;
2168                 }
2169                 else if(timeleft <= 10)
2170                 {
2171                         if(timeleft != self.idlekick_lasttimeleft)
2172                         {
2173                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2174                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2175                         }
2176                 }
2177                 else
2178                 {
2179                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2180                 }
2181                 self.idlekick_lasttimeleft = timeleft;
2182         }
2183
2184         if(self.classname == "player") {
2185                 CheckRules_Player();
2186                 UpdateChatBubble();
2187                 UpdateTeamBubble();
2188                 if (self.impulse)
2189                         ImpulseCommands();
2190                 if (intermission_running)
2191                         return;         // intermission or finale
2192
2193                 //PrintWelcomeMessage(self);
2194                 //if (TetrisPostFrame()) return;
2195
2196                 // restart countdown
2197                 if (restart_countdown) {
2198                         if(time < restart_countdown) {
2199                                 if (!cvar("sv_ready_restart_after_countdown"))
2200                                 {
2201                                         self.movetype = MOVETYPE_NONE;
2202                                         self.velocity = '0 0 0';
2203                                         self.avelocity = '0 0 0';
2204                                         self.movement = '0 0 0';
2205                                 }
2206                         }
2207                         else
2208                         {
2209                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2210                                 if (!cvar("sv_ready_restart_after_countdown"))
2211                                 {
2212                                         if(self.movetype == MOVETYPE_NONE)
2213                                         {
2214                                                 self.movetype = MOVETYPE_WALK;
2215                                         }
2216                                 }
2217                         }
2218                 }
2219
2220         } else if (self.classname == "observer") {
2221                 //do nothing
2222         } else if (self.classname == "spectator") {
2223                 //do nothing
2224         }
2225
2226         /*
2227         float i;
2228         for(i = 0; i < 1000; ++i)
2229         {
2230                 vector end;
2231                 end = self.origin + '0 0 1024' + 512 * randomvec();
2232                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2233                 if(trace_fraction < 1)
2234                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2235                 {
2236                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2237                         break;
2238                 }
2239         }
2240         */
2241
2242         Arena_Warmup();
2243 }