data/qcsrc/server/campaign.qc

   1 // campaign cvars:
   2 //   _campaign_index: index of CURRENT map
   3 //   _campaign_name: name of the current campaign
   4 //   g_campaign(name)_index: index of current LAST map (saved)
   5 //   g_campaign_skill: bot skill offset
   6
   7 float campaign_level;
   8 float campaign_won;
   9 string campaign_index_var;
  10 float checkrules_equality;
  11
  12 void CampaignBailout(string s)
  13 {
  14         cvar_set("g_campaign", "0");
  15         cvar = cvar_builtin;
  16         cvar_string = cvar_string_builtin;
  17         cvar_set = cvar_set_builtin;
  18         print("campaign initialization failed: ", s, "\n");
  19         return;
  20 }
  21
  22 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  23 string cvar_string_campaignwrapper(string theCvar)
  24 {
  25         float p, q;
  26         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  27         if(p < 0)
  28                 return cvar_defstring(theCvar);
  29         p += strlen(theCvar) + 3;
  30         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  31         if(q < 0)
  32                 return cvar_defstring(theCvar);
  33         return substring(cvar_campaignwrapper_list, p, q - p);
  34 }
  35 float cvar_campaignwrapper(string theCvar)
  36 {
  37         return stof(cvar_string_campaignwrapper(theCvar));
  38 }
  39 void cvar_set_campaignwrapper(string theCvar, string theValue)
  40 {
  41         if(cvar_string_campaignwrapper(theCvar) == theValue)
  42                 return;
  43         string s;
  44         s = cvar_campaignwrapper_list;
  45         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  46         strunzone(s);
  47         //print(cvar_campaignwrapper_list, "\n");
  48 }
  49
  50 void CampaignPreInit()
  51 {
  52         float baseskill;
  53         string title;
  54         campaign_level = cvar("_campaign_index");
  55         campaign_name = strzone(cvar_string("_campaign_name"));
  56         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  57         CampaignFile_Load(campaign_level, 2);
  58         if(campaign_entries < 1)
  59                 return CampaignBailout("unknown map");
  60
  61         baseskill = cvar("g_campaign_skill");
  62         baseskill = baseskill + campaign_botskill[0];
  63         if(baseskill < 0)
  64                 baseskill = 0;
  65
  66         cvar_set("sv_public", "0");
  67         cvar_set("pausable", "1");
  68
  69         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
  70
  71         cvar = cvar_campaignwrapper;
  72         cvar_string = cvar_string_campaignwrapper;
  73         cvar_set = cvar_set_campaignwrapper;
  74
  75         cvar_set("g_campaign", "1");
  76         cvar_set("g_dm", "0");
  77         cvar_set("skill", ftos(baseskill));
  78         cvar_set("bot_number", ftos(campaign_bots[0]));
  79         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
  80
  81         title = campaign_shortdesc[0];
  82         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
  83         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
  84         strunzone(title);
  85 }
  86
  87 string GetMapname();
  88 void CampaignPostInit()
  89 {
  90         // now some sanity checks
  91         string thismapname, wantedmapname;
  92         thismapname = GetMapname();
  93         wantedmapname = campaign_gametype[0];
  94         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  95                 return CampaignBailout("wrong game type!");
  96         wantedmapname = campaign_mapname[0];
  97         if(wantedmapname != thismapname)
  98                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  99         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 100         cvar_set("timelimit", "0");
 101 }
 102
 103 void CampaignSaveCvar(string cvarname, float value)
 104 {
 105         float fh;
 106         float len;
 107         string contents;
 108         string l;
 109
 110         registercvar(cvarname, ftos(value));
 111         cvar_set_builtin(cvarname, ftos(value));
 112         // note: cvarname must be remembered
 113
 114         fh = fopen("campaign.cfg", FILE_READ);
 115         contents = "";
 116         if(fh >= 0)
 117         {
 118                 while((l = fgets(fh)))
 119                 {
 120                         len = tokenize_sane(l);
 121                         if(len != 3)
 122                                 continue;
 123                         if(argv(0) != "set")
 124                                 continue;
 125                         if(argv(1) == cvarname)
 126                                 continue;
 127                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 128                 }
 129                 fclose(fh);
 130         }
 131         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 132         fh = fopen("campaign.cfg", FILE_WRITE);
 133         if(fh >= 0)
 134         {
 135                 fputs(fh, contents);
 136         }
 137         else
 138         {
 139                 error("Cannot write to campaign file");
 140         }
 141 }
 142
 143 void CampaignPreIntermission()
 144 {
 145         entity head;
 146         float won;
 147         float lost;
 148         local string savevar;
 149
 150         won = 0;
 151
 152         head = findchain(classname, "player");
 153         while(head)
 154         {
 155                 if(clienttype(head) == CLIENTTYPE_REAL)
 156                 {
 157                         if(head.winning)
 158                                 won = won + 1;
 159                         else
 160                                 lost = lost + 1;
 161                 }
 162                 head = head.chain;
 163         }
 164
 165         if(won == 1 && lost == 0 && checkrules_equality == 0)
 166         {
 167                 campaign_won = 1;
 168                 bprint("The current level has been WON.\n");
 169                 // sound!
 170         }
 171         else
 172         {
 173                 campaign_won = 0;
 174                 bprint("The current level has been LOST.\n");
 175                 // sound!
 176         }
 177
 178         if(campaign_won)
 179         {
 180                 if(campaign_entries < 2)
 181                 {
 182                         // I have won
 183                         savevar = strcat("g_campaign", campaign_name, "_won");
 184                         CampaignSaveCvar(savevar, 1);
 185                         // advance level (for menu to show it right)
 186                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 187                 }
 188                 else if(campaign_level == cvar_builtin(campaign_index_var))
 189                 {
 190                         // advance level
 191                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 192                 }
 193         }
 194 }
 195
 196 void CampaignPostIntermission()
 197 {
 198         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 199
 200         if(campaign_won && campaign_entries < 2)
 201         {
 202                 // last map won!
 203                 localcmd("togglemenu 1\n");
 204                 CampaignFile_Unload();
 205                 return;
 206         }
 207
 208         CampaignSetup(campaign_won);
 209         CampaignFile_Unload();
 210         strunzone(campaign_message);
 211         strunzone(campaign_index_var);
 212         strunzone(campaign_name);
 213         campaign_name = "";
 214 }
 215
 216
 217
 218 void CampaignLevelWarp(float n)
 219 {
 220         if(!sv_cheats)
 221                 return;
 222         CampaignFile_Unload();
 223         CampaignFile_Load(n, 1);
 224         if(campaign_entries)
 225                 CampaignSetup(0);
 226         else
 227                 error("Sorry, cheater. You are NOT WELCOME.");
 228         CampaignFile_Unload();
 229 }