data/qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float t, float msg);
   2
   3 float ClientData_Send(entity to, float sf)
   4 {
   5         if(to != self.owner)
   6         {
   7                 error("wtf");
   8                 return FALSE;
   9         }
  10
  11         entity e;
  12
  13         e = to;
  14         if(to.classname == "spectator")
  15                 e = to.enemy;
  16
  17         sf = 0;
  18
  19         if(e.race_completed)
  20                 sf |= 1; // forced scoreboard
  21         if(to.spectatee_status)
  22                 sf |= 2; // spectator ent number follows
  23         if(e.zoomstate)
  24                 sf |= 4; // zoomed
  25         if(e.porto_v_angle_held)
  26                 sf |= 8; // angles held
  27
  28         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  29         WriteByte(MSG_ENTITY, sf);
  30
  31         if(sf & 2)
  32                 WriteByte(MSG_ENTITY, to.spectatee_status);
  33
  34         if(sf & 8)
  35         {
  36                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  37                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  38         }
  39
  40         return TRUE;
  41 }
  42
  43 void ClientData_Attach()
  44 {
  45         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  46         self.clientdata.drawonlytoclient = self;
  47         self.clientdata.owner = self;
  48 }
  49
  50 void ClientData_Detach()
  51 {
  52         remove(self.clientdata);
  53         self.clientdata = world;
  54 }
  55
  56 void ClientData_Touch(entity e)
  57 {
  58         e.clientdata.SendFlags = 1;
  59
  60         // make it spectatable
  61         entity e2;
  62         FOR_EACH_REALCLIENT(e2)
  63         {
  64                 if(e2 != e)
  65                         if(e2.classname == "spectator")
  66                                 if(e2.enemy == e)
  67                                         e2.clientdata.SendFlags = 1;
  68         }
  69 }
  70
  71
  72 #define SPAWNPOINT_SCORE frags
  73
  74 .string netname_previous;
  75
  76 void spawnfunc_info_player_survivor (void)
  77 {
  78         spawnfunc_info_player_deathmatch();
  79 }
  80
  81 void spawnfunc_info_player_start (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_deathmatch (void)
  87 {
  88         self.classname = "info_player_deathmatch";
  89         relocate_spawnpoint();
  90 }
  91
  92 void spawnpoint_use()
  93 {
  94         if(teams_matter)
  95         if(have_team_spawns)
  96         {
  97                 self.team = activator.team;
  98                 some_spawn_has_been_used = 1;
  99         }
 100 };
 101
 102 // Returns:
 103 //   -1 if a spawn can't be used
 104 //   otherwise, a weight of the spawnpoint
 105 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 106 {
 107         float shortest, thisdist;
 108         entity player;
 109
 110         // filter out spots for the wrong team
 111         if(teamcheck)
 112         if(spot.team != teamcheck)
 113                 return -1;
 114
 115         if(race_spawns)
 116                 if(spot.target == "")
 117                         return -1;
 118
 119         if(clienttype(self) == CLIENTTYPE_REAL)
 120         {
 121                 if(spot.restriction == 1)
 122                         return -1;
 123         }
 124         else
 125         {
 126                 if(spot.restriction == 2)
 127                         return -1;
 128         }
 129
 130         // filter out spots for assault
 131         if(spot.target != "") {
 132                 local entity ent;
 133                 float good, found;
 134                 ent = find(world, targetname, spot.target);
 135                 while(ent) {
 136                         if(ent.classname == "target_objective")
 137                         {
 138                                 found = 1;
 139                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 140                                         return -1;
 141                                 good = 1;
 142                         }
 143                         else if(ent.classname == "trigger_race_checkpoint")
 144                         {
 145                                 found = 1;
 146                                 if(self.classname == "player") // spectators may spawn everywhere
 147                                 {
 148                                         if(g_race_qualifying)
 149                                         {
 150                                                 // spawn at first
 151                                                 if(ent.race_checkpoint != 0)
 152                                                         return -1;
 153                                                 if(spot.race_place != race_lowest_place_spawn)
 154                                                         return -1;
 155                                         }
 156                                         else
 157                                         {
 158                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 159                                                         return -1;
 160                                                 float pl;
 161                                                 pl = self.race_place;
 162                                                 if(pl > race_highest_place_spawn)
 163                                                         pl = 0;
 164                                                 if(spot.race_place != pl)
 165                                                         return -1;
 166                                         }
 167                                 }
 168                                 good = 1;
 169                         }
 170                         ent = find(ent, targetname, spot.target);
 171                 }
 172
 173                 if(found && !good)
 174                         return -1;
 175         }
 176
 177         player = playerlist;
 178         shortest = vlen(world.maxs - world.mins);
 179         for(player = playerlist; player; player = player.chain)
 180                 if (player != self)
 181                 {
 182                         thisdist = vlen(player.origin - spot.origin);
 183                         if (thisdist < shortest)
 184                                 shortest = thisdist;
 185                 }
 186         return shortest;
 187 }
 188
 189 float spawn_allbad;
 190 float spawn_allgood;
 191 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 192 {
 193         local entity spot, spotlist, spotlistend;
 194         spawn_allgood = TRUE;
 195         spawn_allbad = TRUE;
 196
 197         spotlist = world;
 198         spotlistend = world;
 199
 200         for(spot = firstspot; spot; spot = spot.chain)
 201         {
 202                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 203
 204                 if(cvar("spawn_debugview"))
 205                 {
 206                         setmodel(spot, "models/runematch/rune.mdl");
 207                         if(spot.SPAWNPOINT_SCORE < mindist)
 208                         {
 209                                 spot.colormod = '1 0 0';
 210                                 spot.scale = 1;
 211                         }
 212                         else
 213                         {
 214                                 spot.colormod = '0 1 0';
 215                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 216                         }
 217                 }
 218
 219                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 220                 {
 221                         if(spot.SPAWNPOINT_SCORE < mindist)
 222                         {
 223                                 // too short distance
 224                                 spawn_allgood = FALSE;
 225                         }
 226                         else
 227                         {
 228                                 // perfect
 229                                 spawn_allbad = FALSE;
 230
 231                                 if(spotlistend)
 232                                         spotlistend.chain = spot;
 233                                 spotlistend = spot;
 234                                 if(!spotlist)
 235                                         spotlist = spot;
 236
 237                                 /*
 238                                 if(teamcheck)
 239                                 if(spot.team != teamcheck)
 240                                         error("invalid spawn added");
 241
 242                                 print("added ", etos(spot), "\n");
 243                                 */
 244                         }
 245                 }
 246         }
 247         if(spotlistend)
 248                 spotlistend.chain = world;
 249
 250         /*
 251                 entity e;
 252                 if(teamcheck)
 253                         for(e = spotlist; e; e = e.chain)
 254                         {
 255                                 print("seen ", etos(e), "\n");
 256                                 if(e.team != teamcheck)
 257                                         error("invalid spawn found");
 258                         }
 259         */
 260
 261         return spotlist;
 262 }
 263
 264 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 265 {
 266         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 267         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 268         local entity spot;
 269
 270         RandomSelection_Init();
 271         for(spot = firstspot; spot; spot = spot.chain)
 272                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 273
 274         return RandomSelection_chosen_ent;
 275 }
 276
 277 /*
 278 =============
 279 SelectSpawnPoint
 280
 281 Finds a point to respawn
 282 =============
 283 */
 284 entity SelectSpawnPoint (float anypoint)
 285 {
 286         local float teamcheck;
 287         local entity firstspot_new;
 288         local entity spot, firstspot, playerlist;
 289
 290         spot = find (world, classname, "testplayerstart");
 291         if (spot)
 292                 return spot;
 293
 294         teamcheck = 0;
 295
 296         if(!anypoint && have_team_spawns)
 297                 teamcheck = self.team;
 298
 299         // get the list of players
 300         playerlist = findchain(classname, "player");
 301         // get the entire list of spots
 302         firstspot = findchain(classname, "info_player_deathmatch");
 303         // filter out the bad ones
 304         // (note this returns the original list if none survived)
 305         if(anypoint)
 306         {
 307                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 308         }
 309         else
 310         {
 311                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 312                 if(!firstspot_new)
 313                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 314                 firstspot = firstspot_new;
 315
 316                 // there is 50/50 chance of choosing a random spot or the furthest spot
 317                 // (this means that roughly every other spawn will be furthest, so you
 318                 // usually won't get fragged at spawn twice in a row)
 319                 if (arena_roundbased)
 320                 {
 321                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 322                         if(firstspot_new)
 323                                 firstspot = firstspot_new;
 324                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 325                 }
 326                 else if (random() > cvar("g_spawn_furthest"))
 327                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 328                 else
 329                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 330         }
 331
 332         if(cvar("spawn_debugview"))
 333         {
 334                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 335
 336                 entity e;
 337                 if(teamcheck)
 338                         for(e = firstspot; e; e = e.chain)
 339                                 if(e.team != teamcheck)
 340                                         error("invalid spawn found");
 341         }
 342
 343         if (!spot)
 344         {
 345                 if(cvar("spawn_debug"))
 346                         GotoNextMap();
 347                 else
 348                 {
 349                         if(some_spawn_has_been_used)
 350                                 return world; // team can't spawn any more, because of actions of other team
 351                         else
 352                                 error("Cannot find a spawn point - please fix the map!");
 353                 }
 354         }
 355
 356         return spot;
 357 }
 358
 359 /*
 360 =============
 361 CheckPlayerModel
 362
 363 Checks if the argument string can be a valid playermodel.
 364 Returns a valid one in doubt.
 365 =============
 366 */
 367 string FallbackPlayerModel = "models/player/marine.zym";
 368 string CheckPlayerModel(string plyermodel) {
 369         if(strlen(plyermodel) < 4)
 370                 return FallbackPlayerModel;
 371         if( substring(plyermodel,0,14) != "models/player/")
 372                 return FallbackPlayerModel;
 373         else if(cvar("sv_servermodelsonly"))
 374         {
 375                 if(substring(plyermodel,-4,4) != ".zym")
 376                 if(substring(plyermodel,-4,4) != ".dpm")
 377                 if(substring(plyermodel,-4,4) != ".md3")
 378                 if(substring(plyermodel,-4,4) != ".psk")
 379                         return FallbackPlayerModel;
 380                 // forbid the LOD models
 381                 if(substring(plyermodel, -9,5) == "_lod1")
 382                         return FallbackPlayerModel;
 383                 if(substring(plyermodel, -9,5) == "_lod2")
 384                         return FallbackPlayerModel;
 385                 if(plyermodel != strtolower(plyermodel))
 386                         return FallbackPlayerModel;
 387                 if(!fexists(plyermodel))
 388                         return FallbackPlayerModel;
 389         }
 390         return plyermodel;
 391 }
 392
 393 /*
 394 =============
 395 Client_customizeentityforclient
 396
 397 LOD reduction
 398 =============
 399 */
 400 void Client_uncustomizeentityforclient()
 401 {
 402         if(self.modelindex == 0) // no need to uncustomize then
 403                 return;
 404         self.modelindex = self.modelindex_lod0;
 405         self.skin = self.skinindex;
 406 }
 407
 408 float Client_customizeentityforclient()
 409 {
 410         entity modelsource;
 411
 412         if(self.modelindex == 0)
 413                 return TRUE;
 414
 415         // forcemodel stuff
 416
 417 #ifdef PROFILING
 418         float t0;
 419         t0 = gettime(GETTIME_HIRES); // reference
 420 #endif
 421
 422         modelsource = self;
 423
 424 #ifdef ALLOW_FORCEMODELS
 425         if(other.cvar_cl_forceplayermodelsfromnexuiz)
 426                 if not(self.modelindex_lod0_from_nexuiz)
 427                         modelsource = other;
 428         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 429                 modelsource = other;
 430 #endif
 431
 432         self.skin = modelsource.skinindex;
 433
 434 #if 0
 435         if(modelsource == self)
 436                 self.skin = modelsource.skinindex;
 437         else
 438                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 439 #endif
 440
 441         // self: me
 442         // other: the player viewing me
 443         float distance;
 444         float f;
 445
 446         if(other.cvar_cl_playerdetailreduction <= 0)
 447         {
 448                 if(other.cvar_cl_playerdetailreduction <= -2)
 449                         self.modelindex = modelsource.modelindex_lod2;
 450                 else if(other.cvar_cl_playerdetailreduction <= -1)
 451                         self.modelindex = modelsource.modelindex_lod1;
 452                 else
 453                         self.modelindex = modelsource.modelindex_lod0;
 454         }
 455         else
 456         {
 457                 distance = vlen(self.origin - other.origin);
 458                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 459                 if(f > sv_loddistance2)
 460                         self.modelindex = modelsource.modelindex_lod2;
 461                 else if(f > sv_loddistance1)
 462                         self.modelindex = modelsource.modelindex_lod1;
 463                 else
 464                         self.modelindex = modelsource.modelindex_lod0;
 465         }
 466
 467 #ifdef PROFILING
 468         float t1;
 469         t1 = gettime(GETTIME_HIRES); // reference
 470         client_cefc_accumulator += (t1 - t0);
 471 #endif
 472
 473         return TRUE;
 474 }
 475
 476 void UpdatePlayerSounds();
 477 void setmodel_lod(entity e, string modelname)
 478 {
 479         string s;
 480
 481         if(sv_loddistance1)
 482         {
 483                 // FIXME: this only supports 3-letter extensions
 484                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 485                 if(fexists(s))
 486                 {
 487                         setmodel(e, s); // players have high precision
 488                         self.modelindex_lod1 = self.modelindex;
 489                 }
 490                 else
 491                         self.modelindex_lod1 = -1;
 492
 493                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 494                 if(fexists(s))
 495                 {
 496                         setmodel(e, s); // players have high precision
 497                         self.modelindex_lod2 = self.modelindex;
 498                 }
 499                 else
 500                         self.modelindex_lod2 = -1;
 501
 502                 precache_model(modelname);
 503                 setmodel(e, modelname); // players have high precision
 504                 self.modelindex_lod0 = self.modelindex;
 505
 506                 if(self.modelindex_lod1 < 0)
 507                         self.modelindex_lod1 = self.modelindex;
 508
 509                 if(self.modelindex_lod2 < 0)
 510                         self.modelindex_lod2 = self.modelindex;
 511         }
 512         else
 513         {
 514                 precache_model(modelname);
 515                 setmodel(e, modelname); // players have high precision
 516                 self.modelindex_lod0 = self.modelindex;
 517                         // save it for possible player model forcing
 518         }
 519
 520         s = whichpack(self.model);
 521         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
 522
 523         player_setupanimsformodel();
 524         UpdatePlayerSounds();
 525 }
 526
 527 /*
 528 =============
 529 PutObserverInServer
 530
 531 putting a client as observer in the server
 532 =============
 533 */
 534 void FixPlayermodel();
 535 void PutObserverInServer (void)
 536 {
 537         entity  spot;
 538
 539         race_PreSpawnObserver();
 540
 541         spot = SelectSpawnPoint (TRUE);
 542         if(!spot)
 543                 error("No spawnpoints for observers?!?\n");
 544         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 545
 546         if(clienttype(self) == CLIENTTYPE_REAL)
 547         {
 548                 msg_entity = self;
 549                 WriteByte(MSG_ONE, SVC_SETVIEW);
 550                 WriteEntity(MSG_ONE, self);
 551         }
 552
 553         DropAllRunes(self);
 554         kh_Key_DropAll(self, TRUE);
 555
 556         Portal_ClearAll(self);
 557
 558         if(self.flagcarried)
 559                 DropFlag(self.flagcarried, world, world);
 560         if(self.ballcarried)
 561                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 562
 563         WaypointSprite_PlayerDead();
 564
 565         if(self.killcount != -666)
 566         {
 567                 if(g_lms)
 568                 {
 569                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 570                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 571                         else
 572                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 573                 }
 574                 else
 575                         bprint ("^4", self.netname, "^4 is spectating now\n");
 576         }
 577
 578         PlayerScore_Clear(self); // clear scores when needed
 579
 580         self.spectatortime = time;
 581
 582         self.classname = "observer";
 583         self.iscreature = FALSE;
 584         self.health = -666;
 585         self.takedamage = DAMAGE_NO;
 586         self.solid = SOLID_NOT;
 587         self.movetype = MOVETYPE_NOCLIP;
 588         self.flags = FL_CLIENT | FL_NOTARGET;
 589         self.armorvalue = 666;
 590         self.effects = 0;
 591         self.armorvalue = cvar("g_balance_armor_start");
 592         self.pauserotarmor_finished = 0;
 593         self.pauserothealth_finished = 0;
 594         self.pauseregen_finished = 0;
 595         self.damageforcescale = 0;
 596         self.death_time = 0;
 597         self.dead_frame = 0;
 598         self.alpha = 0;
 599         self.scale = 0;
 600         self.fade_time = 0;
 601         self.pain_frame = 0;
 602         self.pain_finished = 0;
 603         self.strength_finished = 0;
 604         self.invincible_finished = 0;
 605         self.pushltime = 0;
 606         self.think = SUB_Null;
 607         self.nextthink = 0;
 608         self.hook_time = 0;
 609         self.runes = 0;
 610         self.deadflag = DEAD_NO;
 611         self.angles = spot.angles;
 612         self.angles_z = 0;
 613         self.fixangle = TRUE;
 614         self.crouch = FALSE;
 615
 616         self.view_ofs = PL_VIEW_OFS;
 617         setorigin (self, spot.origin);
 618         setsize (self, '0 0 0', '0 0 0');
 619         self.prevorigin = self.origin;
 620         self.items = 0;
 621         self.weapons = 0;
 622         self.model = "";
 623         FixPlayermodel();
 624         self.model = "";
 625         self.modelindex = 0;
 626         self.weapon = 0;
 627         self.weaponmodel = "";
 628         self.weaponentity = world;
 629         self.exteriorweaponentity = world;
 630         self.killcount = -666;
 631         self.velocity = '0 0 0';
 632         self.avelocity = '0 0 0';
 633         self.punchangle = '0 0 0';
 634         self.punchvector = '0 0 0';
 635         self.oldvelocity = self.velocity;
 636         self.fire_endtime = -1;
 637
 638         if(sv_loddistance1)
 639                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 640
 641         self.team = -1;
 642
 643         if(g_arena)
 644         {
 645                 if(self.version_mismatch)
 646                 {
 647                         Spawnqueue_Unmark(self);
 648                         Spawnqueue_Remove(self);
 649                 }
 650                 else
 651                 {
 652                         Spawnqueue_Insert(self);
 653                 }
 654         }
 655         else if(g_lms)
 656         {
 657                 // Only if the player cannot play at all
 658                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 659                         self.frags = FRAGS_SPECTATOR;
 660                 else
 661                         self.frags = FRAGS_LMS_LOSER;
 662         }
 663         else
 664                 self.frags = FRAGS_SPECTATOR;
 665 }
 666
 667 float RestrictSkin(float s)
 668 {
 669         if(!teams_matter)
 670                 return s;
 671         if(s == 6)
 672                 return 6;
 673         return mod(s, 3);
 674 }
 675
 676 void FixPlayermodel()
 677 {
 678         local string defaultmodel;
 679         local float defaultskin, chmdl, oldskin;
 680         local vector m1, m2;
 681
 682         defaultmodel = "";
 683
 684         if(cvar("sv_defaultcharacter") == 1) {
 685                 defaultskin = 0;
 686
 687                 if(teams_matter)
 688                 {
 689                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 690                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 691                 }
 692
 693                 if(defaultmodel == "")
 694                 {
 695                         defaultmodel = cvar_string("sv_defaultplayermodel");
 696                         defaultskin = cvar("sv_defaultplayerskin");
 697                 }
 698         }
 699
 700         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 701         {
 702                 if(self.model != "")
 703                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 704                 self.model = ""; // force the != checks to return true
 705         }
 706
 707         if(defaultmodel != "")
 708         {
 709                 if (defaultmodel != self.model)
 710                 {
 711                         m1 = self.mins;
 712                         m2 = self.maxs;
 713                         setmodel_lod (self, defaultmodel);
 714                         setsize (self, m1, m2);
 715                         chmdl = TRUE;
 716                 }
 717
 718                 oldskin = self.skinindex;
 719                 self.skinindex = defaultskin;
 720         } else {
 721                 if (self.playermodel != self.model)
 722                 {
 723                         self.playermodel = CheckPlayerModel(self.playermodel);
 724                         m1 = self.mins;
 725                         m2 = self.maxs;
 726                         setmodel_lod (self, self.playermodel);
 727                         setsize (self, m1, m2);
 728                         chmdl = TRUE;
 729                 }
 730
 731                 oldskin = self.skinindex;
 732                 self.skinindex = RestrictSkin(stof(self.playerskin));
 733         }
 734
 735         if(chmdl || oldskin != self.skinindex)
 736                 self.species = player_getspecies(); // model or skin has changed
 737
 738         if(!teams_matter)
 739                 if(strlen(cvar_string("sv_defaultplayercolors")))
 740                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 741                                 setcolor(self, cvar("sv_defaultplayercolors"));
 742 }
 743
 744 void PlayerTouchExplode(entity p1, entity p2)
 745 {
 746         vector org;
 747         org = (p1.origin + p2.origin) * 0.5;
 748         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 749
 750         te_explosion(org);
 751
 752         entity e;
 753         e = spawn();
 754         setorigin(e, org);
 755         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 756         remove(e);
 757 }
 758
 759 /*
 760 =============
 761 PutClientInServer
 762
 763 Called when a client spawns in the server
 764 =============
 765 */
 766 //void() ctf_playerchanged;
 767 void PutClientInServer (void)
 768 {
 769         if(clienttype(self) == CLIENTTYPE_BOT)
 770         {
 771                 self.classname = "player";
 772         }
 773         else if(clienttype(self) == CLIENTTYPE_REAL)
 774         {
 775                 msg_entity = self;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, self);
 778         }
 779
 780         // player is dead and becomes observer
 781         // FIXME fix LMS scoring for new system
 782         if(g_lms)
 783         {
 784                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 785                         self.classname = "observer";
 786         }
 787
 788         if(g_arena)
 789         if(!self.spawned)
 790                 self.classname = "observer";
 791
 792         if(gameover)
 793                 self.classname = "observer";
 794
 795         if(self.classname == "player") {
 796                 entity spot, oldself;
 797                 float j;
 798
 799                 if(self.team < 0)
 800                         JoinBestTeam(self, FALSE, TRUE);
 801
 802                 race_PreSpawn();
 803
 804                 spot = SelectSpawnPoint (FALSE);
 805                 if(!spot)
 806                 {
 807                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 808                         return; // spawn failed
 809                 }
 810
 811                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 812
 813                 self.classname = "player";
 814                 self.wasplayer = TRUE;
 815                 self.iscreature = TRUE;
 816                 self.movetype = MOVETYPE_WALK;
 817                 self.solid = SOLID_SLIDEBOX;
 818                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 819                 self.frags = FRAGS_PLAYER;
 820                 if(independent_players)
 821                         MAKE_INDEPENDENT_PLAYER(self);
 822                 self.flags = FL_CLIENT;
 823                 self.takedamage = DAMAGE_AIM;
 824                 if(g_minstagib)
 825                         self.effects = EF_FULLBRIGHT;
 826                 else
 827                         self.effects = 0;
 828                 self.air_finished = time + 12;
 829                 self.dmg = 2;
 830
 831                 if(inWarmupStage)
 832                 {
 833                         self.ammo_shells = warmup_start_ammo_shells;
 834                         self.ammo_nails = warmup_start_ammo_nails;
 835                         self.ammo_rockets = warmup_start_ammo_rockets;
 836                         self.ammo_cells = warmup_start_ammo_cells;
 837                         self.ammo_fuel = warmup_start_ammo_fuel;
 838                         self.health = warmup_start_health;
 839                         self.armorvalue = warmup_start_armorvalue;
 840                         self.weapons = warmup_start_weapons;
 841                 }
 842                 else
 843                 {
 844                         self.ammo_shells = start_ammo_shells;
 845                         self.ammo_nails = start_ammo_nails;
 846                         self.ammo_rockets = start_ammo_rockets;
 847                         self.ammo_cells = start_ammo_cells;
 848                         self.ammo_fuel = start_ammo_fuel;
 849                         self.health = start_health;
 850                         self.armorvalue = start_armorvalue;
 851                         self.weapons = start_weapons;
 852                 }
 853
 854                 if(g_weaponarena_random)
 855                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 856
 857                 self.items = start_items;
 858                 self.switchweapon = w_getbestweapon(self);
 859                 self.cnt = self.switchweapon;
 860                 self.weapon = 0;
 861                 self.jump_interval = time;
 862
 863                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 864                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 865                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 866                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 867                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 868                 //extend the pause of rotting if client was reset at the beginning of the countdown
 869                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 870                         self.spawnshieldtime += game_starttime - time;
 871                         self.pauserotarmor_finished += game_starttime - time;
 872                         self.pauserothealth_finished += game_starttime - time;
 873                         self.pauseregen_finished += game_starttime - time;
 874                 }
 875                 self.damageforcescale = 2;
 876                 self.death_time = 0;
 877                 self.dead_frame = 0;
 878                 self.alpha = 0;
 879                 self.scale = 0;
 880                 self.fade_time = 0;
 881                 self.pain_frame = 0;
 882                 self.pain_finished = 0;
 883                 self.strength_finished = 0;
 884                 self.invincible_finished = 0;
 885                 self.pushltime = 0;
 886                 //self.speed_finished = 0;
 887                 //self.slowmo_finished = 0;
 888                 // players have no think function
 889                 self.think = SUB_Null;
 890                 self.nextthink = 0;
 891                 self.hook_time = 0;
 892                 self.dmg_team = 0;
 893
 894                 self.metertime = 0;
 895
 896                 self.runes = 0;
 897
 898                 self.deadflag = DEAD_NO;
 899
 900                 self.angles = spot.angles;
 901
 902                 self.angles_z = 0; // never spawn tilted even if the spot says to
 903                 self.fixangle = TRUE; // turn this way immediately
 904                 self.velocity = '0 0 0';
 905                 self.avelocity = '0 0 0';
 906                 self.punchangle = '0 0 0';
 907                 self.punchvector = '0 0 0';
 908                 self.oldvelocity = self.velocity;
 909                 self.fire_endtime = -1;
 910
 911                 msg_entity = self;
 912                 WRITESPECTATABLE_MSG_ONE({
 913                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 914                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 915                 });
 916
 917                 if(sv_loddistance1)
 918                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 919
 920                 self.model = "";
 921                 FixPlayermodel();
 922
 923                 self.crouch = FALSE;
 924                 self.view_ofs = PL_VIEW_OFS;
 925                 setsize (self, PL_MIN, PL_MAX);
 926                 self.spawnorigin = spot.origin;
 927                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 928                 // don't reset back to last position, even if new position is stuck in solid
 929                 self.oldorigin = self.origin;
 930                 self.prevorigin = self.origin;
 931                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 932
 933                 if(g_arena)
 934                 {
 935                         Spawnqueue_Remove(self);
 936                         Spawnqueue_Mark(self);
 937                 }
 938
 939                 self.event_damage = PlayerDamage;
 940
 941                 self.bot_attack = TRUE;
 942
 943                 self.statdraintime = time + 5;
 944                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 945
 946                 if(self.killcount == -666) {
 947                         PlayerScore_Clear(self);
 948                         self.killcount = 0;
 949                 }
 950
 951                 self.cnt = WEP_LASER;
 952                 self.nixnex_lastchange_id = -1;
 953
 954                 CL_SpawnWeaponentity();
 955                 self.alpha = default_player_alpha;
 956                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 957                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 958
 959                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 960                 self.lms_traveled_distance = 0;
 961                 self.speedrunning = FALSE;
 962
 963                 race_PostSpawn(spot);
 964
 965                 if(cvar("spawn_debug"))
 966                 {
 967                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 968                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 969                 }
 970
 971                 //stuffcmd(self, "chase_active 0");
 972                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 973
 974                 if (cvar("g_spawnsound"))
 975                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 976
 977                 if(g_assault) {
 978                         if(self.team == assault_attacker_team)
 979                                 centerprint(self, "You are attacking!");
 980                         else
 981                                 centerprint(self, "You are defending!");
 982                 }
 983
 984                 target_voicescript_clear(self);
 985
 986                 // reset fields the weapons may use
 987         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 988             weapon_action(j, WR_RESETPLAYER);
 989
 990                 oldself = self;
 991                 self = spot;
 992                         activator = oldself;
 993                                 SUB_UseTargets();
 994                         activator = world;
 995                 self = oldself;
 996         } else if(self.classname == "observer") {
 997                 PutObserverInServer ();
 998         }
 999
