data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  67                                                 return -1;
  68                                         float pl;
  69                                         pl = self.race_place;
  70                                         if(pl > race_highest_place_spawn)
  71                                                 pl = 0;
  72                                         if(spot.race_place != pl)
  73                                                 return -1;
  74                                 }
  75                                 good = 1;
  76                         }
  77                         else
  78                         {
  79                         }
  80                         ent = find(ent, targetname, spot.target);
  81                 }
  82
  83                 if(!good)
  84                         return -1;
  85         }
  86
  87         player = playerlist;
  88         shortest = vlen(world.maxs - world.mins);
  89         for(player = playerlist; player; player = player.chain)
  90                 if (player != self)
  91                 {
  92                         thisdist = vlen(player.origin - spot.origin);
  93                         if (thisdist < shortest)
  94                                 shortest = thisdist;
  95                 }
  96         return shortest;
  97 }
  98
  99 float spawn_allbad;
 100 float spawn_allgood;
 101 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 102 {
 103         local entity spot, spotlist, spotlistend;
 104         spawn_allgood = TRUE;
 105         spawn_allbad = TRUE;
 106
 107         spotlist = world;
 108         spotlistend = world;
 109
 110         for(spot = firstspot; spot; spot = spot.chain)
 111         {
 112                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 113
 114                 if(cvar("spawn_debugview"))
 115                 {
 116                         setmodel(spot, "models/runematch/rune.mdl");
 117                         if(spot.SPAWNPOINT_SCORE < mindist)
 118                         {
 119                                 spot.colormod = '1 0 0';
 120                                 spot.scale = 1;
 121                         }
 122                         else
 123                         {
 124                                 spot.colormod = '0 1 0';
 125                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 126                         }
 127                 }
 128
 129                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 130                 {
 131                         if(spot.SPAWNPOINT_SCORE < mindist)
 132                         {
 133                                 // too short distance
 134                                 spawn_allgood = FALSE;
 135                         }
 136                         else
 137                         {
 138                                 // perfect
 139                                 spawn_allbad = FALSE;
 140
 141                                 if(spotlistend)
 142                                         spotlistend.chain = spot;
 143                                 spotlistend = spot;
 144                                 if(!spotlist)
 145                                         spotlist = spot;
 146
 147                                 /*
 148                                 if(teamcheck)
 149                                 if(spot.team != teamcheck)
 150                                         error("invalid spawn added");
 151
 152                                 print("added ", etos(spot), "\n");
 153                                 */
 154                         }
 155                 }
 156         }
 157         if(spotlistend)
 158                 spotlistend.chain = world;
 159
 160         /*
 161                 entity e;
 162                 if(teamcheck)
 163                         for(e = spotlist; e; e = e.chain)
 164                         {
 165                                 print("seen ", etos(e), "\n");
 166                                 if(e.team != teamcheck)
 167                                         error("invalid spawn found");
 168                         }
 169         */
 170
 171         return spotlist;
 172 }
 173
 174 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 175 {
 176         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 177         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 178         local entity spot;
 179
 180         RandomSelection_Init();
 181         for(spot = firstspot; spot; spot = spot.chain)
 182                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 183
 184         return RandomSelection_chosen_ent;
 185 }
 186
 187 /*
 188 =============
 189 SelectSpawnPoint
 190
 191 Finds a point to respawn
 192 =============
 193 */
 194 entity SelectSpawnPoint (float anypoint)
 195 {
 196         local float teamcheck;
 197         local entity firstspot_new;
 198         local entity spot, firstspot, playerlist;
 199
 200         spot = find (world, classname, "testplayerstart");
 201         if (spot)
 202                 return spot;
 203
 204         teamcheck = 0;
 205
 206         if(!anypoint && have_team_spawns)
 207                 teamcheck = self.team;
 208
 209         // get the list of players
 210         playerlist = findchain(classname, "player");
 211         // get the entire list of spots
 212         firstspot = findchain(classname, "info_player_deathmatch");
 213         // filter out the bad ones
 214         // (note this returns the original list if none survived)
 215         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 216         if(!firstspot_new)
 217                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 218         firstspot = firstspot_new;
 219
 220         // there is 50/50 chance of choosing a random spot or the furthest spot
 221         // (this means that roughly every other spawn will be furthest, so you
 222         // usually won't get fragged at spawn twice in a row)
 223         if (arena_roundbased)
 224         {
 225                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 226                 if(firstspot_new)
 227                         firstspot = firstspot_new;
 228                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 229         }
 230         else if (random() > cvar("g_spawn_furthest"))
 231                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 232         else
 233                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 234
 235         if(cvar("spawn_debugview"))
 236         {
 237                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 238
 239                 entity e;
 240                 if(teamcheck)
 241                         for(e = firstspot; e; e = e.chain)
 242                                 if(e.team != teamcheck)
 243                                         error("invalid spawn found");
 244         }
 245
 246         if (!spot)
 247         {
 248                 if(cvar("spawn_debug"))
 249                         GotoNextMap();
 250                 else
 251                 {
 252                         if(some_spawn_has_been_used)
 253                                 return world; // team can't spawn any more, because of actions of other team
 254                         else
 255                                 error("Cannot find a spawn point - please fix the map!");
 256                 }
 257         }
 258
 259         return spot;
 260 }
 261
 262 /*
 263 =============
 264 CheckPlayerModel
 265
 266 Checks if the argument string can be a valid playermodel.
 267 Returns a valid one in doubt.
 268 =============
 269 */
 270 string FallbackPlayerModel = "models/player/marine.zym";
 271 string CheckPlayerModel(string plyermodel) {
 272         if(strlen(plyermodel) < 4)
 273                 return FallbackPlayerModel;
 274         if( substring(plyermodel,0,14) != "models/player/")
 275                 return FallbackPlayerModel;
 276         else if(cvar("sv_servermodelsonly"))
 277         {
 278                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 279                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 280                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 281                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 282                         return FallbackPlayerModel;
 283                 if(!fexists(plyermodel))
 284                         return FallbackPlayerModel;
 285         }
 286         return plyermodel;
 287 }
 288
 289 /*
 290 =============
 291 Client_customizeentityforclient
 292
 293 LOD reduction
 294 =============
 295 */
 296 float Client_customizeentityforclient()
 297 {
 298 #ifdef ALLOW_VARIABLE_LOD
 299         // self: me
 300         // other: the player viewing me
 301         float distance;
 302         float f;
 303
 304         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 305                 return TRUE;
 306
 307         if(other.cvar_cl_playerdetailreduction <= 0)
 308         {
 309                 if(other.cvar_cl_playerdetailreduction <= -2)
 310                         self.modelindex = self.modelindex_lod2;
 311                 else if(other.cvar_cl_playerdetailreduction <= -1)
 312                         self.modelindex = self.modelindex_lod1;
 313                 else
 314                         self.modelindex = self.modelindex_lod0;
 315         }
 316         else
 317         {
 318                 distance = vlen(self.origin - other.origin);
 319                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 320                 if(f > 10000)
 321                         self.modelindex = self.modelindex_lod2;
 322                 else if(f > 5000)
 323                         self.modelindex = self.modelindex_lod1;
 324                 else
 325                         self.modelindex = self.modelindex_lod0;
 326         }
 327 #endif
 328
 329         return TRUE;
 330 }
 331
 332 void UpdatePlayerSounds();
 333 void setmodel_lod(entity e, string modelname)
 334 {
 335 #ifdef ALLOW_VARIABLE_LOD
 336         string s;
 337
 338         // FIXME: this only supports 3-letter extensions
 339         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 340         if(fexists(s))
 341         {
 342                 precache_model(s);
 343                 setmodel(e, s); // players have high precision
 344                 self.modelindex_lod1 = self.modelindex;
 345         }
 346         else
 347                 self.modelindex_lod1 = -1;
 348
 349         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 350         if(fexists(s))
 351         {
 352                 precache_model(s);
 353                 setmodel(e, s); // players have high precision
 354                 self.modelindex_lod2 = self.modelindex;
 355         }
 356         else
 357                 self.modelindex_lod2 = -1;
 358
 359         precache_model(modelname);
 360         setmodel(e, modelname); // players have high precision
 361         self.modelindex_lod0 = self.modelindex;
 362
 363         if(self.modelindex_lod1 < 0)
 364                 self.modelindex_lod1 = self.modelindex;
 365
 366         if(self.modelindex_lod2 < 0)
 367                 self.modelindex_lod2 = self.modelindex;
 368 #else
 369         precache_model(modelname);
 370         setmodel(e, modelname); // players have high precision
 371 #endif
 372         player_setupanimsformodel();
 373         UpdatePlayerSounds();
 374 }
 375
 376 /*
 377 =============
 378 PutObserverInServer
 379
 380 putting a client as observer in the server
 381 =============
 382 */
 383 void PutObserverInServer (void)
 384 {
 385         entity  spot;
 386
 387         race_PreSpawnObserver();
 388
 389         spot = SelectSpawnPoint (TRUE);
 390         if(!spot)
 391                 error("No spawnpoints for observers?!?\n");
 392         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394         if(clienttype(self) == CLIENTTYPE_REAL)
 395         {
 396                 msg_entity = self;
 397                 WriteByte(MSG_ONE, SVC_SETVIEW);
 398                 WriteEntity(MSG_ONE, self);
 399         }
 400
 401         DropAllRunes(self);
 402         kh_Key_DropAll(self, TRUE);
 403
 404         if(self.flagcarried)
 405                 DropFlag(self.flagcarried);
 406
 407         WaypointSprite_PlayerDead();
 408
 409         if(self.killcount != -666)
 410         {
 411                 if(g_lms)
 412                 {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 414                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 415                         else
 416                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 417                 }
 418                 else
 419                         bprint ("^4", self.netname, "^4 is spectating now\n");
 420         }
 421
 422         PlayerScore_Clear(self); // clear scores when needed
 423
 424         self.spectatortime = time;
 425
 426         self.classname = "observer";
 427         self.health = -666;
 428         self.takedamage = DAMAGE_NO;
 429         self.solid = SOLID_NOT;
 430         self.movetype = MOVETYPE_NOCLIP;
 431         self.flags = FL_CLIENT | FL_NOTARGET;
 432         self.armorvalue = 666;
 433         self.effects = 0;
 434         self.armorvalue = cvar("g_balance_armor_start");
 435         self.pauserotarmor_finished = 0;
 436         self.pauserothealth_finished = 0;
 437         self.pauseregen_finished = 0;
 438         self.damageforcescale = 0;
 439         self.death_time = 0;
 440         self.dead_frame = 0;
 441         self.alpha = 0;
 442         self.scale = 0;
 443         self.fade_time = 0;
 444         self.pain_frame = 0;
 445         self.pain_finished = 0;
 446         self.strength_finished = 0;
 447         self.invincible_finished = 0;
 448         self.pushltime = 0;
 449         self.think = SUB_Null;
 450         self.nextthink = 0;
 451         self.hook_time = 0;
 452         self.runes = 0;
 453         self.deadflag = DEAD_NO;
 454         self.angles = spot.angles;
 455         self.angles_z = 0;
 456         self.fixangle = TRUE;
 457         self.crouch = FALSE;
 458
 459         self.view_ofs = PL_VIEW_OFS;
 460         setorigin (self, spot.origin);
 461         setsize (self, '0 0 0', '0 0 0');
 462         self.oldorigin = self.origin;
 463         self.items = 0;
 464         self.model = "";
 465         self.modelindex = 0;
 466         self.weapon = 0;
 467         self.weaponmodel = "";
 468         self.weaponentity = world;
 469         self.killcount = -666;
 470         self.velocity = '0 0 0';
 471         self.avelocity = '0 0 0';
 472         self.punchangle = '0 0 0';
 473         self.punchvector = '0 0 0';
 474         self.oldvelocity = self.velocity;
 475         self.customizeentityforclient = Client_customizeentityforclient;
 476         self.viewzoom = 1;
 477         self.wantswelcomemessage = 1;
 478
 479         if(g_arena)
 480         {
 481                 if(self.version_mismatch)
 482                 {
 483                         Spawnqueue_Unmark(self);
 484                         Spawnqueue_Remove(self);
 485                 }
 486                 else
 487                 {
 488                         Spawnqueue_Insert(self);
 489                 }
 490         }
 491         else if(g_lms)
 492         {
 493                 // Only if the player cannot play at all
 494                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 495                         self.frags = -666;
 496                 else
 497                         self.frags = -667;
 498         }
 499         else
 500                 self.frags = -666;
 501 }
 502
 503 float RestrictSkin(float s)
 504 {
 505         if(!teams_matter)
 506                 return s;
 507         if(s == 6)
 508                 return 6;
 509         return mod(s, 3);
 510 }
 511
 512 void FixPlayermodel()
 513 {
 514         local string defaultmodel;
 515         local float defaultskin;
 516         local vector m1, m2;
 517
 518         defaultmodel = "";
 519
 520         if(cvar("sv_defaultcharacter") == 1) {
 521                 defaultskin = 0;
 522
 523                 if(teams_matter)
 524                 {
 525                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 526                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 527                 }
 528
 529                 if(defaultmodel == "")
 530                 {
 531                         defaultmodel = cvar_string("sv_defaultplayermodel");
 532                         defaultskin = cvar("sv_defaultplayerskin");
 533                 }
 534         }
 535
 536         if(defaultmodel != "")
 537         {
 538                 if (defaultmodel != self.model)
 539                 {
 540                         m1 = self.mins;
 541                         m2 = self.maxs;
 542                         setmodel_lod (self, defaultmodel);
 543                         setsize (self, m1, m2);
 544                 }
 545
 546                 self.skin = defaultskin;
 547         } else {
 548                 if (self.playermodel != self.model)
 549                 {
 550                         self.playermodel = CheckPlayerModel(self.playermodel);
 551                         m1 = self.mins;
 552                         m2 = self.maxs;
 553                         setmodel_lod (self, self.playermodel);
 554                         setsize (self, m1, m2);
 555                 }
 556
 557                 self.skin = RestrictSkin(stof(self.playerskin));
 558         }
 559
 560         if(!teams_matter)
 561                 if(strlen(cvar_string("sv_defaultplayercolors")))
 562                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 563                                 setcolor(self, cvar("sv_defaultplayercolors"));
 564 }
 565
 566 /*
 567 =============
 568 PutClientInServer
 569
 570 Called when a client spawns in the server
 571 =============
 572 */
 573 //void() ctf_playerchanged;
 574 void PutClientInServer (void)
 575 {
 576         if(clienttype(self) == CLIENTTYPE_BOT)
 577         {
 578                 self.classname = "player";
 579         }
 580         else if(clienttype(self) == CLIENTTYPE_REAL)
 581         {
 582                 msg_entity = self;
 583                 WriteByte(MSG_ONE, SVC_SETVIEW);
 584                 WriteEntity(MSG_ONE, self);
 585         }
 586
 587         // player is dead and becomes observer
 588         // FIXME fix LMS scoring for new system
 589         if(g_lms)
 590         {
 591                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 592                         self.classname = "observer";
 593         }
 594
 595         if(g_arena)
 596         if(!self.spawned)
 597                 self.classname = "observer";
 598
 599         if(self.classname == "player") {
 600                 entity  spot;
 601
 602                 race_PreSpawn();
 603
 604                 spot = SelectSpawnPoint (FALSE);
 605                 if(!spot)
 606                 {
 607                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 608                         return; // spawn failed
 609                 }
 610
 611                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 612
 613                 self.classname = "player";
 614                 self.iscreature = TRUE;
 615                 self.movetype = MOVETYPE_WALK;
 616                 self.solid = SOLID_SLIDEBOX;
 617                 if(independent_players)
 618                         MAKE_INDEPENDENT_PLAYER(self);
 619                 self.flags = FL_CLIENT;
 620                 self.takedamage = DAMAGE_AIM;
 621                 if(g_minstagib)
 622                         self.effects = EF_FULLBRIGHT;
 623                 else
 624                         self.effects = 0;
 625                 self.air_finished = time + 12;
 626                 self.dmg = 2;
 627
 628                 self.ammo_shells = start_ammo_shells;
 629                 self.ammo_nails = start_ammo_nails;
 630                 self.ammo_rockets = start_ammo_rockets;
 631                 self.ammo_cells = start_ammo_cells;
 632                 self.health = start_health;
 633                 self.armorvalue = start_armorvalue;
 634                 self.items = start_items;
 635                 self.switchweapon = start_switchweapon;
 636                 self.cnt = start_switchweapon;
 637                 self.weapon = 0;
 638                 self.jump_interval = time;
 639
 640                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 641                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 642                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 643                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 644                 //extend the pause of rotting if client was reset at the beginning of the countdown
 645                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
 646                         self.spawnshieldtime += RESTART_COUNTDOWN;
 647                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
 648                         self.pauserothealth_finished += RESTART_COUNTDOWN;
 649                         self.pauseregen_finished += RESTART_COUNTDOWN;
 650                 }
 651                 self.damageforcescale = 2;
 652                 self.death_time = 0;
 653                 self.dead_frame = 0;
 654                 self.alpha = 0;
 655                 self.scale = 0;
 656                 self.fade_time = 0;
 657                 self.pain_frame = 0;
 658                 self.pain_finished = 0;
 659                 self.strength_finished = 0;
 660                 self.invincible_finished = 0;
 661                 self.pushltime = 0;
 662                 //self.speed_finished = 0;
 663                 //self.slowmo_finished = 0;
 664                 // players have no think function
 665                 self.think = SUB_Null;
 666                 self.nextthink = 0;
 667                 self.hook_time = 0;
 668
 669                 self.runes = 0;
 670
 671                 self.deadflag = DEAD_NO;
 672
 673                 self.angles = spot.angles;
 674
 675                 self.angles_z = 0; // never spawn tilted even if the spot says to
 676                 self.fixangle = TRUE; // turn this way immediately
 677                 self.velocity = '0 0 0';
 678                 self.avelocity = '0 0 0';
 679                 self.punchangle = '0 0 0';
 680                 self.punchvector = '0 0 0';
 681                 self.oldvelocity = self.velocity;
 682
 683                 self.viewzoom = 0.6;
 684                 self.has_zoomed = 0;
 685
 686                 self.customizeentityforclient = Client_customizeentityforclient;
 687
 688                 self.model = "";
 689                 FixPlayermodel();
 690
 691                 self.crouch = FALSE;
 692                 self.view_ofs = PL_VIEW_OFS;
 693                 setsize (self, PL_MIN, PL_MAX);
 694                 self.spawnorigin = spot.origin;
 695                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 696                 // don't reset back to last position, even if new position is stuck in solid
 697                 self.oldorigin = self.origin;
 698
 699                 if(g_arena)
 700                 {
 701                         Spawnqueue_Remove(self);
 702                         Spawnqueue_Mark(self);
 703                 }
 704
 705                 self.event_damage = PlayerDamage;
 706
 707                 self.bot_attack = TRUE;
 708
 709                 self.statdraintime = time + 5;
 710                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 711
 712                 if(self.killcount == -666) {
 713                         PlayerScore_Clear(self);
 714                         self.killcount = 0;
 715                         self.frags = 0;
 716                 }
 717
 718                 self.cnt = WEP_LASER;
 719                 self.nixnex_lastchange_id = -1;
 720
 721                 CL_SpawnWeaponentity();
 722                 self.alpha = default_player_alpha;
 723                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 724                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 725
 726                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 727                 self.lms_traveled_distance = 0;
 728                 self.speedrunning = FALSE;
 729
 730                 race_PostSpawn(spot);
 731
 732                 if(cvar("spawn_debug"))
 733                 {
 734                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 735                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 736                 }
 737
 738                 //stuffcmd(self, "chase_active 0");
 739                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 740
 741                 if (cvar("g_spawnsound"))
 742                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 743
 744                 if(g_assault) {
 745                         if(self.team == assault_attacker_team)
 746                                 centerprint(self, "You are attacking!\n");
 747                         else
 748                                 centerprint(self, "You are defending!\n");
 749                 }
 750
 751         } else if(self.classname == "observer") {
 752                 PutObserverInServer ();
 753         }
 754
 755         //if(g_ctf)
 756         //      ctf_playerchanged();
 757 }
 758
 759 /*
 760 =============
 761 SendCSQCInfo
 762
 763 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 764 =============
 765 */
 766 void SendCSQCInfo(void)
 767 {
 768         if(clienttype(self) != CLIENTTYPE_REAL)
 769                 return;
 770         msg_entity = self;
 771         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 772         WriteByte(MSG_ONE, TE_CSQC_INIT);
 773         WriteShort(MSG_ONE, CSQC_REVISION);
 774         WriteByte(MSG_ONE, maxclients);
 775 }
 776
 777 /*
 778 =============
 779 SetNewParms
 780 =============
 781 */
 782 void SetNewParms (void)
 783 {
 784         // initialize parms for a new player
 785         parm1 = -(86400 * 366);
 786 }
 787
 788 /*
 789 =============
 790 SetChangeParms
 791 =============
 792 */
 793 void SetChangeParms (void)
 794 {
 795         // save parms for level change
 796         parm1 = self.parm_idlesince - time;
 797 }
 798
 799 /*
 800 =============
 801 DecodeLevelParms
 802 =============
 803 */
 804 void DecodeLevelParms (void)
 805 {
 806         // load parms
 807         self.parm_idlesince = parm1;
 808         if(self.parm_idlesince == -(86400 * 366))
 809                 self.parm_idlesince = time;
 810 }
 811
 812 /*
 813 =============
 814 ClientKill
 815
 816 Called when a client types 'kill' in the console
 817 =============
 818 */
 819
 820 void ClientKill_Now_TeamChange()
 821 {
 822         if(self.killindicator_teamchange == -1)
 823         {
 824                 self.team = -1;
 825                 JoinBestTeam( self, FALSE, FALSE );
 826         }
 827         else
 828         {
 829                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 830         }
 831 }
 832
 833 void ClientKill_Now()
 834 {
 835         if(self.killindicator_teamchange)
 836                 ClientKill_Now_TeamChange();
 837
 838         // in any case:
 839         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 840
 841         if(self.killindicator)
 842         {
 843                 dprint("Cleaned up after a leaked kill indicator.\n");
 844                 remove(self.killindicator);
 845                 self.killindicator = world;
 846         }
 847 }
 848 void KillIndicator_Think()
 849 {
 850         if (!self.owner.modelindex)
 851         {
 852                 self.owner.killindicator = world;
 853                 remove(self);
 854                 return;
 855         }
 856
 857         if(self.cnt <= 0)
 858         {
 859                 self = self.owner;
 860                 ClientKill_Now(); // no oldself needed
 861                 return;
 862         }
 863         else
 864         {
 865                 if(self.cnt <= 10)
 866                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 867                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 868                 {
 869                         if(self.cnt <= 10)
 870                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 871                         if(self.owner.killindicator_teamchange)
 872                         {
 873                                 if(self.owner.killindicator_teamchange == -1)
 874                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 875                                 else
 876                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 877                         }
 878                         else
 879                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 880                 }
 881                 self.nextthink = time + 1;
 882                 self.cnt -= 1;
 883         }
 884 }
 885
 886 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 887 {
 888         float killtime;
 889         entity e;
 890         killtime = cvar("g_balance_kill_delay");
 891
 892         self.killindicator_teamchange = targetteam;
 893
 894         if(!self.killindicator)
 895         {
 896                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 897                 {
 898                         ClientKill_Now();
 899                 }
 900                 else
 901                 {
 902                         self.killindicator = spawn();
 903                         self.killindicator.owner = self;
 904                         self.killindicator.scale = 0.5;
 905                         setattachment(self.killindicator, self, "");
 906                         setorigin(self.killindicator, '0 0 52');
 907                         self.killindicator.think = KillIndicator_Think;
 908                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 909                         self.killindicator.cnt = ceil(killtime);
 910                         self.killindicator.count = bound(0, ceil(killtime), 10);
 911                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 912
 913                         for(e = world; (e = find(e, classname, "body")) != world; )
 914                         {
 915                                 if(e.enemy != self)
 916                                         continue;
 917                                 e.killindicator = spawn();
 918                                 e.killindicator.owner = e;
 919                                 e.killindicator.scale = 0.5;
 920                                 setattachment(e.killindicator, e, "");
 921                                 setorigin(e.killindicator, '0 0 52');
 922                                 e.killindicator.think = KillIndicator_Think;
 923                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 924                                 e.killindicator.cnt = ceil(killtime);
 925                         }
 926                         self.lip = 0;
 927                 }
 928         }
 929         if(self.killindicator)
 930         {
 931                 if(targetteam)
 932                         self.killindicator.colormod = TeamColor(targetteam);
 933                 else
 934                         self.killindicator.colormod = '0 0 0';
 935         }
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         ClientKill_TeamChange(0);
 941 }
 942
 943 void DoTeamChange(float destteam)
 944 {
 945         float t, c0;
 946         if(!cvar("teamplay"))
 947         {
 948                 if(destteam >= 0)
 949                         SetPlayerColors(self, destteam);
 950                 return;
 951         }
 952         if(self.classname == "player")
 953         if(destteam == -1)
 954         {
 955                 CheckAllowedTeams(self);
 956                 t = FindSmallestTeam(self, TRUE);
 957                 switch(self.team)
 958                 {
 959                         case COLOR_TEAM1: c0 = c1; break;
 960                         case COLOR_TEAM2: c0 = c2; break;
 961                         case COLOR_TEAM3: c0 = c3; break;
 962                         case COLOR_TEAM4: c0 = c4; break;
 963                         default:          c0 = 999;
 964                 }
 965                 switch(t)
 966                 {
 967                         case 1:
 968                                 if(c0 > c1)
 969                                         destteam = COLOR_TEAM1;
 970                                 break;
 971                         case 2:
 972                                 if(c0 > c2)
 973                                         destteam = COLOR_TEAM2;
 974                                 break;
 975                         case 3:
 976                                 if(c0 > c3)
 977                                         destteam = COLOR_TEAM3;
 978                                 break;
 979                         case 4:
 980                                 if(c0 > c4)
 981                                         destteam = COLOR_TEAM4;
 982                                 break;
 983                 }
 984                 if(destteam == -1)
 985                         return;
 986         }
 987         if(destteam == self.team && !self.killindicator)
 988                 return;
 989         ClientKill_TeamChange(destteam);
 990 }
 991
 992 void FixClientCvars(entity e)
 993 {
 994         // send prediction settings to the client
 995         stuffcmd(e, "\nin_bindmap 0 0\n");
 996         /*
 997          * we no longer need to stuff this. Remove this comment block if you feel
 998          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 999         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1000         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1001         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1002         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1003         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1004         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1005         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1006         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1007         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1008         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1009         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1010         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1011         stuffcmd(e, "cl_movement_edgefriction 1\n");
1012          */
1013 }
1014
1015 /*
1016 =============
1017 ClientConnect
1018
1019 Called when a client connects to the server
1020 =============
1021 */
1022 //void ctf_clientconnect();
1023 string ColoredTeamName(float t);
1024 void DecodeLevelParms (void);
1025 //void dom_player_join_team(entity pl);
1026 void ClientConnect (void)
1027 {
1028         local string s;
1029         float wep;
1030
1031         if(self.flags & FL_CLIENT)
1032         {
1033                 print("Warning: ClientConnect, but already connected!\n");
1034                 return;
1035         }
1036
1037         if(Ban_IsClientBanned(self))
1038         {
1039                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
1040                 dropclient(self);
1041                 bprint(s);
1042                 return;
1043         }
1044
1045         DecodeLevelParms();
1046
1047         self.classname = "player_joining";
1048
1049         self.flags = self.flags | FL_CLIENT;
1050         self.version_nagtime = time + 10 + random() * 10;
1051
1052         if(player_count<0)
1053         {
1054                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1055                 player_count = 0;
1056         }
1057
1058         PlayerScore_Attach(self);
1059
1060         bot_clientconnect();
1061
1062         race_PreSpawnObserver();
1063
1064         //if(g_domination)
1065         //      dom_player_join_team(self);
1066
1067         //JoinBestTeam(self, FALSE, FALSE);
1068
1069         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1070                 self.classname = "observer";
1071         } else {
1072                 self.classname = "player";
1073                 campaign_bots_may_start = 1;
1074         }
1075
1076         self.playerid = (playerid_last = playerid_last + 1);
1077         if(cvar("sv_eventlog"))
1078         {
1079                 if(clienttype(self) == CLIENTTYPE_REAL)
1080                         s = "player";
1081                 else
1082                         s = "bot";
1083                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1084                 s = strcat(":team:", ftos(self.playerid), ":");
1085                 s = strcat(s, ftos(self.team));
1086                 GameLogEcho(s, FALSE);
1087         }
1088         self.netname_previous = strzone(self.netname);
1089
1090         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1091
1092         bprint ("^4",self.netname);
1093         bprint ("^4 connected");
1094
1095         if(g_domination || g_ctf)
1096         {
1097                 bprint(" and joined the ");
1098                 bprint(ColoredTeamName(self.team));
1099         }
1100
1101         bprint("\n");
1102
1103         self.welcomemessage_time = 0;
1104
1105         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1106         // TODO: is this being used for anything else than cd tracks?
1107         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1108         //
1109         stuffcmd(self, "cl_particles_reloadeffects\n");
1110
1111         FixClientCvars(self);
1112
1113         // spawnfunc_waypoint sprites
1114         WaypointSprite_InitClient(self);
1115
1116         // Wazat's grappling hook
1117         SetGrappleHookBindings();
1118
1119         // get autoswitch state from player when he toggles it
1120         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1121
1122         // get version info from player
1123         stuffcmd(self, "cmd clientversion $gameversion\n");
1124
1125         // send all weapon info strings
1126         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1127         wep = WEP_FIRST;
1128         while (wep <= WEP_LAST)
1129         {
1130                 weapon_action(wep, WR_REGISTER);
1131                 wep = wep + 1;
1132         }
1133
1134         // get other cvars from player
1135         GetCvars(0);
1136
1137         // set cvar for team scoreboard
1138         if (teams_matter)
1139         {
1140                 local float t;
1141                 t = cvar("teamplay");
1142                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1143                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1144         }
1145         else
1146                 stuffcmd(self, "set teamplay 0\n");
1147
1148         // notify about available teams
1149         if(teamplay)
1150         {
1151                 CheckAllowedTeams(self);
1152                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1153                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1154         }
1155         else
1156                 stuffcmd(self, "set _teams_available 0\n");
1157
1158         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1159
1160         if(g_arena)
1161         {
1162                 self.classname = "observer";
1163                 Spawnqueue_Insert(self);
1164         }
1165         /*else if(g_ctf)
1166         {
1167                 ctf_clientconnect();
1168         }*/
1169
1170         if(entcs_start)
1171                 attach_entcs();
1172
1173         bot_relinkplayerlist();
1174
1175         self.spectatortime = time;
1176         if(blockSpectators)
1177         {
1178                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1179         }
1180
1181         self.jointime = time;
1182         self.allowedTimeouts = cvar("sv_timeout_number");
1183
1184         if(clienttype(self) == CLIENTTYPE_REAL)
1185         {
1186                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1187                 SendCSQCInfo();
1188                 msg_entity = self;
1189                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1190                 {
1191                         MapVote_SendData(MSG_ONE);
1192                         MapVote_UpdateData(MSG_ONE);
1193                 }
1194                 ScoreInfo_Write(MSG_ONE);
1195         }
1196
1197         if(g_lms)
1198         {
1199                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1200                 {
1201                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1202                         self.frags = -666; // FIXME do we still need this?
1203                 }
1204         }
1205 }
1206
1207 /*
1208 =============
1209 ClientDisconnect
1210
1211 Called when a client disconnects from the server
1212 =============
1213 */
1214 void(entity e) DropFlag;
1215 .entity chatbubbleentity;
1216 .entity teambubbleentity;
1217 void ReadyCount();
1218 //void() ctf_clientdisconnect;
1219 void ClientDisconnect (void)
1220 {
1221         float save;
1222
1223         if not(self.flags & FL_CLIENT)
1224         {
1225                 print("Warning: ClientDisconnect without ClientConnect\n");
1226                 return;
1227         }
1228
1229         bot_clientdisconnect();
1230
1231         if(entcs_start)
1232                 detach_entcs();
1233
1234         if(cvar("sv_eventlog"))
1235                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1236         bprint ("^4",self.netname);
1237         bprint ("^4 disconnected\n");
1238
1239         if (self.chatbubbleentity)
1240         {
1241                 remove (self.chatbubbleentity);
1242                 self.chatbubbleentity = world;
1243         }
1244
1245         if (self.teambubbleentity)
1246         {
1247                 remove (self.teambubbleentity);
1248                 self.teambubbleentity = world;
1249         }
1250
1251         if (self.killindicator)
1252         {
1253                 remove (self.killindicator);
1254                 self.killindicator = world;
1255         }
1256
1257         WaypointSprite_PlayerGone();
1258
1259         DropAllRunes(self);
1260         kh_Key_DropAll(self, TRUE);
1261
1262         if(self.flagcarried)
1263                 DropFlag(self.flagcarried);
1264
1265         save = self.flags;
1266         self.flags = self.flags - (self.flags & FL_CLIENT);
1267         bot_relinkplayerlist();
1268         self.flags = save;
1269
1270         // remove laserdot
1271         if(self.weaponentity)
1272                 if(self.weaponentity.lasertarget)
1273                         remove(self.weaponentity.lasertarget);
1274
1275         if(g_arena)
1276         {
1277                 Spawnqueue_Unmark(self);
1278                 Spawnqueue_Remove(self);
1279         }
1280         /*if(g_ctf)
1281         {
1282                 ctf_clientdisconnect();
1283         }
1284         */
1285
1286         PlayerScore_Detach(self);
1287
1288         if(self.netname_previous)
1289                 strunzone(self.netname_previous);
1290
1291         ClearPlayerSounds();
1292
1293         // free cvars
1294         GetCvars(-1);
1295         self.playerid = 0;
1296
1297         ReadyCount();
1298 }
1299
1300 .float BUTTON_CHAT;
1301 void ChatBubbleThink()
1302 {
1303         self.nextthink = time;
1304         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1305         {
1306                 self.owner.chatbubbleentity = world;
1307                 remove(self);
1308                 return;
1309         }
1310         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1311         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1312                 self.model = self.mdl;
1313         else
1314                 self.model = "";
1315 };
1316
1317 void UpdateChatBubble()
1318 {
1319         if (!self.modelindex)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!self.chatbubbleentity)
1323         {
1324                 self.chatbubbleentity = spawn();
1325                 self.chatbubbleentity.owner = self;
1326                 self.chatbubbleentity.exteriormodeltoclient = self;
1327                 self.chatbubbleentity.think = ChatBubbleThink;
1328                 self.chatbubbleentity.nextthink = time;
1329                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1330                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1331                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1332                 self.chatbubbleentity.model = "";
1333                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337
1338 void TeamBubbleThink()
1339 {
1340         self.nextthink = time;
1341         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1342         {
1343                 self.owner.teambubbleentity = world;
1344                 remove(self);
1345                 return;
1346         }
1347 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1348         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1349                 self.model = "";
1350         else
1351                 self.model = self.mdl;
1352
1353 };
1354
1355 float TeamBubble_customizeentityforclient()
1356 {
1357         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1358 }
1359
1360 void UpdateTeamBubble()
1361 {
1362         if (!self.modelindex || !cvar("teamplay"))
1363                 return;
1364         // spawn a teambubble entity if needed
1365         if (!self.teambubbleentity && cvar("teamplay"))
1366         {
1367                 self.teambubbleentity = spawn();
1368                 self.teambubbleentity.owner = self;
1369                 self.teambubbleentity.exteriormodeltoclient = self;
1370                 self.teambubbleentity.think = TeamBubbleThink;
1371                 self.teambubbleentity.nextthink = time;
1372                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1373 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1374                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1375                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1376                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1377                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1378                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1379                 self.teambubbleentity.effects = EF_LOWPRECISION;
1380         }
1381 }
1382
1383 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1384 // added to the model skins
1385 /*void UpdateColorModHack()
1386 {
1387         local float c;
1388         c = self.clientcolors & 15;
1389         // LordHavoc: only bothering to support white, green, red, yellow, blue
1390              if (teamplay == 0) self.colormod = '0 0 0';
1391         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1392         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1393         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1394         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1395         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1396         else self.colormod = '1 1 1';
1397 };*/
1398
1399 void respawn(void)
1400 {
1401         CopyBody(1);
1402         self.effects |= EF_NODRAW; // prevent another CopyBody
1403         PutClientInServer();
1404 }
1405
1406 /**
1407  * When sv_timeout is used this function returs strings like
1408  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1409  * Called by centerprint functions
1410  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1411  */
1412 string getTimeoutText(float addOneSecond) {
1413         if (!cvar("sv_timeout") || !timeoutStatus)
1414                 return "";
1415
1416         local string retStr;
1417         if (timeoutStatus == 1) {
1418                 if (addOneSecond == 1) {
1419                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1420                 }
1421                 else {
1422                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1423                 }
1424                 return retStr;
1425         }
1426         else if (timeoutStatus == 2) {
1427                 if (addOneSecond) {
1428                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1429                         //don't show messages like "Timeout ends in 0 seconds"...
1430                         if ((remainingTimeoutTime + 1) > 0)
1431                                 return retStr;
1432                         else
1433                                 return "";
1434                 }
1435                 else {
1436                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1437                         //don't show messages like "Timeout ends in 0 seconds"...
1438                         if (remainingTimeoutTime > 0)
1439                                 return retStr;
1440                         else
1441                                 return "";
1442                 }
1443         }
1444         else return "";
1445 }
1446
1447 void player_powerups (void)
1448 {
1449         if (g_minstagib)
1450         {
1451                 if (self.items & IT_STRENGTH)
1452                 {
1453                         if (time > self.strength_finished)
1454                         {
1455                                 if (g_minstagib_invis_alpha > 0)
1456                                 {
1457                                         self.alpha = default_player_alpha;
1458                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1459                                         self.effects = self.effects | EF_FULLBRIGHT;
1460                                 }
1461                                 else
1462                                 {
1463                                         self.effects -= self.effects & EF_NODRAW;
1464                                 }
1465                                 self.items = self.items - (self.items & IT_STRENGTH);
1466                                 sprint(self, "^3Invisibility has worn off\n");
1467                         }
1468                 }
1469                 else
1470                 {
1471                         if (time < self.strength_finished)
1472                         {
1473                                 if (g_minstagib_invis_alpha > 0)
1474                                 {
1475                                         self.alpha = g_minstagib_invis_alpha;
1476                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1477                                         self.effects -= self.effects & EF_FULLBRIGHT;
1478                                 }
1479                                 else
1480                                 {
1481                                         self.effects = self.effects | EF_NODRAW;
1482                                 }
1483                                 self.items = self.items | IT_STRENGTH;
1484                                 sprint(self, "^3You are invisible\n");
1485                         }
1486                 }
1487
1488                 if (self.items & IT_INVINCIBLE)
1489                 {
1490                         if (time > self.invincible_finished)
1491                         {
1492                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1493                                 sprint(self, "^3Speed has worn off\n");
1494                         }
1495                 }
1496                 else
1497                 {
1498                         if (time < self.invincible_finished)
1499                         {
1500                                 self.items = self.items | IT_INVINCIBLE;
1501                                 sprint(self, "^3You are on speed\n");
1502                         }
1503                 }
1504                 return;
1505         }
1506
1507         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1508         if (self.items & IT_STRENGTH)
1509         {
1510                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1511                 if (time > self.strength_finished)
1512                 {
1513                         self.items = self.items - (self.items & IT_STRENGTH);
1514                         sprint(self, "^3Strength has worn off\n");
1515                 }
1516         }
1517         else
1518         {
1519                 if (time < self.strength_finished)
1520                 {
1521                         self.items = self.items | IT_STRENGTH;
1522                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1523                 }
1524         }
1525         if (self.items & IT_INVINCIBLE)
1526         {
1527                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1528                 if (time > self.invincible_finished)
1529                 {
1530                         self.items = self.items - (self.items & IT_INVINCIBLE);
1531                         sprint(self, "^3Shield has worn off\n");
1532                 }
1533         }
1534         else
1535         {
1536                 if (time < self.invincible_finished)
1537                 {
1538                         self.items = self.items | IT_INVINCIBLE;
1539                         sprint(self, "^3Shield surrounds you\n");
1540                 }
1541         }
1542
1543         if (cvar("g_fullbrightplayers"))
1544                 self.effects = self.effects | EF_FULLBRIGHT;
1545
1546         // midair gamemode: damage only while in the air
1547         // if in midair mode, being on ground grants temporary invulnerability
1548         // (this is so that multishot weapon don't clear the ground flag on the
1549         // first damage in the frame, leaving the player vulnerable to the
1550         // remaining hits in the same frame)
1551         if (self.flags & FL_ONGROUND)
1552         if (g_midair)
1553                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1554
1555         if (time < self.spawnshieldtime)
1556                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1557 }
1558
1559 float CalcRegen(float current, float stable, float regenfactor)
1560 {
1561         if(current > stable)
1562                 return current;
1563         else if(current > stable - 0.25) // when close enough, "snap"
1564                 return stable;
1565         else
1566                 return min(stable, current + (stable - current) * regenfactor * frametime);
1567 }
1568
1569 void player_regen (void)
1570 {
1571         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1572         maxh = cvar("g_balance_health_stable");
1573         maxa = cvar("g_balance_armor_stable");
1574         limith = cvar("g_balance_health_limit");
1575         limita = cvar("g_balance_armor_limit");
1576
1577         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1578                 return;
1579
1580         max_mod = regen_mod = rot_mod = limit_mod = 1;
1581
1582         if (self.runes & RUNE_REGEN)
1583         {
1584                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1585                 {
1586                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1587                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1588                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1589                 }
1590                 else
1591                 {
1592                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1593                         max_mod = cvar("g_balance_rune_regen_hpmod");
1594                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1595                 }
1596         }
1597         else if (self.runes & CURSE_VENOM)
1598         {
1599                 max_mod = cvar("g_balance_curse_venom_hpmod");
1600                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1601                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1602                 else
1603                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1604                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1605                 //if (!self.runes & RUNE_REGEN)
1606                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1607         }
1608         maxh = maxh * max_mod;
1609         //maxa = maxa * max_mod;
1610         limith = limith * limit_mod;
1611         limita = limita * limit_mod;
1612
1613         if (self.armorvalue > maxa)
1614         {
1615                 if (time > self.pauserotarmor_finished)
1616                 {
1617                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1618                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1619                 }
1620         }
1621         else if (self.armorvalue < maxa)
1622         {
1623                 if (time > self.pauseregen_finished)
1624                 {
1625                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1626                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1627                 }
1628         }
1629         if (self.health > maxh)
1630         {
1631                 if (time > self.pauserothealth_finished)
1632                 {
1633                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1634                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1635                 }
1636         }
1637         else if (self.health < maxh)
1638         {
1639                 if (time > self.pauseregen_finished)
1640                 {
1641                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1642                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1643                 }
1644         }
1645
1646         if (self.health > limith)
1647                 self.health = limith;
1648         if (self.armorvalue > limita)
1649                 self.armorvalue = limita;
1650
1651         // if player rotted to death...  die!
1652         if(self.health < 1)
1653                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1654 }
1655
1656 /*
1657 ======================
1658 spectate mode routines
1659 ======================
1660 */
1661 void SpectateCopy(entity spectatee) {
1662         self.armortype = spectatee.armortype;
1663         self.armorvalue = spectatee.armorvalue;
1664         self.currentammo = spectatee.currentammo;
1665         self.effects = spectatee.effects;
1666         self.health = spectatee.health;
1667         self.impulse = 0;
1668         self.items = spectatee.items;
1669         self.punchangle = spectatee.punchangle;
1670         self.view_ofs = spectatee.view_ofs;
1671         self.v_angle = spectatee.v_angle;
1672         self.viewzoom = spectatee.viewzoom;
1673         self.velocity = spectatee.velocity;
1674         self.dmg_take = spectatee.dmg_take;
1675         self.dmg_save = spectatee.dmg_save;
1676         self.dmg_inflictor = spectatee.dmg_inflictor;
1677         self.angles = spectatee.v_angle;
1678         self.fixangle = TRUE;
1679         setorigin(self, spectatee.origin);
1680         setsize(self, spectatee.mins, spectatee.maxs);
1681 }
1682
1683 float SpectateUpdate() {
1684         if(!self.enemy)
1685                 return 0;
1686
1687         if (self == self.enemy)
1688                 return 0;
1689
1690         if(self.enemy.flags & FL_NOTARGET)
1691                 return 0;
1692
1693         SpectateCopy(self.enemy);
1694
1695         return 1;
1696 }
1697
1698 float SpectateNext() {
1699         other = find(self.enemy, classname, "player");
1700         if (!other) {
1701                 other = find(other, classname, "player");
1702         }
1703         if (other) {
1704                 self.enemy = other;
1705         }
1706         if(self.enemy.classname == "player") {
1707                 msg_entity = self;
1708                 WriteByte(MSG_ONE, SVC_SETVIEW);
1709                 WriteEntity(MSG_ONE, self.enemy);
1710                 self.wantswelcomemessage = 1;
1711                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1712                 if(!SpectateUpdate())
1713                         PutObserverInServer();
1714                 return 1;
1715         } else {
1716                 return 0;
1717         }
1718 }
1719
1720 /*
1721 =============
1722 ShowRespawnCountdown()
1723
1724 Update a respawn countdown display.
1725 =============
1726 */
1727 void ShowRespawnCountdown()
1728 {
1729         float number;
1730         if(self.deadflag == DEAD_NO) // just respawned?
1731                 return;
1732         else
1733         {
1734                 number = ceil(self.death_time - time);
1735                 if(number <= 0)
1736                         return;
1737                 if(number <= self.respawn_countdown)
1738                 {
1739                         self.respawn_countdown = number - 1;
1740                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1741                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1742                 }
1743         }
1744 }
1745
1746 void LeaveSpectatorMode()
1747 {
1748         if(isJoinAllowed()) {
1749                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1750                         self.classname = "player";
1751                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1752                                 JoinBestTeam(self, FALSE, TRUE);
1753                         if(cvar("g_campaign"))
1754                                 campaign_bots_may_start = 1;
1755                         PutClientInServer();
1756                         if(!(self.flags & FL_NOTARGET))
1757                                 bprint ("^4", self.netname, "^4 is playing now\n");
1758                         centerprint(self,"");
1759                         return;
1760                 } else {
1761                         stuffcmd(self,"menu_showteamselect\n");
1762                         return;
1763                 }
1764         }
1765         else {
1766                 //player may not join because of g_maxplayers is set
1767                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1768         }
1769 }
1770
1771 /**
1772  * Determines whether the player is allowed to join. This depends on cvar
1773  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1774  * it checks whether the number of currently playing players exceeds g_maxplayers.
1775  * @return bool TRUE if the player is allowed to join, false otherwise
1776  */
1777 float isJoinAllowed() {
1778         if (!cvar("g_maxplayers"))
1779                 return TRUE;
1780
1781         local entity e;
1782         local float currentlyPlaying;
1783         FOR_EACH_REALPLAYER(e) {
1784                 if(e.classname == "player")
1785                         currentlyPlaying += 1;
1786         }
1787         if(currentlyPlaying < cvar("g_maxplayers"))
1788                 return TRUE;
1789
1790         return FALSE;
1791 }
1792
1793 /**
1794  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1795  * g_maxplayers_spectator_blocktime seconds
1796  */
1797 void checkSpectatorBlock() {
1798         if(self.classname == "spectator" || self.classname == "observer") {
1799                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1800                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1801                         dropclient(self);
1802                 }
1803         }
1804 }
1805
1806 float vercmp_recursive(string v1, string v2)
1807 {
1808         float dot1, dot2;
1809         string s1, s2;
1810         float r;
1811
1812         dot1 = strstrofs(v1, ".", 0);
1813         dot2 = strstrofs(v2, ".", 0);
1814         if(dot1 == -1)
1815                 s1 = v1;
1816         else
1817                 s1 = substring(v1, 0, dot1);
1818         if(dot2 == -1)
1819                 s2 = v2;
1820         else
1821                 s2 = substring(v2, 0, dot2);
1822
1823         r = stof(s1) - stof(s2);
1824         if(r != 0)
1825                 return r;
1826
1827         r = strcasecmp(s1, s2);
1828         if(r != 0)
1829                 return r;
1830
1831         if(dot1 == -1)
1832                 if(dot2 == -1)
1833                         return 0;
1834                 else
1835                         return -1;
1836         else
1837                 if(dot2 == -1)
1838                         return 1;
1839                 else
1840                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1841 }
1842
1843 float vercmp(string v1, string v2)
1844 {
1845         if(strcasecmp(v1, v2) == 0) // early out check
1846                 return 0;
1847         return vercmp_recursive(v1, v2);
1848 }
1849
1850 void ObserverThink()
1851 {
1852         if (self.flags & FL_JUMPRELEASED) {
1853                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1854                         self.welcomemessage_time = 0;
1855                         self.flags = self.flags - FL_JUMPRELEASED;
1856                         LeaveSpectatorMode();
1857                         return;
1858                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1859                         self.welcomemessage_time = 0;
1860                         self.flags = self.flags - FL_JUMPRELEASED;
1861                         if(SpectateNext() == 1) {
1862                                 self.classname = "spectator";
1863                         }
1864                 }
1865         } else {
1866                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1867                         self.flags = self.flags | FL_JUMPRELEASED;
1868                 }
1869         }
1870         if(self.BUTTON_ZOOM)
1871                 self.wantswelcomemessage = 0;
1872         if(self.wantswelcomemessage)
1873                 PrintWelcomeMessage(self);
1874 }
1875
1876 void SpectatorThink()
1877 {
1878         if (self.flags & FL_JUMPRELEASED) {
1879                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1880                         self.welcomemessage_time = 0;
1881                         self.flags = self.flags - FL_JUMPRELEASED;
1882                         LeaveSpectatorMode();
1883                         return;
1884                 } else if(self.BUTTON_ATCK) {
1885                         self.welcomemessage_time = 0;
1886                         self.flags = self.flags - FL_JUMPRELEASED;
1887                         if(SpectateNext() == 1) {
1888                                 self.classname = "spectator";
1889                         } else {
1890                                 self.classname = "observer";
1891                                 PutClientInServer();
1892                         }
1893                 } else if (self.BUTTON_ATCK2) {
1894                         self.welcomemessage_time = 0;
1895                         self.flags = self.flags - FL_JUMPRELEASED;
1896                         self.classname = "observer";
1897                         PutClientInServer();
1898                 } else {
1899                         if(!SpectateUpdate())
1900                                 PutObserverInServer();
1901                 }
1902         } else {
1903                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1904                         self.flags = self.flags | FL_JUMPRELEASED;
1905                 }
1906         }
1907         if(self.BUTTON_ZOOM)
1908                 self.wantswelcomemessage = 0;
1909         if(self.wantswelcomemessage)
1910                 PrintWelcomeMessage(self);
1911         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1912 }
1913
1914 /*
1915 =============
1916 PlayerPreThink
1917
1918 Called every frame for each client before the physics are run
1919 =============
1920 */
1921 void() ctf_setstatus;
1922 .float vote_nagtime;
1923 .float spectatee_status;
1924 void PlayerPreThink (void)
1925 {
1926         if(blockSpectators)
1927                 checkSpectatorBlock();
1928
1929         if(self.netname_previous != self.netname)
1930         {
1931                 if(cvar("sv_eventlog"))
1932                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1933                 if(self.netname_previous)
1934                         strunzone(self.netname_previous);
1935                 self.netname_previous = strzone(self.netname);
1936         }
1937
1938         // version nagging
1939         if(self.version_nagtime)
1940                 if(self.cvar_g_nexuizversion)
1941                         if(time > self.version_nagtime)
1942                         {
1943                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1944                                 {
1945                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1946                                         {
1947                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1948                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1949                                         }
1950                                         else
1951                                         {
1952                                                 float r;
1953                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1954                                                 if(r < 0)
1955                                                 {
1956                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1957                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1958                                                 }
1959                                                 else if(r > 0)
1960                                                 {
1961                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1962                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1963                                                 }
1964                                         }
1965                                 }
1966                                 self.version_nagtime = 0;
1967                         }
1968
1969         // vote nagging
1970         if(self.cvar_scr_centertime)
1971                 if(time > self.vote_nagtime)
1972                 {
1973                         VoteNag();
1974                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1975                 }
1976
1977         // GOD MODE info
1978         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1979         {
1980                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1981                 self.max_armorvalue = 0;
1982         }
1983
1984         if(frametime)
1985                 antilag_record(self);
1986
1987         if(self.classname == "player") {
1988 //              if(self.netname == "Wazat")
1989 //                      bprint(self.classname, "\n");
1990
1991                 CheckRules_Player();
1992
1993                 if(self.BUTTON_INFO)
1994                         PrintWelcomeMessage(self);
1995
1996                 if(g_lms || !cvar("sv_spectate"))
1997                 if((time - self.jointime) <= cvar("welcome_message_time"))
1998                         PrintWelcomeMessage(self);
1999
2000                 if (intermission_running)
2001                 {
2002                         IntermissionThink ();   // otherwise a button could be missed between
2003                         return;                                 // the think tics
2004                 }
2005
2006                 if(self.teleport_time)
2007                 if(time > self.teleport_time)
2008                 {
2009                         self.teleport_time = 0;
2010                         self.effects = self.effects - (self.effects & EF_NODRAW);
2011                         if(self.weaponentity)
2012                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2013                 }
2014
2015                 Nixnex_GiveCurrentWeapon();
2016
2017                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2018                         UpdateSelectedPlayer();
2019
2020                 //don't allow the player to turn around while game is paused!
2021                 if(timeoutStatus == 2) {
2022                         self.v_angle = self.lastV_angle;
2023                         self.angles = self.lastV_angle;
2024                         self.fixangle = TRUE;
2025                 }
2026
2027                 if (self.deadflag != DEAD_NO)
2028                 {
2029                         float button_pressed, force_respawn;
2030                         player_anim();
2031                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2032                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2033                         if (self.deadflag == DEAD_DYING)
2034                         {
2035                                 if(force_respawn)
2036                                         self.deadflag = DEAD_RESPAWNING;
2037                                 else if(!button_pressed)
2038                                         self.deadflag = DEAD_DEAD;
2039                         }
2040                         else if (self.deadflag == DEAD_DEAD)
2041                         {
2042                                 if(button_pressed)
2043                                         self.deadflag = DEAD_RESPAWNABLE;
2044                         }
2045                         else if (self.deadflag == DEAD_RESPAWNABLE)
2046                         {
2047                                 if(!button_pressed)
2048                                         self.deadflag = DEAD_RESPAWNING;
2049                         }
2050                         else if (self.deadflag == DEAD_RESPAWNING)
2051                         {
2052                                 if(time > self.death_time)
2053                                 {
2054                                         self.death_time = time + 1; // only retry once a second
2055                                         respawn();
2056                                 }
2057                         }
2058                         ShowRespawnCountdown();
2059                         return;
2060                 }
2061
2062                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2063                 {
2064                         vector dist;
2065
2066                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2067                         dist = self.oldorigin - self.origin;
2068                         dist_z = 0;
2069                         self.lms_traveled_distance += fabs(vlen(dist));
2070
2071                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
2072                         {
2073                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2074                                 self.lms_traveled_distance = 0;
2075                         }
2076
2077                         if(time > self.lms_nextcheck)
2078                         {
2079                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2080                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2081                                 {
2082                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2083                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2084                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2085                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2086                                 }
2087                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2088                                 self.lms_traveled_distance = 0;
2089                         }
2090                 }
2091
2092                 if (self.BUTTON_CROUCH && !self.hook.state)
2093                 {
2094                         if (!self.crouch)
2095                         {
2096                                 self.crouch = TRUE;
2097                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2098                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2099                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2100                         }
2101                 }
2102                 else
2103                 {
2104                         if (self.crouch)
2105                         {
2106                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2107                                 if (!trace_startsolid)
2108                                 {
2109                                         self.crouch = FALSE;
2110                                         self.view_ofs = PL_VIEW_OFS;
2111                                         setsize (self, PL_MIN, PL_MAX);
2112                                 }
2113                         }
2114                 }
2115
2116                 FixPlayermodel();
2117
2118                 GrapplingHookFrame();
2119
2120                 W_WeaponFrame();
2121
2122                 {
2123                         float zoomfactor, zoomspeed, zoomdir;
2124                         zoomfactor = self.cvar_cl_zoomfactor;
2125                         if(zoomfactor < 1 || zoomfactor > 16)
2126                                 zoomfactor = 2.5;
2127                         zoomspeed = self.cvar_cl_zoomspeed;
2128                         if(zoomspeed >= 0) // < 0 is instant zoom
2129                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2130                                         zoomspeed = 3.5;
2131
2132                         zoomdir = self.BUTTON_ZOOM;
2133                         if(self.BUTTON_ATCK2)
2134                                 if(self.weapon == WEP_NEX)
2135                                         if(!g_minstagib)
2136                                                 zoomdir = 1;
2137
2138                         if(zoomdir)
2139                                 self.has_zoomed = 1;
2140
2141                         if(self.has_zoomed)
2142                         {
2143                                 if(zoomspeed <= 0) // instant zoom
2144                                 {
2145                                         if(zoomdir)
2146                                                 self.viewzoom = 1 / zoomfactor;
2147                                         else
2148                                                 self.viewzoom = 1;
2149                                 }
2150                                 else
2151                                 {
2152                                         // geometric zoom would be:
2153                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2154                                         // however, testing showed that arithmetic/harmonic zoom works better
2155                                         if(zoomdir)
2156                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2157                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2158                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2159                                         else
2160                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2161                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2162                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2163                                 }
2164                         }
2165                         else
2166                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2167                 }
2168
2169                 player_powerups();
2170                 player_regen();
2171                 player_anim();
2172
2173                 if (g_minstagib)
2174                         minstagib_ammocheck();
2175
2176                 ctf_setstatus();
2177                 kh_setstatus();
2178
2179                 //self.angles_y=self.v_angle_y + 90;   // temp
2180
2181                 //if (TetrisPreFrame()) return;
2182         } else if(gameover) {
2183                 if (intermission_running)
2184                         IntermissionThink ();   // otherwise a button could be missed between
2185                 return;
2186         } else if(self.classname == "observer") {
2187                 ObserverThink();
2188         } else if(self.classname == "spectator") {
2189                 SpectatorThink();
2190         }
2191
2192         float oldspectatee_status;
2193         oldspectatee_status = self.spectatee_status;
2194         if(self.classname == "spectator")
2195                 self.spectatee_status = num_for_edict(self.enemy);
2196         else if(self.classname == "observer")
2197                 self.spectatee_status = num_for_edict(self);
2198         else
2199                 self.spectatee_status = 0;
2200         if(self.spectatee_status != oldspectatee_status)
2201         {
2202                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2203                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2204                 WriteByte(MSG_ONE, self.spectatee_status);
2205         }
2206 }
2207
2208
2209 /*
2210 =============
2211 PlayerPostThink
2212
2213 Called every frame for each client after the physics are run
2214 =============
2215 */
2216 .float idlekick_lasttimeleft;
2217 .float race_penalty;
2218 .float race_penalty_nagged;
2219 void PlayerPostThink (void)
2220 {
2221         // Savage: Check for nameless players
2222         if (strlen(self.netname) < 1) {
2223                 self.netname = "Player";
2224                 stuffcmd(self, "seta _cl_name Player\n");
2225         }
2226
2227         if(sv_maxidle)
2228         {
2229                 float timeleft;
2230                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2231                 if(timeleft <= 0)
2232                 {
2233                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2234                         announce(self, "announcer/robotic/terminated.ogg");
2235                         dropclient(self);
2236                         return;
2237                 }
2238                 else if(timeleft <= 10)
2239                 {
2240                         if(timeleft != self.idlekick_lasttimeleft)
2241                         {
2242                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2243                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2244                         }
2245                 }
2246                 else
2247                 {
2248                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2249                 }
2250                 self.idlekick_lasttimeleft = timeleft;
2251         }
2252
2253         if(self.classname == "player") {
2254                 CheckRules_Player();
2255                 UpdateChatBubble();
2256                 UpdateTeamBubble();
2257                 if (self.impulse)
2258                         ImpulseCommands();
2259                 if (intermission_running)
2260                         return;         // intermission or finale
2261
2262                 //PrintWelcomeMessage(self);
2263                 //if (TetrisPostFrame()) return;
2264
2265                 // restart countdown
2266                 if (restart_countdown) {
2267                         if(time < restart_countdown) {
2268                                 if (!cvar("sv_ready_restart_after_countdown"))
2269                                 {
2270                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2271                                         {
2272                                                 if(time < restart_countdown - 2)
2273                                                 {
2274                                                         if(!self.race_penalty_nagged)
2275                                                         {
2276                                                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2277                                                                 self.race_penalty_nagged = 1;
2278                                                         }
2279                                                 }
2280                                                 else if(!self.race_penalty)
2281                                                 {
2282                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2283                                                         self.race_penalty = time + 5;
2284                                                 }
2285                                         }
2286                                         self.movetype = MOVETYPE_NONE;
2287                                         self.velocity = '0 0 0';
2288                                         self.avelocity = '0 0 0';
2289                                         self.movement = '0 0 0';
2290                                 }
2291                         }
2292                         else if (time < self.race_penalty)
2293                         {
2294                                 self.movetype = MOVETYPE_NONE;
2295                                 self.velocity = '0 0 0';
2296                                 self.avelocity = '0 0 0';
2297                                 self.movement = '0 0 0';
2298                         }
2299                         else
2300                         {
2301                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2302                                 if (!cvar("sv_ready_restart_after_countdown"))
2303                                 {
2304                                         if(self.movetype == MOVETYPE_NONE)
2305                                         {
2306                                                 self.movetype = MOVETYPE_WALK;
2307                                         }
2308                                         self.race_penalty = 0;
2309                                         self.race_penalty_nagged = 0;
2310                                 }
2311                         }
2312                 }
2313
2314         } else if (self.classname == "observer") {
2315                 //do nothing
2316         } else if (self.classname == "spectator") {
2317                 //do nothing
2318         }
2319
2320         /*
2321         float i;
2322         for(i = 0; i < 1000; ++i)
2323         {
2324                 vector end;
2325                 end = self.origin + '0 0 1024' + 512 * randomvec();
2326                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2327                 if(trace_fraction < 1)
2328                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2329                 {
2330                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2331                         break;
2332                 }
2333         }
2334         */
2335
2336         Arena_Warmup();
2337 }