data/qcsrc/server/cl_client.qc

   1 float ClientData_Send(entity to, float sf)
   2 {
   3         if(to != self.owner)
   4         {
   5                 error("wtf");
   6                 return FALSE;
   7         }
   8
   9         entity e;
  10
  11         e = to;
  12         if(to.classname == "spectator")
  13                 e = to.enemy;
  14
  15         sf = 0;
  16
  17         if(e.race_completed)
  18                 sf |= 1; // forced scoreboard
  19         if(to.spectatee_status)
  20                 sf |= 2; // spectator ent number follows
  21         if(e.zoomstate)
  22                 sf |= 4; // zoomed
  23         if(e.porto_v_angle_held)
  24                 sf |= 8; // angles held
  25
  26         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  27         WriteByte(MSG_ENTITY, sf);
  28
  29         if(sf & 2)
  30                 WriteByte(MSG_ENTITY, to.spectatee_status);
  31
  32         if(sf & 8)
  33         {
  34                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  35                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  36         }
  37
  38         return TRUE;
  39 }
  40
  41 void ClientData_Attach()
  42 {
  43         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  44         self.clientdata.drawonlytoclient = self;
  45         self.clientdata.owner = self;
  46 }
  47
  48 void ClientData_Detach()
  49 {
  50         remove(self.clientdata);
  51         self.clientdata = world;
  52 }
  53
  54 void ClientData_Touch(entity e)
  55 {
  56         e.clientdata.SendFlags = 1;
  57
  58         // make it spectatable
  59         entity e2;
  60         FOR_EACH_REALCLIENT(e2)
  61         {
  62                 if(e2 != e)
  63                         if(e2.classname == "spectator")
  64                                 if(e2.enemy == e)
  65                                         e2.clientdata.SendFlags = 1;
  66         }
  67 }
  68
  69
  70 #define SPAWNPOINT_SCORE frags
  71
  72 .string netname_previous;
  73
  74 void spawnfunc_info_player_survivor (void)
  75 {
  76         spawnfunc_info_player_deathmatch();
  77 }
  78
  79 void spawnfunc_info_player_start (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_deathmatch (void)
  85 {
  86         self.classname = "info_player_deathmatch";
  87         relocate_spawnpoint();
  88 }
  89
  90 void spawnpoint_use()
  91 {
  92         if(teams_matter)
  93         if(have_team_spawns)
  94         {
  95                 self.team = activator.team;
  96                 some_spawn_has_been_used = 1;
  97         }
  98 };
  99
 100 // Returns:
 101 //   -1 if a spawn can't be used
 102 //   otherwise, a weight of the spawnpoint
 103 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 104 {
 105         float shortest, thisdist;
 106         entity player;
 107
 108         // filter out spots for the wrong team
 109         if(teamcheck)
 110         if(spot.team != teamcheck)
 111                 return -1;
 112
 113         if(race_spawns)
 114                 if(spot.target == "")
 115                         return -1;
 116
 117         if(clienttype(self) == CLIENTTYPE_REAL)
 118         {
 119                 if(spot.restriction == 1)
 120                         return -1;
 121         }
 122         else
 123         {
 124                 if(spot.restriction == 2)
 125                         return -1;
 126         }
 127
 128         // filter out spots for assault
 129         if(spot.target != "") {
 130                 local entity ent;
 131                 float good, found;
 132                 ent = find(world, targetname, spot.target);
 133                 while(ent) {
 134                         if(ent.classname == "target_objective")
 135                         {
 136                                 found = 1;
 137                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 138                                         return -1;
 139                                 good = 1;
 140                         }
 141                         else if(ent.classname == "trigger_race_checkpoint")
 142                         {
 143                                 found = 1;
 144                                 if(self.classname == "player") // spectators may spawn everywhere
 145                                 {
 146                                         if(g_race_qualifying)
 147                                         {
 148                                                 // spawn at first
 149                                                 if(ent.race_checkpoint != 0)
 150                                                         return -1;
 151                                                 if(spot.race_place != race_lowest_place_spawn)
 152                                                         return -1;
 153                                         }
 154                                         else
 155                                         {
 156                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 157                                                         return -1;
 158                                                 float pl;
 159                                                 pl = self.race_place;
 160                                                 if(pl > race_highest_place_spawn)
 161                                                         pl = 0;
 162                                                 if(spot.race_place != pl)
 163                                                         return -1;
 164                                         }
 165                                 }
 166                                 good = 1;
 167                         }
 168                         ent = find(ent, targetname, spot.target);
 169                 }
 170
 171                 if(found && !good)
 172                         return -1;
 173         }
 174
 175         player = playerlist;
 176         shortest = vlen(world.maxs - world.mins);
 177         for(player = playerlist; player; player = player.chain)
 178                 if (player != self)
 179                 {
 180                         thisdist = vlen(player.origin - spot.origin);
 181                         if (thisdist < shortest)
 182                                 shortest = thisdist;
 183                 }
 184         return shortest;
 185 }
 186
 187 float spawn_allbad;
 188 float spawn_allgood;
 189 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 190 {
 191         local entity spot, spotlist, spotlistend;
 192         spawn_allgood = TRUE;
 193         spawn_allbad = TRUE;
 194
 195         spotlist = world;
 196         spotlistend = world;
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 201
 202                 if(cvar("spawn_debugview"))
 203                 {
 204                         setmodel(spot, "models/runematch/rune.mdl");
 205                         if(spot.SPAWNPOINT_SCORE < mindist)
 206                         {
 207                                 spot.colormod = '1 0 0';
 208                                 spot.scale = 1;
 209                         }
 210                         else
 211                         {
 212                                 spot.colormod = '0 1 0';
 213                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 214                         }
 215                 }
 216
 217                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 218                 {
 219                         if(spot.SPAWNPOINT_SCORE < mindist)
 220                         {
 221                                 // too short distance
 222                                 spawn_allgood = FALSE;
 223                         }
 224                         else
 225                         {
 226                                 // perfect
 227                                 spawn_allbad = FALSE;
 228
 229                                 if(spotlistend)
 230                                         spotlistend.chain = spot;
 231                                 spotlistend = spot;
 232                                 if(!spotlist)
 233                                         spotlist = spot;
 234
 235                                 /*
 236                                 if(teamcheck)
 237                                 if(spot.team != teamcheck)
 238                                         error("invalid spawn added");
 239
 240                                 print("added ", etos(spot), "\n");
 241                                 */
 242                         }
 243                 }
 244         }
 245         if(spotlistend)
 246                 spotlistend.chain = world;
 247
 248         /*
 249                 entity e;
 250                 if(teamcheck)
 251                         for(e = spotlist; e; e = e.chain)
 252                         {
 253                                 print("seen ", etos(e), "\n");
 254                                 if(e.team != teamcheck)
 255                                         error("invalid spawn found");
 256                         }
 257         */
 258
 259         return spotlist;
 260 }
 261
 262 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 263 {
 264         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 265         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 266         local entity spot;
 267
 268         RandomSelection_Init();
 269         for(spot = firstspot; spot; spot = spot.chain)
 270                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 271
 272         return RandomSelection_chosen_ent;
 273 }
 274
 275 /*
 276 =============
 277 SelectSpawnPoint
 278
 279 Finds a point to respawn
 280 =============
 281 */
 282 entity SelectSpawnPoint (float anypoint)
 283 {
 284         local float teamcheck;
 285         local entity firstspot_new;
 286         local entity spot, firstspot, playerlist;
 287
 288         spot = find (world, classname, "testplayerstart");
 289         if (spot)
 290                 return spot;
 291
 292         teamcheck = 0;
 293
 294         if(!anypoint && have_team_spawns)
 295                 teamcheck = self.team;
 296
 297         // get the list of players
 298         playerlist = findchain(classname, "player");
 299         // get the entire list of spots
 300         firstspot = findchain(classname, "info_player_deathmatch");
 301         // filter out the bad ones
 302         // (note this returns the original list if none survived)
 303         if(anypoint)
 304         {
 305                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 306         }
 307         else
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 310                 if(!firstspot_new)
 311                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 312                 firstspot = firstspot_new;
 313
 314                 // there is 50/50 chance of choosing a random spot or the furthest spot
 315                 // (this means that roughly every other spawn will be furthest, so you
 316                 // usually won't get fragged at spawn twice in a row)
 317                 if (arena_roundbased)
 318                 {
 319                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 320                         if(firstspot_new)
 321                                 firstspot = firstspot_new;
 322                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 323                 }
 324                 else if (random() > cvar("g_spawn_furthest"))
 325                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 326                 else
 327                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 328         }
 329
 330         if(cvar("spawn_debugview"))
 331         {
 332                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 333
 334                 entity e;
 335                 if(teamcheck)
 336                         for(e = firstspot; e; e = e.chain)
 337                                 if(e.team != teamcheck)
 338                                         error("invalid spawn found");
 339         }
 340
 341         if (!spot)
 342         {
 343                 if(cvar("spawn_debug"))
 344                         GotoNextMap();
 345                 else
 346                 {
 347                         if(some_spawn_has_been_used)
 348                                 return world; // team can't spawn any more, because of actions of other team
 349                         else
 350                                 error("Cannot find a spawn point - please fix the map!");
 351                 }
 352         }
 353
 354         return spot;
 355 }
 356
 357 /*
 358 =============
 359 CheckPlayerModel
 360
 361 Checks if the argument string can be a valid playermodel.
 362 Returns a valid one in doubt.
 363 =============
 364 */
 365 string FallbackPlayerModel = "models/player/marine.zym";
 366 string CheckPlayerModel(string plyermodel) {
 367         if(strlen(plyermodel) < 4)
 368                 return FallbackPlayerModel;
 369         if( substring(plyermodel,0,14) != "models/player/")
 370                 return FallbackPlayerModel;
 371         else if(cvar("sv_servermodelsonly"))
 372         {
 373                 if(substring(plyermodel,-4,4) != ".zym")
 374                 if(substring(plyermodel,-4,4) != ".dpm")
 375                 if(substring(plyermodel,-4,4) != ".md3")
 376                 if(substring(plyermodel,-4,4) != ".psk")
 377                         return FallbackPlayerModel;
 378                 // forbid the LOD models
 379                 if(substring(plyermodel, -9,5) == "_lod1")
 380                         return FallbackPlayerModel;
 381                 if(substring(plyermodel, -9,5) == "_lod2")
 382                         return FallbackPlayerModel;
 383                 if(plyermodel != strtolower(plyermodel))
 384                         return FallbackPlayerModel;
 385                 if(!fexists(plyermodel))
 386                         return FallbackPlayerModel;
 387         }
 388         return plyermodel;
 389 }
 390
 391 /*
 392 =============
 393 Client_customizeentityforclient
 394
 395 LOD reduction
 396 =============
 397 */
 398 void Client_uncustomizeentityforclient()
 399 {
 400         if(self.modelindex == 0) // no need to uncustomize then
 401                 return;
 402         self.modelindex = self.modelindex_lod0;
 403         self.skin = self.skinindex;
 404 }
 405
 406 float Client_customizeentityforclient()
 407 {
 408         entity modelsource;
 409
 410         if(self.modelindex == 0)
 411                 return TRUE;
 412
 413         // forcemodel stuff
 414
 415 #ifdef PROFILING
 416         float t0;
 417         t0 = gettime(GETTIME_HIRES); // reference
 418 #endif
 419
 420         modelsource = self;
 421
 422 #ifdef ALLOW_FORCEMODELS
 423         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 424                 if not(self.modelindex_lod0_from_nexuiz)
 425                         modelsource = other;
 426         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 427                 modelsource = other;
 428 #endif
 429
 430         self.skin = modelsource.skinindex;
 431
 432 #if 0
 433         if(modelsource == self)
 434                 self.skin = modelsource.skinindex;
 435         else
 436                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 437 #endif
 438
 439         // self: me
 440         // other: the player viewing me
 441         float distance;
 442         float f;
 443
 444         if(other.cvar_cl_playerdetailreduction <= 0)
 445         {
 446                 if(other.cvar_cl_playerdetailreduction <= -2)
 447                         self.modelindex = modelsource.modelindex_lod2;
 448                 else if(other.cvar_cl_playerdetailreduction <= -1)
 449                         self.modelindex = modelsource.modelindex_lod1;
 450                 else
 451                         self.modelindex = modelsource.modelindex_lod0;
 452         }
 453         else
 454         {
 455                 distance = vlen(self.origin - other.origin);
 456                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 457                 if(f > sv_loddistance2)
 458                         self.modelindex = modelsource.modelindex_lod2;
 459                 else if(f > sv_loddistance1)
 460                         self.modelindex = modelsource.modelindex_lod1;
 461                 else
 462                         self.modelindex = modelsource.modelindex_lod0;
 463         }
 464
 465 #ifdef PROFILING
 466         float t1;
 467         t1 = gettime(GETTIME_HIRES); // reference
 468         client_cefc_accumulator += (t1 - t0);
 469 #endif
 470
 471         return TRUE;
 472 }
 473
 474 void UpdatePlayerSounds();
 475 void setmodel_lod(entity e, string modelname)
 476 {
 477         string s;
 478
 479         if(sv_loddistance1)
 480         {
 481                 // FIXME: this only supports 3-letter extensions
 482                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 483                 if(fexists(s))
 484                 {
 485                         setmodel(e, s); // players have high precision
 486                         self.modelindex_lod1 = self.modelindex;
 487                 }
 488                 else
 489                         self.modelindex_lod1 = -1;
 490
 491                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 492                 if(fexists(s))
 493                 {
 494                         setmodel(e, s); // players have high precision
 495                         self.modelindex_lod2 = self.modelindex;
 496                 }
 497                 else
 498                         self.modelindex_lod2 = -1;
 499
 500                 precache_model(modelname);
 501                 setmodel(e, modelname); // players have high precision
 502                 self.modelindex_lod0 = self.modelindex;
 503
 504                 if(self.modelindex_lod1 < 0)
 505                         self.modelindex_lod1 = self.modelindex;
 506
 507                 if(self.modelindex_lod2 < 0)
 508                         self.modelindex_lod2 = self.modelindex;
 509         }
 510         else
 511         {
 512                 precache_model(modelname);
 513                 setmodel(e, modelname); // players have high precision
 514                 self.modelindex_lod0 = self.modelindex;
 515                         // save it for possible player model forcing
 516         }
 517
 518         s = whichpack(self.model);
 519         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 520
 521         player_setupanimsformodel();
 522         UpdatePlayerSounds();
 523 }
 524
 525 /*
 526 =============
 527 PutObserverInServer
 528
 529 putting a client as observer in the server
 530 =============
 531 */
 532 void FixPlayermodel();
 533 void PutObserverInServer (void)
 534 {
 535         entity  spot;
 536
 537         race_PreSpawnObserver();
 538
 539         spot = SelectSpawnPoint (TRUE);
 540         if(!spot)
 541                 error("No spawnpoints for observers?!?\n");
 542         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 543
 544         if(clienttype(self) == CLIENTTYPE_REAL)
 545         {
 546                 msg_entity = self;
 547                 WriteByte(MSG_ONE, SVC_SETVIEW);
 548                 WriteEntity(MSG_ONE, self);
 549         }
 550
 551         DropAllRunes(self);
 552         kh_Key_DropAll(self, TRUE);
 553
 554         Portal_ClearAll(self);
 555
 556         if(self.flagcarried)
 557                 DropFlag(self.flagcarried, world, world);
 558         if(self.ballcarried)
 559                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 560
 561         WaypointSprite_PlayerDead();
 562
 563         if(self.killcount != -666)
 564         {
 565                 if(g_lms)
 566                 {
 567                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 568                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 569                         else
 570                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 571                 }
 572                 else
 573                         bprint ("^4", self.netname, "^4 is spectating now\n");
 574         }
 575
 576         PlayerScore_Clear(self); // clear scores when needed
 577
 578         self.spectatortime = time;
 579
 580         self.classname = "observer";
 581         self.iscreature = FALSE;
 582         self.health = -666;
 583         self.takedamage = DAMAGE_NO;
 584         self.solid = SOLID_NOT;
 585         self.movetype = MOVETYPE_NOCLIP;
 586         self.flags = FL_CLIENT | FL_NOTARGET;
 587         self.armorvalue = 666;
 588         self.effects = 0;
 589         self.armorvalue = cvar("g_balance_armor_start");
 590         self.pauserotarmor_finished = 0;
 591         self.pauserothealth_finished = 0;
 592         self.pauseregen_finished = 0;
 593         self.damageforcescale = 0;
 594         self.death_time = 0;
 595         self.dead_frame = 0;
 596         self.alpha = 0;
 597         self.scale = 0;
 598         self.fade_time = 0;
 599         self.pain_frame = 0;
 600         self.pain_finished = 0;
 601         self.strength_finished = 0;
 602         self.invincible_finished = 0;
 603         self.pushltime = 0;
 604         self.think = SUB_Null;
 605         self.nextthink = 0;
 606         self.hook_time = 0;
 607         self.runes = 0;
 608         self.deadflag = DEAD_NO;
 609         self.angles = spot.angles;
 610         self.angles_z = 0;
 611         self.fixangle = TRUE;
 612         self.crouch = FALSE;
 613
 614         self.view_ofs = PL_VIEW_OFS;
 615         setorigin (self, spot.origin);
 616         setsize (self, '0 0 0', '0 0 0');
 617         self.prevorigin = self.origin;
 618         self.items = 0;
 619         self.weapons = 0;
 620         self.model = "";
 621         FixPlayermodel();
 622         self.model = "";
 623         self.modelindex = 0;
 624         self.weapon = 0;
 625         self.weaponmodel = "";
 626         self.weaponentity = world;
 627         self.exteriorweaponentity = world;
 628         self.killcount = -666;
 629         self.velocity = '0 0 0';
 630         self.avelocity = '0 0 0';
 631         self.punchangle = '0 0 0';
 632         self.punchvector = '0 0 0';
 633         self.oldvelocity = self.velocity;
 634         self.fire_endtime = -1;
 635
 636         if(sv_loddistance1)
 637                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 638
 639         self.team = -1;
 640
 641         if(g_arena)
 642         {
 643                 if(self.version_mismatch)
 644                 {
 645                         Spawnqueue_Unmark(self);
 646                         Spawnqueue_Remove(self);
 647                 }
 648                 else
 649                 {
 650                         Spawnqueue_Insert(self);
 651                 }
 652         }
 653         else if(g_lms)
 654         {
 655                 // Only if the player cannot play at all
 656                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 657                         self.frags = FRAGS_SPECTATOR;
 658                 else
 659                         self.frags = FRAGS_LMS_LOSER;
 660         }
 661         else
 662                 self.frags = FRAGS_SPECTATOR;
 663 }
 664
 665 float RestrictSkin(float s)
 666 {
 667         if(!teams_matter)
 668                 return s;
 669         if(s == 6)
 670                 return 6;
 671         return mod(s, 3);
 672 }
 673
 674 void FixPlayermodel()
 675 {
 676         local string defaultmodel;
 677         local float defaultskin, chmdl, oldskin;
 678         local vector m1, m2;
 679
 680         defaultmodel = "";
 681
 682         if(cvar("sv_defaultcharacter") == 1) {
 683                 defaultskin = 0;
 684
 685                 if(teams_matter)
 686                 {
 687                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 688                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 689                 }
 690
 691                 if(defaultmodel == "")
 692                 {
 693                         defaultmodel = cvar_string("sv_defaultplayermodel");
 694                         defaultskin = cvar("sv_defaultplayerskin");
 695                 }
 696         }
 697
 698         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 699         {
 700                 if(self.model != "")
 701                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 702                 self.model = ""; // force the != checks to return true
 703         }
 704
 705         if(defaultmodel != "")
 706         {
 707                 if (defaultmodel != self.model)
 708                 {
 709                         m1 = self.mins;
 710                         m2 = self.maxs;
 711                         setmodel_lod (self, defaultmodel);
 712                         setsize (self, m1, m2);
 713                         chmdl = TRUE;
 714                 }
 715
 716                 oldskin = self.skinindex;
 717                 self.skinindex = defaultskin;
 718         } else {
 719                 if (self.playermodel != self.model)
 720                 {
 721                         self.playermodel = CheckPlayerModel(self.playermodel);
 722                         m1 = self.mins;
 723                         m2 = self.maxs;
 724                         setmodel_lod (self, self.playermodel);
 725                         setsize (self, m1, m2);
 726                         chmdl = TRUE;
 727                 }
 728
 729                 oldskin = self.skinindex;
 730                 self.skinindex = RestrictSkin(stof(self.playerskin));
 731         }
 732
 733         if(chmdl || oldskin != self.skinindex)
 734                 self.species = player_getspecies(); // model or skin has changed
 735
 736         if(!teams_matter)
 737                 if(strlen(cvar_string("sv_defaultplayercolors")))
 738                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 739                                 setcolor(self, cvar("sv_defaultplayercolors"));
 740 }
 741
 742 void PlayerTouchExplode(entity p1, entity p2)
 743 {
 744         vector org;
 745         org = (p1.origin + p2.origin) * 0.5;
 746         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 747
 748         te_explosion(org);
 749
 750         entity e;
 751         e = spawn();
 752         setorigin(e, org);
 753         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 754         remove(e);
 755 }
 756
 757 /*
 758 =============
 759 PutClientInServer
 760
 761 Called when a client spawns in the server
 762 =============
 763 */
 764 //void() ctf_playerchanged;
 765 void PutClientInServer (void)
 766 {
 767         if(clienttype(self) == CLIENTTYPE_BOT)
 768         {
 769                 self.classname = "player";
 770         }
 771         else if(clienttype(self) == CLIENTTYPE_REAL)
 772         {
 773                 msg_entity = self;
 774                 WriteByte(MSG_ONE, SVC_SETVIEW);
 775                 WriteEntity(MSG_ONE, self);
 776         }
 777
 778         // player is dead and becomes observer
 779         // FIXME fix LMS scoring for new system
 780         if(g_lms)
 781         {
 782                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 783                         self.classname = "observer";
 784         }
 785
 786         if(g_arena)
 787         if(!self.spawned)
 788                 self.classname = "observer";
 789
 790         if(gameover)
 791                 self.classname = "observer";
 792
 793         if(self.classname == "player") {
 794                 entity spot, oldself;
 795                 float j;
 796
 797                 if(self.team < 0)
 798                         JoinBestTeam(self, FALSE, TRUE);
 799
 800                 race_PreSpawn();
 801
 802                 spot = SelectSpawnPoint (FALSE);
 803                 if(!spot)
 804                 {
 805                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 806                         return; // spawn failed
 807                 }
 808
 809                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 810
 811                 self.classname = "player";
 812                 self.wasplayer = TRUE;
 813                 self.iscreature = TRUE;
 814                 self.movetype = MOVETYPE_WALK;
 815                 self.solid = SOLID_SLIDEBOX;
 816                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 817                 self.frags = FRAGS_PLAYER;
 818                 if(independent_players)
 819                         MAKE_INDEPENDENT_PLAYER(self);
 820                 self.flags = FL_CLIENT;
 821                 self.takedamage = DAMAGE_AIM;
 822                 if(g_minstagib)
 823                         self.effects = EF_FULLBRIGHT;
 824                 else
 825                         self.effects = 0;
 826                 self.air_finished = time + 12;
 827                 self.dmg = 2;
 828
 829                 if(inWarmupStage)
 830                 {
 831                         self.ammo_shells = warmup_start_ammo_shells;
 832                         self.ammo_nails = warmup_start_ammo_nails;
 833                         self.ammo_rockets = warmup_start_ammo_rockets;
 834                         self.ammo_cells = warmup_start_ammo_cells;
 835                         self.ammo_fuel = warmup_start_ammo_fuel;
 836                         self.health = warmup_start_health;
 837                         self.armorvalue = warmup_start_armorvalue;
 838                         self.weapons = warmup_start_weapons;
 839                 }
 840                 else
 841                 {
 842                         self.ammo_shells = start_ammo_shells;
 843                         self.ammo_nails = start_ammo_nails;
 844                         self.ammo_rockets = start_ammo_rockets;
 845                         self.ammo_cells = start_ammo_cells;
 846                         self.ammo_fuel = start_ammo_fuel;
 847                         self.health = start_health;
 848                         self.armorvalue = start_armorvalue;
 849                         self.weapons = start_weapons;
 850                 }
 851
 852                 if(g_weaponarena_random)
 853                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 854
 855                 self.items = start_items;
 856                 self.switchweapon = w_getbestweapon(self);
 857                 self.cnt = self.switchweapon;
 858                 self.weapon = 0;
 859                 self.jump_interval = time;
 860
 861                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 862                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 863                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 864                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 865                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 866                 //extend the pause of rotting if client was reset at the beginning of the countdown
 867                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 868                         self.spawnshieldtime += game_starttime - time;
 869                         self.pauserotarmor_finished += game_starttime - time;
 870                         self.pauserothealth_finished += game_starttime - time;
 871                         self.pauseregen_finished += game_starttime - time;
 872                 }
 873                 self.damageforcescale = 2;
 874                 self.death_time = 0;
 875                 self.dead_frame = 0;
 876                 self.alpha = 0;
 877                 self.scale = 0;
 878                 self.fade_time = 0;
 879                 self.pain_frame = 0;
 880                 self.pain_finished = 0;
 881                 self.strength_finished = 0;
 882                 self.invincible_finished = 0;
 883                 self.pushltime = 0;
 884                 //self.speed_finished = 0;
 885                 //self.slowmo_finished = 0;
 886                 // players have no think function
 887                 self.think = SUB_Null;
 888                 self.nextthink = 0;
 889                 self.hook_time = 0;
 890                 self.dmg_team = 0;
 891
 892                 self.metertime = 0;
 893
 894                 self.runes = 0;
 895
 896                 self.deadflag = DEAD_NO;
 897
 898                 self.angles = spot.angles;
 899
 900                 self.angles_z = 0; // never spawn tilted even if the spot says to
 901                 self.fixangle = TRUE; // turn this way immediately
 902                 self.velocity = '0 0 0';
 903                 self.avelocity = '0 0 0';
 904                 self.punchangle = '0 0 0';
 905                 self.punchvector = '0 0 0';
 906                 self.oldvelocity = self.velocity;
 907                 self.fire_endtime = -1;
 908
 909                 msg_entity = self;
 910                 WRITESPECTATABLE_MSG_ONE({
 911                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 912                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 913                 });
 914
 915                 if(sv_loddistance1)
 916                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 917
 918                 self.model = "";
 919                 FixPlayermodel();
 920
 921                 self.crouch = FALSE;
 922                 self.view_ofs = PL_VIEW_OFS;
 923                 setsize (self, PL_MIN, PL_MAX);
 924                 self.spawnorigin = spot.origin;
 925                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 926                 // don't reset back to last position, even if new position is stuck in solid
 927                 self.oldorigin = self.origin;
 928                 self.prevorigin = self.origin;
 929                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 930
 931                 if(g_arena)
 932                 {
 933                         Spawnqueue_Remove(self);
 934                         Spawnqueue_Mark(self);
 935                 }
 936
 937                 self.event_damage = PlayerDamage;
 938
 939                 self.bot_attack = TRUE;
 940
 941                 self.statdraintime = time + 5;
 942                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 943
 944                 if(self.killcount == -666) {
 945                         PlayerScore_Clear(self);
 946                         self.killcount = 0;
 947                 }
 948
 949                 self.cnt = WEP_LASER;
 950                 self.nixnex_lastchange_id = -1;
 951
 952                 CL_SpawnWeaponentity();
 953                 self.alpha = default_player_alpha;
 954                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 955                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 956
 957                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 958                 self.lms_traveled_distance = 0;
 959                 self.speedrunning = FALSE;
 960
 961                 race_PostSpawn(spot);
 962
 963                 if(cvar("spawn_debug"))
 964                 {
 965                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 966                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 967                 }
 968
 969                 //stuffcmd(self, "chase_active 0");
 970                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 971
 972                 if (cvar("g_spawnsound"))
 973                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 974
 975                 if(g_assault) {
 976                         if(self.team == assault_attacker_team)
 977                                 centerprint(self, "You are attacking!");
 978                         else
 979                                 centerprint(self, "You are defending!");
 980                 }
 981
 982                 target_voicescript_clear(self);
 983
 984                 // reset fields the weapons may use
 985         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 986             weapon_action(j, WR_RESETPLAYER);
 987
 988                 oldself = self;
 989                 self = spot;
 990                         activator = oldself;
 991                                 SUB_UseTargets();
 992                         activator = world;
 993                 self = oldself;
 994         } else if(self.classname == "observer") {
 995                 PutObserverInServer ();
 996         }
 997
 998         //if(g_ctf)
 999         //      ctf_playerchanged();