1000         //if(g_ctf)
1001         //      ctf_playerchanged();
1002 }
1003
1004 float ClientInit_SendEntity(entity to, float sf)
1005 {
1006         float i;
1007         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1008         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1009         for(i = 1; i <= 24; ++i)
1010                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1011         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1012         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1013         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1014
1015         if(sv_foginterval && world.fog != "")
1016                 WriteString(MSG_ENTITY, world.fog);
1017         else
1018                 WriteString(MSG_ENTITY, "");
1019         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1020         return TRUE;
1021 }
1022
1023 void ClientInit_Spawn()
1024 {
1025         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1026 }
1027
1028 /*
1029 =============
1030 SetNewParms
1031 =============
1032 */
1033 void SetNewParms (void)
1034 {
1035         // initialize parms for a new player
1036         parm1 = -(86400 * 366);
1037 }
1038
1039 /*
1040 =============
1041 SetChangeParms
1042 =============
1043 */
1044 void SetChangeParms (void)
1045 {
1046         // save parms for level change
1047         parm1 = self.parm_idlesince - time;
1048 }
1049
1050 /*
1051 =============
1052 DecodeLevelParms
1053 =============
1054 */
1055 void DecodeLevelParms (void)
1056 {
1057         // load parms
1058         self.parm_idlesince = parm1;
1059         if(self.parm_idlesince == -(86400 * 366))
1060                 self.parm_idlesince = time;
1061
1062         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1063         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1064 }
1065
1066 /*
1067 =============
1068 ClientKill
1069
1070 Called when a client types 'kill' in the console
1071 =============
1072 */
1073
1074 void ClientKill_Now_TeamChange()
1075 {
1076         if(self.killindicator_teamchange == -1)
1077         {
1078                 self.team = -1;
1079                 JoinBestTeam( self, FALSE, FALSE );
1080         }
1081         else
1082                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1083 }
1084
1085 void ClientKill_Now()
1086 {
1087         if(self.killindicator_teamchange)
1088                 ClientKill_Now_TeamChange();
1089
1090         // in any case:
1091         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1092
1093         if(self.killindicator)
1094         {
1095                 dprint("Cleaned up after a leaked kill indicator.\n");
1096                 remove(self.killindicator);
1097                 self.killindicator = world;
1098         }
1099 }
1100 void KillIndicator_Think()
1101 {
1102         if (!self.owner.modelindex)
1103         {
1104                 self.owner.killindicator = world;
1105                 remove(self);
1106                 return;
1107         }
1108
1109         if(self.cnt <= 0)
1110         {
1111                 self = self.owner;
1112                 ClientKill_Now(); // no oldself needed
1113                 return;
1114         }
1115         else
1116         {
1117                 if(self.cnt <= 10)
1118                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1119                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1120                 {
1121                         if(self.cnt <= 10)
1122                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1123                         if(self.owner.killindicator_teamchange)
1124                         {
1125                                 if(self.owner.killindicator_teamchange == -1)
1126                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1127                                 else
1128                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1129                         }
1130                         else
1131                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1132                 }
1133                 self.nextthink = time + 1;
1134                 self.cnt -= 1;
1135         }
1136 }
1137
1138 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1139 {
1140         float killtime;
1141         entity e;
1142         killtime = cvar("g_balance_kill_delay");
1143
1144         if(g_race_qualifying)
1145                 killtime = 0;
1146
1147         self.killindicator_teamchange = targetteam;
1148
1149         if(!self.killindicator)
1150         {
1151                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1152                 {
1153                         ClientKill_Now();
1154                 }
1155                 else
1156                 {
1157                         self.killindicator = spawn();
1158                         self.killindicator.owner = self;
1159                         self.killindicator.scale = 0.5;
1160                         setattachment(self.killindicator, self, "");
1161                         setorigin(self.killindicator, '0 0 52');
1162                         self.killindicator.think = KillIndicator_Think;
1163                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1164                         self.killindicator.cnt = ceil(killtime);
1165                         self.killindicator.count = bound(0, ceil(killtime), 10);
1166                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1167
1168                         for(e = world; (e = find(e, classname, "body")) != world; )
1169                         {
1170                                 if(e.enemy != self)
1171                                         continue;
1172                                 e.killindicator = spawn();
1173                                 e.killindicator.owner = e;
1174                                 e.killindicator.scale = 0.5;
1175                                 setattachment(e.killindicator, e, "");
1176                                 setorigin(e.killindicator, '0 0 52');
1177                                 e.killindicator.think = KillIndicator_Think;
1178                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1179                                 e.killindicator.cnt = ceil(killtime);
1180                         }
1181                         self.lip = 0;
1182                 }
1183         }
1184         if(self.killindicator)
1185         {
1186                 if(targetteam)
1187                         self.killindicator.colormod = TeamColor(targetteam);
1188                 else
1189                         self.killindicator.colormod = '0 0 0';
1190         }
1191 }
1192
1193 void ClientKill (void)
1194 {
1195         ClientKill_TeamChange(0);
1196 }
1197
1198 void DoTeamChange(float destteam)
1199 {
1200         float t, c0;
1201         if(!teams_matter)
1202         {
1203                 if(destteam >= 0)
1204                         SetPlayerColors(self, destteam);
1205                 return;
1206         }
1207         if(self.classname == "player")
1208         if(destteam == -1)
1209         {
1210                 CheckAllowedTeams(self);
1211                 t = FindSmallestTeam(self, TRUE);
1212                 switch(self.team)
1213                 {
1214                         case COLOR_TEAM1: c0 = c1; break;
1215                         case COLOR_TEAM2: c0 = c2; break;
1216                         case COLOR_TEAM3: c0 = c3; break;
1217                         case COLOR_TEAM4: c0 = c4; break;
1218                         default:          c0 = 999;
1219                 }
1220                 switch(t)
1221                 {
1222                         case 1:
1223                                 if(c0 > c1)
1224                                         destteam = COLOR_TEAM1;
1225                                 break;
1226                         case 2:
1227                                 if(c0 > c2)
1228                                         destteam = COLOR_TEAM2;
1229                                 break;
1230                         case 3:
1231                                 if(c0 > c3)
1232                                         destteam = COLOR_TEAM3;
1233                                 break;
1234                         case 4:
1235                                 if(c0 > c4)
1236                                         destteam = COLOR_TEAM4;
1237                                 break;
1238                 }
1239                 if(destteam == -1)
1240                         return;
1241         }
1242         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1243                 return;
1244         ClientKill_TeamChange(destteam);
1245 }
1246
1247 void FixClientCvars(entity e)
1248 {
1249         // send prediction settings to the client
1250         stuffcmd(e, "\nin_bindmap 0 0\n");
1251         if(g_race || g_cts)
1252                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1253         /*
1254          * we no longer need to stuff this. Remove this comment block if you feel
1255          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1256         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1257         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1258         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1259         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1260         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1261         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1262         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1263         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1264         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1265         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1266         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1267         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1268         stuffcmd(e, "cl_movement_edgefriction 1\n");
1269          */
1270 }
1271
1272 /*
1273 =============
1274 ClientConnect
1275
1276 Called when a client connects to the server
1277 =============
1278 */
1279 //void ctf_clientconnect();
1280 string ColoredTeamName(float t);
1281 void DecodeLevelParms (void);
1282 //void dom_player_join_team(entity pl);
1283 void ClientConnect (void)
1284 {
1285         local string s;
1286         float t;
1287
1288         if(self.flags & FL_CLIENT)
1289         {
1290                 print("Warning: ClientConnect, but already connected!\n");
1291                 return;
1292         }
1293
1294         if(Ban_MaybeEnforceBan(self))
1295                 return;
1296
1297         DecodeLevelParms();
1298
1299         self.classname = "player_joining";
1300
1301         self.flags = FL_CLIENT;
1302         self.version_nagtime = time + 10 + random() * 10;
1303
1304         if(player_count<0)
1305         {
1306                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1307                 player_count = 0;
1308         }
1309
1310         PlayerScore_Attach(self);
1311         ClientData_Attach();
1312
1313         bot_clientconnect();
1314
1315         race_PreSpawnObserver();
1316
1317         //if(g_domination)
1318         //      dom_player_join_team(self);
1319
1320         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1321
1322         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1323                 self.classname = "observer";
1324         } else {
1325                 if(teams_matter)
1326                 {
1327                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1328                         {
1329                                 self.classname = "player";
1330                                 campaign_bots_may_start = 1;
1331                         }
1332                         else
1333                         {
1334                                 self.classname = "observer"; // do it anyway
1335                         }
1336                 }
1337                 else
1338                 {
1339                         self.classname = "player";
1340                         campaign_bots_may_start = 1;
1341                 }
1342         }
1343
1344         self.playerid = (playerid_last = playerid_last + 1);
1345         if(cvar("sv_eventlog"))
1346         {
1347                 if(clienttype(self) == CLIENTTYPE_REAL)
1348                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1349                 else
1350                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1351                 s = strcat(":team:", ftos(self.playerid), ":");
1352                 s = strcat(s, ftos(self.team));
1353                 GameLogEcho(s);
1354         }
1355         self.netname_previous = strzone(self.netname);
1356
1357         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1358
1359         bprint ("^4",self.netname);
1360         bprint ("^4 connected");
1361
1362         if(g_domination || g_ctf)
1363         {
1364                 bprint(" and joined the ");
1365                 bprint(ColoredTeamName(self.team));
1366         }
1367
1368         bprint("\n");
1369
1370         self.welcomemessage_time = 0;
1371
1372         stuffcmd(self, strcat(clientstuff, "\n"));
1373         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1374         stuffcmd(self, "cl_particles_reloadeffects\n");
1375
1376         FixClientCvars(self);
1377
1378         // spawnfunc_waypoint sprites
1379         WaypointSprite_InitClient(self);
1380
1381         // Wazat's grappling hook
1382         SetGrappleHookBindings();
1383
1384         // get autoswitch state from player when he toggles it
1385         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1386
1387         // get version info from player
1388         stuffcmd(self, "cmd clientversion $gameversion\n");
1389
1390         // get other cvars from player
1391         GetCvars(0);
1392
1393         // set cvar for team scoreboard
1394         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1395
1396         // notify about available teams
1397         if(teams_matter)
1398         {
1399                 CheckAllowedTeams(self);
1400                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1401                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1402         }
1403         else
1404                 stuffcmd(self, "set _teams_available 0\n");
1405
1406         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1407
1408         if(g_arena)
1409         {
1410                 self.classname = "observer";
1411                 Spawnqueue_Insert(self);
1412         }
1413         /*else if(g_ctf)
1414         {
1415                 ctf_clientconnect();
1416         }*/
1417
1418         if(teams_matter || sv_cheats)
1419                 attach_entcs();
1420
1421         bot_relinkplayerlist();
1422
1423         self.spectatortime = time;
1424         if(blockSpectators)
1425         {
1426                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1427         }
1428
1429         self.jointime = time;
1430         self.allowedTimeouts = cvar("sv_timeout_number");
1431
1432         if(clienttype(self) == CLIENTTYPE_REAL)
1433         {
1434                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1435                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1436         }
1437
1438         if(g_lms)
1439         {
1440                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1441                 {
1442                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1443                         self.frags = FRAGS_SPECTATOR;
1444                 }
1445         }
1446
1447         if(!sv_foginterval && world.fog != "")
1448                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1449
1450         SoundEntity_Attach(self);
1451
1452         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1453         {
1454                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1455                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1456         }
1457         else
1458                 self.hitplotfh = -1;
1459
1460         if(g_race || g_cts) {
1461                 string rr;
1462                 if(g_cts)
1463                         rr = CTS_RECORD;
1464                 else
1465                         rr = RACE_RECORD;
1466                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1467
1468                 race_send_recordtime(t, MSG_ONE);
1469                 race_send_speedaward(MSG_ONE);
1470
1471                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), "bestspeed")));
1472                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), "bestspeed_holder"));
1473                 race_send_speedaward_alltimebest(MSG_ONE);
1474         }
1475 }
1476
1477 /*
1478 =============
1479 ClientDisconnect
1480
1481 Called when a client disconnects from the server
1482 =============
1483 */
1484 .entity chatbubbleentity;
1485 .entity teambubbleentity;
1486 void ReadyCount();
1487 void ClientDisconnect (void)
1488 {
1489         if not(self.flags & FL_CLIENT)
1490         {
1491                 print("Warning: ClientDisconnect without ClientConnect\n");
1492                 return;
1493         }
1494
1495         if(self.hitplotfh >= 0)
1496         {
1497                 fclose(self.hitplotfh);
1498                 self.hitplotfh = -1;
1499         }
1500
1501         bot_clientdisconnect();
1502
1503         if(self.entcs)
1504                 detach_entcs();
1505
1506         if(cvar("sv_eventlog"))
1507                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1508         bprint ("^4",self.netname);
1509         bprint ("^4 disconnected\n");
1510
1511         SoundEntity_Detach(self);
1512
1513         DropAllRunes(self);
1514         kh_Key_DropAll(self, TRUE);
1515
1516         Portal_ClearAll(self);
1517
1518         if(self.flagcarried)
1519                 DropFlag(self.flagcarried, world, world);
1520         if(self.ballcarried)
1521                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1522
1523         // Here, everything has been done that requires this player to be a client.
1524
1525         self.flags &~= FL_CLIENT;
1526
1527         if (self.chatbubbleentity)
1528                 remove (self.chatbubbleentity);
1529
1530         if (self.teambubbleentity)
1531                 remove (self.teambubbleentity);
1532
1533         if (self.killindicator)
1534                 remove (self.killindicator);
1535
1536         WaypointSprite_PlayerGone();
1537
1538         bot_relinkplayerlist();
1539
1540         // remove laserdot
1541         if(self.weaponentity)
1542                 if(self.weaponentity.lasertarget)
1543                         remove(self.weaponentity.lasertarget);
1544
1545         if(g_arena)
1546         {
1547                 Spawnqueue_Unmark(self);
1548                 Spawnqueue_Remove(self);
1549         }
1550
1551         ClientData_Detach();
1552         PlayerScore_Detach(self);
1553
1554         if(self.netname_previous)
1555                 strunzone(self.netname_previous);
1556         if(self.clientstatus)
1557                 strunzone(self.clientstatus);
1558
1559         ClearPlayerSounds();
1560
1561         if(self.personal)
1562                 remove(self.personal);
1563
1564         self.playerid = 0;
1565         ReadyCount();
1566
1567         // free cvars
1568         GetCvars(-1);
1569 }
1570
1571 .float BUTTON_CHAT;
1572 void ChatBubbleThink()
1573 {
1574         self.nextthink = time;
1575         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1576         {
1577                 if(self.owner) // but why can that ever be world?
1578                         self.owner.chatbubbleentity = world;
1579                 remove(self);
1580                 return;
1581         }
1582         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1583 #ifdef TETRIS
1584                 || self.owner.tetris_on
1585 #endif
1586         )
1587                 self.model = self.mdl;
1588         else
1589                 self.model = "";
1590 };
1591
1592 void UpdateChatBubble()
1593 {
1594         if (!self.modelindex)
1595                 return;
1596         // spawn a chatbubble entity if needed
1597         if (!self.chatbubbleentity)
1598         {
1599                 self.chatbubbleentity = spawn();
1600                 self.chatbubbleentity.owner = self;
1601                 self.chatbubbleentity.exteriormodeltoclient = self;
1602                 self.chatbubbleentity.think = ChatBubbleThink;
1603                 self.chatbubbleentity.nextthink = time;
1604                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1605                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1606                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1607                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1608                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1609                 self.chatbubbleentity.model = "";
1610                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1611         }
1612 }
1613
1614
1615 void TeamBubbleThink()
1616 {
1617         self.nextthink = time;
1618         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1619         {
1620                 if(self.owner) // but why can that ever be world?
1621                         self.owner.teambubbleentity = world;
1622                 remove(self);
1623                 return;
1624         }
1625 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1626         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1627                 self.model = "";
1628         else
1629                 self.model = self.mdl;
1630
1631 };
1632
1633 float TeamBubble_customizeentityforclient()
1634 {
1635         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1636 }
1637
1638 void UpdateTeamBubble()
1639 {
1640         if (!self.modelindex || !teams_matter)
1641                 return;
1642         // spawn a teambubble entity if needed
1643         if (!self.teambubbleentity && teams_matter)
1644         {
1645                 self.teambubbleentity = spawn();
1646                 self.teambubbleentity.owner = self;
1647                 self.teambubbleentity.exteriormodeltoclient = self;
1648                 self.teambubbleentity.think = TeamBubbleThink;
1649                 self.teambubbleentity.nextthink = time;
1650                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1651 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1652                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1653                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1654                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1655                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1656                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1657                 self.teambubbleentity.effects = EF_LOWPRECISION;
1658         }
1659 }
1660
1661 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1662 // added to the model skins
1663 /*void UpdateColorModHack()
1664 {
1665         local float c;
1666         c = self.clientcolors & 15;
1667         // LordHavoc: only bothering to support white, green, red, yellow, blue
1668              if (!teams_matter) self.colormod = '0 0 0';
1669         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1670         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1671         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1672         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1673         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1674         else self.colormod = '1 1 1';
1675 };*/
1676
1677 void respawn(void)
1678 {
1679         CopyBody(1);
1680         self.effects |= EF_NODRAW; // prevent another CopyBody
1681         PutClientInServer();
1682 }
1683
1684 void play_countdown(float finished, string samp)
1685 {
1686         if(clienttype(self) == CLIENTTYPE_REAL)
1687                 if(floor(finished - time - frametime) != floor(finished - time))
1688                         if(finished - time < 6)
1689                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1690 }
1691
1692 /**
1693  * When sv_timeout is used this function returs strings like
1694  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1695  * Called by centerprint functions
1696  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1697  */
1698 string getTimeoutText(float addOneSecond) {
1699         if (!cvar("sv_timeout") || !timeoutStatus)
1700                 return "";
1701
1702         local string retStr;
1703         if (timeoutStatus == 1) {
1704                 if (addOneSecond == 1) {
1705                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1706                 }
1707                 else {
1708                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1709                 }
1710                 return retStr;
1711         }
1712         else if (timeoutStatus == 2) {
1713                 if (addOneSecond) {
1714                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1715                         //don't show messages like "Timeout ends in 0 seconds"...
1716                         if ((remainingTimeoutTime + 1) > 0)
1717                                 return retStr;
1718                         else
1719                                 return "";
1720                 }
1721                 else {
1722                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1723                         //don't show messages like "Timeout ends in 0 seconds"...
1724                         if (remainingTimeoutTime > 0)
1725                                 return retStr;
1726                         else
1727                                 return "";
1728                 }
1729         }
1730         else return "";
1731 }
1732
1733 void player_powerups (void)
1734 {
1735         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1736         {
1737                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1738                 self.modelflags |= MF_ROCKET;
1739         }
1740         else
1741         {
1742                 SoundEntity_StopSound(self, CHAN_PLAYER);
1743                 self.modelflags &~= MF_ROCKET;
1744         }
1745
1746         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME);
1747
1748         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1749                 return;
1750
1751         Fire_ApplyDamage(self);
1752         Fire_ApplyEffect(self);
1753
1754         if (g_minstagib)
1755         {
1756                 self.effects |= EF_FULLBRIGHT;
1757
1758                 if (self.items & IT_STRENGTH)
1759                 {
1760                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1761                         if (time > self.strength_finished)
1762                         {
1763                                 self.alpha = default_player_alpha;
1764                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1765                                 self.items &~= IT_STRENGTH;
1766                                 sprint(self, "^3Invisibility has worn off\n");
1767                         }
1768                 }
1769                 else
1770                 {
1771                         if (time < self.strength_finished)
1772                         {
1773                                 self.alpha = g_minstagib_invis_alpha;
1774                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1775                                 self.items |= IT_STRENGTH;
1776                                 sprint(self, "^3You are invisible\n");
1777                         }
1778                 }
1779
1780                 if (self.items & IT_INVINCIBLE)
1781                 {
1782                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1783                         if (time > self.invincible_finished)
1784                         {
1785                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1786                                 sprint(self, "^3Speed has worn off\n");
1787                         }
1788                 }
1789                 else
1790                 {
1791                         if (time < self.invincible_finished)
1792                         {
1793                                 self.items = self.items | IT_INVINCIBLE;
1794                                 sprint(self, "^3You are on speed\n");
1795                         }
1796                 }
1797                 return;
1798         }
1799
1800         if (self.items & IT_STRENGTH)
1801         {
1802                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1803                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1804                 if (time > self.strength_finished)
1805                 {
1806                         self.items = self.items - (self.items & IT_STRENGTH);
1807                         sprint(self, "^3Strength has worn off\n");
1808                 }
1809         }
1810         else
1811         {
1812                 if (time < self.strength_finished)
1813                 {
1814                         self.items = self.items | IT_STRENGTH;
1815                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1816                 }
1817         }
1818         if (self.items & IT_INVINCIBLE)
1819         {
1820                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1821                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1822                 if (time > self.invincible_finished)
1823                 {
1824                         self.items = self.items - (self.items & IT_INVINCIBLE);
1825                         sprint(self, "^3Shield has worn off\n");
1826                 }
1827         }
1828         else
1829         {
1830                 if (time < self.invincible_finished)
1831                 {
1832                         self.items = self.items | IT_INVINCIBLE;
1833                         sprint(self, "^3Shield surrounds you\n");
1834                 }
1835         }
1836
1837         if (cvar("g_fullbrightplayers"))
1838                 self.effects = self.effects | EF_FULLBRIGHT;
1839
1840         // midair gamemode: damage only while in the air
1841         // if in midair mode, being on ground grants temporary invulnerability
1842         // (this is so that multishot weapon don't clear the ground flag on the
1843         // first damage in the frame, leaving the player vulnerable to the
1844         // remaining hits in the same frame)
1845         if (self.flags & FL_ONGROUND)
1846         if (g_midair)
1847                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1848
1849         if (time >= game_starttime)
1850         if (time < self.spawnshieldtime)
1851                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1852 }
1853
1854 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1855 {
1856         if(current > stable)
1857                 return current;
1858         else if(current > stable - 0.25) // when close enough, "snap"
1859                 return stable;
1860         else
1861                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1862 }
1863
1864 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1865 {
1866         if(current < stable)
1867                 return current;
1868         else if(current < stable + 0.25) // when close enough, "snap"
1869                 return stable;
1870         else
1871                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1872 }
1873
1874 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1875 {
1876         if(current > rotstable)
1877         {
1878                 if(rotframetime > 0)
1879                 {
1880                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1881                         current = max(rotstable, current - rotlinear * rotframetime);
1882                 }
1883         }
1884         else if(current < regenstable)
1885         {
1886                 if(regenframetime > 0)
1887                 {
1888                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1889                         current = min(regenstable, current + regenlinear * regenframetime);
1890                 }
1891         }
1892
1893         if(current > limit)
1894                 current = limit;
1895
1896         return current;
1897 }
1898
1899 void player_regen (void)
1900 {
1901         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1902         maxh = cvar("g_balance_health_rotstable");
1903         maxa = cvar("g_balance_armor_rotstable");
1904         maxf = cvar("g_balance_fuel_rotstable");
1905         minh = cvar("g_balance_health_regenstable");
1906         mina = cvar("g_balance_armor_regenstable");
1907         minf = cvar("g_balance_fuel_regenstable");
1908         limith = cvar("g_balance_health_limit");
1909         limita = cvar("g_balance_armor_limit");
1910         limitf = cvar("g_balance_fuel_limit");
1911
1912         max_mod = regen_mod = rot_mod = limit_mod = 1;
1913
1914         if (self.runes & RUNE_REGEN)
1915         {
1916                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1917                 {
1918                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1919                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1920                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1921                 }
1922                 else
1923                 {
1924                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1925                         max_mod = cvar("g_balance_rune_regen_hpmod");
1926                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1927                 }
1928         }
1929         else if (self.runes & CURSE_VENOM)
1930         {
1931                 max_mod = cvar("g_balance_curse_venom_hpmod");
1932                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1933                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1934                 else
1935                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1936                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1937                 //if (!self.runes & RUNE_REGEN)
1938                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1939         }
1940         maxh = maxh * max_mod;
1941         //maxa = maxa * max_mod;
1942         //maxf = maxf * max_mod;
1943         minh = minh * max_mod;
1944         //mina = mina * max_mod;
1945         //minf = minf * max_mod;
1946         limith = limith * limit_mod;
1947         limita = limita * limit_mod;
1948         //limitf = limitf * limit_mod;
1949
1950         if(g_lms)
1951                 rot_mod = 0;
1952
1953         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1954         {
1955                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1956                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1957
1958                 // if player rotted to death...  die!
1959                 if(self.health < 1)
1960                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1961         }
1962
1963         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1964                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1965 }
1966
1967 float zoomstate_set;
1968 void SetZoomState(float z)
1969 {
1970         if(z != self.zoomstate)
1971         {
1972                 self.zoomstate = z;
1973                 ClientData_Touch(self);
1974         }
1975         zoomstate_set = 1;
1976 }
1977
1978 void GetPressedKeys(void) {
1979         if (self.movement_x > 0) // get if movement keys are pressed
1980         {       // forward key pressed
1981                 self.pressedkeys |= KEY_FORWARD;
1982                 self.pressedkeys &~= KEY_BACKWARD;
1983         }
1984         else if (self.movement_x < 0)
1985         {       // backward key pressed
1986                 self.pressedkeys |= KEY_BACKWARD;
1987                 self.pressedkeys &~= KEY_FORWARD;
1988         }
1989         else
1990         {       // no x input
1991                 self.pressedkeys &~= KEY_FORWARD;
1992                 self.pressedkeys &~= KEY_BACKWARD;
1993         }
1994
1995         if (self.movement_y > 0)
1996         {       // right key pressed
1997                 self.pressedkeys |= KEY_RIGHT;
1998                 self.pressedkeys &~= KEY_LEFT;
1999         }
2000         else if (self.movement_y < 0)
2001         {       // left key pressed
2002                 self.pressedkeys |= KEY_LEFT;
2003                 self.pressedkeys &~= KEY_RIGHT;
2004         }
2005         else
2006         {       // no y input
2007                 self.pressedkeys &~= KEY_RIGHT;
2008                 self.pressedkeys &~= KEY_LEFT;
2009         }
2010
2011         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2012                 self.pressedkeys |= KEY_JUMP;
2013         else
2014                 self.pressedkeys &~= KEY_JUMP;
2015         if (self.BUTTON_CROUCH)
2016                 self.pressedkeys |= KEY_CROUCH;
2017         else
2018                 self.pressedkeys &~= KEY_CROUCH;
2019 }
2020
2021 /*
2022 ======================
2023 spectate mode routines
2024 ======================
2025 */
2026 void SpectateCopy(entity spectatee) {
2027         self.kh_state = spectatee.kh_state;
2028         self.armortype = spectatee.armortype;
2029         self.armorvalue = spectatee.armorvalue;
2030         self.ammo_cells = spectatee.ammo_cells;
2031         self.ammo_shells = spectatee.ammo_shells;
2032         self.ammo_nails = spectatee.ammo_nails;
2033         self.ammo_rockets = spectatee.ammo_rockets;
2034         self.ammo_fuel = spectatee.ammo_fuel;
2035         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2036         self.health = spectatee.health;
2037         self.impulse = 0;
2038         self.items = spectatee.items;
2039         self.metertime = spectatee.metertime;
2040         self.strength_finished = spectatee.strength_finished;
2041         self.invincible_finished = spectatee.invincible_finished;
2042         self.pressedkeys = spectatee.pressedkeys;
2043         self.weapons = spectatee.weapons;
2044         self.switchweapon = spectatee.switchweapon;
2045         self.weapon = spectatee.weapon;
2046         self.punchangle = spectatee.punchangle;
2047         self.view_ofs = spectatee.view_ofs;
2048         self.v_angle = spectatee.v_angle;
2049         self.velocity = spectatee.velocity;
2050         self.dmg_take = spectatee.dmg_take;
2051         self.dmg_save = spectatee.dmg_save;
2052         self.dmg_inflictor = spectatee.dmg_inflictor;
2053         self.angles = spectatee.v_angle;
2054         self.fixangle = TRUE;
2055         setorigin(self, spectatee.origin);
2056         setsize(self, spectatee.mins, spectatee.maxs);
2057         SetZoomState(spectatee.zoomstate);
2058 }
2059
2060 float SpectateUpdate() {
2061         if(!self.enemy)
2062                 return 0;
2063
2064         if (self == self.enemy)
2065                 return 0;
2066
2067         if(self.enemy.classname != "player")
2068                 return 0;
2069
2070         SpectateCopy(self.enemy);
2071
2072         return 1;
2073 }
2074
2075 float SpectateNext() {
2076         other = find(self.enemy, classname, "player");
2077         if (!other) {
2078                 other = find(other, classname, "player");
2079         }
2080         if (other) {
2081                 self.enemy = other;
2082         }
2083         if(self.enemy.classname == "player") {
2084                 msg_entity = self;
2085                 WriteByte(MSG_ONE, SVC_SETVIEW);
2086                 WriteEntity(MSG_ONE, self.enemy);
2087                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2088                 self.movetype = MOVETYPE_NONE;
2089                 if(!SpectateUpdate())
2090                         PutObserverInServer();
2091                 return 1;
2092         } else {
2093                 return 0;
2094         }
2095 }
2096
2097 /*
2098 =============
2099 ShowRespawnCountdown()
2100
2101 Update a respawn countdown display.
2102 =============
2103 */
2104 void ShowRespawnCountdown()
2105 {
2106         float number;
2107         if(self.deadflag == DEAD_NO) // just respawned?
2108                 return;
2109         else
2110         {
2111                 number = ceil(self.death_time - time);
2112                 if(number <= 0)
2113                         return;
2114                 if(number <= self.respawn_countdown)
2115                 {
2116                         self.respawn_countdown = number - 1;
2117                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2118                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2119                 }
2120         }
2121 }
2122
2123 void LeaveSpectatorMode()
2124 {
2125         if(isJoinAllowed()) {
2126                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2127                         self.classname = "player";
2128                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2129                                 JoinBestTeam(self, FALSE, TRUE);
2130                         if(cvar("g_campaign"))
2131                                 campaign_bots_may_start = 1;
2132                         PutClientInServer();
2133                         if(self.classname == "player")
2134                                 bprint ("^4", self.netname, "^4 is playing now\n");
2135                         if(!cvar("g_campaign"))
2136                                 centerprint(self,""); // clear MOTD
2137                         return;
2138                 } else {
2139                         stuffcmd(self,"menu_showteamselect\n");
2140                         return;
2141                 }
2142         }
2143         else {
2144                 //player may not join because of g_maxplayers is set
2145                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2146         }
2147 }
2148
2149 /**
2150  * Determines whether the player is allowed to join. This depends on cvar
2151  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2152  * it checks whether the number of currently playing players exceeds g_maxplayers.
2153  * @return bool TRUE if the player is allowed to join, false otherwise
2154  */
2155 float isJoinAllowed() {
2156         if (!cvar("g_maxplayers"))
2157                 return TRUE;
2158
2159         local entity e;
2160         local float currentlyPlaying;
2161         FOR_EACH_REALPLAYER(e) {
2162                 if(e.classname == "player")
2163                         currentlyPlaying += 1;
2164         }
2165         if(currentlyPlaying < cvar("g_maxplayers"))
2166                 return TRUE;
2167
2168         return FALSE;
2169 }
2170
2171 /**
2172  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2173  * g_maxplayers_spectator_blocktime seconds
2174  */
2175 void checkSpectatorBlock() {
2176         if(self.classname == "spectator" || self.classname == "observer") {
2177                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2178                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2179                         dropclient(self);
2180                 }
2181         }
2182 }
2183
2184 float vercmp_recursive(string v1, string v2)
2185 {
2186         float dot1, dot2;
2187         string s1, s2;
2188         float r;
2189
2190         dot1 = strstrofs(v1, ".", 0);
2191         dot2 = strstrofs(v2, ".", 0);
2192         if(dot1 == -1)
2193                 s1 = v1;
2194         else
2195                 s1 = substring(v1, 0, dot1);
2196         if(dot2 == -1)
2197                 s2 = v2;
2198         else
2199                 s2 = substring(v2, 0, dot2);
2200
2201         r = stof(s1) - stof(s2);
2202         if(r != 0)
2203                 return r;
2204
2205         r = strcasecmp(s1, s2);
2206         if(r != 0)
2207                 return r;
2208
2209         if(dot1 == -1)
2210                 if(dot2 == -1)
2211                         return 0;
2212                 else
2213                         return -1;
2214         else
2215                 if(dot2 == -1)
2216                         return 1;
2217                 else
2218                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2219 }
2220
2221 float vercmp(string v1, string v2)
2222 {
2223         if(strcasecmp(v1, v2) == 0) // early out check
2224                 return 0;
2225         return vercmp_recursive(v1, v2);
2226 }
2227
2228 void ObserverThink()
2229 {
2230         if (self.flags & FL_JUMPRELEASED) {
2231                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2232                         self.welcomemessage_time = 0;
2233                         self.flags &~= FL_JUMPRELEASED;
2234                         self.flags |= FL_SPAWNING;
2235                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2236                         self.welcomemessage_time = 0;
2237                         self.flags &~= FL_JUMPRELEASED;
2238                         if(SpectateNext() == 1) {
2239                                 self.classname = "spectator";
2240                         }
2241                 }
2242         } else {
2243                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2244                         self.flags |= FL_JUMPRELEASED;
2245                         if(self.flags & FL_SPAWNING)
2246                         {
2247                                 self.flags &~= FL_SPAWNING;
2248                                 LeaveSpectatorMode();
2249                                 return;
2250                         }
2251                 }
2252         }
2253         PrintWelcomeMessage(self);
2254 }
2255
2256 void SpectatorThink()
2257 {
2258         if (self.flags & FL_JUMPRELEASED) {
2259                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2260                         self.welcomemessage_time = 0;
2261                         self.flags &~= FL_JUMPRELEASED;
2262                         self.flags |= FL_SPAWNING;
2263                 } else if(self.BUTTON_ATCK) {
2264                         self.welcomemessage_time = 0;
2265                         self.flags &~= FL_JUMPRELEASED;
2266                         if(SpectateNext() == 1) {
2267                                 self.classname = "spectator";
2268                         } else {
2269                                 self.classname = "observer";
2270                                 PutClientInServer();
2271                         }
2272                 } else if (self.BUTTON_ATCK2) {
2273                         self.welcomemessage_time = 0;
2274                         self.flags &~= FL_JUMPRELEASED;
2275                         self.classname = "observer";
2276                         PutClientInServer();
2277                 } else {
2278                         if(!SpectateUpdate())
2279                                 PutObserverInServer();
2280                 }
2281         } else {
2282                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2283                         self.flags |= FL_JUMPRELEASED;
2284                         if(self.flags & FL_SPAWNING)
2285                         {
2286                                 self.flags &~= FL_SPAWNING;
2287                                 LeaveSpectatorMode();
2288                                 return;
2289                         }
2290                 }
2291         }
2292         PrintWelcomeMessage(self);
2293         self.flags |= FL_CLIENT | FL_NOTARGET;
2294 }
2295
2296 .float touchexplode_time;
2297
2298 /*
2299 =============
2300 PlayerPreThink
2301
2302 Called every frame for each client before the physics are run
2303 =============
2304 */
2305 void() ctf_setstatus;
2306 void() nexball_setstatus;
2307 .float items_added;
2308 void PlayerPreThink (void)
2309 {
2310         self.stat_game_starttime = game_starttime;
2311         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2312         self.stat_leadlimit = cvar("leadlimit");
2313
2314         if(blockSpectators && frametime)
2315                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2316                 checkSpectatorBlock();
2317
2318         zoomstate_set = 0;
2319
2320         if(self.netname_previous != self.netname)
2321         {
2322                 if(cvar("sv_eventlog"))
2323                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2324                 if(self.netname_previous)
2325                         strunzone(self.netname_previous);
2326                 self.netname_previous = strzone(self.netname);
2327         }
2328
2329         // version nagging
2330         if(self.version_nagtime)
2331                 if(self.cvar_g_nexuizversion)
2332                         if(time > self.version_nagtime)
2333                         {
2334                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2335                                 {
2336                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2337                                         {
2338                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2339                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2340                                         }
2341                                         else
2342                                         {
2343                                                 float r;
2344                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2345                                                 if(r < 0)
2346                                                 {
2347                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2348                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2349                                                 }
2350                                                 else if(r > 0)
2351                                                 {
2352                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2353                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2354                                                 }
2355                                         }
2356                                 }
2357                                 self.version_nagtime = 0;
2358                         }
2359
2360         // GOD MODE info
2361         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2362         {
2363                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2364                 self.max_armorvalue = 0;
2365         }
2366
2367 #ifdef TETRIS
2368         if (TetrisPreFrame())
2369                 return;
2370 #endif
2371
2372         if(self.classname == "player") {
2373 //              if(self.netname == "Wazat")
2374 //                      bprint(self.classname, "\n");
2375
2376                 CheckRules_Player();
2377
2378                 PrintWelcomeMessage(self);
2379
2380                 if (intermission_running)
2381                 {
2382                         IntermissionThink ();   // otherwise a button could be missed between
2383                         return;                                 // the think tics
2384                 }
2385
2386                 if(self.teleport_time)
2387                 if(time > self.teleport_time)
2388                 {
2389                         self.teleport_time = 0;
2390                         self.effects = self.effects - (self.effects & EF_NODRAW);
2391                 }
2392
2393                 Nixnex_GiveCurrentWeapon();
2394
2395                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2396                         UpdateSelectedPlayer();
2397
2398                 //don't allow the player to turn around while game is paused!
2399                 if(timeoutStatus == 2) {
2400                         self.v_angle = self.lastV_angle;
2401                         self.angles = self.lastV_angle;
2402                         self.fixangle = TRUE;
2403                 }
2404
2405                 if(frametime)
2406                         player_powerups();
2407
2408                 if (self.deadflag != DEAD_NO)
2409                 {
2410                         float button_pressed, force_respawn;
2411                         if(self.personal && g_race_qualifying)
2412                         {
2413                                 if(time > self.death_time)
2414                                 {
2415                                         self.death_time = time + 1; // only retry once a second
2416                                         respawn();
2417                                         self.impulse = 141;
2418                                 }
2419                         }
2420                         else
2421                         {
2422                                 if(frametime)
2423                                         player_anim();
2424                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2425                                 force_respawn = (g_lms || cvar("g_forced_respawn"));
2426                                 if (self.deadflag == DEAD_DYING)
2427                                 {
2428                                         if(force_respawn)
2429                                                 self.deadflag = DEAD_RESPAWNING;
2430                                         else if(!button_pressed)
2431                                                 self.deadflag = DEAD_DEAD;
2432                                 }
2433                                 else if (self.deadflag == DEAD_DEAD)
2434                                 {
2435                                         if(button_pressed)
2436                                                 self.deadflag = DEAD_RESPAWNABLE;
2437                                 }
2438                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2439                                 {
2440                                         if(!button_pressed)
2441                                                 self.deadflag = DEAD_RESPAWNING;
2442                                 }
2443                                 else if (self.deadflag == DEAD_RESPAWNING)
2444                                 {
2445                                         if(time > self.death_time)
2446                                         {
2447                                                 self.death_time = time + 1; // only retry once a second
2448                                                 respawn();
2449                                         }
2450                                 }
2451                                 ShowRespawnCountdown();
2452                         }
2453                         return;
2454                 }
2455
2456                 if(g_touchexplode)
2457                 if(time > self.touchexplode_time)
2458                 if(self.classname == "player")
2459                 if(self.deadflag == DEAD_NO)
2460                 if not(IS_INDEPENDENT_PLAYER(self))
2461                 FOR_EACH_PLAYER(other) if(self != other)
2462                 {
2463                         if(time > other.touchexplode_time)
2464                         if(other.classname == "player")
2465                         if(other.deadflag == DEAD_NO)
2466                         if not(IS_INDEPENDENT_PLAYER(other))
2467                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2468                         {
2469                                 PlayerTouchExplode(self, other);
2470                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2471                         }
2472                 }
2473
2474                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2475                 {
2476                         vector dist;
2477
2478                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2479                         dist = self.prevorigin - self.origin;
2480                         dist_z = 0;
2481                         self.lms_traveled_distance += fabs(vlen(dist));
2482
2483                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2484                         {
2485                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2486                                 self.lms_traveled_distance = 0;
2487                         }
2488
2489                         if(time > self.lms_nextcheck)
2490                         {
2491                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2492                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2493                                 {
2494                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2495                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2496                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2497                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2498                                 }
2499                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2500                                 self.lms_traveled_distance = 0;
2501                         }
2502                 }
2503
2504                 self.prevorigin = self.origin;
2505
2506                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2507                 {
2508                         if (!self.crouch)
2509                         {
2510                                 self.crouch = TRUE;
2511                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2512                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2513                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2514                         }
2515                 }
2516                 else
2517                 {
2518                         if (self.crouch)
2519                         {
2520                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2521                                 if (!trace_startsolid)
2522                                 {
2523                                         self.crouch = FALSE;
2524                                         self.view_ofs = PL_VIEW_OFS;
2525                                         setsize (self, PL_MIN, PL_MAX);
2526                                 }
2527                         }
2528                 }
2529
2530                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2531                 {
2532                         if(self.bloodloss_timer < time)
2533                         {
2534                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2535                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2536                         }
2537                 }
2538
2539                 FixPlayermodel();
2540
2541                 GrapplingHookFrame();
2542
2543                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2544                 //if(frametime)
2545                 {
2546                         self.items &~= self.items_added;
2547
2548                         W_WeaponFrame();
2549
2550                         self.items_added = 0;
2551                         if(self.items & IT_JETPACK)
2552                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2553                                         self.items_added |= IT_FUEL;
2554
2555                         self.items |= self.items_added;
2556                 }
2557
2558                 player_regen();
2559                 if(frametime)
2560                         player_anim();
2561
2562                 if (g_minstagib)
2563                         minstagib_ammocheck();
2564
2565                 ctf_setstatus();
2566                 nexball_setstatus();
2567
2568                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2569
2570                 //self.angles_y=self.v_angle_y + 90;   // temp
2571         } else if(gameover) {
2572                 if (intermission_running)
2573                         IntermissionThink ();   // otherwise a button could be missed between
2574                 return;
2575         } else if(self.classname == "observer") {
2576                 ObserverThink();
2577         } else if(self.classname == "spectator") {
2578                 SpectatorThink();
2579         }
2580
2581         if(!zoomstate_set)
2582                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2583
2584         float oldspectatee_status;
2585         oldspectatee_status = self.spectatee_status;
2586         if(self.classname == "spectator")
2587                 self.spectatee_status = num_for_edict(self.enemy);
2588         else if(self.classname == "observer")
2589                 self.spectatee_status = num_for_edict(self);
2590         else
2591                 self.spectatee_status = 0;
2592         if(self.spectatee_status != oldspectatee_status)
2593         {
2594                 ClientData_Touch(self);
2595                 if(g_race || g_cts)
2596                         race_InitSpectator();
2597         }
2598
2599         if(self.teamkill_soundtime)
2600         if(time > self.teamkill_soundtime)
2601         {
2602                 self.teamkill_soundtime = 0;
2603
2604                 entity oldpusher, oldself;
2605
2606                 oldself = self; self = self.teamkill_soundsource;
2607                 oldpusher = self.pusher; self.pusher = oldself;
2608
2609                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2610
2611                 self.pusher = oldpusher;
2612                 self = oldself;
2613         }
2614
2615         if(self.taunt_soundtime)
2616         if(time > self.taunt_soundtime)
2617         {
2618                 self.taunt_soundtime = 0;
2619                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2620         }
2621
2622         target_voicescript_next(self);
2623 }
2624
2625 // on dragger:
2626 .entity dragentity;
2627 .float draggravity;
2628 .float dragspeed; // speed of mouse wheel action
2629 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2630 .vector draglocalvector; // local attachment vector of the dragentity
2631 .float draglocalangle;
2632 // on draggee:
2633 .entity draggedby;
2634 .float dragmovetype;
2635 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2636 {
2637         float tagscale;
2638
2639         draggee.dragmovetype = draggee.movetype;
2640         draggee.draggravity = draggee.gravity;
2641         draggee.movetype = MOVETYPE_WALK;
2642         draggee.gravity = 0.00001;
2643         draggee.flags &~= FL_ONGROUND;
2644         draggee.draggedby = dragger;
2645
2646         dragger.dragentity = draggee;
2647
2648         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2649         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2650         touchpoint = touchpoint - gettaginfo(draggee, 0);
2651         tagscale = pow(vlen(v_forward), -2);
2652         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2653         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2654         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2655
2656         dragger.dragspeed = 64;
2657 }
2658
2659 void Drag_Finish(entity dragger)
2660 {
2661         entity draggee;
2662         draggee = dragger.dragentity;
2663         if(dragger)
2664                 dragger.dragentity = world;
2665         draggee.draggedby = world;
2666         draggee.movetype = draggee.dragmovetype;
2667         draggee.gravity = draggee.draggravity;
2668
2669         switch(draggee.movetype)
2670         {
2671                 case MOVETYPE_TOSS:
2672                 case MOVETYPE_WALK:
2673                 case MOVETYPE_STEP:
2674                 case MOVETYPE_FLYMISSILE:
2675                 case MOVETYPE_BOUNCE:
2676                 case MOVETYPE_BOUNCEMISSILE:
2677                         break;
2678                 default:
2679                         draggee.velocity = '0 0 0';
2680                         break;
2681         }
2682
2683         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2684         {
2685                 draggee.velocity = '0 0 0';
2686                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2687         }
2688 }
2689
2690 float Drag_IsDraggable(entity draggee)
2691 {
2692         // TODO add more checks for bad stuff here
2693         if(draggee.classname == "func_bobbing")
2694                 return FALSE;
2695         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2696                 return FALSE;
2697         if(draggee.classname == "plat")
2698                 return FALSE;
2699         if(draggee.classname == "func_button")
2700                 return FALSE;
2701         if(draggee.model == "")
2702                 return FALSE;
2703         if(draggee.classname == "spectator")
2704                 return FALSE;
2705         if(draggee.classname == "observer")
2706                 return FALSE;
2707         if(draggee.classname == "exteriorweaponentity")
2708                 return FALSE;
2709
2710         return TRUE;
2711 }
2712
2713 float Drag_MayChangeAngles(entity draggee)
2714 {
2715         // TODO add more checks for bad stuff here
2716         if(substring(draggee.model, 0, 1) == "*")
2717                 return FALSE;
2718         return TRUE;
2719 }
2720
2721 void Drag_MoveForward(entity dragger)
2722 {
2723         dragger.dragdistance += dragger.dragspeed;
2724 }
2725
2726 void Drag_SetSpeed(entity dragger, float s)
2727 {
2728         dragger.dragspeed = pow(2, s);
2729 }
2730
2731 void Drag_MoveBackward(entity dragger)
2732 {
2733         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2734 }
2735
2736 void Drag_Update(entity dragger)
2737 {
2738         vector curorigin, neworigin, goodvelocity;
2739         float f;
2740         entity draggee;
2741
2742         draggee = dragger.dragentity;
2743         draggee.flags &~= FL_ONGROUND;
2744
2745         curorigin = gettaginfo(draggee, 0);
2746         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2747         makevectors(dragger.v_angle);
2748         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2749         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2750
2751         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2752                 dragger.draglocalangle += 360;
2753         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2754                 dragger.draglocalangle -= 360;
2755
2756         f = min(frametime * 10, 1);
2757         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2758
2759         if(Drag_MayChangeAngles(draggee))
2760                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2761
2762         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2763
2764         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2765 }
2766
2767 float Drag_CanDrag(entity dragger)
2768 {
2769         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2770 }
2771
2772 float Drag_IsDragging(entity dragger)
2773 {
2774         if(!dragger.dragentity)
2775                 return FALSE;
2776         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2777         {
2778                 dragger.dragentity = world;
2779                 return FALSE;
2780         }
2781         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2782         {
2783                 Drag_Finish(dragger);
2784                 return FALSE;
2785         }
2786         return TRUE;
2787 }
2788
2789 void Drag_MoveDrag(entity from, entity to)
2790 {
2791         if(from.draggedby)
2792         {
2793                 to.draggedby = from.draggedby;
2794                 to.draggedby.dragentity = to;
2795                 from.draggedby = world;
2796         }
2797 }
2798
2799 /*
2800 =============
2801 PlayerPostThink
2802
2803 Called every frame for each client after the physics are run
2804 =============
2805 */
2806 .float idlekick_lasttimeleft;
2807 void PlayerPostThink (void)
2808 {
2809         // Savage: Check for nameless players
2810         if (strlen(self.netname) < 1) {
2811                 self.netname = "Player";
2812                 stuffcmd(self, "seta _cl_name Player\n");
2813         }
2814
2815         if(sv_maxidle && frametime)
2816         {
2817                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2818                 float timeleft;
2819                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2820                 if(timeleft <= 0)
2821                 {
2822                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2823                         announce(self, "announcer/robotic/terminated.wav");
2824                         dropclient(self);
2825                         return;
2826                 }
2827                 else if(timeleft <= 10)
2828                 {
2829                         if(timeleft != self.idlekick_lasttimeleft)
2830                         {
2831                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2832                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2833                         }
2834                 }
2835                 else
2836                 {
2837                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2838                 }
2839                 self.idlekick_lasttimeleft = timeleft;
2840         }
2841
2842 #ifdef TETRIS
2843         if(self.impulse == 100)
2844                 ImpulseCommands();
2845         if (TetrisPostFrame())
2846                 return;
2847 #endif
2848
2849         if(sv_cheats || self.maycheat)
2850                 if(Drag_CanDrag(self))
2851                         if(self.BUTTON_DRAG)
2852                                 if(!self.dragentity)
2853                                         if(self.cursor_trace_ent)
2854                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2855                                                 {
2856                                                         if(self.cursor_trace_ent.draggedby)
2857                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2858                                                         if(self.cursor_trace_ent.tag_entity)
2859                                                                 detach_sameorigin(self.cursor_trace_ent);
2860                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2861                                                 }
2862
2863         if(Drag_IsDragging(self))
2864         {
2865                 if(self.BUTTON_DRAG)
2866                 {
2867                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2868                         {
2869                                 Drag_MoveForward(self);
2870                                 self.impulse = 0;
2871                         }
2872                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2873                         {
2874                                 Drag_MoveBackward(self);
2875                                 self.impulse = 0;
2876                         }
2877                         else if(self.impulse >= 1 && self.impulse <= 9)
2878                         {
2879                                 Drag_SetSpeed(self, self.impulse - 1);
2880                         }
2881                         else if(self.impulse == 14)
2882                         {
2883                                 Drag_SetSpeed(self, 9);
2884                         }
2885
2886                         if(frametime)
2887                                 Drag_Update(self);
2888                 }
2889                 else
2890                 {
2891                         Drag_Finish(self);
2892                 }
2893         }
2894
2895         if(self.classname == "player") {
2896                 CheckRules_Player();
2897                 UpdateChatBubble();
2898                 UpdateTeamBubble();
2899                 if (self.impulse)
2900                         ImpulseCommands();
2901                 if (intermission_running)
2902                         return;         // intermission or finale
2903
2904                 GetPressedKeys();
2905         } else if (self.classname == "observer") {
2906                 //do nothing
2907         } else if (self.classname == "spectator") {
2908                 //do nothing
2909         }
2910
2911         /*
2912         float i;
2913         for(i = 0; i < 1000; ++i)
2914         {
2915                 vector end;
2916                 end = self.origin + '0 0 1024' + 512 * randomvec();
2917                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2918                 if(trace_fraction < 1)
2919                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2920                 {
2921                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2922                         break;
2923                 }
2924         }
2925         */
2926
2927         Arena_Warmup();
2928
2929         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2930
2931         if(self.waypointsprite_attachedforcarrier)
2932                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2933 }