data/qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float sv_cheats;
  18 float autocvar_sv_cheats;
  19
  20 #define CHIMPULSE_SPEEDRUN_INIT 30
  21 #define CHIMPULSE_GIVE_ALL 99
  22 #define CHIMPULSE_CLONE_MOVING 140
  23 #define CHIMPULSE_SPEEDRUN 141
  24 #define CHIMPULSE_CLONE_STANDING 142
  25 #define CHIMPULSE_TELEPORT 143
  26 #define CHIMPULSE_R00T 148
  27
  28 #define CHRAME_DRAG 8
  29
  30 void CheatInit()
  31 {
  32         sv_cheats = cvar("sv_cheats");
  33 }
  34
  35 void CheatShutdown()
  36 {
  37 }
  38
  39 void CheatInitClient()
  40 {
  41 }
  42
  43 void CheatShutdownClient()
  44 {
  45 }
  46
  47 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  48 {
  49         // dead people cannot cheat
  50         if(self.deadflag != DEAD_NO)
  51                 return 0;
  52         if(self.classname != "player")
  53                 return 0;
  54
  55         // sv_clones
  56         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  57                 if(self.lip < sv_clones)
  58                         return 1;
  59
  60         // haha
  61         if(self.maycheat)
  62                 return 1;
  63
  64         // sv_cheats
  65         if(sv_cheats && autocvar_sv_cheats)
  66                 return 1;
  67
  68         // if we get here, player is not allowed to cheat. Log it.
  69         if(i)
  70                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  71         else if(argc)
  72                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  73         else if(fr)
  74                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  75         else
  76                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  77
  78         return 0;
  79 }
  80
  81 #define BEGIN_CHEAT_FUNCTION() \
  82         float cheating, attempting; \
  83         cheating = 0; attempting = 0
  84 #define DID_CHEAT() \
  85         ++cheating
  86 #define ADD_CHEATS(e,n) \
  87         cheatcount_total += n; \
  88         e.cheatcount += n
  89 #define END_CHEAT_FUNCTION() \
  90         ADD_CHEATS(self,cheating); \
  91         return attempting
  92 #define IS_CHEAT(i,argc,fr) \
  93         ++attempting; \
  94         if(!CheatsAllowed(i,argc,fr)) \
  95                 break
  96
  97 float CheatImpulse(float i)
  98 {
  99         BEGIN_CHEAT_FUNCTION();
 100         switch(i)
 101         {
 102                 entity e, e2;
 103                 vector org;
 104
 105                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 106                         // shared with regular waypoint init, so this is not a cheat by itself
 107                         if(!self.personal)
 108                         {
 109                                 self.personal = spawn();
 110                                 self.personal.classname = "personal_wp";
 111                         }
 112                         self.personal.origin = self.origin;
 113                         self.personal.v_angle = self.v_angle;
 114                         self.personal.velocity = self.velocity;
 115                         self.personal.ammo_rockets = self.ammo_rockets;
 116                         self.personal.ammo_nails = self.ammo_nails;
 117                         self.personal.ammo_cells = self.ammo_cells;
 118                         self.personal.ammo_shells = self.ammo_shells;
 119                         self.personal.ammo_fuel = self.ammo_fuel;
 120                         self.personal.health = self.health;
 121                         self.personal.armorvalue = self.armorvalue;
 122                         self.personal.weapons = self.weapons;
 123                         self.personal.items = self.items;
 124                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 125                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 126                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 127                         self.personal.pauseregen_finished = self.pauseregen_finished;
 128                         self.personal.strength_finished = self.strength_finished;
 129                         self.personal.invincible_finished = self.invincible_finished;
 130                         self.personal.teleport_time = time;
 131                         break; // this part itself doesn't cheat, so let's not count this
 132                 case CHIMPULSE_CLONE_MOVING:
 133                         IS_CHEAT(i, 0, 0);
 134                         makevectors (self.v_angle);
 135                         self.velocity = self.velocity + v_forward * 300;
 136                         CopyBody(1);
 137                         self.lip += 1;
 138                         self.velocity = self.velocity - v_forward * 300;
 139                         DID_CHEAT();
 140                         break;
 141                 case CHIMPULSE_CLONE_STANDING:
 142                         IS_CHEAT(i, 0, 0);
 143                         CopyBody(0);
 144                         self.lip += 1;
 145                         DID_CHEAT();
 146                         break;
 147                 case CHIMPULSE_GIVE_ALL:
 148                         IS_CHEAT(i, 0, 0);
 149                         CheatCommand(tokenize_console("give all"));
 150                         break; // already counted as cheat
 151                 case CHIMPULSE_SPEEDRUN:
 152                         IS_CHEAT(i, 0, 0);
 153                         if(self.personal)
 154                         {
 155                                 self.speedrunning = TRUE;
 156                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 157                                 if(trace_startsolid)
 158                                 {
 159                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 160                                 }
 161                                 else
 162                                 {
 163                                         // Abort speedrun, teleport back
 164                                         setorigin(self, self.personal.origin);
 165                                         self.oldvelocity = self.velocity = self.personal.velocity;
 166                                         self.angles = self.personal.v_angle;
 167                                         self.fixangle = TRUE;
 168                                         if(self.flagcarried)
 169                                         {
 170                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 171                                                 ReturnFlag(self.flagcarried);
 172                                         }
 173                                 }
 174                                 if(g_ctf)
 175                                 {
 176                                         self.ammo_rockets = 999;
 177                                         self.ammo_nails = 999;
 178                                         self.ammo_cells = 999;
 179                                         self.ammo_shells = 999;
 180                                         self.ammo_fuel = 999;
 181                                         self.health = start_health;
 182                                         self.armorvalue = start_armorvalue;
 183                                         self.weapons |= weaponsInMap;
 184                                         self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 185                                         self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 186                                         self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 187                                         self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 188                                         self.strength_finished = 0;
 189                                         self.invincible_finished = 0;
 190                                 }
 191                                 else
 192                                 {
 193                                         self.ammo_rockets = self.personal.ammo_rockets;
 194                                         self.ammo_nails = self.personal.ammo_nails;
 195                                         self.ammo_cells = self.personal.ammo_cells;
 196                                         self.ammo_shells = self.personal.ammo_shells;
 197                                         self.ammo_fuel = self.personal.ammo_fuel;
 198                                         self.health = self.personal.health;
 199                                         self.armorvalue = self.personal.armorvalue;
 200                                         self.weapons = self.personal.weapons;
 201                                         self.items = self.personal.items;
 202                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 203                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 204                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 205                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 206                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 207                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 208                                 }
 209                                 DID_CHEAT();
 210                                 break;
 211                         }
 212                         if(self.deadflag != DEAD_NO)
 213                                 sprint(self, "UR DEAD AHAHAH))\n");
 214                         else
 215                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 216                         break;
 217                 case CHIMPULSE_TELEPORT:
 218                         IS_CHEAT(i, 0, 0);
 219                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 220                         {
 221                                 self.angles_x = -self.angles_x;
 222                                 self.fixangle = TRUE;
 223                                 self.velocity = '0 0 0';
 224                                 DID_CHEAT();
 225                                 break;
 226                         }
 227                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 228                         break;
 229                 case CHIMPULSE_R00T:
 230                         IS_CHEAT(i, 0, 0);
 231                         FOR_EACH_PLAYER(e)
 232                         {
 233                                 if( e.playermodel == "models/player/jeandarc.zym"
 234                                                 ||  e.playermodel == "models/player/pyria.zym"
 235                                                 ||  e.playermodel == "models/player/skadi.zym"
 236                                                 || (e.playermodel == "models/player/specop.zym" && random() < 0.5) // you never know
 237                                                 ||  e.playermodel == "models/player/visitant.zym")
 238                                 {
 239                                         makevectors(e.angles);
 240                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 241                                 }
 242                                 else
 243                                 {
 244                                         org_x = random();
 245                                         org_y = random();
 246                                         org_z = 0;
 247                                         org = normalize(org);
 248                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 249                                 }
 250
 251                                 org = findbetterlocation(trace_endpos, 12);
 252
 253                                 e2 = spawn();
 254                                 setorigin(e2, org);
 255                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 256                                 sound(e2, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 257                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 258                                 remove(e2);
 259                         }
 260                         print("404 Sportsmanship not found.\n");
 261                         DID_CHEAT();
 262                         break;
 263         }
 264
 265         END_CHEAT_FUNCTION();
 266 }
 267
 268 void DragBox_Think();
 269 float drag_lastcnt;
 270 float CheatCommand(float argc)
 271 {
 272         BEGIN_CHEAT_FUNCTION();
 273         string cmd;
 274         cmd = argv(0);
 275         switch(cmd)
 276         {
 277                 entity e;
 278                 float effectnum, f;
 279                 vector start, end;
 280                 entity oldself;
 281
 282                 case "pointparticles":
 283                         IS_CHEAT(0, argc, 0);
 284                         if(argc == 5)
 285                         {
 286                                 // arguments:
 287                                 //   effectname
 288                                 //   origin (0..1, on crosshair line)
 289                                 //   velocity
 290                                 //   howmany
 291                                 effectnum = particleeffectnum(argv(1));
 292                                 f = stof(argv(2));
 293                                 start = (1-f) * self.origin + f * self.cursor_trace_endpos;
 294                                 end = stov(argv(3));
 295                                 f = stof(argv(4));
 296                                 pointparticles(effectnum, start, end, f);
 297                                 DID_CHEAT();
 298                                 break;
 299                         }
 300                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 301                         break;
 302                 case "trailparticles":
 303                         IS_CHEAT(0, argc, 0);
 304                         if(argc == 2)
 305                         {
 306                                 // arguments:
 307                                 //   effectname
 308                                 effectnum = particleeffectnum(argv(1));
 309                                 W_SetupShot(self, FALSE, FALSE, "",0);
 310                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 311                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 312                                 DID_CHEAT();
 313                                 break;
 314                         }
 315                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 316                         break;
 317                 case "make":
 318                         IS_CHEAT(0, argc, 0);
 319                         if(argc == 3)
 320                         {
 321                                 // arguments:
 322                                 //   modelname mode
 323                                 f = stof(argv(2));
 324                                 W_SetupShot(self, FALSE, FALSE, "", 0);
 325                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 326                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 327                                 {
 328                                         sprint(self, "cannot make stuff there (bad surface)\n");
 329                                 }
 330                                 else
 331                                 {
 332                                         e = spawn();
 333                                         e.model = strzone(argv(1));
 334                                         e.mdl = "rocket_explode";
 335                                         e.health = 1000;
 336                                         setorigin(e, trace_endpos);
 337                                         e.effects = EF_NOMODELFLAGS;
 338                                         if(f == 1)
 339                                         {
 340                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 341                                                 e.angles = AnglesTransform_Multiply(e.angles, '-90 0 0'); // so unrotated models work
 342                                         }
 343                                         oldself = self;
 344                                         self = e;
 345                                         spawnfunc_func_breakable();
 346                                         self = oldself;
 347                                         // now, is it valid?
 348                                         if(f == 0)
 349                                         {
 350                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 351                                                 if(trace_startsolid)
 352                                                 {
 353                                                         remove(e);
 354                                                         sprint(self, "cannot make stuff there (no space)\n");
 355                                                 }
 356                                                 else
 357                                                         DID_CHEAT();
 358                                         }
 359                                         else
 360                                                 DID_CHEAT();
 361                                 }
 362                         }
 363                         else
 364                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 365                         break;
 366                 case "penalty":
 367                         IS_CHEAT(0, argc, 0);
 368                         if(argc == 3)
 369                         {
 370                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 371                                 DID_CHEAT();
 372                                 break;
 373                         }
 374                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 375                         break;
 376                 case "dragbox_spawn":
 377                         IS_CHEAT(0, argc, 0);
 378                         e = spawn();
 379                         e.classname = "dragbox_box";
 380                         e.think = DragBox_Think;
 381                         e.nextthink = time;
 382                         e.solid = -1; // black
 383                         setmodel(e, "null"); // network it
 384                         if(argc == 4)
 385                                 e.cnt = stof(argv(1));
 386                         else
 387                                 e.cnt = max(0, drag_lastcnt);
 388
 389                         e.aiment = spawn();
 390                         e.aiment.classname = "dragbox_corner_1";
 391                         e.aiment.owner = e;
 392                         setmodel(e.aiment, "models/marker.md3");
 393                         e.aiment.skin = 0;
 394                         setsize(e.aiment, '0 0 0', '0 0 0');
 395                         if(argc == 4)
 396                                 setorigin(e.aiment, stov(argv(2)));
 397                         else
 398                                 setorigin(e.aiment, self.cursor_trace_endpos);
 399
 400                         e.enemy = spawn();
 401                         e.enemy.classname = "dragbox_corner_2";
 402                         e.enemy.owner = e;
 403                         setmodel(e.enemy, "models/marker.md3");
 404                         e.enemy.skin = 1;
 405                         setsize(e.enemy, '0 0 0', '0 0 0');
 406                         end = normalize(self.cursor_trace_start - e.aiment.origin);
 407                         end_x = (end_x > 0) * 2 - 1;
 408                         end_y = (end_y > 0) * 2 - 1;
 409                         end_z = (end_z > 0) * 2 - 1;
 410                         if(argc == 4)
 411                                 setorigin(e.enemy, stov(argv(3)));
 412                         else
 413                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 414
 415                         e.killindicator = spawn();
 416                         e.killindicator.classname = "drag_digit";
 417                         e.killindicator.owner = e;
 418                         setattachment(e.killindicator, e, "");
 419                         setorigin(e.killindicator, '0 0 -8');
 420                         e.killindicator.killindicator = spawn();
 421                         e.killindicator.killindicator.classname = "drag_digit";
 422                         e.killindicator.killindicator.owner = e;
 423                         setattachment(e.killindicator.killindicator, e, "");
 424                         setorigin(e.killindicator.killindicator, '0 0 8');
 425                         DID_CHEAT();
 426                         break;
 427                 case "dragpoint_spawn":
 428                         IS_CHEAT(0, argc, 0);
 429                         e = spawn();
 430                         e.classname = "dragpoint";
 431                         e.think = DragBox_Think;
 432                         e.nextthink = time;
 433                         e.solid = 0; // nothing special
 434                         setmodel(e, "models/marker.md3");
 435                         setsize(e, PL_MIN, PL_MAX);
 436                         e.skin = 2;
 437                         if(argc == 3)
 438                                 e.cnt = stof(argv(1));
 439                         else
 440                                 e.cnt = drag_lastcnt;
 441                         if(argc == 3)
 442                                 setorigin(e, stov(argv(2)));
 443                         else
 444                         {
 445                                 setorigin(e, self.cursor_trace_endpos + normalize(self.cursor_trace_start - self.cursor_trace_endpos));
 446                                 move_out_of_solid(e);
 447                         }
 448
 449                         e.killindicator = spawn();
 450                         e.killindicator.classname = "drag_digit";
 451                         e.killindicator.owner = e;
 452                         setattachment(e.killindicator, e, "");
 453                         setorigin(e.killindicator, '0 0 40');
 454                         e.killindicator.killindicator = spawn();
 455                         e.killindicator.killindicator.classname = "drag_digit";
 456                         e.killindicator.killindicator.owner = e;
 457                         setattachment(e.killindicator.killindicator, e, "");
 458                         setorigin(e.killindicator.killindicator, '0 0 56');
 459                         DID_CHEAT();
 460                         break;
 461                 case "drag_remove":
 462                         IS_CHEAT(0, argc, 0);
 463                         RandomSelection_Init();
 464                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 465                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 466                         for(e = world; (e = find(e, classname, "dragpoint")); )
 467                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 468                         if(RandomSelection_chosen_ent)
 469                         {
 470                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 471                                 remove(RandomSelection_chosen_ent.killindicator);
 472                                 if(RandomSelection_chosen_ent.aiment)
 473                                         remove(RandomSelection_chosen_ent.aiment);
 474                                 if(RandomSelection_chosen_ent.enemy)
 475                                         remove(RandomSelection_chosen_ent.enemy);
 476                                 remove(RandomSelection_chosen_ent);
 477                         }
 478                         DID_CHEAT();
 479                         break;
 480                 case "drag_setcnt":
 481                         IS_CHEAT(0, argc, 0);
 482                         if(argc == 2)
 483                         {
 484                                 RandomSelection_Init();
 485                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 486                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 487                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 488                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - self.cursor_trace_endpos));
 489                                 if(RandomSelection_chosen_ent)
 490                                 {
 491                                         if(substring(argv(1), 0, 1) == "*")
 492                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 493                                         else
 494                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 495                                 }
 496                                 DID_CHEAT();
 497                                 break;
 498                         }
 499                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 500                         break;
 501                 case "drag_save":
 502                         IS_CHEAT(0, argc, 0);
 503                         if(argc == 2)
 504                         {
 505                                 f = fopen(argv(1), FILE_WRITE);
 506                                 fputs(f, "cmd drag_clear\n");
 507                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 508                                 {
 509                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 510                                 }
 511                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 512                                 {
 513                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 514                                 }
 515                                 fclose(f);
 516                                 DID_CHEAT();
 517                                 break;
 518                         }
 519                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 520                         break;
 521                 case "drag_saveraceent":
 522                         IS_CHEAT(0, argc, 0);
 523                         if(argc == 2)
 524                         {
 525                                 f = fopen(argv(1), FILE_WRITE);
 526                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 527                                 {
 528                                         fputs(f, "{\n");
 529                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 530                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 531                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 532                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 533                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 534                                         fputs(f, "}\n");
 535                                 }
 536                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 537                                 {
 538                                         start = '0 0 0';
 539                                         effectnum = 0;
 540                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 541                                         {
 542                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 543                                                 {
 544                                                         start = start + oldself.origin;
 545                                                         ++effectnum;
 546                                                 }
 547                                         }
 548                                         start *= 1 / effectnum;
 549                                         fputs(f, "{\n");
 550                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 551                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 552                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 553                                         if(e.cnt == -2)
 554                                         {
 555                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 556                                                 fputs(f, "\"race_place\" \"0\"\n");
 557                                         }
 558                                         else if(e.cnt == -1)
 559                                         {
 560                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 561                                                 fputs(f, "\"race_place\" \"-1\"\n");
 562                                         }
 563                                         else
 564                                         {
 565                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 566                                                 if(e.cnt == 0)
 567                                                 {
 568                                                         // these need race_place
 569                                                         // counting...
 570                                                         effectnum = 1;
 571                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 572                                                         if(oldself.cnt == 0)
 573                                                         {
 574                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 575                                                                         ++effectnum;
 576                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 577                                                                         ++effectnum;
 578                                                         }
 579                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 580                                                 }
 581                                         }
 582                                         fputs(f, "}\n");
 583                                 }
 584                                 fclose(f);
 585                                 DID_CHEAT();
 586                                 break;
 587                         }
 588                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 589                         break;
 590                 case "drag_clear":
 591                         IS_CHEAT(0, argc, 0);
 592                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 593                                 remove(e);
 594                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 595                                 remove(e);
 596                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 597                                 remove(e);
 598                         for(e = world; (e = find(e, classname, "dragpoint")); )
 599                                 remove(e);
 600                         for(e = world; (e = find(e, classname, "drag_digit")); )
 601                                 remove(e);
 602                         DID_CHEAT();
 603                         break;
 604                 case "warp":
 605                         IS_CHEAT(0, argc, 0);
 606                         if(argc == 2) if(cvar("g_campaign"))
 607                         {
 608                                 CampaignLevelWarp(stof(argv(1)));
 609                                 DID_CHEAT();
 610                         }
 611                         break;
 612                 case "god":
 613                         IS_CHEAT(0, argc, 0);
 614                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 615                         if(self.flags & FL_GODMODE)
 616                         {
 617                                 sprint(self, "godmode ON\n");
 618                                 DID_CHEAT();
 619                         }
 620                         else
 621                                 sprint(self, "godmode OFF\n");
 622                         break;
 623                 case "notarget":
 624                         IS_CHEAT(0, argc, 0);
 625                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 626                         if(self.flags & FL_NOTARGET)
 627                         {
 628                                 sprint(self, "notarget ON\n");
 629                                 DID_CHEAT();
 630                         }
 631                         else
 632                                 sprint(self, "notarget OFF\n");
 633                         break;
 634                 case "noclip":
 635                         IS_CHEAT(0, argc, 0);
 636                         if(self.movetype != MOVETYPE_NOCLIP)
 637                         {
 638                                 self.movetype = MOVETYPE_NOCLIP;
 639                                 sprint(self, "noclip ON\n");
 640                                 DID_CHEAT();
 641                         }
 642                         else
 643                         {
 644                                 self.movetype = MOVETYPE_WALK;
 645                                 sprint(self, "noclip OFF\n");
 646                         }
 647                         break;
 648                 case "fly":
 649                         IS_CHEAT(0, argc, 0);
 650                         if(self.movetype != MOVETYPE_FLY)
 651                         {
 652                                 self.movetype = MOVETYPE_FLY;
 653                                 sprint(self, "flmodey ON\n");
 654                                 DID_CHEAT();
 655                         }
 656                         else
 657                         {
 658                                 self.movetype = MOVETYPE_WALK;
 659                                 sprint(self, "flymode OFF\n");
 660                         }
 661                         break;
 662                 case "give":
 663                         IS_CHEAT(0, argc, 0);
 664                         if(GiveItems(self, 1, argc))
 665                                 DID_CHEAT();
 666                         break;
 667         }
 668
 669         END_CHEAT_FUNCTION();
 670 }
 671
 672 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 673 void Drag_Finish(entity dragger);
 674 float Drag_IsDraggable(entity draggee);
 675 float Drag_MayChangeAngles(entity draggee);
 676 void Drag_MoveForward(entity dragger);
 677 void Drag_SetSpeed(entity dragger, float s);
 678 void Drag_MoveBackward(entity dragger);
 679 void Drag_Update(entity dragger);
 680 float Drag_CanDrag(entity dragger);
 681 float Drag_IsDragging(entity dragger);
 682 void Drag_MoveDrag(entity from, entity to);
 683 .entity dragentity;
 684
 685 float CheatFrame()
 686 {
 687         BEGIN_CHEAT_FUNCTION();
 688
 689         if(Drag_IsDragging(self))
 690         {
 691                 if(self.BUTTON_DRAG)
 692                 {
 693                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 694                         {
 695                                 Drag_MoveForward(self);
 696                                 self.impulse = 0;
 697                         }
 698                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 699                         {
 700                                 Drag_MoveBackward(self);
 701                                 self.impulse = 0;
 702                         }
 703                         else if(self.impulse >= 1 && self.impulse <= 9)
 704                         {
 705                                 Drag_SetSpeed(self, self.impulse - 1);
 706                         }
 707                         else if(self.impulse == 14)
 708                         {
 709                                 Drag_SetSpeed(self, 9);
 710                         }
 711
 712                         if(frametime)
 713                                 Drag_Update(self);
 714                 }
 715                 else
 716                 {
 717                         Drag_Finish(self);
 718                 }
 719         }
 720         else
 721         {
 722                 if(Drag_CanDrag(self))
 723                         if(self.BUTTON_DRAG)
 724                                 if(self.cursor_trace_ent)
 725                                         if(Drag_IsDraggable(self.cursor_trace_ent))
 726                                                 switch(0)
 727                                                 {
 728                                                         default:
 729                                                                 IS_CHEAT(0, 0, CHRAME_DRAG);
 730                                                                 if(self.cursor_trace_ent.draggedby)
 731                                                                         Drag_Finish(self.cursor_trace_ent.draggedby);
 732                                                                 if(self.cursor_trace_ent.tag_entity)
 733                                                                         detach_sameorigin(self.cursor_trace_ent);
 734                                                                 Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
 735                                                                 DID_CHEAT();
 736                                                                 break;
 737                                                 }
 738         }
 739
 740         END_CHEAT_FUNCTION();
 741 }
 742
 743
 744
 745
 746
 747 // ENTITY DRAGGING
 748
 749 // on dragger:
 750 .float draggravity;
 751 .float dragspeed; // speed of mouse wheel action
 752 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 753 .vector draglocalvector; // local attachment vector of the dragentity
 754 .float draglocalangle;
 755 // on draggee:
 756 .entity draggedby;
 757 .float dragmovetype;
 758 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 759 {
 760         float tagscale;
 761
 762         draggee.dragmovetype = draggee.movetype;
 763         draggee.draggravity = draggee.gravity;
 764         draggee.movetype = MOVETYPE_WALK;
 765         draggee.gravity = 0.00001;
 766         draggee.flags &~= FL_ONGROUND;
 767         draggee.draggedby = dragger;
 768
 769         dragger.dragentity = draggee;
 770
 771         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 772         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 773         touchpoint = touchpoint - gettaginfo(draggee, 0);
 774         tagscale = pow(vlen(v_forward), -2);
 775         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 776         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 777         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 778
 779         dragger.dragspeed = 64;
 780 }
 781
 782 void Drag_Finish(entity dragger)
 783 {
 784         entity draggee;
 785         draggee = dragger.dragentity;
 786         if(dragger)
 787                 dragger.dragentity = world;
 788         draggee.draggedby = world;
 789         draggee.movetype = draggee.dragmovetype;
 790         draggee.gravity = draggee.draggravity;
 791
 792         switch(draggee.movetype)
 793         {
 794                 case MOVETYPE_TOSS:
 795                 case MOVETYPE_WALK:
 796                 case MOVETYPE_STEP:
 797                 case MOVETYPE_FLYMISSILE:
 798                 case MOVETYPE_BOUNCE:
 799                 case MOVETYPE_BOUNCEMISSILE:
 800                 case MOVETYPE_PHYSICS:
 801                         break;
 802                 default:
 803                         draggee.velocity = '0 0 0';
 804                         break;
 805         }
 806
 807         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 808         {
 809                 draggee.velocity = '0 0 0';
 810                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 811         }
 812 }
 813
 814 float Drag_IsDraggable(entity draggee)
 815 {
 816         // TODO add more checks for bad stuff here
 817         if(draggee.classname == "func_bobbing")
 818                 return FALSE;
 819         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 820                 return FALSE;
 821         if(draggee.classname == "plat")
 822                 return FALSE;
 823         if(draggee.classname == "func_button")
 824                 return FALSE;
 825         if(draggee.model == "")
 826                 return FALSE;
 827         if(draggee.classname == "spectator")
 828                 return FALSE;
 829         if(draggee.classname == "observer")
 830                 return FALSE;
 831         if(draggee.classname == "exteriorweaponentity")
 832                 return FALSE;
 833
 834         return TRUE;
 835 }
 836
 837 float Drag_MayChangeAngles(entity draggee)
 838 {
 839         // TODO add more checks for bad stuff here
 840         if(substring(draggee.model, 0, 1) == "*")
 841                 return FALSE;
 842         return TRUE;
 843 }
 844
 845 void Drag_MoveForward(entity dragger)
 846 {
 847         dragger.dragdistance += dragger.dragspeed;
 848 }
 849
 850 void Drag_SetSpeed(entity dragger, float s)
 851 {
 852         dragger.dragspeed = pow(2, s);
 853 }
 854
 855 void Drag_MoveBackward(entity dragger)
 856 {
 857         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 858 }
 859
 860 void Drag_Update(entity dragger)
 861 {
 862         vector curorigin, neworigin, goodvelocity;
 863         float f;
 864         entity draggee;
 865
 866         draggee = dragger.dragentity;
 867         draggee.flags &~= FL_ONGROUND;
 868
 869         curorigin = gettaginfo(draggee, 0);
 870         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 871         makevectors(dragger.v_angle);
 872         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 873         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 874
 875         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 876                 dragger.draglocalangle += 360;
 877         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 878                 dragger.draglocalangle -= 360;
 879
 880         f = min(frametime * 10, 1);
 881         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 882
 883         if(Drag_MayChangeAngles(draggee))
 884                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 885
 886         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 887
 888         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 889 }
 890
 891 float Drag_CanDrag(entity dragger)
 892 {
 893         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 894 }
 895
 896 float Drag_IsDragging(entity dragger)
 897 {
 898         if(!dragger.dragentity)
 899                 return FALSE;
 900         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 901         {
 902                 dragger.dragentity = world;
 903                 return FALSE;
 904         }
 905         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 906         {
 907                 Drag_Finish(dragger);
 908                 return FALSE;
 909         }
 910         return TRUE;
 911 }
 912
 913 void Drag_MoveDrag(entity from, entity to)
 914 {
 915         if(from.draggedby)
 916         {
 917                 to.draggedby = from.draggedby;
 918                 to.draggedby.dragentity = to;
 919                 from.draggedby = world;
 920         }
 921 }
 922
 923
 924
 925
 926
 927
 928 void DragBox_Think()
 929 {
 930         if(self.aiment && self.enemy)
 931         {
 932                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
 933                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
 934                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
 935                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
 936                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
 937                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
 938                 self.mins = -1 * self.maxs;
 939                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
 940         }
 941
 942         if(self.cnt == -1) // actually race_place -1
 943         {
 944                 // show "10 10" for qualifying spawns
 945                 setmodel(self.killindicator, "models/sprites/10.spr32");
 946                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
 947         }
 948         else if(self.cnt == -2) // actually race_place 0
 949         {
 950                 // show "10 0" for loser spawns
 951                 setmodel(self.killindicator, "models/sprites/10.spr32");
 952                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
 953         }
 954         else
 955         {
 956                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
 957                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
 958         }
 959
 960         self.nextthink = time;
 961 }
 962
 963 #endif