data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(!good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, world, world);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.iscreature = FALSE;
 443         self.health = -666;
 444         self.takedamage = DAMAGE_NO;
 445         self.solid = SOLID_NOT;
 446         self.movetype = MOVETYPE_NOCLIP;
 447         self.flags = FL_CLIENT | FL_NOTARGET;
 448         self.armorvalue = 666;
 449         self.effects = 0;
 450         self.armorvalue = cvar("g_balance_armor_start");
 451         self.pauserotarmor_finished = 0;
 452         self.pauserothealth_finished = 0;
 453         self.pauseregen_finished = 0;
 454         self.damageforcescale = 0;
 455         self.death_time = 0;
 456         self.dead_frame = 0;
 457         self.alpha = 0;
 458         self.scale = 0;
 459         self.fade_time = 0;
 460         self.pain_frame = 0;
 461         self.pain_finished = 0;
 462         self.strength_finished = 0;
 463         self.invincible_finished = 0;
 464         self.pushltime = 0;
 465         self.think = SUB_Null;
 466         self.nextthink = 0;
 467         self.hook_time = 0;
 468         self.runes = 0;
 469         self.deadflag = DEAD_NO;
 470         self.angles = spot.angles;
 471         self.angles_z = 0;
 472         self.fixangle = TRUE;
 473         self.crouch = FALSE;
 474
 475         self.view_ofs = PL_VIEW_OFS;
 476         setorigin (self, spot.origin);
 477         setsize (self, '0 0 0', '0 0 0');
 478         self.oldorigin = self.origin;
 479         self.items = 0;
 480         self.weapons = 0;
 481         self.model = "";
 482         self.modelindex = 0;
 483         self.weapon = 0;
 484         self.weaponmodel = "";
 485         self.weaponentity = world;
 486         self.killcount = -666;
 487         self.velocity = '0 0 0';
 488         self.avelocity = '0 0 0';
 489         self.punchangle = '0 0 0';
 490         self.punchvector = '0 0 0';
 491         self.oldvelocity = self.velocity;
 492         self.customizeentityforclient = Client_customizeentityforclient;
 493         self.wantswelcomemessage = 1;
 494
 495         if(g_arena)
 496         {
 497                 if(self.version_mismatch)
 498                 {
 499                         Spawnqueue_Unmark(self);
 500                         Spawnqueue_Remove(self);
 501                 }
 502                 else
 503                 {
 504                         Spawnqueue_Insert(self);
 505                 }
 506         }
 507         else if(g_lms)
 508         {
 509                 // Only if the player cannot play at all
 510                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 511                         self.frags = -666;
 512                 else
 513                         self.frags = -667;
 514         }
 515         else
 516                 self.frags = -666;
 517 }
 518
 519 float RestrictSkin(float s)
 520 {
 521         if(!teams_matter)
 522                 return s;
 523         if(s == 6)
 524                 return 6;
 525         return mod(s, 3);
 526 }
 527
 528 void FixPlayermodel()
 529 {
 530         local string defaultmodel;
 531         local float defaultskin;
 532         local vector m1, m2;
 533
 534         defaultmodel = "";
 535
 536         if(cvar("sv_defaultcharacter") == 1) {
 537                 defaultskin = 0;
 538
 539                 if(teams_matter)
 540                 {
 541                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 542                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 543                 }
 544
 545                 if(defaultmodel == "")
 546                 {
 547                         defaultmodel = cvar_string("sv_defaultplayermodel");
 548                         defaultskin = cvar("sv_defaultplayerskin");
 549                 }
 550         }
 551
 552         if(self.modelindex == 0)
 553         {
 554                 bprint("^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 555                 self.model = "INVALID"; // force the != checks to return true
 556         }
 557
 558         if(defaultmodel != "")
 559         {
 560                 if (defaultmodel != self.model)
 561                 {
 562                         m1 = self.mins;
 563                         m2 = self.maxs;
 564                         setmodel_lod (self, defaultmodel);
 565                         setsize (self, m1, m2);
 566                 }
 567
 568                 self.skin = defaultskin;
 569         } else {
 570                 if (self.playermodel != self.model)
 571                 {
 572                         self.playermodel = CheckPlayerModel(self.playermodel);
 573                         m1 = self.mins;
 574                         m2 = self.maxs;
 575                         setmodel_lod (self, self.playermodel);
 576                         setsize (self, m1, m2);
 577                 }
 578
 579                 self.skin = RestrictSkin(stof(self.playerskin));
 580         }
 581
 582         if(!teams_matter)
 583                 if(strlen(cvar_string("sv_defaultplayercolors")))
 584                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 585                                 setcolor(self, cvar("sv_defaultplayercolors"));
 586 }
 587
 588 /*
 589 =============
 590 PutClientInServer
 591
 592 Called when a client spawns in the server
 593 =============
 594 */
 595 //void() ctf_playerchanged;
 596 void PutClientInServer (void)
 597 {
 598         if(clienttype(self) == CLIENTTYPE_BOT)
 599         {
 600                 self.classname = "player";
 601         }
 602         else if(clienttype(self) == CLIENTTYPE_REAL)
 603         {
 604                 msg_entity = self;
 605                 WriteByte(MSG_ONE, SVC_SETVIEW);
 606                 WriteEntity(MSG_ONE, self);
 607         }
 608
 609         // player is dead and becomes observer
 610         // FIXME fix LMS scoring for new system
 611         if(g_lms)
 612         {
 613                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 614                         self.classname = "observer";
 615         }
 616
 617         if(g_arena)
 618         if(!self.spawned)
 619                 self.classname = "observer";
 620
 621         if(self.classname == "player") {
 622                 entity  spot;
 623
 624                 race_PreSpawn();
 625
 626                 spot = SelectSpawnPoint (FALSE);
 627                 if(!spot)
 628                 {
 629                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 630                         return; // spawn failed
 631                 }
 632
 633                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 634
 635                 self.classname = "player";
 636                 self.iscreature = TRUE;
 637                 self.movetype = MOVETYPE_WALK;
 638                 self.solid = SOLID_SLIDEBOX;
 639                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 640                 if(independent_players)
 641                         MAKE_INDEPENDENT_PLAYER(self);
 642                 self.flags = FL_CLIENT;
 643                 self.takedamage = DAMAGE_AIM;
 644                 if(g_minstagib)
 645                         self.effects = EF_FULLBRIGHT;
 646                 else
 647                         self.effects = 0;
 648                 self.air_finished = time + 12;
 649                 self.dmg = 2;
 650
 651                 if(inWarmupStage)
 652                 {
 653                         self.ammo_shells = warmup_start_ammo_shells;
 654                         self.ammo_nails = warmup_start_ammo_nails;
 655                         self.ammo_rockets = warmup_start_ammo_rockets;
 656                         self.ammo_cells = warmup_start_ammo_cells;
 657                         self.health = warmup_start_health;
 658                         self.armorvalue = warmup_start_armorvalue;
 659                         self.weapons = warmup_start_weapons;
 660                 }
 661                 else
 662                 {
 663                         self.ammo_shells = start_ammo_shells;
 664                         self.ammo_nails = start_ammo_nails;
 665                         self.ammo_rockets = start_ammo_rockets;
 666                         self.ammo_cells = start_ammo_cells;
 667                         self.health = start_health;
 668                         self.armorvalue = start_armorvalue;
 669                         self.weapons = start_weapons;
 670                 }
 671                 self.items = start_items;
 672                 self.switchweapon = w_getbestweapon(self);
 673                 self.cnt = self.switchweapon;
 674                 self.weapon = 0;
 675                 self.jump_interval = time;
 676
 677                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 678                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 679                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 680                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 681                 //extend the pause of rotting if client was reset at the beginning of the countdown
 682                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 683                         self.spawnshieldtime += game_starttime - time;
 684                         self.pauserotarmor_finished += game_starttime - time;
 685                         self.pauserothealth_finished += game_starttime - time;
 686                         self.pauseregen_finished += game_starttime - time;
 687                 }
 688                 self.damageforcescale = 2;
 689                 self.death_time = 0;
 690                 self.dead_frame = 0;
 691                 self.alpha = 0;
 692                 self.scale = 0;
 693                 self.fade_time = 0;
 694                 self.pain_frame = 0;
 695                 self.pain_finished = 0;
 696                 self.strength_finished = 0;
 697                 self.invincible_finished = 0;
 698                 self.pushltime = 0;
 699                 //self.speed_finished = 0;
 700                 //self.slowmo_finished = 0;
 701                 // players have no think function
 702                 self.think = SUB_Null;
 703                 self.nextthink = 0;
 704                 self.hook_time = 0;
 705
 706                 self.runes = 0;
 707
 708                 self.deadflag = DEAD_NO;
 709
 710                 self.angles = spot.angles;
 711
 712                 self.angles_z = 0; // never spawn tilted even if the spot says to
 713                 self.fixangle = TRUE; // turn this way immediately
 714                 self.velocity = '0 0 0';
 715                 self.avelocity = '0 0 0';
 716                 self.punchangle = '0 0 0';
 717                 self.punchvector = '0 0 0';
 718                 self.oldvelocity = self.velocity;
 719
 720                 msg_entity = self;
 721                 WRITESPECTATABLE_MSG_ONE({
 722                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 723                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 724                 });
 725
 726                 self.customizeentityforclient = Client_customizeentityforclient;
 727
 728                 self.model = "";
 729                 FixPlayermodel();
 730
 731                 self.crouch = FALSE;
 732                 self.view_ofs = PL_VIEW_OFS;
 733                 setsize (self, PL_MIN, PL_MAX);
 734                 self.spawnorigin = spot.origin;
 735                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 736                 // don't reset back to last position, even if new position is stuck in solid
 737                 self.oldorigin = self.origin;
 738
 739                 if(g_arena)
 740                 {
 741                         Spawnqueue_Remove(self);
 742                         Spawnqueue_Mark(self);
 743                 }
 744
 745                 self.event_damage = PlayerDamage;
 746
 747                 self.bot_attack = TRUE;
 748
 749                 self.statdraintime = time + 5;
 750                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 751
 752                 if(self.killcount == -666) {
 753                         PlayerScore_Clear(self);
 754                         self.killcount = 0;
 755                         self.frags = 0;
 756                 }
 757
 758                 self.cnt = WEP_LASER;
 759                 self.nixnex_lastchange_id = -1;
 760
 761                 CL_SpawnWeaponentity();
 762                 self.alpha = default_player_alpha;
 763                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 764                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 765
 766                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 767                 self.lms_traveled_distance = 0;
 768                 self.speedrunning = FALSE;
 769
 770                 race_PostSpawn(spot);
 771
 772                 if(cvar("spawn_debug"))
 773                 {
 774                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 775                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 776                 }
 777
 778                 //stuffcmd(self, "chase_active 0");
 779                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 780
 781                 if (cvar("g_spawnsound"))
 782                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 783
 784                 if(g_assault) {
 785                         if(self.team == assault_attacker_team)
 786                                 centerprint(self, "You are attacking!\n");
 787                         else
 788                                 centerprint(self, "You are defending!\n");
 789                 }
 790
 791         } else if(self.classname == "observer") {
 792                 PutObserverInServer ();
 793         }
 794
 795         //if(g_ctf)
 796         //      ctf_playerchanged();
 797 }
 798
 799 /*
 800 =============
 801 SendCSQCInfo
 802
 803 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 804 =============
 805 */
 806 void SendCSQCInfo(void)
 807 {
 808         float i;
 809         if(clienttype(self) != CLIENTTYPE_REAL)
 810                 return;
 811         msg_entity = self;
 812         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 813         WriteByte(MSG_ONE, TE_CSQC_INIT);
 814         WriteShort(MSG_ONE, CSQC_REVISION);
 815         WriteByte(MSG_ONE, maxclients);
 816         for(i = 1; i <= 24; ++i)
 817                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 818         WriteCoord(MSG_ONE, hook_shotorigin_x);
 819         WriteCoord(MSG_ONE, hook_shotorigin_y);
 820         WriteCoord(MSG_ONE, hook_shotorigin_z);
 821 }
 822
 823 /*
 824 =============
 825 SetNewParms
 826 =============
 827 */
 828 void SetNewParms (void)
 829 {
 830         // initialize parms for a new player
 831         parm1 = -(86400 * 366);
 832 }
 833
 834 /*
 835 =============
 836 SetChangeParms
 837 =============
 838 */
 839 void SetChangeParms (void)
 840 {
 841         // save parms for level change
 842         parm1 = self.parm_idlesince - time;
 843 }
 844
 845 /*
 846 =============
 847 DecodeLevelParms
 848 =============
 849 */
 850 void DecodeLevelParms (void)
 851 {
 852         // load parms
 853         self.parm_idlesince = parm1;
 854         if(self.parm_idlesince == -(86400 * 366))
 855                 self.parm_idlesince = time;
 856 }
 857
 858 /*
 859 =============
 860 ClientKill
 861
 862 Called when a client types 'kill' in the console
 863 =============
 864 */
 865
 866 void ClientKill_Now_TeamChange()
 867 {
 868         if(self.killindicator_teamchange == -1)
 869         {
 870                 self.team = -1;
 871                 JoinBestTeam( self, FALSE, FALSE );
 872         }
 873         else
 874         {
 875                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 876         }
 877 }
 878
 879 void ClientKill_Now()
 880 {
 881         if(self.killindicator_teamchange)
 882                 ClientKill_Now_TeamChange();
 883
 884         // in any case:
 885         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 886
 887         if(self.killindicator)
 888         {
 889                 dprint("Cleaned up after a leaked kill indicator.\n");
 890                 remove(self.killindicator);
 891                 self.killindicator = world;
 892         }
 893 }
 894 void KillIndicator_Think()
 895 {
 896         if (!self.owner.modelindex)
 897         {
 898                 self.owner.killindicator = world;
 899                 remove(self);
 900                 return;
 901         }
 902
 903         if(self.cnt <= 0)
 904         {
 905                 self = self.owner;
 906                 ClientKill_Now(); // no oldself needed
 907                 return;
 908         }
 909         else
 910         {
 911                 if(self.cnt <= 10)
 912                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 913                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 914                 {
 915                         if(self.cnt <= 10)
 916                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 917                         if(self.owner.killindicator_teamchange)
 918                         {
 919                                 if(self.owner.killindicator_teamchange == -1)
 920                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 921                                 else
 922                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 923                         }
 924                         else
 925                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 926                 }
 927                 self.nextthink = time + 1;
 928                 self.cnt -= 1;
 929         }
 930 }
 931
 932 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 933 {
 934         float killtime;
 935         entity e;
 936         killtime = cvar("g_balance_kill_delay");
 937
 938         self.killindicator_teamchange = targetteam;
 939
 940         if(!self.killindicator)
 941         {
 942                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 943                 {
 944                         ClientKill_Now();
 945                 }
 946                 else
 947                 {
 948                         self.killindicator = spawn();
 949                         self.killindicator.owner = self;
 950                         self.killindicator.scale = 0.5;
 951                         setattachment(self.killindicator, self, "");
 952                         setorigin(self.killindicator, '0 0 52');
 953                         self.killindicator.think = KillIndicator_Think;
 954                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 955                         self.killindicator.cnt = ceil(killtime);
 956                         self.killindicator.count = bound(0, ceil(killtime), 10);
 957                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 958
 959                         for(e = world; (e = find(e, classname, "body")) != world; )
 960                         {
 961                                 if(e.enemy != self)
 962                                         continue;
 963                                 e.killindicator = spawn();
 964                                 e.killindicator.owner = e;
 965                                 e.killindicator.scale = 0.5;
 966                                 setattachment(e.killindicator, e, "");
 967                                 setorigin(e.killindicator, '0 0 52');
 968                                 e.killindicator.think = KillIndicator_Think;
 969                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 970                                 e.killindicator.cnt = ceil(killtime);
 971                         }
 972                         self.lip = 0;
 973                 }
 974         }
 975         if(self.killindicator)
 976         {
 977                 if(targetteam)
 978                         self.killindicator.colormod = TeamColor(targetteam);
 979                 else
 980                         self.killindicator.colormod = '0 0 0';
 981         }
 982 }
 983
 984 void ClientKill (void)
 985 {
 986         ClientKill_TeamChange(0);
 987 }
 988
 989 void DoTeamChange(float destteam)
 990 {
 991         float t, c0;
 992         if(!cvar("teamplay"))
 993         {
 994                 if(destteam >= 0)
 995                         SetPlayerColors(self, destteam);
 996                 return;
 997         }
 998         if(self.classname == "player")
 999         if(destteam == -1)
1000         {
1001                 CheckAllowedTeams(self);
1002                 t = FindSmallestTeam(self, TRUE);
1003                 switch(self.team)
1004                 {
1005                         case COLOR_TEAM1: c0 = c1; break;
1006                         case COLOR_TEAM2: c0 = c2; break;
1007                         case COLOR_TEAM3: c0 = c3; break;
1008                         case COLOR_TEAM4: c0 = c4; break;
1009                         default:          c0 = 999;
1010                 }
1011                 switch(t)
1012                 {
1013                         case 1:
1014                                 if(c0 > c1)
1015                                         destteam = COLOR_TEAM1;
1016                                 break;
1017                         case 2:
1018                                 if(c0 > c2)
1019                                         destteam = COLOR_TEAM2;
1020                                 break;
1021                         case 3:
1022                                 if(c0 > c3)
1023                                         destteam = COLOR_TEAM3;
1024                                 break;
1025                         case 4:
1026                                 if(c0 > c4)
1027                                         destteam = COLOR_TEAM4;
1028                                 break;
1029                 }
1030                 if(destteam == -1)
1031                         return;
1032         }
1033         if(destteam == self.team && !self.killindicator)
1034                 return;
1035         ClientKill_TeamChange(destteam);
1036 }
1037
1038 void FixClientCvars(entity e)
1039 {
1040         // send prediction settings to the client
1041         stuffcmd(e, "\nin_bindmap 0 0\n");
1042         /*
1043          * we no longer need to stuff this. Remove this comment block if you feel
1044          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1045         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1046         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1047         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1048         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1049         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1050         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1051         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1052         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1053         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1054         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1055         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1056         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1057         stuffcmd(e, "cl_movement_edgefriction 1\n");
1058          */
1059 }
1060
1061 .float fog_set;
1062 void SendFog()
1063 {
1064         if(clienttype(self) == CLIENTTYPE_REAL)
1065         if(world.fog) // NOT string_null!
1066         {
1067                 if(!self.fog_set)
1068                 {
1069                         if(sv_foginterval)
1070                         {
1071                                 msg_entity = self;
1072                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1073                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1074                                 WriteCoord(MSG_ONE, sv_foginterval);
1075                                 WriteString(MSG_ONE, world.fog);
1076                         }
1077                         else
1078                                 // set it once
1079                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1080
1081                         self.fog_set = 1;
1082                 }
1083         }
1084 }
1085
1086 /*
1087 =============
1088 ClientConnect
1089
1090 Called when a client connects to the server
1091 =============
1092 */
1093 //void ctf_clientconnect();
1094 string ColoredTeamName(float t);
1095 void DecodeLevelParms (void);
1096 //void dom_player_join_team(entity pl);
1097 void ClientConnect (void)
1098 {
1099         local string s;
1100
1101         if(self.flags & FL_CLIENT)
1102         {
1103                 print("Warning: ClientConnect, but already connected!\n");
1104                 return;
1105         }
1106
1107         if(Ban_MaybeEnforceBan(self))
1108                 return;
1109
1110         DecodeLevelParms();
1111
1112         self.classname = "player_joining";
1113
1114         self.flags = self.flags | FL_CLIENT;
1115         self.version_nagtime = time + 10 + random() * 10;
1116
1117         if(player_count<0)
1118         {
1119                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1120                 player_count = 0;
1121         }
1122
1123         PlayerScore_Attach(self);
1124
1125         bot_clientconnect();
1126
1127         race_PreSpawnObserver();
1128
1129         //if(g_domination)
1130         //      dom_player_join_team(self);
1131
1132         //JoinBestTeam(self, FALSE, FALSE);
1133         //
1134         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1135                 self.classname = "observer";
1136         } else {
1137                 self.classname = "player";
1138                 campaign_bots_may_start = 1;
1139         }
1140
1141         self.playerid = (playerid_last = playerid_last + 1);
1142         if(cvar("sv_eventlog"))
1143         {
1144                 if(clienttype(self) == CLIENTTYPE_REAL)
1145                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1146                 else
1147                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1148                 s = strcat(":team:", ftos(self.playerid), ":");
1149                 s = strcat(s, ftos(self.team));
1150                 GameLogEcho(s);
1151         }
1152         self.netname_previous = strzone(self.netname);
1153
1154         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1155
1156         bprint ("^4",self.netname);
1157         bprint ("^4 connected");
1158
1159         if(g_domination || g_ctf)
1160         {
1161                 bprint(" and joined the ");
1162                 bprint(ColoredTeamName(self.team));
1163         }
1164
1165         bprint("\n");
1166
1167         self.welcomemessage_time = 0;
1168
1169         stuffcmd(self, strcat(clientstuff, "\n"));
1170         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1171         stuffcmd(self, "cl_particles_reloadeffects\n");
1172
1173         FixClientCvars(self);
1174
1175         // spawnfunc_waypoint sprites
1176         WaypointSprite_InitClient(self);
1177
1178         // Wazat's grappling hook
1179         SetGrappleHookBindings();
1180
1181         // get autoswitch state from player when he toggles it
1182         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1183
1184         // get version info from player
1185         stuffcmd(self, "cmd clientversion $gameversion\n");
1186
1187         // get other cvars from player
1188         GetCvars(0);
1189
1190         // set cvar for team scoreboard
1191         if (teams_matter)
1192         {
1193                 local float t;
1194                 t = cvar("teamplay");
1195                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1196                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1197         }
1198         else
1199                 stuffcmd(self, "set teamplay 0\n");
1200
1201         // notify about available teams
1202         if(teamplay)
1203         {
1204                 CheckAllowedTeams(self);
1205                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1206                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1207         }
1208         else
1209                 stuffcmd(self, "set _teams_available 0\n");
1210
1211         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1212
1213         if(g_arena)
1214         {
1215                 self.classname = "observer";
1216                 Spawnqueue_Insert(self);
1217         }
1218         /*else if(g_ctf)
1219         {
1220                 ctf_clientconnect();
1221         }*/
1222
1223         if(teams_matter)
1224                 attach_entcs();
1225
1226         bot_relinkplayerlist();
1227
1228         self.spectatortime = time;
1229         if(blockSpectators)
1230         {
1231                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1232         }
1233
1234         self.jointime = time;
1235         self.allowedTimeouts = cvar("sv_timeout_number");
1236
1237         if(clienttype(self) == CLIENTTYPE_REAL)
1238         {
1239                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1240                 SendCSQCInfo();
1241                 msg_entity = self;
1242                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1243                 {
1244                         MapVote_SendData(MSG_ONE);
1245                         MapVote_UpdateData(MSG_ONE);
1246                 }
1247                 ScoreInfo_Write(MSG_ONE);
1248         }
1249
1250         if(inWarmupStage)
1251         {
1252                 msg_entity = self;
1253                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1254                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1255                 WriteByte(MSG_ONE, 1);
1256         }
1257
1258         if(g_lms)
1259         {
1260                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1261                 {
1262                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1263                         self.frags = -666; // FIXME do we still need this?
1264                 }
1265         }
1266
1267         SendFog();
1268 }
1269
1270 /*
1271 =============
1272 ClientDisconnect
1273
1274 Called when a client disconnects from the server
1275 =============
1276 */
1277 .entity chatbubbleentity;
1278 .entity teambubbleentity;
1279 void ReadyCount();
1280 void ClientDisconnect (void)
1281 {
1282         if not(self.flags & FL_CLIENT)
1283         {
1284                 print("Warning: ClientDisconnect without ClientConnect\n");
1285                 return;
1286         }
1287
1288         bot_clientdisconnect();
1289
1290         if(teams_matter)
1291                 detach_entcs();
1292
1293         if(cvar("sv_eventlog"))
1294                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1295         bprint ("^4",self.netname);
1296         bprint ("^4 disconnected\n");
1297
1298         DropAllRunes(self);
1299         kh_Key_DropAll(self, TRUE);
1300
1301         Portal_ClearAll(self);
1302
1303         if(self.flagcarried)
1304                 DropFlag(self.flagcarried, world, world);
1305
1306         // Here, everything has been done that requires this player to be a client.
1307
1308         self.flags (-) FL_CLIENT;
1309
1310         if (self.chatbubbleentity)
1311                 remove (self.chatbubbleentity);
1312
1313         if (self.teambubbleentity)
1314                 remove (self.teambubbleentity);
1315
1316         if (self.killindicator)
1317                 remove (self.killindicator);
1318
1319         WaypointSprite_PlayerGone();
1320
1321         bot_relinkplayerlist();
1322
1323         // remove laserdot
1324         if(self.weaponentity)
1325                 if(self.weaponentity.lasertarget)
1326                         remove(self.weaponentity.lasertarget);
1327
1328         if(g_arena)
1329         {
1330                 Spawnqueue_Unmark(self);
1331                 Spawnqueue_Remove(self);
1332         }
1333
1334         PlayerScore_Detach(self);
1335
1336         if(self.netname_previous)
1337                 strunzone(self.netname_previous);
1338
1339         ClearPlayerSounds();
1340
1341         self.playerid = 0;
1342         ReadyCount();
1343
1344         // free cvars
1345         GetCvars(-1);
1346 }
1347
1348 .float BUTTON_CHAT;
1349 void ChatBubbleThink()
1350 {
1351         self.nextthink = time;
1352         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1353         {
1354                 if(self.owner) // but why can that ever be world?
1355                         self.owner.chatbubbleentity = world;
1356                 remove(self);
1357                 return;
1358         }
1359         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1360         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1361                 self.model = self.mdl;
1362         else
1363                 self.model = "";
1364 };
1365
1366 void UpdateChatBubble()
1367 {
1368         if (!self.modelindex)
1369                 return;
1370         // spawn a chatbubble entity if needed
1371         if (!self.chatbubbleentity)
1372         {
1373                 self.chatbubbleentity = spawn();
1374                 self.chatbubbleentity.owner = self;
1375                 self.chatbubbleentity.exteriormodeltoclient = self;
1376                 self.chatbubbleentity.think = ChatBubbleThink;
1377                 self.chatbubbleentity.nextthink = time;
1378                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1379                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1380                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1381                 self.chatbubbleentity.model = "";
1382                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1383         }
1384 }
1385
1386
1387 void TeamBubbleThink()
1388 {
1389         self.nextthink = time;
1390         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1391         {
1392                 if(self.owner) // but why can that ever be world?
1393                         self.owner.teambubbleentity = world;
1394                 remove(self);
1395                 return;
1396         }
1397 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1398         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1399                 self.model = "";
1400         else
1401                 self.model = self.mdl;
1402
1403 };
1404
1405 float TeamBubble_customizeentityforclient()
1406 {
1407         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1408 }
1409
1410 void UpdateTeamBubble()
1411 {
1412         if (!self.modelindex || !cvar("teamplay"))
1413                 return;
1414         // spawn a teambubble entity if needed
1415         if (!self.teambubbleentity && cvar("teamplay"))
1416         {
1417                 self.teambubbleentity = spawn();
1418                 self.teambubbleentity.owner = self;
1419                 self.teambubbleentity.exteriormodeltoclient = self;
1420                 self.teambubbleentity.think = TeamBubbleThink;
1421                 self.teambubbleentity.nextthink = time;
1422                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1423 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1424                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1425                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1426                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1427                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1428                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1429                 self.teambubbleentity.effects = EF_LOWPRECISION;
1430         }
1431 }
1432
1433 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1434 // added to the model skins
1435 /*void UpdateColorModHack()
1436 {
1437         local float c;
1438         c = self.clientcolors & 15;
1439         // LordHavoc: only bothering to support white, green, red, yellow, blue
1440              if (teamplay == 0) self.colormod = '0 0 0';
1441         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1442         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1443         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1444         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1445         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1446         else self.colormod = '1 1 1';
1447 };*/
1448
1449 void respawn(void)
1450 {
1451         CopyBody(1);
1452         self.effects |= EF_NODRAW; // prevent another CopyBody
1453         PutClientInServer();
1454 }
1455
1456 /**
1457  * When sv_timeout is used this function returs strings like
1458  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1459  * Called by centerprint functions
1460  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1461  */
1462 string getTimeoutText(float addOneSecond) {
1463         if (!cvar("sv_timeout") || !timeoutStatus)
1464                 return "";
1465
1466         local string retStr;
1467         if (timeoutStatus == 1) {
1468                 if (addOneSecond == 1) {
1469                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1470                 }
1471                 else {
1472                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1473                 }
1474                 return retStr;
1475         }
1476         else if (timeoutStatus == 2) {
1477                 if (addOneSecond) {
1478                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1479                         //don't show messages like "Timeout ends in 0 seconds"...
1480                         if ((remainingTimeoutTime + 1) > 0)
1481                                 return retStr;
1482                         else
1483                                 return "";
1484                 }
1485                 else {
1486                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1487                         //don't show messages like "Timeout ends in 0 seconds"...
1488                         if (remainingTimeoutTime > 0)
1489                                 return retStr;
1490                         else
1491                                 return "";
1492                 }
1493         }
1494         else return "";
1495 }
1496
1497 void player_powerups (void)
1498 {
1499         if (g_minstagib)
1500         {
1501                 if (self.items & IT_STRENGTH)
1502                 {
1503                         if (time > self.strength_finished)
1504                         {
1505                                 if (g_minstagib_invis_alpha > 0)
1506                                 {
1507                                         self.alpha = default_player_alpha;
1508                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1509                                         self.effects = self.effects | EF_FULLBRIGHT;
1510                                 }
1511                                 else
1512                                 {
1513                                         self.effects -= self.effects & EF_NODRAW;
1514                                 }
1515                                 self.items = self.items - (self.items & IT_STRENGTH);
1516                                 sprint(self, "^3Invisibility has worn off\n");
1517                         }
1518                 }
1519                 else
1520                 {
1521                         if (time < self.strength_finished)
1522                         {
1523                                 if (g_minstagib_invis_alpha > 0)
1524                                 {
1525                                         self.alpha = g_minstagib_invis_alpha;
1526                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1527                                         self.effects -= self.effects & EF_FULLBRIGHT;
1528                                 }
1529                                 else
1530                                 {
1531                                         self.effects = self.effects | EF_NODRAW;
1532                                 }
1533                                 self.items = self.items | IT_STRENGTH;
1534                                 sprint(self, "^3You are invisible\n");
1535                         }
1536                 }
1537
1538                 if (self.items & IT_INVINCIBLE)
1539                 {
1540                         if (time > self.invincible_finished)
1541                         {
1542                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1543                                 sprint(self, "^3Speed has worn off\n");
1544                         }
1545                 }
1546                 else
1547                 {
1548                         if (time < self.invincible_finished)
1549                         {
1550                                 self.items = self.items | IT_INVINCIBLE;
1551                                 sprint(self, "^3You are on speed\n");
1552                         }
1553                 }
1554                 return;
1555         }
1556
1557         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1558         if (self.items & IT_STRENGTH)
1559         {
1560                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1561                 if (time > self.strength_finished)
1562                 {
1563                         self.items = self.items - (self.items & IT_STRENGTH);
1564                         sprint(self, "^3Strength has worn off\n");
1565                 }
1566         }
1567         else
1568         {
1569                 if (time < self.strength_finished)
1570                 {
1571                         self.items = self.items | IT_STRENGTH;
1572                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1573                 }
1574         }
1575         if (self.items & IT_INVINCIBLE)
1576         {
1577                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1578                 if (time > self.invincible_finished)
1579                 {
1580                         self.items = self.items - (self.items & IT_INVINCIBLE);
1581                         sprint(self, "^3Shield has worn off\n");
1582                 }
1583         }
1584         else
1585         {
1586                 if (time < self.invincible_finished)
1587                 {
1588                         self.items = self.items | IT_INVINCIBLE;
1589                         sprint(self, "^3Shield surrounds you\n");
1590                 }
1591         }
1592
1593         if (cvar("g_fullbrightplayers"))
1594                 self.effects = self.effects | EF_FULLBRIGHT;
1595
1596         // midair gamemode: damage only while in the air
1597         // if in midair mode, being on ground grants temporary invulnerability
1598         // (this is so that multishot weapon don't clear the ground flag on the
1599         // first damage in the frame, leaving the player vulnerable to the
1600         // remaining hits in the same frame)
1601         if (self.flags & FL_ONGROUND)
1602         if (g_midair)
1603                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1604
1605         if (time >= game_starttime)
1606         if (time < self.spawnshieldtime)
1607                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1608 }
1609
1610 float CalcRegen(float current, float stable, float regenfactor)
1611 {
1612         if(current > stable)
1613                 return current;
1614         else if(current > stable - 0.25) // when close enough, "snap"
1615                 return stable;
1616         else
1617                 return min(stable, current + (stable - current) * regenfactor * frametime);
1618 }
1619
1620 void player_regen (void)
1621 {
1622         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1623         maxh = cvar("g_balance_health_stable");
1624         maxa = cvar("g_balance_armor_stable");
1625         limith = cvar("g_balance_health_limit");
1626         limita = cvar("g_balance_armor_limit");
1627
1628         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1629                 return;
1630
1631         max_mod = regen_mod = rot_mod = limit_mod = 1;
1632
1633         if (self.runes & RUNE_REGEN)
1634         {
1635                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1636                 {
1637                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1638                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1639                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1640                 }
1641                 else
1642                 {
1643                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1644                         max_mod = cvar("g_balance_rune_regen_hpmod");
1645                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1646                 }
1647         }
1648         else if (self.runes & CURSE_VENOM)
1649         {
1650                 max_mod = cvar("g_balance_curse_venom_hpmod");
1651                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1652                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1653                 else
1654                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1655                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1656                 //if (!self.runes & RUNE_REGEN)
1657                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1658         }
1659         maxh = maxh * max_mod;
1660         //maxa = maxa * max_mod;
1661         limith = limith * limit_mod;
1662         limita = limita * limit_mod;
1663
1664         if (self.armorvalue > maxa)
1665         {
1666                 if (time > self.pauserotarmor_finished)
1667                 {
1668                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1669                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1670                 }
1671         }
1672         else if (self.armorvalue < maxa)
1673         {
1674                 if (time > self.pauseregen_finished)
1675                 {
1676                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1677                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1678                 }
1679         }
1680         if (self.health > maxh)
1681         {
1682                 if (time > self.pauserothealth_finished)
1683                 {
1684                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1685                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1686                 }
1687         }
1688         else if (self.health < maxh)
1689         {
1690                 if (time > self.pauseregen_finished)
1691                 {
1692                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1693                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1694                 }
1695         }
1696
1697         if (self.health > limith)
1698                 self.health = limith;
1699         if (self.armorvalue > limita)
1700                 self.armorvalue = limita;
1701
1702         // if player rotted to death...  die!
1703         if(self.health < 1)
1704                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1705 }
1706
1707 .float zoomstate;
1708 float zoomstate_set;
1709 void SetZoomState(float z)
1710 {
1711         if(z != self.zoomstate)
1712         {
1713                 msg_entity = self;
1714                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1715                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1716                 WriteByte(MSG_ONE, z);
1717                 self.zoomstate = z;
1718         }
1719         zoomstate_set = 1;
1720 }
1721
1722 /*
1723 ======================
1724 spectate mode routines
1725 ======================
1726 */
1727 void SpectateCopy(entity spectatee) {
1728         self.armortype = spectatee.armortype;
1729         self.armorvalue = spectatee.armorvalue;
1730         self.currentammo = spectatee.currentammo;
1731         self.effects = spectatee.effects;
1732         self.health = spectatee.health;
1733         self.impulse = 0;
1734         self.items = spectatee.items;
1735         self.weapons = spectatee.weapons;
1736         self.switchweapon = spectatee.switchweapon;
1737         self.weapon = spectatee.weapon;
1738         self.punchangle = spectatee.punchangle;
1739         self.view_ofs = spectatee.view_ofs;
1740         self.v_angle = spectatee.v_angle;
1741         self.velocity = spectatee.velocity;
1742         self.dmg_take = spectatee.dmg_take;
1743         self.dmg_save = spectatee.dmg_save;
1744         self.dmg_inflictor = spectatee.dmg_inflictor;
1745         self.angles = spectatee.v_angle;
1746         self.fixangle = TRUE;
1747         setorigin(self, spectatee.origin);
1748         setsize(self, spectatee.mins, spectatee.maxs);
1749         SetZoomState(spectatee.zoomstate);
1750 }
1751
1752 float SpectateUpdate() {
1753         if(!self.enemy)
1754                 return 0;
1755
1756         if (self == self.enemy)
1757                 return 0;
1758
1759         if(self.enemy.flags & FL_NOTARGET)
1760                 return 0;
1761
1762         SpectateCopy(self.enemy);
1763
1764         return 1;
1765 }
1766
1767 float SpectateNext() {
1768         other = find(self.enemy, classname, "player");
1769         if (!other) {
1770                 other = find(other, classname, "player");
1771         }
1772         if (other) {
1773                 self.enemy = other;
1774         }
1775         if(self.enemy.classname == "player") {
1776                 msg_entity = self;
1777                 WriteByte(MSG_ONE, SVC_SETVIEW);
1778                 WriteEntity(MSG_ONE, self.enemy);
1779                 self.wantswelcomemessage = 1;
1780                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1781                 if(!SpectateUpdate())
1782                         PutObserverInServer();
1783                 return 1;
1784         } else {
1785                 return 0;
1786         }
1787 }
1788
1789 /*
1790 =============
1791 ShowRespawnCountdown()
1792
1793 Update a respawn countdown display.
1794 =============
1795 */
1796 void ShowRespawnCountdown()
1797 {
1798         float number;
1799         if(self.deadflag == DEAD_NO) // just respawned?
1800                 return;
1801         else
1802         {
1803                 number = ceil(self.death_time - time);
1804                 if(number <= 0)
1805                         return;
1806                 if(number <= self.respawn_countdown)
1807                 {
1808                         self.respawn_countdown = number - 1;
1809                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1810                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1811                 }
1812         }
1813 }
1814
1815 void LeaveSpectatorMode()
1816 {
1817         if(isJoinAllowed()) {
1818                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1819                         self.classname = "player";
1820                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1821                                 JoinBestTeam(self, FALSE, TRUE);
1822                         if(cvar("g_campaign"))
1823                                 campaign_bots_may_start = 1;
1824                         PutClientInServer();
1825                         if(!(self.flags & FL_NOTARGET))
1826                                 bprint ("^4", self.netname, "^4 is playing now\n");
1827                         centerprint(self,"");
1828                         return;
1829                 } else {
1830                         stuffcmd(self,"menu_showteamselect\n");
1831                         return;
1832                 }
1833         }
1834         else {
1835                 //player may not join because of g_maxplayers is set
1836                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1837         }
1838 }
1839
1840 /**
1841  * Determines whether the player is allowed to join. This depends on cvar
1842  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1843  * it checks whether the number of currently playing players exceeds g_maxplayers.
1844  * @return bool TRUE if the player is allowed to join, false otherwise
1845  */
1846 float isJoinAllowed() {
1847         if (!cvar("g_maxplayers"))
1848                 return TRUE;
1849
1850         local entity e;
1851         local float currentlyPlaying;
1852         FOR_EACH_REALPLAYER(e) {
1853                 if(e.classname == "player")
1854                         currentlyPlaying += 1;
1855         }
1856         if(currentlyPlaying < cvar("g_maxplayers"))
1857                 return TRUE;
1858
1859         return FALSE;
1860 }
1861
1862 /**
1863  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1864  * g_maxplayers_spectator_blocktime seconds
1865  */
1866 void checkSpectatorBlock() {
1867         if(self.classname == "spectator" || self.classname == "observer") {
1868                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1869                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1870                         dropclient(self);
1871                 }
1872         }
1873 }
1874
1875 float vercmp_recursive(string v1, string v2)
1876 {
1877         float dot1, dot2;
1878         string s1, s2;
1879         float r;
1880
1881         dot1 = strstrofs(v1, ".", 0);
1882         dot2 = strstrofs(v2, ".", 0);
1883         if(dot1 == -1)
1884                 s1 = v1;
1885         else
1886                 s1 = substring(v1, 0, dot1);
1887         if(dot2 == -1)
1888                 s2 = v2;
1889         else
1890                 s2 = substring(v2, 0, dot2);
1891
1892         r = stof(s1) - stof(s2);
1893         if(r != 0)
1894                 return r;
1895
1896         r = strcasecmp(s1, s2);
1897         if(r != 0)
1898                 return r;
1899
1900         if(dot1 == -1)
1901                 if(dot2 == -1)
1902                         return 0;
1903                 else
1904                         return -1;
1905         else
1906                 if(dot2 == -1)
1907                         return 1;
1908                 else
1909                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1910 }
1911
1912 float vercmp(string v1, string v2)
1913 {
1914         if(strcasecmp(v1, v2) == 0) // early out check
1915                 return 0;
1916         return vercmp_recursive(v1, v2);
1917 }
1918
1919 void ObserverThink()
1920 {
1921         if (self.flags & FL_JUMPRELEASED) {
1922                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1923                         self.welcomemessage_time = 0;
1924                         self.flags = self.flags - FL_JUMPRELEASED;
1925                         LeaveSpectatorMode();
1926                         return;
1927                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1928                         self.welcomemessage_time = 0;
1929                         self.flags = self.flags - FL_JUMPRELEASED;
1930                         if(SpectateNext() == 1) {
1931                                 self.classname = "spectator";
1932                         }
1933                 }
1934         } else {
1935                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1936                         self.flags = self.flags | FL_JUMPRELEASED;
1937                 }
1938         }
1939         /*
1940         if(self.BUTTON_ZOOM)
1941                 self.wantswelcomemessage = 0;
1942         */
1943         if(self.wantswelcomemessage)
1944                 PrintWelcomeMessage(self);
1945 }
1946
1947 void SpectatorThink()
1948 {
1949         if (self.flags & FL_JUMPRELEASED) {
1950                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1951                         self.welcomemessage_time = 0;
1952                         self.flags = self.flags - FL_JUMPRELEASED;
1953                         LeaveSpectatorMode();
1954                         return;
1955                 } else if(self.BUTTON_ATCK) {
1956                         self.welcomemessage_time = 0;
1957                         self.flags = self.flags - FL_JUMPRELEASED;
1958                         if(SpectateNext() == 1) {
1959                                 self.classname = "spectator";
1960                         } else {
1961                                 self.classname = "observer";
1962                                 PutClientInServer();
1963                         }
1964                 } else if (self.BUTTON_ATCK2) {
1965                         self.welcomemessage_time = 0;
1966                         self.flags = self.flags - FL_JUMPRELEASED;
1967                         self.classname = "observer";
1968                         PutClientInServer();
1969                 } else {
1970                         if(!SpectateUpdate())
1971                                 PutObserverInServer();
1972                 }
1973         } else {
1974                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1975                         self.flags = self.flags | FL_JUMPRELEASED;
1976                 }
1977         }
1978         /*
1979         if(self.BUTTON_ZOOM)
1980                 self.wantswelcomemessage = 0;
1981         */
1982         if(self.wantswelcomemessage)
1983                 PrintWelcomeMessage(self);
1984         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1985 }
1986
1987 /*
1988 =============
1989 PlayerPreThink
1990
1991 Called every frame for each client before the physics are run
1992 =============
1993 */
1994 void() ctf_setstatus;
1995 .float spectatee_status;
1996 void PlayerPreThink (void)
1997 {
1998         self.stat_sys_ticrate = cvar("sys_ticrate");
1999         self.stat_game_starttime = game_starttime;
2000
2001         if(blockSpectators)
2002                 checkSpectatorBlock();
2003
2004         zoomstate_set = 0;
2005
2006         if(self.netname_previous != self.netname)
2007         {
2008                 if(cvar("sv_eventlog"))
2009                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2010                 if(self.netname_previous)
2011                         strunzone(self.netname_previous);
2012                 self.netname_previous = strzone(self.netname);
2013         }
2014
2015         // version nagging
2016         if(self.version_nagtime)
2017                 if(self.cvar_g_nexuizversion)
2018                         if(time > self.version_nagtime)
2019                         {
2020                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2021                                 {
2022                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2023                                         {
2024                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2025                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2026                                         }
2027                                         else
2028                                         {
2029                                                 float r;
2030                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2031                                                 if(r < 0)
2032                                                 {
2033                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2034                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2035                                                 }
2036                                                 else if(r > 0)
2037                                                 {
2038                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2039                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2040                                                 }
2041                                         }
2042                                 }
2043                                 self.version_nagtime = 0;
2044                         }
2045
2046         // GOD MODE info
2047         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2048         {
2049                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2050                 self.max_armorvalue = 0;
2051         }
2052
2053         if(frametime)
2054         {
2055                 SendFog();
2056                 antilag_record(self);
2057         }
2058
2059         if(self.classname == "player") {
2060 //              if(self.netname == "Wazat")
2061 //                      bprint(self.classname, "\n");
2062
2063                 CheckRules_Player();
2064
2065                 if(self.BUTTON_INFO)
2066                         PrintWelcomeMessage(self);
2067
2068                 if(g_lms || !cvar("sv_spectate"))
2069                 if((time - self.jointime) <= cvar("welcome_message_time"))
2070                         PrintWelcomeMessage(self);
2071
2072                 if (intermission_running)
2073                 {
2074                         IntermissionThink ();   // otherwise a button could be missed between
2075                         return;                                 // the think tics
2076                 }
2077
2078                 if(self.teleport_time)
2079                 if(time > self.teleport_time)
2080                 {
2081                         self.teleport_time = 0;
2082                         self.effects = self.effects - (self.effects & EF_NODRAW);
2083                         if(self.weaponentity)
2084                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2085                 }
2086
2087                 Nixnex_GiveCurrentWeapon();
2088
2089                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2090                         UpdateSelectedPlayer();
2091
2092                 //don't allow the player to turn around while game is paused!
2093                 if(timeoutStatus == 2) {
2094                         self.v_angle = self.lastV_angle;
2095                         self.angles = self.lastV_angle;
2096                         self.fixangle = TRUE;
2097                 }
2098
2099                 if (self.deadflag != DEAD_NO)
2100                 {
2101                         float button_pressed, force_respawn;
2102                         player_anim();
2103                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2104                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2105                         if (self.deadflag == DEAD_DYING)
2106                         {
2107                                 if(force_respawn)
2108                                         self.deadflag = DEAD_RESPAWNING;
2109                                 else if(!button_pressed)
2110                                         self.deadflag = DEAD_DEAD;
2111                         }
2112                         else if (self.deadflag == DEAD_DEAD)
2113                         {
2114                                 if(button_pressed)
2115                                         self.deadflag = DEAD_RESPAWNABLE;
2116                         }
2117                         else if (self.deadflag == DEAD_RESPAWNABLE)
2118                         {
2119                                 if(!button_pressed)
2120                                         self.deadflag = DEAD_RESPAWNING;
2121                         }
2122                         else if (self.deadflag == DEAD_RESPAWNING)
2123                         {
2124                                 if(time > self.death_time)
2125                                 {
2126                                         self.death_time = time + 1; // only retry once a second
2127                                         respawn();
2128                                 }
2129                         }
2130                         ShowRespawnCountdown();
2131                         return;
2132                 }
2133
2134                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2135                 {
2136                         vector dist;
2137
2138                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2139                         dist = self.oldorigin - self.origin;
2140                         dist_z = 0;
2141                         self.lms_traveled_distance += fabs(vlen(dist));
2142
2143                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2144                         {
2145                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2146                                 self.lms_traveled_distance = 0;
2147                         }
2148
2149                         if(time > self.lms_nextcheck)
2150                         {
2151                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2152                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2153                                 {
2154                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2155                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2156                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2157                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2158                                 }
2159                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2160                                 self.lms_traveled_distance = 0;
2161                         }
2162                 }
2163
2164                 if (self.BUTTON_CROUCH && !self.hook.state)
2165                 {
2166                         if (!self.crouch)
2167                         {
2168                                 self.crouch = TRUE;
2169                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2170                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2171                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2172                         }
2173                 }
2174                 else
2175                 {
2176                         if (self.crouch)
2177                         {
2178                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2179                                 if (!trace_startsolid)
2180                                 {
2181                                         self.crouch = FALSE;
2182                                         self.view_ofs = PL_VIEW_OFS;
2183                                         setsize (self, PL_MIN, PL_MAX);
2184                                 }
2185                         }
2186                 }
2187
2188                 FixPlayermodel();
2189
2190                 GrapplingHookFrame();
2191
2192                 W_WeaponFrame();
2193
2194                 player_powerups();
2195                 player_regen();
2196                 player_anim();
2197
2198                 if (g_minstagib)
2199                         minstagib_ammocheck();
2200
2201                 ctf_setstatus();
2202                 kh_setstatus();
2203
2204                 //self.angles_y=self.v_angle_y + 90;   // temp
2205
2206                 //if (TetrisPreFrame()) return;
2207         } else if(gameover) {
2208                 if (intermission_running)
2209                         IntermissionThink ();   // otherwise a button could be missed between
2210                 return;
2211         } else if(self.classname == "observer") {
2212                 ObserverThink();
2213         } else if(self.classname == "spectator") {
2214                 SpectatorThink();
2215         }
2216
2217         if(!zoomstate_set)
2218                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2219
2220         float oldspectatee_status;
2221         oldspectatee_status = self.spectatee_status;
2222         if(self.classname == "spectator")
2223                 self.spectatee_status = num_for_edict(self.enemy);
2224         else if(self.classname == "observer")
2225                 self.spectatee_status = num_for_edict(self);
2226         else
2227                 self.spectatee_status = 0;
2228         if(self.spectatee_status != oldspectatee_status)
2229         {
2230                 msg_entity = self;
2231                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2232                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2233                 WriteByte(MSG_ONE, self.spectatee_status);
2234                 if(g_race)
2235                         race_InitSpectator();
2236         }
2237
2238         if(self.teamkill_soundtime)
2239         if(time > self.teamkill_soundtime)
2240         {
2241                 self.teamkill_soundtime = 0;
2242
2243                 entity oldpusher, oldself;
2244
2245                 oldself = self; self = self.teamkill_soundsource;
2246                 oldpusher = self.pusher; self.pusher = oldself;
2247
2248                 VoiceMessage("teamshoot_auto");
2249
2250                 self.pusher = oldpusher;
2251                 self = oldself;
2252         }
2253 }
2254
2255
2256 /*
2257 =============
2258 PlayerPostThink
2259
2260 Called every frame for each client after the physics are run
2261 =============
2262 */
2263 .float idlekick_lasttimeleft;
2264 .float race_penalty;
2265 .float race_penalty_nagged;
2266 .float race_penalty_nagtime;
2267 void PlayerPostThink (void)
2268 {
2269         // Savage: Check for nameless players
2270         if (strlen(self.netname) < 1) {
2271                 self.netname = "Player";
2272                 stuffcmd(self, "seta _cl_name Player\n");
2273         }
2274
2275         if(sv_maxidle)
2276         {
2277                 float timeleft;
2278                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2279                 if(timeleft <= 0)
2280                 {
2281                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2282                         announce(self, "announcer/robotic/terminated.ogg");
2283                         dropclient(self);
2284                         return;
2285                 }
2286                 else if(timeleft <= 10)
2287                 {
2288                         if(timeleft != self.idlekick_lasttimeleft)
2289                         {
2290                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2291                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2292                         }
2293                 }
2294                 else
2295                 {
2296                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2297                 }
2298                 self.idlekick_lasttimeleft = timeleft;
2299         }
2300
2301         if(self.classname == "player") {
2302                 CheckRules_Player();
2303                 UpdateChatBubble();
2304                 UpdateTeamBubble();
2305                 if (self.impulse)
2306                         ImpulseCommands();
2307                 if (intermission_running)
2308                         return;         // intermission or finale
2309
2310                 //PrintWelcomeMessage(self);
2311                 //if (TetrisPostFrame()) return;
2312
2313                 // restart countdown
2314                         if(time < game_starttime) {
2315                                 if (!cvar("sv_ready_restart_after_countdown"))
2316                                 {
2317                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2318                                         {
2319                                                 if(time < game_starttime - 2)
2320                                                 {
2321                                                         if(!self.race_penalty_nagged)
2322                                                         {
2323                                                                 // TODO better notification for this!
2324                                                                 self.race_penalty_nagtime = 0;
2325                                                                 self.race_penalty_nagged = 1;
2326                                                         }
2327                                                 }
2328                                                 else if(!self.race_penalty)
2329                                                 {
2330                                                         self.race_penalty_nagtime = 0;
2331                                                         self.race_penalty = time + 5;
2332                                                 }
2333                                         }
2334                                         if(time > self.race_penalty_nagtime)
2335                                         {
2336                                                 if(self.race_penalty > time)
2337                                                 {
2338                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2339                                                 }
2340                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2341                                                 {
2342                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2343                                                 }
2344                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2345                                         }
2346                                         self.movetype = MOVETYPE_NONE;
2347                                         self.velocity = '0 0 0';
2348                                         self.avelocity = '0 0 0';
2349                                         self.movement = '0 0 0';
2350                                 }
2351                         }
2352                         else if (time < self.race_penalty)
2353                         {
2354                                 self.movetype = MOVETYPE_NONE;
2355                                 self.velocity = '0 0 0';
2356                                 self.avelocity = '0 0 0';
2357                                 self.movement = '0 0 0';
2358                         }
2359                         else
2360                         {
2361                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2362                                 if (!cvar("sv_ready_restart_after_countdown"))
2363                                 {
2364                                         if(self.movetype == MOVETYPE_NONE)
2365                                         {
2366                                                 self.movetype = MOVETYPE_WALK;
2367                                         }
2368                                         self.race_penalty = 0;
2369                                         self.race_penalty_nagged = 0;
2370                                 }
2371                         }
2372
2373         } else if (self.classname == "observer") {
2374                 //do nothing
2375         } else if (self.classname == "spectator") {
2376                 //do nothing
2377         }
2378
2379         /*
2380         float i;
2381         for(i = 0; i < 1000; ++i)
2382         {
2383                 vector end;
2384                 end = self.origin + '0 0 1024' + 512 * randomvec();
2385                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2386                 if(trace_fraction < 1)
2387                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2388                 {
2389                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2390                         break;
2391                 }
2392         }
2393         */
2394
2395         Arena_Warmup();
2396
2397         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2398 }