Added the capture-counter and changed the CTF scoreboard to display the caps.
[divverent/nexuiz.git] / data / qcsrc / server / cl_client.qc
1 .float wantswelcomemessage;
2 .string netname_previous;
3
4 void spawnfunc_info_player_survivor (void)
5 {
6         spawnfunc_info_player_deathmatch();
7 }
8
9 void spawnfunc_info_player_start (void)
10 {
11         spawnfunc_info_player_deathmatch();
12 }
13
14 void spawnfunc_info_player_deathmatch (void)
15 {
16         self.classname = "info_player_deathmatch";
17         relocate_spawnpoint();
18 }
19
20 void spawnpoint_use()
21 {
22         if(teams_matter)
23         if(have_team_spawns)
24         {
25                 self.team = activator.team;
26                 some_spawn_has_been_used = 1;
27         }
28 };
29
30 // Returns:
31 //   -1 if a spawn can't be used
32 //   otherwise, a weight of the spawnpoint
33 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
34 {
35         float shortest, thisdist;
36         entity player;
37
38         // filter out spots for the wrong team
39         if(teamcheck)
40         if(spot.team != teamcheck)
41                 return -1;
42
43         // filter out spots for assault
44         if(spot.target != "") {
45                 local entity ent;
46                 ent = find(world, targetname, spot.target);
47                 while(ent) {
48                         if(ent.classname == "target_objective")
49                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
50                                         return -1;
51                         ent = find(ent, targetname, spot.target);
52                 }
53         }
54
55         player = playerlist;
56         shortest = vlen(world.maxs - world.mins);
57         for(player = playerlist; player; player = player.chain)
58                 if (player != self)
59                 {
60                         thisdist = vlen(player.origin - spot.origin);
61                         if (thisdist < shortest)
62                                 shortest = thisdist;
63                 }
64         return shortest;
65 }
66
67 float spawn_allbad;
68 float spawn_allgood;
69 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
70 {
71         local entity spot, spotlist, spotlistend;
72         spawn_allgood = TRUE;
73         spawn_allbad = TRUE;
74
75         spotlist = world;
76         spotlistend = world;
77
78         for(spot = firstspot; spot; spot = spot.chain)
79         {
80                 spot.frags = Spawn_Score(spot, playerlist, teamcheck);
81
82                 if(cvar("spawn_debugview"))
83                 {
84                         setmodel(spot, "models/runematch/rune.mdl");
85                         if(spot.frags < mindist)
86                         {
87                                 spot.colormod = '1 0 0';
88                                 spot.scale = 1;
89                         }
90                         else
91                         {
92                                 spot.colormod = '0 1 0';
93                                 spot.scale = spot.frags / mindist;
94                         }
95                 }
96
97                 if(spot.frags >= 0) // spawning allowed here
98                 {
99                         if(spot.frags < mindist)
100                         {
101                                 // too short distance
102                                 spawn_allgood = FALSE;
103                         }
104                         else 
105                         {
106                                 // perfect
107                                 spawn_allbad = FALSE;
108
109                                 if(spotlistend)
110                                         spotlistend.chain = spot;
111                                 spotlistend = spot;
112                                 if(!spotlist)
113                                         spotlist = spot;
114
115                                 /*
116                                 if(teamcheck)
117                                 if(spot.team != teamcheck)
118                                         error("invalid spawn added");
119
120                                 print("added ", etos(spot), "\n");
121                                 */
122                         }
123                 }
124         }
125         if(spotlistend)
126                 spotlistend.chain = world;
127
128         /*
129                 entity e;
130                 if(teamcheck)
131                         for(e = spotlist; e; e = e.chain)
132                         {
133                                 print("seen ", etos(e), "\n");
134                                 if(e.team != teamcheck)
135                                         error("invalid spawn found");
136                         }
137         */
138
139         return spotlist;
140 }
141
142 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
143 {
144         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
145         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
146         local entity spot;
147
148         RandomSelection_Init();
149         for(spot = firstspot; spot; spot = spot.chain)
150                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.frags, upper), exponent) * spot.cnt);
151
152         return RandomSelection_chosen_ent;
153 }
154
155 /*
156 =============
157 SelectSpawnPoint
158
159 Finds a point to respawn
160 =============
161 */
162 entity SelectSpawnPoint (float anypoint)
163 {
164         local float teamcheck;
165         local entity firstspot_new;
166         local entity spot, firstspot, playerlist;
167
168         spot = find (world, classname, "testplayerstart");
169         if (spot)
170                 return spot;
171
172         teamcheck = 0;
173
174         if(!anypoint && have_team_spawns)
175                 teamcheck = self.team;
176
177         // get the list of players
178         playerlist = findchain(classname, "player");
179         // get the entire list of spots
180         firstspot = findchain(classname, "info_player_deathmatch");
181         // filter out the bad ones
182         // (note this returns the original list if none survived)
183         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
184         if(!firstspot_new)
185                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
186         firstspot = firstspot_new;
187
188         // there is 50/50 chance of choosing a random spot or the furthest spot
189         // (this means that roughly every other spawn will be furthest, so you
190         // usually won't get fragged at spawn twice in a row)
191         if (arena_roundbased)
192         {
193                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
194                 if(firstspot_new)
195                         firstspot = firstspot_new;
196                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
197         }
198         else if (random() > cvar("g_spawn_furthest"))
199                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
200         else
201                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
202
203         if(cvar("spawn_debugview"))
204         {
205                 print("spot mindistance: ", ftos(spot.frags), "\n");
206
207                 entity e;
208                 if(teamcheck)
209                         for(e = firstspot; e; e = e.chain)
210                                 if(e.team != teamcheck)
211                                         error("invalid spawn found");
212         }
213
214         if (!spot)
215         {
216                 if(cvar("spawn_debug"))
217                         GotoNextMap();
218                 else
219                 {
220                         if(some_spawn_has_been_used)
221                                 return world; // team can't spawn any more, because of actions of other team
222                         else
223                                 error("Cannot find a spawn point - please fix the map!");
224                 }
225         }
226
227         return spot;
228 }
229
230 /*
231 =============
232 CheckPlayerModel
233
234 Checks if the argument string can be a valid playermodel.
235 Returns a valid one in doubt.
236 =============
237 */
238 string FallbackPlayerModel = "models/player/marine.zym";
239 string CheckPlayerModel(string plyermodel) {
240         if(strlen(plyermodel) < 4)
241                 return FallbackPlayerModel;
242         if( substring(plyermodel,0,14) != "models/player/")
243                 return FallbackPlayerModel;
244         else if(cvar("sv_servermodelsonly"))
245         {
246                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
247                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
248                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
249                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
250                         return FallbackPlayerModel;
251                 if(!fexists(plyermodel))
252                         return FallbackPlayerModel;
253         }
254         return plyermodel;
255 }
256
257 /*
258 =============
259 Client_customizeentityforclient
260
261 LOD reduction
262 =============
263 */
264 float Client_customizeentityforclient()
265 {
266 #ifdef ALLOW_VARIABLE_LOD
267         // self: me
268         // other: the player viewing me
269         float distance;
270         float f;
271
272         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
273                 return TRUE;
274
275         if(other.cvar_cl_playerdetailreduction <= 0)
276         {
277                 if(other.cvar_cl_playerdetailreduction <= -2)
278                         self.modelindex = self.modelindex_lod2;
279                 else if(other.cvar_cl_playerdetailreduction <= -1)
280                         self.modelindex = self.modelindex_lod1;
281                 else
282                         self.modelindex = self.modelindex_lod0;
283         }
284         else
285         {
286                 distance = vlen(self.origin - other.origin);
287                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
288                 if(f > 10000)
289                         self.modelindex = self.modelindex_lod2;
290                 else if(f > 5000)
291                         self.modelindex = self.modelindex_lod1;
292                 else
293                         self.modelindex = self.modelindex_lod0;
294         }
295 #endif
296
297         return TRUE;
298 }
299
300 void UpdatePlayerSounds();
301 void setmodel_lod(entity e, string modelname)
302 {
303 #ifdef ALLOW_VARIABLE_LOD
304         string s;
305
306         // FIXME: this only supports 3-letter extensions
307         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
308         if(fexists(s))
309         {
310                 precache_model(s);
311                 setmodel(e, s); // players have high precision
312                 self.modelindex_lod1 = self.modelindex;
313         }
314         else
315                 self.modelindex_lod1 = -1;
316
317         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
318         if(fexists(s))
319         {
320                 precache_model(s);
321                 setmodel(e, s); // players have high precision
322                 self.modelindex_lod2 = self.modelindex;
323         }
324         else
325                 self.modelindex_lod2 = -1;
326
327         precache_model(modelname);
328         setmodel(e, modelname); // players have high precision
329         self.modelindex_lod0 = self.modelindex;
330
331         if(self.modelindex_lod1 < 0)
332                 self.modelindex_lod1 = self.modelindex;
333
334         if(self.modelindex_lod2 < 0)
335                 self.modelindex_lod2 = self.modelindex;
336 #else
337         precache_model(modelname);
338         setmodel(e, modelname); // players have high precision
339 #endif
340         player_setupanimsformodel();
341         UpdatePlayerSounds();
342 }
343
344 /*
345 =============
346 PutObserverInServer
347
348 putting a client as observer in the server
349 =============
350 */
351 void ctf_UpdateCaptures();
352 void PutObserverInServer (void)
353 {
354         entity  spot;
355         spot = SelectSpawnPoint (TRUE);
356         if(!spot)
357                 error("No spawnpoints for observers?!?\n");
358         RemoveGrapplingHook(self); // Wazat's Grappling Hook
359
360         if(clienttype(self) == CLIENTTYPE_REAL)
361         {
362                 msg_entity = self;
363                 WriteByte(MSG_ONE, SVC_SETVIEW);
364                 WriteEntity(MSG_ONE, self);
365         }
366
367         DropAllRunes(self);
368         kh_Key_DropAll(self, TRUE);
369
370         if(self.flagcarried)
371                 DropFlag(self.flagcarried);
372
373         WaypointSprite_PlayerDead();
374
375         DistributeFragsAmongTeam(self, self.team, 1);
376         if(g_ctf)
377         {
378                 self.captures = 0;
379                 ctf_UpdateCaptures();
380         }
381
382         if(self.frags <= 0 && self.frags > -666 && g_lms && self.killcount != -666)
383                 bprint ("^4", self.netname, "^4 has no more lives left\n");
384         else if(self.killcount != -666)
385                 bprint ("^4", self.netname, "^4 is spectating now\n");
386
387         self.spectatortime = time;
388         
389         self.classname = "observer";
390         self.health = -666;
391         self.takedamage = DAMAGE_NO;
392         self.solid = SOLID_NOT;
393         self.movetype = MOVETYPE_NOCLIP;
394         self.flags = FL_CLIENT | FL_NOTARGET;
395         self.armorvalue = 666;
396         self.effects = 0;
397         self.armorvalue = cvar("g_balance_armor_start");
398         self.pauserotarmor_finished = 0;
399         self.pauserothealth_finished = 0;
400         self.pauseregen_finished = 0;
401         self.damageforcescale = 0;
402         self.death_time = 0;
403         self.dead_frame = 0;
404         self.deaths = 0;
405         self.alpha = 0;
406         self.scale = 0;
407         self.fade_time = 0;
408         self.pain_frame = 0;
409         self.pain_finished = 0;
410         self.strength_finished = 0;
411         self.invincible_finished = 0;
412         self.pushltime = 0;
413         self.think = SUB_Null;
414         self.nextthink = 0;
415         self.hook_time = 0;
416         self.runes = 0;
417         self.deadflag = DEAD_NO;
418         self.angles = spot.angles;
419         self.angles_z = 0;
420         self.fixangle = TRUE;
421         self.crouch = FALSE;
422
423         self.view_ofs = PL_VIEW_OFS;
424         setorigin (self, spot.origin);
425         setsize (self, '0 0 0', '0 0 0');
426         self.oldorigin = self.origin;
427         self.items = 0;
428         self.model = "";
429         self.modelindex = 0;
430         self.weapon = 0;
431         self.weaponmodel = "";
432         self.weaponentity = world;
433         self.killcount = -666;
434         self.velocity = '0 0 0';
435         self.avelocity = '0 0 0';
436         self.punchangle = '0 0 0';
437         self.punchvector = '0 0 0';
438         self.oldvelocity = self.velocity;
439         self.customizeentityforclient = Client_customizeentityforclient;
440         self.viewzoom = 1;
441         self.wantswelcomemessage = 1;
442
443         if(g_arena)
444         {
445                 if(self.frags != -2)
446                 {
447                         Spawnqueue_Insert(self);
448                 }
449                 else
450                 {
451                         Spawnqueue_Unmark(self);
452                         Spawnqueue_Remove(self);
453                 }
454         }
455         else if(!g_lms)
456                 self.frags = -666;
457 }
458
459 float RestrictSkin(float s)
460 {
461         if(!teams_matter)
462                 return s;
463         if(s == 6)
464                 return 6;
465         return mod(s, 3);
466 }
467
468 void FixPlayermodel()
469 {
470         local string defaultmodel;
471         local float defaultskin;
472         local vector m1, m2;
473
474         defaultmodel = "";
475
476         if(cvar("sv_defaultcharacter") == 1) {
477                 defaultskin = 0;
478
479                 if(teams_matter)
480                 {
481                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
482                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
483                 }
484
485                 if(defaultmodel == "")
486                 {
487                         defaultmodel = cvar_string("sv_defaultplayermodel");
488                         defaultskin = cvar("sv_defaultplayerskin");
489                 }
490         }
491
492         if(defaultmodel != "")
493         {
494                 if (defaultmodel != self.model)
495                 {
496                         m1 = self.mins;
497                         m2 = self.maxs;
498                         setmodel_lod (self, defaultmodel);
499                         setsize (self, m1, m2);
500                 }
501
502                 self.skin = defaultskin;
503         } else {
504                 if (self.playermodel != self.model)
505                 {
506                         self.playermodel = CheckPlayerModel(self.playermodel);
507                         m1 = self.mins;
508                         m2 = self.maxs;
509                         setmodel_lod (self, self.playermodel);
510                         setsize (self, m1, m2);
511                 }
512
513                 self.skin = RestrictSkin(stof(self.playerskin));
514         }
515
516         if(!teams_matter)
517                 if(strlen(cvar_string("sv_defaultplayercolors")))
518                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
519                                 setcolor(self, cvar("sv_defaultplayercolors"));
520 }
521
522 /*
523 =============
524 PutClientInServer
525
526 Called when a client spawns in the server
527 =============
528 */
529 //void() ctf_playerchanged;
530 void PutClientInServer (void)
531 {
532         if(clienttype(self) == CLIENTTYPE_BOT)
533         {
534                 self.classname = "player";
535         }
536         else if(clienttype(self) == CLIENTTYPE_REAL)
537         {
538                 msg_entity = self;
539                 WriteByte(MSG_ONE, SVC_SETVIEW);
540                 WriteEntity(MSG_ONE, self);
541         }
542
543         // player is dead and becomes observer
544         if(g_lms && self.frags < 1)
545                 self.classname = "observer";
546
547         if(g_arena)
548         if(!self.spawned)
549                 self.classname = "observer";
550
551         if(self.classname == "player") {
552                 entity  spot;
553
554                 spot = SelectSpawnPoint (FALSE);
555                 if(!spot)
556                 {
557                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
558                         return; // spawn failed
559                 }
560
561                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
562
563                 self.classname = "player";
564                 self.iscreature = TRUE;
565                 self.movetype = MOVETYPE_WALK;
566                 self.solid = SOLID_SLIDEBOX;
567                 self.flags = FL_CLIENT;
568                 self.takedamage = DAMAGE_AIM;
569                 if(g_minstagib)
570                         self.effects = EF_FULLBRIGHT;
571                 else
572                         self.effects = 0;
573                 self.air_finished = time + 12;
574                 self.dmg = 2;
575
576                 self.ammo_shells = start_ammo_shells;
577                 self.ammo_nails = start_ammo_nails;
578                 self.ammo_rockets = start_ammo_rockets;
579                 self.ammo_cells = start_ammo_cells;
580                 self.health = start_health;
581                 self.armorvalue = start_armorvalue;
582                 self.items = start_items;
583                 self.switchweapon = start_switchweapon;
584                 self.cnt = start_switchweapon;
585                 self.weapon = 0;
586                 self.jump_interval = time;
587
588                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
589                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
590                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
591                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
592                 //extend the pause of rotting if client was reset at the beginning of the countdown
593                 if(!cvar("sv_ready_restart_after_countdown") && time < restart_countdown) {
594                         self.spawnshieldtime += RESTART_COUNTDOWN;
595                         self.pauserotarmor_finished += RESTART_COUNTDOWN;
596                         self.pauserothealth_finished += RESTART_COUNTDOWN;
597                         self.pauseregen_finished += RESTART_COUNTDOWN;
598                 }
599                 self.damageforcescale = 2;
600                 self.death_time = 0;
601                 self.dead_frame = 0;
602                 self.alpha = 0;
603                 self.scale = 0;
604                 self.fade_time = 0;
605                 self.pain_frame = 0;
606                 self.pain_finished = 0;
607                 self.strength_finished = 0;
608                 self.invincible_finished = 0;
609                 self.pushltime = 0;
610                 //self.speed_finished = 0;
611                 //self.slowmo_finished = 0;
612                 // players have no think function
613                 self.think = SUB_Null;
614                 self.nextthink = 0;
615                 self.hook_time = 0;
616
617                 self.runes = 0;
618
619                 self.deadflag = DEAD_NO;
620
621                 self.angles = spot.angles;
622
623                 self.angles_z = 0; // never spawn tilted even if the spot says to
624                 self.fixangle = TRUE; // turn this way immediately
625                 self.velocity = '0 0 0';
626                 self.avelocity = '0 0 0';
627                 self.punchangle = '0 0 0';
628                 self.punchvector = '0 0 0';
629                 self.oldvelocity = self.velocity;
630
631                 self.viewzoom = 0.6;
632                 self.has_zoomed = 0;
633
634                 self.customizeentityforclient = Client_customizeentityforclient;
635
636                 self.model = "";
637                 FixPlayermodel();
638
639                 self.crouch = FALSE;
640                 self.view_ofs = PL_VIEW_OFS;
641                 setsize (self, PL_MIN, PL_MAX);
642                 self.spawnorigin = spot.origin;
643                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
644                 // don't reset back to last position, even if new position is stuck in solid
645                 self.oldorigin = self.origin;
646
647                 if(g_arena)
648                 {
649                         Spawnqueue_Remove(self);
650                         Spawnqueue_Mark(self);
651                 }
652
653                 self.event_damage = PlayerDamage;
654
655                 self.bot_attack = TRUE;
656
657                 self.statdraintime = time + 5;
658                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
659
660                 if(self.killcount == -666) {
661                         self.killcount = 0;
662                         if(!g_arena)
663                         if(!g_lms)
664                                 self.frags = 0;
665                 }
666
667                 self.cnt = WEP_LASER;
668                 self.nixnex_lastchange_id = -1;
669
670                 CL_SpawnWeaponentity();
671                 self.alpha = default_player_alpha;
672                 self.colormod = '1 1 1' * cvar("g_player_brightness");
673                 self.exteriorweaponentity.alpha = default_weapon_alpha;
674
675                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
676                 self.lms_traveled_distance = 0;
677                 self.speedrunning = FALSE;
678
679                 if(cvar("spawn_debug"))
680                 {
681                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
682                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
683                 }
684
685                 //stuffcmd(self, "chase_active 0");
686                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
687
688                 if (cvar("g_spawnsound"))
689                         sound (self, CHAN_AUTO, "misc/spawn.wav", 1, ATTN_NORM);
690
691                 if(g_assault) {
692                         if(self.team == assault_attacker_team)
693                                 centerprint(self, "You are attacking!\n");
694                         else
695                                 centerprint(self, "You are defending!\n");
696                 }
697
698         } else if(self.classname == "observer") {
699                 PutObserverInServer ();
700         }
701
702         //if(g_ctf)
703         //      ctf_playerchanged();
704 }
705
706 /*
707 =============
708 SendCSQCInfo
709
710 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
711 =============
712 */
713 void SendCSQCInfo(void)
714 {
715         if(clienttype(self) != CLIENTTYPE_REAL)
716                 return;
717         msg_entity = self;
718         WriteByte(MSG_ONE, SVC_TEMPENTITY);
719         WriteByte(MSG_ONE, TE_CSQC_INIT);
720         WriteByte(MSG_ONE, maxclients-1);
721 }
722
723 /*
724 =============
725 SetNewParms
726 =============
727 */
728 void SetNewParms (void)
729 {
730         // initialize parms for a new player
731         print("SetNewParms\n");
732         parm1 = -(86400 * 366);
733 }
734
735 /*
736 =============
737 SetChangeParms
738 =============
739 */
740 void SetChangeParms (void)
741 {
742         // save parms for level change
743         print("SetChangeParms\n");
744         parm1 = self.parm_idlesince - time;
745 }
746
747 /*
748 =============
749 DecodeLevelParms
750 =============
751 */
752 void DecodeLevelParms (void)
753 {
754         // load parms
755         print("DecodeLevelParms\n");
756         self.parm_idlesince = parm1;
757         if(self.parm_idlesince == -(86400 * 366))
758                 self.parm_idlesince = time;
759 }
760
761 /*
762 =============
763 ClientKill
764
765 Called when a client types 'kill' in the console
766 =============
767 */
768
769 void ClientKill_Now_TeamChange()
770 {
771         if(g_ctf)
772         {
773                 self.captures = 0;
774                 ctf_UpdateCaptures();
775         }
776         if(self.killindicator_teamchange == -1)
777         {
778                 self.team = -1;
779                 JoinBestTeam( self, FALSE, FALSE );
780         }
781         else
782         {
783                 SV_ChangeTeam(self.killindicator_teamchange - 1);
784         }
785 }
786
787 void ClientKill_Now()
788 {
789         if(self.killindicator_teamchange)
790                 ClientKill_Now_TeamChange();
791
792         // in any case:
793         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
794 }
795 void KillIndicator_Think()
796 {
797         if (!self.owner.modelindex)
798         {
799                 self.owner.killindicator = world;
800                 remove(self);
801                 return;
802         }
803
804         if(self.cnt <= 0)
805         {
806                 self = self.owner;
807                 ClientKill_Now(); // no oldself needed
808                 return;
809         }
810         else
811         {
812                 if(self.cnt <= 10)
813                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
814                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
815                 {
816                         if(self.cnt <= 10)
817                                 play2(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".ogg"));
818                         if(self.owner.killindicator_teamchange)
819                         {
820                                 if(self.owner.killindicator_teamchange == -1)
821                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
822                                 else
823                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
824                         }
825                         else
826                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
827                 }
828                 self.nextthink = time + 1;
829                 self.cnt -= 1;
830         }
831 }
832
833 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
834 {
835         float killtime;
836         entity e;
837         killtime = cvar("g_balance_kill_delay");
838
839         self.killindicator_teamchange = targetteam;
840
841         if(!self.killindicator)
842         {
843                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
844                 {
845                         ClientKill_Now();
846                 }
847                 else
848                 {
849                         self.killindicator = spawn();
850                         self.killindicator.owner = self;
851                         self.killindicator.scale = 0.5;
852                         setattachment(self.killindicator, self, "");
853                         setorigin(self.killindicator, '0 0 52');
854                         self.killindicator.think = KillIndicator_Think;
855                         self.killindicator.nextthink = time + (self.lip) * 0.05;
856                         self.killindicator.cnt = ceil(killtime);
857                         self.killindicator.count = bound(0, ceil(killtime), 10);
858                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
859
860                         for(e = world; (e = find(e, classname, "body")) != world; )
861                         {
862                                 if(e.enemy != self)
863                                         continue;
864                                 e.killindicator = spawn();
865                                 e.killindicator.owner = e;
866                                 e.killindicator.scale = 0.5;
867                                 setattachment(e.killindicator, e, "");
868                                 setorigin(e.killindicator, '0 0 52');
869                                 e.killindicator.think = KillIndicator_Think;
870                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
871                                 e.killindicator.cnt = ceil(killtime);
872                         }
873                         self.lip = 0;
874                 }
875         }
876         if(self.killindicator)
877         {
878                 if(targetteam)
879                         self.killindicator.colormod = TeamColor(targetteam);
880                 else
881                         self.killindicator.colormod = '0 0 0';
882         }
883 }
884
885 void ClientKill (void)
886 {
887         ClientKill_TeamChange(0);
888 }
889
890 void DoTeamChange(float destteam)
891 {
892         float t, c0;
893         if(!cvar("teamplay"))
894         {
895                 if(destteam >= 0)
896                         SetPlayerColors(self, destteam);
897                 return;
898         }
899         if(self.classname == "player")
900         if(destteam == -1)
901         {
902                 CheckAllowedTeams(self);
903                 t = FindSmallestTeam(self, TRUE);
904                 switch(self.team)
905                 {
906                         case COLOR_TEAM1: c0 = c1; break;
907                         case COLOR_TEAM2: c0 = c2; break;
908                         case COLOR_TEAM3: c0 = c3; break;
909                         case COLOR_TEAM4: c0 = c4; break;
910                         default:          c0 = 999;
911                 }
912                 switch(t)
913                 {
914                         case 1:
915                                 if(c0 > c1)
916                                         destteam = COLOR_TEAM1;
917                                 break;
918                         case 2:
919                                 if(c0 > c2)
920                                         destteam = COLOR_TEAM2;
921                                 break;
922                         case 3:
923                                 if(c0 > c3)
924                                         destteam = COLOR_TEAM3;
925                                 break;
926                         case 4:
927                                 if(c0 > c4)
928                                         destteam = COLOR_TEAM4;
929                                 break;
930                 }
931                 if(destteam == -1)
932                         return;
933         }
934         if(destteam == self.team && !self.killindicator)
935                 return;
936         ClientKill_TeamChange(destteam);
937 }
938
939 void FixClientCvars(entity e)
940 {
941         // send prediction settings to the client
942         stuffcmd(e, "\nin_bindmap 0 0\n");
943         /*
944          * we no longer need to stuff this. Remove this comment block if you feel 
945          * 2.3 and higher (or was it 2.2.3?) don't need these any more
946         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
947         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
948         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
949         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
950         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
951         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
952         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
953         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
954         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
955         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
956         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
957         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
958         stuffcmd(e, "cl_movement_edgefriction 1\n");
959          */
960 }
961
962 /*
963 =============
964 ClientConnect
965
966 Called when a client connects to the server
967 =============
968 */
969 //void ctf_clientconnect();
970 string ColoredTeamName(float t);
971 void DecodeLevelParms (void);
972 void ctf_SendCaptures(entity);
973 //void dom_player_join_team(entity pl);
974 void ClientConnect (void)
975 {
976         local string s;
977         float wep;
978
979         if(Ban_IsClientBanned(self))
980         {
981                 s = strcat("^1NOTE:^7 banned client ", self.netaddress, " just tried to enter\n");
982                 dropclient(self);
983                 bprint(s);
984                 return;
985         }
986
987         DecodeLevelParms();
988
989         self.classname = "player_joining";
990         self.flags = self.flags | FL_CLIENT;
991         self.version_nagtime = time + 10 + random() * 10;
992
993         if(player_count<0)
994         {
995                 dprint("BUG player count is lower than zero, this cannot happen!\n");
996                 player_count = 0;
997         }
998
999         bot_clientconnect();
1000
1001         //if(g_domination)
1002         //      dom_player_join_team(self);
1003
1004         //JoinBestTeam(self, FALSE, FALSE);
1005
1006         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1007                 self.classname = "observer";
1008         } else {
1009                 self.classname = "player";
1010                 campaign_bots_may_start = 1;
1011         }
1012
1013         self.playerid = (playerid_last = playerid_last + 1);
1014         if(cvar("sv_eventlog"))
1015         {
1016                 if(clienttype(self) == CLIENTTYPE_REAL)
1017                         s = "player";
1018                 else
1019                         s = "bot";
1020                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
1021                 s = strcat(":team:", ftos(self.playerid), ":");
1022                 s = strcat(s, ftos(self.team));
1023                 GameLogEcho(s, FALSE);
1024         }
1025         self.netname_previous = strzone(self.netname);
1026
1027         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1028
1029         bprint ("^4",self.netname);
1030         bprint ("^4 connected");
1031
1032         if(g_domination || g_ctf)
1033         {
1034                 bprint(" and joined the ");
1035                 bprint(ColoredTeamName(self.team));
1036         }
1037
1038         bprint("\n");
1039
1040         self.welcomemessage_time = 0;
1041
1042         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1043         // TODO: is this being used for anything else than cd tracks?
1044         // Remember: SVC_CDTRACK exists. Maybe it should be used.
1045         //
1046         stuffcmd(self, "cl_particles_reloadeffects\n");
1047
1048         FixClientCvars(self);
1049
1050         // spawnfunc_waypoint sprites
1051         WaypointSprite_InitClient(self);
1052
1053         // Wazat's grappling hook
1054         SetGrappleHookBindings();
1055
1056         // get autoswitch state from player when he toggles it
1057         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1058
1059         // get version info from player
1060         stuffcmd(self, "cmd clientversion $gameversion\n");
1061
1062         // send all weapon info strings
1063         stuffcmd(self, "register_bestweapon clear\n"); // clear the Quake stuff
1064         wep = WEP_FIRST;
1065         while (wep <= WEP_LAST)
1066         {
1067                 weapon_action(wep, WR_REGISTER);
1068                 wep = wep + 1;
1069         }
1070
1071         // get other cvars from player
1072         GetCvars(0);
1073
1074         // set cvar for team scoreboard
1075         if (teams_matter)
1076         {
1077                 local float t;
1078                 t = cvar("teamplay");
1079                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1080                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1081         }
1082         else
1083                 stuffcmd(self, "set teamplay 0\n");
1084
1085         // notify about available teams
1086         if(teamplay)
1087         {
1088                 CheckAllowedTeams(self);
1089                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1090                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1091         }
1092         else
1093                 stuffcmd(self, "set _teams_available 0\n");
1094
1095         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1096
1097         if(g_lms)
1098         {
1099                 self.frags = LMS_NewPlayerLives();
1100                 if(!self.frags)
1101                         self.frags = -666;
1102         }
1103         else if(g_arena)
1104         {
1105                 self.classname = "observer";
1106                 Spawnqueue_Insert(self);
1107         }
1108         /*else if(g_ctf)
1109         {
1110                 ctf_clientconnect();
1111         }*/
1112
1113         if(entcs_start)
1114                 attach_entcs();
1115
1116         bot_relinkplayerlist();
1117
1118         self.spectatortime = time;
1119         if(blockSpectators)
1120         {
1121                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1122         }
1123
1124         self.jointime = time;
1125         self.allowedTimeouts = cvar("sv_timeout_number");
1126
1127         SendCSQCInfo();
1128         ctf_SendCaptures(self);
1129 }
1130
1131 /*
1132 =============
1133 ClientDisconnect
1134
1135 Called when a client disconnects from the server
1136 =============
1137 */
1138 void(entity e) DropFlag;
1139 .entity chatbubbleentity;
1140 .entity teambubbleentity;
1141 //void() ctf_clientdisconnect;
1142 void ClientDisconnect (void)
1143 {
1144         float save;
1145
1146         if(entcs_start)
1147                 detach_entcs();
1148         
1149         if(cvar("sv_eventlog"))
1150                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
1151         bprint ("^4",self.netname);
1152         bprint ("^4 disconnected\n");
1153
1154         if (self.chatbubbleentity)
1155         {
1156                 remove (self.chatbubbleentity);
1157                 self.chatbubbleentity = world;
1158         }
1159
1160         if (self.teambubbleentity)
1161         {
1162                 remove (self.teambubbleentity);
1163                 self.teambubbleentity = world;
1164         }
1165
1166         if (self.killindicator)
1167         {
1168                 remove (self.killindicator);
1169                 self.killindicator = world;
1170         }
1171
1172         WaypointSprite_PlayerGone();
1173
1174         DropAllRunes(self);
1175         kh_Key_DropAll(self, TRUE);
1176
1177         if(self.flagcarried)
1178                 DropFlag(self.flagcarried);
1179
1180         DistributeFragsAmongTeam(self, self.team, 1);
1181         if(g_ctf)
1182         {
1183                 self.captures = 0;
1184                 ctf_UpdateCaptures();
1185         }
1186
1187         save = self.flags;
1188         self.flags = self.flags - (self.flags & FL_CLIENT);
1189         bot_relinkplayerlist();
1190         self.flags = save;
1191
1192         // remove laserdot
1193         if(self.weaponentity)
1194                 if(self.weaponentity.lasertarget)
1195                         remove(self.weaponentity.lasertarget);
1196
1197         if(g_arena)
1198         {
1199                 Spawnqueue_Unmark(self);
1200                 Spawnqueue_Remove(self);
1201         }
1202         /*if(g_ctf)
1203         {
1204                 ctf_clientdisconnect();
1205         }
1206         */
1207
1208         if(self.netname_previous)
1209                 strunzone(self.netname_previous);
1210
1211         // free cvars
1212         GetCvars(-1);
1213 }
1214
1215 .float BUTTON_CHAT;
1216 void ChatBubbleThink()
1217 {
1218         self.nextthink = time;
1219         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1220         {
1221                 self.owner.chatbubbleentity = world;
1222                 remove(self);
1223                 return;
1224         }
1225         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1226         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1227                 self.model = self.mdl;
1228         else
1229                 self.model = "";
1230 };
1231
1232 void UpdateChatBubble()
1233 {
1234         if (!self.modelindex)
1235                 return;
1236         // spawn a chatbubble entity if needed
1237         if (!self.chatbubbleentity)
1238         {
1239                 self.chatbubbleentity = spawn();
1240                 self.chatbubbleentity.owner = self;
1241                 self.chatbubbleentity.exteriormodeltoclient = self;
1242                 self.chatbubbleentity.think = ChatBubbleThink;
1243                 self.chatbubbleentity.nextthink = time;
1244                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1245                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1246                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1247                 self.chatbubbleentity.model = "";
1248                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1249         }
1250 }
1251
1252
1253 void TeamBubbleThink()
1254 {
1255         self.nextthink = time;
1256         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1257         {
1258                 self.owner.teambubbleentity = world;
1259                 remove(self);
1260                 return;
1261         }
1262 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1263         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1264                 self.model = "";
1265         else
1266                 self.model = self.mdl;
1267
1268 };
1269
1270 float TeamBubble_customizeentityforclient()
1271 {
1272         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1273 }
1274
1275 void UpdateTeamBubble()
1276 {
1277         if (!self.modelindex || !cvar("teamplay"))
1278                 return;
1279         // spawn a teambubble entity if needed
1280         if (!self.teambubbleentity && cvar("teamplay"))
1281         {
1282                 self.teambubbleentity = spawn();
1283                 self.teambubbleentity.owner = self;
1284                 self.teambubbleentity.exteriormodeltoclient = self;
1285                 self.teambubbleentity.think = TeamBubbleThink;
1286                 self.teambubbleentity.nextthink = time;
1287                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1288 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1289                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1290                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1291                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1292                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1293                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1294                 self.teambubbleentity.effects = EF_LOWPRECISION;
1295         }
1296 }
1297
1298 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1299 // added to the model skins
1300 /*void UpdateColorModHack()
1301 {
1302         local float c;
1303         c = self.clientcolors & 15;
1304         // LordHavoc: only bothering to support white, green, red, yellow, blue
1305              if (teamplay == 0) self.colormod = '0 0 0';
1306         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1307         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1308         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1309         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1310         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1311         else self.colormod = '1 1 1';
1312 };*/
1313
1314 void respawn(void)
1315 {
1316         CopyBody(1);
1317         self.effects |= EF_NODRAW; // prevent another CopyBody
1318         PutClientInServer();
1319 }
1320
1321 /**
1322  * When sv_timeout is used this function returs strings like
1323  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1324  * Called by centerprint functions
1325  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1326  */
1327 string getTimeoutText(float addOneSecond) {
1328         if (!cvar("sv_timeout") || !timeoutStatus)
1329                 return "";
1330
1331         local string retStr;
1332         if (timeoutStatus == 1) {
1333                 if (addOneSecond == 1) {
1334                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1335                 }
1336                 else {
1337                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1338                 }
1339                 return retStr;
1340         }
1341         else if (timeoutStatus == 2) {
1342                 if (addOneSecond) {
1343                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1344                         //don't show messages like "Timeout ends in 0 seconds"...
1345                         if ((remainingTimeoutTime + 1) > 0)
1346                                 return retStr;
1347                         else
1348                                 return "";
1349                 }
1350                 else {
1351                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1352                         //don't show messages like "Timeout ends in 0 seconds"...
1353                         if (remainingTimeoutTime > 0)
1354                                 return retStr;
1355                         else
1356                                 return "";
1357                 }
1358         }
1359         else return "";
1360 }
1361
1362 void player_powerups (void)
1363 {
1364         if (g_minstagib)
1365         {
1366                 if (self.items & IT_STRENGTH)
1367                 {
1368                         if (time > self.strength_finished)
1369                         {
1370                                 if (g_minstagib_invis_alpha > 0)
1371                                 {
1372                                         self.alpha = default_player_alpha;
1373                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1374                                         self.effects = self.effects | EF_FULLBRIGHT;
1375                                 }
1376                                 else
1377                                 {
1378                                         self.effects -= self.effects & EF_NODRAW;
1379                                 }
1380                                 self.items = self.items - (self.items & IT_STRENGTH);
1381                                 sprint(self, "^3Invisibility has worn off\n");
1382                         }
1383                 }
1384                 else
1385                 {
1386                         if (time < self.strength_finished)
1387                         {
1388                                 if (g_minstagib_invis_alpha > 0)
1389                                 {
1390                                         self.alpha = g_minstagib_invis_alpha;
1391                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1392                                         self.effects -= self.effects & EF_FULLBRIGHT;
1393                                 }
1394                                 else
1395                                 {
1396                                         self.effects = self.effects | EF_NODRAW;
1397                                 }
1398                                 self.items = self.items | IT_STRENGTH;
1399                                 sprint(self, "^3You are invisible\n");
1400                         }
1401                 }
1402
1403                 if (self.items & IT_INVINCIBLE)
1404                 {
1405                         if (time > self.invincible_finished)
1406                         {
1407                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1408                                 sprint(self, "^3Speed has worn off\n");
1409                         }
1410                 }
1411                 else
1412                 {
1413                         if (time < self.invincible_finished)
1414                         {
1415                                 self.items = self.items | IT_INVINCIBLE;
1416                                 sprint(self, "^3You are on speed\n");
1417                         }
1418                 }
1419                 return;
1420         }
1421
1422         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1423         if (self.items & IT_STRENGTH)
1424         {
1425                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1426                 if (time > self.strength_finished)
1427                 {
1428                         self.items = self.items - (self.items & IT_STRENGTH);
1429                         sprint(self, "^3Strength has worn off\n");
1430                 }
1431         }
1432         else
1433         {
1434                 if (time < self.strength_finished)
1435                 {
1436                         self.items = self.items | IT_STRENGTH;
1437                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1438                 }
1439         }
1440         if (self.items & IT_INVINCIBLE)
1441         {
1442                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1443                 if (time > self.invincible_finished)
1444                 {
1445                         self.items = self.items - (self.items & IT_INVINCIBLE);
1446                         sprint(self, "^3Shield has worn off\n");
1447                 }
1448         }
1449         else
1450         {
1451                 if (time < self.invincible_finished)
1452                 {
1453                         self.items = self.items | IT_INVINCIBLE;
1454                         sprint(self, "^3Shield surrounds you\n");
1455                 }
1456         }
1457
1458         if (cvar("g_fullbrightplayers"))
1459                 self.effects = self.effects | EF_FULLBRIGHT;
1460
1461         // midair gamemode: damage only while in the air
1462         // if in midair mode, being on ground grants temporary invulnerability
1463         // (this is so that multishot weapon don't clear the ground flag on the
1464         // first damage in the frame, leaving the player vulnerable to the
1465         // remaining hits in the same frame)
1466         if (self.flags & FL_ONGROUND)
1467         if (g_midair)
1468                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1469
1470         if (time < self.spawnshieldtime)
1471                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1472 }
1473
1474 float CalcRegen(float current, float stable, float regenfactor)
1475 {
1476         if(current > stable)
1477                 return current;
1478         else if(current > stable - 0.25) // when close enough, "snap"
1479                 return stable;
1480         else
1481                 return min(stable, current + (stable - current) * regenfactor * frametime);
1482 }
1483
1484 void player_regen (void)
1485 {
1486         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1487         maxh = cvar("g_balance_health_stable");
1488         maxa = cvar("g_balance_armor_stable");
1489         limith = cvar("g_balance_health_limit");
1490         limita = cvar("g_balance_armor_limit");
1491
1492         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1493                 return;
1494
1495         max_mod = regen_mod = rot_mod = limit_mod = 1;
1496
1497         if (self.runes & RUNE_REGEN)
1498         {
1499                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1500                 {
1501                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1502                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1503                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1504                 }
1505                 else
1506                 {
1507                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1508                         max_mod = cvar("g_balance_rune_regen_hpmod");
1509                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1510                 }
1511         }
1512         else if (self.runes & CURSE_VENOM)
1513         {
1514                 max_mod = cvar("g_balance_curse_venom_hpmod");
1515                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1516                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1517                 else
1518                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1519                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1520                 //if (!self.runes & RUNE_REGEN)
1521                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1522         }
1523         maxh = maxh * max_mod;
1524         //maxa = maxa * max_mod;
1525         limith = limith * limit_mod;
1526         limita = limita * limit_mod;
1527
1528         if (self.armorvalue > maxa)
1529         {
1530                 if (time > self.pauserotarmor_finished)
1531                 {
1532                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1533                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1534                 }
1535         }
1536         else if (self.armorvalue < maxa)
1537         {
1538                 if (time > self.pauseregen_finished)
1539                 {
1540                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1541                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1542                 }
1543         }
1544         if (self.health > maxh)
1545         {
1546                 if (time > self.pauserothealth_finished)
1547                 {
1548                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1549                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1550                 }
1551         }
1552         else if (self.health < maxh)
1553         {
1554                 if (time > self.pauseregen_finished)
1555                 {
1556                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1557                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1558                 }
1559         }
1560
1561         if (self.health > limith)
1562                 self.health = limith;
1563         if (self.armorvalue > limita)
1564                 self.armorvalue = limita;
1565
1566         // if player rotted to death...  die!
1567         if(self.health < 1)
1568                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1569 }
1570
1571 /*
1572 ======================
1573 spectate mode routines
1574 ======================
1575 */
1576 void SpectateCopy(entity spectatee) {
1577         self.armortype = spectatee.armortype;
1578         self.armorvalue = spectatee.armorvalue;
1579         self.currentammo = spectatee.currentammo;
1580         self.effects = spectatee.effects;
1581         self.health = spectatee.health;
1582         self.impulse = 0;
1583         self.items = spectatee.items;
1584         self.punchangle = spectatee.punchangle;
1585         self.view_ofs = spectatee.view_ofs;
1586         self.v_angle = spectatee.v_angle;
1587         self.viewzoom = spectatee.viewzoom;
1588         self.velocity = spectatee.velocity;
1589         self.dmg_take = spectatee.dmg_take;
1590         self.dmg_save = spectatee.dmg_save;
1591         self.dmg_inflictor = spectatee.dmg_inflictor;
1592         self.angles = spectatee.v_angle;
1593         self.fixangle = TRUE;
1594         setorigin(self, spectatee.origin);
1595         setsize(self, spectatee.mins, spectatee.maxs);
1596 }
1597
1598 float SpectateUpdate() {
1599         if(!self.enemy)
1600                 return 0;
1601
1602         if (self == self.enemy)
1603                 return 0;
1604         
1605         if(self.enemy.flags & FL_NOTARGET)
1606                 return 0;
1607
1608         SpectateCopy(self.enemy);
1609
1610         return 1;
1611 }
1612
1613 float SpectateNext() {
1614         other = find(self.enemy, classname, "player");
1615         if (!other) {
1616                 other = find(other, classname, "player");
1617         }
1618         if (other) {
1619                 self.enemy = other;
1620         }
1621         if(self.enemy.classname == "player") {
1622                 msg_entity = self;
1623                 WriteByte(MSG_ONE, SVC_SETVIEW);
1624                 WriteEntity(MSG_ONE, self.enemy);
1625                 self.wantswelcomemessage = 1;
1626                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1627                 if(!SpectateUpdate())
1628                         PutObserverInServer();
1629                 return 1;
1630         } else {
1631                 return 0;
1632         }
1633 }
1634
1635 /*
1636 =============
1637 ShowRespawnCountdown()
1638
1639 Update a respawn countdown display.
1640 =============
1641 */
1642 void ShowRespawnCountdown()
1643 {
1644         float number;
1645         if(self.deadflag == DEAD_NO) // just respawned?
1646                 return;
1647         else
1648         {
1649                 number = ceil(self.death_time - time);
1650                 if(number <= 0)
1651                         return;
1652                 if(number <= self.respawn_countdown)
1653                 {
1654                         self.respawn_countdown = number - 1;
1655                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1656                                 play2(self, strcat("announcer/robotic/", ftos(number), ".ogg"));
1657                 }
1658         }
1659 }
1660
1661 void LeaveSpectatorMode()
1662 {
1663         if(isJoinAllowed()) {
1664                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1665                         self.classname = "player";
1666                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1667                                 JoinBestTeam(self, FALSE, TRUE);
1668                         if(cvar("g_campaign"))
1669                                 campaign_bots_may_start = 1;
1670                         PutClientInServer();
1671                         if(!(self.flags & FL_NOTARGET))
1672                                 bprint ("^4", self.netname, "^4 is playing now\n");
1673                         centerprint(self,"");
1674                         return;
1675                 } else {
1676                         stuffcmd(self,"menu_showteamselect\n");
1677                         return;
1678                 }
1679         }
1680         else {
1681                 //player may not join because of g_maxplayers is set
1682                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1683         }
1684 }
1685
1686 /**
1687  * Determines whether the player is allowed to join. This depends on cvar
1688  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1689  * it checks whether the number of currently playing players exceeds g_maxplayers.
1690  * @return bool TRUE if the player is allowed to join, false otherwise
1691  */
1692 float isJoinAllowed() {
1693         if (!cvar("g_maxplayers"))
1694                 return TRUE;
1695
1696         local entity e;
1697         local float currentlyPlaying;
1698         FOR_EACH_REALPLAYER(e) {
1699                 if(e.classname == "player")
1700                         currentlyPlaying += 1;
1701         }
1702         if(currentlyPlaying < cvar("g_maxplayers"))
1703                 return TRUE;
1704
1705         return FALSE;
1706 }
1707
1708 /**
1709  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1710  * g_maxplayers_spectator_blocktime seconds
1711  */
1712 void checkSpectatorBlock() {
1713         if(self.classname == "spectator" || self.classname == "observer") {
1714                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1715                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1716                         dropclient(self);
1717                 }
1718         }
1719 }
1720
1721 float vercmp_recursive(string v1, string v2)
1722 {
1723         float dot1, dot2;
1724         string s1, s2;
1725         float r;
1726
1727         dot1 = strstrofs(v1, ".", 0);
1728         dot2 = strstrofs(v2, ".", 0);
1729         if(dot1 == -1)
1730                 s1 = v1;
1731         else
1732                 s1 = substring(v1, 0, dot1);
1733         if(dot2 == -1)
1734                 s2 = v2;
1735         else
1736                 s2 = substring(v2, 0, dot2);
1737
1738         r = stof(s1) - stof(s2);
1739         if(r != 0)
1740                 return r;
1741
1742         r = strcasecmp(s1, s2);
1743         if(r != 0)
1744                 return r;
1745
1746         if(dot1 == -1)
1747                 if(dot2 == -1)
1748                         return 0;
1749                 else
1750                         return -1;
1751         else
1752                 if(dot2 == -1)
1753                         return 1;
1754                 else
1755                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1756 }
1757
1758 float vercmp(string v1, string v2)
1759 {
1760         if(strcasecmp(v1, v2) == 0) // early out check
1761                 return 0;
1762         return vercmp_recursive(v1, v2);
1763 }
1764
1765 void ObserverThink()
1766 {
1767         if (self.flags & FL_JUMPRELEASED) {
1768                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1769                         self.welcomemessage_time = 0;
1770                         self.flags = self.flags - FL_JUMPRELEASED;
1771                         LeaveSpectatorMode();
1772                         return;
1773                 } else if(self.BUTTON_ATCK && self.version == cvar("gameversion")) {
1774                         self.welcomemessage_time = 0;
1775                         self.flags = self.flags - FL_JUMPRELEASED;
1776                         if(SpectateNext() == 1) {
1777                                 self.classname = "spectator";
1778                         }
1779                 }
1780         } else {
1781                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1782                         self.flags = self.flags | FL_JUMPRELEASED;
1783                 }
1784         }
1785         if(self.BUTTON_ZOOM)
1786                 self.wantswelcomemessage = 0;
1787         if(self.wantswelcomemessage)
1788                 PrintWelcomeMessage(self);
1789 }
1790
1791 void SpectatorThink()
1792 {
1793         if (self.flags & FL_JUMPRELEASED) {
1794                 if (self.BUTTON_JUMP && self.version == cvar("gameversion")) {
1795                         self.welcomemessage_time = 0;
1796                         self.flags = self.flags - FL_JUMPRELEASED;
1797                         LeaveSpectatorMode();
1798                         return;
1799                 } else if(self.BUTTON_ATCK) {
1800                         self.welcomemessage_time = 0;
1801                         self.flags = self.flags - FL_JUMPRELEASED;
1802                         if(SpectateNext() == 1) {
1803                                 self.classname = "spectator";
1804                         } else {
1805                                 self.classname = "observer";
1806                                 PutClientInServer();
1807                         }
1808                 } else if (self.BUTTON_ATCK2) {
1809                         self.welcomemessage_time = 0;
1810                         self.flags = self.flags - FL_JUMPRELEASED;
1811                         self.classname = "observer";
1812                         PutClientInServer();
1813                 } else {
1814                         if(!SpectateUpdate())
1815                                 PutObserverInServer();
1816                 }
1817         } else {
1818                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
1819                         self.flags = self.flags | FL_JUMPRELEASED;
1820                 }
1821         }
1822         if(self.BUTTON_ZOOM)
1823                 self.wantswelcomemessage = 0;
1824         if(self.wantswelcomemessage)
1825                 PrintWelcomeMessage(self);
1826         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1827 }
1828
1829 /*
1830 =============
1831 PlayerPreThink
1832
1833 Called every frame for each client before the physics are run
1834 =============
1835 */
1836 void() ctf_setstatus;
1837 .float vote_nagtime;
1838 void PlayerPreThink (void)
1839 {
1840         if(blockSpectators)
1841                 checkSpectatorBlock();
1842         
1843         if(self.netname_previous != self.netname)
1844         {
1845                 if(cvar("sv_eventlog"))
1846                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname), TRUE);
1847                 if(self.netname_previous)
1848                         strunzone(self.netname_previous);
1849                 self.netname_previous = strzone(self.netname);
1850         }
1851
1852         // version nagging
1853         if(self.version_nagtime)
1854                 if(self.cvar_g_nexuizversion)
1855                         if(time > self.version_nagtime)
1856                         {
1857                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
1858                                 {
1859                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
1860                                         {
1861                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1862                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1863                                         }
1864                                         else
1865                                         {
1866                                                 float r;
1867                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
1868                                                 if(r < 0)
1869                                                 {
1870                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
1871                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
1872                                                 }
1873                                                 else if(r > 0)
1874                                                 {
1875                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
1876                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
1877                                                 }
1878                                         }
1879                                 }
1880                                 self.version_nagtime = 0;
1881                         }
1882
1883         // vote nagging
1884         if(self.cvar_scr_centertime)
1885                 if(time > self.vote_nagtime)
1886                 {
1887                         VoteNag();
1888                         self.vote_nagtime = time + self.cvar_scr_centertime * 0.6;
1889                 }
1890
1891         // GOD MODE info
1892         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
1893         {
1894                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
1895                 self.max_armorvalue = 0;
1896         }
1897
1898         if(frametime)
1899                 antilag_record(self);
1900
1901         if(self.classname == "player") {
1902 //              if(self.netname == "Wazat")
1903 //                      bprint(self.classname, "\n");
1904
1905                 CheckRules_Player();
1906
1907                 if(self.BUTTON_INFO)
1908                         PrintWelcomeMessage(self);
1909
1910                 if(g_lms || !cvar("sv_spectate"))
1911                 if((time - self.jointime) <= cvar("welcome_message_time"))
1912                         PrintWelcomeMessage(self);
1913
1914                 if (intermission_running)
1915                 {
1916                         IntermissionThink ();   // otherwise a button could be missed between
1917                         return;                                 // the think tics
1918                 }
1919
1920                 if(self.teleport_time)
1921                 if(time > self.teleport_time)
1922                 {
1923                         self.teleport_time = 0;
1924                         self.effects = self.effects - (self.effects & EF_NODRAW);
1925                         if(self.weaponentity)
1926                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
1927                 }
1928
1929                 Nixnex_GiveCurrentWeapon();
1930
1931                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
1932                         UpdateSelectedPlayer();
1933
1934                 //don't allow the player to turn around while game is paused!
1935                 if(timeoutStatus == 2) {
1936                         self.v_angle = self.lastV_angle;
1937                         self.angles = self.lastV_angle;
1938                         self.fixangle = TRUE;
1939                 }
1940
1941                 if (self.deadflag != DEAD_NO)
1942                 {
1943                         float button_pressed, force_respawn;
1944                         player_anim();
1945                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
1946                         force_respawn = (g_lms || cvar("g_forced_respawn"));
1947                         if (self.deadflag == DEAD_DYING)
1948                         {
1949                                 if(force_respawn)
1950                                         self.deadflag = DEAD_RESPAWNING;
1951                                 else if(!button_pressed)
1952                                         self.deadflag = DEAD_DEAD;
1953                         }
1954                         else if (self.deadflag == DEAD_DEAD)
1955                         {
1956                                 if(button_pressed)
1957                                         self.deadflag = DEAD_RESPAWNABLE;
1958                         }
1959                         else if (self.deadflag == DEAD_RESPAWNABLE)
1960                         {
1961                                 if(!button_pressed)
1962                                         self.deadflag = DEAD_RESPAWNING;
1963                         }
1964                         else if (self.deadflag == DEAD_RESPAWNING)
1965                         {
1966                                 if(time > self.death_time)
1967                                 {
1968                                         self.death_time = time + 1; // only retry once a second
1969                                         respawn();
1970                                 }
1971                         }
1972                         ShowRespawnCountdown();
1973                         return;
1974                 }
1975
1976                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
1977                 {
1978                         vector dist;
1979
1980                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1981                         dist = self.oldorigin - self.origin;
1982                         dist_z = 0;
1983                         self.lms_traveled_distance += fabs(vlen(dist));
1984
1985                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < restart_countdown))
1986                         {
1987                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1988                                 self.lms_traveled_distance = 0;
1989                         }
1990
1991                         if(time > self.lms_nextcheck)
1992                         {
1993                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1994                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1995                                 {
1996                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1997                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1998                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1999                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2000                                 }
2001                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2002                                 self.lms_traveled_distance = 0;
2003                         }
2004                 }
2005
2006                 if (self.BUTTON_CROUCH && !self.hook.state)
2007                 {
2008                         if (!self.crouch)
2009                         {
2010                                 self.crouch = TRUE;
2011                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2012                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2013                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2014                         }
2015                 }
2016                 else
2017                 {
2018                         if (self.crouch)
2019                         {
2020                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2021                                 if (!trace_startsolid)
2022                                 {
2023                                         self.crouch = FALSE;
2024                                         self.view_ofs = PL_VIEW_OFS;
2025                                         setsize (self, PL_MIN, PL_MAX);
2026                                 }
2027                         }
2028                 }
2029
2030                 FixPlayermodel();
2031
2032                 GrapplingHookFrame();
2033
2034                 W_WeaponFrame();
2035
2036                 {
2037                         float zoomfactor, zoomspeed, zoomdir;
2038                         zoomfactor = self.cvar_cl_zoomfactor;
2039                         if(zoomfactor < 1 || zoomfactor > 16)
2040                                 zoomfactor = 2.5;
2041                         zoomspeed = self.cvar_cl_zoomspeed;
2042                         if(zoomspeed >= 0) // < 0 is instant zoom
2043                                 if(zoomspeed < 0.5 || zoomspeed > 16)
2044                                         zoomspeed = 3.5;
2045
2046                         zoomdir = self.BUTTON_ZOOM;
2047                         if(self.BUTTON_ATCK2)
2048                                 if(self.weapon == WEP_NEX)
2049                                         if(!g_minstagib)
2050                                                 zoomdir = 1;
2051
2052                         if(zoomdir)
2053                                 self.has_zoomed = 1;
2054
2055                         if(self.has_zoomed)
2056                         {
2057                                 if(zoomspeed <= 0) // instant zoom
2058                                 {
2059                                         if(zoomdir)
2060                                                 self.viewzoom = 1 / zoomfactor;
2061                                         else
2062                                                 self.viewzoom = 1;
2063                                 }
2064                                 else
2065                                 {
2066                                         // geometric zoom would be:
2067                                         //   self.viewzoom = bound(1 / zoomfactor, self.viewzoom * pow(zoomfactor, (zoomdir ? -1 : 1) * frametime * zoomspeed), 1);
2068                                         // however, testing showed that arithmetic/harmonic zoom works better
2069                                         if(zoomdir)
2070                                                 // self.viewzoom = 1 / bound(1, 1 / self.viewzoom + (zoomdir ? 1 : -1) * frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2071                                                 // zoom in = arithmetic: 1x, 2x, 3x, 4x, ..., 8x
2072                                                 self.viewzoom = 1 / bound(1, 1 / self.viewzoom + frametime * zoomspeed * (zoomfactor - 1), zoomfactor);
2073                                         else
2074                                                 // self.viewzoom = bound(1 / zoomfactor, self.viewzoom + (zoomdir ? -1 : 1) * frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2075                                                 // zoom out = harmonic: 8/1x, 8/2x, 8/3x, 8/4x, ..., 8/8x
2076                                                 self.viewzoom = bound(1 / zoomfactor, self.viewzoom + frametime * zoomspeed * (1 - 1 / zoomfactor), 1);
2077                                 }
2078                         }
2079                         else
2080                                 self.viewzoom = min(1, self.viewzoom + frametime); // spawn zoom-in
2081                 }
2082
2083                 player_powerups();
2084                 player_regen();
2085                 player_anim();
2086
2087                 if (g_minstagib)
2088                         minstagib_ammocheck();
2089
2090                 ctf_setstatus();
2091                 kh_setstatus();
2092
2093                 //self.angles_y=self.v_angle_y + 90;   // temp
2094
2095                 //if (TetrisPreFrame()) return;
2096         } else if(gameover) {
2097                 if (intermission_running)
2098                         IntermissionThink ();   // otherwise a button could be missed between
2099                 return;
2100         } else if(self.classname == "observer") {
2101                 ObserverThink();
2102         } else if(self.classname == "spectator") {
2103                 SpectatorThink();
2104         }
2105 }
2106
2107
2108 /*
2109 =============
2110 PlayerPostThink
2111
2112 Called every frame for each client after the physics are run
2113 =============
2114 */
2115 .float idlekick_lasttimeleft;
2116 void PlayerPostThink (void)
2117 {
2118         // Savage: Check for nameless players
2119         if (strlen(self.netname) < 1) {
2120                 self.netname = "Player";
2121                 stuffcmd(self, "seta _cl_name Player\n");
2122         }
2123
2124         if(sv_maxidle)
2125         {
2126                 float timeleft;
2127                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2128                 if(timeleft <= 0)
2129                 {
2130                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2131                         play2(self, "announcer/robotic/terminated.ogg");
2132                         dropclient(self);
2133                         return;
2134                 }
2135                 else if(timeleft <= 10)
2136                 {
2137                         if(timeleft != self.idlekick_lasttimeleft)
2138                         {
2139                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2140                                 play2(self, strcat("announcer/robotic/", ftos(timeleft), ".ogg"));
2141                         }
2142                 }
2143                 else
2144                 {
2145                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2146                 }
2147                 self.idlekick_lasttimeleft = timeleft;
2148         }
2149
2150         if(self.classname == "player") {
2151                 CheckRules_Player();
2152                 UpdateChatBubble();
2153                 UpdateTeamBubble();
2154                 if (self.impulse)
2155                         ImpulseCommands();
2156                 if (intermission_running)
2157                         return;         // intermission or finale
2158
2159                 //PrintWelcomeMessage(self);
2160                 //if (TetrisPostFrame()) return;
2161
2162                 // restart countdown
2163                 if (restart_countdown) {
2164                         if(time < restart_countdown) {
2165                                 if (!cvar("sv_ready_restart_after_countdown"))
2166                                 {
2167                                         self.movetype = MOVETYPE_NONE;          
2168                                         self.velocity = '0 0 0';
2169                                         self.avelocity = '0 0 0';
2170                                         self.movement = '0 0 0';
2171                                 }
2172                         }
2173                         else
2174                         {
2175                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2176                                 if (!cvar("sv_ready_restart_after_countdown"))
2177                                 {
2178                                         if(self.movetype == MOVETYPE_NONE)
2179                                         {
2180                                                 self.movetype = MOVETYPE_WALK;
2181                                         }
2182                                 }
2183                         }
2184                 }
2185                 
2186         } else if (self.classname == "observer") {
2187                 //do nothing
2188         } else if (self.classname == "spectator") {
2189                 //do nothing
2190         }
2191
2192         Arena_Warmup();
2193 }