sync crosshair effects to weapon switch delay
[divverent/nexuiz.git] / data / qcsrc / server / cl_client.qc
1 void race_send_recordtime(float t, float msg);
2
3 float ClientData_Send(entity to, float sf)
4 {
5         if(to != self.owner)
6         {
7                 error("wtf");
8                 return FALSE;
9         }
10
11         entity e;
12
13         e = to;
14         if(to.classname == "spectator")
15                 e = to.enemy;
16
17         sf = 0;
18
19         if(e.race_completed)
20                 sf |= 1; // forced scoreboard
21         if(to.spectatee_status)
22                 sf |= 2; // spectator ent number follows
23         if(e.zoomstate)
24                 sf |= 4; // zoomed
25         if(e.porto_v_angle_held)
26                 sf |= 8; // angles held
27
28         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
29         WriteByte(MSG_ENTITY, sf);
30
31         if(sf & 2)
32                 WriteByte(MSG_ENTITY, to.spectatee_status);
33
34         if(sf & 8)
35         {
36                 WriteAngle(MSG_ENTITY, e.v_angle_x);
37                 WriteAngle(MSG_ENTITY, e.v_angle_y);
38         }
39
40         return TRUE;
41 }
42
43 void ClientData_Attach()
44 {
45         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
46         self.clientdata.drawonlytoclient = self;
47         self.clientdata.owner = self;
48 }
49
50 void ClientData_Detach()
51 {
52         remove(self.clientdata);
53         self.clientdata = world;
54 }
55
56 void ClientData_Touch(entity e)
57 {
58         e.clientdata.SendFlags = 1;
59
60         // make it spectatable
61         entity e2;
62         FOR_EACH_REALCLIENT(e2)
63         {
64                 if(e2 != e)
65                         if(e2.classname == "spectator")
66                                 if(e2.enemy == e)
67                                         e2.clientdata.SendFlags = 1;
68         }
69 }
70
71
72 #define SPAWNPOINT_SCORE frags
73
74 .string netname_previous;
75
76 void spawnfunc_info_player_survivor (void)
77 {
78         spawnfunc_info_player_deathmatch();
79 }
80
81 void spawnfunc_info_player_start (void)
82 {
83         spawnfunc_info_player_deathmatch();
84 }
85
86 void spawnfunc_info_player_deathmatch (void)
87 {
88         self.classname = "info_player_deathmatch";
89         relocate_spawnpoint();
90 }
91
92 void spawnpoint_use()
93 {
94         if(teams_matter)
95         if(have_team_spawns)
96         {
97                 self.team = activator.team;
98                 some_spawn_has_been_used = 1;
99         }
100 };
101
102 // Returns:
103 //   -1 if a spawn can't be used
104 //   otherwise, a weight of the spawnpoint
105 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
106 {
107         float shortest, thisdist;
108         entity player;
109
110         // filter out spots for the wrong team
111         if(teamcheck)
112         if(spot.team != teamcheck)
113                 return -1;
114
115         if(race_spawns)
116                 if(spot.target == "")
117                         return -1;
118
119         if(clienttype(self) == CLIENTTYPE_REAL)
120         {
121                 if(spot.restriction == 1)
122                         return -1;
123         }
124         else
125         {
126                 if(spot.restriction == 2)
127                         return -1;
128         }
129
130         // filter out spots for assault
131         if(spot.target != "") {
132                 local entity ent;
133                 float good, found;
134                 ent = find(world, targetname, spot.target);
135                 while(ent) {
136                         if(ent.classname == "target_objective")
137                         {
138                                 found = 1;
139                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
140                                         return -1;
141                                 good = 1;
142                         }
143                         else if(ent.classname == "trigger_race_checkpoint")
144                         {
145                                 found = 1;
146                                 if(self.classname == "player") // spectators may spawn everywhere
147                                 {
148                                         if(g_race_qualifying)
149                                         {
150                                                 // spawn at first
151                                                 if(ent.race_checkpoint != 0)
152                                                         return -1;
153                                                 if(spot.race_place != race_lowest_place_spawn)
154                                                         return -1;
155                                         }
156                                         else
157                                         {
158                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
159                                                         return -1;
160                                                 float pl;
161                                                 pl = self.race_place;
162                                                 if(pl > race_highest_place_spawn)
163                                                         pl = 0;
164                                                 if(spot.race_place != pl)
165                                                         return -1;
166                                         }
167                                 }
168                                 good = 1;
169                         }
170                         ent = find(ent, targetname, spot.target);
171                 }
172
173                 if(found && !good)
174                         return -1;
175         }
176
177         player = playerlist;
178         shortest = vlen(world.maxs - world.mins);
179         for(player = playerlist; player; player = player.chain)
180                 if (player != self)
181                 {
182                         thisdist = vlen(player.origin - spot.origin);
183                         if (thisdist < shortest)
184                                 shortest = thisdist;
185                 }
186         return shortest;
187 }
188
189 float spawn_allbad;
190 float spawn_allgood;
191 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
192 {
193         local entity spot, spotlist, spotlistend;
194         spawn_allgood = TRUE;
195         spawn_allbad = TRUE;
196
197         spotlist = world;
198         spotlistend = world;
199
200         for(spot = firstspot; spot; spot = spot.chain)
201         {
202                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
203
204                 if(cvar("spawn_debugview"))
205                 {
206                         setmodel(spot, "models/runematch/rune.mdl");
207                         if(spot.SPAWNPOINT_SCORE < mindist)
208                         {
209                                 spot.colormod = '1 0 0';
210                                 spot.scale = 1;
211                         }
212                         else
213                         {
214                                 spot.colormod = '0 1 0';
215                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
216                         }
217                 }
218
219                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
220                 {
221                         if(spot.SPAWNPOINT_SCORE < mindist)
222                         {
223                                 // too short distance
224                                 spawn_allgood = FALSE;
225                         }
226                         else
227                         {
228                                 // perfect
229                                 spawn_allbad = FALSE;
230
231                                 if(spotlistend)
232                                         spotlistend.chain = spot;
233                                 spotlistend = spot;
234                                 if(!spotlist)
235                                         spotlist = spot;
236
237                                 /*
238                                 if(teamcheck)
239                                 if(spot.team != teamcheck)
240                                         error("invalid spawn added");
241
242                                 print("added ", etos(spot), "\n");
243                                 */
244                         }
245                 }
246         }
247         if(spotlistend)
248                 spotlistend.chain = world;
249
250         /*
251                 entity e;
252                 if(teamcheck)
253                         for(e = spotlist; e; e = e.chain)
254                         {
255                                 print("seen ", etos(e), "\n");
256                                 if(e.team != teamcheck)
257                                         error("invalid spawn found");
258                         }
259         */
260
261         return spotlist;
262 }
263
264 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
265 {
266         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
267         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
268         local entity spot;
269
270         RandomSelection_Init();
271         for(spot = firstspot; spot; spot = spot.chain)
272                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
273
274         return RandomSelection_chosen_ent;
275 }
276
277 /*
278 =============
279 SelectSpawnPoint
280
281 Finds a point to respawn
282 =============
283 */
284 entity SelectSpawnPoint (float anypoint)
285 {
286         local float teamcheck;
287         local entity firstspot_new;
288         local entity spot, firstspot, playerlist;
289
290         spot = find (world, classname, "testplayerstart");
291         if (spot)
292                 return spot;
293
294         teamcheck = 0;
295
296         if(!anypoint && have_team_spawns)
297                 teamcheck = self.team;
298
299         // get the list of players
300         playerlist = findchain(classname, "player");
301         // get the entire list of spots
302         firstspot = findchain(classname, "info_player_deathmatch");
303         // filter out the bad ones
304         // (note this returns the original list if none survived)
305         if(anypoint)
306         {
307                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
308         }
309         else
310         {
311                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
312                 if(!firstspot_new)
313                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
314                 firstspot = firstspot_new;
315
316                 // there is 50/50 chance of choosing a random spot or the furthest spot
317                 // (this means that roughly every other spawn will be furthest, so you
318                 // usually won't get fragged at spawn twice in a row)
319                 if (arena_roundbased)
320                 {
321                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
322                         if(firstspot_new)
323                                 firstspot = firstspot_new;
324                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
325                 }
326                 else if (random() > cvar("g_spawn_furthest"))
327                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
328                 else
329                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
330         }
331
332         if(cvar("spawn_debugview"))
333         {
334                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
335
336                 entity e;
337                 if(teamcheck)
338                         for(e = firstspot; e; e = e.chain)
339                                 if(e.team != teamcheck)
340                                         error("invalid spawn found");
341         }
342
343         if (!spot)
344         {
345                 if(cvar("spawn_debug"))
346                         GotoNextMap();
347                 else
348                 {
349                         if(some_spawn_has_been_used)
350                                 return world; // team can't spawn any more, because of actions of other team
351                         else
352                                 error("Cannot find a spawn point - please fix the map!");
353                 }
354         }
355
356         return spot;
357 }
358
359 /*
360 =============
361 CheckPlayerModel
362
363 Checks if the argument string can be a valid playermodel.
364 Returns a valid one in doubt.
365 =============
366 */
367 string FallbackPlayerModel = "models/player/marine.zym";
368 string CheckPlayerModel(string plyermodel) {
369         if(strlen(plyermodel) < 4)
370                 return FallbackPlayerModel;
371         if( substring(plyermodel,0,14) != "models/player/")
372                 return FallbackPlayerModel;
373         else if(cvar("sv_servermodelsonly"))
374         {
375                 if(substring(plyermodel,-4,4) != ".zym")
376                 if(substring(plyermodel,-4,4) != ".dpm")
377                 if(substring(plyermodel,-4,4) != ".md3")
378                 if(substring(plyermodel,-4,4) != ".psk")
379                         return FallbackPlayerModel;
380                 // forbid the LOD models
381                 if(substring(plyermodel, -9,5) == "_lod1")
382                         return FallbackPlayerModel;
383                 if(substring(plyermodel, -9,5) == "_lod2")
384                         return FallbackPlayerModel;
385                 if(plyermodel != strtolower(plyermodel))
386                         return FallbackPlayerModel;
387                 if(!fexists(plyermodel))
388                         return FallbackPlayerModel;
389         }
390         return plyermodel;
391 }
392
393 /*
394 =============
395 Client_customizeentityforclient
396
397 LOD reduction
398 =============
399 */
400 void Client_uncustomizeentityforclient()
401 {
402         if(self.modelindex == 0) // no need to uncustomize then
403                 return;
404         self.modelindex = self.modelindex_lod0;
405         self.skin = self.skinindex;
406 }
407
408 float Client_customizeentityforclient()
409 {
410         entity modelsource;
411
412         if(self.modelindex == 0)
413                 return TRUE;
414
415         // forcemodel stuff
416
417 #ifdef PROFILING
418         float t0;
419         t0 = gettime(GETTIME_HIRES); // reference
420 #endif
421
422         modelsource = self;
423
424 #ifdef ALLOW_FORCEMODELS
425         if(other.cvar_cl_forceplayermodelsfromnexuiz)
426                 if not(self.modelindex_lod0_from_nexuiz)
427                         modelsource = other;
428         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
429                 modelsource = other;
430 #endif
431
432         self.skin = modelsource.skinindex;
433
434 #if 0
435         if(modelsource == self)
436                 self.skin = modelsource.skinindex;
437         else
438                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
439 #endif
440
441         // self: me
442         // other: the player viewing me
443         float distance;
444         float f;
445
446         if(other.cvar_cl_playerdetailreduction <= 0)
447         {
448                 if(other.cvar_cl_playerdetailreduction <= -2)
449                         self.modelindex = modelsource.modelindex_lod2;
450                 else if(other.cvar_cl_playerdetailreduction <= -1)
451                         self.modelindex = modelsource.modelindex_lod1;
452                 else
453                         self.modelindex = modelsource.modelindex_lod0;
454         }
455         else
456         {
457                 distance = vlen(self.origin - other.origin);
458                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
459                 if(f > sv_loddistance2)
460                         self.modelindex = modelsource.modelindex_lod2;
461                 else if(f > sv_loddistance1)
462                         self.modelindex = modelsource.modelindex_lod1;
463                 else
464                         self.modelindex = modelsource.modelindex_lod0;
465         }
466
467 #ifdef PROFILING
468         float t1;
469         t1 = gettime(GETTIME_HIRES); // reference
470         client_cefc_accumulator += (t1 - t0);
471 #endif
472
473         return TRUE;
474 }
475
476 void UpdatePlayerSounds();
477 void setmodel_lod(entity e, string modelname)
478 {
479         string s;
480
481         if(sv_loddistance1)
482         {
483                 // FIXME: this only supports 3-letter extensions
484                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
485                 if(fexists(s))
486                 {
487                         setmodel(e, s); // players have high precision
488                         self.modelindex_lod1 = self.modelindex;
489                 }
490                 else
491                         self.modelindex_lod1 = -1;
492
493                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
494                 if(fexists(s))
495                 {
496                         setmodel(e, s); // players have high precision
497                         self.modelindex_lod2 = self.modelindex;
498                 }
499                 else
500                         self.modelindex_lod2 = -1;
501
502                 precache_model(modelname);
503                 setmodel(e, modelname); // players have high precision
504                 self.modelindex_lod0 = self.modelindex;
505
506                 if(self.modelindex_lod1 < 0)
507                         self.modelindex_lod1 = self.modelindex;
508
509                 if(self.modelindex_lod2 < 0)
510                         self.modelindex_lod2 = self.modelindex;
511         }
512         else
513         {
514                 precache_model(modelname);
515                 setmodel(e, modelname); // players have high precision
516                 self.modelindex_lod0 = self.modelindex;
517                         // save it for possible player model forcing
518         }
519
520         s = whichpack(self.model);
521         self.modelindex_lod0_from_nexuiz = ((s == "") || (substring(s, 0, 4) == "data"));
522
523         player_setupanimsformodel();
524         UpdatePlayerSounds();
525 }
526
527 /*
528 =============
529 PutObserverInServer
530
531 putting a client as observer in the server
532 =============
533 */
534 void FixPlayermodel();
535 void PutObserverInServer (void)
536 {
537         entity  spot;
538
539         race_PreSpawnObserver();
540
541         spot = SelectSpawnPoint (TRUE);
542         if(!spot)
543                 error("No spawnpoints for observers?!?\n");
544         RemoveGrapplingHook(self); // Wazat's Grappling Hook
545
546         if(clienttype(self) == CLIENTTYPE_REAL)
547         {
548                 msg_entity = self;
549                 WriteByte(MSG_ONE, SVC_SETVIEW);
550                 WriteEntity(MSG_ONE, self);
551         }
552
553         DropAllRunes(self);
554         kh_Key_DropAll(self, TRUE);
555
556         Portal_ClearAll(self);
557
558         if(self.flagcarried)
559                 DropFlag(self.flagcarried, world, world);
560         if(self.ballcarried)
561                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
562
563         WaypointSprite_PlayerDead();
564
565         if(self.killcount != -666)
566         {
567                 if(g_lms)
568                 {
569                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
570                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
571                         else
572                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
573                 }
574                 else
575                         bprint ("^4", self.netname, "^4 is spectating now\n");
576         }
577
578         PlayerScore_Clear(self); // clear scores when needed
579
580         self.spectatortime = time;
581
582         self.classname = "observer";
583         self.iscreature = FALSE;
584         self.health = -666;
585         self.takedamage = DAMAGE_NO;
586         self.solid = SOLID_NOT;
587         self.movetype = MOVETYPE_NOCLIP;
588         self.flags = FL_CLIENT | FL_NOTARGET;
589         self.armorvalue = 666;
590         self.effects = 0;
591         self.armorvalue = cvar("g_balance_armor_start");
592         self.pauserotarmor_finished = 0;
593         self.pauserothealth_finished = 0;
594         self.pauseregen_finished = 0;
595         self.damageforcescale = 0;
596         self.death_time = 0;
597         self.dead_frame = 0;
598         self.alpha = 0;
599         self.scale = 0;
600         self.fade_time = 0;
601         self.pain_frame = 0;
602         self.pain_finished = 0;
603         self.strength_finished = 0;
604         self.invincible_finished = 0;
605         self.pushltime = 0;
606         self.think = SUB_Null;
607         self.nextthink = 0;
608         self.hook_time = 0;
609         self.runes = 0;
610         self.deadflag = DEAD_NO;
611         self.angles = spot.angles;
612         self.angles_z = 0;
613         self.fixangle = TRUE;
614         self.crouch = FALSE;
615
616         self.view_ofs = PL_VIEW_OFS;
617         setorigin (self, spot.origin);
618         setsize (self, '0 0 0', '0 0 0');
619         self.prevorigin = self.origin;
620         self.items = 0;
621         self.weapons = 0;
622         self.model = "";
623         FixPlayermodel();
624         self.model = "";
625         self.modelindex = 0;
626         self.weapon = 0;
627         self.weaponmodel = "";
628         self.weaponentity = world;
629         self.exteriorweaponentity = world;
630         self.killcount = -666;
631         self.velocity = '0 0 0';
632         self.avelocity = '0 0 0';
633         self.punchangle = '0 0 0';
634         self.punchvector = '0 0 0';
635         self.oldvelocity = self.velocity;
636         self.fire_endtime = -1;
637
638         if(sv_loddistance1)
639                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
640
641         self.team = -1;
642
643         if(g_arena)
644         {
645                 if(self.version_mismatch)
646                 {
647                         Spawnqueue_Unmark(self);
648                         Spawnqueue_Remove(self);
649                 }
650                 else
651                 {
652                         Spawnqueue_Insert(self);
653                 }
654         }
655         else if(g_lms)
656         {
657                 // Only if the player cannot play at all
658                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
659                         self.frags = FRAGS_SPECTATOR;
660                 else
661                         self.frags = FRAGS_LMS_LOSER;
662         }
663         else
664                 self.frags = FRAGS_SPECTATOR;
665 }
666
667 float RestrictSkin(float s)
668 {
669         if(!teams_matter)
670                 return s;
671         if(s == 6)
672                 return 6;
673         return mod(s, 3);
674 }
675
676 void FixPlayermodel()
677 {
678         local string defaultmodel;
679         local float defaultskin, chmdl, oldskin;
680         local vector m1, m2;
681
682         defaultmodel = "";
683
684         if(cvar("sv_defaultcharacter") == 1) {
685                 defaultskin = 0;
686
687                 if(teams_matter)
688                 {
689                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
690                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
691                 }
692
693                 if(defaultmodel == "")
694                 {
695                         defaultmodel = cvar_string("sv_defaultplayermodel");
696                         defaultskin = cvar("sv_defaultplayerskin");
697                 }
698         }
699
700         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
701         {
702                 if(self.model != "")
703                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
704                 self.model = ""; // force the != checks to return true
705         }
706
707         if(defaultmodel != "")
708         {
709                 if (defaultmodel != self.model)
710                 {
711                         m1 = self.mins;
712                         m2 = self.maxs;
713                         setmodel_lod (self, defaultmodel);
714                         setsize (self, m1, m2);
715                         chmdl = TRUE;
716                 }
717
718                 oldskin = self.skinindex;
719                 self.skinindex = defaultskin;
720         } else {
721                 if (self.playermodel != self.model)
722                 {
723                         self.playermodel = CheckPlayerModel(self.playermodel);
724                         m1 = self.mins;
725                         m2 = self.maxs;
726                         setmodel_lod (self, self.playermodel);
727                         setsize (self, m1, m2);
728                         chmdl = TRUE;
729                 }
730
731                 oldskin = self.skinindex;
732                 self.skinindex = RestrictSkin(stof(self.playerskin));
733         }
734
735         if(chmdl || oldskin != self.skinindex)
736                 self.species = player_getspecies(); // model or skin has changed
737
738         if(!teams_matter)
739                 if(strlen(cvar_string("sv_defaultplayercolors")))
740                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
741                                 setcolor(self, cvar("sv_defaultplayercolors"));
742 }
743
744 void PlayerTouchExplode(entity p1, entity p2)
745 {
746         vector org;
747         org = (p1.origin + p2.origin) * 0.5;
748         org_z += (p1.mins_z + p2.mins_z) * 0.5;
749
750         te_explosion(org);
751
752         entity e;
753         e = spawn();
754         setorigin(e, org);
755         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
756         remove(e);
757 }
758
759 /*
760 =============
761 PutClientInServer
762
763 Called when a client spawns in the server
764 =============
765 */
766 //void() ctf_playerchanged;
767 void PutClientInServer (void)
768 {
769         if(clienttype(self) == CLIENTTYPE_BOT)
770         {
771                 self.classname = "player";
772         }
773         else if(clienttype(self) == CLIENTTYPE_REAL)
774         {
775                 msg_entity = self;
776                 WriteByte(MSG_ONE, SVC_SETVIEW);
777                 WriteEntity(MSG_ONE, self);
778         }
779
780         // player is dead and becomes observer
781         // FIXME fix LMS scoring for new system
782         if(g_lms)
783         {
784                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
785                         self.classname = "observer";
786         }
787
788         if(g_arena)
789         if(!self.spawned)
790                 self.classname = "observer";
791
792         if(gameover)
793                 self.classname = "observer";
794
795         if(self.classname == "player") {
796                 entity spot, oldself;
797                 float j;
798
799                 if(self.team < 0)
800                         JoinBestTeam(self, FALSE, TRUE);
801
802                 race_PreSpawn();
803
804                 spot = SelectSpawnPoint (FALSE);
805                 if(!spot)
806                 {
807                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
808                         return; // spawn failed
809                 }
810
811                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
812
813                 self.classname = "player";
814                 self.wasplayer = TRUE;
815                 self.iscreature = TRUE;
816                 self.movetype = MOVETYPE_WALK;
817                 self.solid = SOLID_SLIDEBOX;
818                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
819                 self.frags = FRAGS_PLAYER;
820                 if(independent_players)
821                         MAKE_INDEPENDENT_PLAYER(self);
822                 self.flags = FL_CLIENT;
823                 self.takedamage = DAMAGE_AIM;
824                 if(g_minstagib)
825                         self.effects = EF_FULLBRIGHT;
826                 else
827                         self.effects = 0;
828                 self.air_finished = time + 12;
829                 self.dmg = 2;
830
831                 if(inWarmupStage)
832                 {
833                         self.ammo_shells = warmup_start_ammo_shells;
834                         self.ammo_nails = warmup_start_ammo_nails;
835                         self.ammo_rockets = warmup_start_ammo_rockets;
836                         self.ammo_cells = warmup_start_ammo_cells;
837                         self.ammo_fuel = warmup_start_ammo_fuel;
838                         self.health = warmup_start_health;
839                         self.armorvalue = warmup_start_armorvalue;
840                         self.weapons = warmup_start_weapons;
841                 }
842                 else
843                 {
844                         self.ammo_shells = start_ammo_shells;
845                         self.ammo_nails = start_ammo_nails;
846                         self.ammo_rockets = start_ammo_rockets;
847                         self.ammo_cells = start_ammo_cells;
848                         self.ammo_fuel = start_ammo_fuel;
849                         self.health = start_health;
850                         self.armorvalue = start_armorvalue;
851                         self.weapons = start_weapons;
852                 }
853
854                 if(g_weaponarena_random)
855                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
856
857                 self.items = start_items;
858                 self.switchweapon = w_getbestweapon(self);
859                 self.cnt = self.switchweapon;
860                 self.weapon = 0;
861                 self.jump_interval = time;
862
863                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
864                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
865                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
866                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
867                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
868                 //extend the pause of rotting if client was reset at the beginning of the countdown
869                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
870                         self.spawnshieldtime += game_starttime - time;
871                         self.pauserotarmor_finished += game_starttime - time;
872                         self.pauserothealth_finished += game_starttime - time;
873                         self.pauseregen_finished += game_starttime - time;
874                 }
875                 self.damageforcescale = 2;
876                 self.death_time = 0;
877                 self.dead_frame = 0;
878                 self.alpha = 0;
879                 self.scale = 0;
880                 self.fade_time = 0;
881                 self.pain_frame = 0;
882                 self.pain_finished = 0;
883                 self.strength_finished = 0;
884                 self.invincible_finished = 0;
885                 self.pushltime = 0;
886                 //self.speed_finished = 0;
887                 //self.slowmo_finished = 0;
888                 // players have no think function
889                 self.think = SUB_Null;
890                 self.nextthink = 0;
891                 self.hook_time = 0;
892                 self.dmg_team = 0;
893
894                 self.metertime = 0;
895
896                 self.runes = 0;
897
898                 self.deadflag = DEAD_NO;
899
900                 self.angles = spot.angles;
901
902                 self.angles_z = 0; // never spawn tilted even if the spot says to
903                 self.fixangle = TRUE; // turn this way immediately
904                 self.velocity = '0 0 0';
905                 self.avelocity = '0 0 0';
906                 self.punchangle = '0 0 0';
907                 self.punchvector = '0 0 0';
908                 self.oldvelocity = self.velocity;
909                 self.fire_endtime = -1;
910
911                 msg_entity = self;
912                 WRITESPECTATABLE_MSG_ONE({
913                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
914                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
915                 });
916
917                 if(sv_loddistance1)
918                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
919
920                 self.model = "";
921                 FixPlayermodel();
922
923                 self.crouch = FALSE;
924                 self.view_ofs = PL_VIEW_OFS;
925                 setsize (self, PL_MIN, PL_MAX);
926                 self.spawnorigin = spot.origin;
927                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
928                 // don't reset back to last position, even if new position is stuck in solid
929                 self.oldorigin = self.origin;
930                 self.prevorigin = self.origin;
931                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
932
933                 if(g_arena)
934                 {
935                         Spawnqueue_Remove(self);
936                         Spawnqueue_Mark(self);
937                 }
938
939                 self.event_damage = PlayerDamage;
940
941                 self.bot_attack = TRUE;
942
943                 self.statdraintime = time + 5;
944                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
945
946                 if(self.killcount == -666) {
947                         PlayerScore_Clear(self);
948                         self.killcount = 0;
949                 }
950
951                 self.cnt = WEP_LASER;
952                 self.nixnex_lastchange_id = -1;
953
954                 CL_SpawnWeaponentity();
955                 self.alpha = default_player_alpha;
956                 self.colormod = '1 1 1' * cvar("g_player_brightness");
957                 self.exteriorweaponentity.alpha = default_weapon_alpha;
958
959                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
960                 self.lms_traveled_distance = 0;
961                 self.speedrunning = FALSE;
962
963                 race_PostSpawn(spot);
964
965                 if(cvar("spawn_debug"))
966                 {
967                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
968                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
969                 }
970
971                 //stuffcmd(self, "chase_active 0");
972                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
973
974                 if (cvar("g_spawnsound"))
975                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
976
977                 if(g_assault) {
978                         if(self.team == assault_attacker_team)
979                                 centerprint(self, "You are attacking!");
980                         else
981                                 centerprint(self, "You are defending!");
982                 }
983
984                 target_voicescript_clear(self);
985
986                 // reset fields the weapons may use
987         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
988             weapon_action(j, WR_RESETPLAYER);
989
990                 oldself = self;
991                 self = spot;
992                         activator = oldself;
993                                 SUB_UseTargets();
994                         activator = world;
995                 self = oldself;
996         } else if(self.classname == "observer") {
997                 PutObserverInServer ();
998         }
999
1000         //if(g_ctf)
1001         //      ctf_playerchanged();
1002 }
1003
1004 float ClientInit_SendEntity(entity to, float sf)
1005 {
1006         float i;
1007         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1008         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1009         for(i = 1; i <= 24; ++i)
1010                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
1011         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
1012         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
1013         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
1014
1015         if(sv_foginterval && world.fog != "")
1016                 WriteString(MSG_ENTITY, world.fog);
1017         else
1018                 WriteString(MSG_ENTITY, "");
1019         WriteByte(MSG_ENTITY, cvar("g_balance_armor_blockpercent") * 255.0);
1020         WriteByte(MSG_ENTITY, cvar("g_balance_weaponswitchdelay") * 255.0);
1021         return TRUE;
1022 }
1023
1024 void ClientInit_Spawn()
1025 {
1026         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
1027 }
1028
1029 /*
1030 =============
1031 SetNewParms
1032 =============
1033 */
1034 void SetNewParms (void)
1035 {
1036         // initialize parms for a new player
1037         parm1 = -(86400 * 366);
1038 }
1039
1040 /*
1041 =============
1042 SetChangeParms
1043 =============
1044 */
1045 void SetChangeParms (void)
1046 {
1047         // save parms for level change
1048         parm1 = self.parm_idlesince - time;
1049 }
1050
1051 /*
1052 =============
1053 DecodeLevelParms
1054 =============
1055 */
1056 void DecodeLevelParms (void)
1057 {
1058         // load parms
1059         self.parm_idlesince = parm1;
1060         if(self.parm_idlesince == -(86400 * 366))
1061                 self.parm_idlesince = time;
1062
1063         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1064         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1065 }
1066
1067 /*
1068 =============
1069 ClientKill
1070
1071 Called when a client types 'kill' in the console
1072 =============
1073 */
1074
1075 void ClientKill_Now_TeamChange()
1076 {
1077         if(self.killindicator_teamchange == -1)
1078         {
1079                 self.team = -1;
1080                 JoinBestTeam( self, FALSE, FALSE );
1081         }
1082         else
1083                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1084 }
1085
1086 void ClientKill_Now()
1087 {
1088         if(self.killindicator_teamchange)
1089                 ClientKill_Now_TeamChange();
1090
1091         // in any case:
1092         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1093
1094         if(self.killindicator)
1095         {
1096                 dprint("Cleaned up after a leaked kill indicator.\n");
1097                 remove(self.killindicator);
1098                 self.killindicator = world;
1099         }
1100 }
1101 void KillIndicator_Think()
1102 {
1103         if (!self.owner.modelindex)
1104         {
1105                 self.owner.killindicator = world;
1106                 remove(self);
1107                 return;
1108         }
1109
1110         if(self.cnt <= 0)
1111         {
1112                 self = self.owner;
1113                 ClientKill_Now(); // no oldself needed
1114                 return;
1115         }
1116         else
1117         {
1118                 if(self.cnt <= 10)
1119                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1120                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1121                 {
1122                         if(self.cnt <= 10)
1123                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1124                         if(self.owner.killindicator_teamchange)
1125                         {
1126                                 if(self.owner.killindicator_teamchange == -1)
1127                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1128                                 else
1129                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1130                         }
1131                         else
1132                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1133                 }
1134                 self.nextthink = time + 1;
1135                 self.cnt -= 1;
1136         }
1137 }
1138
1139 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1140 {
1141         float killtime;
1142         entity e;
1143         killtime = cvar("g_balance_kill_delay");
1144
1145         if(g_race_qualifying)
1146                 killtime = 0;
1147
1148         self.killindicator_teamchange = targetteam;
1149
1150         if(!self.killindicator)
1151         {
1152                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1153                 {
1154                         ClientKill_Now();
1155                 }
1156                 else
1157                 {
1158                         self.killindicator = spawn();
1159                         self.killindicator.owner = self;
1160                         self.killindicator.scale = 0.5;
1161                         setattachment(self.killindicator, self, "");
1162                         setorigin(self.killindicator, '0 0 52');
1163                         self.killindicator.think = KillIndicator_Think;
1164                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1165                         self.killindicator.cnt = ceil(killtime);
1166                         self.killindicator.count = bound(0, ceil(killtime), 10);
1167                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1168
1169                         for(e = world; (e = find(e, classname, "body")) != world; )
1170                         {
1171                                 if(e.enemy != self)
1172                                         continue;
1173                                 e.killindicator = spawn();
1174                                 e.killindicator.owner = e;
1175                                 e.killindicator.scale = 0.5;
1176                                 setattachment(e.killindicator, e, "");
1177                                 setorigin(e.killindicator, '0 0 52');
1178                                 e.killindicator.think = KillIndicator_Think;
1179                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1180                                 e.killindicator.cnt = ceil(killtime);
1181                         }
1182                         self.lip = 0;
1183                 }
1184         }
1185         if(self.killindicator)
1186         {
1187                 if(targetteam)
1188                         self.killindicator.colormod = TeamColor(targetteam);
1189                 else
1190                         self.killindicator.colormod = '0 0 0';
1191         }
1192 }
1193
1194 void ClientKill (void)
1195 {
1196         ClientKill_TeamChange(0);
1197 }
1198
1199 void DoTeamChange(float destteam)
1200 {
1201         float t, c0;
1202         if(!teams_matter)
1203         {
1204                 if(destteam >= 0)
1205                         SetPlayerColors(self, destteam);
1206                 return;
1207         }
1208         if(self.classname == "player")
1209         if(destteam == -1)
1210         {
1211                 CheckAllowedTeams(self);
1212                 t = FindSmallestTeam(self, TRUE);
1213                 switch(self.team)
1214                 {
1215                         case COLOR_TEAM1: c0 = c1; break;
1216                         case COLOR_TEAM2: c0 = c2; break;
1217                         case COLOR_TEAM3: c0 = c3; break;
1218                         case COLOR_TEAM4: c0 = c4; break;
1219                         default:          c0 = 999;
1220                 }
1221                 switch(t)
1222                 {
1223                         case 1:
1224                                 if(c0 > c1)
1225                                         destteam = COLOR_TEAM1;
1226                                 break;
1227                         case 2:
1228                                 if(c0 > c2)
1229                                         destteam = COLOR_TEAM2;
1230                                 break;
1231                         case 3:
1232                                 if(c0 > c3)
1233                                         destteam = COLOR_TEAM3;
1234                                 break;
1235                         case 4:
1236                                 if(c0 > c4)
1237                                         destteam = COLOR_TEAM4;
1238                                 break;
1239                 }
1240                 if(destteam == -1)
1241                         return;
1242         }
1243         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1244                 return;
1245         ClientKill_TeamChange(destteam);
1246 }
1247
1248 void FixClientCvars(entity e)
1249 {
1250         // send prediction settings to the client
1251         stuffcmd(e, "\nin_bindmap 0 0\n");
1252         if(g_race || g_cts)
1253                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1254         /*
1255          * we no longer need to stuff this. Remove this comment block if you feel
1256          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1257         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1258         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1259         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1260         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1261         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1262         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1263         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1264         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1265         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1266         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1267         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1268         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1269         stuffcmd(e, "cl_movement_edgefriction 1\n");
1270          */
1271 }
1272
1273 /*
1274 =============
1275 ClientConnect
1276
1277 Called when a client connects to the server
1278 =============
1279 */
1280 //void ctf_clientconnect();
1281 string ColoredTeamName(float t);
1282 void DecodeLevelParms (void);
1283 //void dom_player_join_team(entity pl);
1284 void ClientConnect (void)
1285 {
1286         local string s;
1287         float t;
1288
1289         if(self.flags & FL_CLIENT)
1290         {
1291                 print("Warning: ClientConnect, but already connected!\n");
1292                 return;
1293         }
1294
1295         if(Ban_MaybeEnforceBan(self))
1296                 return;
1297
1298         DecodeLevelParms();
1299
1300         self.classname = "player_joining";
1301
1302         self.flags = FL_CLIENT;
1303         self.version_nagtime = time + 10 + random() * 10;
1304
1305         if(player_count<0)
1306         {
1307                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1308                 player_count = 0;
1309         }
1310
1311         PlayerScore_Attach(self);
1312         ClientData_Attach();
1313
1314         bot_clientconnect();
1315
1316         race_PreSpawnObserver();
1317
1318         //if(g_domination)
1319         //      dom_player_join_team(self);
1320
1321         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1322
1323         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1324                 self.classname = "observer";
1325         } else {
1326                 if(teams_matter)
1327                 {
1328                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1329                         {
1330                                 self.classname = "player";
1331                                 campaign_bots_may_start = 1;
1332                         }
1333                         else
1334                         {
1335                                 self.classname = "observer"; // do it anyway
1336                         }
1337                 }
1338                 else
1339                 {
1340                         self.classname = "player";
1341                         campaign_bots_may_start = 1;
1342                 }
1343         }
1344
1345         self.playerid = (playerid_last = playerid_last + 1);
1346         if(cvar("sv_eventlog"))
1347         {
1348                 if(clienttype(self) == CLIENTTYPE_REAL)
1349                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1350                 else
1351                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1352                 s = strcat(":team:", ftos(self.playerid), ":");
1353                 s = strcat(s, ftos(self.team));
1354                 GameLogEcho(s);
1355         }
1356         self.netname_previous = strzone(self.netname);
1357
1358         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1359
1360         bprint ("^4",self.netname);
1361         bprint ("^4 connected");
1362
1363         if(g_domination || g_ctf)
1364         {
1365                 bprint(" and joined the ");
1366                 bprint(ColoredTeamName(self.team));
1367         }
1368
1369         bprint("\n");
1370
1371         self.welcomemessage_time = 0;
1372
1373         stuffcmd(self, strcat(clientstuff, "\n"));
1374         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1375         stuffcmd(self, "cl_particles_reloadeffects\n");
1376
1377         FixClientCvars(self);
1378
1379         // spawnfunc_waypoint sprites
1380         WaypointSprite_InitClient(self);
1381
1382         // Wazat's grappling hook
1383         SetGrappleHookBindings();
1384
1385         // get autoswitch state from player when he toggles it
1386         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1387
1388         // get version info from player
1389         stuffcmd(self, "cmd clientversion $gameversion\n");
1390
1391         // get other cvars from player
1392         GetCvars(0);
1393
1394         // set cvar for team scoreboard
1395         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1396
1397         // notify about available teams
1398         if(teams_matter)
1399         {
1400                 CheckAllowedTeams(self);
1401                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1402                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1403         }
1404         else
1405                 stuffcmd(self, "set _teams_available 0\n");
1406
1407         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1408
1409         if(g_arena)
1410         {
1411                 self.classname = "observer";
1412                 Spawnqueue_Insert(self);
1413         }
1414         /*else if(g_ctf)
1415         {
1416                 ctf_clientconnect();
1417         }*/
1418
1419         if(teams_matter || sv_cheats)
1420                 attach_entcs();
1421
1422         bot_relinkplayerlist();
1423
1424         self.spectatortime = time;
1425         if(blockSpectators)
1426         {
1427                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1428         }
1429
1430         self.jointime = time;
1431         self.allowedTimeouts = cvar("sv_timeout_number");
1432
1433         if(clienttype(self) == CLIENTTYPE_REAL)
1434         {
1435                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1436                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1437         }
1438
1439         if(g_lms)
1440         {
1441                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1442                 {
1443                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1444                         self.frags = FRAGS_SPECTATOR;
1445                 }
1446         }
1447
1448         if(!sv_foginterval && world.fog != "")
1449                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1450
1451         SoundEntity_Attach(self);
1452
1453         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1454         {
1455                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1456                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1457         }
1458         else
1459                 self.hitplotfh = -1;
1460
1461         if(g_race || g_cts) {
1462                 string rr;
1463                 if(g_cts)
1464                         rr = CTS_RECORD;
1465                 else
1466                         rr = RACE_RECORD;
1467                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1468
1469                 race_send_recordtime(t, MSG_ONE);
1470                 race_send_speedaward(MSG_ONE);
1471
1472                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1473                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1474                 race_send_speedaward_alltimebest(MSG_ONE);
1475         }
1476 }
1477
1478 /*
1479 =============
1480 ClientDisconnect
1481
1482 Called when a client disconnects from the server
1483 =============
1484 */
1485 .entity chatbubbleentity;
1486 .entity teambubbleentity;
1487 void ReadyCount();
1488 void ClientDisconnect (void)
1489 {
1490         if not(self.flags & FL_CLIENT)
1491         {
1492                 print("Warning: ClientDisconnect without ClientConnect\n");
1493                 return;
1494         }
1495
1496         if(self.hitplotfh >= 0)
1497         {
1498                 fclose(self.hitplotfh);
1499                 self.hitplotfh = -1;
1500         }
1501
1502         bot_clientdisconnect();
1503
1504         if(self.entcs)
1505                 detach_entcs();
1506
1507         if(cvar("sv_eventlog"))
1508                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1509         bprint ("^4",self.netname);
1510         bprint ("^4 disconnected\n");
1511
1512         SoundEntity_Detach(self);
1513
1514         DropAllRunes(self);
1515         kh_Key_DropAll(self, TRUE);
1516
1517         Portal_ClearAll(self);
1518
1519         if(self.flagcarried)
1520                 DropFlag(self.flagcarried, world, world);
1521         if(self.ballcarried)
1522                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1523
1524         // Here, everything has been done that requires this player to be a client.
1525
1526         self.flags &~= FL_CLIENT;
1527
1528         if (self.chatbubbleentity)
1529                 remove (self.chatbubbleentity);
1530
1531         if (self.teambubbleentity)
1532                 remove (self.teambubbleentity);
1533
1534         if (self.killindicator)
1535                 remove (self.killindicator);
1536
1537         WaypointSprite_PlayerGone();
1538
1539         bot_relinkplayerlist();
1540
1541         // remove laserdot
1542         if(self.weaponentity)
1543                 if(self.weaponentity.lasertarget)
1544                         remove(self.weaponentity.lasertarget);
1545
1546         if(g_arena)
1547         {
1548                 Spawnqueue_Unmark(self);
1549                 Spawnqueue_Remove(self);
1550         }
1551
1552         ClientData_Detach();
1553         PlayerScore_Detach(self);
1554
1555         if(self.netname_previous)
1556                 strunzone(self.netname_previous);
1557         if(self.clientstatus)
1558                 strunzone(self.clientstatus);
1559
1560         ClearPlayerSounds();
1561
1562         if(self.personal)
1563                 remove(self.personal);
1564
1565         self.playerid = 0;
1566         ReadyCount();
1567
1568         // free cvars
1569         GetCvars(-1);
1570 }
1571
1572 .float BUTTON_CHAT;
1573 void ChatBubbleThink()
1574 {
1575         self.nextthink = time;
1576         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1577         {
1578                 if(self.owner) // but why can that ever be world?
1579                         self.owner.chatbubbleentity = world;
1580                 remove(self);
1581                 return;
1582         }
1583         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1584 #ifdef TETRIS
1585                 || self.owner.tetris_on
1586 #endif
1587         )
1588                 self.model = self.mdl;
1589         else
1590                 self.model = "";
1591 };
1592
1593 void UpdateChatBubble()
1594 {
1595         if (!self.modelindex)
1596                 return;
1597         // spawn a chatbubble entity if needed
1598         if (!self.chatbubbleentity)
1599         {
1600                 self.chatbubbleentity = spawn();
1601                 self.chatbubbleentity.owner = self;
1602                 self.chatbubbleentity.exteriormodeltoclient = self;
1603                 self.chatbubbleentity.think = ChatBubbleThink;
1604                 self.chatbubbleentity.nextthink = time;
1605                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1606                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1607                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1608                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1609                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1610                 self.chatbubbleentity.model = "";
1611                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1612         }
1613 }
1614
1615
1616 void TeamBubbleThink()
1617 {
1618         self.nextthink = time;
1619         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1620         {
1621                 if(self.owner) // but why can that ever be world?
1622                         self.owner.teambubbleentity = world;
1623                 remove(self);
1624                 return;
1625         }
1626 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1627         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1628                 self.model = "";
1629         else
1630                 self.model = self.mdl;
1631
1632 };
1633
1634 float TeamBubble_customizeentityforclient()
1635 {
1636         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1637 }
1638
1639 void UpdateTeamBubble()
1640 {
1641         if (!self.modelindex || !teams_matter)
1642                 return;
1643         // spawn a teambubble entity if needed
1644         if (!self.teambubbleentity && teams_matter)
1645         {
1646                 self.teambubbleentity = spawn();
1647                 self.teambubbleentity.owner = self;
1648                 self.teambubbleentity.exteriormodeltoclient = self;
1649                 self.teambubbleentity.think = TeamBubbleThink;
1650                 self.teambubbleentity.nextthink = time;
1651                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1652 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1653                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1654                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1655                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1656                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1657                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1658                 self.teambubbleentity.effects = EF_LOWPRECISION;
1659         }
1660 }
1661
1662 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1663 // added to the model skins
1664 /*void UpdateColorModHack()
1665 {
1666         local float c;
1667         c = self.clientcolors & 15;
1668         // LordHavoc: only bothering to support white, green, red, yellow, blue
1669              if (!teams_matter) self.colormod = '0 0 0';
1670         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1671         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1672         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1673         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1674         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1675         else self.colormod = '1 1 1';
1676 };*/
1677
1678 void respawn(void)
1679 {
1680         CopyBody(1);
1681         self.effects |= EF_NODRAW; // prevent another CopyBody
1682         PutClientInServer();
1683 }
1684
1685 void play_countdown(float finished, string samp)
1686 {
1687         if(clienttype(self) == CLIENTTYPE_REAL)
1688                 if(floor(finished - time - frametime) != floor(finished - time))
1689                         if(finished - time < 6)
1690                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1691 }
1692
1693 /**
1694  * When sv_timeout is used this function returs strings like
1695  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1696  * Called by centerprint functions
1697  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1698  */
1699 string getTimeoutText(float addOneSecond) {
1700         if (!cvar("sv_timeout") || !timeoutStatus)
1701                 return "";
1702
1703         local string retStr;
1704         if (timeoutStatus == 1) {
1705                 if (addOneSecond == 1) {
1706                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1707                 }
1708                 else {
1709                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1710                 }
1711                 return retStr;
1712         }
1713         else if (timeoutStatus == 2) {
1714                 if (addOneSecond) {
1715                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1716                         //don't show messages like "Timeout ends in 0 seconds"...
1717                         if ((remainingTimeoutTime + 1) > 0)
1718                                 return retStr;
1719                         else
1720                                 return "";
1721                 }
1722                 else {
1723                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1724                         //don't show messages like "Timeout ends in 0 seconds"...
1725                         if (remainingTimeoutTime > 0)
1726                                 return retStr;
1727                         else
1728                                 return "";
1729                 }
1730         }
1731         else return "";
1732 }
1733
1734 void player_powerups (void)
1735 {
1736         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1737         {
1738                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1739                 self.modelflags |= MF_ROCKET;
1740         }
1741         else
1742         {
1743                 SoundEntity_StopSound(self, CHAN_PLAYER);
1744                 self.modelflags &~= MF_ROCKET;
1745         }
1746
1747         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME);
1748
1749         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1750                 return;
1751         
1752         Fire_ApplyDamage(self);
1753         Fire_ApplyEffect(self);
1754
1755         if (g_minstagib)
1756         {
1757                 self.effects |= EF_FULLBRIGHT;
1758
1759                 if (self.items & IT_STRENGTH)
1760                 {
1761                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1762                         if (time > self.strength_finished)
1763                         {
1764                                 self.alpha = default_player_alpha;
1765                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1766                                 self.items &~= IT_STRENGTH;
1767                                 sprint(self, "^3Invisibility has worn off\n");
1768                         }
1769                 }
1770                 else
1771                 {
1772                         if (time < self.strength_finished)
1773                         {
1774                                 self.alpha = g_minstagib_invis_alpha;
1775                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1776                                 self.items |= IT_STRENGTH;
1777                                 sprint(self, "^3You are invisible\n");
1778                         }
1779                 }
1780
1781                 if (self.items & IT_INVINCIBLE)
1782                 {
1783                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1784                         if (time > self.invincible_finished)
1785                         {
1786                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1787                                 sprint(self, "^3Speed has worn off\n");
1788                         }
1789                 }
1790                 else
1791                 {
1792                         if (time < self.invincible_finished)
1793                         {
1794                                 self.items = self.items | IT_INVINCIBLE;
1795                                 sprint(self, "^3You are on speed\n");
1796                         }
1797                 }
1798                 return;
1799         }
1800
1801         if (self.items & IT_STRENGTH)
1802         {
1803                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1804                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1805                 if (time > self.strength_finished)
1806                 {
1807                         self.items = self.items - (self.items & IT_STRENGTH);
1808                         sprint(self, "^3Strength has worn off\n");
1809                 }
1810         }
1811         else
1812         {
1813                 if (time < self.strength_finished)
1814                 {
1815                         self.items = self.items | IT_STRENGTH;
1816                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1817                 }
1818         }
1819         if (self.items & IT_INVINCIBLE)
1820         {
1821                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1822                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1823                 if (time > self.invincible_finished)
1824                 {
1825                         self.items = self.items - (self.items & IT_INVINCIBLE);
1826                         sprint(self, "^3Shield has worn off\n");
1827                 }
1828         }
1829         else
1830         {
1831                 if (time < self.invincible_finished)
1832                 {
1833                         self.items = self.items | IT_INVINCIBLE;
1834                         sprint(self, "^3Shield surrounds you\n");
1835                 }
1836         }
1837
1838         if (cvar("g_fullbrightplayers"))
1839                 self.effects = self.effects | EF_FULLBRIGHT;
1840
1841         // midair gamemode: damage only while in the air
1842         // if in midair mode, being on ground grants temporary invulnerability
1843         // (this is so that multishot weapon don't clear the ground flag on the
1844         // first damage in the frame, leaving the player vulnerable to the
1845         // remaining hits in the same frame)
1846         if (self.flags & FL_ONGROUND)
1847         if (g_midair)
1848                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1849
1850         if (time >= game_starttime)
1851         if (time < self.spawnshieldtime)
1852                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1853 }
1854
1855 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1856 {
1857         if(current > stable)
1858                 return current;
1859         else if(current > stable - 0.25) // when close enough, "snap"
1860                 return stable;
1861         else
1862                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1863 }
1864
1865 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1866 {
1867         if(current < stable)
1868                 return current;
1869         else if(current < stable + 0.25) // when close enough, "snap"
1870                 return stable;
1871         else
1872                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1873 }
1874
1875 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1876 {
1877         if(current > rotstable)
1878         {
1879                 if(rotframetime > 0)
1880                 {
1881                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1882                         current = max(rotstable, current - rotlinear * rotframetime);
1883                 }
1884         }
1885         else if(current < regenstable)
1886         {
1887                 if(regenframetime > 0)
1888                 {
1889                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1890                         current = min(regenstable, current + regenlinear * regenframetime);
1891                 }
1892         }
1893
1894         if(current > limit)
1895                 current = limit;
1896
1897         return current;
1898 }
1899
1900 void player_regen (void)
1901 {
1902         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1903         maxh = cvar("g_balance_health_rotstable");
1904         maxa = cvar("g_balance_armor_rotstable");
1905         maxf = cvar("g_balance_fuel_rotstable");
1906         minh = cvar("g_balance_health_regenstable");
1907         mina = cvar("g_balance_armor_regenstable");
1908         minf = cvar("g_balance_fuel_regenstable");
1909         limith = cvar("g_balance_health_limit");
1910         limita = cvar("g_balance_armor_limit");
1911         limitf = cvar("g_balance_fuel_limit");
1912
1913         max_mod = regen_mod = rot_mod = limit_mod = 1;
1914
1915         if (self.runes & RUNE_REGEN)
1916         {
1917                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1918                 {
1919                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1920                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1921                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1922                 }
1923                 else
1924                 {
1925                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1926                         max_mod = cvar("g_balance_rune_regen_hpmod");
1927                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1928                 }
1929         }
1930         else if (self.runes & CURSE_VENOM)
1931         {
1932                 max_mod = cvar("g_balance_curse_venom_hpmod");
1933                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1934                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1935                 else
1936                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1937                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1938                 //if (!self.runes & RUNE_REGEN)
1939                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1940         }
1941         maxh = maxh * max_mod;
1942         //maxa = maxa * max_mod;
1943         //maxf = maxf * max_mod;
1944         minh = minh * max_mod;
1945         //mina = mina * max_mod;
1946         //minf = minf * max_mod;
1947         limith = limith * limit_mod;
1948         limita = limita * limit_mod;
1949         //limitf = limitf * limit_mod;
1950
1951         if(g_lms)
1952                 rot_mod = 0;
1953
1954         if (!g_minstagib && (!g_lms || cvar("g_lms_regenerate")))
1955         {
1956                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1957                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1958
1959                 // if player rotted to death...  die!
1960                 if(self.health < 1)
1961                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1962         }
1963
1964         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1965                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1966 }
1967
1968 float zoomstate_set;
1969 void SetZoomState(float z)
1970 {
1971         if(z != self.zoomstate)
1972         {
1973                 self.zoomstate = z;
1974                 ClientData_Touch(self);
1975         }
1976         zoomstate_set = 1;
1977 }
1978
1979 void GetPressedKeys(void) {
1980         if (self.movement_x > 0) // get if movement keys are pressed
1981         {       // forward key pressed
1982                 self.pressedkeys |= KEY_FORWARD;
1983                 self.pressedkeys &~= KEY_BACKWARD;
1984         }
1985         else if (self.movement_x < 0)
1986         {       // backward key pressed
1987                 self.pressedkeys |= KEY_BACKWARD;
1988                 self.pressedkeys &~= KEY_FORWARD;
1989         }
1990         else
1991         {       // no x input
1992                 self.pressedkeys &~= KEY_FORWARD;
1993                 self.pressedkeys &~= KEY_BACKWARD;
1994         }
1995
1996         if (self.movement_y > 0)
1997         {       // right key pressed
1998                 self.pressedkeys |= KEY_RIGHT;
1999                 self.pressedkeys &~= KEY_LEFT;
2000         }
2001         else if (self.movement_y < 0)
2002         {       // left key pressed
2003                 self.pressedkeys |= KEY_LEFT;
2004                 self.pressedkeys &~= KEY_RIGHT;
2005         }
2006         else
2007         {       // no y input
2008                 self.pressedkeys &~= KEY_RIGHT;
2009                 self.pressedkeys &~= KEY_LEFT;
2010         }
2011
2012         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2013                 self.pressedkeys |= KEY_JUMP;
2014         else
2015                 self.pressedkeys &~= KEY_JUMP;
2016         if (self.BUTTON_CROUCH)
2017                 self.pressedkeys |= KEY_CROUCH;
2018         else
2019                 self.pressedkeys &~= KEY_CROUCH;
2020 }
2021
2022 /*
2023 ======================
2024 spectate mode routines
2025 ======================
2026 */
2027 void SpectateCopy(entity spectatee) {
2028         self.kh_state = spectatee.kh_state;
2029         self.armortype = spectatee.armortype;
2030         self.armorvalue = spectatee.armorvalue;
2031         self.ammo_cells = spectatee.ammo_cells;
2032         self.ammo_shells = spectatee.ammo_shells;
2033         self.ammo_nails = spectatee.ammo_nails;
2034         self.ammo_rockets = spectatee.ammo_rockets;
2035         self.ammo_fuel = spectatee.ammo_fuel;
2036         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2037         self.health = spectatee.health;
2038         self.impulse = 0;
2039         self.items = spectatee.items;
2040         self.metertime = spectatee.metertime;
2041         self.strength_finished = spectatee.strength_finished;
2042         self.invincible_finished = spectatee.invincible_finished;
2043         self.pressedkeys = spectatee.pressedkeys;
2044         self.weapons = spectatee.weapons;
2045         self.switchweapon = spectatee.switchweapon;
2046         self.weapon = spectatee.weapon;
2047         self.punchangle = spectatee.punchangle;
2048         self.view_ofs = spectatee.view_ofs;
2049         self.v_angle = spectatee.v_angle;
2050         self.velocity = spectatee.velocity;
2051         self.dmg_take = spectatee.dmg_take;
2052         self.dmg_save = spectatee.dmg_save;
2053         self.dmg_inflictor = spectatee.dmg_inflictor;
2054         self.angles = spectatee.v_angle;
2055         self.fixangle = TRUE;
2056         setorigin(self, spectatee.origin);
2057         setsize(self, spectatee.mins, spectatee.maxs);
2058         SetZoomState(spectatee.zoomstate);
2059 }
2060
2061 float SpectateUpdate() {
2062         if(!self.enemy)
2063                 return 0;
2064
2065         if (self == self.enemy)
2066                 return 0;
2067
2068         if(self.enemy.classname != "player")
2069                 return 0;
2070
2071         SpectateCopy(self.enemy);
2072
2073         return 1;
2074 }
2075
2076 float SpectateNext() {
2077         other = find(self.enemy, classname, "player");
2078         if (!other) {
2079                 other = find(other, classname, "player");
2080         }
2081         if (other) {
2082                 self.enemy = other;
2083         }
2084         if(self.enemy.classname == "player") {
2085                 msg_entity = self;
2086                 WriteByte(MSG_ONE, SVC_SETVIEW);
2087                 WriteEntity(MSG_ONE, self.enemy);
2088                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2089                 self.movetype = MOVETYPE_NONE;
2090                 if(!SpectateUpdate())
2091                         PutObserverInServer();
2092                 return 1;
2093         } else {
2094                 return 0;
2095         }
2096 }
2097
2098 /*
2099 =============
2100 ShowRespawnCountdown()
2101
2102 Update a respawn countdown display.
2103 =============
2104 */
2105 void ShowRespawnCountdown()
2106 {
2107         float number;
2108         if(self.deadflag == DEAD_NO) // just respawned?
2109                 return;
2110         else
2111         {
2112                 number = ceil(self.death_time - time);
2113                 if(number <= 0)
2114                         return;
2115                 if(number <= self.respawn_countdown)
2116                 {
2117                         self.respawn_countdown = number - 1;
2118                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2119                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
2120                 }
2121         }
2122 }
2123
2124 void LeaveSpectatorMode()
2125 {
2126         if(isJoinAllowed()) {
2127                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2128                         self.classname = "player";
2129                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2130                                 JoinBestTeam(self, FALSE, TRUE);
2131                         if(cvar("g_campaign"))
2132                                 campaign_bots_may_start = 1;
2133                         PutClientInServer();
2134                         if(self.classname == "player")
2135                                 bprint ("^4", self.netname, "^4 is playing now\n");
2136                         if(!cvar("g_campaign"))
2137                                 centerprint(self,""); // clear MOTD
2138                         return;
2139                 } else {
2140                         stuffcmd(self,"menu_showteamselect\n");
2141                         return;
2142                 }
2143         }
2144         else {
2145                 //player may not join because of g_maxplayers is set
2146                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2147         }
2148 }
2149
2150 /**
2151  * Determines whether the player is allowed to join. This depends on cvar
2152  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2153  * it checks whether the number of currently playing players exceeds g_maxplayers.
2154  * @return bool TRUE if the player is allowed to join, false otherwise
2155  */
2156 float isJoinAllowed() {
2157         if (!cvar("g_maxplayers"))
2158                 return TRUE;
2159
2160         local entity e;
2161         local float currentlyPlaying;
2162         FOR_EACH_REALPLAYER(e) {
2163                 if(e.classname == "player")
2164                         currentlyPlaying += 1;
2165         }
2166         if(currentlyPlaying < cvar("g_maxplayers"))
2167                 return TRUE;
2168
2169         return FALSE;
2170 }
2171
2172 /**
2173  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2174  * g_maxplayers_spectator_blocktime seconds
2175  */
2176 void checkSpectatorBlock() {
2177         if(self.classname == "spectator" || self.classname == "observer") {
2178                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2179                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2180                         dropclient(self);
2181                 }
2182         }
2183 }
2184
2185 float vercmp_recursive(string v1, string v2)
2186 {
2187         float dot1, dot2;
2188         string s1, s2;
2189         float r;
2190
2191         dot1 = strstrofs(v1, ".", 0);
2192         dot2 = strstrofs(v2, ".", 0);
2193         if(dot1 == -1)
2194                 s1 = v1;
2195         else
2196                 s1 = substring(v1, 0, dot1);
2197         if(dot2 == -1)
2198                 s2 = v2;
2199         else
2200                 s2 = substring(v2, 0, dot2);
2201
2202         r = stof(s1) - stof(s2);
2203         if(r != 0)
2204                 return r;
2205
2206         r = strcasecmp(s1, s2);
2207         if(r != 0)
2208                 return r;
2209
2210         if(dot1 == -1)
2211                 if(dot2 == -1)
2212                         return 0;
2213                 else
2214                         return -1;
2215         else
2216                 if(dot2 == -1)
2217                         return 1;
2218                 else
2219                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2220 }
2221
2222 float vercmp(string v1, string v2)
2223 {
2224         if(strcasecmp(v1, v2) == 0) // early out check
2225                 return 0;
2226         return vercmp_recursive(v1, v2);
2227 }
2228
2229 void ObserverThink()
2230 {
2231         if (self.flags & FL_JUMPRELEASED) {
2232                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2233                         self.welcomemessage_time = 0;
2234                         self.flags &~= FL_JUMPRELEASED;
2235                         self.flags |= FL_SPAWNING;
2236                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2237                         self.welcomemessage_time = 0;
2238                         self.flags &~= FL_JUMPRELEASED;
2239                         if(SpectateNext() == 1) {
2240                                 self.classname = "spectator";
2241                         }
2242                 }
2243         } else {
2244                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2245                         self.flags |= FL_JUMPRELEASED;
2246                         if(self.flags & FL_SPAWNING)
2247                         {
2248                                 self.flags &~= FL_SPAWNING;
2249                                 LeaveSpectatorMode();
2250                                 return;
2251                         }
2252                 }
2253         }
2254         PrintWelcomeMessage(self);
2255 }
2256
2257 void SpectatorThink()
2258 {
2259         if (self.flags & FL_JUMPRELEASED) {
2260                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2261                         self.welcomemessage_time = 0;
2262                         self.flags &~= FL_JUMPRELEASED;
2263                         self.flags |= FL_SPAWNING;
2264                 } else if(self.BUTTON_ATCK) {
2265                         self.welcomemessage_time = 0;
2266                         self.flags &~= FL_JUMPRELEASED;
2267                         if(SpectateNext() == 1) {
2268                                 self.classname = "spectator";
2269                         } else {
2270                                 self.classname = "observer";
2271                                 PutClientInServer();
2272                         }
2273                 } else if (self.BUTTON_ATCK2) {
2274                         self.welcomemessage_time = 0;
2275                         self.flags &~= FL_JUMPRELEASED;
2276                         self.classname = "observer";
2277                         PutClientInServer();
2278                 } else {
2279                         if(!SpectateUpdate())
2280                                 PutObserverInServer();
2281                 }
2282         } else {
2283                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2284                         self.flags |= FL_JUMPRELEASED;
2285                         if(self.flags & FL_SPAWNING)
2286                         {
2287                                 self.flags &~= FL_SPAWNING;
2288                                 LeaveSpectatorMode();
2289                                 return;
2290                         }
2291                 }
2292         }
2293         PrintWelcomeMessage(self);
2294         self.flags |= FL_CLIENT | FL_NOTARGET;
2295 }
2296
2297 .float touchexplode_time;
2298
2299 /*
2300 =============
2301 PlayerPreThink
2302
2303 Called every frame for each client before the physics are run
2304 =============
2305 */
2306 void() ctf_setstatus;
2307 void() nexball_setstatus;
2308 .float items_added;
2309 void PlayerPreThink (void)
2310 {
2311         self.stat_game_starttime = game_starttime;
2312         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2313         self.stat_leadlimit = cvar("leadlimit");
2314
2315         if(blockSpectators && frametime)
2316                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2317                 checkSpectatorBlock();
2318
2319         zoomstate_set = 0;
2320
2321         if(self.netname_previous != self.netname)
2322         {
2323                 if(cvar("sv_eventlog"))
2324                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2325                 if(self.netname_previous)
2326                         strunzone(self.netname_previous);
2327                 self.netname_previous = strzone(self.netname);
2328         }
2329
2330         // version nagging
2331         if(self.version_nagtime)
2332                 if(self.cvar_g_nexuizversion)
2333                         if(time > self.version_nagtime)
2334                         {
2335                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2336                                 {
2337                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2338                                         {
2339                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2340                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2341                                         }
2342                                         else
2343                                         {
2344                                                 float r;
2345                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2346                                                 if(r < 0)
2347                                                 {
2348                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2349                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2350                                                 }
2351                                                 else if(r > 0)
2352                                                 {
2353                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2354                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2355                                                 }
2356                                         }
2357                                 }
2358                                 self.version_nagtime = 0;
2359                         }
2360
2361         // GOD MODE info
2362         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2363         {
2364                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2365                 self.max_armorvalue = 0;
2366         }
2367
2368 #ifdef TETRIS
2369         if (TetrisPreFrame())
2370                 return;
2371 #endif
2372
2373         if(self.classname == "player") {
2374 //              if(self.netname == "Wazat")
2375 //                      bprint(self.classname, "\n");
2376
2377                 CheckRules_Player();
2378
2379                 PrintWelcomeMessage(self);
2380
2381                 if (intermission_running)
2382                 {
2383                         IntermissionThink ();   // otherwise a button could be missed between
2384                         return;                                 // the think tics
2385                 }
2386
2387                 if(self.teleport_time)
2388                 if(time > self.teleport_time)
2389                 {
2390                         self.teleport_time = 0;
2391                         self.effects = self.effects - (self.effects & EF_NODRAW);
2392                 }
2393
2394                 Nixnex_GiveCurrentWeapon();
2395
2396                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2397                         UpdateSelectedPlayer();
2398
2399                 //don't allow the player to turn around while game is paused!
2400                 if(timeoutStatus == 2) {
2401                         self.v_angle = self.lastV_angle;
2402                         self.angles = self.lastV_angle;
2403                         self.fixangle = TRUE;
2404                 }
2405
2406                 if(frametime)
2407                         player_powerups();
2408
2409                 if (self.deadflag != DEAD_NO)
2410                 {
2411                         float button_pressed, force_respawn;
2412                         if(self.personal && g_race_qualifying)
2413                         {
2414                                 if(time > self.death_time)
2415                                 {
2416                                         self.death_time = time + 1; // only retry once a second
2417                                         respawn();
2418                                         self.impulse = 141;
2419                                 }
2420                         }
2421                         else
2422                         {
2423                                 if(frametime)
2424                                         player_anim();
2425                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2426                                 force_respawn = (g_lms || cvar("g_forced_respawn"));
2427                                 if (self.deadflag == DEAD_DYING)
2428                                 {
2429                                         if(force_respawn)
2430                                                 self.deadflag = DEAD_RESPAWNING;
2431                                         else if(!button_pressed)
2432                                                 self.deadflag = DEAD_DEAD;
2433                                 }
2434                                 else if (self.deadflag == DEAD_DEAD)
2435                                 {
2436                                         if(button_pressed)
2437                                                 self.deadflag = DEAD_RESPAWNABLE;
2438                                 }
2439                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2440                                 {
2441                                         if(!button_pressed)
2442                                                 self.deadflag = DEAD_RESPAWNING;
2443                                 }
2444                                 else if (self.deadflag == DEAD_RESPAWNING)
2445                                 {
2446                                         if(time > self.death_time)
2447                                         {
2448                                                 self.death_time = time + 1; // only retry once a second
2449                                                 respawn();
2450                                         }
2451                                 }
2452                                 ShowRespawnCountdown();
2453                         }
2454                         return;
2455                 }
2456
2457                 if(g_touchexplode)
2458                 if(time > self.touchexplode_time)
2459                 if(self.classname == "player")
2460                 if(self.deadflag == DEAD_NO)
2461                 if not(IS_INDEPENDENT_PLAYER(self))
2462                 FOR_EACH_PLAYER(other) if(self != other)
2463                 {
2464                         if(time > other.touchexplode_time)
2465                         if(other.classname == "player")
2466                         if(other.deadflag == DEAD_NO)
2467                         if not(IS_INDEPENDENT_PLAYER(other))
2468                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2469                         {
2470                                 PlayerTouchExplode(self, other);
2471                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2472                         }
2473                 }
2474
2475                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2476                 {
2477                         vector dist;
2478
2479                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2480                         dist = self.prevorigin - self.origin;
2481                         dist_z = 0;
2482                         self.lms_traveled_distance += fabs(vlen(dist));
2483
2484                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2485                         {
2486                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2487                                 self.lms_traveled_distance = 0;
2488                         }
2489
2490                         if(time > self.lms_nextcheck)
2491                         {
2492                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2493                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2494                                 {
2495                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2496                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2497                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2498                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2499                                 }
2500                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2501                                 self.lms_traveled_distance = 0;
2502                         }
2503                 }
2504
2505                 self.prevorigin = self.origin;
2506
2507                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2508                 {
2509                         if (!self.crouch)
2510                         {
2511                                 self.crouch = TRUE;
2512                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2513                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2514                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2515                         }
2516                 }
2517                 else
2518                 {
2519                         if (self.crouch)
2520                         {
2521                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2522                                 if (!trace_startsolid)
2523                                 {
2524                                         self.crouch = FALSE;
2525                                         self.view_ofs = PL_VIEW_OFS;
2526                                         setsize (self, PL_MIN, PL_MAX);
2527                                 }
2528                         }
2529                 }
2530
2531                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2532                 {
2533                         if(self.bloodloss_timer < time)
2534                         {
2535                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2536                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2537                         }
2538                 }
2539
2540                 FixPlayermodel();
2541
2542                 GrapplingHookFrame();
2543
2544                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2545                 //if(frametime)
2546                 {
2547                         self.items &~= self.items_added;
2548
2549                         W_WeaponFrame();
2550
2551                         self.items_added = 0;
2552                         if(self.items & IT_JETPACK)
2553                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2554                                         self.items_added |= IT_FUEL;
2555
2556                         self.items |= self.items_added;
2557                 }
2558
2559                 player_regen();
2560                 if(frametime)
2561                         player_anim();
2562
2563                 if (g_minstagib)
2564                         minstagib_ammocheck();
2565
2566                 ctf_setstatus();
2567                 nexball_setstatus();
2568
2569                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2570
2571                 //self.angles_y=self.v_angle_y + 90;   // temp
2572         } else if(gameover) {
2573                 if (intermission_running)
2574                         IntermissionThink ();   // otherwise a button could be missed between
2575                 return;
2576         } else if(self.classname == "observer") {
2577                 ObserverThink();
2578         } else if(self.classname == "spectator") {
2579                 SpectatorThink();
2580         }
2581
2582         if(!zoomstate_set)
2583                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2584
2585         float oldspectatee_status;
2586         oldspectatee_status = self.spectatee_status;
2587         if(self.classname == "spectator")
2588                 self.spectatee_status = num_for_edict(self.enemy);
2589         else if(self.classname == "observer")
2590                 self.spectatee_status = num_for_edict(self);
2591         else
2592                 self.spectatee_status = 0;
2593         if(self.spectatee_status != oldspectatee_status)
2594         {
2595                 ClientData_Touch(self);
2596                 if(g_race || g_cts)
2597                         race_InitSpectator();
2598         }
2599
2600         if(self.teamkill_soundtime)
2601         if(time > self.teamkill_soundtime)
2602         {
2603                 self.teamkill_soundtime = 0;
2604
2605                 entity oldpusher, oldself;
2606
2607                 oldself = self; self = self.teamkill_soundsource;
2608                 oldpusher = self.pusher; self.pusher = oldself;
2609
2610                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2611
2612                 self.pusher = oldpusher;
2613                 self = oldself;
2614         }
2615
2616         if(self.taunt_soundtime)
2617         if(time > self.taunt_soundtime)
2618         {
2619                 self.taunt_soundtime = 0;
2620                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2621         }
2622
2623         target_voicescript_next(self);
2624 }
2625
2626 // on dragger:
2627 .entity dragentity;
2628 .float draggravity;
2629 .float dragspeed; // speed of mouse wheel action
2630 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2631 .vector draglocalvector; // local attachment vector of the dragentity
2632 .float draglocalangle;
2633 // on draggee:
2634 .entity draggedby;
2635 .float dragmovetype;
2636 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2637 {
2638         float tagscale;
2639
2640         draggee.dragmovetype = draggee.movetype;
2641         draggee.draggravity = draggee.gravity;
2642         draggee.movetype = MOVETYPE_WALK;
2643         draggee.gravity = 0.00001;
2644         draggee.flags &~= FL_ONGROUND;
2645         draggee.draggedby = dragger;
2646
2647         dragger.dragentity = draggee;
2648
2649         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2650         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2651         touchpoint = touchpoint - gettaginfo(draggee, 0);
2652         tagscale = pow(vlen(v_forward), -2);
2653         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2654         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2655         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2656
2657         dragger.dragspeed = 64;
2658 }
2659
2660 void Drag_Finish(entity dragger)
2661 {
2662         entity draggee;
2663         draggee = dragger.dragentity;
2664         if(dragger)
2665                 dragger.dragentity = world;
2666         draggee.draggedby = world;
2667         draggee.movetype = draggee.dragmovetype;
2668         draggee.gravity = draggee.draggravity;
2669
2670         switch(draggee.movetype)
2671         {
2672                 case MOVETYPE_TOSS:
2673                 case MOVETYPE_WALK:
2674                 case MOVETYPE_STEP:
2675                 case MOVETYPE_FLYMISSILE:
2676                 case MOVETYPE_BOUNCE:
2677                 case MOVETYPE_BOUNCEMISSILE:
2678                         break;
2679                 default:
2680                         draggee.velocity = '0 0 0';
2681                         break;
2682         }
2683
2684         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2685         {
2686                 draggee.velocity = '0 0 0';
2687                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2688         }
2689 }
2690
2691 float Drag_IsDraggable(entity draggee)
2692 {
2693         // TODO add more checks for bad stuff here
2694         if(draggee.classname == "func_bobbing")
2695                 return FALSE;
2696         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2697                 return FALSE;
2698         if(draggee.classname == "plat")
2699                 return FALSE;
2700         if(draggee.classname == "func_button")
2701                 return FALSE;
2702         if(draggee.model == "")
2703                 return FALSE;
2704         if(draggee.classname == "spectator")
2705                 return FALSE;
2706         if(draggee.classname == "observer")
2707                 return FALSE;
2708         if(draggee.classname == "exteriorweaponentity")
2709                 return FALSE;
2710
2711         return TRUE;
2712 }
2713
2714 float Drag_MayChangeAngles(entity draggee)
2715 {
2716         // TODO add more checks for bad stuff here
2717         if(substring(draggee.model, 0, 1) == "*")
2718                 return FALSE;
2719         return TRUE;
2720 }
2721
2722 void Drag_MoveForward(entity dragger)
2723 {
2724         dragger.dragdistance += dragger.dragspeed;
2725 }
2726
2727 void Drag_SetSpeed(entity dragger, float s)
2728 {
2729         dragger.dragspeed = pow(2, s);
2730 }
2731
2732 void Drag_MoveBackward(entity dragger)
2733 {
2734         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2735 }
2736
2737 void Drag_Update(entity dragger)
2738 {
2739         vector curorigin, neworigin, goodvelocity;
2740         float f;
2741         entity draggee;
2742
2743         draggee = dragger.dragentity;
2744         draggee.flags &~= FL_ONGROUND;
2745
2746         curorigin = gettaginfo(draggee, 0);
2747         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2748         makevectors(dragger.v_angle);
2749         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2750         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2751
2752         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2753                 dragger.draglocalangle += 360;
2754         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2755                 dragger.draglocalangle -= 360;
2756
2757         f = min(frametime * 10, 1);
2758         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2759
2760         if(Drag_MayChangeAngles(draggee))
2761                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2762
2763         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2764
2765         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2766 }
2767
2768 float Drag_CanDrag(entity dragger)
2769 {
2770         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2771 }
2772
2773 float Drag_IsDragging(entity dragger)
2774 {
2775         if(!dragger.dragentity)
2776                 return FALSE;
2777         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2778         {
2779                 dragger.dragentity = world;
2780                 return FALSE;
2781         }
2782         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2783         {
2784                 Drag_Finish(dragger);
2785                 return FALSE;
2786         }
2787         return TRUE;
2788 }
2789
2790 void Drag_MoveDrag(entity from, entity to)
2791 {
2792         if(from.draggedby)
2793         {
2794                 to.draggedby = from.draggedby;
2795                 to.draggedby.dragentity = to;
2796                 from.draggedby = world;
2797         }
2798 }
2799
2800 /*
2801 =============
2802 PlayerPostThink
2803
2804 Called every frame for each client after the physics are run
2805 =============
2806 */
2807 .float idlekick_lasttimeleft;
2808 void PlayerPostThink (void)
2809 {
2810         // Savage: Check for nameless players
2811         if (strlen(self.netname) < 1) {
2812                 self.netname = "Player";
2813                 stuffcmd(self, "seta _cl_name Player\n");
2814         }
2815
2816         if(sv_maxidle && frametime)
2817         {
2818                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2819                 float timeleft;
2820                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2821                 if(timeleft <= 0)
2822                 {
2823                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2824                         announce(self, "announcer/robotic/terminated.wav");
2825                         dropclient(self);
2826                         return;
2827                 }
2828                 else if(timeleft <= 10)
2829                 {
2830                         if(timeleft != self.idlekick_lasttimeleft)
2831                         {
2832                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2833                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2834                         }
2835                 }
2836                 else
2837                 {
2838                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2839                 }
2840                 self.idlekick_lasttimeleft = timeleft;
2841         }
2842
2843 #ifdef TETRIS
2844         if(self.impulse == 100)
2845                 ImpulseCommands();
2846         if (TetrisPostFrame())
2847                 return;
2848 #endif
2849
2850         if(sv_cheats || self.maycheat)
2851                 if(Drag_CanDrag(self))
2852                         if(self.BUTTON_DRAG)
2853                                 if(!self.dragentity)
2854                                         if(self.cursor_trace_ent)
2855                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2856                                                 {
2857                                                         if(self.cursor_trace_ent.draggedby)
2858                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2859                                                         if(self.cursor_trace_ent.tag_entity)
2860                                                                 detach_sameorigin(self.cursor_trace_ent);
2861                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2862                                                 }
2863
2864         if(Drag_IsDragging(self))
2865         {
2866                 if(self.BUTTON_DRAG)
2867                 {
2868                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2869                         {
2870                                 Drag_MoveForward(self);
2871                                 self.impulse = 0;
2872                         }
2873                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2874                         {
2875                                 Drag_MoveBackward(self);
2876                                 self.impulse = 0;
2877                         }
2878                         else if(self.impulse >= 1 && self.impulse <= 9)
2879                         {
2880                                 Drag_SetSpeed(self, self.impulse - 1);
2881                         }
2882                         else if(self.impulse == 14)
2883                         {
2884                                 Drag_SetSpeed(self, 9);
2885                         }
2886
2887                         if(frametime)
2888                                 Drag_Update(self);
2889                 }
2890                 else
2891                 {
2892                         Drag_Finish(self);
2893                 }
2894         }
2895
2896         if(self.classname == "player") {
2897                 CheckRules_Player();
2898                 UpdateChatBubble();
2899                 UpdateTeamBubble();
2900                 if (self.impulse)
2901                         ImpulseCommands();
2902                 if (intermission_running)
2903                         return;         // intermission or finale
2904
2905                 GetPressedKeys();
2906         } else if (self.classname == "observer") {
2907                 //do nothing
2908         } else if (self.classname == "spectator") {
2909                 //do nothing
2910         }
2911
2912         /*
2913         float i;
2914         for(i = 0; i < 1000; ++i)
2915         {
2916                 vector end;
2917                 end = self.origin + '0 0 1024' + 512 * randomvec();
2918                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2919                 if(trace_fraction < 1)
2920                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2921                 {
2922                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2923                         break;
2924                 }
2925         }
2926         */
2927
2928         Arena_Warmup();
2929
2930         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2931
2932         if(self.waypointsprite_attachedforcarrier)
2933                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2934 }