data/qcsrc/server/cl_client.qc

   1 // let's abuse an existing field
   2 #define SPAWNPOINT_SCORE frags
   3
   4 .float wantswelcomemessage;
   5 .string netname_previous;
   6
   7 void spawnfunc_info_player_survivor (void)
   8 {
   9         spawnfunc_info_player_deathmatch();
  10 }
  11
  12 void spawnfunc_info_player_start (void)
  13 {
  14         spawnfunc_info_player_deathmatch();
  15 }
  16
  17 void spawnfunc_info_player_deathmatch (void)
  18 {
  19         self.classname = "info_player_deathmatch";
  20         relocate_spawnpoint();
  21 }
  22
  23 void spawnpoint_use()
  24 {
  25         if(teams_matter)
  26         if(have_team_spawns)
  27         {
  28                 self.team = activator.team;
  29                 some_spawn_has_been_used = 1;
  30         }
  31 };
  32
  33 // Returns:
  34 //   -1 if a spawn can't be used
  35 //   otherwise, a weight of the spawnpoint
  36 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  37 {
  38         float shortest, thisdist;
  39         entity player;
  40
  41         // filter out spots for the wrong team
  42         if(teamcheck)
  43         if(spot.team != teamcheck)
  44                 return -1;
  45
  46         if(race_spawns)
  47                 if(spot.target == "")
  48                         return -1;
  49
  50         // filter out spots for assault
  51         if(spot.target != "") {
  52                 local entity ent;
  53                 float good;
  54                 ent = find(world, targetname, spot.target);
  55                 while(ent) {
  56                         if(ent.classname == "target_objective")
  57                         {
  58                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  59                                         return -1;
  60                                 good = 1;
  61                         }
  62                         else if(ent.classname == "trigger_race_checkpoint")
  63                         {
  64                                 if(self.classname == "player") // spectators may spawn everywhere
  65                                 {
  66                                         if(g_race_qualifying)
  67                                         {
  68                                                 // spawn at first
  69                                                 if(ent.race_checkpoint != 0)
  70                                                         return -1;
  71                                                 if(spot.race_place != race_lowest_place_spawn)
  72                                                         return -1;
  73                                         }
  74                                         else
  75                                         {
  76                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  77                                                         return -1;
  78                                                 float pl;
  79                                                 pl = self.race_place;
  80                                                 if(pl > race_highest_place_spawn)
  81                                                         pl = 0;
  82                                                 if(spot.race_place != pl)
  83                                                         return -1;
  84                                         }
  85                                 }
  86                                 good = 1;
  87                         }
  88                         else
  89                         {
  90                         }
  91                         ent = find(ent, targetname, spot.target);
  92                 }
  93
  94                 if(!good)
  95                         return -1;
  96         }
  97
  98         player = playerlist;
  99         shortest = vlen(world.maxs - world.mins);
 100         for(player = playerlist; player; player = player.chain)
 101                 if (player != self)
 102                 {
 103                         thisdist = vlen(player.origin - spot.origin);
 104                         if (thisdist < shortest)
 105                                 shortest = thisdist;
 106                 }
 107         return shortest;
 108 }
 109
 110 float spawn_allbad;
 111 float spawn_allgood;
 112 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 113 {
 114         local entity spot, spotlist, spotlistend;
 115         spawn_allgood = TRUE;
 116         spawn_allbad = TRUE;
 117
 118         spotlist = world;
 119         spotlistend = world;
 120
 121         for(spot = firstspot; spot; spot = spot.chain)
 122         {
 123                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 124
 125                 if(cvar("spawn_debugview"))
 126                 {
 127                         setmodel(spot, "models/runematch/rune.mdl");
 128                         if(spot.SPAWNPOINT_SCORE < mindist)
 129                         {
 130                                 spot.colormod = '1 0 0';
 131                                 spot.scale = 1;
 132                         }
 133                         else
 134                         {
 135                                 spot.colormod = '0 1 0';
 136                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 137                         }
 138                 }
 139
 140                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 141                 {
 142                         if(spot.SPAWNPOINT_SCORE < mindist)
 143                         {
 144                                 // too short distance
 145                                 spawn_allgood = FALSE;
 146                         }
 147                         else
 148                         {
 149                                 // perfect
 150                                 spawn_allbad = FALSE;
 151
 152                                 if(spotlistend)
 153                                         spotlistend.chain = spot;
 154                                 spotlistend = spot;
 155                                 if(!spotlist)
 156                                         spotlist = spot;
 157
 158                                 /*
 159                                 if(teamcheck)
 160                                 if(spot.team != teamcheck)
 161                                         error("invalid spawn added");
 162
 163                                 print("added ", etos(spot), "\n");
 164                                 */
 165                         }
 166                 }
 167         }
 168         if(spotlistend)
 169                 spotlistend.chain = world;
 170
 171         /*
 172                 entity e;
 173                 if(teamcheck)
 174                         for(e = spotlist; e; e = e.chain)
 175                         {
 176                                 print("seen ", etos(e), "\n");
 177                                 if(e.team != teamcheck)
 178                                         error("invalid spawn found");
 179                         }
 180         */
 181
 182         return spotlist;
 183 }
 184
 185 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 186 {
 187         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 188         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 189         local entity spot;
 190
 191         RandomSelection_Init();
 192         for(spot = firstspot; spot; spot = spot.chain)
 193                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 194
 195         return RandomSelection_chosen_ent;
 196 }
 197
 198 /*
 199 =============
 200 SelectSpawnPoint
 201
 202 Finds a point to respawn
 203 =============
 204 */
 205 entity SelectSpawnPoint (float anypoint)
 206 {
 207         local float teamcheck;
 208         local entity firstspot_new;
 209         local entity spot, firstspot, playerlist;
 210
 211         spot = find (world, classname, "testplayerstart");
 212         if (spot)
 213                 return spot;
 214
 215         teamcheck = 0;
 216
 217         if(!anypoint && have_team_spawns)
 218                 teamcheck = self.team;
 219
 220         // get the list of players
 221         playerlist = findchain(classname, "player");
 222         // get the entire list of spots
 223         firstspot = findchain(classname, "info_player_deathmatch");
 224         // filter out the bad ones
 225         // (note this returns the original list if none survived)
 226         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 227         if(!firstspot_new)
 228                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 229         firstspot = firstspot_new;
 230
 231         // there is 50/50 chance of choosing a random spot or the furthest spot
 232         // (this means that roughly every other spawn will be furthest, so you
 233         // usually won't get fragged at spawn twice in a row)
 234         if (arena_roundbased)
 235         {
 236                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 237                 if(firstspot_new)
 238                         firstspot = firstspot_new;
 239                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 240         }
 241         else if (random() > cvar("g_spawn_furthest"))
 242                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 243         else
 244                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 245
 246         if(cvar("spawn_debugview"))
 247         {
 248                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 249
 250                 entity e;
 251                 if(teamcheck)
 252                         for(e = firstspot; e; e = e.chain)
 253                                 if(e.team != teamcheck)
 254                                         error("invalid spawn found");
 255         }
 256
 257         if (!spot)
 258         {
 259                 if(cvar("spawn_debug"))
 260                         GotoNextMap();
 261                 else
 262                 {
 263                         if(some_spawn_has_been_used)
 264                                 return world; // team can't spawn any more, because of actions of other team
 265                         else
 266                                 error("Cannot find a spawn point - please fix the map!");
 267                 }
 268         }
 269
 270         return spot;
 271 }
 272
 273 /*
 274 =============
 275 CheckPlayerModel
 276
 277 Checks if the argument string can be a valid playermodel.
 278 Returns a valid one in doubt.
 279 =============
 280 */
 281 string FallbackPlayerModel = "models/player/marine.zym";
 282 string CheckPlayerModel(string plyermodel) {
 283         if(strlen(plyermodel) < 4)
 284                 return FallbackPlayerModel;
 285         if( substring(plyermodel,0,14) != "models/player/")
 286                 return FallbackPlayerModel;
 287         else if(cvar("sv_servermodelsonly"))
 288         {
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 292                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 293                         return FallbackPlayerModel;
 294                 if(plyermodel != strtolower(plyermodel))
 295                         return FallbackPlayerModel;
 296                 if(!fexists(plyermodel))
 297                         return FallbackPlayerModel;
 298         }
 299         return plyermodel;
 300 }
 301
 302 /*
 303 =============
 304 Client_customizeentityforclient
 305
 306 LOD reduction
 307 =============
 308 */
 309 float Client_customizeentityforclient()
 310 {
 311 #ifdef ALLOW_VARIABLE_LOD
 312         // self: me
 313         // other: the player viewing me
 314         float distance;
 315         float f;
 316
 317         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 318                 return TRUE;
 319
 320         if(other.cvar_cl_playerdetailreduction <= 0)
 321         {
 322                 if(other.cvar_cl_playerdetailreduction <= -2)
 323                         self.modelindex = self.modelindex_lod2;
 324                 else if(other.cvar_cl_playerdetailreduction <= -1)
 325                         self.modelindex = self.modelindex_lod1;
 326                 else
 327                         self.modelindex = self.modelindex_lod0;
 328         }
 329         else
 330         {
 331                 distance = vlen(self.origin - other.origin);
 332                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 333                 if(f > 10000)
 334                         self.modelindex = self.modelindex_lod2;
 335                 else if(f > 5000)
 336                         self.modelindex = self.modelindex_lod1;
 337                 else
 338                         self.modelindex = self.modelindex_lod0;
 339         }
 340 #endif
 341
 342         return TRUE;
 343 }
 344
 345 void UpdatePlayerSounds();
 346 void setmodel_lod(entity e, string modelname)
 347 {
 348 #ifdef ALLOW_VARIABLE_LOD
 349         string s;
 350
 351         // FIXME: this only supports 3-letter extensions
 352         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 353         if(fexists(s))
 354         {
 355                 precache_model(s);
 356                 setmodel(e, s); // players have high precision
 357                 self.modelindex_lod1 = self.modelindex;
 358         }
 359         else
 360                 self.modelindex_lod1 = -1;
 361
 362         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 363         if(fexists(s))
 364         {
 365                 precache_model(s);
 366                 setmodel(e, s); // players have high precision
 367                 self.modelindex_lod2 = self.modelindex;
 368         }
 369         else
 370                 self.modelindex_lod2 = -1;
 371
 372         precache_model(modelname);
 373         setmodel(e, modelname); // players have high precision
 374         self.modelindex_lod0 = self.modelindex;
 375
 376         if(self.modelindex_lod1 < 0)
 377                 self.modelindex_lod1 = self.modelindex;
 378
 379         if(self.modelindex_lod2 < 0)
 380                 self.modelindex_lod2 = self.modelindex;
 381 #else
 382         precache_model(modelname);
 383         setmodel(e, modelname); // players have high precision
 384 #endif
 385         player_setupanimsformodel();
 386         UpdatePlayerSounds();
 387 }
 388
 389 /*
 390 =============
 391 PutObserverInServer
 392
 393 putting a client as observer in the server
 394 =============
 395 */
 396 void PutObserverInServer (void)
 397 {
 398         entity  spot;
 399
 400         race_PreSpawnObserver();
 401
 402         spot = SelectSpawnPoint (TRUE);
 403         if(!spot)
 404                 error("No spawnpoints for observers?!?\n");
 405         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 406
 407         if(clienttype(self) == CLIENTTYPE_REAL)
 408         {
 409                 msg_entity = self;
 410                 WriteByte(MSG_ONE, SVC_SETVIEW);
 411                 WriteEntity(MSG_ONE, self);
 412         }
 413
 414         DropAllRunes(self);
 415         kh_Key_DropAll(self, TRUE);
 416
 417         Portal_ClearAll(self);
 418
 419         if(self.flagcarried)
 420                 DropFlag(self.flagcarried, world, world);
 421
 422         WaypointSprite_PlayerDead();
 423
 424         if(self.killcount != -666)
 425         {
 426                 if(g_lms)
 427                 {
 428                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 429                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 430                         else
 431                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 432                 }
 433                 else
 434                         bprint ("^4", self.netname, "^4 is spectating now\n");
 435         }
 436
 437         PlayerScore_Clear(self); // clear scores when needed
 438
 439         self.spectatortime = time;
 440
 441         self.classname = "observer";
 442         self.health = -666;
 443         self.takedamage = DAMAGE_NO;
 444         self.solid = SOLID_NOT;
 445         self.movetype = MOVETYPE_NOCLIP;
 446         self.flags = FL_CLIENT | FL_NOTARGET;
 447         self.armorvalue = 666;
 448         self.effects = 0;
 449         self.armorvalue = cvar("g_balance_armor_start");
 450         self.pauserotarmor_finished = 0;
 451         self.pauserothealth_finished = 0;
 452         self.pauseregen_finished = 0;
 453         self.damageforcescale = 0;
 454         self.death_time = 0;
 455         self.dead_frame = 0;
 456         self.alpha = 0;
 457         self.scale = 0;
 458         self.fade_time = 0;
 459         self.pain_frame = 0;
 460         self.pain_finished = 0;
 461         self.strength_finished = 0;
 462         self.invincible_finished = 0;
 463         self.pushltime = 0;
 464         self.think = SUB_Null;
 465         self.nextthink = 0;
 466         self.hook_time = 0;
 467         self.runes = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         self.view_ofs = PL_VIEW_OFS;
 475         setorigin (self, spot.origin);
 476         setsize (self, '0 0 0', '0 0 0');
 477         self.oldorigin = self.origin;
 478         self.items = 0;
 479         self.weapons = 0;
 480         self.model = "";
 481         self.modelindex = 0;
 482         self.weapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.killcount = -666;
 486         self.velocity = '0 0 0';
 487         self.avelocity = '0 0 0';
 488         self.punchangle = '0 0 0';
 489         self.punchvector = '0 0 0';
 490         self.oldvelocity = self.velocity;
 491         self.customizeentityforclient = Client_customizeentityforclient;
 492         self.wantswelcomemessage = 1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         Spawnqueue_Unmark(self);
 499                         Spawnqueue_Remove(self);
 500                 }
 501                 else
 502                 {
 503                         Spawnqueue_Insert(self);
 504                 }
 505         }
 506         else if(g_lms)
 507         {
 508                 // Only if the player cannot play at all
 509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 510                         self.frags = -666;
 511                 else
 512                         self.frags = -667;
 513         }
 514         else
 515                 self.frags = -666;
 516 }
 517
 518 float RestrictSkin(float s)
 519 {
 520         if(!teams_matter)
 521                 return s;
 522         if(s == 6)
 523                 return 6;
 524         return mod(s, 3);
 525 }
 526
 527 void FixPlayermodel()
 528 {
 529         local string defaultmodel;
 530         local float defaultskin;
 531         local vector m1, m2;
 532
 533         defaultmodel = "";
 534
 535         if(cvar("sv_defaultcharacter") == 1) {
 536                 defaultskin = 0;
 537
 538                 if(teams_matter)
 539                 {
 540                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 541                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 542                 }
 543
 544                 if(defaultmodel == "")
 545                 {
 546                         defaultmodel = cvar_string("sv_defaultplayermodel");
 547                         defaultskin = cvar("sv_defaultplayerskin");
 548                 }
 549         }
 550
 551         if(defaultmodel != "")
 552         {
 553                 if (defaultmodel != self.model)
 554                 {
 555                         m1 = self.mins;
 556                         m2 = self.maxs;
 557                         setmodel_lod (self, defaultmodel);
 558                         setsize (self, m1, m2);
 559                 }
 560
 561                 self.skin = defaultskin;
 562         } else {
 563                 if (self.playermodel != self.model)
 564                 {
 565                         self.playermodel = CheckPlayerModel(self.playermodel);
 566                         m1 = self.mins;
 567                         m2 = self.maxs;
 568                         setmodel_lod (self, self.playermodel);
 569                         setsize (self, m1, m2);
 570                 }
 571
 572                 self.skin = RestrictSkin(stof(self.playerskin));
 573         }
 574
 575         if(!teams_matter)
 576                 if(strlen(cvar_string("sv_defaultplayercolors")))
 577                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 578                                 setcolor(self, cvar("sv_defaultplayercolors"));
 579 }
 580
 581 /*
 582 =============
 583 PutClientInServer
 584
 585 Called when a client spawns in the server
 586 =============
 587 */
 588 //void() ctf_playerchanged;
 589 void PutClientInServer (void)
 590 {
 591         if(clienttype(self) == CLIENTTYPE_BOT)
 592         {
 593                 self.classname = "player";
 594         }
 595         else if(clienttype(self) == CLIENTTYPE_REAL)
 596         {
 597                 msg_entity = self;
 598                 WriteByte(MSG_ONE, SVC_SETVIEW);
 599                 WriteEntity(MSG_ONE, self);
 600         }
 601
 602         // player is dead and becomes observer
 603         // FIXME fix LMS scoring for new system
 604         if(g_lms)
 605         {
 606                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 607                         self.classname = "observer";
 608         }
 609
 610         if(g_arena)
 611         if(!self.spawned)
 612                 self.classname = "observer";
 613
 614         if(self.classname == "player") {
 615                 entity  spot;
 616
 617                 race_PreSpawn();
 618
 619                 spot = SelectSpawnPoint (FALSE);
 620                 if(!spot)
 621                 {
 622                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 623                         return; // spawn failed
 624                 }
 625
 626                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 627
 628                 self.classname = "player";
 629                 self.iscreature = TRUE;
 630                 self.movetype = MOVETYPE_WALK;
 631                 self.solid = SOLID_SLIDEBOX;
 632                 if(independent_players)
 633                         MAKE_INDEPENDENT_PLAYER(self);
 634                 self.flags = FL_CLIENT;
 635                 self.takedamage = DAMAGE_AIM;
 636                 if(g_minstagib)
 637                         self.effects = EF_FULLBRIGHT;
 638                 else
 639                         self.effects = 0;
 640                 self.air_finished = time + 12;
 641                 self.dmg = 2;
 642
 643                 if(inWarmupStage)
 644                 {
 645                         self.ammo_shells = warmup_start_ammo_shells;
 646                         self.ammo_nails = warmup_start_ammo_nails;
 647                         self.ammo_rockets = warmup_start_ammo_rockets;
 648                         self.ammo_cells = warmup_start_ammo_cells;
 649                         self.health = warmup_start_health;
 650                         self.armorvalue = warmup_start_armorvalue;
 651                         self.weapons = warmup_start_weapons;
 652                 }
 653                 else
 654                 {
 655                         self.ammo_shells = start_ammo_shells;
 656                         self.ammo_nails = start_ammo_nails;
 657                         self.ammo_rockets = start_ammo_rockets;
 658                         self.ammo_cells = start_ammo_cells;
 659                         self.health = start_health;
 660                         self.armorvalue = start_armorvalue;
 661                         self.weapons = start_weapons;
 662                 }
 663                 self.items = start_items;
 664                 self.switchweapon = w_getbestweapon(self);
 665                 self.cnt = self.switchweapon;
 666                 self.weapon = 0;
 667                 self.jump_interval = time;
 668
 669                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 670                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 671                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 672                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 673                 //extend the pause of rotting if client was reset at the beginning of the countdown
 674                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 675                         self.spawnshieldtime += game_starttime - time;
 676                         self.pauserotarmor_finished += game_starttime - time;
 677                         self.pauserothealth_finished += game_starttime - time;
 678                         self.pauseregen_finished += game_starttime - time;
 679                 }
 680                 self.damageforcescale = 2;
 681                 self.death_time = 0;
 682                 self.dead_frame = 0;
 683                 self.alpha = 0;
 684                 self.scale = 0;
 685                 self.fade_time = 0;
 686                 self.pain_frame = 0;
 687                 self.pain_finished = 0;
 688                 self.strength_finished = 0;
 689                 self.invincible_finished = 0;
 690                 self.pushltime = 0;
 691                 //self.speed_finished = 0;
 692                 //self.slowmo_finished = 0;
 693                 // players have no think function
 694                 self.think = SUB_Null;
 695                 self.nextthink = 0;
 696                 self.hook_time = 0;
 697
 698                 self.runes = 0;
 699
 700                 self.deadflag = DEAD_NO;
 701
 702                 self.angles = spot.angles;
 703
 704                 self.angles_z = 0; // never spawn tilted even if the spot says to
 705                 self.fixangle = TRUE; // turn this way immediately
 706                 self.velocity = '0 0 0';
 707                 self.avelocity = '0 0 0';
 708                 self.punchangle = '0 0 0';
 709                 self.punchvector = '0 0 0';
 710                 self.oldvelocity = self.velocity;
 711
 712                 msg_entity = self;
 713                 WRITESPECTATABLE_MSG_ONE({
 714                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 715                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 716                 });
 717
 718                 self.customizeentityforclient = Client_customizeentityforclient;
 719
 720                 self.model = "";
 721                 FixPlayermodel();
 722
 723                 self.crouch = FALSE;
 724                 self.view_ofs = PL_VIEW_OFS;
 725                 setsize (self, PL_MIN, PL_MAX);
 726                 self.spawnorigin = spot.origin;
 727                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 728                 // don't reset back to last position, even if new position is stuck in solid
 729                 self.oldorigin = self.origin;
 730
 731                 if(g_arena)
 732                 {
 733                         Spawnqueue_Remove(self);
 734                         Spawnqueue_Mark(self);
 735                 }
 736
 737                 self.event_damage = PlayerDamage;
 738
 739                 self.bot_attack = TRUE;
 740
 741                 self.statdraintime = time + 5;
 742                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 743
 744                 if(self.killcount == -666) {
 745                         PlayerScore_Clear(self);
 746                         self.killcount = 0;
 747                         self.frags = 0;
 748                 }
 749
 750                 self.cnt = WEP_LASER;
 751                 self.nixnex_lastchange_id = -1;
 752
 753                 CL_SpawnWeaponentity();
 754                 self.alpha = default_player_alpha;
 755                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 756                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 757
 758                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 759                 self.lms_traveled_distance = 0;
 760                 self.speedrunning = FALSE;
 761
 762                 race_PostSpawn(spot);
 763
 764                 if(cvar("spawn_debug"))
 765                 {
 766                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 768                 }
 769
 770                 //stuffcmd(self, "chase_active 0");
 771                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 772
 773                 if (cvar("g_spawnsound"))
 774                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 775
 776                 if(g_assault) {
 777                         if(self.team == assault_attacker_team)
 778                                 centerprint(self, "You are attacking!\n");
 779                         else
 780                                 centerprint(self, "You are defending!\n");
 781                 }
 782
 783         } else if(self.classname == "observer") {
 784                 PutObserverInServer ();
 785         }
 786
 787         //if(g_ctf)
 788         //      ctf_playerchanged();
 789 }
 790
 791 /*
 792 =============
 793 SendCSQCInfo
 794
 795 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 796 =============
 797 */
 798 void SendCSQCInfo(void)
 799 {
 800         float i;
 801         if(clienttype(self) != CLIENTTYPE_REAL)
 802                 return;
 803         msg_entity = self;
 804         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 805         WriteByte(MSG_ONE, TE_CSQC_INIT);
 806         WriteShort(MSG_ONE, CSQC_REVISION);
 807         WriteByte(MSG_ONE, maxclients);
 808         for(i = 1; i <= 24; ++i)
 809                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 810         WriteCoord(MSG_ONE, hook_shotorigin_x);
 811         WriteCoord(MSG_ONE, hook_shotorigin_y);
 812         WriteCoord(MSG_ONE, hook_shotorigin_z);
 813 }
 814
 815 /*
 816 =============
 817 SetNewParms
 818 =============
 819 */
 820 void SetNewParms (void)
 821 {
 822         // initialize parms for a new player
 823         parm1 = -(86400 * 366);
 824 }
 825
 826 /*
 827 =============
 828 SetChangeParms
 829 =============
 830 */
 831 void SetChangeParms (void)
 832 {
 833         // save parms for level change
 834         parm1 = self.parm_idlesince - time;
 835 }
 836
 837 /*
 838 =============
 839 DecodeLevelParms
 840 =============
 841 */
 842 void DecodeLevelParms (void)
 843 {
 844         // load parms
 845         self.parm_idlesince = parm1;
 846         if(self.parm_idlesince == -(86400 * 366))
 847                 self.parm_idlesince = time;
 848 }
 849
 850 /*
 851 =============
 852 ClientKill
 853
 854 Called when a client types 'kill' in the console
 855 =============
 856 */
 857
 858 void ClientKill_Now_TeamChange()
 859 {
 860         if(self.killindicator_teamchange == -1)
 861         {
 862                 self.team = -1;
 863                 JoinBestTeam( self, FALSE, FALSE );
 864         }
 865         else
 866         {
 867                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 868         }
 869 }
 870
 871 void ClientKill_Now()
 872 {
 873         if(self.killindicator_teamchange)
 874                 ClientKill_Now_TeamChange();
 875
 876         // in any case:
 877         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 878
 879         if(self.killindicator)
 880         {
 881                 dprint("Cleaned up after a leaked kill indicator.\n");
 882                 remove(self.killindicator);
 883                 self.killindicator = world;
 884         }
 885 }
 886 void KillIndicator_Think()
 887 {
 888         if (!self.owner.modelindex)
 889         {
 890                 self.owner.killindicator = world;
 891                 remove(self);
 892                 return;
 893         }
 894
 895         if(self.cnt <= 0)
 896         {
 897                 self = self.owner;
 898                 ClientKill_Now(); // no oldself needed
 899                 return;
 900         }
 901         else
 902         {
 903                 if(self.cnt <= 10)
 904                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 905                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 906                 {
 907                         if(self.cnt <= 10)
 908                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
 909                         if(self.owner.killindicator_teamchange)
 910                         {
 911                                 if(self.owner.killindicator_teamchange == -1)
 912                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 913                                 else
 914                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 915                         }
 916                         else
 917                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 918                 }
 919                 self.nextthink = time + 1;
 920                 self.cnt -= 1;
 921         }
 922 }
 923
 924 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 925 {
 926         float killtime;
 927         entity e;
 928         killtime = cvar("g_balance_kill_delay");
 929
 930         self.killindicator_teamchange = targetteam;
 931
 932         if(!self.killindicator)
 933         {
 934                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 935                 {
 936                         ClientKill_Now();
 937                 }
 938                 else
 939                 {
 940                         self.killindicator = spawn();
 941                         self.killindicator.owner = self;
 942                         self.killindicator.scale = 0.5;
 943                         setattachment(self.killindicator, self, "");
 944                         setorigin(self.killindicator, '0 0 52');
 945                         self.killindicator.think = KillIndicator_Think;
 946                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 947                         self.killindicator.cnt = ceil(killtime);
 948                         self.killindicator.count = bound(0, ceil(killtime), 10);
 949                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 950
 951                         for(e = world; (e = find(e, classname, "body")) != world; )
 952                         {
 953                                 if(e.enemy != self)
 954                                         continue;
 955                                 e.killindicator = spawn();
 956                                 e.killindicator.owner = e;
 957                                 e.killindicator.scale = 0.5;
 958                                 setattachment(e.killindicator, e, "");
 959                                 setorigin(e.killindicator, '0 0 52');
 960                                 e.killindicator.think = KillIndicator_Think;
 961                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 962                                 e.killindicator.cnt = ceil(killtime);
 963                         }
 964                         self.lip = 0;
 965                 }
 966         }
 967         if(self.killindicator)
 968         {
 969                 if(targetteam)
 970                         self.killindicator.colormod = TeamColor(targetteam);
 971                 else
 972                         self.killindicator.colormod = '0 0 0';
 973         }
 974 }
 975
 976 void ClientKill (void)
 977 {
 978         ClientKill_TeamChange(0);
 979 }
 980
 981 void DoTeamChange(float destteam)
 982 {
 983         float t, c0;
 984         if(!cvar("teamplay"))
 985         {
 986                 if(destteam >= 0)
 987                         SetPlayerColors(self, destteam);
 988                 return;
 989         }
 990         if(self.classname == "player")
 991         if(destteam == -1)
 992         {
 993                 CheckAllowedTeams(self);
 994                 t = FindSmallestTeam(self, TRUE);
 995                 switch(self.team)
 996                 {
 997                         case COLOR_TEAM1: c0 = c1; break;
 998                         case COLOR_TEAM2: c0 = c2; break;
 999                         case COLOR_TEAM3: c0 = c3; break;
1000                         case COLOR_TEAM4: c0 = c4; break;
1001                         default:          c0 = 999;
1002                 }
1003                 switch(t)
1004                 {
1005                         case 1:
1006                                 if(c0 > c1)
1007                                         destteam = COLOR_TEAM1;
1008                                 break;
1009                         case 2:
1010                                 if(c0 > c2)
1011                                         destteam = COLOR_TEAM2;
1012                                 break;
1013                         case 3:
1014                                 if(c0 > c3)
1015                                         destteam = COLOR_TEAM3;
1016                                 break;
1017                         case 4:
1018                                 if(c0 > c4)
1019                                         destteam = COLOR_TEAM4;
1020                                 break;
1021                 }
1022                 if(destteam == -1)
1023                         return;
1024         }
1025         if(destteam == self.team && !self.killindicator)
1026                 return;
1027         ClientKill_TeamChange(destteam);
1028 }
1029
1030 void FixClientCvars(entity e)
1031 {
1032         // send prediction settings to the client
1033         stuffcmd(e, "\nin_bindmap 0 0\n");
1034         /*
1035          * we no longer need to stuff this. Remove this comment block if you feel
1036          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1037         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1038         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1039         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1040         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1041         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1042         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1043         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1044         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1045         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1046         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1047         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1048         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1049         stuffcmd(e, "cl_movement_edgefriction 1\n");
1050          */
1051 }
1052
1053 .float fog_set;
1054 void SendFog()
1055 {
1056         if(clienttype(self) == CLIENTTYPE_REAL)
1057         if(world.fog) // NOT string_null!
1058         {
1059                 if(!self.fog_set)
1060                 {
1061                         if(sv_foginterval)
1062                         {
1063                                 msg_entity = self;
1064                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1065                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1066                                 WriteCoord(MSG_ONE, sv_foginterval);
1067                                 WriteString(MSG_ONE, world.fog);
1068                         }
1069                         else
1070                                 // set it once
1071                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1072
1073                         self.fog_set = 1;
1074                 }
1075         }
1076 }
1077
1078 /*
1079 =============
1080 ClientConnect
1081
1082 Called when a client connects to the server
1083 =============
1084 */
1085 //void ctf_clientconnect();
1086 string ColoredTeamName(float t);
1087 void DecodeLevelParms (void);
1088 //void dom_player_join_team(entity pl);
1089 void ClientConnect (void)
1090 {
1091         local string s;
1092
1093         if(self.flags & FL_CLIENT)
1094         {
1095                 print("Warning: ClientConnect, but already connected!\n");
1096                 return;
1097         }
1098
1099         if(Ban_MaybeEnforceBan(self))
1100                 return;
1101
1102         DecodeLevelParms();
1103
1104         self.classname = "player_joining";
1105
1106         self.flags = self.flags | FL_CLIENT;
1107         self.version_nagtime = time + 10 + random() * 10;
1108
1109         if(player_count<0)
1110         {
1111                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1112                 player_count = 0;
1113         }
1114
1115         PlayerScore_Attach(self);
1116
1117         bot_clientconnect();
1118
1119         race_PreSpawnObserver();
1120
1121         //if(g_domination)
1122         //      dom_player_join_team(self);
1123
1124         //JoinBestTeam(self, FALSE, FALSE);
1125         //
1126         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1127                 self.classname = "observer";
1128         } else {
1129                 self.classname = "player";
1130                 campaign_bots_may_start = 1;
1131         }
1132
1133         self.playerid = (playerid_last = playerid_last + 1);
1134         if(cvar("sv_eventlog"))
1135         {
1136                 if(clienttype(self) == CLIENTTYPE_REAL)
1137                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1138                 else
1139                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1140                 s = strcat(":team:", ftos(self.playerid), ":");
1141                 s = strcat(s, ftos(self.team));
1142                 GameLogEcho(s);
1143         }
1144         self.netname_previous = strzone(self.netname);
1145
1146         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1147
1148         bprint ("^4",self.netname);
1149         bprint ("^4 connected");
1150
1151         if(g_domination || g_ctf)
1152         {
1153                 bprint(" and joined the ");
1154                 bprint(ColoredTeamName(self.team));
1155         }
1156
1157         bprint("\n");
1158
1159         self.welcomemessage_time = 0;
1160
1161         stuffcmd(self, strcat(clientstuff, "\n"));
1162         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1163         stuffcmd(self, "cl_particles_reloadeffects\n");
1164
1165         FixClientCvars(self);
1166
1167         // spawnfunc_waypoint sprites
1168         WaypointSprite_InitClient(self);
1169
1170         // Wazat's grappling hook
1171         SetGrappleHookBindings();
1172
1173         // get autoswitch state from player when he toggles it
1174         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1175
1176         // get version info from player
1177         stuffcmd(self, "cmd clientversion $gameversion\n");
1178
1179         // get other cvars from player
1180         GetCvars(0);
1181
1182         // set cvar for team scoreboard
1183         if (teams_matter)
1184         {
1185                 local float t;
1186                 t = cvar("teamplay");
1187                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1188                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1189         }
1190         else
1191                 stuffcmd(self, "set teamplay 0\n");
1192
1193         // notify about available teams
1194         if(teamplay)
1195         {
1196                 CheckAllowedTeams(self);
1197                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1198                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1199         }
1200         else
1201                 stuffcmd(self, "set _teams_available 0\n");
1202
1203         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1204
1205         if(g_arena)
1206         {
1207                 self.classname = "observer";
1208                 Spawnqueue_Insert(self);
1209         }
1210         /*else if(g_ctf)
1211         {
1212                 ctf_clientconnect();
1213         }*/
1214
1215         if(teams_matter)
1216                 attach_entcs();
1217
1218         bot_relinkplayerlist();
1219
1220         self.spectatortime = time;
1221         if(blockSpectators)
1222         {
1223                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1224         }
1225
1226         self.jointime = time;
1227         self.allowedTimeouts = cvar("sv_timeout_number");
1228
1229         if(clienttype(self) == CLIENTTYPE_REAL)
1230         {
1231                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1232                 SendCSQCInfo();
1233                 msg_entity = self;
1234                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1235                 {
1236                         MapVote_SendData(MSG_ONE);
1237                         MapVote_UpdateData(MSG_ONE);
1238                 }
1239                 ScoreInfo_Write(MSG_ONE);
1240         }
1241
1242         if(inWarmupStage)
1243         {
1244                 msg_entity = self;
1245                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1246                 WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1247                 WriteByte(MSG_ONE, 1);
1248         }
1249
1250         if(g_lms)
1251         {
1252                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1253                 {
1254                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1255                         self.frags = -666; // FIXME do we still need this?
1256                 }
1257         }
1258
1259         SendFog();
1260 }
1261
1262 /*
1263 =============
1264 ClientDisconnect
1265
1266 Called when a client disconnects from the server
1267 =============
1268 */
1269 .entity chatbubbleentity;
1270 .entity teambubbleentity;
1271 void ReadyCount();
1272 //void() ctf_clientdisconnect;
1273 void ClientDisconnect (void)
1274 {
1275         float save;
1276
1277         if not(self.flags & FL_CLIENT)
1278         {
1279                 print("Warning: ClientDisconnect without ClientConnect\n");
1280                 return;
1281         }
1282
1283         bot_clientdisconnect();
1284
1285         if(teams_matter)
1286                 detach_entcs();
1287
1288         if(cvar("sv_eventlog"))
1289                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1290         bprint ("^4",self.netname);
1291         bprint ("^4 disconnected\n");
1292
1293         if (self.chatbubbleentity)
1294         {
1295                 remove (self.chatbubbleentity);
1296                 self.chatbubbleentity = world;
1297         }
1298
1299         if (self.teambubbleentity)
1300         {
1301                 remove (self.teambubbleentity);
1302                 self.teambubbleentity = world;
1303         }
1304
1305         if (self.killindicator)
1306         {
1307                 remove (self.killindicator);
1308                 self.killindicator = world;
1309         }
1310
1311         DropAllRunes(self);
1312         kh_Key_DropAll(self, TRUE);
1313
1314         Portal_ClearAll(self);
1315
1316         if(self.flagcarried)
1317                 DropFlag(self.flagcarried, world, world);
1318
1319         WaypointSprite_PlayerGone();
1320
1321         save = self.flags;
1322         self.flags = self.flags - (self.flags & FL_CLIENT);
1323         bot_relinkplayerlist();
1324         self.flags = save;
1325
1326         // remove laserdot
1327         if(self.weaponentity)
1328                 if(self.weaponentity.lasertarget)
1329                         remove(self.weaponentity.lasertarget);
1330
1331         if(g_arena)
1332         {
1333                 Spawnqueue_Unmark(self);
1334                 Spawnqueue_Remove(self);
1335         }
1336         /*if(g_ctf)
1337         {
1338                 ctf_clientdisconnect();
1339         }
1340         */
1341
1342         PlayerScore_Detach(self);
1343
1344         if(self.netname_previous)
1345                 strunzone(self.netname_previous);
1346
1347         ClearPlayerSounds();
1348
1349         // free cvars
1350         GetCvars(-1);
1351         self.playerid = 0;
1352
1353         ReadyCount();
1354 }
1355
1356 .float BUTTON_CHAT;
1357 void ChatBubbleThink()
1358 {
1359         self.nextthink = time;
1360         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1361         {
1362                 self.owner.chatbubbleentity = world;
1363                 remove(self);
1364                 return;
1365         }
1366         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1367         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1368                 self.model = self.mdl;
1369         else
1370                 self.model = "";
1371 };
1372
1373 void UpdateChatBubble()
1374 {
1375         if (!self.modelindex)
1376                 return;
1377         // spawn a chatbubble entity if needed
1378         if (!self.chatbubbleentity)
1379         {
1380                 self.chatbubbleentity = spawn();
1381                 self.chatbubbleentity.owner = self;
1382                 self.chatbubbleentity.exteriormodeltoclient = self;
1383                 self.chatbubbleentity.think = ChatBubbleThink;
1384                 self.chatbubbleentity.nextthink = time;
1385                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1386                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1387                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1388                 self.chatbubbleentity.model = "";
1389                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1390         }
1391 }
1392
1393
1394 void TeamBubbleThink()
1395 {
1396         self.nextthink = time;
1397         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1398         {
1399                 self.owner.teambubbleentity = world;
1400                 remove(self);
1401                 return;
1402         }
1403 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1404         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1405                 self.model = "";
1406         else
1407                 self.model = self.mdl;
1408
1409 };
1410
1411 float TeamBubble_customizeentityforclient()
1412 {
1413         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1414 }
1415
1416 void UpdateTeamBubble()
1417 {
1418         if (!self.modelindex || !cvar("teamplay"))
1419                 return;
1420         // spawn a teambubble entity if needed
1421         if (!self.teambubbleentity && cvar("teamplay"))
1422         {
1423                 self.teambubbleentity = spawn();
1424                 self.teambubbleentity.owner = self;
1425                 self.teambubbleentity.exteriormodeltoclient = self;
1426                 self.teambubbleentity.think = TeamBubbleThink;
1427                 self.teambubbleentity.nextthink = time;
1428                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1429 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1430                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1431                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1432                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1433                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1434                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1435                 self.teambubbleentity.effects = EF_LOWPRECISION;
1436         }
1437 }
1438
1439 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1440 // added to the model skins
1441 /*void UpdateColorModHack()
1442 {
1443         local float c;
1444         c = self.clientcolors & 15;
1445         // LordHavoc: only bothering to support white, green, red, yellow, blue
1446              if (teamplay == 0) self.colormod = '0 0 0';
1447         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1448         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1449         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1450         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1451         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1452         else self.colormod = '1 1 1';
1453 };*/
1454
1455 void respawn(void)
1456 {
1457         CopyBody(1);
1458         self.effects |= EF_NODRAW; // prevent another CopyBody
1459         PutClientInServer();
1460 }
1461
1462 /**
1463  * When sv_timeout is used this function returs strings like
1464  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1465  * Called by centerprint functions
1466  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1467  */
1468 string getTimeoutText(float addOneSecond) {
1469         if (!cvar("sv_timeout") || !timeoutStatus)
1470                 return "";
1471
1472         local string retStr;
1473         if (timeoutStatus == 1) {
1474                 if (addOneSecond == 1) {
1475                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1476                 }
1477                 else {
1478                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1479                 }
1480                 return retStr;
1481         }
1482         else if (timeoutStatus == 2) {
1483                 if (addOneSecond) {
1484                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1485                         //don't show messages like "Timeout ends in 0 seconds"...
1486                         if ((remainingTimeoutTime + 1) > 0)
1487                                 return retStr;
1488                         else
1489                                 return "";
1490                 }
1491                 else {
1492                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1493                         //don't show messages like "Timeout ends in 0 seconds"...
1494                         if (remainingTimeoutTime > 0)
1495                                 return retStr;
1496                         else
1497                                 return "";
1498                 }
1499         }
1500         else return "";
1501 }
1502
1503 void player_powerups (void)
1504 {
1505         if (g_minstagib)
1506         {
1507                 if (self.items & IT_STRENGTH)
1508                 {
1509                         if (time > self.strength_finished)
1510                         {
1511                                 if (g_minstagib_invis_alpha > 0)
1512                                 {
1513                                         self.alpha = default_player_alpha;
1514                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1515                                         self.effects = self.effects | EF_FULLBRIGHT;
1516                                 }
1517                                 else
1518                                 {
1519                                         self.effects -= self.effects & EF_NODRAW;
1520                                 }
1521                                 self.items = self.items - (self.items & IT_STRENGTH);
1522                                 sprint(self, "^3Invisibility has worn off\n");
1523                         }
1524                 }
1525                 else
1526                 {
1527                         if (time < self.strength_finished)
1528                         {
1529                                 if (g_minstagib_invis_alpha > 0)
1530                                 {
1531                                         self.alpha = g_minstagib_invis_alpha;
1532                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1533                                         self.effects -= self.effects & EF_FULLBRIGHT;
1534                                 }
1535                                 else
1536                                 {
1537                                         self.effects = self.effects | EF_NODRAW;
1538                                 }
1539                                 self.items = self.items | IT_STRENGTH;
1540                                 sprint(self, "^3You are invisible\n");
1541                         }
1542                 }
1543
1544                 if (self.items & IT_INVINCIBLE)
1545                 {
1546                         if (time > self.invincible_finished)
1547                         {
1548                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1549                                 sprint(self, "^3Speed has worn off\n");
1550                         }
1551                 }
1552                 else
1553                 {
1554                         if (time < self.invincible_finished)
1555                         {
1556                                 self.items = self.items | IT_INVINCIBLE;
1557                                 sprint(self, "^3You are on speed\n");
1558                         }
1559                 }
1560                 return;
1561         }
1562
1563         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1564         if (self.items & IT_STRENGTH)
1565         {
1566                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1567                 if (time > self.strength_finished)
1568                 {
1569                         self.items = self.items - (self.items & IT_STRENGTH);
1570                         sprint(self, "^3Strength has worn off\n");
1571                 }
1572         }
1573         else
1574         {
1575                 if (time < self.strength_finished)
1576                 {
1577                         self.items = self.items | IT_STRENGTH;
1578                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1579                 }
1580         }
1581         if (self.items & IT_INVINCIBLE)
1582         {
1583                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1584                 if (time > self.invincible_finished)
1585                 {
1586                         self.items = self.items - (self.items & IT_INVINCIBLE);
1587                         sprint(self, "^3Shield has worn off\n");
1588                 }
1589         }
1590         else
1591         {
1592                 if (time < self.invincible_finished)
1593                 {
1594                         self.items = self.items | IT_INVINCIBLE;
1595                         sprint(self, "^3Shield surrounds you\n");
1596                 }
1597         }
1598
1599         if (cvar("g_fullbrightplayers"))
1600                 self.effects = self.effects | EF_FULLBRIGHT;
1601
1602         // midair gamemode: damage only while in the air
1603         // if in midair mode, being on ground grants temporary invulnerability
1604         // (this is so that multishot weapon don't clear the ground flag on the
1605         // first damage in the frame, leaving the player vulnerable to the
1606         // remaining hits in the same frame)
1607         if (self.flags & FL_ONGROUND)
1608         if (g_midair)
1609                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1610
1611         if (time >= game_starttime)
1612         if (time < self.spawnshieldtime)
1613                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1614 }
1615
1616 float CalcRegen(float current, float stable, float regenfactor)
1617 {
1618         if(current > stable)
1619                 return current;
1620         else if(current > stable - 0.25) // when close enough, "snap"
1621                 return stable;
1622         else
1623                 return min(stable, current + (stable - current) * regenfactor * frametime);
1624 }
1625
1626 void player_regen (void)
1627 {
1628         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1629         maxh = cvar("g_balance_health_stable");
1630         maxa = cvar("g_balance_armor_stable");
1631         limith = cvar("g_balance_health_limit");
1632         limita = cvar("g_balance_armor_limit");
1633
1634         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1635                 return;
1636
1637         max_mod = regen_mod = rot_mod = limit_mod = 1;
1638
1639         if (self.runes & RUNE_REGEN)
1640         {
1641                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1642                 {
1643                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1644                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1645                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1646                 }
1647                 else
1648                 {
1649                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1650                         max_mod = cvar("g_balance_rune_regen_hpmod");
1651                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1652                 }
1653         }
1654         else if (self.runes & CURSE_VENOM)
1655         {
1656                 max_mod = cvar("g_balance_curse_venom_hpmod");
1657                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1658                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1659                 else
1660                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1661                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1662                 //if (!self.runes & RUNE_REGEN)
1663                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1664         }
1665         maxh = maxh * max_mod;
1666         //maxa = maxa * max_mod;
1667         limith = limith * limit_mod;
1668         limita = limita * limit_mod;
1669
1670         if (self.armorvalue > maxa)
1671         {
1672                 if (time > self.pauserotarmor_finished)
1673                 {
1674                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1675                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1676                 }
1677         }
1678         else if (self.armorvalue < maxa)
1679         {
1680                 if (time > self.pauseregen_finished)
1681                 {
1682                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1683                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1684                 }
1685         }
1686         if (self.health > maxh)
1687         {
1688                 if (time > self.pauserothealth_finished)
1689                 {
1690                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1691                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1692                 }
1693         }
1694         else if (self.health < maxh)
1695         {
1696                 if (time > self.pauseregen_finished)
1697                 {
1698                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1699                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1700                 }
1701         }
1702
1703         if (self.health > limith)
1704                 self.health = limith;
1705         if (self.armorvalue > limita)
1706                 self.armorvalue = limita;
1707
1708         // if player rotted to death...  die!
1709         if(self.health < 1)
1710                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1711 }
1712
1713 .float zoomstate;
1714 float zoomstate_set;
1715 void SetZoomState(float z)
1716 {
1717         if(z != self.zoomstate)
1718         {
1719                 msg_entity = self;
1720                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1721                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1722                 WriteByte(MSG_ONE, z);
1723                 self.zoomstate = z;
1724         }
1725         zoomstate_set = 1;
1726 }
1727
1728 /*
1729 ======================
1730 spectate mode routines
1731 ======================
1732 */
1733 void SpectateCopy(entity spectatee) {
1734         self.armortype = spectatee.armortype;
1735         self.armorvalue = spectatee.armorvalue;
1736         self.currentammo = spectatee.currentammo;
1737         self.effects = spectatee.effects;
1738         self.health = spectatee.health;
1739         self.impulse = 0;
1740         self.items = spectatee.items;
1741         self.weapons = spectatee.weapons;
1742         self.switchweapon = spectatee.switchweapon;
1743         self.weapon = spectatee.weapon;
1744         self.punchangle = spectatee.punchangle;
1745         self.view_ofs = spectatee.view_ofs;
1746         self.v_angle = spectatee.v_angle;
1747         self.velocity = spectatee.velocity;
1748         self.dmg_take = spectatee.dmg_take;
1749         self.dmg_save = spectatee.dmg_save;
1750         self.dmg_inflictor = spectatee.dmg_inflictor;
1751         self.angles = spectatee.v_angle;
1752         self.fixangle = TRUE;
1753         setorigin(self, spectatee.origin);
1754         setsize(self, spectatee.mins, spectatee.maxs);
1755         SetZoomState(spectatee.zoomstate);
1756 }
1757
1758 float SpectateUpdate() {
1759         if(!self.enemy)
1760                 return 0;
1761
1762         if (self == self.enemy)
1763                 return 0;
1764
1765         if(self.enemy.flags & FL_NOTARGET)
1766                 return 0;
1767
1768         SpectateCopy(self.enemy);
1769
1770         return 1;
1771 }
1772
1773 float SpectateNext() {
1774         other = find(self.enemy, classname, "player");
1775         if (!other) {
1776                 other = find(other, classname, "player");
1777         }
1778         if (other) {
1779                 self.enemy = other;
1780         }
1781         if(self.enemy.classname == "player") {
1782                 msg_entity = self;
1783                 WriteByte(MSG_ONE, SVC_SETVIEW);
1784                 WriteEntity(MSG_ONE, self.enemy);
1785                 self.wantswelcomemessage = 1;
1786                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1787                 if(!SpectateUpdate())
1788                         PutObserverInServer();
1789                 return 1;
1790         } else {
1791                 return 0;
1792         }
1793 }
1794
1795 /*
1796 =============
1797 ShowRespawnCountdown()
1798
1799 Update a respawn countdown display.
1800 =============
1801 */
1802 void ShowRespawnCountdown()
1803 {
1804         float number;
1805         if(self.deadflag == DEAD_NO) // just respawned?
1806                 return;
1807         else
1808         {
1809                 number = ceil(self.death_time - time);
1810                 if(number <= 0)
1811                         return;
1812                 if(number <= self.respawn_countdown)
1813                 {
1814                         self.respawn_countdown = number - 1;
1815                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1816                                 announce(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1817                 }
1818         }
1819 }
1820
1821 void LeaveSpectatorMode()
1822 {
1823         if(isJoinAllowed()) {
1824                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1825                         self.classname = "player";
1826                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1827                                 JoinBestTeam(self, FALSE, TRUE);
1828                         if(cvar("g_campaign"))
1829                                 campaign_bots_may_start = 1;
1830                         PutClientInServer();
1831                         if(!(self.flags & FL_NOTARGET))
1832                                 bprint ("^4", self.netname, "^4 is playing now\n");
1833                         centerprint(self,"");
1834                         return;
1835                 } else {
1836                         stuffcmd(self,"menu_showteamselect\n");
1837                         return;
1838                 }
1839         }
1840         else {
1841                 //player may not join because of g_maxplayers is set
1842                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1843         }
1844 }
1845
1846 /**
1847  * Determines whether the player is allowed to join. This depends on cvar
1848  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1849  * it checks whether the number of currently playing players exceeds g_maxplayers.
1850  * @return bool TRUE if the player is allowed to join, false otherwise
1851  */
1852 float isJoinAllowed() {
1853         if (!cvar("g_maxplayers"))
1854                 return TRUE;
1855
1856         local entity e;
1857         local float currentlyPlaying;
1858         FOR_EACH_REALPLAYER(e) {
1859                 if(e.classname == "player")
1860                         currentlyPlaying += 1;
1861         }
1862         if(currentlyPlaying < cvar("g_maxplayers"))
1863                 return TRUE;
1864
1865         return FALSE;
1866 }
1867
1868 /**
1869  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1870  * g_maxplayers_spectator_blocktime seconds
1871  */
1872 void checkSpectatorBlock() {
1873         if(self.classname == "spectator" || self.classname == "observer") {
1874                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1875                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1876                         dropclient(self);
1877                 }
1878         }
1879 }
1880
1881 float vercmp_recursive(string v1, string v2)
1882 {
1883         float dot1, dot2;
1884         string s1, s2;
1885         float r;
1886
1887         dot1 = strstrofs(v1, ".", 0);
1888         dot2 = strstrofs(v2, ".", 0);
1889         if(dot1 == -1)
1890                 s1 = v1;
1891         else
1892                 s1 = substring(v1, 0, dot1);
1893         if(dot2 == -1)
1894                 s2 = v2;
1895         else
1896                 s2 = substring(v2, 0, dot2);
1897
1898         r = stof(s1) - stof(s2);
1899         if(r != 0)
1900                 return r;
1901
1902         r = strcasecmp(s1, s2);
1903         if(r != 0)
1904                 return r;
1905
1906         if(dot1 == -1)
1907                 if(dot2 == -1)
1908                         return 0;
1909                 else
1910                         return -1;
1911         else
1912                 if(dot2 == -1)
1913                         return 1;
1914                 else
1915                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1916 }
1917
1918 float vercmp(string v1, string v2)
1919 {
1920         if(strcasecmp(v1, v2) == 0) // early out check
1921                 return 0;
1922         return vercmp_recursive(v1, v2);
1923 }
1924
1925 void ObserverThink()
1926 {
1927         if (self.flags & FL_JUMPRELEASED) {
1928                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1929                         self.welcomemessage_time = 0;
1930                         self.flags = self.flags - FL_JUMPRELEASED;
1931                         LeaveSpectatorMode();
1932                         return;
1933                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1934                         self.welcomemessage_time = 0;
1935                         self.flags = self.flags - FL_JUMPRELEASED;
1936                         if(SpectateNext() == 1) {
1937                                 self.classname = "spectator";
1938                         }
1939                 }
1940         } else {
1941                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1942                         self.flags = self.flags | FL_JUMPRELEASED;
1943                 }
1944         }
1945         /*
1946         if(self.BUTTON_ZOOM)
1947                 self.wantswelcomemessage = 0;
1948         */
1949         if(self.wantswelcomemessage)
1950                 PrintWelcomeMessage(self);
1951 }
1952
1953 void SpectatorThink()
1954 {
1955         if (self.flags & FL_JUMPRELEASED) {
1956                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1957                         self.welcomemessage_time = 0;
1958                         self.flags = self.flags - FL_JUMPRELEASED;
1959                         LeaveSpectatorMode();
1960                         return;
1961                 } else if(self.BUTTON_ATCK) {
1962                         self.welcomemessage_time = 0;
1963                         self.flags = self.flags - FL_JUMPRELEASED;
1964                         if(SpectateNext() == 1) {
1965                                 self.classname = "spectator";
1966                         } else {
1967                                 self.classname = "observer";
1968                                 PutClientInServer();
1969                         }
1970                 } else if (self.BUTTON_ATCK2) {
1971                         self.welcomemessage_time = 0;
1972                         self.flags = self.flags - FL_JUMPRELEASED;
1973                         self.classname = "observer";
1974                         PutClientInServer();
1975                 } else {
1976                         if(!SpectateUpdate())
1977                                 PutObserverInServer();
1978                 }
1979         } else {
1980                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1981                         self.flags = self.flags | FL_JUMPRELEASED;
1982                 }
1983         }
1984         /*
1985         if(self.BUTTON_ZOOM)
1986                 self.wantswelcomemessage = 0;
1987         */
1988         if(self.wantswelcomemessage)
1989                 PrintWelcomeMessage(self);
1990         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1991 }
1992
1993 /*
1994 =============
1995 PlayerPreThink
1996
1997 Called every frame for each client before the physics are run
1998 =============
1999 */
2000 void() ctf_setstatus;
2001 .float spectatee_status;
2002 void PlayerPreThink (void)
2003 {
2004         self.stat_sys_ticrate = cvar("sys_ticrate");
2005         self.stat_game_starttime = game_starttime;
2006
2007         if(blockSpectators)
2008                 checkSpectatorBlock();
2009
2010         zoomstate_set = 0;
2011
2012         if(self.netname_previous != self.netname)
2013         {
2014                 if(cvar("sv_eventlog"))
2015                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2016                 if(self.netname_previous)
2017                         strunzone(self.netname_previous);
2018                 self.netname_previous = strzone(self.netname);
2019         }
2020
2021         // version nagging
2022         if(self.version_nagtime)
2023                 if(self.cvar_g_nexuizversion)
2024                         if(time > self.version_nagtime)
2025                         {
2026                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2027                                 {
2028                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2029                                         {
2030                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2031                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2032                                         }
2033                                         else
2034                                         {
2035                                                 float r;
2036                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2037                                                 if(r < 0)
2038                                                 {
2039                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2040                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2041                                                 }
2042                                                 else if(r > 0)
2043                                                 {
2044                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2045                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2046                                                 }
2047                                         }
2048                                 }
2049                                 self.version_nagtime = 0;
2050                         }
2051
2052         // GOD MODE info
2053         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2054         {
2055                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2056                 self.max_armorvalue = 0;
2057         }
2058
2059         if(frametime)
2060         {
2061                 SendFog();
2062                 antilag_record(self);
2063         }
2064
2065         if(self.classname == "player") {
2066 //              if(self.netname == "Wazat")
2067 //                      bprint(self.classname, "\n");
2068
2069                 CheckRules_Player();
2070
2071                 if(self.BUTTON_INFO)
2072                         PrintWelcomeMessage(self);
2073
2074                 if(g_lms || !cvar("sv_spectate"))
2075                 if((time - self.jointime) <= cvar("welcome_message_time"))
2076                         PrintWelcomeMessage(self);
2077
2078                 if (intermission_running)
2079                 {
2080                         IntermissionThink ();   // otherwise a button could be missed between
2081                         return;                                 // the think tics
2082                 }
2083
2084                 if(self.teleport_time)
2085                 if(time > self.teleport_time)
2086                 {
2087                         self.teleport_time = 0;
2088                         self.effects = self.effects - (self.effects & EF_NODRAW);
2089                         if(self.weaponentity)
2090                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2091                 }
2092
2093                 Nixnex_GiveCurrentWeapon();
2094
2095                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2096                         UpdateSelectedPlayer();
2097
2098                 //don't allow the player to turn around while game is paused!
2099                 if(timeoutStatus == 2) {
2100                         self.v_angle = self.lastV_angle;
2101                         self.angles = self.lastV_angle;
2102                         self.fixangle = TRUE;
2103                 }
2104
2105                 if (self.deadflag != DEAD_NO)
2106                 {
2107                         float button_pressed, force_respawn;
2108                         player_anim();
2109                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2110                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2111                         if (self.deadflag == DEAD_DYING)
2112                         {
2113                                 if(force_respawn)
2114                                         self.deadflag = DEAD_RESPAWNING;
2115                                 else if(!button_pressed)
2116                                         self.deadflag = DEAD_DEAD;
2117                         }
2118                         else if (self.deadflag == DEAD_DEAD)
2119                         {
2120                                 if(button_pressed)
2121                                         self.deadflag = DEAD_RESPAWNABLE;
2122                         }
2123                         else if (self.deadflag == DEAD_RESPAWNABLE)
2124                         {
2125                                 if(!button_pressed)
2126                                         self.deadflag = DEAD_RESPAWNING;
2127                         }
2128                         else if (self.deadflag == DEAD_RESPAWNING)
2129                         {
2130                                 if(time > self.death_time)
2131                                 {
2132                                         self.death_time = time + 1; // only retry once a second
2133                                         respawn();
2134                                 }
2135                         }
2136                         ShowRespawnCountdown();
2137                         return;
2138                 }
2139
2140                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2141                 {
2142                         vector dist;
2143
2144                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2145                         dist = self.oldorigin - self.origin;
2146                         dist_z = 0;
2147                         self.lms_traveled_distance += fabs(vlen(dist));
2148
2149                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2150                         {
2151                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2152                                 self.lms_traveled_distance = 0;
2153                         }
2154
2155                         if(time > self.lms_nextcheck)
2156                         {
2157                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2158                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2159                                 {
2160                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2161                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2162                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2163                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2164                                 }
2165                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2166                                 self.lms_traveled_distance = 0;
2167                         }
2168                 }
2169
2170                 if (self.BUTTON_CROUCH && !self.hook.state)
2171                 {
2172                         if (!self.crouch)
2173                         {
2174                                 self.crouch = TRUE;
2175                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2176                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2177                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2178                         }
2179                 }
2180                 else
2181                 {
2182                         if (self.crouch)
2183                         {
2184                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2185                                 if (!trace_startsolid)
2186                                 {
2187                                         self.crouch = FALSE;
2188                                         self.view_ofs = PL_VIEW_OFS;
2189                                         setsize (self, PL_MIN, PL_MAX);
2190                                 }
2191                         }
2192                 }
2193
2194                 FixPlayermodel();
2195
2196                 GrapplingHookFrame();
2197
2198                 W_WeaponFrame();
2199
2200                 player_powerups();
2201                 player_regen();
2202                 player_anim();
2203
2204                 if (g_minstagib)
2205                         minstagib_ammocheck();
2206
2207                 ctf_setstatus();
2208                 kh_setstatus();
2209
2210                 //self.angles_y=self.v_angle_y + 90;   // temp
2211
2212                 //if (TetrisPreFrame()) return;
2213         } else if(gameover) {
2214                 if (intermission_running)
2215                         IntermissionThink ();   // otherwise a button could be missed between
2216                 return;
2217         } else if(self.classname == "observer") {
2218                 ObserverThink();
2219         } else if(self.classname == "spectator") {
2220                 SpectatorThink();
2221         }
2222
2223         if(!zoomstate_set)
2224                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2225
2226         float oldspectatee_status;
2227         oldspectatee_status = self.spectatee_status;
2228         if(self.classname == "spectator")
2229                 self.spectatee_status = num_for_edict(self.enemy);
2230         else if(self.classname == "observer")
2231                 self.spectatee_status = num_for_edict(self);
2232         else
2233                 self.spectatee_status = 0;
2234         if(self.spectatee_status != oldspectatee_status)
2235         {
2236                 msg_entity = self;
2237                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2238                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2239                 WriteByte(MSG_ONE, self.spectatee_status);
2240                 if(g_race)
2241                         race_InitSpectator();
2242         }
2243
2244         if(self.teamkill_soundtime)
2245         if(time > self.teamkill_soundtime)
2246         {
2247                 self.teamkill_soundtime = 0;
2248
2249                 entity oldpusher, oldself;
2250
2251                 oldself = self; self = self.teamkill_soundsource;
2252                 oldpusher = self.pusher; self.pusher = oldself;
2253
2254                 VoiceMessage("teamshoot_auto");
2255
2256                 self.pusher = oldpusher;
2257                 self = oldself;
2258         }
2259 }
2260
2261
2262 /*
2263 =============
2264 PlayerPostThink
2265
2266 Called every frame for each client after the physics are run
2267 =============
2268 */
2269 .float idlekick_lasttimeleft;
2270 .float race_penalty;
2271 .float race_penalty_nagged;
2272 .float race_penalty_nagtime;
2273 void PlayerPostThink (void)
2274 {
2275         // Savage: Check for nameless players
2276         if (strlen(self.netname) < 1) {
2277                 self.netname = "Player";
2278                 stuffcmd(self, "seta _cl_name Player\n");
2279         }
2280
2281         if(sv_maxidle)
2282         {
2283                 float timeleft;
2284                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2285                 if(timeleft <= 0)
2286                 {
2287                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2288                         announce(self, "announcer/robotic/terminated.ogg");
2289                         dropclient(self);
2290                         return;
2291                 }
2292                 else if(timeleft <= 10)
2293                 {
2294                         if(timeleft != self.idlekick_lasttimeleft)
2295                         {
2296                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2297                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2298                         }
2299                 }
2300                 else
2301                 {
2302                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2303                 }
2304                 self.idlekick_lasttimeleft = timeleft;
2305         }
2306
2307         if(self.classname == "player") {
2308                 CheckRules_Player();
2309                 UpdateChatBubble();
2310                 UpdateTeamBubble();
2311                 if (self.impulse)
2312                         ImpulseCommands();
2313                 if (intermission_running)
2314                         return;         // intermission or finale
2315
2316                 //PrintWelcomeMessage(self);
2317                 //if (TetrisPostFrame()) return;
2318
2319                 // restart countdown
2320                         if(time < game_starttime) {
2321                                 if (!cvar("sv_ready_restart_after_countdown"))
2322                                 {
2323                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2324                                         {
2325                                                 if(time < game_starttime - 2)
2326                                                 {
2327                                                         if(!self.race_penalty_nagged)
2328                                                         {
2329                                                                 // TODO better notification for this!
2330                                                                 self.race_penalty_nagtime = 0;
2331                                                                 self.race_penalty_nagged = 1;
2332                                                         }
2333                                                 }
2334                                                 else if(!self.race_penalty)
2335                                                 {
2336                                                         self.race_penalty_nagtime = 0;
2337                                                         self.race_penalty = time + 5;
2338                                                 }
2339                                         }
2340                                         if(time > self.race_penalty_nagtime)
2341                                         {
2342                                                 if(self.race_penalty > time)
2343                                                 {
2344                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2345                                                 }
2346                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2347                                                 {
2348                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2349                                                 }
2350                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2351                                         }
2352                                         self.movetype = MOVETYPE_NONE;
2353                                         self.velocity = '0 0 0';
2354                                         self.avelocity = '0 0 0';
2355                                         self.movement = '0 0 0';
2356                                 }
2357                         }
2358                         else if (time < self.race_penalty)
2359                         {
2360                                 self.movetype = MOVETYPE_NONE;
2361                                 self.velocity = '0 0 0';
2362                                 self.avelocity = '0 0 0';
2363                                 self.movement = '0 0 0';
2364                         }
2365                         else
2366                         {
2367                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2368                                 if (!cvar("sv_ready_restart_after_countdown"))
2369                                 {
2370                                         if(self.movetype == MOVETYPE_NONE)
2371                                         {
2372                                                 self.movetype = MOVETYPE_WALK;
2373                                         }
2374                                         self.race_penalty = 0;
2375                                         self.race_penalty_nagged = 0;
2376                                 }
2377                         }
2378
2379         } else if (self.classname == "observer") {
2380                 //do nothing
2381         } else if (self.classname == "spectator") {
2382                 //do nothing
2383         }
2384
2385         /*
2386         float i;
2387         for(i = 0; i < 1000; ++i)
2388         {
2389                 vector end;
2390                 end = self.origin + '0 0 1024' + 512 * randomvec();
2391                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2392                 if(trace_fraction < 1)
2393                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2394                 {
2395                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2396                         break;
2397                 }
2398         }
2399         */
2400
2401         Arena_Warmup();
2402
2403         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2404 }