data/qcsrc/server/campaign.qc

   1 // campaign cvars:
   2 //   _campaign_index: index of CURRENT map
   3 //   _campaign_name: name of the current campaign
   4 //   g_campaign(name)_index: index of current LAST map (saved)
   5 //   g_campaign_skill: bot skill offset
   6
   7 float campaign_level;
   8 float campaign_won;
   9 string campaign_index_var;
  10 float checkrules_equality;
  11
  12 void(string s) CampaignBailout =
  13 {
  14         cvar_set("g_campaign", "0");
  15         ServerConsoleEcho(strcat("campaign initialization failed: ", s), TRUE);
  16         return;
  17 }
  18
  19 void() CampaignPreInit =
  20 {
  21         float baseskill;
  22         string title;
  23         campaign_level = cvar("_campaign_index");
  24         campaign_name = strzone(cvar_string("_campaign_name"));
  25         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  26         CampaignFile_Load(campaign_level, 2);
  27         if(campaign_entries < 1)
  28                 return CampaignBailout("unknown map");
  29         cvar_set("bot_number", ftos(campaign_bots[0]));
  30
  31         baseskill = cvar("g_campaign_skill");
  32         baseskill = baseskill + campaign_botskill[0];
  33         if(baseskill < 0)
  34                 baseskill = 0;
  35         cvar_set("skill", ftos(baseskill));
  36
  37         cvar_set("sv_public", "0");
  38         cvar_set("pausable", "1");
  39
  40         title = campaign_shortdesc[0];
  41         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
  42         campaign_message = strzone(strcat("\n\n\n\n\n\n\n\n\n\n^1\n", title, "\n^3\n", wordwrap(campaign_longdesc[0], 50), "\n\n^1press jump to enter the game"));
  43         strunzone(title);
  44 }
  45
  46 string GetMapname();
  47 void() CampaignPostInit =
  48 {
  49         // now some sanity checks
  50         string thismapname, wantedmapname;
  51         thismapname = GetMapname();
  52         wantedmapname = campaign_gametype[0];
  53         wantedmapname = strcat(wantedmapname, "_", campaign_mapname[0]);
  54         if(wantedmapname != thismapname)
  55                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  56         cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
  57         cvar_set("timelimit", "0");
  58 }
  59
  60 void CampaignSaveCvar(string cvarname, float value)
  61 {
  62         float fh;
  63         float len;
  64         string contents;
  65         string l;
  66
  67         registercvar(cvarname, ftos(value));
  68         cvar_set(cvarname, ftos(value));
  69         // note: cvarname must be remembered
  70
  71         fh = fopen("campaign.cfg", FILE_READ);
  72         contents = "";
  73         if(fh >= 0)
  74         {
  75                 while((l = fgets(fh)))
  76                 {
  77                         cvarname = strcat1(cvarname);
  78                         contents = strcat1(contents);
  79                         len = tokenize(l);
  80                         if(len != 3)
  81                                 continue;
  82                         if(argv(0) != "set")
  83                                 continue;
  84                         if(argv(1) == cvarname)
  85                                 continue;
  86                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
  87                 }
  88                 fclose(fh);
  89         }
  90         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
  91         fh = fopen("campaign.cfg", FILE_WRITE);
  92         if(fh >= 0)
  93         {
  94                 fputs(fh, contents);
  95         }
  96         else
  97         {
  98                 error("Cannot write to campaign file");
  99         }
 100 }
 101
 102 void() CampaignPreIntermission =
 103 {
 104         entity head;
 105         float won;
 106         float lost;
 107         local string savevar;
 108
 109         won = 0;
 110
 111         head = findchain(classname, "player");
 112         while(head)
 113         {
 114                 if(clienttype(head) == CLIENTTYPE_REAL)
 115                 {
 116                         if(head.winning)
 117                                 won = won + 1;
 118                         else
 119                                 lost = lost + 1;
 120                 }
 121                 head = head.chain;
 122         }
 123
 124         if(won == 1 && lost == 0 && checkrules_equality == 0)
 125         {
 126                 campaign_won = 1;
 127                 bprint("The current level has been WON.\n");
 128                 // sound!
 129         }
 130         else
 131         {
 132                 campaign_won = 0;
 133                 bprint("The current level has been LOST.\n");
 134                 // sound!
 135         }
 136
 137         if(campaign_won)
 138         {
 139                 if(campaign_entries < 2)
 140                 {
 141                         // I have won
 142                         savevar = strcat("g_campaign", campaign_name, "_won");
 143                         CampaignSaveCvar(savevar, 1);
 144                 }
 145                 else if(campaign_level == cvar(campaign_index_var))
 146                 {
 147                         // advance level
 148                         CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 149                 }
 150         }
 151 }
 152
 153 void() CampaignPostIntermission =
 154 {
 155         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 156
 157         if(campaign_won && campaign_entries < 2)
 158         {
 159                 // last map won!
 160                 localcmd("togglemenu\n");
 161                 CampaignFile_Unload();
 162                 return;
 163         }
 164
 165         CampaignSetup(campaign_won);
 166         CampaignFile_Unload();
 167         strunzone(campaign_message);
 168         strunzone(campaign_index_var);
 169         strunzone(campaign_name);
 170         campaign_name = "";
 171 }
 172
 173
 174
 175 void(float n) CampaignLevelWarp =
 176 {
 177         if(!cvar("sv_cheats"))
 178                 return;
 179         CampaignFile_Unload();
 180         CampaignFile_Load(n, 1);
 181         if(campaign_entries)
 182                 CampaignSetup(0);
 183         else
 184                 error("Sorry, cheater. You are NOT WELCOME.");
 185         CampaignFile_Unload();
 186 }