data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         DistributeFragsAmongTeam(self, self.team, 1);
 294
 295         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 297         else if(self.killcount != -666)
 298                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 299
 300         self.classname = "observer";
 301         self.health = -666;
 302         self.takedamage = DAMAGE_NO;
 303         self.solid = SOLID_NOT;
 304         self.movetype = MOVETYPE_NOCLIP;
 305         self.flags = FL_CLIENT | FL_NOTARGET;
 306         self.armorvalue = 666;
 307         self.effects = 0;
 308         self.armorvalue = cvar("g_balance_armor_start");
 309         self.pauserotarmor_finished = 0;
 310         self.pauserothealth_finished = 0;
 311         self.pauseregen_finished = 0;
 312         self.damageforcescale = 0;
 313         self.death_time = 0;
 314         self.dead_time = 0;
 315         self.dead_frame = 0;
 316         self.die_frame = 0;
 317         self.deaths = 0;
 318         self.alpha = 0;
 319         self.scale = 0;
 320         self.fade_time = 0;
 321         self.pain_frame = 0;
 322         self.pain_finished = 0;
 323         self.strength_finished = 0;
 324         self.invincible_finished = 0;
 325         self.pushltime = 0;
 326         self.think = SUB_Null;
 327         self.nextthink = 0;
 328         self.hook_time = 0;
 329         self.runes = 0;
 330         self.deadflag = DEAD_NO;
 331         self.angles = spot.angles;
 332         self.angles_z = 0;
 333         self.fixangle = TRUE;
 334         self.crouch = FALSE;
 335
 336         self.view_ofs = PL_VIEW_OFS;
 337         setorigin (self, spot.origin);
 338         setsize (self, '0 0 0', '0 0 0');
 339         self.oldorigin = self.origin;
 340         self.items = 0;
 341         self.model = "";
 342         self.modelindex = 0;
 343         self.weapon = 0;
 344         self.weaponmodel = "";
 345         self.weaponentity = world;
 346         self.killcount = -666;
 347         self.velocity = '0 0 0';
 348         self.avelocity = '0 0 0';
 349         self.punchangle = '0 0 0';
 350         self.punchvector = '0 0 0';
 351         self.oldvelocity = self.velocity;
 352         self.customizeentityforclient = Client_customizeentityforclient;
 353
 354         if(cvar("g_arena"))
 355         {
 356                 if(self.frags != -2)
 357                 {
 358                         Spawnqueue_Insert(self);
 359                 }
 360                 else
 361                 {
 362                         Spawnqueue_Unmark(self);
 363                         Spawnqueue_Remove(self);
 364                 }
 365         }
 366         else if(!cvar("g_lms"))
 367                 self.frags = -666;
 368 }
 369
 370
 371 /*
 372 =============
 373 PutClientInServer
 374
 375 Called when a client spawns in the server
 376 =============
 377 */
 378 void PutClientInServer (void)
 379 {
 380         if(clienttype(self) == CLIENTTYPE_BOT)
 381         {
 382                 self.classname = "player";
 383         }
 384         else if(clienttype(self) == CLIENTTYPE_REAL)
 385         {
 386                 msg_entity = self;
 387                 WriteByte(MSG_ONE, SVC_SETVIEW);
 388                 WriteEntity(MSG_ONE, self);
 389         }
 390
 391         // player is dead and becomes observer
 392         if(cvar("g_lms") && self.frags < 1)
 393                 self.classname = "observer";
 394
 395         if(cvar("g_arena"))
 396         if(!self.spawned)
 397                 self.classname = "observer";
 398
 399         if(self.classname == "player") {
 400                 entity  spot;
 401
 402                 spot = SelectSpawnPoint (FALSE);
 403
 404                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406                 self.classname = "player";
 407                 self.iscreature = TRUE;
 408                 self.movetype = MOVETYPE_WALK;
 409                 self.solid = SOLID_SLIDEBOX;
 410                 self.flags = FL_CLIENT;
 411                 self.takedamage = DAMAGE_AIM;
 412                 self.effects = 0;
 413                 self.health = cvar("g_balance_health_start");
 414                 self.armorvalue = cvar("g_balance_armor_start");
 415                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 416                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 417                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 418                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 419                 self.damageforcescale = 2;
 420                 self.death_time = 0;
 421                 self.dead_time = 0;
 422                 self.dead_frame = 0;
 423                 self.die_frame = 0;
 424                 self.alpha = 0;
 425                 self.scale = 0;
 426                 self.fade_time = 0;
 427                 self.pain_frame = 0;
 428                 self.pain_finished = 0;
 429                 self.strength_finished = 0;
 430                 self.invincible_finished = 0;
 431                 self.pushltime = 0;
 432                 //self.speed_finished = 0;
 433                 //self.slowmo_finished = 0;
 434                 // players have no think function
 435                 self.think = SUB_Null;
 436                 self.nextthink = 0;
 437                 self.weapon = 0;
 438                 self.switchweapon = 0;
 439                 self.hook_time = 0;
 440
 441                 self.runes = 0;
 442
 443                 self.deadflag = DEAD_NO;
 444
 445                 self.angles = spot.angles;
 446
 447                 self.angles_z = 0; // never spawn tilted even if the spot says to
 448                 self.fixangle = TRUE; // turn this way immediately
 449                 self.velocity = '0 0 0';
 450                 self.avelocity = '0 0 0';
 451                 self.punchangle = '0 0 0';
 452                 self.punchvector = '0 0 0';
 453                 self.oldvelocity = self.velocity;
 454
 455                 self.viewzoom = 0.6;
 456
 457                 self.customizeentityforclient = Client_customizeentityforclient;
 458
 459                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 460                         local string defaultmodel;
 461                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 462                         setmodel_lod (self, defaultmodel);
 463                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 464                 } else {
 465                         self.playermodel = CheckPlayerModel(self.playermodel);
 466                         setmodel_lod (self, self.playermodel);
 467                         self.skin = stof(self.playerskin);
 468
 469                 }
 470
 471                 self.crouch = FALSE;
 472                 self.view_ofs = PL_VIEW_OFS;
 473                 setsize (self, PL_MIN, PL_MAX);
 474                 self.spawnorigin = spot.origin;
 475                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 476                 // don't reset back to last position, even if new position is stuck in solid
 477                 self.oldorigin = self.origin;
 478
 479                 if(cvar("g_lms"))
 480                 {
 481                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 482                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 483                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 484                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 485                         self.health = cvar("g_lms_start_health");
 486                         self.armorvalue = cvar("g_lms_start_armor");
 487                 }
 488                 else if (cvar("g_use_ammunition")) {
 489                         self.ammo_shells = cvar("g_start_ammo_shells");
 490                         self.ammo_nails = cvar("g_start_ammo_nails");
 491                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 492                         self.ammo_cells = cvar("g_start_ammo_cells");
 493                 } else {
 494                         self.ammo_shells = 999;
 495                         self.ammo_nails = 999;
 496                         self.ammo_rockets = 999;
 497                         self.ammo_cells = 999;
 498                 }
 499
 500                 self.items = 0;
 501                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 502                 {
 503                         self.items = self.items | IT_LASER;
 504                         self.switchweapon = WEP_LASER;
 505                 }
 506                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 507                 {
 508                         self.items = self.items | IT_SHOTGUN;
 509                         self.switchweapon = WEP_SHOTGUN;
 510                 }
 511                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 512                 {
 513                         self.items = self.items | IT_UZI;
 514                         self.switchweapon = WEP_UZI;
 515                 }
 516                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 517                 {
 518                         self.items = self.items | IT_GRENADE_LAUNCHER;
 519                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 520                 }
 521                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 522                 {
 523                         self.items = self.items | IT_ELECTRO;
 524                         self.switchweapon = WEP_ELECTRO;
 525                 }
 526                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 527                 {
 528                         self.items = self.items | IT_CRYLINK;
 529                         self.switchweapon = WEP_CRYLINK;
 530                 }
 531                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 532                 {
 533                         self.items = self.items | IT_NEX;
 534                         self.switchweapon = WEP_NEX;
 535                 }
 536                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 537                 {
 538                         self.items = self.items | IT_HAGAR;
 539                         self.switchweapon = WEP_HAGAR;
 540                 }
 541                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 542                 {
 543                         self.items = self.items | IT_ROCKET_LAUNCHER;
 544                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 545                 }
 546
 547                 if(cvar("g_instagib"))
 548                 {
 549                         self.items = IT_NEX;
 550                         self.switchweapon = WEP_NEX;
 551                         self.ammo_cells = 999;
 552                 }
 553
 554                 if(cvar("g_rocketarena"))
 555                 {
 556                         self.items = IT_ROCKET_LAUNCHER;
 557                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 558                         self.ammo_rockets = 999;
 559                 }
 560
 561                 if(cvar("g_nixnex"))
 562                 {
 563                         self.items = 0;
 564                         // will be done later
 565                 }
 566
 567                 if(cvar("g_minstagib"))
 568                 {
 569                         self.health = 100;
 570                         self.armorvalue = 0;
 571                         self.items = IT_NEX;
 572                         self.switchweapon = WEP_NEX;
 573                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 574                         self.extralives = 0;
 575                         self.jump_interval = time;
 576                 }
 577
 578                 if(cvar("g_arena"))
 579                 {
 580                         Spawnqueue_Remove(self);
 581                         Spawnqueue_Mark(self);
 582                 }
 583
 584                 self.event_damage = PlayerDamage;
 585
 586                 self.bot_attack = TRUE;
 587
 588                 self.statdraintime = time + 5;
 589                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 590
 591                 if(self.killcount == -666) {
 592                         self.killcount = 0;
 593                         if(!cvar("g_arena"))
 594                         if(!cvar("g_lms"))
 595                                 self.frags = 0;
 596                 }
 597
 598                 self.cnt = WEP_LASER;
 599                 self.nixnex_lastchange_id = -1;
 600
 601                 CL_SpawnWeaponentity();
 602                 self.alpha = default_player_alpha;
 603                 self.exteriorweaponentity.alpha = default_player_alpha;
 604
 605                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 606                 self.lms_traveled_distance = 0;
 607
 608                 if(cvar("spawn_debug"))
 609                 {
 610                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 611                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 612                 }
 613
 614                 //stuffcmd(self, "chase_active 0");
 615                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 616         } else if(self.classname == "observer") {
 617                 PutObserverInServer ();
 618         }
 619 }
 620
 621 /*
 622 =============
 623 SetNewParms
 624 =============
 625 */
 626 void SetNewParms (void)
 627 {
 628
 629 }
 630
 631 /*
 632 =============
 633 SetChangeParms
 634 =============
 635 */
 636 void SetChangeParms (void)
 637 {
 638
 639 }
 640
 641 /*
 642 =============
 643 ClientKill
 644
 645 Called when a client types 'kill' in the console
 646 =============
 647 */
 648 void ClientKill (void)
 649 {
 650         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 651 }
 652
 653 /*
 654 =============
 655 ClientConnect
 656
 657 Called when a client connects to the server
 658 =============
 659 */
 660 string ColoredTeamName(float t);
 661 //void dom_player_join_team(entity pl);
 662 void ClientConnect (void)
 663 {
 664         local float fh;
 665         local string s;
 666
 667         self.classname = "player_joining";
 668         self.flags = self.flags | FL_CLIENT;
 669
 670         if(player_count<0) player_count = 0;
 671
 672         bot_clientconnect();
 673
 674         //if(cvar("g_domination"))
 675         //      dom_player_join_team(self);
 676
 677         //JoinBestTeam(self, FALSE);
 678
 679         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 680                 self.classname = "observer";
 681         } else {
 682                 self.classname = "player";
 683                 campaign_bots_may_start = 1;
 684         }
 685
 686         self.playerid = (playerid_last = playerid_last + 1);
 687         if(cvar("sv_eventlog"))
 688         {
 689                 if(clienttype(self) == CLIENTTYPE_REAL)
 690                         s = "player";
 691                 else
 692                         s = "bot";
 693                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 694                 s = strcat(":team:", ftos(self.playerid), ":");
 695                 s = strcat(s, ftos(self.team));
 696                 GameLogEcho(s, FALSE);
 697         }
 698
 699         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 700
 701         bprint ("^4",self.netname);
 702         bprint ("^4 connected");
 703
 704         if(cvar("g_domination") || cvar("g_ctf"))
 705         {
 706                 bprint(" and joined the ");
 707                 bprint(ColoredTeamName(self.team));
 708         }
 709
 710         bprint("\n");
 711
 712         self.welcomemessage_time = time + cvar("welcome_message_time");
 713         self.welcomemessage_time2 = 0;
 714
 715         //stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 716         // the client might not have that file yet!
 717         fh = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 718         if(fh >= 0)
 719         {
 720                 while((s = fgets(fh)))
 721                         stuffcmd(self, strcat(s, "\n"));
 722                 fclose(fh);
 723         }
 724         // TODO: is this being used for anything else than cd tracks?
 725         // Remember: SVC_CDTRACK exists. Maybe it should be used.
 726
 727
 728         // send prediction settings to the client
 729         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 730         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 731         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 732         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 733         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 734         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 735         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 736         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 737         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 738         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 739         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 740         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 741         // Wazat's grappling hook
 742         SetGrappleHookBindings();
 743
 744         // get autoswitch state from player
 745         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 746         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 747
 748         // get version info from player
 749         stuffcmd(self, "cmd clientversion $gameversion\n");
 750
 751         // get other cvars from player
 752         GetCvars(0);
 753
 754         // set cvar for team scoreboard
 755         if (teams_matter)
 756         {
 757                 local float t;
 758                 t = cvar("teamplay");
 759                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 760                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 761         }
 762         else
 763                 stuffcmd(self, strcat("set teamplay 0\n"));
 764
 765         if(cvar("g_lms"))
 766         {
 767                 self.frags = cvar("fraglimit");
 768                 // no fraglimit was set, so player gets 999 lives
 769                 if(self.frags < 1)
 770                         self.frags = 999;
 771
 772                 // disallow player to join after the worst player has lost g_lms_last_join lives
 773                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 774                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 775                 {
 776                         self.frags = -666;
 777                         lms_dead_count += 1;
 778                 }
 779                 else if(cvar("fraglimit") > lms_lowest_lives)
 780                 {
 781                         self.frags = lms_lowest_lives;
 782                 }
 783         }
 784         else if(cvar("g_arena"))
 785         {
 786                 self.classname = "observer";
 787                 Spawnqueue_Insert(self);
 788         }
 789
 790         bot_relinkplayerlist();
 791
 792         self.jointime = time;
 793 }
 794
 795 /*
 796 =============
 797 ClientDisconnect
 798
 799 Called when a client disconnects from the server
 800 =============
 801 */
 802 void(entity e) DropFlag;
 803 .entity chatbubbleentity;
 804 .entity teambubbleentity;
 805 void ClientDisconnect (void)
 806 {
 807         float save;
 808         if(cvar("sv_eventlog"))
 809                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 810         bprint ("^4",self.netname);
 811         bprint ("^4 disconnected\n");
 812
 813         if (self.chatbubbleentity)
 814         {
 815                 remove (self.chatbubbleentity);
 816                 self.chatbubbleentity = world;
 817         }
 818
 819         if (self.teambubbleentity)
 820         {
 821                 remove (self.teambubbleentity);
 822                 self.teambubbleentity = world;
 823         }
 824
 825         DropAllRunes(self);
 826
 827         if(self.flagcarried)
 828                 DropFlag(self.flagcarried);
 829
 830         DistributeFragsAmongTeam(self, self.team, 1);
 831
 832         save = self.flags;
 833         self.flags = self.flags - (self.flags & FL_CLIENT);
 834         bot_relinkplayerlist();
 835         self.flags = save;
 836
 837         // remove laserdot
 838         if(self.weaponentity)
 839                 if(self.weaponentity.lasertarget)
 840                         remove(self.weaponentity.lasertarget);
 841
 842         // player was dead, decrease dead count
 843         if(cvar("g_lms") && self.frags < 1)
 844                 lms_dead_count -= 1;
 845         else if(cvar("g_arena"))
 846         {
 847                 Spawnqueue_Unmark(self);
 848                 Spawnqueue_Remove(self);
 849         }
 850 }
 851
 852 .float buttonchat;
 853 void() ChatBubbleThink =
 854 {
 855         self.nextthink = time;
 856         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 857         {
 858                 self.owner.chatbubbleentity = world;
 859                 remove(self);
 860                 return;
 861         }
 862         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 863         if (self.owner.buttonchat && !self.owner.deadflag)
 864                 self.model = self.mdl;
 865         else
 866                 self.model = "";
 867 };
 868
 869 void() UpdateChatBubble =
 870 {
 871         if (!self.modelindex)
 872                 return;
 873         // spawn a chatbubble entity if needed
 874         if (!self.chatbubbleentity)
 875         {
 876                 self.chatbubbleentity = spawn();
 877                 self.chatbubbleentity.owner = self;
 878                 self.chatbubbleentity.exteriormodeltoclient = self;
 879                 self.chatbubbleentity.think = ChatBubbleThink;
 880                 self.chatbubbleentity.nextthink = time;
 881                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 882                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 883                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 884                 self.chatbubbleentity.model = "";
 885         }
 886 }
 887
 888
 889 void() TeamBubbleThink =
 890 {
 891         self.nextthink = time;
 892         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 893         {
 894                 self.owner.teambubbleentity = world;
 895                 remove(self);
 896                 return;
 897         }
 898 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 899         if (self.owner.buttonchat || self.owner.deadflag)
 900                 self.model = "";
 901         else
 902                 self.model = self.mdl;
 903
 904 };
 905
 906 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 907
 908 void() UpdateTeamBubble =
 909 {
 910         if (!self.modelindex || !cvar("teamplay"))
 911                 return;
 912         // spawn a teambubble entity if needed
 913         if (!self.teambubbleentity && cvar("teamplay"))
 914         {
 915                 self.teambubbleentity = spawn();
 916                 self.teambubbleentity.owner = self;
 917                 self.teambubbleentity.exteriormodeltoclient = self;
 918                 self.teambubbleentity.think = TeamBubbleThink;
 919                 self.teambubbleentity.nextthink = time;
 920                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 921 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 922                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 923                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 924                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 925                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 926                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 927         }
 928 }
 929
 930 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 931 // added to the model skins
 932 /*void() UpdateColorModHack =
 933 {
 934         local float c;
 935         c = self.clientcolors & 15;
 936         // LordHavoc: only bothering to support white, green, red, yellow, blue
 937              if (teamplay == 0) self.colormod = '0 0 0';
 938         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 939         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 940         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 941         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 942         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 943         else self.colormod = '1 1 1';
 944 };*/
 945
 946 /*
 947 =============
 948 PlayerJump
 949
 950 When you press the jump key
 951 =============
 952 */
 953 void PlayerJump (void)
 954 {
 955         float mjumpheight;
 956
 957         mjumpheight = cvar("g_balance_jumpheight");
 958         if (self.waterlevel >= 2)
 959         {
 960                 if (self.watertype == CONTENT_WATER)
 961                         self.velocity_z = 200;
 962                 else if (self.watertype == CONTENT_SLIME)
 963                         self.velocity_z = 80;
 964                 else
 965                         self.velocity_z = 50;
 966
 967                 return;
 968         }
 969
 970
 971         if (!(self.flags & FL_ONGROUND))
 972                 return;
 973
 974         if (!(self.flags & FL_JUMPRELEASED))
 975                 return;
 976
 977         if(cvar("g_runematch"))
 978         {
 979                 if(self.runes & RUNE_SPEED)
 980                 {
 981                         if(self.runes & CURSE_SLOW)
 982                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 983                         else
 984                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 985                 }
 986                 else if(self.runes & CURSE_SLOW)
 987                 {
 988                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 989                 }
 990         }
 991
 992         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 993         {
 994                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 995         }
 996
 997         self.velocity_z = self.velocity_z + mjumpheight;
 998         self.oldvelocity_z = self.velocity_z;
 999
1000         self.flags = self.flags - FL_ONGROUND;
1001         self.flags = self.flags - FL_JUMPRELEASED;
1002 }
1003
1004 void() CheckWaterJump =
1005 {
1006         local vector start, end;
1007
1008 // check for a jump-out-of-water
1009         makevectors (self.angles);
1010         start = self.origin;
1011         start_z = start_z + 8;
1012         v_forward_z = 0;
1013         normalize(v_forward);
1014         end = start + v_forward*24;
1015         traceline (start, end, TRUE, self);
1016         if (trace_fraction < 1)
1017         {       // solid at waist
1018                 start_z = start_z + self.maxs_z - 8;
1019                 end = start + v_forward*24;
1020                 self.movedir = trace_plane_normal * -50;
1021                 traceline (start, end, TRUE, self);
1022                 if (trace_fraction == 1)
1023                 {       // open at eye level
1024                         self.flags = self.flags | FL_WATERJUMP;
1025                         self.velocity_z = 225;
1026                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1027                         self.teleport_time = time + 2;  // safety net
1028                         return;
1029                 }
1030         }
1031 };
1032
1033
1034 void respawn(void)
1035 {
1036         CopyBody(1);
1037         PutClientInServer();
1038 }
1039
1040 void player_powerups (void)
1041 {
1042         if (cvar("g_minstagib"))
1043         {
1044                 self.effects = EF_FULLBRIGHT;
1045                 if (self.items & IT_STRENGTH)
1046                 {
1047                         if (time > self.strength_finished)
1048                         {
1049                                 self.alpha = default_player_alpha;
1050                                 self.exteriorweaponentity.alpha = default_player_alpha;
1051                                 self.items = self.items - (self.items & IT_STRENGTH);
1052                                 sprint(self, "^3Invisibility has worn off\n");
1053                         }
1054                 }
1055                 else
1056                 {
1057                         if (time < self.strength_finished)
1058                         {
1059                                 self.alpha = cvar("g_minstagib_invis_alpha");
1060                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1061                                 self.items = self.items | IT_STRENGTH;
1062                                 sprint(self, "^3You are invisible\n");
1063                         }
1064                 }
1065
1066                 if (self.items & IT_INVINCIBLE)
1067                 {
1068                         if (time > self.invincible_finished)
1069                         {
1070                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1071                                 sprint(self, "^3Speed has worn off\n");
1072                         }
1073                 }
1074                 else
1075                 {
1076                         if (time < self.invincible_finished)
1077                         {
1078                                 self.items = self.items | IT_INVINCIBLE;
1079                                 sprint(self, "^3You are on speed\n");
1080                         }
1081                 }
1082                 return;
1083         }
1084
1085         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1086         if (self.items & IT_STRENGTH)
1087         {
1088                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1089                 if (time > self.strength_finished)
1090                 {
1091                         self.items = self.items - (self.items & IT_STRENGTH);
1092                         sprint(self, "^3Strength has worn off\n");
1093                 }
1094         }
1095         else
1096         {
1097                 if (time < self.strength_finished)
1098                 {
1099                         self.items = self.items | IT_STRENGTH;
1100                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1101                 }
1102         }
1103         if (self.items & IT_INVINCIBLE)
1104         {
1105                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1106                 if (time > self.invincible_finished)
1107                 {
1108                         self.items = self.items - (self.items & IT_INVINCIBLE);
1109                         sprint(self, "^3Shield has worn off\n");
1110                 }
1111         }
1112         else
1113         {
1114                 if (time < self.invincible_finished)
1115                 {
1116                         self.items = self.items | IT_INVINCIBLE;
1117                         sprint(self, "^3Shield surrounds you\n");
1118                 }
1119         }
1120
1121         if (cvar("g_fullbrightplayers"))
1122                 self.effects = self.effects | EF_FULLBRIGHT;
1123
1124         // midair gamemode: damage only while in the air
1125         // if in midair mode, being on ground grants temporary invulnerability
1126         // (this is so that multishot weapon don't clear the ground flag on the
1127         // first damage in the frame, leaving the player vulnerable to the
1128         // remaining hits in the same frame)
1129         if (self.flags & FL_ONGROUND)
1130         if (cvar("g_midair"))
1131                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1132
1133         if (time < self.spawnshieldtime)
1134                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1135 }
1136
1137 void player_regen (void)
1138 {
1139         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1140         maxh = cvar("g_balance_health_stable");
1141         maxa = cvar("g_balance_armor_stable");
1142         limith = cvar("g_balance_health_limit");
1143         limita = cvar("g_balance_armor_limit");
1144
1145         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1146                 return;
1147
1148         if(cvar("g_runematch"))
1149         {
1150                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1151                 if (self.runes & RUNE_REGEN)
1152                 {
1153                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1154                         {
1155                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1156                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1157                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1158                         }
1159                         else
1160                         {
1161                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1162                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1163                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1164                         }
1165                 }
1166                 else if (self.runes & CURSE_VENOM)
1167                 {
1168                         max_mod = cvar("g_balance_curse_venom_hpmod");
1169                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1170                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1171                         else
1172                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1173                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1174                         //if (!self.runes & RUNE_REGEN)
1175                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1176                 }
1177                 maxh = maxh * max_mod;
1178                 //maxa = maxa * max_mod;
1179
1180                 if (time > self.pauserotarmor_finished)
1181                 {
1182                         if (self.armorvalue > maxa)
1183                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1184                 }
1185                 if (time > self.pauserothealth_finished)
1186                 {
1187                         if (self.health > maxh)
1188                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1189                 }
1190                 if (time > self.pauseregen_finished)
1191                 {
1192                         if (self.health < maxh)
1193                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1194                         if (self.armorvalue < maxa)
1195                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1196                 }
1197         }
1198         else
1199         {
1200                 if (time > self.pauserothealth_finished)
1201                 if (self.health > maxh)
1202                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1203                 if (time > self.pauserotarmor_finished)
1204                 if (self.armorvalue > maxa)
1205                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1206                 if (time > self.pauseregen_finished)
1207                 {
1208                         if (self.health < maxh)
1209                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1210                         if (self.armorvalue < maxa)
1211                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1212                 }
1213         }
1214
1215         if (self.health > limith)
1216                 self.health = limith;
1217         if(self.health < 1)
1218                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1219         if (self.armorvalue > limita)
1220                 self.armorvalue = limita;
1221 }
1222
1223 /*
1224 ======================
1225 spectate mode routines
1226 ======================
1227 */
1228 void SpectateCopy(entity spectatee) {
1229         self.armortype = spectatee.armortype;
1230         self.armorvalue = spectatee.armorvalue;
1231         self.currentammo = spectatee.currentammo;
1232         self.effects = spectatee.effects;
1233         self.health = spectatee.health;
1234         self.impulse = 0;
1235         self.items = spectatee.items;
1236         self.punchangle = spectatee.punchangle;
1237         self.view_ofs = spectatee.view_ofs;
1238         self.v_angle = spectatee.v_angle;
1239         self.viewzoom = spectatee.viewzoom;
1240         setorigin(self, spectatee.origin);
1241         setsize(self, spectatee.mins, spectatee.maxs);
1242 }
1243
1244 void SpectateUpdate() {
1245         if(!self.enemy)
1246                         PutObserverInServer();
1247
1248         if (self != self.enemy) {
1249                 if(self.enemy.flags & FL_NOTARGET)
1250                         PutObserverInServer();
1251                 SpectateCopy(self.enemy);
1252                 self.dmg_take = self.enemy.dmg_take;
1253                 self.dmg_save = self.enemy.dmg_save;
1254                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1255                 self.fixangle = TRUE;
1256                 self.angles = self.enemy.v_angle;
1257                 //msg_entity = self;
1258                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1259                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1260                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1261                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1262         }
1263 }
1264
1265 float SpectateNext() {
1266         other = find(self.enemy, classname, "player");
1267         if (!other) {
1268                 other = find(other, classname, "player");
1269         }
1270         if (other) {
1271                 self.enemy = other;
1272         }
1273         if(self.enemy.classname == "player") {
1274                 msg_entity = self;
1275                 WriteByte(MSG_ONE, SVC_SETVIEW);
1276                 WriteEntity(MSG_ONE, self.enemy);
1277                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1278                 SpectateUpdate();
1279                 return 1;
1280         } else {
1281                 return 0;
1282         }
1283 }
1284
1285 /*
1286 =============
1287 PlayerPreThink
1288
1289 Called every frame for each client before the physics are run
1290 =============
1291 */
1292 void PlayerPreThink (void)
1293 {
1294         if(self.classname == "player") {
1295                 local vector m1, m2;
1296
1297 //              if(self.netname == "Wazat")
1298 //                      bprint(strcat(self.classname, "\n"));
1299
1300                 CheckRules_Player();
1301
1302                 Nixnex_GiveCurrentWeapon();
1303
1304                 if(self.button7)
1305                         PrintWelcomeMessage(self);
1306
1307                 if(cvar("g_lms") || !cvar("sv_spectate"))
1308                 if((time - self.jointime) <= cvar("welcome_message_time"))
1309                         PrintWelcomeMessage(self);
1310
1311                 if (intermission_running)
1312                 {
1313                         IntermissionThink ();   // otherwise a button could be missed between
1314                         return;                                 // the think tics
1315                 }
1316
1317                 if (self.deadflag != DEAD_NO)
1318                 {
1319                         player_anim();
1320                         if (self.deadflag == DEAD_DYING)
1321                         {
1322                                 if (time > self.dead_time)
1323                                         self.deadflag = DEAD_DEAD;
1324                         }
1325                         else if (self.deadflag == DEAD_DEAD)
1326                         {
1327                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1328                                         self.deadflag = DEAD_RESPAWNABLE;
1329                                 else if (!self.button0 && !self.button2 && !self.button3)
1330                                         self.deadflag = DEAD_RESPAWNABLE;
1331                         }
1332                         else if (self.deadflag == DEAD_RESPAWNABLE)
1333                         {
1334                                 if (self.button0  ||
1335                                     self.button2  ||
1336                                     self.button3  ||
1337                                     self.button4  ||
1338                                     self.button5  ||
1339                                     self.button6  ||
1340                                     self.button7  ||
1341                                     self.button8  ||
1342                                     self.buttonuse ||
1343                                     cvar("g_lms") ||
1344                                     cvar("g_forced_respawn"))
1345                                         respawn();
1346                         }
1347                         return;
1348                 }
1349
1350                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1351                 {
1352                         vector dist;
1353
1354                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1355                         dist = self.oldorigin - self.origin;
1356                         dist_z = 0;
1357                         self.lms_traveled_distance += fabs(vlen(dist));
1358
1359                         if(cvar("g_campaign"))
1360                         if(!campaign_bots_may_start)
1361                         {
1362                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1363                                 self.lms_traveled_distance = 0;
1364                         }
1365
1366                         if(time > self.lms_nextcheck)
1367                         {
1368                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1369                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1370                                 {
1371                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1372                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1373                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1374                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1375                                 }
1376                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1377                                 self.lms_traveled_distance = 0;
1378                         }
1379                 }
1380
1381                 if (self.button5 && !self.hook.state)
1382                 {
1383                         if (!self.crouch)
1384                         {
1385                                 self.crouch = TRUE;
1386                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1387                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1388                         }
1389                 }
1390                 else
1391                 {
1392                         if (self.crouch)
1393                         {
1394                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1395                                 if (!trace_startsolid)
1396                                 {
1397                                         self.crouch = FALSE;
1398                                         self.view_ofs = PL_VIEW_OFS;
1399                                         setsize (self, PL_MIN, PL_MAX);
1400                                 }
1401                         }
1402                 }
1403
1404                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1405                         local string defaultmodel;
1406                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1407
1408                         if (defaultmodel != self.model)
1409                         {
1410                                 m1 = self.mins;
1411                                 m2 = self.maxs;
1412                                 setmodel_lod (self, defaultmodel);
1413                                 setsize (self, m1, m2);
1414                         }
1415
1416                         if (self.skin != cvar("sv_defaultplayerskin"))
1417                                 self.skin = cvar("sv_defaultplayerskin");
1418                 } else {
1419                         if (self.playermodel != self.model)
1420                         {
1421                                 self.playermodel = CheckPlayerModel(self.playermodel);
1422                                 m1 = self.mins;
1423                                 m2 = self.maxs;
1424                                 setmodel_lod (self, self.playermodel);
1425                                 setsize (self, m1, m2);
1426                         }
1427
1428                         if (self.skin != stof(self.playerskin))
1429                                 self.skin = stof(self.playerskin);
1430                 }
1431                 // Savage: Check for nameless players
1432                 if (strlen(self.netname) < 1) {
1433                         self.netname = "Player";
1434                         stuffcmd(self, "name Player\n");
1435                 }
1436
1437                 GrapplingHookFrame();
1438
1439                 W_WeaponFrame();
1440
1441                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1442                 {
1443                         if (cvar("g_minstagib") && self.button3)
1444                         {
1445                                 if (self.jump_interval <= (time + 0.1))
1446                                 {
1447                                         self.jump_interval = time + 1;
1448                                         W_Laser_Attack();
1449                                 }
1450                         }
1451                         else if (self.viewzoom > 0.4)
1452                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1453                 }
1454                 else if (self.viewzoom < 1.0)
1455                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1456
1457
1458                 if (self.button2)
1459                         PlayerJump ();
1460                 else
1461                         self.flags = self.flags | FL_JUMPRELEASED;
1462
1463                 player_powerups();
1464                 player_regen();
1465                 player_anim();
1466
1467                 if (cvar("g_minstagib"))
1468                         minstagib_ammocheck();
1469
1470                 //self.angles_y=self.v_angle_y + 90;   // temp
1471
1472                 if (self.waterlevel == 2)
1473                         CheckWaterJump ();
1474
1475                 //if (TetrisPreFrame()) return;
1476         } else if(gameover) {
1477                 if (intermission_running)
1478                         IntermissionThink ();   // otherwise a button could be missed between
1479                 return;
1480         } else if(self.classname == "observer") {
1481
1482                 if (self.flags & FL_JUMPRELEASED) {
1483                         if (self.button2 && self.version == cvar("gameversion")) {
1484                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1485                                         self.flags = self.flags & !FL_JUMPRELEASED;
1486                                         self.classname = "player";
1487                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1488                                                 JoinBestTeam(self, 0);
1489                                         if(cvar("g_campaign"))
1490                                                 campaign_bots_may_start = 1;
1491                                         PutClientInServer();
1492                                         if(self.flags & !FL_NOTARGET)
1493                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1494                                         centerprint(self,"");
1495                                         return;
1496                                 } else {
1497                                         self.flags = self.flags & !FL_JUMPRELEASED;
1498                                         stuffcmd(self,"menu_showteamselect\n");
1499                                         return;
1500                                 }
1501                         } else if(self.button0 && self.version == cvar("gameversion")) {
1502                                 self.flags = self.flags & !FL_JUMPRELEASED;
1503                                 if(SpectateNext() == 1) {
1504                                         self.classname = "spectator";
1505                                 }
1506                         }
1507                 } else {
1508                         if (!(self.button0 || self.button2)) {
1509                                 self.flags = self.flags | FL_JUMPRELEASED;
1510                         }
1511                 }
1512                 PrintWelcomeMessage(self);
1513         } else if(self.classname == "spectator") {
1514                 if (self.flags & FL_JUMPRELEASED) {
1515                         if (self.button2 && self.version == cvar("gameversion")) {
1516                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1517                                         self.flags = self.flags & !FL_JUMPRELEASED;
1518                                         self.classname = "player";
1519                                         if(!cvar("g_lms"))
1520                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1521
1522                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1523                                                 JoinBestTeam(self, 0);
1524                                         if(cvar("g_campaign"))
1525                                                 campaign_bots_may_start = 1;
1526                                         PutClientInServer();
1527                                         centerprint(self,"");
1528                                         return;
1529                                 } else {
1530                                         self.flags = self.flags & !FL_JUMPRELEASED;
1531                                         stuffcmd(self,"menu_showteamselect\n");
1532                                         return;
1533                                 }
1534                         } else if(self.button0) {
1535                                 self.flags = self.flags & !FL_JUMPRELEASED;
1536                                 if(SpectateNext() == 1) {
1537                                         self.classname = "spectator";
1538                                 } else {
1539                                         self.classname = "observer";
1540                                         PutClientInServer();
1541                                 }
1542                         } else if (self.button3) {
1543                                 self.flags = self.flags & !FL_JUMPRELEASED;
1544                                 self.classname = "observer";
1545                                 PutClientInServer();
1546                         } else {
1547                                 SpectateUpdate();
1548                         }
1549                 } else {
1550                         if (!(self.button0 || self.button3)) {
1551                                 self.flags = self.flags | FL_JUMPRELEASED;
1552                         }
1553                 }
1554                 PrintWelcomeMessage(self);
1555                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1556         }
1557 }
1558
1559
1560 /*
1561 =============
1562 PlayerPostThink
1563
1564 Called every frame for each client after the physics are run
1565 =============
1566 */
1567 void PlayerPostThink (void)
1568 {
1569         if(self.classname == "player") {
1570                 CheckRules_Player();
1571                 UpdateChatBubble();
1572                 UpdateTeamBubble();
1573                 if (self.deadflag == DEAD_NO)
1574                 if (self.impulse)
1575                         ImpulseCommands ();
1576                 if (intermission_running)
1577                         return;         // intermission or finale
1578
1579                 //PrintWelcomeMessage(self);
1580                 //if (TetrisPostFrame()) return;
1581         } else if (self.classname == "observer") {
1582                 //do nothing
1583         } else if (self.classname == "spectator") {
1584                 //do nothing
1585         }
1586         Arena_Warmup();
1587 }