1000 }
1001
1002 float ClientInit_SendEntity(entity to, float sf)
1003 {
1004         float i;
1005         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1006         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1007         for(i = 1; i <= 24; ++i)
1008                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1009         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1010         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1011         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1012
1013         if(sv_foginterval && world.fog != "")
1014                 WriteString(MSG_ENTITY, world.fog);
1015         else
1016                 WriteString(MSG_ENTITY, "");
1017         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1018         return TRUE;
1019 }
1020
1021 void ClientInit_Spawn()
1022 {
1023         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1024 }
1025
1026 /*
1027 =============
1028 SetNewParms
1029 =============
1030 */
1031 void SetNewParms (void)
1032 {
1033         // initialize parms for a new player
1034         parm1 = -(86400 * 366);
1035 }
1036
1037 /*
1038 =============
1039 SetChangeParms
1040 =============
1041 */
1042 void SetChangeParms (void)
1043 {
1044         // save parms for level change
1045         parm1 = self.parm_idlesince - time;
1046 }
1047
1048 /*
1049 =============
1050 DecodeLevelParms
1051 =============
1052 */
1053 void DecodeLevelParms (void)
1054 {
1055         // load parms
1056         self.parm_idlesince = parm1;
1057         if(self.parm_idlesince == -(86400 * 366))
1058                 self.parm_idlesince = time;
1059
1060         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1061         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1062 }
1063
1064 /*
1065 =============
1066 ClientKill
1067
1068 Called when a client types 'kill' in the console
1069 =============
1070 */
1071
1072 void ClientKill_Now_TeamChange()
1073 {
1074         if(self.killindicator_teamchange == -1)
1075         {
1076                 self.team = -1;
1077                 JoinBestTeam( self, FALSE, FALSE );
1078         }
1079         else
1080                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1081 }
1082
1083 void ClientKill_Now()
1084 {
1085         if(self.killindicator_teamchange)
1086                 ClientKill_Now_TeamChange();
1087
1088         // in any case:
1089         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1090
1091         if(self.killindicator)
1092         {
1093                 dprint("Cleaned up after a leaked kill indicator.\n");
1094                 remove(self.killindicator);
1095                 self.killindicator = world;
1096         }
1097 }
1098 void KillIndicator_Think()
1099 {
1100         if (!self.owner.modelindex)
1101         {
1102                 self.owner.killindicator = world;
1103                 remove(self);
1104                 return;
1105         }
1106
1107         if(self.cnt <= 0)
1108         {
1109                 self = self.owner;
1110                 ClientKill_Now(); // no oldself needed
1111                 return;
1112         }
1113         else
1114         {
1115                 if(self.cnt <= 10)
1116                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1117                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1118                 {
1119                         if(self.cnt <= 10)
1120                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1121                         if(self.owner.killindicator_teamchange)
1122                         {
1123                                 if(self.owner.killindicator_teamchange == -1)
1124                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1125                                 else
1126                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1127                         }
1128                         else
1129                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1130                 }
1131                 self.nextthink = time + 1;
1132                 self.cnt -= 1;
1133         }
1134 }
1135
1136 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1137 {
1138         float killtime;
1139         entity e;
1140         killtime = cvar("g_balance_kill_delay");
1141
1142         if(g_race_qualifying)
1143                 killtime = 0;
1144
1145         self.killindicator_teamchange = targetteam;
1146
1147         if(!self.killindicator)
1148         {
1149                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1150                 {
1151                         ClientKill_Now();
1152                 }
1153                 else
1154                 {
1155                         self.killindicator = spawn();
1156                         self.killindicator.owner = self;
1157                         self.killindicator.scale = 0.5;
1158                         setattachment(self.killindicator, self, "");
1159                         setorigin(self.killindicator, '0 0 52');
1160                         self.killindicator.think = KillIndicator_Think;
1161                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1162                         self.killindicator.cnt = ceil(killtime);
1163                         self.killindicator.count = bound(0, ceil(killtime), 10);
1164                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1165
1166                         for(e = world; (e = find(e, classname, "body")) != world; )
1167                         {
1168                                 if(e.enemy != self)
1169                                         continue;
1170                                 e.killindicator = spawn();
1171                                 e.killindicator.owner = e;
1172                                 e.killindicator.scale = 0.5;
1173                                 setattachment(e.killindicator, e, "");
1174                                 setorigin(e.killindicator, '0 0 52');
1175                                 e.killindicator.think = KillIndicator_Think;
1176                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1177                                 e.killindicator.cnt = ceil(killtime);
1178                         }
1179                         self.lip = 0;
1180                 }
1181         }
1182         if(self.killindicator)
1183         {
1184                 if(targetteam)
1185                         self.killindicator.colormod = TeamColor(targetteam);
1186                 else
1187                         self.killindicator.colormod = '0 0 0';
1188         }
1189 }
1190
1191 void ClientKill (void)
1192 {
1193         ClientKill_TeamChange(0);
1194 }
1195
1196 void DoTeamChange(float destteam)
1197 {
1198         float t, c0;
1199         if(!teams_matter)
1200         {
1201                 if(destteam >= 0)
1202                         SetPlayerColors(self, destteam);
1203                 return;
1204         }
1205         if(self.classname == "player")
1206         if(destteam == -1)
1207         {
1208                 CheckAllowedTeams(self);
1209                 t = FindSmallestTeam(self, TRUE);
1210                 switch(self.team)
1211                 {
1212                         case COLOR_TEAM1: c0 = c1; break;
1213                         case COLOR_TEAM2: c0 = c2; break;
1214                         case COLOR_TEAM3: c0 = c3; break;
1215                         case COLOR_TEAM4: c0 = c4; break;
1216                         default:          c0 = 999;
1217                 }
1218                 switch(t)
1219                 {
1220                         case 1:
1221                                 if(c0 > c1)
1222                                         destteam = COLOR_TEAM1;
1223                                 break;
1224                         case 2:
1225                                 if(c0 > c2)
1226                                         destteam = COLOR_TEAM2;
1227                                 break;
1228                         case 3:
1229                                 if(c0 > c3)
1230                                         destteam = COLOR_TEAM3;
1231                                 break;
1232                         case 4:
1233                                 if(c0 > c4)
1234                                         destteam = COLOR_TEAM4;
1235                                 break;
1236                 }
1237                 if(destteam == -1)
1238                         return;
1239         }
1240         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1241                 return;
1242         ClientKill_TeamChange(destteam);
1243 }
1244
1245 void FixClientCvars(entity e)
1246 {
1247         // send prediction settings to the client
1248         stuffcmd(e, "\nin_bindmap 0 0\n");
1249         if(g_race || g_cts)
1250                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1251         /*
1252          * we no longer need to stuff this. Remove this comment block if you feel
1253          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1254         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1255         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1256         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1257         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1258         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1259         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1260         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1261         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1262         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1263         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1264         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1265         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1266         stuffcmd(e, "cl_movement_edgefriction 1\n");
1267          */
1268 }
1269
1270 /*
1271 =============
1272 ClientConnect
1273
1274 Called when a client connects to the server
1275 =============
1276 */
1277 //void ctf_clientconnect();
1278 string ColoredTeamName(float t);
1279 void DecodeLevelParms (void);
1280 //void dom_player_join_team(entity pl);
1281 void ClientConnect (void)
1282 {
1283         local string s;
1284         float t;
1285
1286         if(self.flags & FL_CLIENT)
1287         {
1288                 print("Warning: ClientConnect, but already connected!\n");
1289                 return;
1290         }
1291
1292         if(Ban_MaybeEnforceBan(self))
1293                 return;
1294
1295         DecodeLevelParms();
1296
1297         self.classname = "player_joining";
1298
1299         self.flags = FL_CLIENT;
1300         self.version_nagtime = time + 10 + random() * 10;
1301
1302         if(player_count<0)
1303         {
1304                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1305                 player_count = 0;
1306         }
1307
1308         PlayerScore_Attach(self);
1309         ClientData_Attach();
1310
1311         bot_clientconnect();
1312
1313         race_PreSpawnObserver();
1314
1315         //if(g_domination)
1316         //      dom_player_join_team(self);
1317
1318         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1319
1320         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1321                 self.classname = "observer";
1322         } else {
1323                 if(teams_matter)
1324                 {
1325                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1326                         {
1327                                 self.classname = "player";
1328                                 campaign_bots_may_start = 1;
1329                         }
1330                         else
1331                         {
1332                                 self.classname = "observer"; // do it anyway
1333                         }
1334                 }
1335                 else
1336                 {
1337                         self.classname = "player";
1338                         campaign_bots_may_start = 1;
1339                 }
1340         }
1341
1342         self.playerid = (playerid_last = playerid_last + 1);
1343         if(cvar("sv_eventlog"))
1344         {
1345                 if(clienttype(self) == CLIENTTYPE_REAL)
1346                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1347                 else
1348                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1349                 s = strcat(":team:", ftos(self.playerid), ":");
1350                 s = strcat(s, ftos(self.team));
1351                 GameLogEcho(s);
1352         }
1353         self.netname_previous = strzone(self.netname);
1354
1355         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1356
1357         bprint ("^4",self.netname);
1358         bprint ("^4 connected");
1359
1360         if(g_domination || g_ctf)
1361         {
1362                 bprint(" and joined the ");
1363                 bprint(ColoredTeamName(self.team));
1364         }
1365
1366         bprint("\n");
1367
1368         self.welcomemessage_time = 0;
1369
1370         stuffcmd(self, strcat(clientstuff, "\n"));
1371         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1372         stuffcmd(self, "cl_particles_reloadeffects\n");
1373
1374         FixClientCvars(self);
1375
1376         // spawnfunc_waypoint sprites
1377         WaypointSprite_InitClient(self);
1378
1379         // Wazat's grappling hook
1380         SetGrappleHookBindings();
1381
1382         // get autoswitch state from player when he toggles it
1383         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1384
1385         // get version info from player
1386         stuffcmd(self, "cmd clientversion $gameversion\n");
1387
1388         // get other cvars from player
1389         GetCvars(0);
1390
1391         // set cvar for team scoreboard
1392         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1393
1394         // notify about available teams
1395         if(teams_matter)
1396         {
1397                 CheckAllowedTeams(self);
1398                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1399                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1400         }
1401         else
1402                 stuffcmd(self, "set _teams_available 0\n");
1403
1404         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1405
1406         if(g_arena)
1407         {
1408                 self.classname = "observer";
1409                 Spawnqueue_Insert(self);
1410         }
1411         /*else if(g_ctf)
1412         {
1413                 ctf_clientconnect();
1414         }*/
1415
1416         if(teams_matter || sv_cheats)
1417                 attach_entcs();
1418
1419         bot_relinkplayerlist();
1420
1421         self.spectatortime = time;
1422         if(blockSpectators)
1423         {
1424                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1425         }
1426
1427         self.jointime = time;
1428         self.allowedTimeouts = cvar("sv_timeout_number");
1429
1430         if(clienttype(self) == CLIENTTYPE_REAL)
1431         {
1432                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1433                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1434         }
1435
1436         if(g_lms)
1437         {
1438                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1439                 {
1440                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1441                         self.frags = FRAGS_SPECTATOR;
1442                 }
1443         }
1444
1445         if(!sv_foginterval && world.fog != "")
1446                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1447
1448         SoundEntity_Attach(self);
1449
1450         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1451         {
1452                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1453                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1454         }
1455         else
1456                 self.hitplotfh = -1;
1457 }
1458
1459 /*
1460 =============
1461 ClientDisconnect
1462
1463 Called when a client disconnects from the server
1464 =============
1465 */
1466 .entity chatbubbleentity;
1467 .entity teambubbleentity;
1468 void ReadyCount();
1469 void ClientDisconnect (void)
1470 {
1471         if not(self.flags & FL_CLIENT)
1472         {
1473                 print("Warning: ClientDisconnect without ClientConnect\n");
1474                 return;
1475         }
1476
1477         if(self.hitplotfh >= 0)
1478         {
1479                 fclose(self.hitplotfh);
1480                 self.hitplotfh = -1;
1481         }
1482
1483         bot_clientdisconnect();
1484
1485         if(self.entcs)
1486                 detach_entcs();
1487
1488         if(cvar("sv_eventlog"))
1489                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1490         bprint ("^4",self.netname);
1491         bprint ("^4 disconnected\n");
1492
1493         SoundEntity_Detach(self);
1494
1495         DropAllRunes(self);
1496         kh_Key_DropAll(self, TRUE);
1497
1498         Portal_ClearAll(self);
1499
1500         if(self.flagcarried)
1501                 DropFlag(self.flagcarried, world, world);
1502         if(self.ballcarried)
1503                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1504
1505         // Here, everything has been done that requires this player to be a client.
1506
1507         self.flags &~= FL_CLIENT;
1508
1509         if (self.chatbubbleentity)
1510                 remove (self.chatbubbleentity);
1511
1512         if (self.teambubbleentity)
1513                 remove (self.teambubbleentity);
1514
1515         if (self.killindicator)
1516                 remove (self.killindicator);
1517
1518         WaypointSprite_PlayerGone();
1519
1520         bot_relinkplayerlist();
1521
1522         // remove laserdot
1523         if(self.weaponentity)
1524                 if(self.weaponentity.lasertarget)
1525                         remove(self.weaponentity.lasertarget);
1526
1527         if(g_arena)
1528         {
1529                 Spawnqueue_Unmark(self);
1530                 Spawnqueue_Remove(self);
1531         }
1532
1533         ClientData_Detach();
1534         PlayerScore_Detach(self);
1535
1536         if(self.netname_previous)
1537                 strunzone(self.netname_previous);
1538         if(self.clientstatus)
1539                 strunzone(self.clientstatus);
1540
1541         ClearPlayerSounds();
1542
1543         if(self.personal)
1544                 remove(self.personal);
1545
1546         self.playerid = 0;
1547         ReadyCount();
1548
1549         // free cvars
1550         GetCvars(-1);
1551 }
1552
1553 .float BUTTON_CHAT;
1554 void ChatBubbleThink()
1555 {
1556         self.nextthink = time;
1557         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1558         {
1559                 if(self.owner) // but why can that ever be world?
1560                         self.owner.chatbubbleentity = world;
1561                 remove(self);
1562                 return;
1563         }
1564         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1565 #ifdef TETRIS
1566                 || self.owner.tetris_on
1567 #endif
1568         )
1569                 self.model = self.mdl;
1570         else
1571                 self.model = "";
1572 };
1573
1574 void UpdateChatBubble()
1575 {
1576         if (!self.modelindex)
1577                 return;
1578         // spawn a chatbubble entity if needed
1579         if (!self.chatbubbleentity)
1580         {
1581                 self.chatbubbleentity = spawn();
1582                 self.chatbubbleentity.owner = self;
1583                 self.chatbubbleentity.exteriormodeltoclient = self;
1584                 self.chatbubbleentity.think = ChatBubbleThink;
1585                 self.chatbubbleentity.nextthink = time;
1586                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1587                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1588                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1589                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1590                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1591                 self.chatbubbleentity.model = "";
1592                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1593         }
1594 }
1595
1596
1597 void TeamBubbleThink()
1598 {
1599         self.nextthink = time;
1600         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1601         {
1602                 if(self.owner) // but why can that ever be world?
1603                         self.owner.teambubbleentity = world;
1604                 remove(self);
1605                 return;
1606         }
1607 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1608         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1609                 self.model = "";
1610         else
1611                 self.model = self.mdl;
1612
1613 };
1614
1615 float TeamBubble_customizeentityforclient()
1616 {
1617         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1618 }
1619
1620 void UpdateTeamBubble()
1621 {
1622         if (!self.modelindex || !teams_matter)
1623                 return;
1624         // spawn a teambubble entity if needed
1625         if (!self.teambubbleentity && teams_matter)
1626         {
1627                 self.teambubbleentity = spawn();
1628                 self.teambubbleentity.owner = self;
1629                 self.teambubbleentity.exteriormodeltoclient = self;
1630                 self.teambubbleentity.think = TeamBubbleThink;
1631                 self.teambubbleentity.nextthink = time;
1632                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1633 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1634                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1635                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1636                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1637                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1638                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1639                 self.teambubbleentity.effects = EF_LOWPRECISION;
1640         }
1641 }
1642
1643 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1644 // added to the model skins
1645 /*void UpdateColorModHack()
1646 {
1647         local float c;
1648         c = self.clientcolors & 15;
1649         // LordHavoc: only bothering to support white, green, red, yellow, blue
1650              if (!teams_matter) self.colormod = '0 0 0';
1651         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1652         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1653         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1654         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1655         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1656         else self.colormod = '1 1 1';
1657 };*/
1658
1659 void respawn(void)
1660 {
1661         CopyBody(1);
1662         self.effects |= EF_NODRAW; // prevent another CopyBody
1663         PutClientInServer();
1664 }
1665
1666 void play_countdown(float finished, string samp)
1667 {
1668         if(clienttype(self) == CLIENTTYPE_REAL)
1669                 if(floor(finished - time - frametime) != floor(finished - time))
1670                         if(finished - time < 6)
1671                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1672 }
1673
1674 /**
1675  * When sv_timeout is used this function returs strings like
1676  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1677  * Called by centerprint functions
1678  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1679  */
1680 string getTimeoutText(float addOneSecond) {
1681         if (!cvar("sv_timeout") || !timeoutStatus)
1682                 return "";
1683
1684         local string retStr;
1685         if (timeoutStatus == 1) {
1686                 if (addOneSecond == 1) {
1687                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1688                 }
1689                 else {
1690                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1691                 }
1692                 return retStr;
1693         }
1694         else if (timeoutStatus == 2) {
1695                 if (addOneSecond) {
1696                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1697                         //don't show messages like "Timeout ends in 0 seconds"...
1698                         if ((remainingTimeoutTime + 1) > 0)
1699                                 return retStr;
1700                         else
1701                                 return "";
1702                 }
1703                 else {
1704                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1705                         //don't show messages like "Timeout ends in 0 seconds"...
1706                         if (remainingTimeoutTime > 0)
1707                                 return retStr;
1708                         else
1709                                 return "";
1710                 }
1711         }
1712         else return "";
1713 }
1714
1715 void player_powerups (void)
1716 {
1717         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1718         {
1719                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1720                 self.modelflags |= MF_ROCKET;
1721         }
1722         else
1723         {
1724                 SoundEntity_StopSound(self, CHAN_PLAYER);
1725                 self.modelflags &~= MF_ROCKET;
1726         }
1727
1728         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME);
1729
1730         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1731                 return;
1732
1733         Fire_ApplyDamage(self);
1734         Fire_ApplyEffect(self);
1735
1736         if (g_minstagib)
1737         {
1738                 self.effects |= EF_FULLBRIGHT;
1739
1740                 if (self.items & IT_STRENGTH)
1741                 {
1742                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1743                         if (time > self.strength_finished)
1744                         {
1745                                 self.alpha = default_player_alpha;
1746                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1747                                 self.items &~= IT_STRENGTH;
1748                                 sprint(self, "^3Invisibility has worn off\n");
1749                         }
1750                 }
1751                 else
1752                 {
1753                         if (time < self.strength_finished)
1754                         {
1755                                 self.alpha = g_minstagib_invis_alpha;
1756                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1757                                 self.items |= IT_STRENGTH;
1758                                 sprint(self, "^3You are invisible\n");
1759                         }
1760                 }
1761
1762                 if (self.items & IT_INVINCIBLE)
1763                 {
1764                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1765                         if (time > self.invincible_finished)
1766                         {
1767                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1768                                 sprint(self, "^3Speed has worn off\n");
1769                         }
1770                 }
1771                 else
1772                 {
1773                         if (time < self.invincible_finished)
1774                         {
1775                                 self.items = self.items | IT_INVINCIBLE;
1776                                 sprint(self, "^3You are on speed\n");
1777                         }
1778                 }
1779                 return;
1780         }
1781
1782         if (self.items & IT_STRENGTH)
1783         {
1784                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1785                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1786                 if (time > self.strength_finished)
1787                 {
1788                         self.items = self.items - (self.items & IT_STRENGTH);
1789                         sprint(self, "^3Strength has worn off\n");
1790                 }
1791         }
1792         else
1793         {
1794                 if (time < self.strength_finished)
1795                 {
1796                         self.items = self.items | IT_STRENGTH;
1797                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1798                 }
1799         }
1800         if (self.items & IT_INVINCIBLE)
1801         {
1802                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1803                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1804                 if (time > self.invincible_finished)
1805                 {
1806                         self.items = self.items - (self.items & IT_INVINCIBLE);
1807                         sprint(self, "^3Shield has worn off\n");
1808                 }
1809         }
1810         else
1811         {
1812                 if (time < self.invincible_finished)
1813                 {
1814                         self.items = self.items | IT_INVINCIBLE;
1815                         sprint(self, "^3Shield surrounds you\n");
1816                 }
1817         }
1818
1819         if (cvar("g_fullbrightplayers"))
1820                 self.effects = self.effects | EF_FULLBRIGHT;
1821
1822         // midair gamemode: damage only while in the air
1823         // if in midair mode, being on ground grants temporary invulnerability
1824         // (this is so that multishot weapon don't clear the ground flag on the
1825         // first damage in the frame, leaving the player vulnerable to the
1826         // remaining hits in the same frame)
1827         if (self.flags & FL_ONGROUND)
1828         if (g_midair)
1829                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1830
1831         if (time >= game_starttime)
1832         if (time < self.spawnshieldtime)
1833                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1834 }
1835
1836 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1837 {
1838         if(current > stable)
1839                 return current;
1840         else if(current > stable - 0.25) // when close enough, "snap"
1841                 return stable;
1842         else
1843                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1844 }
1845
1846 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1847 {
1848         if(current < stable)
1849                 return current;
1850         else if(current < stable + 0.25) // when close enough, "snap"
1851                 return stable;
1852         else
1853                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1854 }
1855
1856 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1857 {
1858         if(current > rotstable)
1859         {
1860                 if(rotframetime > 0)
1861                 {
1862                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1863                         current = max(rotstable, current - rotlinear * rotframetime);
1864                 }
1865         }
1866         else if(current < regenstable)
1867         {
1868                 if(regenframetime > 0)
1869                 {
1870                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1871                         current = min(regenstable, current + regenlinear * regenframetime);
1872                 }
1873         }
1874
1875         if(current > limit)
1876                 current = limit;
1877
1878         return current;
1879 }
1880
1881 void player_regen (void)
1882 {
1883         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1884         maxh = cvar("g_balance_health_rotstable");
1885         maxa = cvar("g_balance_armor_rotstable");
1886         maxf = cvar("g_balance_fuel_rotstable");
1887         minh = cvar("g_balance_health_regenstable");
1888         mina = cvar("g_balance_armor_regenstable");
1889         minf = cvar("g_balance_fuel_regenstable");
1890         limith = cvar("g_balance_health_limit");
1891         limita = cvar("g_balance_armor_limit");
1892         limitf = cvar("g_balance_fuel_limit");
1893
1894         max_mod = regen_mod = rot_mod = limit_mod = 1;
1895
1896         if (self.runes & RUNE_REGEN)
1897         {
1898                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1899                 {
1900                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1901                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1902                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1903                 }
1904                 else
1905                 {
1906                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1907                         max_mod = cvar("g_balance_rune_regen_hpmod");
1908                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1909                 }
1910         }
1911         else if (self.runes & CURSE_VENOM)
1912         {
1913                 max_mod = cvar("g_balance_curse_venom_hpmod");
1914                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1915                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1916                 else
1917                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1918                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1919                 //if (!self.runes & RUNE_REGEN)
1920                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1921         }
1922         maxh = maxh * max_mod;
1923         //maxa = maxa * max_mod;
1924         //maxf = maxf * max_mod;
1925         minh = minh * max_mod;
1926         //mina = mina * max_mod;
1927         //minf = minf * max_mod;
1928         limith = limith * limit_mod;
1929         limita = limita * limit_mod;
1930         //limitf = limitf * limit_mod;
1931
1932         if(g_lms)
1933                 rot_mod = 0;
1934
1935         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1936         {
1937                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1938                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1939
1940                 // if player rotted to death...  die!
1941                 if(self.health < 1)
1942                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1943         }
1944
1945         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1946                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1947 }
1948
1949 float zoomstate_set;
1950 void SetZoomState(float z)
1951 {
1952         if(z != self.zoomstate)
1953         {
1954                 self.zoomstate = z;
1955                 ClientData_Touch(self);
1956         }
1957         zoomstate_set = 1;
1958 }
1959
1960 void GetPressedKeys(void) {
1961         if (self.movement_x > 0) // get if movement keys are pressed
1962         {       // forward key pressed
1963                 self.pressedkeys |= KEY_FORWARD;
1964                 self.pressedkeys &~= KEY_BACKWARD;
1965         }
1966         else if (self.movement_x < 0)
1967         {       // backward key pressed
1968                 self.pressedkeys |= KEY_BACKWARD;
1969                 self.pressedkeys &~= KEY_FORWARD;
1970         }
1971         else
1972         {       // no x input
1973                 self.pressedkeys &~= KEY_FORWARD;
1974                 self.pressedkeys &~= KEY_BACKWARD;
1975         }
1976
1977         if (self.movement_y > 0)
1978         {       // right key pressed
1979                 self.pressedkeys |= KEY_RIGHT;
1980                 self.pressedkeys &~= KEY_LEFT;
1981         }
1982         else if (self.movement_y < 0)
1983         {       // left key pressed
1984                 self.pressedkeys |= KEY_LEFT;
1985                 self.pressedkeys &~= KEY_RIGHT;
1986         }
1987         else
1988         {       // no y input
1989                 self.pressedkeys &~= KEY_RIGHT;
1990                 self.pressedkeys &~= KEY_LEFT;
1991         }
1992
1993         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1994                 self.pressedkeys |= KEY_JUMP;
1995         else
1996                 self.pressedkeys &~= KEY_JUMP;
1997         if (self.BUTTON_CROUCH)
1998                 self.pressedkeys |= KEY_CROUCH;
1999         else
2000                 self.pressedkeys &~= KEY_CROUCH;
2001 }
2002
2003 /*
2004 ======================
2005 spectate mode routines
2006 ======================
2007 */
2008 void SpectateCopy(entity spectatee) {
2009         self.kh_state = spectatee.kh_state;
2010         self.armortype = spectatee.armortype;
2011         self.armorvalue = spectatee.armorvalue;
2012         self.ammo_cells = spectatee.ammo_cells;
2013         self.ammo_shells = spectatee.ammo_shells;
2014         self.ammo_nails = spectatee.ammo_nails;
2015         self.ammo_rockets = spectatee.ammo_rockets;
2016         self.ammo_fuel = spectatee.ammo_fuel;
2017         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2018         self.health = spectatee.health;
2019         self.impulse = 0;
2020         self.items = spectatee.items;
2021         self.metertime = spectatee.metertime;
2022         self.strength_finished = spectatee.strength_finished;
2023         self.invincible_finished = spectatee.invincible_finished;
2024         self.pressedkeys = spectatee.pressedkeys;
2025         self.weapons = spectatee.weapons;
2026         self.switchweapon = spectatee.switchweapon;
2027         self.weapon = spectatee.weapon;
2028         self.punchangle = spectatee.punchangle;
2029         self.view_ofs = spectatee.view_ofs;
2030         self.v_angle = spectatee.v_angle;
2031         self.velocity = spectatee.velocity;
2032         self.dmg_take = spectatee.dmg_take;
2033         self.dmg_save = spectatee.dmg_save;
2034         self.dmg_inflictor = spectatee.dmg_inflictor;
2035         self.angles = spectatee.v_angle;
2036         self.fixangle = TRUE;
2037         setorigin(self, spectatee.origin);
2038         setsize(self, spectatee.mins, spectatee.maxs);
2039         SetZoomState(spectatee.zoomstate);
2040 }
2041
2042 float SpectateUpdate() {
2043         if(!self.enemy)
2044                 return 0;
2045
2046         if (self == self.enemy)
2047                 return 0;
2048
2049         if(self.enemy.classname != "player")
2050                 return 0;
2051
2052         SpectateCopy(self.enemy);
2053
2054         return 1;
2055 }
2056
2057 float SpectateNext() {
2058         other = find(self.enemy, classname, "player");
2059         if (!other) {
2060                 other = find(other, classname, "player");
2061         }
2062         if (other) {
2063                 self.enemy = other;
2064         }
2065         if(self.enemy.classname == "player") {
2066                 msg_entity = self;
2067                 WriteByte(MSG_ONE, SVC_SETVIEW);
2068                 WriteEntity(MSG_ONE, self.enemy);
2069                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2070                 self.movetype = MOVETYPE_NONE;
2071                 if(!SpectateUpdate())
2072                         PutObserverInServer();
2073                 return 1;
2074         } else {
2075                 return 0;
2076         }
2077 }
2078
2079 /*
2080 =============
2081 ShowRespawnCountdown()
2082
2083 Update a respawn countdown display.
2084 =============
2085 */
2086 void ShowRespawnCountdown()
2087 {
2088         float number;
2089         if(self.deadflag == DEAD_NO) // just respawned?
2090                 return;
2091         else
2092         {
2093                 number = ceil(self.death_time - time);
2094                 if(number <= 0)
2095                         return;
2096                 if(number <= self.respawn_countdown)
2097                 {
2098                         self.respawn_countdown = number - 1;
2099                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2100                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2101                 }
2102         }
2103 }
2104
2105 void LeaveSpectatorMode()
2106 {
2107         if(isJoinAllowed()) {
2108                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2109                         self.classname = "player";
2110                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2111                                 JoinBestTeam(self, FALSE, TRUE);
2112                         if(cvar("g_campaign"))
2113                                 campaign_bots_may_start = 1;
2114                         PutClientInServer();
2115                         if(self.classname == "player")
2116                                 bprint ("^4", self.netname, "^4 is playing now\n");
2117                         if(!cvar("g_campaign"))
2118                                 centerprint(self,""); // clear MOTD
2119                         return;
2120                 } else {
2121                         stuffcmd(self,"menu_showteamselect\n");
2122                         return;
2123                 }
2124         }
2125         else {
2126                 //player may not join because of g_maxplayers is set
2127                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2128         }
2129 }
2130
2131 /**
2132  * Determines whether the player is allowed to join. This depends on cvar
2133  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2134  * it checks whether the number of currently playing players exceeds g_maxplayers.
2135  * @return bool TRUE if the player is allowed to join, false otherwise
2136  */
2137 float isJoinAllowed() {
2138         if (!cvar("g_maxplayers"))
2139                 return TRUE;
2140
2141         local entity e;
2142         local float currentlyPlaying;
2143         FOR_EACH_REALPLAYER(e) {
2144                 if(e.classname == "player")
2145                         currentlyPlaying += 1;
2146         }
2147         if(currentlyPlaying < cvar("g_maxplayers"))
2148                 return TRUE;
2149
2150         return FALSE;
2151 }
2152
2153 /**
2154  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2155  * g_maxplayers_spectator_blocktime seconds
2156  */
2157 void checkSpectatorBlock() {
2158         if(self.classname == "spectator" || self.classname == "observer") {
2159                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2160                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2161                         dropclient(self);
2162                 }
2163         }
2164 }
2165
2166 float vercmp_recursive(string v1, string v2)
2167 {
2168         float dot1, dot2;
2169         string s1, s2;
2170         float r;
2171
2172         dot1 = strstrofs(v1, ".", 0);
2173         dot2 = strstrofs(v2, ".", 0);
2174         if(dot1 == -1)
2175                 s1 = v1;
2176         else
2177                 s1 = substring(v1, 0, dot1);
2178         if(dot2 == -1)
2179                 s2 = v2;
2180         else
2181                 s2 = substring(v2, 0, dot2);
2182
2183         r = stof(s1) - stof(s2);
2184         if(r != 0)
2185                 return r;
2186
2187         r = strcasecmp(s1, s2);
2188         if(r != 0)
2189                 return r;
2190
2191         if(dot1 == -1)
2192                 if(dot2 == -1)
2193                         return 0;
2194                 else
2195                         return -1;
2196         else
2197                 if(dot2 == -1)
2198                         return 1;
2199                 else
2200                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2201 }
2202
2203 float vercmp(string v1, string v2)
2204 {
2205         if(strcasecmp(v1, v2) == 0) // early out check
2206                 return 0;
2207         return vercmp_recursive(v1, v2);
2208 }
2209
2210 void ObserverThink()
2211 {
2212         if (self.flags & FL_JUMPRELEASED) {
2213                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2214                         self.welcomemessage_time = 0;
2215                         self.flags &~= FL_JUMPRELEASED;
2216                         self.flags |= FL_SPAWNING;
2217                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2218                         self.welcomemessage_time = 0;
2219                         self.flags &~= FL_JUMPRELEASED;
2220                         if(SpectateNext() == 1) {
2221                                 self.classname = "spectator";
2222                         }
2223                 }
2224         } else {
2225                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2226                         self.flags |= FL_JUMPRELEASED;
2227                         if(self.flags & FL_SPAWNING)
2228                         {
2229                                 self.flags &~= FL_SPAWNING;
2230                                 LeaveSpectatorMode();
2231                                 return;
2232                         }
2233                 }
2234         }
2235         PrintWelcomeMessage(self);
2236 }
2237
2238 void SpectatorThink()
2239 {
2240         if (self.flags & FL_JUMPRELEASED) {
2241                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2242                         self.welcomemessage_time = 0;
2243                         self.flags &~= FL_JUMPRELEASED;
2244                         self.flags |= FL_SPAWNING;
2245                 } else if(self.BUTTON_ATCK) {
2246                         self.welcomemessage_time = 0;
2247                         self.flags &~= FL_JUMPRELEASED;
2248                         if(SpectateNext() == 1) {
2249                                 self.classname = "spectator";
2250                         } else {
2251                                 self.classname = "observer";
2252                                 PutClientInServer();
2253                         }
2254                 } else if (self.BUTTON_ATCK2) {
2255                         self.welcomemessage_time = 0;
2256                         self.flags &~= FL_JUMPRELEASED;
2257                         self.classname = "observer";
2258                         PutClientInServer();
2259                 } else {
2260                         if(!SpectateUpdate())
2261                                 PutObserverInServer();
2262                 }
2263         } else {
2264                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2265                         self.flags |= FL_JUMPRELEASED;
2266                         if(self.flags & FL_SPAWNING)
2267                         {
2268                                 self.flags &~= FL_SPAWNING;
2269                                 LeaveSpectatorMode();
2270                                 return;
2271                         }
2272                 }
2273         }
2274         PrintWelcomeMessage(self);
2275         self.flags |= FL_CLIENT | FL_NOTARGET;
2276 }
2277
2278 .float touchexplode_time;
2279
2280 /*
2281 =============
2282 PlayerPreThink
2283
2284 Called every frame for each client before the physics are run
2285 =============
2286 */
2287 void() ctf_setstatus;
2288 void() nexball_setstatus;
2289 .float items_added;
2290 void PlayerPreThink (void)
2291 {
2292         self.stat_game_starttime = game_starttime;
2293         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2294         self.stat_leadlimit = cvar("leadlimit");
2295
2296         if(blockSpectators && frametime)
2297                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2298                 checkSpectatorBlock();
2299
2300         zoomstate_set = 0;
2301
2302         if(self.netname_previous != self.netname)
2303         {
2304                 if(cvar("sv_eventlog"))
2305                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2306                 if(self.netname_previous)
2307                         strunzone(self.netname_previous);
2308                 self.netname_previous = strzone(self.netname);
2309         }
2310
2311         // version nagging
2312         if(self.version_nagtime)
2313                 if(self.cvar_g_nexuizversion)
2314                         if(time > self.version_nagtime)
2315                         {
2316                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2317                                 {
2318                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2319                                         {
2320                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2321                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2322                                         }
2323                                         else
2324                                         {
2325                                                 float r;
2326                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2327                                                 if(r < 0)
2328                                                 {
2329                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2330                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2331                                                 }
2332                                                 else if(r > 0)
2333                                                 {
2334                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2335                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2336                                                 }
2337                                         }
2338                                 }
2339                                 self.version_nagtime = 0;
2340                         }
2341
2342         // GOD MODE info
2343         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2344         {
2345                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2346                 self.max_armorvalue = 0;
2347         }
2348
2349 #ifdef TETRIS
2350         if (TetrisPreFrame())
2351                 return;
2352 #endif
2353
2354         if(self.classname == "player") {
2355 //              if(self.netname == "Wazat")
2356 //                      bprint(self.classname, "\n");
2357
2358                 CheckRules_Player();
2359
2360                 PrintWelcomeMessage(self);
2361
2362                 if (intermission_running)
2363                 {
2364                         IntermissionThink ();   // otherwise a button could be missed between
2365                         return;                                 // the think tics
2366                 }
2367
2368                 if(self.teleport_time)
2369                 if(time > self.teleport_time)
2370                 {
2371                         self.teleport_time = 0;
2372                         self.effects = self.effects - (self.effects & EF_NODRAW);
2373                 }
2374
2375                 Nixnex_GiveCurrentWeapon();
2376
2377                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2378                         UpdateSelectedPlayer();
2379
2380                 //don't allow the player to turn around while game is paused!
2381                 if(timeoutStatus == 2) {
2382                         self.v_angle = self.lastV_angle;
2383                         self.angles = self.lastV_angle;
2384                         self.fixangle = TRUE;
2385                 }
2386
2387                 if(frametime)
2388                         player_powerups();
2389
2390                 if (self.deadflag != DEAD_NO)
2391                 {
2392                         float button_pressed, force_respawn;
2393                         if(self.personal && g_race_qualifying)
2394                         {
2395                                 if(time > self.death_time)
2396                                 {
2397                                         self.death_time = time + 1; // only retry once a second
2398                                         respawn();
2399                                         self.impulse = 141;
2400                                 }
2401                         }
2402                         else
2403                         {
2404                                 if(frametime)
2405                                         player_anim();
2406                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2407                                 force_respawn = (g_lms || cvar("g_forced_respawn"));
2408                                 if (self.deadflag == DEAD_DYING)
2409                                 {
2410                                         if(force_respawn)
2411                                                 self.deadflag = DEAD_RESPAWNING;
2412                                         else if(!button_pressed)
2413                                                 self.deadflag = DEAD_DEAD;
2414                                 }
2415                                 else if (self.deadflag == DEAD_DEAD)
2416                                 {
2417                                         if(button_pressed)
2418                                                 self.deadflag = DEAD_RESPAWNABLE;
2419                                 }
2420                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2421                                 {
2422                                         if(!button_pressed)
2423                                                 self.deadflag = DEAD_RESPAWNING;
2424                                 }
2425                                 else if (self.deadflag == DEAD_RESPAWNING)
2426                                 {
2427                                         if(time > self.death_time)
2428                                         {
2429                                                 self.death_time = time + 1; // only retry once a second
2430                                                 respawn();
2431                                         }
2432                                 }
2433                                 ShowRespawnCountdown();
2434                         }
2435                         return;
2436                 }
2437
2438                 if(g_touchexplode)
2439                 if(time > self.touchexplode_time)
2440                 if(self.classname == "player")
2441                 if(self.deadflag == DEAD_NO)
2442                 if not(IS_INDEPENDENT_PLAYER(self))
2443                 FOR_EACH_PLAYER(other) if(self != other)
2444                 {
2445                         if(time > other.touchexplode_time)
2446                         if(other.classname == "player")
2447                         if(other.deadflag == DEAD_NO)
2448                         if not(IS_INDEPENDENT_PLAYER(other))
2449                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2450                         {
2451                                 PlayerTouchExplode(self, other);
2452                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2453                         }
2454                 }
2455
2456                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2457                 {
2458                         vector dist;
2459
2460                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2461                         dist = self.prevorigin - self.origin;
2462                         dist_z = 0;
2463                         self.lms_traveled_distance += fabs(vlen(dist));
2464
2465                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2466                         {
2467                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2468                                 self.lms_traveled_distance = 0;
2469                         }
2470
2471                         if(time > self.lms_nextcheck)
2472                         {
2473                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2474                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2475                                 {
2476                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2477                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2478                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2479                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2480                                 }
2481                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2482                                 self.lms_traveled_distance = 0;
2483                         }
2484                 }
2485
2486                 self.prevorigin = self.origin;
2487
2488                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2489                 {
2490                         if (!self.crouch)
2491                         {
2492                                 self.crouch = TRUE;
2493                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2494                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2495                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2496                         }
2497                 }
2498                 else
2499                 {
2500                         if (self.crouch)
2501                         {
2502                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2503                                 if (!trace_startsolid)
2504                                 {
2505                                         self.crouch = FALSE;
2506                                         self.view_ofs = PL_VIEW_OFS;
2507                                         setsize (self, PL_MIN, PL_MAX);
2508                                 }
2509                         }
2510                 }
2511
2512                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2513                 {
2514                         if(self.bloodloss_timer < time)
2515                         {
2516                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2517                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2518                         }
2519                 }
2520
2521                 FixPlayermodel();
2522
2523                 GrapplingHookFrame();
2524
2525                 if(frametime)
2526                 {
2527                         self.items &~= self.items_added;
2528
2529                         W_WeaponFrame();
2530
2531                         self.items_added = 0;
2532                         if(self.items & IT_JETPACK)
2533                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2534                                         self.items_added |= IT_FUEL;
2535
2536                         self.items |= self.items_added;
2537                 }
2538
2539                 player_regen();
2540                 if(frametime)
2541                         player_anim();
2542
2543                 if (g_minstagib)
2544                         minstagib_ammocheck();
2545
2546                 ctf_setstatus();
2547                 nexball_setstatus();
2548
2549                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2550
2551                 //self.angles_y=self.v_angle_y + 90;   // temp
2552         } else if(gameover) {
2553                 if (intermission_running)
2554                         IntermissionThink ();   // otherwise a button could be missed between
2555                 return;
2556         } else if(self.classname == "observer") {
2557                 ObserverThink();
2558         } else if(self.classname == "spectator") {
2559                 SpectatorThink();
2560         }
2561
2562         if(!zoomstate_set)
2563                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2564
2565         float oldspectatee_status;
2566         oldspectatee_status = self.spectatee_status;
2567         if(self.classname == "spectator")
2568                 self.spectatee_status = num_for_edict(self.enemy);
2569         else if(self.classname == "observer")
2570                 self.spectatee_status = num_for_edict(self);
2571         else
2572                 self.spectatee_status = 0;
2573         if(self.spectatee_status != oldspectatee_status)
2574         {
2575                 ClientData_Touch(self);
2576                 if(g_race || g_cts)
2577                         race_InitSpectator();
2578         }
2579
2580         if(self.teamkill_soundtime)
2581         if(time > self.teamkill_soundtime)
2582         {
2583                 self.teamkill_soundtime = 0;
2584
2585                 entity oldpusher, oldself;
2586
2587                 oldself = self; self = self.teamkill_soundsource;
2588                 oldpusher = self.pusher; self.pusher = oldself;
2589
2590                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2591
2592                 self.pusher = oldpusher;
2593                 self = oldself;
2594         }
2595
2596         if(self.taunt_soundtime)
2597         if(time > self.taunt_soundtime)
2598         {
2599                 self.taunt_soundtime = 0;
2600                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2601         }
2602
2603         target_voicescript_next(self);
2604 }
2605
2606 // on dragger:
2607 .entity dragentity;
2608 .float draggravity;
2609 .float dragspeed; // speed of mouse wheel action
2610 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2611 .vector draglocalvector; // local attachment vector of the dragentity
2612 .float draglocalangle;
2613 // on draggee:
2614 .entity draggedby;
2615 .float dragmovetype;
2616 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2617 {
2618         float tagscale;
2619
2620         draggee.dragmovetype = draggee.movetype;
2621         draggee.draggravity = draggee.gravity;
2622         draggee.movetype = MOVETYPE_WALK;
2623         draggee.gravity = 0.00001;
2624         draggee.flags &~= FL_ONGROUND;
2625         draggee.draggedby = dragger;
2626
2627         dragger.dragentity = draggee;
2628
2629         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2630         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2631         touchpoint = touchpoint - gettaginfo(draggee, 0);
2632         tagscale = pow(vlen(v_forward), -2);
2633         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2634         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2635         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2636
2637         dragger.dragspeed = 64;
2638 }
2639
2640 void Drag_Finish(entity dragger)
2641 {
2642         entity draggee;
2643         draggee = dragger.dragentity;
2644         if(dragger)
2645                 dragger.dragentity = world;
2646         draggee.draggedby = world;
2647         draggee.movetype = draggee.dragmovetype;
2648         draggee.gravity = draggee.draggravity;
2649
2650         switch(draggee.movetype)
2651         {
2652                 case MOVETYPE_TOSS:
2653                 case MOVETYPE_WALK:
2654                 case MOVETYPE_STEP:
2655                 case MOVETYPE_FLYMISSILE:
2656                 case MOVETYPE_BOUNCE:
2657                 case MOVETYPE_BOUNCEMISSILE:
2658                         break;
2659                 default:
2660                         draggee.velocity = '0 0 0';
2661                         break;
2662         }
2663
2664         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2665         {
2666                 draggee.velocity = '0 0 0';
2667                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2668         }
2669 }
2670
2671 float Drag_IsDraggable(entity draggee)
2672 {
2673         // TODO add more checks for bad stuff here
2674         if(draggee.classname == "func_bobbing")
2675                 return FALSE;
2676         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2677                 return FALSE;
2678         if(draggee.classname == "plat")
2679                 return FALSE;
2680         if(draggee.classname == "func_button")
2681                 return FALSE;
2682         if(draggee.model == "")
2683                 return FALSE;
2684         if(draggee.classname == "spectator")
2685                 return FALSE;
2686         if(draggee.classname == "observer")
2687                 return FALSE;
2688         if(draggee.classname == "exteriorweaponentity")
2689                 return FALSE;
2690
2691         return TRUE;
2692 }
2693
2694 float Drag_MayChangeAngles(entity draggee)
2695 {
2696         // TODO add more checks for bad stuff here
2697         if(substring(draggee.model, 0, 1) == "*")
2698                 return FALSE;
2699         return TRUE;
2700 }
2701
2702 void Drag_MoveForward(entity dragger)
2703 {
2704         dragger.dragdistance += dragger.dragspeed;
2705 }
2706
2707 void Drag_SetSpeed(entity dragger, float s)
2708 {
2709         dragger.dragspeed = pow(2, s);
2710 }
2711
2712 void Drag_MoveBackward(entity dragger)
2713 {
2714         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2715 }
2716
2717 void Drag_Update(entity dragger)
2718 {
2719         vector curorigin, neworigin, goodvelocity;
2720         float f;
2721         entity draggee;
2722
2723         draggee = dragger.dragentity;
2724         draggee.flags &~= FL_ONGROUND;
2725
2726         curorigin = gettaginfo(draggee, 0);
2727         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2728         makevectors(dragger.v_angle);
2729         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2730         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2731
2732         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2733                 dragger.draglocalangle += 360;
2734         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2735                 dragger.draglocalangle -= 360;
2736
2737         f = min(frametime * 10, 1);
2738         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2739
2740         if(Drag_MayChangeAngles(draggee))
2741                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2742
2743         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2744
2745         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2746 }
2747
2748 float Drag_CanDrag(entity dragger)
2749 {
2750         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2751 }
2752
2753 float Drag_IsDragging(entity dragger)
2754 {
2755         if(!dragger.dragentity)
2756                 return FALSE;
2757         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2758         {
2759                 dragger.dragentity = world;
2760                 return FALSE;
2761         }
2762         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2763         {
2764                 Drag_Finish(dragger);
2765                 return FALSE;
2766         }
2767         return TRUE;
2768 }
2769
2770 void Drag_MoveDrag(entity from, entity to)
2771 {
2772         if(from.draggedby)
2773         {
2774                 to.draggedby = from.draggedby;
2775                 to.draggedby.dragentity = to;
2776                 from.draggedby = world;
2777         }
2778 }
2779
2780 /*
2781 =============
2782 PlayerPostThink
2783
2784 Called every frame for each client after the physics are run
2785 =============
2786 */
2787 .float idlekick_lasttimeleft;
2788 void PlayerPostThink (void)
2789 {
2790         // Savage: Check for nameless players
2791         if (strlen(self.netname) < 1) {
2792                 self.netname = "Player";
2793                 stuffcmd(self, "seta _cl_name Player\n");
2794         }
2795
2796         if(sv_maxidle && frametime)
2797         {
2798                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2799                 float timeleft;
2800                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2801                 if(timeleft <= 0)
2802                 {
2803                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2804                         announce(self, "announcer/robotic/terminated.wav");
2805                         dropclient(self);
2806                         return;
2807                 }
2808                 else if(timeleft <= 10)
2809                 {
2810                         if(timeleft != self.idlekick_lasttimeleft)
2811                         {
2812                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2813                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2814                         }
2815                 }
2816                 else
2817                 {
2818                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2819                 }
2820                 self.idlekick_lasttimeleft = timeleft;
2821         }
2822
2823 #ifdef TETRIS
2824         if(self.impulse == 100)
2825                 ImpulseCommands();
2826         if (TetrisPostFrame())
2827                 return;
2828 #endif
2829
2830         if(sv_cheats || self.maycheat)
2831                 if(Drag_CanDrag(self))
2832                         if(self.BUTTON_DRAG)
2833                                 if(!self.dragentity)
2834                                         if(self.cursor_trace_ent)
2835                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2836                                                 {
2837                                                         if(self.cursor_trace_ent.draggedby)
2838                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2839                                                         if(self.cursor_trace_ent.tag_entity)
2840                                                                 detach_sameorigin(self.cursor_trace_ent);
2841                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2842                                                 }
2843
2844         if(Drag_IsDragging(self))
2845         {
2846                 if(self.BUTTON_DRAG)
2847                 {
2848                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2849                         {
2850                                 Drag_MoveForward(self);
2851                                 self.impulse = 0;
2852                         }
2853                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2854                         {
2855                                 Drag_MoveBackward(self);
2856                                 self.impulse = 0;
2857                         }
2858                         else if(self.impulse >= 1 && self.impulse <= 9)
2859                         {
2860                                 Drag_SetSpeed(self, self.impulse - 1);
2861                         }
2862                         else if(self.impulse == 14)
2863                         {
2864                                 Drag_SetSpeed(self, 9);
2865                         }
2866
2867                         if(frametime)
2868                                 Drag_Update(self);
2869                 }
2870                 else
2871                 {
2872                         Drag_Finish(self);
2873                 }
2874         }
2875
2876         if(self.classname == "player") {
2877                 CheckRules_Player();
2878                 UpdateChatBubble();
2879                 UpdateTeamBubble();
2880                 if (self.impulse)
2881                         ImpulseCommands();
2882                 if (intermission_running)
2883                         return;         // intermission or finale
2884
2885                 GetPressedKeys();
2886         } else if (self.classname == "observer") {
2887                 //do nothing
2888         } else if (self.classname == "spectator") {
2889                 //do nothing
2890         }
2891
2892         /*
2893         float i;
2894         for(i = 0; i < 1000; ++i)
2895         {
2896                 vector end;
2897                 end = self.origin + '0 0 1024' + 512 * randomvec();
2898                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2899                 if(trace_fraction < 1)
2900                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2901                 {
2902                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2903                         break;
2904                 }
2905         }
2906         */
2907
2908         Arena_Warmup();
2909
2910         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2911
2912         if(self.waypointsprite_attachedforcarrier)
2913                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2914 }