data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         info_player_deathmatch();
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8         self.classname = "info_player_deathmatch";
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27
  28                 local float spotactive;
  29                 spotactive = 1;
  30
  31                 // filter out spots for assault
  32                 if(spot.target != "") {
  33                         local entity ent;
  34                         ent = find(world, targetname, spot.target);
  35                         while(ent) {
  36                                 if(ent.classname == "target_objective")
  37                                         if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  38                                                 spotactive = 0;
  39                                 ent = find(ent, targetname, spot.target);
  40                         }
  41                 }
  42
  43                 if (spot.team == teamcheck && spotactive > 0)
  44                 {
  45                         pcount = 0;
  46                         player = playerlist;
  47                         while (player)
  48                         {
  49                                 if (player != self)
  50                                 if (vlen(player.origin - spot.origin) < mindist)
  51                                         pcount = pcount + 1;
  52                                 player = player.chain;
  53                         }
  54                         if (!pcount)
  55                         {
  56                                 spawn_allbad = FALSE;
  57                                 if (newfirstspot)
  58                                         previousspot.chain = spot;
  59                                 else
  60                                         newfirstspot = spot;
  61                                 previousspot = spot;
  62                                 spot.chain = world;
  63                         }
  64                         else
  65                                 spawn_allgood = FALSE;
  66                 }
  67                 spot = nextspot;
  68         }
  69         // if we couldn't find ANY good points, return the original list
  70         if (!newfirstspot)
  71                 newfirstspot = firstspot;
  72         return newfirstspot;
  73 }
  74
  75 entity Spawn_RandomPoint(entity firstspot)
  76 {
  77         local entity spot;
  78         local float numspots;
  79         // count number of spots
  80         numspots = 0;
  81         spot = firstspot;
  82         while (spot)
  83         {
  84                 numspots = numspots + 1;
  85                 spot = spot.chain;
  86         }
  87         // pick a random one
  88         numspots = numspots * random();
  89         spot = firstspot;
  90         while (spot.chain && numspots >= 1)
  91         {
  92                 numspots = numspots - 1;
  93                 spot = spot.chain;
  94         }
  95         return spot;
  96 }
  97
  98 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  99 {
 100         local entity best, spot, player;
 101         local float bestrating, rating;
 102         best = world;
 103         bestrating = -1000000;
 104         spot = firstspot;
 105         while (spot)
 106         {
 107                 rating = 1000000000;
 108                 player = playerlist;
 109                 while (player)
 110                 {
 111                         if (player != self)
 112                                 rating = min(rating, vlen(player.origin - spot.origin));
 113                         player = player.chain;
 114                 }
 115                 rating = rating + random() * 16;
 116                 if (bestrating < rating)
 117                 {
 118                         best = spot;
 119                         bestrating = rating;
 120                 }
 121                 spot = spot.chain;
 122         }
 123         return best;
 124 }
 125
 126 /*
 127 =============
 128 SelectSpawnPoint
 129
 130 Finds a point to respawn
 131 =============
 132 */
 133 entity SelectSpawnPoint (float anypoint)
 134 {
 135         local float teamcheck;
 136         local entity spot, firstspot, playerlist;
 137
 138         spot = find (world, classname, "testplayerstart");
 139         if (spot)
 140                 return spot;
 141
 142         teamcheck = 0;
 143
 144         if(!anypoint && (g_ctf || g_assault))
 145                 teamcheck = self.team;
 146
 147         // get the list of players
 148         playerlist = findchain(classname, "player");
 149         // get the entire list of spots
 150         firstspot = findchain(classname, "info_player_deathmatch");
 151         // filter out the bad ones
 152         // (note this returns the original list if none survived)
 153         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 154
 155         // there is 50/50 chance of choosing a random spot or the furthest spot
 156         // (this means that roughly every other spawn will be furthest, so you
 157         // usually won't get fragged at spawn twice in a row)
 158         if (arena_roundbased)
 159         {
 160                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 161                 spot = Spawn_RandomPoint(firstspot);
 162         }
 163         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 164                 spot = Spawn_RandomPoint(firstspot);
 165         else
 166                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 167
 168         if (!spot)
 169         {
 170                 if(cvar("spawn_debug"))
 171                         GotoNextMap();
 172                 else
 173                         error ("PutClientInServer: no start points on level");
 174         }
 175
 176         return spot;
 177 }
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel = "models/player/marine.zym";
 188 string CheckPlayerModel(string plyermodel) {
 189         if(strlen(plyermodel) < 4)
 190                 return FallbackPlayerModel;
 191         if( substring(plyermodel,0,14) != "models/player/")
 192                 return FallbackPlayerModel;
 193         else if(cvar("sv_servermodelsonly"))
 194         {
 195                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 196                         return FallbackPlayerModel;
 197                 if(!fexists(plyermodel))
 198                         return FallbackPlayerModel;
 199         }
 200         return plyermodel;
 201 }
 202
 203 /*
 204 =============
 205 Client_customizeentityforclient
 206
 207 LOD reduction
 208 =============
 209 */
 210 float Client_customizeentityforclient()
 211 {
 212 #ifdef ALLOW_VARIABLE_LOD
 213         // self: me
 214         // other: the player viewing me
 215         float distance;
 216         float f;
 217
 218         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 219                 return TRUE;
 220
 221         if(other.cvar_cl_playerdetailreduction <= 0)
 222         {
 223                 if(other.cvar_cl_playerdetailreduction <= -2)
 224                         self.modelindex = self.modelindex_lod2;
 225                 else if(other.cvar_cl_playerdetailreduction <= -1)
 226                         self.modelindex = self.modelindex_lod1;
 227                 else
 228                         self.modelindex = self.modelindex_lod0;
 229         }
 230         else
 231         {
 232                 distance = vlen(self.origin - other.origin);
 233                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 234                 if(f > 10000)
 235                         self.modelindex = self.modelindex_lod2;
 236                 else if(f > 5000)
 237                         self.modelindex = self.modelindex_lod1;
 238                 else
 239                         self.modelindex = self.modelindex_lod0;
 240         }
 241 #endif
 242
 243         return TRUE;
 244 }
 245
 246 void setmodel_lod(entity e, string modelname)
 247 {
 248 #ifdef ALLOW_VARIABLE_LOD
 249         string s;
 250
 251         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 252         if(fexists(s))
 253         {
 254                 precache_model(s);
 255                 setmodel(e, s); // players have high precision
 256                 self.modelindex_lod1 = self.modelindex;
 257         }
 258         else
 259                 self.modelindex_lod1 = -1;
 260
 261         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 262         if(fexists(s))
 263         {
 264                 precache_model(s);
 265                 setmodel(e, s); // players have high precision
 266                 self.modelindex_lod2 = self.modelindex;
 267         }
 268         else
 269                 self.modelindex_lod2 = -1;
 270
 271         precache_model(modelname);
 272         setmodel(e, modelname); // players have high precision
 273         self.modelindex_lod0 = self.modelindex;
 274
 275         if(self.modelindex_lod1 < 0)
 276                 self.modelindex_lod1 = self.modelindex;
 277
 278         if(self.modelindex_lod2 < 0)
 279                 self.modelindex_lod2 = self.modelindex;
 280 #else
 281         precache_model(modelname);
 282         setmodel(e, modelname); // players have high precision
 283 #endif
 284 }
 285
 286 /*
 287 =============
 288 PutObserverInServer
 289
 290 putting a client as observer in the server
 291 =============
 292 */
 293 void PutObserverInServer (void)
 294 {
 295         entity  spot;
 296         spot = SelectSpawnPoint (TRUE);
 297         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 298
 299         if(clienttype(self) == CLIENTTYPE_REAL)
 300         {
 301                 msg_entity = self;
 302                 WriteByte(MSG_ONE, SVC_SETVIEW);
 303                 WriteEntity(MSG_ONE, self);
 304         }
 305
 306         DropAllRunes(self);
 307         kh_Key_DropAll(self, TRUE);
 308
 309         if(self.flagcarried)
 310                 DropFlag(self.flagcarried);
 311
 312         WaypointSprite_PlayerDead();
 313
 314         DistributeFragsAmongTeam(self, self.team, 1);
 315
 316         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
 317                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 318         else if(self.killcount != -666)
 319                 bprint ("^4", self.netname, "^4 is spectating now\n");
 320
 321         self.classname = "observer";
 322         self.health = -666;
 323         self.takedamage = DAMAGE_NO;
 324         self.solid = SOLID_NOT;
 325         self.movetype = MOVETYPE_NOCLIP;
 326         self.flags = FL_CLIENT | FL_NOTARGET;
 327         self.armorvalue = 666;
 328         self.effects = 0;
 329         self.armorvalue = cvar("g_balance_armor_start");
 330         self.pauserotarmor_finished = 0;
 331         self.pauserothealth_finished = 0;
 332         self.pauseregen_finished = 0;
 333         self.damageforcescale = 0;
 334         self.death_time = 0;
 335         self.dead_time = 0;
 336         self.dead_frame = 0;
 337         self.die_frame = 0;
 338         self.deaths = 0;
 339         self.alpha = 0;
 340         self.scale = 0;
 341         self.fade_time = 0;
 342         self.pain_frame = 0;
 343         self.pain_finished = 0;
 344         self.strength_finished = 0;
 345         self.invincible_finished = 0;
 346         self.pushltime = 0;
 347         self.think = SUB_Null;
 348         self.nextthink = 0;
 349         self.hook_time = 0;
 350         self.runes = 0;
 351         self.deadflag = DEAD_NO;
 352         self.angles = spot.angles;
 353         self.angles_z = 0;
 354         self.fixangle = TRUE;
 355         self.crouch = FALSE;
 356
 357         self.view_ofs = PL_VIEW_OFS;
 358         setorigin (self, spot.origin);
 359         setsize (self, '0 0 0', '0 0 0');
 360         self.oldorigin = self.origin;
 361         self.items = 0;
 362         self.model = "";
 363         self.modelindex = 0;
 364         self.weapon = 0;
 365         self.weaponmodel = "";
 366         self.weaponentity = world;
 367         self.killcount = -666;
 368         self.velocity = '0 0 0';
 369         self.avelocity = '0 0 0';
 370         self.punchangle = '0 0 0';
 371         self.punchvector = '0 0 0';
 372         self.oldvelocity = self.velocity;
 373         self.customizeentityforclient = Client_customizeentityforclient;
 374
 375         if(g_arena)
 376         {
 377                 if(self.frags != -2)
 378                 {
 379                         Spawnqueue_Insert(self);
 380                 }
 381                 else
 382                 {
 383                         Spawnqueue_Unmark(self);
 384                         Spawnqueue_Remove(self);
 385                 }
 386         }
 387         else if(!g_lms)
 388                 self.frags = -666;
 389 }
 390
 391
 392 /*
 393 =============
 394 PutClientInServer
 395
 396 Called when a client spawns in the server
 397 =============
 398 */
 399 void PutClientInServer (void)
 400 {
 401         if(clienttype(self) == CLIENTTYPE_BOT)
 402         {
 403                 self.classname = "player";
 404         }
 405         else if(clienttype(self) == CLIENTTYPE_REAL)
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         // player is dead and becomes observer
 413         if(g_lms && self.frags < 1)
 414                 self.classname = "observer";
 415
 416         if(g_arena)
 417         if(!self.spawned)
 418                 self.classname = "observer";
 419
 420         if(self.classname == "player") {
 421                 entity  spot;
 422
 423                 spot = SelectSpawnPoint (FALSE);
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 self.classname = "player";
 428                 self.iscreature = TRUE;
 429                 self.movetype = MOVETYPE_WALK;
 430                 self.solid = SOLID_SLIDEBOX;
 431                 self.flags = FL_CLIENT;
 432                 self.takedamage = DAMAGE_AIM;
 433                 self.effects = 0;
 434                 self.air_finished = time + 12;
 435                 self.dmg = 2;
 436
 437                 self.ammo_shells = start_ammo_shells;
 438                 self.ammo_nails = start_ammo_nails;
 439                 self.ammo_rockets = start_ammo_rockets;
 440                 self.ammo_cells = start_ammo_cells;
 441                 self.health = start_health;
 442                 self.armorvalue = start_armorvalue;
 443                 self.items = start_items;
 444                 self.switchweapon = start_switchweapon;
 445                 self.weapon = 0;
 446                 self.jump_interval = time;
 447
 448                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 449                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 450                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 451                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 452                 self.damageforcescale = 2;
 453                 self.death_time = 0;
 454                 self.dead_time = 0;
 455                 self.dead_frame = 0;
 456                 self.die_frame = 0;
 457                 self.alpha = 0;
 458                 self.scale = 0;
 459                 self.fade_time = 0;
 460                 self.pain_frame = 0;
 461                 self.pain_finished = 0;
 462                 self.strength_finished = 0;
 463                 self.invincible_finished = 0;
 464                 self.pushltime = 0;
 465                 //self.speed_finished = 0;
 466                 //self.slowmo_finished = 0;
 467                 // players have no think function
 468                 self.think = SUB_Null;
 469                 self.nextthink = 0;
 470                 self.hook_time = 0;
 471
 472                 self.runes = 0;
 473
 474                 self.deadflag = DEAD_NO;
 475
 476                 self.angles = spot.angles;
 477
 478                 self.angles_z = 0; // never spawn tilted even if the spot says to
 479                 self.fixangle = TRUE; // turn this way immediately
 480                 self.velocity = '0 0 0';
 481                 self.avelocity = '0 0 0';
 482                 self.punchangle = '0 0 0';
 483                 self.punchvector = '0 0 0';
 484                 self.oldvelocity = self.velocity;
 485
 486                 self.viewzoom = 0.6;
 487                 self.has_zoomed = 0;
 488
 489                 self.customizeentityforclient = Client_customizeentityforclient;
 490
 491                 if(cvar("sv_defaultcharacter") == 1) {
 492                         local string defaultmodel;
 493                         defaultmodel = cvar_string("sv_defaultplayermodel");
 494                         setmodel_lod (self, defaultmodel);
 495                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 496                 } else {
 497                         self.playermodel = CheckPlayerModel(self.playermodel);
 498                         setmodel_lod (self, self.playermodel);
 499                         if(teams_matter)
 500                         {
 501                                 float s;
 502                                 s = stof(self.playerskin);
 503                                 if(s >= 0 && s < 3)
 504                                         self.skin = s;
 505                                 else if(s == 6)
 506                                         self.skin = 6;
 507                                 else
 508                                         self.skin = 0;
 509                         }
 510                         else
 511                                 self.skin = stof(self.playerskin);
 512                 }
 513                 if(!teams_matter)
 514                         if(strlen(cvar_string("sv_defaultplayercolors")))
 515                                 setcolor(self, cvar("sv_defaultplayercolors"));
 516
 517                 self.crouch = FALSE;
 518                 self.view_ofs = PL_VIEW_OFS;
 519                 setsize (self, PL_MIN, PL_MAX);
 520                 self.spawnorigin = spot.origin;
 521                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 522                 // don't reset back to last position, even if new position is stuck in solid
 523                 self.oldorigin = self.origin;
 524
 525                 if(g_arena)
 526                 {
 527                         Spawnqueue_Remove(self);
 528                         Spawnqueue_Mark(self);
 529                 }
 530
 531                 self.event_damage = PlayerDamage;
 532
 533                 self.bot_attack = TRUE;
 534
 535                 self.statdraintime = time + 5;
 536                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 537
 538                 if(self.killcount == -666) {
 539                         self.killcount = 0;
 540                         if(!g_arena)
 541                         if(!g_lms)
 542                                 self.frags = 0;
 543                 }
 544
 545                 self.cnt = WEP_LASER;
 546                 self.nixnex_lastchange_id = -1;
 547
 548                 CL_SpawnWeaponentity();
 549                 self.alpha = default_player_alpha;
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 553                 self.lms_traveled_distance = 0;
 554
 555                 if(cvar("spawn_debug"))
 556                 {
 557                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 558                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 559                 }
 560
 561                 //stuffcmd(self, "chase_active 0");
 562                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 563
 564                 if (cvar("g_spawnsound"))
 565                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
 566
 567                 if(g_assault) {
 568                         if(self.team == assault_attacker_team)
 569                                 centerprint(self, "You are attacking!\n");
 570                         else
 571                                 centerprint(self, "You are defending!\n");
 572                 }
 573
 574         } else if(self.classname == "observer") {
 575                 PutObserverInServer ();
 576         }
 577 }
 578
 579 /*
 580 =============
 581 SetNewParms
 582 =============
 583 */
 584 void SetNewParms (void)
 585 {
 586
 587 }
 588
 589 /*
 590 =============
 591 SetChangeParms
 592 =============
 593 */
 594 void SetChangeParms (void)
 595 {
 596
 597 }
 598
 599 /*
 600 =============
 601 ClientKill
 602
 603 Called when a client types 'kill' in the console
 604 =============
 605 */
 606 void ClientKill (void)
 607 {
 608         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 609 }
 610
 611 void FixClientCvars(entity e)
 612 {
 613         float t;
 614         // send prediction settings to the client
 615         stuffcmd(e, "\nin_bindmap 0 0\n");
 616         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
 617         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 618         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 619         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 620         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 621         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 622         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 623         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
 624         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 625         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 626         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 627         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 628         stuffcmd(e, "cl_movement_edgefriction 1\n");
 629
 630         // notify about available teams
 631         if(teamplay)
 632         {
 633                 CheckAllowedTeams(e);
 634                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
 635                 stuffcmd(e, strcat("set _teams_available ", ftos(t), "\n"));
 636         }
 637         else
 638                 stuffcmd(e, "set _teams_available 0\n");
 639 }
 640
 641 /*
 642 =============
 643 ClientConnect
 644
 645 Called when a client connects to the server
 646 =============
 647 */
 648 string ColoredTeamName(float t);
 649 //void dom_player_join_team(entity pl);
 650 void ClientConnect (void)
 651 {
 652         local string s;
 653         float wep;
 654
 655         if(Ban_IsClientBanned(self))
 656         {
 657                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
 658                 dropclient(self);
 659                 bprint(s);
 660                 return;
 661         }
 662
 663         self.classname = "player_joining";
 664         self.flags = self.flags | FL_CLIENT;
 665         self.version_nagtime = time + 10 + random() * 10;
 666
 667         if(player_count<0)
 668         {
 669                 dprint("BUG player count is lower than zero, this cannot happen!\n");
 670                 player_count = 0;
 671         }
 672
 673         bot_clientconnect();
 674
 675         //if(cvar("g_domination"))
 676         //      dom_player_join_team(self);
 677
 678         //JoinBestTeam(self, FALSE);
 679
 680         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
 681                 self.classname = "observer";
 682         } else {
 683                 self.classname = "player";
 684                 campaign_bots_may_start = 1;
 685         }
 686
 687         self.playerid = (playerid_last = playerid_last + 1);
 688         if(cvar("sv_eventlog"))
 689         {
 690                 if(clienttype(self) == CLIENTTYPE_REAL)
 691                         s = "player";
 692                 else
 693                         s = "bot";
 694                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 695                 s = strcat(":team:", ftos(self.playerid), ":");
 696                 s = strcat(s, ftos(self.team));
 697                 GameLogEcho(s, FALSE);
 698         }
 699
 700         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 701
 702         bprint ("^4",self.netname);
 703         bprint ("^4 connected");
 704
 705         if(cvar("g_domination") || g_ctf)
 706         {
 707                 bprint(" and joined the ");
 708                 bprint(ColoredTeamName(self.team));
 709         }
 710
 711         bprint("\n");
 712
 713         self.welcomemessage_time = 0;
 714
 715         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 716         // TODO: is this being used for anything else than cd tracks?
 717         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 718
 719         FixClientCvars(self);
 720
 721         // waypoint sprites
 722         WaypointSprite_InitClient(self);
 723
 724         // Wazat's grappling hook
 725         SetGrappleHookBindings();
 726
 727         // get autoswitch state from player when he toggles it
 728         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n");
 729
 730         // get version info from player
 731         stuffcmd(self, "cmd clientversion $gameversion\n");
 732
 733         // send all weapon info strings
 734         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
 735         wep = WEP_FIRST;
 736         while (wep <= WEP_LAST)
 737         {
 738                 weapon_action(wep, WR_REGISTER);
 739                 wep = wep + 1;
 740         }
 741
 742         // get other cvars from player
 743         GetCvars(0);
 744
 745         // set cvar for team scoreboard
 746         if (teams_matter)
 747         {
 748                 local float t;
 749                 t = cvar("teamplay");
 750                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 751                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 752         }
 753         else
 754                 stuffcmd(self, "set teamplay 0\n");
 755
 756         if(g_lms)
 757         {
 758                 self.frags = cvar("fraglimit");
 759                 // no fraglimit was set, so player gets 999 lives
 760                 if(self.frags < 1)
 761                         self.frags = 999;
 762
 763                 self.frags = LMS_NewPlayerLives();
 764                 if(!self.frags)
 765                 {
 766                         self.frags = -666;
 767                 }
 768         }
 769         else if(g_arena)
 770         {
 771                 self.classname = "observer";
 772                 Spawnqueue_Insert(self);
 773         }
 774
 775         bot_relinkplayerlist();
 776
 777         self.jointime = time;
 778 }
 779
 780 /*
 781 =============
 782 ClientDisconnect
 783
 784 Called when a client disconnects from the server
 785 =============
 786 */
 787 void(entity e) DropFlag;
 788 .entity chatbubbleentity;
 789 .entity teambubbleentity;
 790 void ClientDisconnect (void)
 791 {
 792         float save;
 793         if(cvar("sv_eventlog"))
 794                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 795         bprint ("^4",self.netname);
 796         bprint ("^4 disconnected\n");
 797
 798         if (self.chatbubbleentity)
 799         {
 800                 remove (self.chatbubbleentity);
 801                 self.chatbubbleentity = world;
 802         }
 803
 804         if (self.teambubbleentity)
 805         {
 806                 remove (self.teambubbleentity);
 807                 self.teambubbleentity = world;
 808         }
 809
 810         WaypointSprite_PlayerGone();
 811
 812         DropAllRunes(self);
 813         kh_Key_DropAll(self, TRUE);
 814
 815         if(self.flagcarried)
 816                 DropFlag(self.flagcarried);
 817
 818         DistributeFragsAmongTeam(self, self.team, 1);
 819
 820         save = self.flags;
 821         self.flags = self.flags - (self.flags & FL_CLIENT);
 822         bot_relinkplayerlist();
 823         self.flags = save;
 824
 825         // remove laserdot
 826         if(self.weaponentity)
 827                 if(self.weaponentity.lasertarget)
 828                         remove(self.weaponentity.lasertarget);
 829
 830         if(g_arena)
 831         {
 832                 Spawnqueue_Unmark(self);
 833                 Spawnqueue_Remove(self);
 834         }
 835
 836         // free cvars
 837         GetCvars(-1);
 838 }
 839
 840 .float buttonchat;
 841 void() ChatBubbleThink =
 842 {
 843         self.nextthink = time;
 844         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 845         {
 846                 self.owner.chatbubbleentity = world;
 847                 remove(self);
 848                 return;
 849         }
 850         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 851         if (self.owner.buttonchat && !self.owner.deadflag)
 852                 self.model = self.mdl;
 853         else
 854                 self.model = "";
 855 };
 856
 857 void() UpdateChatBubble =
 858 {
 859         if (!self.modelindex)
 860                 return;
 861         // spawn a chatbubble entity if needed
 862         if (!self.chatbubbleentity)
 863         {
 864                 self.chatbubbleentity = spawn();
 865                 self.chatbubbleentity.owner = self;
 866                 self.chatbubbleentity.exteriormodeltoclient = self;
 867                 self.chatbubbleentity.think = ChatBubbleThink;
 868                 self.chatbubbleentity.nextthink = time;
 869                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
 870                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 871                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 872                 self.chatbubbleentity.model = "";
 873                 self.chatbubbleentity.effects = EF_LOWPRECISION;
 874         }
 875 }
 876
 877
 878 void() TeamBubbleThink =
 879 {
 880         self.nextthink = time;
 881         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 882         {
 883                 self.owner.teambubbleentity = world;
 884                 remove(self);
 885                 return;
 886         }
 887 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 888         if (self.owner.buttonchat || self.owner.deadflag)
 889                 self.model = "";
 890         else
 891                 self.model = self.mdl;
 892
 893 };
 894
 895 float() TeamBubble_customizeentityforclient
 896 {
 897         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
 898 }
 899
 900 void() UpdateTeamBubble =
 901 {
 902         if (!self.modelindex || !cvar("teamplay"))
 903                 return;
 904         // spawn a teambubble entity if needed
 905         if (!self.teambubbleentity && cvar("teamplay"))
 906         {
 907                 self.teambubbleentity = spawn();
 908                 self.teambubbleentity.owner = self;
 909                 self.teambubbleentity.exteriormodeltoclient = self;
 910                 self.teambubbleentity.think = TeamBubbleThink;
 911                 self.teambubbleentity.nextthink = time;
 912                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
 913 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 914                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 915                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 916                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 917                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 918                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
 919                 self.teambubbleentity.effects = EF_LOWPRECISION;
 920         }
 921 }
 922
 923 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 924 // added to the model skins
 925 /*void() UpdateColorModHack =
 926 {
 927         local float c;
 928         c = self.clientcolors & 15;
 929         // LordHavoc: only bothering to support white, green, red, yellow, blue
 930              if (teamplay == 0) self.colormod = '0 0 0';
 931         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 932         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 933         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 934         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 935         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 936         else self.colormod = '1 1 1';
 937 };*/
 938
 939 void respawn(void)
 940 {
 941         CopyBody(1);
 942         PutClientInServer();
 943 }
 944
 945 void player_powerups (void)
 946 {
 947         if (cvar("g_minstagib"))
 948         {
 949                 self.effects = EF_FULLBRIGHT;
 950                 if (self.items & IT_STRENGTH)
 951                 {
 952                         if (time > self.strength_finished)
 953                         {
 954                                 self.alpha = default_player_alpha;
 955                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 956                                 self.items = self.items - (self.items & IT_STRENGTH);
 957                                 sprint(self, "^3Invisibility has worn off\n");
 958                         }
 959                 }
 960                 else
 961                 {
 962                         if (time < self.strength_finished)
 963                         {
 964                                 self.alpha = cvar("g_minstagib_invis_alpha");
 965                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 966                                 self.items = self.items | IT_STRENGTH;
 967                                 sprint(self, "^3You are invisible\n");
 968                         }
 969                 }
 970
 971                 if (self.items & IT_INVINCIBLE)
 972                 {
 973                         if (time > self.invincible_finished)
 974                         {
 975                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 976                                 sprint(self, "^3Speed has worn off\n");
 977                         }
 978                 }
 979                 else
 980                 {
 981                         if (time < self.invincible_finished)
 982                         {
 983                                 self.items = self.items | IT_INVINCIBLE;
 984                                 sprint(self, "^3You are on speed\n");
 985                         }
 986                 }
 987                 return;
 988         }
 989
 990         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 991         if (self.items & IT_STRENGTH)
 992         {
 993                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 994                 if (time > self.strength_finished)
 995                 {
 996                         self.items = self.items - (self.items & IT_STRENGTH);
 997                         sprint(self, "^3Strength has worn off\n");
 998                 }
 999         }
1000         else
1001         {
1002                 if (time < self.strength_finished)
1003                 {
1004                         self.items = self.items | IT_STRENGTH;
1005                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1006                 }
1007         }
1008         if (self.items & IT_INVINCIBLE)
1009         {
1010                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1011                 if (time > self.invincible_finished)
1012                 {
1013                         self.items = self.items - (self.items & IT_INVINCIBLE);
1014                         sprint(self, "^3Shield has worn off\n");
1015                 }
1016         }
1017         else
1018         {
1019                 if (time < self.invincible_finished)
1020                 {
1021                         self.items = self.items | IT_INVINCIBLE;
1022                         sprint(self, "^3Shield surrounds you\n");
1023                 }
1024         }
1025
1026         if (cvar("g_fullbrightplayers"))
1027                 self.effects = self.effects | EF_FULLBRIGHT;
1028
1029         // midair gamemode: damage only while in the air
1030         // if in midair mode, being on ground grants temporary invulnerability
1031         // (this is so that multishot weapon don't clear the ground flag on the
1032         // first damage in the frame, leaving the player vulnerable to the
1033         // remaining hits in the same frame)
1034         if (self.flags & FL_ONGROUND)
1035         if (cvar("g_midair"))
1036                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1037
1038         if (time < self.spawnshieldtime)
1039                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1040 }
1041
1042 float CalcRegen(float current, float stable, float regenfactor)
1043 {
1044         if(current > stable)
1045                 return current;
1046         else if(current > stable - 0.25) // when close enough, "snap"
1047                 return stable;
1048         else
1049                 return min(stable, current + (stable - current) * regenfactor * frametime);
1050 }
1051
1052 void player_regen (void)
1053 {
1054         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1055         maxh = cvar("g_balance_health_stable");
1056         maxa = cvar("g_balance_armor_stable");
1057         limith = cvar("g_balance_health_limit");
1058         limita = cvar("g_balance_armor_limit");
1059
1060         if (cvar("g_minstagib") || (g_lms && !cvar("g_lms_regenerate")))
1061                 return;
1062
1063         max_mod = regen_mod = rot_mod = limit_mod = 1;
1064
1065         if (self.runes & RUNE_REGEN)
1066         {
1067                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1068                 {
1069                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1070                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1071                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1072                 }
1073                 else
1074                 {
1075                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1076                         max_mod = cvar("g_balance_rune_regen_hpmod");
1077                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1078                 }
1079         }
1080         else if (self.runes & CURSE_VENOM)
1081         {
1082                 max_mod = cvar("g_balance_curse_venom_hpmod");
1083                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1084                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1085                 else
1086                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1087                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1088                 //if (!self.runes & RUNE_REGEN)
1089                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1090         }
1091         maxh = maxh * max_mod;
1092         //maxa = maxa * max_mod;
1093         limith = limith * limit_mod;
1094         limita = limita * limit_mod;
1095
1096         if (self.armorvalue > maxa)
1097         {
1098                 if (time > self.pauserotarmor_finished)
1099                 {
1100                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1101                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1102                 }
1103         }
1104         else if (self.armorvalue < maxa)
1105         {
1106                 if (time > self.pauseregen_finished)
1107                 {
1108                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1109                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1110                 }
1111         }
1112         if (self.health > maxh)
1113         {
1114                 if (time > self.pauserothealth_finished)
1115                 {
1116                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1117                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1118                 }
1119         }
1120         else if (self.health < maxh)
1121         {
1122                 if (time > self.pauseregen_finished)
1123                 {
1124                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1125                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1126                 }
1127         }
1128
1129         if (self.health > limith)
1130                 self.health = limith;
1131         if (self.armorvalue > limita)
1132                 self.armorvalue = limita;
1133
1134         // if player rotted to death...  die!
1135         if(self.health < 1)
1136                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1137 }
1138
1139 /*
1140 ======================
1141 spectate mode routines
1142 ======================
1143 */
1144 void SpectateCopy(entity spectatee) {
1145         self.armortype = spectatee.armortype;
1146         self.armorvalue = spectatee.armorvalue;
1147         self.currentammo = spectatee.currentammo;
1148         self.effects = spectatee.effects;
1149         self.health = spectatee.health;
1150         self.impulse = 0;
1151         self.items = spectatee.items;
1152         self.punchangle = spectatee.punchangle;
1153         self.view_ofs = spectatee.view_ofs;
1154         self.v_angle = spectatee.v_angle;
1155         self.viewzoom = spectatee.viewzoom;
1156         setorigin(self, spectatee.origin);
1157         setsize(self, spectatee.mins, spectatee.maxs);
1158 }
1159
1160 void SpectateUpdate() {
1161         if(!self.enemy)
1162                         PutObserverInServer();
1163
1164         if (self != self.enemy) {
1165                 if(self.enemy.flags & FL_NOTARGET)
1166                         PutObserverInServer();
1167                 SpectateCopy(self.enemy);
1168                 self.dmg_take = self.enemy.dmg_take;
1169                 self.dmg_save = self.enemy.dmg_save;
1170                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1171                 self.fixangle = TRUE;
1172                 self.angles = self.enemy.v_angle;
1173                 //msg_entity = self;
1174                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1175                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1176                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1177                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1178         }
1179 }
1180
1181 float SpectateNext() {
1182         other = find(self.enemy, classname, "player");
1183         if (!other) {
1184                 other = find(other, classname, "player");
1185         }
1186         if (other) {
1187                 self.enemy = other;
1188         }
1189         if(self.enemy.classname == "player") {
1190                 msg_entity = self;
1191                 WriteByte(MSG_ONE, SVC_SETVIEW);
1192                 WriteEntity(MSG_ONE, self.enemy);
1193                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1194                 SpectateUpdate();
1195                 return 1;
1196         } else {
1197                 return 0;
1198         }
1199 }
1200
1201 /*
1202 =============
1203 ShowRespawnCountdown()
1204
1205 Update a respawn countdown display.
1206 =============
1207 */
1208 void ShowRespawnCountdown()
1209 {
1210         float number;
1211         if(self.deadflag == DEAD_NO) // just respawned?
1212                 return;
1213         else
1214         {
1215                 number = ceil(self.death_time - time);
1216                 if(number <= 0)
1217                         return;
1218                 if(number <= self.respawn_countdown)
1219                 {
1220                         self.respawn_countdown = number - 1;
1221                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1222                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1223                 }
1224         }
1225 }
1226
1227 void LeaveSpectatorMode()
1228 {
1229         if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1230                 self.classname = "player";
1231                 if(cvar("g_campaign") || cvar("g_balance_teams"))
1232                         JoinBestTeam(self, 0);
1233                 if(cvar("g_campaign"))
1234                         campaign_bots_may_start = 1;
1235                 PutClientInServer();
1236                 if(!(self.flags & FL_NOTARGET))
1237                         bprint ("^4", self.netname, "^4 is playing now\n");
1238                 centerprint(self,"");
1239                 return;
1240         } else {
1241                 stuffcmd(self,"menu_showteamselect\n");
1242                 return;
1243         }
1244 }
1245
1246 /*
1247 =============
1248 PlayerPreThink
1249
1250 Called every frame for each client before the physics are run
1251 =============
1252 */
1253 void() ctf_setstatus;
1254 .float vote_nagtime;
1255 void PlayerPreThink (void)
1256 {
1257         // version nagging
1258         if(self.version_nagtime)
1259                 if(self.cvar_g_nexuizversion)
1260                         if(time > self.version_nagtime)
1261                         {
1262                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1263                                         if(self.cvar_g_nexuizversion != cvar_string("g_nexuizversion"))
1264                                         {
1265                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n");
1266                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "\n"));
1267                                         }
1268                                 self.version_nagtime = 0;
1269                         }
1270
1271         // vote nagging
1272         if(self.cvar_scr_centertime)
1273                 if(time > self.vote_nagtime)
1274                 {
1275                         VoteNag();
1276                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1277                 }
1278
1279         // GOD MODE info
1280         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1281         {
1282                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1283                 self.max_armorvalue = 0;
1284         }
1285
1286         if(self.classname == "player") {
1287                 local vector m1, m2;
1288
1289 //              if(self.netname == "Wazat")
1290 //                      bprint(self.classname, "\n");
1291
1292                 CheckRules_Player();
1293
1294                 if(self.button7)
1295                         PrintWelcomeMessage(self);
1296
1297                 if(g_lms || !cvar("sv_spectate"))
1298                 if((time - self.jointime) <= cvar("welcome_message_time"))
1299                         PrintWelcomeMessage(self);
1300
1301                 if (intermission_running)
1302                 {
1303                         IntermissionThink ();   // otherwise a button could be missed between
1304                         return;                                 // the think tics
1305                 }
1306
1307                 if(time > self.teleport_time)
1308                 {
1309                         self.effects = self.effects - (self.effects & EF_NODRAW);
1310                         if(self.weaponentity)
1311                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1312                 }
1313
1314                 Nixnex_GiveCurrentWeapon();
1315
1316                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1317                         UpdateSelectedPlayer();
1318
1319                 if (self.deadflag != DEAD_NO)
1320                 {
1321                         float button_pressed, force_respawn;
1322                         player_anim();
1323                         button_pressed = (self.button0 || self.button2 || self.button3 || self.button6 || self.buttonuse);
1324                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1325                         if (self.deadflag == DEAD_DYING)
1326                         {
1327                                 if(force_respawn)
1328                                         self.deadflag = DEAD_RESPAWNING;
1329                                 else if(!button_pressed)
1330                                         self.deadflag = DEAD_DEAD;
1331                         }
1332                         else if (self.deadflag == DEAD_DEAD)
1333                         {
1334                                 if(button_pressed)
1335                                         self.deadflag = DEAD_RESPAWNABLE;
1336                         }
1337                         else if (self.deadflag == DEAD_RESPAWNABLE)
1338                         {
1339                                 if(!button_pressed)
1340                                         self.deadflag = DEAD_RESPAWNING;
1341                         }
1342                         else if (self.deadflag == DEAD_RESPAWNING)
1343                         {
1344                                 if(time > self.death_time)
1345                                         respawn();
1346                         }
1347                         ShowRespawnCountdown();
1348                         return;
1349                 }
1350
1351                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1352                 {
1353                         vector dist;
1354
1355                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1356                         dist = self.oldorigin - self.origin;
1357                         dist_z = 0;
1358                         self.lms_traveled_distance += fabs(vlen(dist));
1359
1360                         if(cvar("g_campaign"))
1361                         if(!campaign_bots_may_start)
1362                         {
1363                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1364                                 self.lms_traveled_distance = 0;
1365                         }
1366
1367                         if(time > self.lms_nextcheck)
1368                         {
1369                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1370                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1371                                 {
1372                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1373                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1374                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1375                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1376                                 }
1377                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1378                                 self.lms_traveled_distance = 0;
1379                         }
1380                 }
1381
1382                 if (self.button5 && !self.hook.state)
1383                 {
1384                         if (!self.crouch)
1385                         {
1386                                 self.crouch = TRUE;
1387                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1388                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1389                         }
1390                 }
1391                 else
1392                 {
1393                         if (self.crouch)
1394                         {
1395                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1396                                 if (!trace_startsolid)
1397                                 {
1398                                         self.crouch = FALSE;
1399                                         self.view_ofs = PL_VIEW_OFS;
1400                                         setsize (self, PL_MIN, PL_MAX);
1401                                 }
1402                         }
1403                 }
1404
1405                 if(cvar("sv_defaultcharacter") == 1) {
1406                         local string defaultmodel;
1407                         defaultmodel = cvar_string("sv_defaultplayermodel");
1408
1409                         if (defaultmodel != self.model)
1410                         {
1411                                 m1 = self.mins;
1412                                 m2 = self.maxs;
1413                                 setmodel_lod (self, defaultmodel);
1414                                 setsize (self, m1, m2);
1415                         }
1416
1417                         if (self.skin != cvar("sv_defaultplayerskin"))
1418                                 self.skin = cvar("sv_defaultplayerskin");
1419                 } else {
1420                         if (self.playermodel != self.model)
1421                         {
1422                                 self.playermodel = CheckPlayerModel(self.playermodel);
1423                                 m1 = self.mins;
1424                                 m2 = self.maxs;
1425                                 setmodel_lod (self, self.playermodel);
1426                                 setsize (self, m1, m2);
1427                         }
1428
1429                         if(teams_matter)
1430                         {
1431                                 if (self.skin != math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY))
1432                                         self.skin = math_mod(stof(self.playerskin), NUM_PLAYERSKINS_TEAMPLAY);
1433                         }
1434                         else
1435                         {
1436                                 if (self.skin != stof(self.playerskin))
1437                                         self.skin = stof(self.playerskin);
1438                         }
1439                 }
1440                 if(!teams_matter)
1441                         if(strlen(cvar_string("sv_defaultplayercolors")))
1442                                 if(self.clientcolors != cvar("sv_defaultplayercolors"))
1443                                         setcolor(self, cvar("sv_defaultplayercolors"));
1444
1445                 GrapplingHookFrame();
1446
1447                 W_WeaponFrame();
1448
1449                 {
1450                         float zoomfactor, zoomspeed, zoomdir;
1451                         zoomfactor = self.cvar_cl_zoomfactor;
1452                         if(zoomfactor < 1 || zoomfactor > 16)
1453                                 zoomfactor = 2.5;
1454                         zoomspeed = self.cvar_cl_zoomspeed;
1455                         if(zoomspeed >= 0) // < 0 is instant zoom
1456                                 if(zoomspeed < 0.5 || zoomspeed > 16)
1457                                         zoomspeed = 3.5;
1458
1459                         zoomdir = self.button4;
1460                         if(self.button3)
1461                                 if(self.weapon == WEP_NEX)
1462                                         if(!cvar("g_minstagib"))
1463                                                 zoomdir = 1;
1464
1465                         if(zoomdir)
1466                                 self.has_zoomed = 1;
1467
1468                         if(self.has_zoomed)
1469                         {
1470                                 if(zoomspeed <= 0) // instant zoom
1471                                 {
1472                                         if(zoomdir)
1473                                                 self.viewzoom = 1 / zoomfactor;
1474                                         else
1475                                                 self.viewzoom = 1;
1476                                 }
1477                                 else
1478                                 {
1479                                         // geometric zoom would be:
1480                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
1481                                         // however, testing showed that arithmetic/harmonic zoom works better
1482                                         if(zoomdir)
1483                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1484                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
1485                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
1486                                         else
1487                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1488                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
1489                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
1490                                 }
1491                         }
1492                         else
1493                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
1494                 }
1495
1496                 player_powerups();
1497                 player_regen();
1498                 player_anim();
1499
1500                 if (cvar("g_minstagib"))
1501                         minstagib_ammocheck();
1502
1503                 ctf_setstatus();
1504                 kh_setstatus();
1505
1506                 //self.angles_y=self.v_angle_y + 90;   // temp
1507
1508                 //if (TetrisPreFrame()) return;
1509         } else if(gameover) {
1510                 if (intermission_running)
1511                         IntermissionThink ();   // otherwise a button could be missed between
1512                 return;
1513         } else if(self.classname == "observer") {
1514
1515                 if (self.flags & FL_JUMPRELEASED) {
1516                         if (self.button2 && self.version == cvar("gameversion")) {
1517                                 self.welcomemessage_time = 0;
1518                                 self.flags = self.flags - FL_JUMPRELEASED;
1519                                 LeaveSpectatorMode();
1520                                 return;
1521                         } else if(self.button0 && self.version == cvar("gameversion")) {
1522                                 self.welcomemessage_time = 0;
1523                                 self.flags = self.flags - FL_JUMPRELEASED;
1524                                 if(SpectateNext() == 1) {
1525                                         self.classname = "spectator";
1526                                 }
1527                         }
1528                 } else {
1529                         if (!(self.button0 || self.button2)) {
1530                                 self.flags = self.flags | FL_JUMPRELEASED;
1531                         }
1532                 }
1533                 PrintWelcomeMessage(self);
1534         } else if(self.classname == "spectator") {
1535                 if (self.flags & FL_JUMPRELEASED) {
1536                         if (self.button2 && self.version == cvar("gameversion")) {
1537                                 self.welcomemessage_time = 0;
1538                                 self.flags = self.flags - FL_JUMPRELEASED;
1539                                 LeaveSpectatorMode();
1540                                 return;
1541                         } else if(self.button0) {
1542                                 self.welcomemessage_time = 0;
1543                                 self.flags = self.flags - FL_JUMPRELEASED;
1544                                 if(SpectateNext() == 1) {
1545                                         self.classname = "spectator";
1546                                 } else {
1547                                         self.classname = "observer";
1548                                         PutClientInServer();
1549                                 }
1550                         } else if (self.button3) {
1551                                 self.welcomemessage_time = 0;
1552                                 self.flags = self.flags - FL_JUMPRELEASED;
1553                                 self.classname = "observer";
1554                                 PutClientInServer();
1555                         } else {
1556                                 SpectateUpdate();
1557                         }
1558                 } else {
1559                         if (!(self.button0 || self.button3)) {
1560                                 self.flags = self.flags | FL_JUMPRELEASED;
1561                         }
1562                 }
1563                 PrintWelcomeMessage(self);
1564                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1565         }
1566 }
1567
1568
1569 /*
1570 =============
1571 PlayerPostThink
1572
1573 Called every frame for each client after the physics are run
1574 =============
1575 */
1576 void PlayerPostThink (void)
1577 {
1578         // Savage: Check for nameless players
1579         if (strlen(self.netname) < 1) {
1580                 self.netname = "Player";
1581                 stuffcmd(self, "seta _cl_name Player\n");
1582         }
1583
1584         if(self.classname == "player") {
1585                 CheckRules_Player();
1586                 UpdateChatBubble();
1587                 UpdateTeamBubble();
1588                 if (self.impulse)
1589                         ImpulseCommands ();
1590                 if (intermission_running)
1591                         return;         // intermission or finale
1592
1593                 //PrintWelcomeMessage(self);
1594                 //if (TetrisPostFrame()) return;
1595         } else if (self.classname == "observer") {
1596                 //do nothing
1597         } else if (self.classname == "spectator") {
1598                 //do nothing
1599         }
1600         Arena_Warmup();
1601 }