data/qcsrc/server/cl_client.qc

   1 float ClientData_Send(entity to, float sf)
   2 {
   3         if(to != self.owner)
   4         {
   5                 error("wtf");
   6                 return FALSE;
   7         }
   8
   9         entity e;
  10
  11         e = to;
  12         if(to.classname == "spectator")
  13                 e = to.enemy;
  14
  15         sf = 0;
  16
  17         if(e.race_completed)
  18                 sf |= 1; // forced scoreboard
  19         if(to.spectatee_status)
  20                 sf |= 2; // spectator ent number follows
  21         if(e.zoomstate)
  22                 sf |= 4; // zoomed
  23         if(e.porto_v_angle_held)
  24                 sf |= 8; // angles held
  25
  26         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  27         WriteByte(MSG_ENTITY, sf);
  28
  29         if(sf & 2)
  30                 WriteByte(MSG_ENTITY, to.spectatee_status);
  31
  32         if(sf & 8)
  33         {
  34                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  35                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  36         }
  37
  38         return TRUE;
  39 }
  40
  41 void ClientData_Attach()
  42 {
  43         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  44         self.clientdata.drawonlytoclient = self;
  45         self.clientdata.owner = self;
  46 }
  47
  48 void ClientData_Detach()
  49 {
  50         remove(self.clientdata);
  51         self.clientdata = world;
  52 }
  53
  54 void ClientData_Touch(entity e)
  55 {
  56         e.clientdata.SendFlags = 1;
  57
  58         // make it spectatable
  59         entity e2;
  60         FOR_EACH_REALCLIENT(e2)
  61         {
  62                 if(e2 != e)
  63                         if(e2.classname == "spectator")
  64                                 if(e2.enemy == e)
  65                                         e2.clientdata.SendFlags = 1;
  66         }
  67 }
  68
  69
  70 #define SPAWNPOINT_SCORE frags
  71
  72 .string netname_previous;
  73
  74 void spawnfunc_info_player_survivor (void)
  75 {
  76         spawnfunc_info_player_deathmatch();
  77 }
  78
  79 void spawnfunc_info_player_start (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_deathmatch (void)
  85 {
  86         self.classname = "info_player_deathmatch";
  87         relocate_spawnpoint();
  88 }
  89
  90 void spawnpoint_use()
  91 {
  92         if(teams_matter)
  93         if(have_team_spawns)
  94         {
  95                 self.team = activator.team;
  96                 some_spawn_has_been_used = 1;
  97         }
  98 };
  99
 100 // Returns:
 101 //   -1 if a spawn can't be used
 102 //   otherwise, a weight of the spawnpoint
 103 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 104 {
 105         float shortest, thisdist;
 106         entity player;
 107
 108         // filter out spots for the wrong team
 109         if(teamcheck)
 110         if(spot.team != teamcheck)
 111                 return -1;
 112
 113         if(race_spawns)
 114                 if(spot.target == "")
 115                         return -1;
 116
 117         if(clienttype(self) == CLIENTTYPE_REAL)
 118         {
 119                 if(spot.restriction == 1)
 120                         return -1;
 121         }
 122         else
 123         {
 124                 if(spot.restriction == 2)
 125                         return -1;
 126         }
 127
 128         // filter out spots for assault
 129         if(spot.target != "") {
 130                 local entity ent;
 131                 float good, found;
 132                 ent = find(world, targetname, spot.target);
 133                 while(ent) {
 134                         if(ent.classname == "target_objective")
 135                         {
 136                                 found = 1;
 137                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 138                                         return -1;
 139                                 good = 1;
 140                         }
 141                         else if(ent.classname == "trigger_race_checkpoint")
 142                         {
 143                                 found = 1;
 144                                 if(self.classname == "player") // spectators may spawn everywhere
 145                                 {
 146                                         if(g_race_qualifying)
 147                                         {
 148                                                 // spawn at first
 149                                                 if(ent.race_checkpoint != 0)
 150                                                         return -1;
 151                                                 if(spot.race_place != race_lowest_place_spawn)
 152                                                         return -1;
 153                                         }
 154                                         else
 155                                         {
 156                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 157                                                         return -1;
 158                                                 float pl;
 159                                                 pl = self.race_place;
 160                                                 if(pl > race_highest_place_spawn)
 161                                                         pl = 0;
 162                                                 if(spot.race_place != pl)
 163                                                         return -1;
 164                                         }
 165                                 }
 166                                 good = 1;
 167                         }
 168                         ent = find(ent, targetname, spot.target);
 169                 }
 170
 171                 if(found && !good)
 172                         return -1;
 173         }
 174
 175         player = playerlist;
 176         shortest = vlen(world.maxs - world.mins);
 177         for(player = playerlist; player; player = player.chain)
 178                 if (player != self)
 179                 {
 180                         thisdist = vlen(player.origin - spot.origin);
 181                         if (thisdist < shortest)
 182                                 shortest = thisdist;
 183                 }
 184         return shortest;
 185 }
 186
 187 float spawn_allbad;
 188 float spawn_allgood;
 189 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 190 {
 191         local entity spot, spotlist, spotlistend;
 192         spawn_allgood = TRUE;
 193         spawn_allbad = TRUE;
 194
 195         spotlist = world;
 196         spotlistend = world;
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 201
 202                 if(cvar("spawn_debugview"))
 203                 {
 204                         setmodel(spot, "models/runematch/rune.mdl");
 205                         if(spot.SPAWNPOINT_SCORE < mindist)
 206                         {
 207                                 spot.colormod = '1 0 0';
 208                                 spot.scale = 1;
 209                         }
 210                         else
 211                         {
 212                                 spot.colormod = '0 1 0';
 213                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 214                         }
 215                 }
 216
 217                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 218                 {
 219                         if(spot.SPAWNPOINT_SCORE < mindist)
 220                         {
 221                                 // too short distance
 222                                 spawn_allgood = FALSE;
 223                         }
 224                         else
 225                         {
 226                                 // perfect
 227                                 spawn_allbad = FALSE;
 228
 229                                 if(spotlistend)
 230                                         spotlistend.chain = spot;
 231                                 spotlistend = spot;
 232                                 if(!spotlist)
 233                                         spotlist = spot;
 234
 235                                 /*
 236                                 if(teamcheck)
 237                                 if(spot.team != teamcheck)
 238                                         error("invalid spawn added");
 239
 240                                 print("added ", etos(spot), "\n");
 241                                 */
 242                         }
 243                 }
 244         }
 245         if(spotlistend)
 246                 spotlistend.chain = world;
 247
 248         /*
 249                 entity e;
 250                 if(teamcheck)
 251                         for(e = spotlist; e; e = e.chain)
 252                         {
 253                                 print("seen ", etos(e), "\n");
 254                                 if(e.team != teamcheck)
 255                                         error("invalid spawn found");
 256                         }
 257         */
 258
 259         return spotlist;
 260 }
 261
 262 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 263 {
 264         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 265         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 266         local entity spot;
 267
 268         RandomSelection_Init();
 269         for(spot = firstspot; spot; spot = spot.chain)
 270                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 271
 272         return RandomSelection_chosen_ent;
 273 }
 274
 275 /*
 276 =============
 277 SelectSpawnPoint
 278
 279 Finds a point to respawn
 280 =============
 281 */
 282 entity SelectSpawnPoint (float anypoint)
 283 {
 284         local float teamcheck;
 285         local entity firstspot_new;
 286         local entity spot, firstspot, playerlist;
 287
 288         spot = find (world, classname, "testplayerstart");
 289         if (spot)
 290                 return spot;
 291
 292         teamcheck = 0;
 293
 294         if(!anypoint && have_team_spawns)
 295                 teamcheck = self.team;
 296
 297         // get the list of players
 298         playerlist = findchain(classname, "player");
 299         // get the entire list of spots
 300         firstspot = findchain(classname, "info_player_deathmatch");
 301         // filter out the bad ones
 302         // (note this returns the original list if none survived)
 303         if(anypoint)
 304         {
 305                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 306         }
 307         else
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 310                 if(!firstspot_new)
 311                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 312                 firstspot = firstspot_new;
 313
 314                 // there is 50/50 chance of choosing a random spot or the furthest spot
 315                 // (this means that roughly every other spawn will be furthest, so you
 316                 // usually won't get fragged at spawn twice in a row)
 317                 if (arena_roundbased)
 318                 {
 319                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 320                         if(firstspot_new)
 321                                 firstspot = firstspot_new;
 322                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 323                 }
 324                 else if (random() > cvar("g_spawn_furthest"))
 325                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 326                 else
 327                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 328         }
 329
 330         if(cvar("spawn_debugview"))
 331         {
 332                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 333
 334                 entity e;
 335                 if(teamcheck)
 336                         for(e = firstspot; e; e = e.chain)
 337                                 if(e.team != teamcheck)
 338                                         error("invalid spawn found");
 339         }
 340
 341         if (!spot)
 342         {
 343                 if(cvar("spawn_debug"))
 344                         GotoNextMap();
 345                 else
 346                 {
 347                         if(some_spawn_has_been_used)
 348                                 return world; // team can't spawn any more, because of actions of other team
 349                         else
 350                                 error("Cannot find a spawn point - please fix the map!");
 351                 }
 352         }
 353
 354         return spot;
 355 }
 356
 357 /*
 358 =============
 359 CheckPlayerModel
 360
 361 Checks if the argument string can be a valid playermodel.
 362 Returns a valid one in doubt.
 363 =============
 364 */
 365 string FallbackPlayerModel = "models/player/marine.zym";
 366 string CheckPlayerModel(string plyermodel) {
 367         if(strlen(plyermodel) < 4)
 368                 return FallbackPlayerModel;
 369         if( substring(plyermodel,0,14) != "models/player/")
 370                 return FallbackPlayerModel;
 371         else if(cvar("sv_servermodelsonly"))
 372         {
 373                 if(substring(plyermodel,-4,4) != ".zym")
 374                 if(substring(plyermodel,-4,4) != ".dpm")
 375                 if(substring(plyermodel,-4,4) != ".md3")
 376                 if(substring(plyermodel,-4,4) != ".psk")
 377                         return FallbackPlayerModel;
 378                 // forbid the LOD models
 379                 if(substring(plyermodel, -9,5) == "_lod1")
 380                         return FallbackPlayerModel;
 381                 if(substring(plyermodel, -9,5) == "_lod2")
 382                         return FallbackPlayerModel;
 383                 if(plyermodel != strtolower(plyermodel))
 384                         return FallbackPlayerModel;
 385                 if(!fexists(plyermodel))
 386                         return FallbackPlayerModel;
 387         }
 388         return plyermodel;
 389 }
 390
 391 /*
 392 =============
 393 Client_customizeentityforclient
 394
 395 LOD reduction
 396 =============
 397 */
 398 void Client_uncustomizeentityforclient()
 399 {
 400         if(self.modelindex == 0) // no need to uncustomize then
 401                 return;
 402         self.modelindex = self.modelindex_lod0;
 403         self.skin = self.skinindex;
 404 }
 405
 406 float Client_customizeentityforclient()
 407 {
 408         entity modelsource;
 409
 410         if(self.modelindex == 0)
 411                 return TRUE;
 412
 413         // forcemodel stuff
 414
 415 #ifdef PROFILING
 416         float t0;
 417         t0 = gettime(GETTIME_HIRES); // reference
 418 #endif
 419
 420         modelsource = self;
 421
 422 #ifdef ALLOW_FORCEMODELS
 423         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 424                 if not(self.modelindex_lod0_from_nexuiz)
 425                         modelsource = other;
 426         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 427                 modelsource = other;
 428 #endif
 429
 430         self.skin = modelsource.skinindex;
 431
 432 #if 0
 433         if(modelsource == self)
 434                 self.skin = modelsource.skinindex;
 435         else
 436                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 437 #endif
 438
 439         // self: me
 440         // other: the player viewing me
 441         float distance;
 442         float f;
 443
 444         if(other.cvar_cl_playerdetailreduction <= 0)
 445         {
 446                 if(other.cvar_cl_playerdetailreduction <= -2)
 447                         self.modelindex = modelsource.modelindex_lod2;
 448                 else if(other.cvar_cl_playerdetailreduction <= -1)
 449                         self.modelindex = modelsource.modelindex_lod1;
 450                 else
 451                         self.modelindex = modelsource.modelindex_lod0;
 452         }
 453         else
 454         {
 455                 distance = vlen(self.origin - other.origin);
 456                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 457                 if(f > sv_loddistance2)
 458                         self.modelindex = modelsource.modelindex_lod2;
 459                 else if(f > sv_loddistance1)
 460                         self.modelindex = modelsource.modelindex_lod1;
 461                 else
 462                         self.modelindex = modelsource.modelindex_lod0;
 463         }
 464
 465 #ifdef PROFILING
 466         float t1;
 467         t1 = gettime(GETTIME_HIRES); // reference
 468         client_cefc_accumulator += (t1 - t0);
 469 #endif
 470
 471         return TRUE;
 472 }
 473
 474 void UpdatePlayerSounds();
 475 void setmodel_lod(entity e, string modelname)
 476 {
 477         string s;
 478
 479         if(sv_loddistance1)
 480         {
 481                 // FIXME: this only supports 3-letter extensions
 482                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 483                 if(fexists(s))
 484                 {
 485                         setmodel(e, s); // players have high precision
 486                         self.modelindex_lod1 = self.modelindex;
 487                 }
 488                 else
 489                         self.modelindex_lod1 = -1;
 490
 491                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 492                 if(fexists(s))
 493                 {
 494                         setmodel(e, s); // players have high precision
 495                         self.modelindex_lod2 = self.modelindex;
 496                 }
 497                 else
 498                         self.modelindex_lod2 = -1;
 499
 500                 precache_model(modelname);
 501                 setmodel(e, modelname); // players have high precision
 502                 self.modelindex_lod0 = self.modelindex;
 503
 504                 if(self.modelindex_lod1 < 0)
 505                         self.modelindex_lod1 = self.modelindex;
 506
 507                 if(self.modelindex_lod2 < 0)
 508                         self.modelindex_lod2 = self.modelindex;
 509         }
 510         else
 511         {
 512                 precache_model(modelname);
 513                 setmodel(e, modelname); // players have high precision
 514                 self.modelindex_lod0 = self.modelindex;
 515                         // save it for possible player model forcing
 516         }
 517
 518         s = whichpack(self.model);
 519         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 520
 521         player_setupanimsformodel();
 522         UpdatePlayerSounds();
 523 }
 524
 525 /*
 526 =============
 527 PutObserverInServer
 528
 529 putting a client as observer in the server
 530 =============
 531 */
 532 void FixPlayermodel();
 533 void PutObserverInServer (void)
 534 {
 535         entity  spot;
 536
 537         race_PreSpawnObserver();
 538
 539         spot = SelectSpawnPoint (TRUE);
 540         if(!spot)
 541                 error("No spawnpoints for observers?!?\n");
 542         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 543
 544         if(clienttype(self) == CLIENTTYPE_REAL)
 545         {
 546                 msg_entity = self;
 547                 WriteByte(MSG_ONE, SVC_SETVIEW);
 548                 WriteEntity(MSG_ONE, self);
 549         }
 550
 551         DropAllRunes(self);
 552         kh_Key_DropAll(self, TRUE);
 553
 554         Portal_ClearAll(self);
 555
 556         if(self.flagcarried)
 557                 DropFlag(self.flagcarried, world, world);
 558         if(self.ballcarried)
 559                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 560
 561         WaypointSprite_PlayerDead();
 562
 563         if(self.killcount != -666)
 564         {
 565                 if(g_lms)
 566                 {
 567                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 568                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 569                         else
 570                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 571                 }
 572                 else
 573                         bprint ("^4", self.netname, "^4 is spectating now\n");
 574         }
 575
 576         PlayerScore_Clear(self); // clear scores when needed
 577
 578         self.spectatortime = time;
 579
 580         self.classname = "observer";
 581         self.iscreature = FALSE;
 582         self.health = -666;
 583         self.takedamage = DAMAGE_NO;
 584         self.solid = SOLID_NOT;
 585         self.movetype = MOVETYPE_NOCLIP;
 586         self.flags = FL_CLIENT | FL_NOTARGET;
 587         self.armorvalue = 666;
 588         self.effects = 0;
 589         self.armorvalue = cvar("g_balance_armor_start");
 590         self.pauserotarmor_finished = 0;
 591         self.pauserothealth_finished = 0;
 592         self.pauseregen_finished = 0;
 593         self.damageforcescale = 0;
 594         self.death_time = 0;
 595         self.dead_frame = 0;
 596         self.alpha = 0;
 597         self.scale = 0;
 598         self.fade_time = 0;
 599         self.pain_frame = 0;
 600         self.pain_finished = 0;
 601         self.strength_finished = 0;
 602         self.invincible_finished = 0;
 603         self.pushltime = 0;
 604         self.think = SUB_Null;
 605         self.nextthink = 0;
 606         self.hook_time = 0;
 607         self.runes = 0;
 608         self.deadflag = DEAD_NO;
 609         self.angles = spot.angles;
 610         self.angles_z = 0;
 611         self.fixangle = TRUE;
 612         self.crouch = FALSE;
 613
 614         self.view_ofs = PL_VIEW_OFS;
 615         setorigin (self, spot.origin);
 616         setsize (self, '0 0 0', '0 0 0');
 617         self.prevorigin = self.origin;
 618         self.items = 0;
 619         self.weapons = 0;
 620         self.model = "";
 621         FixPlayermodel();
 622         self.model = "";
 623         self.modelindex = 0;
 624         self.weapon = 0;
 625         self.weaponmodel = "";
 626         self.weaponentity = world;
 627         self.exteriorweaponentity = world;
 628         self.killcount = -666;
 629         self.velocity = '0 0 0';
 630         self.avelocity = '0 0 0';
 631         self.punchangle = '0 0 0';
 632         self.punchvector = '0 0 0';
 633         self.oldvelocity = self.velocity;
 634         self.fire_endtime = -1;
 635
 636         if(sv_loddistance1)
 637                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 638
 639         self.team = -1;
 640
 641         if(g_arena)
 642         {
 643                 if(self.version_mismatch)
 644                 {
 645                         Spawnqueue_Unmark(self);
 646                         Spawnqueue_Remove(self);
 647                 }
 648                 else
 649                 {
 650                         Spawnqueue_Insert(self);
 651                 }
 652         }
 653         else if(g_lms)
 654         {
 655                 // Only if the player cannot play at all
 656                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 657                         self.frags = FRAGS_SPECTATOR;
 658                 else
 659                         self.frags = FRAGS_LMS_LOSER;
 660         }
 661         else
 662                 self.frags = FRAGS_SPECTATOR;
 663 }
 664
 665 float RestrictSkin(float s)
 666 {
 667         if(!teams_matter)
 668                 return s;
 669         if(s == 6)
 670                 return 6;
 671         return mod(s, 3);
 672 }
 673
 674 void FixPlayermodel()
 675 {
 676         local string defaultmodel;
 677         local float defaultskin, chmdl, oldskin;
 678         local vector m1, m2;
 679
 680         defaultmodel = "";
 681
 682         if(cvar("sv_defaultcharacter") == 1) {
 683                 defaultskin = 0;
 684
 685                 if(teams_matter)
 686                 {
 687                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 688                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 689                 }
 690
 691                 if(defaultmodel == "")
 692                 {
 693                         defaultmodel = cvar_string("sv_defaultplayermodel");
 694                         defaultskin = cvar("sv_defaultplayerskin");
 695                 }
 696         }
 697
 698         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 699         {
 700                 if(self.model != "")
 701                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 702                 self.model = ""; // force the != checks to return true
 703         }
 704
 705         if(defaultmodel != "")
 706         {
 707                 if (defaultmodel != self.model)
 708                 {
 709                         m1 = self.mins;
 710                         m2 = self.maxs;
 711                         setmodel_lod (self, defaultmodel);
 712                         setsize (self, m1, m2);
 713                         chmdl = TRUE;
 714                 }
 715
 716                 oldskin = self.skinindex;
 717                 self.skinindex = defaultskin;
 718         } else {
 719                 if (self.playermodel != self.model)
 720                 {
 721                         self.playermodel = CheckPlayerModel(self.playermodel);
 722                         m1 = self.mins;
 723                         m2 = self.maxs;
 724                         setmodel_lod (self, self.playermodel);
 725                         setsize (self, m1, m2);
 726                         chmdl = TRUE;
 727                 }
 728
 729                 oldskin = self.skinindex;
 730                 self.skinindex = RestrictSkin(stof(self.playerskin));
 731         }
 732
 733         if(chmdl || oldskin != self.skinindex)
 734                 self.species = player_getspecies(); // model or skin has changed
 735
 736         if(!teams_matter)
 737                 if(strlen(cvar_string("sv_defaultplayercolors")))
 738                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 739                                 setcolor(self, cvar("sv_defaultplayercolors"));
 740 }
 741
 742 void PlayerTouchExplode(entity p1, entity p2)
 743 {
 744         vector org;
 745         org = (p1.origin + p2.origin) * 0.5;
 746         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 747
 748         te_explosion(org);
 749
 750         entity e;
 751         e = spawn();
 752         setorigin(e, org);
 753         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 754         remove(e);
 755 }
 756
 757 /*
 758 =============
 759 PutClientInServer
 760
 761 Called when a client spawns in the server
 762 =============
 763 */
 764 //void() ctf_playerchanged;
 765 void PutClientInServer (void)
 766 {
 767         if(clienttype(self) == CLIENTTYPE_BOT)
 768         {
 769                 self.classname = "player";
 770         }
 771         else if(clienttype(self) == CLIENTTYPE_REAL)
 772         {
 773                 msg_entity = self;
 774                 WriteByte(MSG_ONE, SVC_SETVIEW);
 775                 WriteEntity(MSG_ONE, self);
 776         }
 777
 778         // player is dead and becomes observer
 779         // FIXME fix LMS scoring for new system
 780         if(g_lms)
 781         {
 782                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 783                         self.classname = "observer";
 784         }
 785
 786         if(g_arena)
 787         if(!self.spawned)
 788                 self.classname = "observer";
 789
 790         if(gameover)
 791                 self.classname = "observer";
 792
 793         if(self.classname == "player") {
 794                 entity spot, oldself;
 795
 796                 if(self.team < 0)
 797                         JoinBestTeam(self, FALSE, TRUE);
 798
 799                 race_PreSpawn();
 800
 801                 spot = SelectSpawnPoint (FALSE);
 802                 if(!spot)
 803                 {
 804                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 805                         return; // spawn failed
 806                 }
 807
 808                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 809                 self.campingrifle_bulletcounter = cvar("g_balance_campingrifle_magazinecapacity");
 810
 811                 self.classname = "player";
 812                 self.wasplayer = TRUE;
 813                 self.iscreature = TRUE;
 814                 self.movetype = MOVETYPE_WALK;
 815                 self.solid = SOLID_SLIDEBOX;
 816                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 817                 self.frags = FRAGS_PLAYER;
 818                 if(independent_players)
 819                         MAKE_INDEPENDENT_PLAYER(self);
 820                 self.flags = FL_CLIENT;
 821                 self.takedamage = DAMAGE_AIM;
 822                 if(g_minstagib)
 823                         self.effects = EF_FULLBRIGHT;
 824                 else
 825                         self.effects = 0;
 826                 self.air_finished = time + 12;
 827                 self.dmg = 2;
 828
 829                 if(inWarmupStage)
 830                 {
 831                         self.ammo_shells = warmup_start_ammo_shells;
 832                         self.ammo_nails = warmup_start_ammo_nails;
 833                         self.ammo_rockets = warmup_start_ammo_rockets;
 834                         self.ammo_cells = warmup_start_ammo_cells;
 835                         self.ammo_fuel = warmup_start_ammo_fuel;
 836                         self.health = warmup_start_health;
 837                         self.armorvalue = warmup_start_armorvalue;
 838                         self.weapons = warmup_start_weapons;
 839                 }
 840                 else
 841                 {
 842                         self.ammo_shells = start_ammo_shells;
 843                         self.ammo_nails = start_ammo_nails;
 844                         self.ammo_rockets = start_ammo_rockets;
 845                         self.ammo_cells = start_ammo_cells;
 846                         self.ammo_fuel = start_ammo_fuel;
 847                         self.health = start_health;
 848                         self.armorvalue = start_armorvalue;
 849                         self.weapons = start_weapons;
 850                 }
 851
 852                 if(g_weaponarena_random)
 853                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 854
 855                 self.items = start_items;
 856                 self.switchweapon = w_getbestweapon(self);
 857                 self.cnt = self.switchweapon;
 858                 self.weapon = 0;
 859                 self.jump_interval = time;
 860
 861                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 862                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 863                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 864                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 865                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 866                 //extend the pause of rotting if client was reset at the beginning of the countdown
 867                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 868                         self.spawnshieldtime += game_starttime - time;
 869                         self.pauserotarmor_finished += game_starttime - time;
 870                         self.pauserothealth_finished += game_starttime - time;
 871                         self.pauseregen_finished += game_starttime - time;
 872                 }
 873                 self.damageforcescale = 2;
 874                 self.death_time = 0;
 875                 self.dead_frame = 0;
 876                 self.alpha = 0;
 877                 self.scale = 0;
 878                 self.fade_time = 0;
 879                 self.pain_frame = 0;
 880                 self.pain_finished = 0;
 881                 self.strength_finished = 0;
 882                 self.invincible_finished = 0;
 883                 self.pushltime = 0;
 884                 //self.speed_finished = 0;
 885                 //self.slowmo_finished = 0;
 886                 // players have no think function
 887                 self.think = SUB_Null;
 888                 self.nextthink = 0;
 889                 self.hook_time = 0;
 890                 self.dmg_team = 0;
 891
 892                 self.metertime = 0;
 893
 894                 self.runes = 0;
 895
 896                 self.deadflag = DEAD_NO;
 897
 898                 self.angles = spot.angles;
 899
 900                 self.angles_z = 0; // never spawn tilted even if the spot says to
 901                 self.fixangle = TRUE; // turn this way immediately
 902                 self.velocity = '0 0 0';
 903                 self.avelocity = '0 0 0';
 904                 self.punchangle = '0 0 0';
 905                 self.punchvector = '0 0 0';
 906                 self.oldvelocity = self.velocity;
 907                 self.fire_endtime = -1;
 908
 909                 msg_entity = self;
 910                 WRITESPECTATABLE_MSG_ONE({
 911                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 912                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 913                 });
 914
 915                 if(sv_loddistance1)
 916                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 917
 918                 self.model = "";
 919                 FixPlayermodel();
 920
 921                 self.crouch = FALSE;
 922                 self.view_ofs = PL_VIEW_OFS;
 923                 setsize (self, PL_MIN, PL_MAX);
 924                 self.spawnorigin = spot.origin;
 925                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 926                 // don't reset back to last position, even if new position is stuck in solid
 927                 self.oldorigin = self.origin;
 928                 self.prevorigin = self.origin;
 929                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 930
 931                 if(g_arena)
 932                 {
 933                         Spawnqueue_Remove(self);
 934                         Spawnqueue_Mark(self);
 935                 }
 936
 937                 self.event_damage = PlayerDamage;
 938
 939                 self.bot_attack = TRUE;
 940
 941                 self.statdraintime = time + 5;
 942                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 943
 944                 if(self.killcount == -666) {
 945                         PlayerScore_Clear(self);
 946                         self.killcount = 0;
 947                 }
 948
 949                 self.cnt = WEP_LASER;
 950                 self.nixnex_lastchange_id = -1;
 951
 952                 CL_SpawnWeaponentity();
 953                 self.alpha = default_player_alpha;
 954                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 955                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 956
 957                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 958                 self.lms_traveled_distance = 0;
 959                 self.speedrunning = FALSE;
 960
 961                 race_PostSpawn(spot);
 962
 963                 if(cvar("spawn_debug"))
 964                 {
 965                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 966                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 967                 }
 968
 969                 //stuffcmd(self, "chase_active 0");
 970                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 971
 972                 if (cvar("g_spawnsound"))
 973                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 974
 975                 if(g_assault) {
 976                         if(self.team == assault_attacker_team)
 977                                 centerprint(self, "You are attacking!");
 978                         else
 979                                 centerprint(self, "You are defending!");
 980                 }
 981
 982                 target_voicescript_clear(self);
 983
 984                 oldself = self;
 985                 self = spot;
 986                         activator = oldself;
 987                                 SUB_UseTargets();
 988                         activator = world;
 989                 self = oldself;
 990
 991         } else if(self.classname == "observer") {
 992                 PutObserverInServer ();
 993         }
 994
 995         //if(g_ctf)
 996         //      ctf_playerchanged();
 997 }
 998
 999 float ClientInit_SendEntity(entity to, float sf)
1000 {
1001         float i;
1002         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1003         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1004         for(i = 1; i <= 24; ++i)
1005                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1006         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1007         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1008         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1009
1010         if(sv_foginterval && world.fog != "")
1011                 WriteString(MSG_ENTITY, world.fog);
1012         else
1013                 WriteString(MSG_ENTITY, "");
1014         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1015         return TRUE;
1016 }
1017
1018 void ClientInit_Spawn()
1019 {
1020         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1021 }
1022
1023 /*
1024 =============
1025 SetNewParms
1026 =============
1027 */
1028 void SetNewParms (void)
1029 {
1030         // initialize parms for a new player
1031         parm1 = -(86400 * 366);
1032 }
1033
1034 /*
1035 =============
1036 SetChangeParms
1037 =============
1038 */
1039 void SetChangeParms (void)
1040 {
1041         // save parms for level change
1042         parm1 = self.parm_idlesince - time;
1043 }
1044
1045 /*
1046 =============
1047 DecodeLevelParms
1048 =============
1049 */
1050 void DecodeLevelParms (void)
1051 {
1052         // load parms
1053         self.parm_idlesince = parm1;
1054         if(self.parm_idlesince == -(86400 * 366))
1055                 self.parm_idlesince = time;
1056
1057         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1058         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1059 }
1060
1061 /*
1062 =============
1063 ClientKill
1064
1065 Called when a client types 'kill' in the console
1066 =============
1067 */
1068
1069 void ClientKill_Now_TeamChange()
1070 {
1071         if(self.killindicator_teamchange == -1)
1072         {
1073                 self.team = -1;
1074                 JoinBestTeam( self, FALSE, FALSE );
1075         }
1076         else
1077                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1078 }
1079
1080 void ClientKill_Now()
1081 {
1082         if(self.killindicator_teamchange)
1083                 ClientKill_Now_TeamChange();
1084
1085         // in any case:
1086         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1087
1088         if(self.killindicator)
1089         {
1090                 dprint("Cleaned up after a leaked kill indicator.\n");
1091                 remove(self.killindicator);
1092                 self.killindicator = world;
1093         }
1094 }
1095 void KillIndicator_Think()
1096 {
1097         if (!self.owner.modelindex)
1098         {
1099                 self.owner.killindicator = world;
1100                 remove(self);
1101                 return;
1102         }
1103
1104         if(self.cnt <= 0)
1105         {
1106                 self = self.owner;
1107                 ClientKill_Now(); // no oldself needed
1108                 return;
1109         }
1110         else
1111         {
1112                 if(self.cnt <= 10)
1113                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1114                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1115                 {
1116                         if(self.cnt <= 10)
1117                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1118                         if(self.owner.killindicator_teamchange)
1119                         {
1120                                 if(self.owner.killindicator_teamchange == -1)
1121                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1122                                 else
1123                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1124                         }
1125                         else
1126                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1127                 }
1128                 self.nextthink = time + 1;
1129                 self.cnt -= 1;
1130         }
1131 }
1132
1133 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1134 {
1135         float killtime;
1136         entity e;
1137         killtime = cvar("g_balance_kill_delay");
1138
1139         if(g_race_qualifying)
1140                 killtime = 0;
1141
1142         self.killindicator_teamchange = targetteam;
1143
1144         if(!self.killindicator)
1145         {
1146                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1147                 {
1148                         ClientKill_Now();
1149                 }
1150                 else
1151                 {
1152                         self.killindicator = spawn();
1153                         self.killindicator.owner = self;
1154                         self.killindicator.scale = 0.5;
1155                         setattachment(self.killindicator, self, "");
1156                         setorigin(self.killindicator, '0 0 52');
1157                         self.killindicator.think = KillIndicator_Think;
1158                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1159                         self.killindicator.cnt = ceil(killtime);
1160                         self.killindicator.count = bound(0, ceil(killtime), 10);
1161                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1162
1163                         for(e = world; (e = find(e, classname, "body")) != world; )
1164                         {
1165                                 if(e.enemy != self)
1166                                         continue;
1167                                 e.killindicator = spawn();
1168                                 e.killindicator.owner = e;
1169                                 e.killindicator.scale = 0.5;
1170                                 setattachment(e.killindicator, e, "");
1171                                 setorigin(e.killindicator, '0 0 52');
1172                                 e.killindicator.think = KillIndicator_Think;
1173                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1174                                 e.killindicator.cnt = ceil(killtime);
1175                         }
1176                         self.lip = 0;
1177                 }
1178         }
1179         if(self.killindicator)
1180         {
1181                 if(targetteam)
1182                         self.killindicator.colormod = TeamColor(targetteam);
1183                 else
1184                         self.killindicator.colormod = '0 0 0';
1185         }
1186 }
1187
1188 void ClientKill (void)
1189 {
1190         ClientKill_TeamChange(0);
1191 }
1192
1193 void DoTeamChange(float destteam)
1194 {
1195         float t, c0;
1196         if(!teams_matter)
1197         {
1198                 if(destteam >= 0)
1199                         SetPlayerColors(self, destteam);
1200                 return;
1201         }
1202         if(self.classname == "player")
1203         if(destteam == -1)
1204         {
1205                 CheckAllowedTeams(self);
1206                 t = FindSmallestTeam(self, TRUE);
1207                 switch(self.team)
1208                 {
1209                         case COLOR_TEAM1: c0 = c1; break;
1210                         case COLOR_TEAM2: c0 = c2; break;
1211                         case COLOR_TEAM3: c0 = c3; break;
1212                         case COLOR_TEAM4: c0 = c4; break;
1213                         default:          c0 = 999;
1214                 }
1215                 switch(t)
1216                 {
1217                         case 1:
1218                                 if(c0 > c1)
1219                                         destteam = COLOR_TEAM1;
1220                                 break;
1221                         case 2:
1222                                 if(c0 > c2)
1223                                         destteam = COLOR_TEAM2;
1224                                 break;
1225                         case 3:
1226                                 if(c0 > c3)
1227                                         destteam = COLOR_TEAM3;
1228                                 break;
1229                         case 4:
1230                                 if(c0 > c4)
1231                                         destteam = COLOR_TEAM4;
1232                                 break;
1233                 }
1234                 if(destteam == -1)
1235                         return;
1236         }
1237         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1238                 return;
1239         ClientKill_TeamChange(destteam);
1240 }
1241
1242 void FixClientCvars(entity e)
1243 {
1244         // send prediction settings to the client
1245         stuffcmd(e, "\nin_bindmap 0 0\n");
1246         if(g_race || g_cts)
1247                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1248         /*
1249          * we no longer need to stuff this. Remove this comment block if you feel
1250          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1251         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1252         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1253         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1254         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1255         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1256         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1257         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1258         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1259         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1260         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1261         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1262         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1263         stuffcmd(e, "cl_movement_edgefriction 1\n");
1264          */
1265 }
1266
1267 /*
1268 =============
1269 ClientConnect
1270
1271 Called when a client connects to the server
1272 =============
1273 */
1274 //void ctf_clientconnect();
1275 string ColoredTeamName(float t);
1276 void DecodeLevelParms (void);
1277 //void dom_player_join_team(entity pl);
1278 void ClientConnect (void)
1279 {
1280         local string s;
1281         float t;
1282
1283         if(self.flags & FL_CLIENT)
1284         {
1285                 print("Warning: ClientConnect, but already connected!\n");
1286                 return;
1287         }
1288
1289         if(Ban_MaybeEnforceBan(self))
1290                 return;
1291
1292         DecodeLevelParms();
1293
1294         self.classname = "player_joining";
1295
1296         self.flags = FL_CLIENT;
1297         self.version_nagtime = time + 10 + random() * 10;
1298
1299         if(player_count<0)
1300         {
1301                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1302                 player_count = 0;
1303         }
1304
1305         PlayerScore_Attach(self);
1306         ClientData_Attach();
1307
1308         bot_clientconnect();
1309
1310         race_PreSpawnObserver();
1311
1312         //if(g_domination)
1313         //      dom_player_join_team(self);
1314
1315         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1316
1317         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1318                 self.classname = "observer";
1319         } else {
1320                 if(teams_matter)
1321                 {
1322                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1323                         {
1324                                 self.classname = "player";
1325                                 campaign_bots_may_start = 1;
1326                         }
1327                         else
1328                         {
1329                                 self.classname = "observer"; // do it anyway
1330                         }
1331                 }
1332                 else
1333                 {
1334                         self.classname = "player";
1335                         campaign_bots_may_start = 1;
1336                 }
1337         }
1338
1339         self.playerid = (playerid_last = playerid_last + 1);
1340         if(cvar("sv_eventlog"))
1341         {
1342                 if(clienttype(self) == CLIENTTYPE_REAL)
1343                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1344                 else
1345                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1346                 s = strcat(":team:", ftos(self.playerid), ":");
1347                 s = strcat(s, ftos(self.team));
1348                 GameLogEcho(s);
1349         }
1350         self.netname_previous = strzone(self.netname);
1351
1352         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1353
1354         bprint ("^4",self.netname);
1355         bprint ("^4 connected");
1356
1357         if(g_domination || g_ctf)
1358         {
1359                 bprint(" and joined the ");
1360                 bprint(ColoredTeamName(self.team));
1361         }
1362
1363         bprint("\n");
1364
1365         self.welcomemessage_time = 0;
1366
1367         stuffcmd(self, strcat(clientstuff, "\n"));
1368         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1369         stuffcmd(self, "cl_particles_reloadeffects\n");
1370
1371         FixClientCvars(self);
1372
1373         // spawnfunc_waypoint sprites
1374         WaypointSprite_InitClient(self);
1375
1376         // Wazat's grappling hook
1377         SetGrappleHookBindings();
1378
1379         // get autoswitch state from player when he toggles it
1380         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1381
1382         // get version info from player
1383         stuffcmd(self, "cmd clientversion $gameversion\n");
1384
1385         // get other cvars from player
1386         GetCvars(0);
1387
1388         // set cvar for team scoreboard
1389         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1390
1391         // notify about available teams
1392         if(teams_matter)
1393         {
1394                 CheckAllowedTeams(self);
1395                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1396                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1397         }
1398         else
1399                 stuffcmd(self, "set _teams_available 0\n");
1400
1401         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1402
1403         if(g_arena)
1404         {
1405                 self.classname = "observer";
1406                 Spawnqueue_Insert(self);
1407         }
1408         /*else if(g_ctf)
1409         {
1410                 ctf_clientconnect();
1411         }*/
1412
1413         if(teams_matter || sv_cheats)
1414                 attach_entcs();
1415
1416         bot_relinkplayerlist();
1417
1418         self.spectatortime = time;
1419         if(blockSpectators)
1420         {
1421                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1422         }
1423
1424         self.jointime = time;
1425         self.allowedTimeouts = cvar("sv_timeout_number");
1426
1427         if(clienttype(self) == CLIENTTYPE_REAL)
1428         {
1429                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1430                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1431         }
1432
1433         if(g_lms)
1434         {
1435                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1436                 {
1437                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1438                         self.frags = FRAGS_SPECTATOR;
1439                 }
1440         }
1441
1442         if(!sv_foginterval && world.fog != "")
1443                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1444
1445         SoundEntity_Attach(self);
1446
1447         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1448         {
1449                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1450                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1451         }
1452         else
1453                 self.hitplotfh = -1;
1454 }
1455
1456 /*
1457 =============
1458 ClientDisconnect
1459
1460 Called when a client disconnects from the server
1461 =============
1462 */
1463 .entity chatbubbleentity;
1464 .entity teambubbleentity;
1465 void ReadyCount();
1466 void ClientDisconnect (void)
1467 {
1468         if not(self.flags & FL_CLIENT)
1469         {
1470                 print("Warning: ClientDisconnect without ClientConnect\n");
1471                 return;
1472         }
1473
1474         if(self.hitplotfh >= 0)
1475         {
1476                 fclose(self.hitplotfh);
1477                 self.hitplotfh = -1;
1478         }
1479
1480         bot_clientdisconnect();
1481
1482         if(self.entcs)
1483                 detach_entcs();
1484
1485         if(cvar("sv_eventlog"))
1486                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1487         bprint ("^4",self.netname);
1488         bprint ("^4 disconnected\n");
1489
1490         SoundEntity_Detach(self);
1491
1492         DropAllRunes(self);
1493         kh_Key_DropAll(self, TRUE);
1494
1495         Portal_ClearAll(self);
1496
1497         if(self.flagcarried)
1498                 DropFlag(self.flagcarried, world, world);
1499         if(self.ballcarried)
1500                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1501
1502         // Here, everything has been done that requires this player to be a client.
1503
1504         self.flags &~= FL_CLIENT;
1505
1506         if (self.chatbubbleentity)
1507                 remove (self.chatbubbleentity);
1508
1509         if (self.teambubbleentity)
1510                 remove (self.teambubbleentity);
1511
1512         if (self.killindicator)
1513                 remove (self.killindicator);
1514
1515         WaypointSprite_PlayerGone();
1516
1517         bot_relinkplayerlist();
1518
1519         // remove laserdot
1520         if(self.weaponentity)
1521                 if(self.weaponentity.lasertarget)
1522                         remove(self.weaponentity.lasertarget);
1523
1524         if(g_arena)
1525         {
1526                 Spawnqueue_Unmark(self);
1527                 Spawnqueue_Remove(self);
1528         }
1529
1530         ClientData_Detach();
1531         PlayerScore_Detach(self);
1532
1533         if(self.netname_previous)
1534                 strunzone(self.netname_previous);
1535         if(self.clientstatus)
1536                 strunzone(self.clientstatus);
1537
1538         ClearPlayerSounds();
1539
1540         self.playerid = 0;
1541         ReadyCount();
1542
1543         // free cvars
1544         GetCvars(-1);
1545 }
1546
1547 .float BUTTON_CHAT;
1548 void ChatBubbleThink()
1549 {
1550         self.nextthink = time;
1551         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1552         {
1553                 if(self.owner) // but why can that ever be world?
1554                         self.owner.chatbubbleentity = world;
1555                 remove(self);
1556                 return;
1557         }
1558         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1559 #ifdef TETRIS
1560                 || self.owner.tetris_on
1561 #endif
1562         )
1563                 self.model = self.mdl;
1564         else
1565                 self.model = "";
1566 };
1567
1568 void UpdateChatBubble()
1569 {
1570         if (!self.modelindex)
1571                 return;
1572         // spawn a chatbubble entity if needed
1573         if (!self.chatbubbleentity)
1574         {
1575                 self.chatbubbleentity = spawn();
1576                 self.chatbubbleentity.owner = self;
1577                 self.chatbubbleentity.exteriormodeltoclient = self;
1578                 self.chatbubbleentity.think = ChatBubbleThink;
1579                 self.chatbubbleentity.nextthink = time;
1580                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1581                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1582                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1583                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1584                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1585                 self.chatbubbleentity.model = "";
1586                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1587         }
1588 }
1589
1590
1591 void TeamBubbleThink()
1592 {
1593         self.nextthink = time;
1594         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1595         {
1596                 if(self.owner) // but why can that ever be world?
1597                         self.owner.teambubbleentity = world;
1598                 remove(self);
1599                 return;
1600         }
1601 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1602         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1603                 self.model = "";
1604         else
1605                 self.model = self.mdl;
1606
1607 };
1608
1609 float TeamBubble_customizeentityforclient()
1610 {
1611         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1612 }
1613
1614 void UpdateTeamBubble()
1615 {
1616         if (!self.modelindex || !teams_matter)
1617                 return;
1618         // spawn a teambubble entity if needed
1619         if (!self.teambubbleentity && teams_matter)
1620         {
1621                 self.teambubbleentity = spawn();
1622                 self.teambubbleentity.owner = self;
1623                 self.teambubbleentity.exteriormodeltoclient = self;
1624                 self.teambubbleentity.think = TeamBubbleThink;
1625                 self.teambubbleentity.nextthink = time;
1626                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1627 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1628                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1629                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1630                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1631                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1632                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1633                 self.teambubbleentity.effects = EF_LOWPRECISION;
1634         }
1635 }
1636
1637 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1638 // added to the model skins
1639 /*void UpdateColorModHack()
1640 {
1641         local float c;
1642         c = self.clientcolors & 15;
1643         // LordHavoc: only bothering to support white, green, red, yellow, blue
1644              if (!teams_matter) self.colormod = '0 0 0';
1645         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1646         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1647         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1648         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1649         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1650         else self.colormod = '1 1 1';
1651 };*/
1652
1653 void respawn(void)
1654 {
1655         CopyBody(1);
1656         self.effects |= EF_NODRAW; // prevent another CopyBody
1657         PutClientInServer();
1658 }
1659
1660 void play_countdown(float finished, string samp)
1661 {
1662         if(clienttype(self) == CLIENTTYPE_REAL)
1663                 if(floor(finished - time - frametime) != floor(finished - time))
1664                         if(finished - time < 6)
1665                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1666 }
1667
1668 /**
1669  * When sv_timeout is used this function returs strings like
1670  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1671  * Called by centerprint functions
1672  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1673  */
1674 string getTimeoutText(float addOneSecond) {
1675         if (!cvar("sv_timeout") || !timeoutStatus)
1676                 return "";
1677
1678         local string retStr;
1679         if (timeoutStatus == 1) {
1680                 if (addOneSecond == 1) {
1681                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1682                 }
1683                 else {
1684                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1685                 }
1686                 return retStr;
1687         }
1688         else if (timeoutStatus == 2) {
1689                 if (addOneSecond) {
1690                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1691                         //don't show messages like "Timeout ends in 0 seconds"...
1692                         if ((remainingTimeoutTime + 1) > 0)
1693                                 return retStr;
1694                         else
1695                                 return "";
1696                 }
1697                 else {
1698                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1699                         //don't show messages like "Timeout ends in 0 seconds"...
1700                         if (remainingTimeoutTime > 0)
1701                                 return retStr;
1702                         else
1703                                 return "";
1704                 }
1705         }
1706         else return "";
1707 }
1708
1709 void player_powerups (void)
1710 {
1711         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1712         {
1713                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1714                 self.modelflags |= MF_ROCKET;
1715         }
1716         else
1717         {
1718                 SoundEntity_StopSound(self, CHAN_PLAYER);
1719                 self.modelflags &~= MF_ROCKET;
1720         }
1721
1722         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME);
1723
1724         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1725                 return;
1726
1727         Fire_ApplyDamage(self);
1728         Fire_ApplyEffect(self);
1729
1730         if (g_minstagib)
1731         {
1732                 self.effects |= EF_FULLBRIGHT;
1733
1734                 if (self.items & IT_STRENGTH)
1735                 {
1736                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1737                         if (time > self.strength_finished)
1738                         {
1739                                 self.alpha = default_player_alpha;
1740                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1741                                 self.items &~= IT_STRENGTH;
1742                                 sprint(self, "^3Invisibility has worn off\n");
1743                         }
1744                 }
1745                 else
1746                 {
1747                         if (time < self.strength_finished)
1748                         {
1749                                 self.alpha = g_minstagib_invis_alpha;
1750                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1751                                 self.items |= IT_STRENGTH;
1752                                 sprint(self, "^3You are invisible\n");
1753                         }
1754                 }
1755
1756                 if (self.items & IT_INVINCIBLE)
1757                 {
1758                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1759                         if (time > self.invincible_finished)
1760                         {
1761                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1762                                 sprint(self, "^3Speed has worn off\n");
1763                         }
1764                 }
1765                 else
1766                 {
1767                         if (time < self.invincible_finished)
1768                         {
1769                                 self.items = self.items | IT_INVINCIBLE;
1770                                 sprint(self, "^3You are on speed\n");
1771                         }
1772                 }
1773                 return;
1774         }
1775
1776         if (self.items & IT_STRENGTH)
1777         {
1778                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1779                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1780                 if (time > self.strength_finished)
1781                 {
1782                         self.items = self.items - (self.items & IT_STRENGTH);
1783                         sprint(self, "^3Strength has worn off\n");
1784                 }
1785         }
1786         else
1787         {
1788                 if (time < self.strength_finished)
1789                 {
1790                         self.items = self.items | IT_STRENGTH;
1791                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1792                 }
1793         }
1794         if (self.items & IT_INVINCIBLE)
1795         {
1796                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1797                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1798                 if (time > self.invincible_finished)
1799                 {
1800                         self.items = self.items - (self.items & IT_INVINCIBLE);
1801                         sprint(self, "^3Shield has worn off\n");
1802                 }
1803         }
1804         else
1805         {
1806                 if (time < self.invincible_finished)
1807                 {
1808                         self.items = self.items | IT_INVINCIBLE;
1809                         sprint(self, "^3Shield surrounds you\n");
1810                 }
1811         }
1812
1813         if (cvar("g_fullbrightplayers"))
1814                 self.effects = self.effects | EF_FULLBRIGHT;
1815
1816         // midair gamemode: damage only while in the air
1817         // if in midair mode, being on ground grants temporary invulnerability
1818         // (this is so that multishot weapon don't clear the ground flag on the
1819         // first damage in the frame, leaving the player vulnerable to the
1820         // remaining hits in the same frame)
1821         if (self.flags & FL_ONGROUND)
1822         if (g_midair)
1823                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1824
1825         if (time >= game_starttime)
1826         if (time < self.spawnshieldtime)
1827                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1828 }
1829
1830 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1831 {
1832         if(current > stable)
1833                 return current;
1834         else if(current > stable - 0.25) // when close enough, "snap"
1835                 return stable;
1836         else
1837                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1838 }
1839
1840 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1841 {
1842         if(current < stable)
1843                 return current;
1844         else if(current < stable + 0.25) // when close enough, "snap"
1845                 return stable;
1846         else
1847                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1848 }
1849
1850 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1851 {
1852         if(current > rotstable)
1853         {
1854                 if(rotframetime > 0)
1855                 {
1856                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1857                         current = max(rotstable, current - rotlinear * rotframetime);
1858                 }
1859         }
1860         else if(current < regenstable)
1861         {
1862                 if(regenframetime > 0)
1863                 {
1864                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1865                         current = min(regenstable, current + regenlinear * regenframetime);
1866                 }
1867         }
1868
1869         if(current > limit)
1870                 current = limit;
1871
1872         return current;
1873 }
1874
1875 void player_regen (void)
1876 {
1877         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1878         maxh = cvar("g_balance_health_rotstable");
1879         maxa = cvar("g_balance_armor_rotstable");
1880         maxf = cvar("g_balance_fuel_rotstable");
1881         minh = cvar("g_balance_health_regenstable");
1882         mina = cvar("g_balance_armor_regenstable");
1883         minf = cvar("g_balance_fuel_regenstable");
1884         limith = cvar("g_balance_health_limit");
1885         limita = cvar("g_balance_armor_limit");
1886         limitf = cvar("g_balance_fuel_limit");
1887
1888         max_mod = regen_mod = rot_mod = limit_mod = 1;
1889
1890         if (self.runes & RUNE_REGEN)
1891         {
1892                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1893                 {
1894                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1895                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1896                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1897                 }
1898                 else
1899                 {
1900                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1901                         max_mod = cvar("g_balance_rune_regen_hpmod");
1902                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1903                 }
1904         }
1905         else if (self.runes & CURSE_VENOM)
1906         {
1907                 max_mod = cvar("g_balance_curse_venom_hpmod");
1908                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1909                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1910                 else
1911                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1912                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1913                 //if (!self.runes & RUNE_REGEN)
1914                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1915         }
1916         maxh = maxh * max_mod;
1917         //maxa = maxa * max_mod;
1918         //maxf = maxf * max_mod;
1919         minh = minh * max_mod;
1920         //mina = mina * max_mod;
1921         //minf = minf * max_mod;
1922         limith = limith * limit_mod;
1923         limita = limita * limit_mod;
1924         //limitf = limitf * limit_mod;
1925
1926         if(g_lms)
1927                 rot_mod = 0;
1928
1929         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1930         {
1931                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1932                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1933
1934                 // if player rotted to death...  die!
1935                 if(self.health < 1)
1936                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1937         }
1938
1939         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1940                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1941 }
1942
1943 float zoomstate_set;
1944 void SetZoomState(float z)
1945 {
1946         if(z != self.zoomstate)
1947         {
1948                 self.zoomstate = z;
1949                 ClientData_Touch(self);
1950         }
1951         zoomstate_set = 1;
1952 }
1953
1954 void GetPressedKeys(void) {
1955         if (self.movement_x > 0) // get if movement keys are pressed
1956         {       // forward key pressed
1957                 self.pressedkeys |= KEY_FORWARD;
1958                 self.pressedkeys &~= KEY_BACKWARD;
1959         }
1960         else if (self.movement_x < 0)
1961         {       // backward key pressed
1962                 self.pressedkeys |= KEY_BACKWARD;
1963                 self.pressedkeys &~= KEY_FORWARD;
1964         }
1965         else
1966         {       // no x input
1967                 self.pressedkeys &~= KEY_FORWARD;
1968                 self.pressedkeys &~= KEY_BACKWARD;
1969         }
1970
1971         if (self.movement_y > 0)
1972         {       // right key pressed
1973                 self.pressedkeys |= KEY_RIGHT;
1974                 self.pressedkeys &~= KEY_LEFT;
1975         }
1976         else if (self.movement_y < 0)
1977         {       // left key pressed
1978                 self.pressedkeys |= KEY_LEFT;
1979                 self.pressedkeys &~= KEY_RIGHT;
1980         }
1981         else
1982         {       // no y input
1983                 self.pressedkeys &~= KEY_RIGHT;
1984                 self.pressedkeys &~= KEY_LEFT;
1985         }
1986
1987         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1988                 self.pressedkeys |= KEY_JUMP;
1989         else
1990                 self.pressedkeys &~= KEY_JUMP;
1991         if (self.BUTTON_CROUCH)
1992                 self.pressedkeys |= KEY_CROUCH;
1993         else
1994                 self.pressedkeys &~= KEY_CROUCH;
1995 }
1996
1997 /*
1998 ======================
1999 spectate mode routines
2000 ======================
2001 */
2002 void SpectateCopy(entity spectatee) {
2003         self.armortype = spectatee.armortype;
2004         self.armorvalue = spectatee.armorvalue;
2005         self.ammo_cells = spectatee.ammo_cells;
2006         self.ammo_shells = spectatee.ammo_shells;
2007         self.ammo_nails = spectatee.ammo_nails;
2008         self.ammo_rockets = spectatee.ammo_rockets;
2009         self.ammo_fuel = spectatee.ammo_fuel;
2010         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2011         self.health = spectatee.health;
2012         self.impulse = 0;
2013         self.items = spectatee.items;
2014         self.metertime = spectatee.metertime;
2015         self.strength_finished = spectatee.strength_finished;
2016         self.invincible_finished = spectatee.invincible_finished;
2017         self.pressedkeys = spectatee.pressedkeys;
2018         self.weapons = spectatee.weapons;
2019         self.switchweapon = spectatee.switchweapon;
2020         self.weapon = spectatee.weapon;
2021         self.punchangle = spectatee.punchangle;
2022         self.view_ofs = spectatee.view_ofs;
2023         self.v_angle = spectatee.v_angle;
2024         self.velocity = spectatee.velocity;
2025         self.dmg_take = spectatee.dmg_take;
2026         self.dmg_save = spectatee.dmg_save;
2027         self.dmg_inflictor = spectatee.dmg_inflictor;
2028         self.angles = spectatee.v_angle;
2029         self.fixangle = TRUE;
2030         setorigin(self, spectatee.origin);
2031         setsize(self, spectatee.mins, spectatee.maxs);
2032         SetZoomState(spectatee.zoomstate);
2033 }
2034
2035 float SpectateUpdate() {
2036         if(!self.enemy)
2037                 return 0;
2038
2039         if (self == self.enemy)
2040                 return 0;
2041
2042         if(self.enemy.classname != "player")
2043                 return 0;
2044
2045         SpectateCopy(self.enemy);
2046
2047         return 1;
2048 }
2049
2050 float SpectateNext() {
2051         other = find(self.enemy, classname, "player");
2052         if (!other) {
2053                 other = find(other, classname, "player");
2054         }
2055         if (other) {
2056                 self.enemy = other;
2057         }
2058         if(self.enemy.classname == "player") {
2059                 msg_entity = self;
2060                 WriteByte(MSG_ONE, SVC_SETVIEW);
2061                 WriteEntity(MSG_ONE, self.enemy);
2062                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2063                 self.movetype = MOVETYPE_NONE;
2064                 if(!SpectateUpdate())
2065                         PutObserverInServer();
2066                 return 1;
2067         } else {
2068                 return 0;
2069         }
2070 }
2071
2072 /*
2073 =============
2074 ShowRespawnCountdown()
2075
2076 Update a respawn countdown display.
2077 =============
2078 */
2079 void ShowRespawnCountdown()
2080 {
2081         float number;
2082         if(self.deadflag == DEAD_NO) // just respawned?
2083                 return;
2084         else
2085         {
2086                 number = ceil(self.death_time - time);
2087                 if(number <= 0)
2088                         return;
2089                 if(number <= self.respawn_countdown)
2090                 {
2091                         self.respawn_countdown = number - 1;
2092                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2093                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2094                 }
2095         }
2096 }
2097
2098 void LeaveSpectatorMode()
2099 {
2100         if(isJoinAllowed()) {
2101                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2102                         self.classname = "player";
2103                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2104                                 JoinBestTeam(self, FALSE, TRUE);
2105                         if(cvar("g_campaign"))
2106                                 campaign_bots_may_start = 1;
2107                         PutClientInServer();
2108                         if(self.classname == "player")
2109                                 bprint ("^4", self.netname, "^4 is playing now\n");
2110                         if(!cvar("g_campaign"))
2111                                 centerprint(self,""); // clear MOTD
2112                         return;
2113                 } else {
2114                         stuffcmd(self,"menu_showteamselect\n");
2115                         return;
2116                 }
2117         }
2118         else {
2119                 //player may not join because of g_maxplayers is set
2120                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2121         }
2122 }
2123
2124 /**
2125  * Determines whether the player is allowed to join. This depends on cvar
2126  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2127  * it checks whether the number of currently playing players exceeds g_maxplayers.
2128  * @return bool TRUE if the player is allowed to join, false otherwise
2129  */
2130 float isJoinAllowed() {
2131         if (!cvar("g_maxplayers"))
2132                 return TRUE;
2133
2134         local entity e;
2135         local float currentlyPlaying;
2136         FOR_EACH_REALPLAYER(e) {
2137                 if(e.classname == "player")
2138                         currentlyPlaying += 1;
2139         }
2140         if(currentlyPlaying < cvar("g_maxplayers"))
2141                 return TRUE;
2142
2143         return FALSE;
2144 }
2145
2146 /**
2147  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2148  * g_maxplayers_spectator_blocktime seconds
2149  */
2150 void checkSpectatorBlock() {
2151         if(self.classname == "spectator" || self.classname == "observer") {
2152                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2153                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2154                         dropclient(self);
2155                 }
2156         }
2157 }
2158
2159 float vercmp_recursive(string v1, string v2)
2160 {
2161         float dot1, dot2;
2162         string s1, s2;
2163         float r;
2164
2165         dot1 = strstrofs(v1, ".", 0);
2166         dot2 = strstrofs(v2, ".", 0);
2167         if(dot1 == -1)
2168                 s1 = v1;
2169         else
2170                 s1 = substring(v1, 0, dot1);
2171         if(dot2 == -1)
2172                 s2 = v2;
2173         else
2174                 s2 = substring(v2, 0, dot2);
2175
2176         r = stof(s1) - stof(s2);
2177         if(r != 0)
2178                 return r;
2179
2180         r = strcasecmp(s1, s2);
2181         if(r != 0)
2182                 return r;
2183
2184         if(dot1 == -1)
2185                 if(dot2 == -1)
2186                         return 0;
2187                 else
2188                         return -1;
2189         else
2190                 if(dot2 == -1)
2191                         return 1;
2192                 else
2193                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2194 }
2195
2196 float vercmp(string v1, string v2)
2197 {
2198         if(strcasecmp(v1, v2) == 0) // early out check
2199                 return 0;
2200         return vercmp_recursive(v1, v2);
2201 }
2202
2203 void ObserverThink()
2204 {
2205         if (self.flags & FL_JUMPRELEASED) {
2206                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2207                         self.welcomemessage_time = 0;
2208                         self.flags &~= FL_JUMPRELEASED;
2209                         self.flags |= FL_SPAWNING;
2210                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2211                         self.welcomemessage_time = 0;
2212                         self.flags &~= FL_JUMPRELEASED;
2213                         if(SpectateNext() == 1) {
2214                                 self.classname = "spectator";
2215                         }
2216                 }
2217         } else {
2218                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2219                         self.flags |= FL_JUMPRELEASED;
2220                         if(self.flags & FL_SPAWNING)
2221                         {
2222                                 self.flags &~= FL_SPAWNING;
2223                                 LeaveSpectatorMode();
2224                                 return;
2225                         }
2226                 }
2227         }
2228         PrintWelcomeMessage(self);
2229 }
2230
2231 void SpectatorThink()
2232 {
2233         if (self.flags & FL_JUMPRELEASED) {
2234                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2235                         self.welcomemessage_time = 0;
2236                         self.flags &~= FL_JUMPRELEASED;
2237                         self.flags |= FL_SPAWNING;
2238                 } else if(self.BUTTON_ATCK) {
2239                         self.welcomemessage_time = 0;
2240                         self.flags &~= FL_JUMPRELEASED;
2241                         if(SpectateNext() == 1) {
2242                                 self.classname = "spectator";
2243                         } else {
2244                                 self.classname = "observer";
2245                                 PutClientInServer();
2246                         }
2247                 } else if (self.BUTTON_ATCK2) {
2248                         self.welcomemessage_time = 0;
2249                         self.flags &~= FL_JUMPRELEASED;
2250                         self.classname = "observer";
2251                         PutClientInServer();
2252                 } else {
2253                         if(!SpectateUpdate())
2254                                 PutObserverInServer();
2255                 }
2256         } else {
2257                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2258                         self.flags |= FL_JUMPRELEASED;
2259                         if(self.flags & FL_SPAWNING)
2260                         {
2261                                 self.flags &~= FL_SPAWNING;
2262                                 LeaveSpectatorMode();
2263                                 return;
2264                         }
2265                 }
2266         }
2267         PrintWelcomeMessage(self);
2268         self.flags |= FL_CLIENT | FL_NOTARGET;
2269 }
2270
2271 .float touchexplode_time;
2272
2273 /*
2274 =============
2275 PlayerPreThink
2276
2277 Called every frame for each client before the physics are run
2278 =============
2279 */
2280 void() ctf_setstatus;
2281 void() nexball_setstatus;
2282 .float items_added;
2283 void PlayerPreThink (void)
2284 {
2285         self.stat_game_starttime = game_starttime;
2286         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2287         self.stat_leadlimit = cvar("leadlimit");
2288
2289         if(blockSpectators && frametime)
2290                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2291                 checkSpectatorBlock();
2292
2293         zoomstate_set = 0;
2294
2295         if(self.netname_previous != self.netname)
2296         {
2297                 if(cvar("sv_eventlog"))
2298                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2299                 if(self.netname_previous)
2300                         strunzone(self.netname_previous);
2301                 self.netname_previous = strzone(self.netname);
2302         }
2303
2304         // version nagging
2305         if(self.version_nagtime)
2306                 if(self.cvar_g_nexuizversion)
2307                         if(time > self.version_nagtime)
2308                         {
2309                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2310                                 {
2311                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2312                                         {
2313                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2314                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2315                                         }
2316                                         else
2317                                         {
2318                                                 float r;
2319                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2320                                                 if(r < 0)
2321                                                 {
2322                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2323                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2324                                                 }
2325                                                 else if(r > 0)
2326                                                 {
2327                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2328                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2329                                                 }
2330                                         }
2331                                 }
2332                                 self.version_nagtime = 0;
2333                         }
2334
2335         // GOD MODE info
2336         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2337         {
2338                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2339                 self.max_armorvalue = 0;
2340         }
2341
2342 #ifdef TETRIS
2343         if (TetrisPreFrame())
2344                 return;
2345 #endif
2346
2347         if(self.classname == "player") {
2348 //              if(self.netname == "Wazat")
2349 //                      bprint(self.classname, "\n");
2350
2351                 CheckRules_Player();
2352
2353                 PrintWelcomeMessage(self);
2354
2355                 if (intermission_running)
2356                 {
2357                         IntermissionThink ();   // otherwise a button could be missed between
2358                         return;                                 // the think tics
2359                 }
2360
2361                 if(self.teleport_time)
2362                 if(time > self.teleport_time)
2363                 {
2364                         self.teleport_time = 0;
2365                         self.effects = self.effects - (self.effects & EF_NODRAW);
2366                 }
2367
2368                 Nixnex_GiveCurrentWeapon();
2369
2370                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2371                         UpdateSelectedPlayer();
2372
2373                 //don't allow the player to turn around while game is paused!
2374                 if(timeoutStatus == 2) {
2375                         self.v_angle = self.lastV_angle;
2376                         self.angles = self.lastV_angle;
2377                         self.fixangle = TRUE;
2378                 }
2379
2380                 if(frametime)
2381                         player_powerups();
2382
2383                 if (self.deadflag != DEAD_NO)
2384                 {
2385                         float button_pressed, force_respawn;
2386                         if(frametime)
2387                                 player_anim();
2388                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2389                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2390                         if (self.deadflag == DEAD_DYING)
2391                         {
2392                                 if(force_respawn)
2393                                         self.deadflag = DEAD_RESPAWNING;
2394                                 else if(!button_pressed)
2395                                         self.deadflag = DEAD_DEAD;
2396                         }
2397                         else if (self.deadflag == DEAD_DEAD)
2398                         {
2399                                 if(button_pressed)
2400                                         self.deadflag = DEAD_RESPAWNABLE;
2401                         }
2402                         else if (self.deadflag == DEAD_RESPAWNABLE)
2403                         {
2404                                 if(!button_pressed)
2405                                         self.deadflag = DEAD_RESPAWNING;
2406                         }
2407                         else if (self.deadflag == DEAD_RESPAWNING)
2408                         {
2409                                 if(time > self.death_time)
2410                                 {
2411                                         self.death_time = time + 1; // only retry once a second
2412                                         respawn();
2413                                 }
2414                         }
2415                         ShowRespawnCountdown();
2416                         return;
2417                 }
2418
2419                 if(g_touchexplode)
2420                 if(time > self.touchexplode_time)
2421                 if(self.classname == "player")
2422                 if(self.deadflag == DEAD_NO)
2423                 if not(IS_INDEPENDENT_PLAYER(self))
2424                 FOR_EACH_PLAYER(other) if(self != other)
2425                 {
2426                         if(time > other.touchexplode_time)
2427                         if(other.classname == "player")
2428                         if(other.deadflag == DEAD_NO)
2429                         if not(IS_INDEPENDENT_PLAYER(other))
2430                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2431                         {
2432                                 PlayerTouchExplode(self, other);
2433                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2434                         }
2435                 }
2436
2437                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2438                 {
2439                         vector dist;
2440
2441                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2442                         dist = self.prevorigin - self.origin;
2443                         dist_z = 0;
2444                         self.lms_traveled_distance += fabs(vlen(dist));
2445
2446                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2447                         {
2448                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2449                                 self.lms_traveled_distance = 0;
2450                         }
2451
2452                         if(time > self.lms_nextcheck)
2453                         {
2454                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2455                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2456                                 {
2457                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2458                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2459                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2460                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2461                                 }
2462                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2463                                 self.lms_traveled_distance = 0;
2464                         }
2465                 }
2466
2467                 self.prevorigin = self.origin;
2468
2469                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2470                 {
2471                         if (!self.crouch)
2472                         {
2473                                 self.crouch = TRUE;
2474                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2475                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2476                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2477                         }
2478                 }
2479                 else
2480                 {
2481                         if (self.crouch)
2482                         {
2483                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2484                                 if (!trace_startsolid)
2485                                 {
2486                                         self.crouch = FALSE;
2487                                         self.view_ofs = PL_VIEW_OFS;
2488                                         setsize (self, PL_MIN, PL_MAX);
2489                                 }
2490                         }
2491                 }
2492
2493                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2494                 {
2495                         if(self.bloodloss_timer < time)
2496                         {
2497                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2498                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2499                         }
2500                 }
2501
2502                 FixPlayermodel();
2503
2504                 GrapplingHookFrame();
2505
2506                 if(frametime)
2507                 {
2508                         self.items &~= self.items_added;
2509
2510                         W_WeaponFrame();
2511
2512                         self.items_added = 0;
2513                         if(self.items & IT_JETPACK)
2514                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2515                                         self.items_added |= IT_FUEL;
2516
2517                         self.items |= self.items_added;
2518                 }
2519
2520                 player_regen();
2521                 if(frametime)
2522                         player_anim();
2523
2524                 if (g_minstagib)
2525                         minstagib_ammocheck();
2526
2527                 ctf_setstatus();
2528                 kh_setstatus();
2529                 nexball_setstatus();
2530
2531                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2532
2533                 //self.angles_y=self.v_angle_y + 90;   // temp
2534         } else if(gameover) {
2535                 if (intermission_running)
2536                         IntermissionThink ();   // otherwise a button could be missed between
2537                 return;
2538         } else if(self.classname == "observer") {
2539                 ObserverThink();
2540         } else if(self.classname == "spectator") {
2541                 SpectatorThink();
2542         }
2543
2544         if(!zoomstate_set)
2545                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2546
2547         float oldspectatee_status;
2548         oldspectatee_status = self.spectatee_status;
2549         if(self.classname == "spectator")
2550                 self.spectatee_status = num_for_edict(self.enemy);
2551         else if(self.classname == "observer")
2552                 self.spectatee_status = num_for_edict(self);
2553         else
2554                 self.spectatee_status = 0;
2555         if(self.spectatee_status != oldspectatee_status)
2556         {
2557                 ClientData_Touch(self);
2558                 if(g_race || g_cts)
2559                         race_InitSpectator();
2560         }
2561
2562         if(self.teamkill_soundtime)
2563         if(time > self.teamkill_soundtime)
2564         {
2565                 self.teamkill_soundtime = 0;
2566
2567                 entity oldpusher, oldself;
2568
2569                 oldself = self; self = self.teamkill_soundsource;
2570                 oldpusher = self.pusher; self.pusher = oldself;
2571
2572                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2573
2574                 self.pusher = oldpusher;
2575                 self = oldself;
2576         }
2577
2578         if(self.taunt_soundtime)
2579         if(time > self.taunt_soundtime)
2580         {
2581                 self.taunt_soundtime = 0;
2582                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2583         }
2584
2585         target_voicescript_next(self);
2586 }
2587
2588 // on dragger:
2589 .entity dragentity;
2590 .float draggravity;
2591 .float dragspeed; // speed of mouse wheel action
2592 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2593 .vector draglocalvector; // local attachment vector of the dragentity
2594 .float draglocalangle;
2595 // on draggee:
2596 .entity draggedby;
2597 .float dragmovetype;
2598 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2599 {
2600         float tagscale;
2601
2602         draggee.dragmovetype = draggee.movetype;
2603         draggee.draggravity = draggee.gravity;
2604         draggee.movetype = MOVETYPE_WALK;
2605         draggee.gravity = 0.00001;
2606         draggee.flags &~= FL_ONGROUND;
2607         draggee.draggedby = dragger;
2608
2609         dragger.dragentity = draggee;
2610
2611         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2612         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2613         touchpoint = touchpoint - gettaginfo(draggee, 0);
2614         tagscale = pow(vlen(v_forward), -2);
2615         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2616         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2617         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2618
2619         dragger.dragspeed = 64;
2620 }
2621
2622 void Drag_Finish(entity dragger)
2623 {
2624         entity draggee;
2625         draggee = dragger.dragentity;
2626         if(dragger)
2627                 dragger.dragentity = world;
2628         draggee.draggedby = world;
2629         draggee.movetype = draggee.dragmovetype;
2630         draggee.gravity = draggee.draggravity;
2631
2632         switch(draggee.movetype)
2633         {
2634                 case MOVETYPE_TOSS:
2635                 case MOVETYPE_WALK:
2636                 case MOVETYPE_STEP:
2637                 case MOVETYPE_FLYMISSILE:
2638                 case MOVETYPE_BOUNCE:
2639                 case MOVETYPE_BOUNCEMISSILE:
2640                         break;
2641                 default:
2642                         draggee.velocity = '0 0 0';
2643                         break;
2644         }
2645
2646         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2647         {
2648                 draggee.velocity = '0 0 0';
2649                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2650         }
2651 }
2652
2653 float Drag_IsDraggable(entity draggee)
2654 {
2655         // TODO add more checks for bad stuff here
2656         if(draggee.classname == "func_bobbing")
2657                 return FALSE;
2658         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2659                 return FALSE;
2660         if(draggee.classname == "plat")
2661                 return FALSE;
2662         if(draggee.classname == "func_button")
2663                 return FALSE;
2664         if(draggee.model == "")
2665                 return FALSE;
2666         if(draggee.classname == "spectator")
2667                 return FALSE;
2668         if(draggee.classname == "observer")
2669                 return FALSE;
2670         if(draggee.classname == "exteriorweaponentity")
2671                 return FALSE;
2672
2673         return TRUE;
2674 }
2675
2676 float Drag_MayChangeAngles(entity draggee)
2677 {
2678         // TODO add more checks for bad stuff here
2679         if(substring(draggee.model, 0, 1) == "*")
2680                 return FALSE;
2681         return TRUE;
2682 }
2683
2684 void Drag_MoveForward(entity dragger)
2685 {
2686         dragger.dragdistance += dragger.dragspeed;
2687 }
2688
2689 void Drag_SetSpeed(entity dragger, float s)
2690 {
2691         dragger.dragspeed = pow(2, s);
2692 }
2693
2694 void Drag_MoveBackward(entity dragger)
2695 {
2696         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2697 }
2698
2699 void Drag_Update(entity dragger)
2700 {
2701         vector curorigin, neworigin, goodvelocity;
2702         float f;
2703         entity draggee;
2704
2705         draggee = dragger.dragentity;
2706         draggee.flags &~= FL_ONGROUND;
2707
2708         curorigin = gettaginfo(draggee, 0);
2709         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2710         makevectors(dragger.v_angle);
2711         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2712         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2713
2714         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2715                 dragger.draglocalangle += 360;
2716         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2717                 dragger.draglocalangle -= 360;
2718
2719         f = min(frametime * 10, 1);
2720         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2721
2722         if(Drag_MayChangeAngles(draggee))
2723                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2724
2725         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2726
2727         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2728 }
2729
2730 float Drag_CanDrag(entity dragger)
2731 {
2732         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2733 }
2734
2735 float Drag_IsDragging(entity dragger)
2736 {
2737         if(!dragger.dragentity)
2738                 return FALSE;
2739         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2740         {
2741                 dragger.dragentity = world;
2742                 return FALSE;
2743         }
2744         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2745         {
2746                 Drag_Finish(dragger);
2747                 return FALSE;
2748         }
2749         return TRUE;
2750 }
2751
2752 void Drag_MoveDrag(entity from, entity to)
2753 {
2754         if(from.draggedby)
2755         {
2756                 to.draggedby = from.draggedby;
2757                 to.draggedby.dragentity = to;
2758                 from.draggedby = world;
2759         }
2760 }
2761
2762 /*
2763 =============
2764 PlayerPostThink
2765
2766 Called every frame for each client after the physics are run
2767 =============
2768 */
2769 .float idlekick_lasttimeleft;
2770 void PlayerPostThink (void)
2771 {
2772         // Savage: Check for nameless players
2773         if (strlen(self.netname) < 1) {
2774                 self.netname = "Player";
2775                 stuffcmd(self, "seta _cl_name Player\n");
2776         }
2777
2778         if(sv_maxidle && frametime)
2779         {
2780                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2781                 float timeleft;
2782                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2783                 if(timeleft <= 0)
2784                 {
2785                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2786                         announce(self, "announcer/robotic/terminated.wav");
2787                         dropclient(self);
2788                         return;
2789                 }
2790                 else if(timeleft <= 10)
2791                 {
2792                         if(timeleft != self.idlekick_lasttimeleft)
2793                         {
2794                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2795                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2796                         }
2797                 }
2798                 else
2799                 {
2800                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2801                 }
2802                 self.idlekick_lasttimeleft = timeleft;
2803         }
2804
2805 #ifdef TETRIS
2806         if(self.impulse == 100)
2807                 ImpulseCommands();
2808         if (TetrisPostFrame())
2809                 return;
2810 #endif
2811
2812         if(sv_cheats || self.maycheat)
2813                 if(Drag_CanDrag(self))
2814                         if(self.BUTTON_DRAG)
2815                                 if(!self.dragentity)
2816                                         if(self.cursor_trace_ent)
2817                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2818                                                 {
2819                                                         if(self.cursor_trace_ent.draggedby)
2820                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2821                                                         if(self.cursor_trace_ent.tag_entity)
2822                                                                 detach_sameorigin(self.cursor_trace_ent);
2823                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2824                                                 }
2825
2826         if(Drag_IsDragging(self))
2827         {
2828                 if(self.BUTTON_DRAG)
2829                 {
2830                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2831                         {
2832                                 Drag_MoveForward(self);
2833                                 self.impulse = 0;
2834                         }
2835                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2836                         {
2837                                 Drag_MoveBackward(self);
2838                                 self.impulse = 0;
2839                         }
2840                         else if(self.impulse >= 1 && self.impulse <= 9)
2841                         {
2842                                 Drag_SetSpeed(self, self.impulse - 1);
2843                         }
2844                         else if(self.impulse == 14)
2845                         {
2846                                 Drag_SetSpeed(self, 9);
2847                         }
2848
2849                         if(frametime)
2850                                 Drag_Update(self);
2851                 }
2852                 else
2853                 {
2854                         Drag_Finish(self);
2855                 }
2856         }
2857
2858         if(self.classname == "player") {
2859                 CheckRules_Player();
2860                 UpdateChatBubble();
2861                 UpdateTeamBubble();
2862                 if (self.impulse)
2863                         ImpulseCommands();
2864                 if (intermission_running)
2865                         return;         // intermission or finale
2866
2867                 GetPressedKeys();
2868         } else if (self.classname == "observer") {
2869                 //do nothing
2870         } else if (self.classname == "spectator") {
2871                 //do nothing
2872         }
2873
2874         /*
2875         float i;
2876         for(i = 0; i < 1000; ++i)
2877         {
2878                 vector end;
2879                 end = self.origin + '0 0 1024' + 512 * randomvec();
2880                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2881                 if(trace_fraction < 1)
2882                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2883                 {
2884                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2885                         break;
2886                 }
2887         }
2888         */
2889
2890         Arena_Warmup();
2891
2892         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2893
2894         if(self.waypointsprite_attachedforcarrier)
2895                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2896 }