data/qcsrc/server/bots.qc

   1 .float aistatus;
   2 float AI_STATUS_ROAMING                 = 1;    // Bot is just crawling the map. No enemies at sight
   3 float AI_STATUS_ATTACKING               = 2;    // There are enemies at sight
   4 float AI_STATUS_RUNNING                 = 4;    // Bot is bunny hopping
   5 float AI_STATUS_DANGER_AHEAD    = 8;    // There is lava/slime/trigger_hurt ahead
   6 float AI_STATUS_OUT_JUMPPAD             = 16;   // Trying to get out of a "vertical" jump pad
   7 float AI_STATUS_OUT_WATER               = 32;   // Trying to get out of water
   8
   9 // utilities for path debugging
  10 #ifdef DEBUG_TRACEWALK
  11
  12 float DEBUG_NODE_SUCCESS        = 1;
  13 float DEBUG_NODE_WARNING        = 2;
  14 float DEBUG_NODE_FAIL           = 3;
  15
  16 vector debuglastnode;
  17
  18 void debugresetnodes()
  19 {
  20         debuglastnode = '0 0 0';
  21 }
  22
  23 void debugnode(vector node)
  24 {
  25         if not(self.classname=="player")
  26                 return;
  27
  28         if(debuglastnode=='0 0 0')
  29         {
  30                 debuglastnode = node;
  31                 return;
  32         }
  33
  34         te_lightning2(world, node, debuglastnode);
  35         debuglastnode = node;
  36 }
  37
  38 void debugnodestatus(vector position, float status)
  39 {
  40         vector color;
  41
  42         switch (status)
  43         {
  44                 case DEBUG_NODE_SUCCESS:
  45                         color = '0 15 0';
  46                         break;
  47                 case DEBUG_NODE_WARNING:
  48                         color = '15 15 0';
  49                         break;
  50                 case DEBUG_NODE_FAIL:
  51                         color = '15 0 0';
  52                         break;
  53                 default:
  54                         color = '15 15 15';
  55         }
  56
  57         te_customflash(position, 40,  2, color);
  58 }
  59
  60 #endif
  61
  62 // rough simulation of walking from one point to another to test if a path
  63 // can be traveled, used for waypoint linking and havocbot
  64
  65 vector stepheightvec;
  66 float navigation_testtracewalk;
  67 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
  68 {
  69         local vector org;
  70         local vector move;
  71         local vector dir;
  72         local float dist;
  73         local float totaldist;
  74         local float stepdist;
  75         local float yaw;
  76         local float ignorehazards;
  77         local float swimming;
  78
  79         #ifdef DEBUG_TRACEWALK
  80                 debugresetnodes();
  81                 debugnode(start);
  82         #endif
  83
  84         move = end - start;
  85         move_z = 0;
  86         org = start;
  87         dist = totaldist = vlen(move);
  88         dir = normalize(move);
  89         stepdist = 32;
  90         ignorehazards = FALSE;
  91
  92         // Analyze starting point
  93         traceline(start, start, MOVE_NORMAL, e);
  94         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  95                 ignorehazards = TRUE;
  96         else
  97         {
  98                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  99                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 100                 {
 101                         ignorehazards = TRUE;
 102                         swimming = TRUE;
 103                 }
 104         }
 105         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 106         if (trace_startsolid)
 107         {
 108                 // Bad start
 109                 #ifdef DEBUG_TRACEWALK
 110                         debugnodestatus(start, DEBUG_NODE_FAIL);
 111                 #endif
 112                 return FALSE;
 113         }
 114
 115         // Movement loop
 116         yaw = vectoyaw(move);
 117         move = end - org;
 118         for (;;)
 119         {
 120                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
 121                 {
 122                         // Succeeded
 123                         #ifdef DEBUG_TRACEWALK
 124                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 125                         #endif
 126                         return TRUE;
 127                 }
 128                 #ifdef DEBUG_TRACEWALK
 129                         debugnode(org);
 130                 #endif
 131
 132                 if (dist <= 0)
 133                         break;
 134                 if (stepdist > dist)
 135                         stepdist = dist;
 136                 dist = dist - stepdist;
 137                 traceline(org, org, MOVE_NORMAL, e);
 138                 if (!ignorehazards)
 139                 {
 140                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 141                         {
 142                                 // hazards blocking path
 143                                 #ifdef DEBUG_TRACEWALK
 144                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 145                                 #endif
 146                                 return FALSE;
 147                         }
 148                 }
 149                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 150                 {
 151                         move = normalize(end - org);
 152                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
 153
 154                         #ifdef DEBUG_TRACEWALK
 155                                 debugnode(trace_endpos);
 156                         #endif
 157
 158                         if (trace_fraction < 1)
 159                         {
 160                                 swimming = TRUE;
 161                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 162                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 163                                 {
 164                                                 #ifdef DEBUG_TRACEWALK
 165                                                         debugnode(org);
 166                                                 #endif
 167                                         if(pointcontents(org) == CONTENT_EMPTY)
 168                                                         break;
 169                                 }
 170
 171                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 172                                 {
 173                                         #ifdef DEBUG_TRACEWALK
 174                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 175                                         #endif
 176                                         return FALSE;
 177                                 }
 178                                 continue;
 179
 180                         }
 181                         else
 182                                 org = trace_endpos;
 183                 }
 184                 else
 185                 {
 186                         move = dir * stepdist + org;
 187                         tracebox(org, m1, m2, move, movemode, e);
 188
 189                         #ifdef DEBUG_TRACEWALK
 190                                 debugnode(trace_endpos);
 191                         #endif
 192
 193                         // hit something
 194                         if (trace_fraction < 1)
 195                         {
 196                                 // check if we can walk over this obstacle
 197                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 198                                 if (trace_fraction < 1 || trace_startsolid)
 199                                 {
 200                                         #ifdef DEBUG_TRACEWALK
 201                                                 debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 202                                         #endif
 203
 204                                         // check for doors
 205                                         traceline( org, move, movemode, e);
 206                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 207                                         {
 208                                                 local vector nextmove;
 209                                                 move = trace_endpos;
 210                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 211                                                 {
 212                                                         nextmove = move + (dir * stepdist);
 213                                                         traceline( move, nextmove, movemode, e);
 214                                                         move = nextmove;
 215                                                 }
 216                                         }
 217                                         else
 218                                         {
 219                                                 #ifdef DEBUG_TRACEWALK
 220                                                         debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 221                                                 #endif
 222                                                 return FALSE; // failed
 223                                         }
 224                                 }
 225                                 else
 226                                         move = trace_endpos;
 227                         }
 228                         else
 229                                 move = trace_endpos;
 230
 231                         // trace down from stepheight as far as possible and move there,
 232                         // if this starts in solid we try again without the stepup, and
 233                         // if that also fails we assume it is a wall
 234                         // (this is the same logic as the Quake walkmove function used)
 235                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 236
 237                         // moved successfully
 238                         if(swimming)
 239                         {
 240                                 local float c;
 241                                 c = pointcontents(org + '0 0 1');
 242                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 243                                         swimming = FALSE;
 244                                 else
 245                                         continue;
 246                         }
 247
 248                         org = trace_endpos;
 249                 }
 250         }
 251
 252         // moved but didn't arrive at the intended destination
 253         #ifdef DEBUG_TRACEWALK
 254                 debugnodestatus(org, DEBUG_NODE_FAIL);
 255         #endif
 256
 257         return FALSE;
 258 };
 259
 260
 261 // grenade tracing to decide the best pitch to fire at
 262
 263 entity tracetossent;
 264 entity tracetossfaketarget;
 265
 266 // traces multiple trajectories to find one that will impact the target
 267 // 'end' vector is the place it aims for,
 268 // returns TRUE only if it hit targ (don't target non-solid entities)
 269 vector findtrajectory_velocity;
 270 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
 271 {
 272         local float c, savesolid, shottime;
 273         local vector dir, end, v;
 274         if (shotspeed < 1)
 275                 return FALSE; // could cause division by zero if calculated
 276         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
 277                 return FALSE; // could never hit it
 278         if (!tracetossent)
 279                 tracetossent = spawn();
 280         tracetossent.owner = ignore;
 281         setsize(tracetossent, m1, m2);
 282         savesolid = targ.solid;
 283         targ.solid = SOLID_NOT;
 284         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
 285         v = targ.velocity * shottime + targ.origin;
 286         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
 287         v = trace_endpos;
 288         end = v + (targ.mins + targ.maxs) * 0.5;
 289         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
 290         {
 291                 // out of range
 292                 targ.solid = savesolid;
 293                 return FALSE;
 294         }
 295
 296         if (!tracetossfaketarget)
 297                 tracetossfaketarget = spawn();
 298         tracetossfaketarget.solid = savesolid;
 299         tracetossfaketarget.movetype = targ.movetype;
 300         setmodel(tracetossfaketarget, targ.model); // no low precision
 301         tracetossfaketarget.model = targ.model;
 302         tracetossfaketarget.modelindex = targ.modelindex;
 303         setsize(tracetossfaketarget, targ.mins, targ.maxs);
 304         setorigin(tracetossfaketarget, v);
 305
 306         c = 0;
 307         dir = normalize(end - org);
 308         while (c < 10) // 10 traces
 309         {
 310                 setorigin(tracetossent, org); // reset
 311                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
 312                 tracetoss(tracetossent, ignore); // love builtin functions...
 313                 if (trace_ent == tracetossfaketarget) // done
 314                 {
 315                         targ.solid = savesolid;
 316
 317                         // make it disappear
 318                         tracetossfaketarget.solid = SOLID_NOT;
 319                         tracetossfaketarget.movetype = MOVETYPE_NONE;
 320                         tracetossfaketarget.model = "";
 321                         tracetossfaketarget.modelindex = 0;
 322                         // relink to remove it from physics considerations
 323                         setorigin(tracetossfaketarget, v);
 324
 325                         return TRUE;
 326                 }
 327                 dir_z = dir_z + 0.1; // aim up a little more
 328                 c = c + 1;
 329         }
 330         targ.solid = savesolid;
 331
 332         // make it disappear
 333         tracetossfaketarget.solid = SOLID_NOT;
 334         tracetossfaketarget.movetype = MOVETYPE_NONE;
 335         tracetossfaketarget.model = "";
 336         tracetossfaketarget.modelindex = 0;
 337         // relink to remove it from physics considerations
 338         setorigin(tracetossfaketarget, v);
 339
 340         // leave a valid one even if it won't reach
 341         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
 342         return FALSE;
 343 };
 344
 345
 346
 347 // lag simulation
 348
 349 .void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_func;
 350
 351 // upto 5 queued messages
 352 .float lag1_time;
 353 .float lag1_float1;
 354 .float lag1_float2;
 355 .entity lag1_entity1;
 356 .vector lag1_vec1;
 357 .vector lag1_vec2;
 358 .vector lag1_vec3;
 359 .vector lag1_vec4;
 360
 361 .float lag2_time;
 362 .float lag2_float1;
 363 .float lag2_float2;
 364 .entity lag2_entity1;
 365 .vector lag2_vec1;
 366 .vector lag2_vec2;
 367 .vector lag2_vec3;
 368 .vector lag2_vec4;
 369
 370 .float lag3_time;
 371 .float lag3_float1;
 372 .float lag3_float2;
 373 .entity lag3_entity1;
 374 .vector lag3_vec1;
 375 .vector lag3_vec2;
 376 .vector lag3_vec3;
 377 .vector lag3_vec4;
 378
 379 .float lag4_time;
 380 .float lag4_float1;
 381 .float lag4_float2;
 382 .entity lag4_entity1;
 383 .vector lag4_vec1;
 384 .vector lag4_vec2;
 385 .vector lag4_vec3;
 386 .vector lag4_vec4;
 387
 388 .float lag5_time;
 389 .float lag5_float1;
 390 .float lag5_float2;
 391 .entity lag5_entity1;
 392 .vector lag5_vec1;
 393 .vector lag5_vec2;
 394 .vector lag5_vec3;
 395 .vector lag5_vec4;
 396
 397 void lag_update()
 398 {
 399         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
 400         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
 401         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
 402         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
 403         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
 404 };
 405
 406 float lag_additem(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 407 {
 408         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return TRUE;}
 409         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return TRUE;}
 410         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return TRUE;}
 411         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return TRUE;}
 412         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return TRUE;}
 413         // no room for it (what is the best thing to do here??)
 414         return FALSE;
 415 };
 416
 417
 418 // Random skill system
 419 .float bot_thinkskill;
 420 .float bot_mouseskill;
 421 .float bot_predictionskill;
 422 .float bot_offsetskill;
 423
 424
 425 // spawnfunc_waypoint navigation system
 426
 427 // itemscore = (howmuchmoreIwant / howmuchIcanwant) / itemdistance
 428 // waypointscore = 0.7 / waypointdistance
 429
 430 .entity wp00, wp01, wp02, wp03, wp04, wp05, wp06, wp07;
 431 .entity wp08, wp09, wp10, wp11, wp12, wp13, wp14, wp15;
 432 .entity wp16, wp17, wp18, wp19, wp20, wp21, wp22, wp23, wp24, wp25, wp26, wp27, wp28, wp29, wp30, wp31;
 433 .float wp00mincost, wp01mincost, wp02mincost, wp03mincost, wp04mincost, wp05mincost, wp06mincost, wp07mincost;
 434 .float wp08mincost, wp09mincost, wp10mincost, wp11mincost, wp12mincost, wp13mincost, wp14mincost, wp15mincost;
 435 .float wp16mincost, wp17mincost, wp18mincost, wp19mincost, wp20mincost, wp21mincost, wp22mincost, wp23mincost, wp24mincost, wp25mincost, wp26mincost, wp27mincost, wp28mincost, wp29mincost, wp30mincost, wp31mincost;
 436 .float wpfire, wpcost, wpconsidered;
 437 .float wpisbox;
 438 .float wpflags;
 439 .vector wpnearestpoint;
 440
 441 // stack of current goals (the last one of which may be an item or other
 442 // desirable object, the rest are typically waypoints to reach it)
 443 .entity goalcurrent, goalstack01, goalstack02, goalstack03;
 444 .entity goalstack04, goalstack05, goalstack06, goalstack07;
 445 .entity goalstack08, goalstack09, goalstack10, goalstack11;
 446 .entity goalstack12, goalstack13, goalstack14, goalstack15;
 447 .entity goalstack16, goalstack17, goalstack18, goalstack19;
 448 .entity goalstack20, goalstack21, goalstack22, goalstack23;
 449 .entity goalstack24, goalstack25, goalstack26, goalstack27;
 450 .entity goalstack28, goalstack29, goalstack30, goalstack31;
 451
 452 .entity nearestwaypoint;
 453 .float nearestwaypointtimeout;
 454
 455 // used during navigation_goalrating_begin/end sessions
 456 #define MAX_BESTGOALS 3
 457 float bestgoalswindex;
 458 float bestgoalsrindex;
 459 float navigation_bestrating;
 460 entity navigation_bestgoals[MAX_BESTGOALS];
 461 .float navigation_hasgoals;
 462
 463 /////////////////////////////////////////////////////////////////////////////
 464 // spawnfunc_waypoint management
 465 /////////////////////////////////////////////////////////////////////////////
 466
 467 // waypoints with this flag are not saved, they are automatically generated
 468 // waypoints like jump pads, teleporters, and items
 469 float WAYPOINTFLAG_GENERATED = 8388608;
 470 float WAYPOINTFLAG_ITEM = 4194304;
 471 float WAYPOINTFLAG_TELEPORT = 2097152;
 472 float WAYPOINTFLAG_NORELINK = 1048576;
 473
 474 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 475 void waypoint_addlink(entity from, entity to)
 476 {
 477         local float c;
 478
 479         if (from == to)
 480                 return;
 481         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 482                 return;
 483
 484         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
 485         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
 486         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
 487         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 488         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 489         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 490         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 491         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 492
 493         if (to.wpisbox || from.wpisbox)
 494         {
 495                 // if either is a box we have to find the nearest points on them to
 496                 // calculate the distance properly
 497                 local vector v1, v2, m1, m2;
 498                 v1 = from.origin;
 499                 m1 = to.absmin;
 500                 m2 = to.absmax;
 501                 v1_x = bound(m1_x, v1_x, m2_x);
 502                 v1_y = bound(m1_y, v1_y, m2_y);
 503                 v1_z = bound(m1_z, v1_z, m2_z);
 504                 v2 = to.origin;
 505                 m1 = from.absmin;
 506                 m2 = from.absmax;
 507                 v2_x = bound(m1_x, v2_x, m2_x);
 508                 v2_y = bound(m1_y, v2_y, m2_y);
 509                 v2_z = bound(m1_z, v2_z, m2_z);
 510                 v2 = to.origin;
 511                 c = vlen(v2 - v1);
 512         }
 513         else
 514                 c = vlen(to.origin - from.origin);
 515
 516         if (from.wp31mincost < c) return;
 517         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 518         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 519         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 520         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 521         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 522         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 523         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 524         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 525         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 526         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 527         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 528         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 529         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 530         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 531         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 532         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 533         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 534         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 535         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 536         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 537         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 538         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 539         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 540         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 541         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 542         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 543         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 544         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 545         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 546         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 547         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 548         from.wp00 = to;from.wp00mincost = c;return;
 549 };
 550
 551 // fields you can query using prvm_global server to get some statistics about waypoint linking culling
 552 float relink_total, relink_walkculled, relink_pvsculled, relink_lengthculled;
 553
 554 // relink this spawnfunc_waypoint
 555 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 556 // (SLOW!)
 557 void waypoint_think()
 558 {
 559         local entity e;
 560         local vector sv, sm1, sm2, ev, em1, em2, dv;
 561         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 562         sm1 = self.origin + self.mins;
 563         sm2 = self.origin + self.maxs;
 564         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 565         for(e = world; (e = find(e, classname, "waypoint")); )
 566         {
 567                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 568                 {
 569                         waypoint_addlink(self, e);
 570                         waypoint_addlink(e, self);
 571                 }
 572                 else
 573                 {
 574                         ++relink_total;
 575                         if(!checkpvs(self.origin, e))
 576                         {
 577                                 ++relink_pvsculled;
 578                                 continue;
 579                         }
 580                         sv = e.origin;
 581                         sv_x = bound(sm1_x, sv_x, sm2_x);
 582                         sv_y = bound(sm1_y, sv_y, sm2_y);
 583                         sv_z = bound(sm1_z, sv_z, sm2_z);
 584                         ev = self.origin;
 585                         em1 = e.origin + e.mins;
 586                         em2 = e.origin + e.maxs;
 587                         ev_x = bound(em1_x, ev_x, em2_x);
 588                         ev_y = bound(em1_y, ev_y, em2_y);
 589                         ev_z = bound(em1_z, ev_z, em2_z);
 590                         dv = ev - sv;
 591                         dv_z = 0;
 592                         if (vlen(dv) >= 1050) // max search distance in XY
 593                         {
 594                                 ++relink_lengthculled;
 595                                 continue;
 596                         }
 597                         navigation_testtracewalk = 0;
 598                         if (!self.wpisbox)
 599                         {
 600                                 tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 601                                 if (!trace_startsolid)
 602                                 {
 603                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 604                                         sv = trace_endpos + '0 0 1';
 605                                 }
 606                         }
 607                         if (!e.wpisbox)
 608                         {
 609                                 tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 610                                 if (!trace_startsolid)
 611                                 {
 612                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 613                                         ev = trace_endpos + '0 0 1';
 614                                 }
 615                         }
 616                         //traceline(self.origin, e.origin, FALSE, world);
 617                         //if (trace_fraction == 1)
 618                         if (!self.wpisbox && tracewalk(self, sv, PL_MIN, PL_MAX, ev, MOVE_NOMONSTERS))
 619                                 waypoint_addlink(self, e);
 620                         else
 621                                 relink_walkculled += 0.5;
 622                         if (!e.wpisbox && tracewalk(e, ev, PL_MIN, PL_MAX, sv, MOVE_NOMONSTERS))
 623                                 waypoint_addlink(e, self);
 624                         else
 625                                 relink_walkculled += 0.5;
 626                 }
 627         }
 628         navigation_testtracewalk = 0;
 629 };
 630
 631 void waypoint_clearlinks(entity wp)
 632 {
 633         // clear links to other waypoints
 634         local float f;
 635         f = 10000000;
 636         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 637         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 638         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 639         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 640 };
 641
 642 // tell a spawnfunc_waypoint to relink
 643 void waypoint_schedulerelink(entity wp)
 644 {
 645         if (wp == world)
 646                 return;
 647         // TODO: add some sort of visible box in edit mode for box waypoints
 648         if (cvar("g_waypointeditor"))
 649         {
 650                 local vector m1, m2;
 651                 m1 = wp.mins;
 652                 m2 = wp.maxs;
 653                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 654                 setsize(wp, m1, m2);
 655                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 656                         wp.colormod = '1 0 0';
 657                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 658                         wp.colormod = '1 1 0';
 659                 else
 660                         wp.colormod = '1 1 1';
 661         }
 662         else
 663                 wp.model = "";
 664         wp.wpisbox = vlen(wp.size) > 0;
 665         wp.enemy = world;
 666         wp.owner = world;
 667         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 668                 waypoint_clearlinks(wp);
 669         // schedule an actual relink on next frame
 670         wp.think = waypoint_think;
 671         wp.nextthink = time;
 672         wp.effects = EF_LOWPRECISION;
 673 }
 674
 675 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 676 // them back to it as well
 677 // (suitable for spawnfunc_waypoint editor)
 678 entity waypoint_spawn(vector m1, vector m2, float f)
 679 {
 680         local entity w;
 681         local vector org;
 682         w = find(world, classname, "waypoint");
 683         while (w)
 684         {
 685                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 686                 if (boxesoverlap(m1, m2, w.absmin, w.absmax))
 687                         return w;
 688                 w = find(w, classname, "waypoint");
 689         }
 690         w = spawn();
 691         w.classname = "waypoint";
 692         w.wpflags = f;
 693         setorigin(w, (m1 + m2) * 0.5);
 694         setsize(w, m1 - w.origin, m2 - w.origin);
 695         if (vlen(w.size) > 0)
 696                 w.wpisbox = TRUE;
 697
 698         if(!(f & WAYPOINTFLAG_GENERATED))
 699         if(!w.wpisbox)
 700         {
 701                 traceline(w.origin + '0 0 1', w.origin + PL_MIN_z * '0 0 1' - '0 0 1', MOVE_NOMONSTERS, w);
 702                 if (trace_fraction < 1)
 703                         setorigin(w, trace_endpos - PL_MIN_z * '0 0 1');
 704
 705                 // check if the start position is stuck
 706                 tracebox(w.origin, PL_MIN + '-1 -1 -1', PL_MAX + '1 1 1', w.origin, MOVE_NOMONSTERS, w);
 707                 if (trace_startsolid)
 708                 {
 709                         org = w.origin + '0 0 26';
 710                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 711                         if(trace_startsolid)
 712                         {
 713                                 org = w.origin + '2 2 2';
 714                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 715                                 if(trace_startsolid)
 716                                 {
 717                                         org = w.origin + '-2 -2 2';
 718                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 719                                         if(trace_startsolid)
 720                                         {
 721                                                 org = w.origin + '-2 2 2';
 722                                                 tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 723                                                 if(trace_startsolid)
 724                                                 {
 725                                                         org = w.origin + '2 -2 2';
 726                                                         tracebox(org, PL_MIN, PL_MAX, w.origin, MOVE_WORLDONLY, w);
 727                                                         if(trace_startsolid)
 728                                                         {
 729                                                                 // this WP is in solid, refuse it
 730                                                                 dprint("Killed a waypoint that was stuck in solid at ", vtos(org), "\n");
 731                                                                 remove(w);
 732                                                                 return world;
 733                                                         }
 734                                                 }
 735                                         }
 736                                 }
 737                         }
 738                         setorigin(w, org * 0.05 + trace_endpos * 0.95); // don't trust the trace fully
 739                 }
 740
 741                 tracebox(w.origin, PL_MIN, PL_MAX, w.origin - '0 0 128', MOVE_WORLDONLY, w);
 742                 if(trace_startsolid)
 743                 {
 744                         dprint("Killed a waypoint that was stuck in solid ", vtos(w.origin), "\n");
 745                         remove(w);
 746                         return world;
 747                 }
 748                 if (!trace_inwater)
 749                 {
 750                         if(trace_fraction == 1)
 751                         {
 752                                 dprint("Killed a waypoint that was stuck in air at ", vtos(w.origin), "\n");
 753                                 remove(w);
 754                                 return world;
 755                         }
 756                         trace_endpos_z += 0.1; // don't trust the trace fully
 757 //                      dprint("Moved waypoint at ", vtos(w.origin), " by ", ftos(vlen(w.origin - trace_endpos)));
 758 //                      dprint(" direction: ", vtos((trace_endpos - w.origin)), "\n");
 759                         setorigin(w, trace_endpos);
 760                 }
 761         }
 762
 763         waypoint_clearlinks(w);
 764         //waypoint_schedulerelink(w);
 765         return w;
 766 };
 767
 768 // spawnfunc_waypoint map entity
 769 void spawnfunc_waypoint()
 770 {
 771         setorigin(self, self.origin);
 772         // schedule a relink after other waypoints have had a chance to spawn
 773         waypoint_clearlinks(self);
 774         //waypoint_schedulerelink(self);
 775 };
 776
 777 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 778 void waypoint_remove(entity e)
 779 {
 780         // tell all linked waypoints that they need to relink
 781         waypoint_schedulerelink(e.wp00);
 782         waypoint_schedulerelink(e.wp01);
 783         waypoint_schedulerelink(e.wp02);
 784         waypoint_schedulerelink(e.wp03);
 785         waypoint_schedulerelink(e.wp04);
 786         waypoint_schedulerelink(e.wp05);
 787         waypoint_schedulerelink(e.wp06);
 788         waypoint_schedulerelink(e.wp07);
 789         waypoint_schedulerelink(e.wp08);
 790         waypoint_schedulerelink(e.wp09);
 791         waypoint_schedulerelink(e.wp10);
 792         waypoint_schedulerelink(e.wp11);
 793         waypoint_schedulerelink(e.wp12);
 794         waypoint_schedulerelink(e.wp13);
 795         waypoint_schedulerelink(e.wp14);
 796         waypoint_schedulerelink(e.wp15);
 797         waypoint_schedulerelink(e.wp16);
 798         waypoint_schedulerelink(e.wp17);
 799         waypoint_schedulerelink(e.wp18);
 800         waypoint_schedulerelink(e.wp19);
 801         waypoint_schedulerelink(e.wp20);
 802         waypoint_schedulerelink(e.wp21);
 803         waypoint_schedulerelink(e.wp22);
 804         waypoint_schedulerelink(e.wp23);
 805         waypoint_schedulerelink(e.wp24);
 806         waypoint_schedulerelink(e.wp25);
 807         waypoint_schedulerelink(e.wp26);
 808         waypoint_schedulerelink(e.wp27);
 809         waypoint_schedulerelink(e.wp28);
 810         waypoint_schedulerelink(e.wp29);
 811         waypoint_schedulerelink(e.wp30);
 812         waypoint_schedulerelink(e.wp31);
 813         // and now remove the spawnfunc_waypoint
 814         remove(e);
 815 };
 816
 817 // empties the map of waypoints
 818 void waypoint_removeall()
 819 {
 820         local entity head, next;
 821         head = findchain(classname, "waypoint");
 822         while (head)
 823         {
 824                 next = head.chain;
 825                 remove(head);
 826                 head = next;
 827         }
 828 };
 829
 830 // tell all waypoints to relink
 831 // (is this useful at all?)
 832 void waypoint_schedulerelinkall()
 833 {
 834         local entity head;
 835         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 836         head = findchain(classname, "waypoint");
 837         while (head)
 838         {
 839                 waypoint_schedulerelink(head);
 840                 head = head.chain;
 841         }
 842 };
 843
 844 // Load waypoint links from file
 845 float botframe_cachedwaypointlinks;
 846 float waypoint_load_links()
 847 {
 848         local string filename, s;
 849         local float file, tokens, c, found;
 850         local entity wp_from, wp_to;
 851         local vector wp_to_pos, wp_from_pos;
 852         filename = strcat("maps/", mapname);
 853         filename = strcat(filename, ".waypoints.cache");
 854         file = fopen(filename, FILE_READ);
 855
 856         if (file < 0)
 857         {
 858                 dprint("waypoint links load from ");
 859                 dprint(filename);
 860                 dprint(" failed\n");
 861                 return FALSE;
 862         }
 863
 864         while (1)
 865         {
 866                 s = fgets(file);
 867                 if (!s)
 868                         break;
 869
 870                 tokens = tokenizebyseparator(s, "*");
 871
 872                 if (tokens!=2)
 873                 {
 874                         // bad file format
 875                         fclose(file);
 876                         return FALSE;
 877                 }
 878
 879                 wp_from_pos     = stov(argv(0));
 880                 wp_to_pos       = stov(argv(1));
 881
 882                 // Search "from" waypoint
 883                 if(wp_from.origin!=wp_from_pos)
 884                 {
 885                         wp_from = findradius(wp_from_pos, 1);
 886                         found = FALSE;
 887                         while(wp_from)
 888                         {
 889                                 if(vlen(wp_from.origin-wp_from_pos)<1)
 890                                 if(wp_from.classname == "waypoint")
 891                                 {
 892                                         found = TRUE;
 893                                         break;
 894                                 }
 895                                 wp_from = wp_from.chain;
 896                         }
 897
 898                         if(!found)
 899                         {
 900                                 // can't find that waypoint
 901                                 fclose(file);
 902                                 return FALSE;
 903                         }
 904                 }
 905
 906                 // Search "to" waypoint
 907                 wp_to = findradius(wp_to_pos, 1);
 908                 found = FALSE;
 909                 while(wp_to)
 910                 {
 911                         if(vlen(wp_to.origin-wp_to_pos)<1)
 912                         if(wp_to.classname == "waypoint")
 913                         {
 914                                 found = TRUE;
 915                                 break;
 916                         }
 917                         wp_to = wp_to.chain;
 918                 }
 919
 920                 if(!found)
 921                 {
 922                         // can't find that waypoint
 923                         fclose(file);
 924                         return FALSE;
 925                 }
 926
 927                 ++c;
 928                 waypoint_addlink(wp_from, wp_to);
 929         }
 930
 931         fclose(file);
 932
 933         dprint("loaded ");
 934         dprint(ftos(c));
 935         dprint(" waypoint links from maps/");
 936         dprint(mapname);
 937         dprint(".waypoints.cache\n");
 938
 939         botframe_cachedwaypointlinks = TRUE;
 940         return TRUE;
 941 };
 942
 943
 944 // Save all waypoint links to a file
 945 void waypoint_save_links()
 946 {
 947         local string filename, s;
 948         local float file, c, i;
 949         local entity w, link;
 950         filename = strcat("maps/", mapname);
 951         filename = strcat(filename, ".waypoints.cache");
 952         file = fopen(filename, FILE_WRITE);
 953         if (file < 0)
 954         {
 955                 print("waypoint links save to ");
 956                 print(filename);
 957                 print(" failed\n");
 958         }
 959         c = 0;
 960         w = findchain(classname, "waypoint");
 961         while (w)
 962         {
 963                 for(i=0;i<32;++i)
 964                 {
 965                         // :S
 966                         switch(i)
 967                         {
 968                                 //      for i in $(seq -w 0 31); do echo "case $i:link = w.wp$i; break;"; done;
 969                                 case 00:link = w.wp00; break;
 970                                 case 01:link = w.wp01; break;
 971                                 case 02:link = w.wp02; break;
 972                                 case 03:link = w.wp03; break;
 973                                 case 04:link = w.wp04; break;
 974                                 case 05:link = w.wp05; break;
 975                                 case 06:link = w.wp06; break;
 976                                 case 07:link = w.wp07; break;
 977                                 case 08:link = w.wp08; break;
 978                                 case 09:link = w.wp09; break;
 979                                 case 10:link = w.wp10; break;
 980                                 case 11:link = w.wp11; break;
 981                                 case 12:link = w.wp12; break;
 982                                 case 13:link = w.wp13; break;
 983                                 case 14:link = w.wp14; break;
 984                                 case 15:link = w.wp15; break;
 985                                 case 16:link = w.wp16; break;
 986                                 case 17:link = w.wp17; break;
 987                                 case 18:link = w.wp18; break;
 988                                 case 19:link = w.wp19; break;
 989                                 case 20:link = w.wp20; break;
 990                                 case 21:link = w.wp21; break;
 991                                 case 22:link = w.wp22; break;
 992                                 case 23:link = w.wp23; break;
 993                                 case 24:link = w.wp24; break;
 994                                 case 25:link = w.wp25; break;
 995                                 case 26:link = w.wp26; break;
 996                                 case 27:link = w.wp27; break;
 997                                 case 28:link = w.wp28; break;
 998                                 case 29:link = w.wp29; break;
 999                                 case 30:link = w.wp30; break;
1000                                 case 31:link = w.wp31; break;
1001                         }
1002
1003                         if(link==world)
1004                                 continue;
1005
1006                         s = strcat(vtos(w.origin), "*", vtos(link.origin), "\n");
1007                         fputs(file, s);
1008                         ++c;
1009                 }
1010                 w = w.chain;
1011         }
1012         fclose(file);
1013         botframe_cachedwaypointlinks = TRUE;
1014
1015         print("saved ");
1016         print(ftos(c));
1017         print(" waypoints links to maps/");
1018         print(mapname);
1019         print(".waypoints.cache\n");
1020 };
1021
1022 // save waypoints to gamedir/data/maps/mapname.waypoints
1023 void waypoint_saveall()
1024 {
1025         local string filename, s;
1026         local float file, c;
1027         local entity w;
1028         filename = strcat("maps/", mapname);
1029         filename = strcat(filename, ".waypoints");
1030         file = fopen(filename, FILE_WRITE);
1031         if (file >= 0)
1032         {
1033                 c = 0;
1034                 w = findchain(classname, "waypoint");
1035                 while (w)
1036                 {
1037                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
1038                         {
1039                                 s = strcat(vtos(w.origin + w.mins), "\n");
1040                                 s = strcat(s, vtos(w.origin + w.maxs));
1041                                 s = strcat(s, "\n");
1042                                 s = strcat(s, ftos(w.wpflags));
1043                                 s = strcat(s, "\n");
1044                                 fputs(file, s);
1045                                 c = c + 1;
1046                         }
1047                         w = w.chain;
1048                 }
1049                 fclose(file);
1050                 bprint("saved ");
1051                 bprint(ftos(c));
1052                 bprint(" waypoints to maps/");
1053                 bprint(mapname);
1054                 bprint(".waypoints\n");
1055         }
1056         else
1057         {
1058                 bprint("waypoint save to ");
1059                 bprint(filename);
1060                 bprint(" failed\n");
1061         }
1062         waypoint_save_links();
1063 };
1064
1065 // load waypoints from file
1066 float waypoint_loadall()
1067 {
1068         local string filename, s;
1069         local float file, cwp, cwb, fl;
1070         local vector m1, m2;
1071         cwp = 0;
1072         cwb = 0;
1073         filename = strcat("maps/", mapname);
1074         filename = strcat(filename, ".waypoints");
1075         file = fopen(filename, FILE_READ);
1076         if (file >= 0)
1077         {
1078                 while (1)
1079                 {
1080                         s = fgets(file);
1081                         if (!s)
1082                                 break;
1083                         m1 = stov(s);
1084                         s = fgets(file);
1085                         if (!s)
1086                                 break;
1087                         m2 = stov(s);
1088                         s = fgets(file);
1089                         if (!s)
1090                                 break;
1091                         fl = stof(s);
1092                         waypoint_spawn(m1, m2, fl);
1093                         if (m1 == m2)
1094                                 cwp = cwp + 1;
1095                         else
1096                                 cwb = cwb + 1;
1097                 }
1098                 fclose(file);
1099                 dprint("loaded ");
1100                 dprint(ftos(cwp));
1101                 dprint(" waypoints and ");
1102                 dprint(ftos(cwb));
1103                 dprint(" wayboxes from maps/");
1104                 dprint(mapname);
1105                 dprint(".waypoints\n");
1106         }
1107         else
1108         {
1109                 dprint("waypoint load from ");
1110                 dprint(filename);
1111                 dprint(" failed\n");
1112         }
1113         return cwp + cwb;
1114 };
1115
1116 void waypoint_spawnforitem(entity e)
1117 {
1118         local entity w;
1119         local vector org;
1120
1121         if(!bot_waypoints_for_items)
1122                 return;
1123
1124         // Center of entity
1125         org = e.origin + (e.mins + e.maxs) * 0.5;
1126
1127         // Calculate the altitude where the waypoint will be placed
1128         traceline(e.origin, e.origin + '0 0 -65535', TRUE, e);
1129         if(e.origin_z + e.mins_z - trace_endpos_z < PL_MAX_z - PL_MIN_z + 10)
1130                 org_z = trace_endpos_z + PL_MAX_z - PL_MIN_z;
1131         else
1132                 org_z = e.origin_z;
1133
1134         e.nearestwaypointtimeout = time + 1000000000;
1135         // don't spawn an item spawnfunc_waypoint if it already exists
1136         w = findchain(classname, "waypoint");
1137         while (w)
1138         {
1139                 if (w.wpisbox)
1140                 {
1141                         if (boxesoverlap(org, org, w.absmin, w.absmax))
1142                         {
1143                                 e.nearestwaypoint = w;
1144                                 return;
1145                         }
1146                 }
1147                 else
1148                 {
1149                         if (vlen(w.origin - org) < 16)
1150                         {
1151                                 e.nearestwaypoint = w;
1152                                 return;
1153                         }
1154                 }
1155                 w = w.chain;
1156         }
1157         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1158 };
1159
1160 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1161 {
1162         local entity w;
1163         local entity dw;
1164         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
1165         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
1166         // one way link to the destination
1167         w.wp00 = dw;
1168         w.wp00mincost = timetaken; // this is just for jump pads
1169         // the teleporter's nearest spawnfunc_waypoint is this one
1170         // (teleporters are not goals, so this is probably useless)
1171         e.nearestwaypoint = w;
1172         e.nearestwaypointtimeout = time + 1000000000;
1173 };
1174
1175
1176
1177
1178
1179 /////////////////////////////////////////////////////////////////////////////
1180 // goal stack
1181 /////////////////////////////////////////////////////////////////////////////
1182
1183 // completely empty the goal stack, used when deciding where to go
1184 void navigation_clearroute()
1185 {
1186         self.goalcurrent = world;
1187         self.goalstack01 = world;
1188         self.goalstack02 = world;
1189         self.goalstack03 = world;
1190         self.goalstack04 = world;
1191         self.goalstack05 = world;
1192         self.goalstack06 = world;
1193         self.goalstack07 = world;
1194         self.goalstack08 = world;
1195         self.goalstack09 = world;
1196         self.goalstack10 = world;
1197         self.goalstack11 = world;
1198         self.goalstack12 = world;
1199         self.goalstack13 = world;
1200         self.goalstack14 = world;
1201         self.goalstack15 = world;
1202         self.goalstack16 = world;
1203         self.goalstack17 = world;
1204         self.goalstack18 = world;
1205         self.goalstack19 = world;
1206         self.goalstack20 = world;
1207         self.goalstack21 = world;
1208         self.goalstack22 = world;
1209         self.goalstack23 = world;
1210         self.goalstack24 = world;
1211         self.goalstack25 = world;
1212         self.goalstack26 = world;
1213         self.goalstack27 = world;
1214         self.goalstack28 = world;
1215         self.goalstack29 = world;
1216         self.goalstack30 = world;
1217         self.goalstack31 = world;
1218 };
1219
1220 // add a new goal at the beginning of the stack
1221 // (in other words: add a new prerequisite before going to the later goals)
1222 void navigation_pushroute(entity e)
1223 {
1224         self.goalstack31 = self.goalstack30;
1225         self.goalstack30 = self.goalstack29;
1226         self.goalstack29 = self.goalstack28;
1227         self.goalstack28 = self.goalstack27;
1228         self.goalstack27 = self.goalstack26;
1229         self.goalstack26 = self.goalstack25;
1230         self.goalstack25 = self.goalstack24;
1231         self.goalstack24 = self.goalstack23;
1232         self.goalstack23 = self.goalstack22;
1233         self.goalstack22 = self.goalstack21;
1234         self.goalstack21 = self.goalstack20;
1235         self.goalstack20 = self.goalstack19;
1236         self.goalstack19 = self.goalstack18;
1237         self.goalstack18 = self.goalstack17;
1238         self.goalstack17 = self.goalstack16;
1239         self.goalstack16 = self.goalstack15;
1240         self.goalstack15 = self.goalstack14;
1241         self.goalstack14 = self.goalstack13;
1242         self.goalstack13 = self.goalstack12;
1243         self.goalstack12 = self.goalstack11;
1244         self.goalstack11 = self.goalstack10;
1245         self.goalstack10 = self.goalstack09;
1246         self.goalstack09 = self.goalstack08;
1247         self.goalstack08 = self.goalstack07;
1248         self.goalstack07 = self.goalstack06;
1249         self.goalstack06 = self.goalstack05;
1250         self.goalstack05 = self.goalstack04;
1251         self.goalstack04 = self.goalstack03;
1252         self.goalstack03 = self.goalstack02;
1253         self.goalstack02 = self.goalstack01;
1254         self.goalstack01 = self.goalcurrent;
1255         self.goalcurrent = e;
1256 };
1257
1258 // remove first goal from stack
1259 // (in other words: remove a prerequisite for reaching the later goals)
1260 // (used when a spawnfunc_waypoint is reached)
1261 void navigation_poproute()
1262 {
1263         self.goalcurrent = self.goalstack01;
1264         self.goalstack01 = self.goalstack02;
1265         self.goalstack02 = self.goalstack03;
1266         self.goalstack03 = self.goalstack04;
1267         self.goalstack04 = self.goalstack05;
1268         self.goalstack05 = self.goalstack06;
1269         self.goalstack06 = self.goalstack07;
1270         self.goalstack07 = self.goalstack08;
1271         self.goalstack08 = self.goalstack09;
1272         self.goalstack09 = self.goalstack10;
1273         self.goalstack10 = self.goalstack11;
1274         self.goalstack11 = self.goalstack12;
1275         self.goalstack12 = self.goalstack13;
1276         self.goalstack13 = self.goalstack14;
1277         self.goalstack14 = self.goalstack15;
1278         self.goalstack15 = self.goalstack16;
1279         self.goalstack16 = self.goalstack17;
1280         self.goalstack17 = self.goalstack18;
1281         self.goalstack18 = self.goalstack19;
1282         self.goalstack19 = self.goalstack20;
1283         self.goalstack20 = self.goalstack21;
1284         self.goalstack21 = self.goalstack22;
1285         self.goalstack22 = self.goalstack23;
1286         self.goalstack23 = self.goalstack24;
1287         self.goalstack24 = self.goalstack25;
1288         self.goalstack25 = self.goalstack26;
1289         self.goalstack26 = self.goalstack27;
1290         self.goalstack27 = self.goalstack28;
1291         self.goalstack28 = self.goalstack29;
1292         self.goalstack29 = self.goalstack30;
1293         self.goalstack30 = self.goalstack31;
1294         self.goalstack31 = world;
1295 };
1296
1297 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
1298 entity navigation_findnearestwaypoint(entity player, float walkfromwp)
1299 {
1300         local entity waylist, w, best;
1301         local float dist, bestdist;
1302         local vector v, org, pm1, pm2;
1303         pm1 = player.origin + PL_MIN;
1304         pm2 = player.origin + PL_MAX;
1305         waylist = findchain(classname, "waypoint");
1306         // do two scans, because box test is cheaper
1307         w = waylist;
1308         while (w)
1309         {
1310                 // if object is touching spawnfunc_waypoint
1311                 if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
1312                         return w;
1313                 w = w.chain;
1314         }
1315
1316         org = player.origin + (player.mins_z - PL_MIN_z) * '0 0 1';
1317         if(player.tag_entity)
1318                 org = org + player.tag_entity.origin;
1319         if (navigation_testtracewalk)
1320                 te_plasmaburn(org);
1321         best = world;
1322         bestdist = 1050;
1323
1324         // box check failed, try walk
1325         w = waylist;
1326         while (w)
1327         {
1328                 // if object can walk from spawnfunc_waypoint
1329                 if (w.wpisbox)
1330                 {
1331                         local vector wm1, wm2;
1332                         wm1 = w.origin + w.mins;
1333                         wm2 = w.origin + w.maxs;
1334                         v_x = bound(wm1_x, org_x, wm2_x);
1335                         v_y = bound(wm1_y, org_y, wm2_y);
1336                         v_z = bound(wm1_z, org_z, wm2_z);
1337                 }
1338                 else
1339                         v = w.origin;
1340                 dist = vlen(v - org);
1341                 if (bestdist > dist)
1342                 {
1343                         if (walkfromwp)
1344                         {
1345                                 traceline(v, org, TRUE, player);
1346                                 if (trace_fraction == 1)
1347                                 if (tracewalk(player, v, PL_MIN, PL_MAX, org, MOVE_NORMAL))
1348                                 {
1349                                         bestdist = dist;
1350                                         best = w;
1351                                 }
1352                         }
1353                         else
1354                         {
1355                                 traceline(v, org, TRUE, player);
1356                                 if (trace_fraction == 1)
1357                                 if (tracewalk(player, org, PL_MIN, PL_MAX, v, MOVE_NORMAL))
1358                                 {
1359                                         bestdist = dist;
1360                                         best = w;
1361                                 }
1362                         }
1363                 }
1364                 w = w.chain;
1365         }
1366         return best;
1367 }
1368
1369 // finds the waypoints near the bot initiating a navigation query
1370 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
1371 {
1372         local entity head;
1373         local vector v, m1, m2, diff;
1374         local float c;
1375 //      navigation_testtracewalk = TRUE;
1376         c = 0;
1377         head = waylist;
1378         while (head)
1379         {
1380                 if (!head.wpconsidered)
1381                 {
1382                         if (head.wpisbox)
1383                         {
1384                                 m1 = head.origin + head.mins;
1385                                 m2 = head.origin + head.maxs;
1386                                 v = self.origin;
1387                                 v_x = bound(m1_x, v_x, m2_x);
1388                                 v_y = bound(m1_y, v_y, m2_y);
1389                                 v_z = bound(m1_z, v_z, m2_z);
1390                         }
1391                         else
1392                                 v = head.origin;
1393                         diff = v - self.origin;
1394                         diff_z = max(0, diff_z);
1395                         if (vlen(diff) < maxdist)
1396                         {
1397                                 head.wpconsidered = TRUE;
1398                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, MOVE_NORMAL))
1399                                 {
1400                                         head.wpnearestpoint = v;
1401                                         head.wpcost = vlen(v - self.origin) + head.dmg;
1402                                         head.wpfire = 1;
1403                                         head.enemy = world;
1404                                         c = c + 1;
1405                                 }
1406                         }
1407                 }
1408                 head = head.chain;
1409         }
1410         //navigation_testtracewalk = FALSE;
1411         return c;
1412 }
1413
1414 // updates a path link if a spawnfunc_waypoint link is better than the current one
1415 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
1416 {
1417         local vector m1;
1418         local vector m2;
1419         local vector v;
1420         if (wp.wpisbox)
1421         {
1422                 m1 = wp.absmin;
1423                 m2 = wp.absmax;
1424                 v_x = bound(m1_x, p_x, m2_x);
1425                 v_y = bound(m1_y, p_y, m2_y);
1426                 v_z = bound(m1_z, p_z, m2_z);
1427         }
1428         else
1429                 v = wp.origin;
1430         cost2 = cost2 + vlen(v);
1431         if (wp.wpcost > cost2)
1432         {
1433                 wp.wpcost = cost2;
1434                 wp.enemy = w;
1435                 wp.wpfire = 1;
1436                 wp.wpnearestpoint = v;
1437         }
1438 };
1439
1440 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
1441 void navigation_markroutes()
1442 {
1443         local entity w, wp, waylist;
1444         local float searching, cost, cost2;
1445         local vector p;
1446         w = waylist = findchain(classname, "waypoint");
1447         while (w)
1448         {
1449                 w.wpconsidered = FALSE;
1450                 w.wpnearestpoint = '0 0 0';
1451                 w.wpcost = 10000000;
1452                 w.wpfire = 0;
1453                 w.enemy = world;
1454                 w = w.chain;
1455         }
1456
1457         // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
1458         // as this search is expensive we will use lower values if the bot is on the air
1459         local float i, increment, maxdistance;
1460         if(self.flags & FL_ONGROUND)
1461         {
1462                 increment = 750;
1463                 maxdistance = 50000;
1464         }
1465         else
1466         {
1467                 increment = 500;
1468                 maxdistance = 1500;
1469         }
1470
1471         for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
1472
1473         searching = TRUE;
1474         while (searching)
1475         {
1476                 searching = FALSE;
1477                 w = waylist;
1478                 while (w)
1479                 {
1480                         if (w.wpfire)
1481                         {
1482                                 searching = TRUE;
1483                                 w.wpfire = 0;
1484                                 cost = w.wpcost;
1485                                 p = w.wpnearestpoint;
1486                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1487                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1488                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1489                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1490                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1491                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1492                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1493                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1494                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1495                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1496                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1497                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1498                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1499                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1500                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1501                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1502                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1503                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1504                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1505                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1506                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1507                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1508                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1509                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1510                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1511                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1512                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1513                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1514                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1515                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1516                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1517                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1518                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1519                         }
1520                         w = w.chain;
1521                 }
1522         }
1523 };
1524
1525 void navigation_bestgoals_reset()
1526 {
1527         local float i;
1528
1529         bestgoalswindex = 0;
1530         bestgoalsrindex = 0;
1531
1532         for(i=0;i>MAX_BESTGOALS-1;++i)
1533         {
1534                 navigation_bestgoals[i] = world;
1535         }
1536 }
1537
1538 void navigation_add_bestgoal(entity goal)
1539 {
1540         local float i;
1541
1542         if(bestgoalsrindex>0)
1543         {
1544                 ++bestgoalsrindex;
1545
1546                 if(bestgoalsrindex==MAX_BESTGOALS)
1547                         bestgoalsrindex = 0;
1548         }
1549
1550         if(bestgoalswindex==MAX_BESTGOALS)
1551         {
1552                 bestgoalswindex=0;
1553                 if(bestgoalsrindex==0)
1554                         bestgoalsrindex=1;
1555         }
1556
1557         navigation_bestgoals[bestgoalswindex] = goal;
1558
1559         ++bestgoalswindex;
1560 }
1561
1562 entity navigation_get_bestgoal()
1563 {
1564         local float i;
1565         local entity ent;
1566
1567         ent = navigation_bestgoals[bestgoalsrindex];
1568         navigation_bestgoals[bestgoalsrindex] = world;
1569
1570         ++bestgoalsrindex;
1571
1572         if(bestgoalsrindex==MAX_BESTGOALS)
1573                 bestgoalsrindex = 0;
1574
1575         return ent;
1576 }
1577
1578 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1579 .void() havocbot_role;
1580 void() havocbot_role_ctf_offense;
1581 void navigation_routerating(entity e, float f, float rangebias)
1582 {
1583         if (!e)
1584                 return;
1585         //te_wizspike(e.origin);
1586         //bprint(etos(e));
1587         //bprint("\n");
1588         // update the cached spawnfunc_waypoint link on a dynamic item entity
1589         if (time > e.nearestwaypointtimeout)
1590         {
1591                 e.nearestwaypoint = navigation_findnearestwaypoint(e, TRUE);
1592                 e.nearestwaypointtimeout = time + random() * 3 + 5;
1593         }
1594         //dprint(e.classname, " ", ftos(f));
1595         //dprint("-- checking ", e.classname, " (with cost ", ftos(e.nearestwaypoint.wpcost), ")\n");
1596         if (e.nearestwaypoint)
1597         if (e.nearestwaypoint.wpcost < 10000000)
1598         {
1599                 //te_wizspike(e.nearestwaypoint.wpnearestpoint);
1600                 //dprint(e.classname, " ", ftos(f), "/(1+", ftos((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint))), "/", ftos(rangebias), ") = ");
1601                 f = f * rangebias / (rangebias + (e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint)));
1602                 //if (self.havocbot_role == havocbot_role_ctf_offense)
1603                 //      dprint("-- considering ", e.classname, " (with rating ", ftos(f), ")\n");
1604                 //dprint(ftos(f));
1605                 if (navigation_bestrating < f)
1606                 {
1607                         navigation_bestrating = f;
1608                         navigation_add_bestgoal(e);
1609                 }
1610         }
1611         //dprint("\n");
1612 };
1613
1614 // adds an item to the the goal stack with the path to a given item
1615 float navigation_routetogoal(entity e, vector startposition)
1616 {
1617         self.goalentity = e;
1618
1619         // if there is no goal, just exit
1620         if (!e)
1621                 return FALSE;
1622
1623         // put the entity on the goal stack
1624         navigation_pushroute(e);
1625
1626         // if it can reach the goal there is nothing more to do
1627         if (tracewalk(self, startposition, PL_MIN, PL_MAX, e.origin, MOVE_NORMAL))
1628                 return TRUE;
1629
1630         // see if there are waypoints describing a path to the item
1631         e = e.nearestwaypoint;
1632         if(e == world)
1633                 return FALSE;
1634
1635         for (;;)
1636         {
1637                 // add the spawnfunc_waypoint to the path
1638                 navigation_pushroute(e);
1639                 e = e.enemy;
1640
1641                 if(e==world)
1642                         break;
1643         }
1644
1645         return FALSE;
1646 };
1647
1648 void navigation_routetogoals()
1649 {
1650         entity g1, g2;
1651
1652         navigation_clearroute();
1653
1654         g1 = navigation_get_bestgoal();
1655         for(;;)
1656         {
1657                 if(g2==world)
1658                         g2 = navigation_get_bestgoal();
1659
1660                 if(g2==world)
1661                 {
1662                         navigation_routetogoal(g1, self.origin);
1663                         return;
1664                 }
1665
1666                 if(navigation_routetogoal(g1, g2.origin))
1667                 {
1668                         g1 = g2;
1669                         g2 = world;
1670                         continue;
1671                 }
1672
1673                 navigation_clearroute();
1674                 g1 = g2;
1675                 g2 = world;
1676         }
1677 }
1678
1679 // removes any currently touching waypoints from the goal stack
1680 // (this is how bots detect if they have reached a goal)
1681 .float lastteleporttime;
1682
1683 void navigation_poptouchedgoals()
1684 {
1685         local vector org, m1, m2;
1686         org = self.origin;
1687         m1 = org + self.mins;
1688         m2 = org + self.maxs;
1689
1690         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1691         {
1692                 if(self.lastteleporttime>0)
1693                 if(time-self.lastteleporttime<0.2)
1694                 {
1695                         navigation_poproute();
1696                         return;
1697                 }
1698         }
1699
1700         // Loose goal touching check when running
1701         if(self.aistatus & AI_STATUS_RUNNING)
1702         if(self.goalcurrent.classname=="waypoint")
1703         {
1704                 if(vlen(self.origin - self.goalcurrent.origin)<150)
1705                 {
1706                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
1707                         if(trace_fraction==1)
1708                                 navigation_poproute();
1709                 }
1710         }
1711
1712         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
1713                 navigation_poproute();
1714 }
1715
1716 // begin a goal selection session (queries spawnfunc_waypoint network)
1717 void navigation_goalrating_start()
1718 {
1719         navigation_bestrating = -1;
1720         self.navigation_hasgoals = TRUE;
1721         navigation_bestgoals_reset();
1722         navigation_markroutes();
1723 };
1724
1725 // ends a goal selection session (updates goal stack to the best goal)
1726 void navigation_goalrating_end()
1727 {
1728         navigation_routetogoals();
1729 };
1730
1731
1732 //////////////////////////////////////////////////////////////////////////////
1733 // general bot functions
1734 //////////////////////////////////////////////////////////////////////////////
1735
1736 .float isbot; // true if this client is actually a bot
1737
1738 float skill;
1739 entity bot_list;
1740 .entity nextbot;
1741 .string netname_freeme;
1742
1743 float sv_maxspeed;
1744 .float createdtime;
1745
1746 .float bot_preferredcolors;
1747
1748 .float bot_attack;
1749 .float bot_dodge;
1750 .float bot_dodgerating;
1751
1752 //.float bot_painintensity;
1753 .float bot_firetimer;
1754 //.float bot_oldhealth;
1755 .void() bot_ai;
1756
1757 .entity bot_aimtarg;
1758 .float bot_aimlatency;
1759 .vector bot_aimselforigin;
1760 .vector bot_aimselfvelocity;
1761 .vector bot_aimtargorigin;
1762 .vector bot_aimtargvelocity;
1763
1764 .float bot_pickup;
1765 .float(entity player, entity item) bot_pickupevalfunc;
1766 .float bot_pickupbasevalue;
1767 .float bot_canfire;
1768 .float bot_strategytime;
1769
1770 // used for aiming currently
1771 // FIXME: make the weapon code use these and then replace the calculations here with a call to the weapon code
1772 vector shotorg;
1773 vector shotdir;
1774
1775 const float BOTSKINS = 19;
1776 const float BOTNAMES = 32;
1777 string bot_namefornumber(float r)
1778 {
1779         if (r <  1) return "Thunderstorm";
1780         if (r <  2) return "Darkness";
1781         if (r <  3) return "Scorcher";
1782         if (r <  4) return "Paranoia";
1783         if (r <  5) return "Eureka";
1784         if (r <  6) return "Mystery";
1785         if (r <  7) return "Toxic";
1786         if (r <  8) return "Dominion";
1787         if (r <  9) return "Pegasus";
1788         if (r < 10) return "Sensible";
1789         if (r < 11) return "Gator";
1790         if (r < 12) return "Kangaroo";
1791         if (r < 13) return "Deadline";
1792         if (r < 14) return "Frosty";
1793         if (r < 15) return "Roadkill";
1794         if (r < 16) return "Death";
1795         if (r < 17) return "Panic";
1796         if (r < 18) return "Discovery";
1797         if (r < 19) return "Shadow";
1798         if (r < 20) return "Acidic";
1799         if (r < 21) return "Dominator";
1800         if (r < 22) return "Hellfire";
1801         if (r < 23) return "Necrotic";
1802         if (r < 24) return "Newbie";
1803         if (r < 25) return "Spellbinder";
1804         if (r < 26) return "Lion";
1805         if (r < 27) return "Controlled";
1806         if (r < 28) return "Airhead";
1807         if (r < 29) return "Delirium";
1808         if (r < 30) return "Resurrection";
1809         if (r < 31) return "Danger";
1810         return "Flatline";
1811 };
1812
1813 string bot_skinfornumber(float r)
1814 {
1815              if (r <  1) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "0";return "Carni"          ;}
1816         else if (r <  2) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "1";return "Armored Carni"  ;}
1817         else if (r <  3) {self.playermodel = "models/player/crash.zym"          ;self.playerskin = "0";return "Quark"          ;}
1818         else if (r <  4) {self.playermodel = "models/player/grunt.zym"          ;self.playerskin = "0";return "Grunt"          ;}
1819         else if (r <  5) {self.playermodel = "models/player/headhunter.zym"     ;self.playerskin = "0";return "HeadHunter"     ;}
1820         else if (r <  6) {self.playermodel = "models/player/insurrectionist.zym";self.playerskin = "0";return "Insurrectionist";}
1821         else if (r <  7) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "0";return "Lurk"           ;}
1822         else if (r <  8) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "1";return "Reptile"        ;}
1823         else if (r <  9) {self.playermodel = "models/player/lycanthrope.zym"    ;self.playerskin = "0";return "Lycanthrope"    ;}
1824         else if (r < 10) {self.playermodel = "models/player/marine.zym"         ;self.playerskin = "0";return "Marine"         ;}
1825         else if (r < 11) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "0";return "Nexus"          ;}
1826         else if (r < 12) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "1";return "Mulder"         ;}
1827         else if (r < 13) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "2";return "Xolar"          ;}
1828         else if (r < 14) {self.playermodel = "models/player/pyria.zym"          ;self.playerskin = "0";return "Pyria"          ;}
1829         else if (r < 15) {self.playermodel = "models/player/shock.zym"          ;self.playerskin = "0";return "Shock"          ;}
1830         else if (r < 16) {self.playermodel = "models/player/skadi.zym"          ;self.playerskin = "0";return "Skadi"          ;}
1831         else if (r < 17) {self.playermodel = "models/player/specop.zym"         ;self.playerskin = "0";return "Specop"         ;}
1832         else             {self.playermodel = "models/player/visitant.zym"       ;self.playerskin = "0";return "Fricka"         ;}
1833 };
1834
1835 void bot_setnameandstuff()
1836 {
1837         local string name, prefix, suffix;
1838         local float r, b, shirt, pants;
1839
1840         prefix = cvar_string("bot_prefix");
1841         suffix = cvar_string("bot_suffix");
1842
1843         // this is really only a default, JoinBestTeam is called later
1844         pants = floor(random() * 15);
1845         shirt = floor(random() * 15);
1846         //shirt = pants;
1847         setcolor(self, shirt * 16 + pants);
1848         self.bot_preferredcolors = self.clientcolors;
1849
1850         // now pick a name...
1851
1852         if (cvar("bot_usemodelnames"))
1853         {
1854                 // first see if all skins are taken
1855                 b = 0;
1856                 do
1857                 {
1858                         name = bot_skinfornumber(b);
1859                         b = b + 1;
1860                 }
1861                 while (b < BOTSKINS && find(world, netname, name));
1862
1863                 // randomly pick a skin, if it's taken either repeat until we find one,
1864                 // or give up if we already know all skins are taken
1865                 do
1866                 {
1867                         r = floor(random() * BOTSKINS);
1868                         name = bot_skinfornumber(r);
1869                 }
1870                 while (b < BOTSKINS && find(world, netname, name));
1871         }
1872         else
1873         {
1874                 // first see if all names are taken
1875                 b = 0;
1876                 do
1877                 {
1878                         name = bot_namefornumber(b);
1879                         b = b + 1;
1880                 }
1881                 while (b < BOTNAMES && find(world, netname, name));
1882
1883                 // randomly pick a name, if it's taken either repeat until we find one,
1884                 // or give up if we already know all names are taken
1885                 do
1886                 {
1887                         r = floor(random() * BOTNAMES);
1888                         name = bot_namefornumber(r);
1889                 }
1890                 while (b < BOTNAMES && find(world, netname, name));
1891
1892                 // randomly pick a skin
1893                 bot_skinfornumber(floor(random() * BOTSKINS));
1894         }
1895         if(!cvar("g_campaign"))
1896                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, suffix));
1897         else
1898                 self.netname = name;
1899 };
1900
1901 float bot_custom_weapon;
1902 float bot_distance_far;
1903 float bot_distance_close;
1904
1905 float bot_weapons_far[WEP_LAST];
1906 float bot_weapons_mid[WEP_LAST];
1907 float bot_weapons_close[WEP_LAST];
1908
1909 void bot_custom_weapon_priority_setup()
1910 {
1911         local float tokens, i, c, w;
1912
1913         bot_custom_weapon = FALSE;
1914
1915         if(     cvar_string("bot_ai_custom_weapon_priority_far") == "" ||
1916                 cvar_string("bot_ai_custom_weapon_priority_mid") == "" ||
1917                 cvar_string("bot_ai_custom_weapon_priority_close") == "" ||
1918                 cvar_string("bot_ai_custom_weapon_priority_distances") == ""
1919         )
1920                 return;
1921
1922         // Parse distances
1923         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_distances")," ");
1924
1925         if (tokens!=2)
1926                 return;
1927
1928         bot_distance_far = stof(argv(0));
1929         bot_distance_close = stof(argv(1));
1930
1931         if(bot_distance_far < bot_distance_close){
1932                 bot_distance_far = stof(argv(1));
1933                 bot_distance_close = stof(argv(0));
1934         }
1935
1936         // Initialize list of weapons
1937         bot_weapons_far[0] = -1;
1938         bot_weapons_mid[0] = -1;
1939         bot_weapons_close[0] = -1;
1940
1941         // Parse far distance weapon priorities
1942         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_far")," ");
1943
1944         c = 0;
1945         for(i=0; i < tokens && c < WEP_COUNT; ++i){
1946                 w = stof(argv(i));
1947                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1948                         bot_weapons_far[c] = w;
1949                         ++c;
1950                 }
1951         }
1952         if(c < WEP_COUNT)
1953                 bot_weapons_far[c] = -1;
1954
1955         // Parse mid distance weapon priorities
1956         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_mid")," ");
1957
1958         c = 0;
1959         for(i=0; i < tokens && c < WEP_COUNT; ++i){
1960                 w = stof(argv(i));
1961                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1962                         bot_weapons_mid[c] = w;
1963                         ++c;
1964                 }
1965         }
1966         if(c < WEP_COUNT)
1967                 bot_weapons_mid[c] = -1;
1968
1969         // Parse close distance weapon priorities
1970         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_close")," ");
1971
1972         c = 0;
1973         for(i=0; i < tokens && i < WEP_COUNT; ++i){
1974                 w = stof(argv(i));
1975                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
1976                         bot_weapons_close[c] = w;
1977                         ++c;
1978                 }
1979         }
1980         if(c < WEP_COUNT)
1981                 bot_weapons_close[c] = -1;
1982
1983         bot_custom_weapon = TRUE;
1984 };
1985
1986
1987 void bot_endgame()
1988 {
1989         local entity e;
1990         //dprint("bot_endgame\n");
1991         e = bot_list;
1992         while (e)
1993         {
1994                 setcolor(e, e.bot_preferredcolors);
1995                 e = e.nextbot;
1996         }
1997         // if dynamic waypoints are ever implemented, save them here
1998 };
1999
2000 float bot_ignore_bots; // let bots not attack other bots (only works in non-teamplay)
2001 float bot_shouldattack(entity e)
2002 {
2003         if (e.team == self.team)
2004         {
2005                 if (e == self)
2006                         return FALSE;
2007                 if (teams_matter)
2008                 if (e.team != 0)
2009                         return FALSE;
2010         }
2011         if(!teams_matter)
2012                 if(bot_ignore_bots)
2013                         if(clienttype(e) == CLIENTTYPE_BOT)
2014                                 return FALSE;
2015         if (!e.takedamage)
2016                 return FALSE;
2017         if (e.deadflag)
2018                 return FALSE;
2019         if (e.BUTTON_CHAT)
2020                 return FALSE;
2021         if(g_minstagib)
2022         if(e.items & IT_STRENGTH)
2023                 return FALSE;
2024         if(e.flags & FL_NOTARGET)
2025                 return FALSE;
2026         return TRUE;
2027 };
2028
2029 void bot_lagfunc(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
2030 {
2031         if(self.flags & FL_INWATER)
2032         {
2033                 self.bot_aimtarg = world;
2034                 return;
2035         }
2036         self.bot_aimtarg = e1;
2037         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
2038         self.bot_aimselforigin = v1;
2039         self.bot_aimselfvelocity = v2;
2040         self.bot_aimtargorigin = v3;
2041         self.bot_aimtargvelocity = v4;
2042         if(skill <= 0)
2043                 self.bot_canfire = (random() < 0.8);
2044         else if(skill <= 1)
2045                 self.bot_canfire = (random() < 0.9);
2046         else if(skill <= 2)
2047                 self.bot_canfire = (random() < 0.95);
2048         else
2049                 self.bot_canfire = 1;
2050 };
2051
2052 .float bot_nextthink;
2053 .float bot_badaimtime;
2054 .float bot_aimthinktime;
2055 .float bot_prevaimtime;
2056 .vector bot_mouseaim;
2057 .vector bot_badaimoffset;
2058 .vector bot_1st_order_aimfilter;
2059 .vector bot_2nd_order_aimfilter;
2060 .vector bot_3th_order_aimfilter;
2061 .vector bot_4th_order_aimfilter;
2062 .vector bot_5th_order_aimfilter;
2063 .vector bot_olddesiredang;
2064 float bot_aimdir(vector v, float maxfiredeviation)
2065 {
2066         local float dist, delta_t, blend;
2067         local vector desiredang, diffang;
2068
2069         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
2070         // make sure v_angle is sane first
2071         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
2072         self.v_angle_z = 0;
2073
2074         // get the desired angles to aim at
2075         //dprint(" at:", vtos(v));
2076         v = normalize(v);
2077         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
2078         if (time >= self.bot_badaimtime)
2079         {
2080                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
2081                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5) * cvar("bot_ai_aimskill_offset");
2082         }
2083         desiredang = vectoangles(v) + self.bot_badaimoffset;
2084         //dprint(" desired:", vtos(desiredang));
2085         if (desiredang_x >= 180)
2086                 desiredang_x = desiredang_x - 360;
2087         desiredang_x = bound(-90, 0 - desiredang_x, 90);
2088         desiredang_z = self.v_angle_z;
2089         //dprint(" / ", vtos(desiredang));
2090
2091         //// pain throws off aim
2092         //if (self.bot_painintensity)
2093         //{
2094         //      // shake from pain
2095         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
2096         //}
2097
2098         // calculate turn angles
2099         diffang = (desiredang - self.bot_olddesiredang);
2100         // wrap yaw turn
2101         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2102         if (diffang_y >= 180)
2103                 diffang_y = diffang_y - 360;
2104         self.bot_olddesiredang = desiredang;
2105         //dprint(" diff:", vtos(diffang));
2106
2107         delta_t = time-self.bot_prevaimtime;
2108         self.bot_prevaimtime = time;
2109         // Here we will try to anticipate the comming aiming direction
2110         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
2111                 + (diffang * (1 / delta_t)    - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
2112         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
2113                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
2114         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
2115                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
2116         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
2117                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
2118         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
2119                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
2120
2121         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
2122         blend = bound(0,skill,10)*0.1;
2123         desiredang = desiredang + blend *
2124         (
2125                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
2126                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
2127                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
2128                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
2129                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
2130         );
2131
2132         // calculate turn angles
2133         diffang = desiredang - self.bot_mouseaim;
2134         // wrap yaw turn
2135         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2136         if (diffang_y >= 180)
2137                 diffang_y = diffang_y - 360;
2138         //dprint(" diff:", vtos(diffang));
2139
2140         if (time >= self.bot_aimthinktime)
2141         {
2142                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
2143                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-skill,10));
2144         }
2145
2146         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
2147
2148         diffang = self.bot_mouseaim - desiredang;
2149         // wrap yaw turn
2150         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2151         if (diffang_y >= 180)
2152                 diffang_y = diffang_y - 360;
2153         desiredang = desiredang + diffang * bound(0,cvar("bot_ai_aimskill_think"),1);
2154
2155         // calculate turn angles
2156         diffang = desiredang - self.v_angle;
2157         // wrap yaw turn
2158         diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2159         if (diffang_y >= 180)
2160                 diffang_y = diffang_y - 360;
2161         //dprint(" diff:", vtos(diffang));
2162
2163         // jitter tracking
2164         dist = vlen(diffang);
2165         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
2166
2167         // turn
2168         local float r, fixedrate, blendrate;
2169         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
2170         blendrate = cvar("bot_ai_aimskill_blendrate");
2171         r = max(fixedrate, blendrate);
2172         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
2173         self.v_angle = self.v_angle + diffang * bound(delta_t, r * delta_t * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
2174         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
2175         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
2176         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
2177         self.v_angle_z = 0;
2178         self.v_angle_y = self.v_angle_y - floor(self.v_angle_y / 360) * 360;
2179         //dprint(" turn:", vtos(self.v_angle));
2180
2181         makevectors(self.v_angle);
2182         shotorg = self.origin + self.view_ofs;
2183         shotdir = v_forward;
2184
2185         //dprint(" dir:", vtos(v_forward));
2186         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
2187
2188         // calculate turn angles again
2189         //diffang = desiredang - self.v_angle;
2190         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
2191         //if (diffang_y >= 180)
2192         //      diffang_y = diffang_y - 360;
2193
2194         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
2195
2196         // decide whether to fire this time
2197         // note the maxfiredeviation is in degrees so this has to convert to radians first
2198         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
2199         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
2200         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill, 10) || random()*random()>bound(0,skill*0.05,1))
2201                 self.bot_firetimer = time + bound(0.1, 0.5-skill*0.05, 0.5);
2202         //traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
2203         //dprint(ftos(maxfiredeviation),"\n");
2204         //dprint(" diff:", vtos(diffang), "\n");
2205
2206         return self.bot_canfire && (time < self.bot_firetimer);
2207 };
2208
2209 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
2210 {
2211         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
2212         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
2213 };
2214
2215 float bot_aim(float shotspeed, float shotspeedupward, float maxshottime, float applygravity)
2216 {
2217         local float f, r;
2218         local vector v;
2219         /*
2220         eprint(self);
2221         dprint("bot_aim(", ftos(shotspeed));
2222         dprint(", ", ftos(shotspeedupward));
2223         dprint(", ", ftos(maxshottime));
2224         dprint(", ", ftos(applygravity));
2225         dprint(");\n");
2226         */
2227         if (!shotspeed)
2228         {
2229                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
2230                 shotspeed = 1000000;
2231         }
2232         if (!maxshottime)
2233         {
2234                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
2235                 maxshottime = 1;
2236         }
2237         makevectors(self.v_angle);
2238         shotorg = self.origin + self.view_ofs;
2239         shotdir = v_forward;
2240         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
2241         local float distanceratio;
2242         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
2243         distanceratio = bound(0,distanceratio,1);
2244         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
2245                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
2246         if (applygravity && self.bot_aimtarg)
2247         {
2248                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
2249                         return FALSE;
2250                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
2251         }
2252         else
2253         {
2254                 f = bot_aimdir(v - shotorg, r);
2255                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
2256                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
2257                 if (trace_ent.takedamage)
2258                 if (trace_fraction < 1)
2259                 if (!bot_shouldattack(trace_ent))
2260                         return FALSE;
2261                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
2262                 if (trace_fraction < 1)
2263                 if (trace_ent != self.enemy)
2264                 if (!bot_shouldattack(trace_ent))
2265                         return FALSE;
2266         }
2267         if (r > maxshottime * shotspeed)
2268                 return FALSE;
2269         return f;
2270 };
2271
2272 // TODO: move this painintensity code to the player damage code
2273 void bot_think()
2274 {
2275         if (self.bot_nextthink > time)
2276                 return;
2277         self.bot_nextthink = self.bot_nextthink + cvar("bot_ai_thinkinterval");
2278         //if (self.bot_painintensity > 0)
2279         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
2280
2281         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
2282         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
2283
2284         if(time < game_starttime || ((cvar("g_campaign") && !campaign_bots_may_start)))
2285         {
2286                 self.nextthink = time + 0.5;
2287                 return;
2288         }
2289
2290         if (self.fixangle)
2291         {
2292                 self.v_angle = self.angles;
2293                 self.v_angle_z = 0;
2294                 self.fixangle = FALSE;
2295         }
2296
2297         self.dmg_take = 0;
2298         self.dmg_save = 0;
2299         self.dmg_inflictor = world;
2300
2301         // calculate an aiming latency based on the skill setting
2302         // (simulated network latency + naturally delayed reflexes)
2303         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
2304         // minimum ping 20+10 random
2305         self.ping = bound(0,0.07 - bound(0, skill * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
2306         // skill 10 = ping 0.2 (adrenaline)
2307         // skill 0 = ping 0.7 (slightly drunk)
2308
2309         // clear buttons
2310         self.BUTTON_ATCK = 0;
2311         self.button1 = 0;
2312         self.BUTTON_JUMP = 0;
2313         self.BUTTON_ATCK2 = 0;
2314         self.BUTTON_ZOOM = 0;
2315         self.BUTTON_CROUCH = 0;
2316         self.BUTTON_HOOK = 0;
2317         self.BUTTON_INFO = 0;
2318         self.button8 = 0;
2319         self.BUTTON_CHAT = 0;
2320         self.BUTTON_USE = 0;
2321
2322         // if dead, just wait until we can respawn
2323         if (self.deadflag)
2324         {
2325                 if (self.deadflag == DEAD_DEAD)
2326                 {
2327                         self.BUTTON_JUMP = 1; // press jump to respawn
2328                         self.bot_strategytime = 0;
2329                 }
2330                 return;
2331         }
2332
2333         // now call the current bot AI (havocbot for example)
2334         self.bot_ai();
2335 };
2336
2337 entity bot_strategytoken;
2338 float bot_strategytoken_taken;
2339 entity player_list;
2340 .entity nextplayer;
2341 void bot_relinkplayerlist()
2342 {
2343         local entity e;
2344         local entity prevbot;
2345         player_count = 0;
2346         currentbots = 0;
2347         player_list = e = findchainflags(flags, FL_CLIENT);
2348         bot_list = world;
2349         prevbot = world;
2350         while (e)
2351         {
2352                 player_count = player_count + 1;
2353                 e.nextplayer = e.chain;
2354                 if (clienttype(e) == CLIENTTYPE_BOT)
2355                 {
2356                         if (prevbot)
2357                                 prevbot.nextbot = e;
2358                         else
2359                                 bot_list = e;
2360                         prevbot = e;
2361                         currentbots = currentbots + 1;
2362                 }
2363                 e = e.chain;
2364         }
2365         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
2366         bot_strategytoken = bot_list;
2367         bot_strategytoken_taken = TRUE;
2368 };
2369
2370 void() havocbot_setupbot;
2371 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam);
2372
2373 void bot_clientdisconnect()
2374 {
2375         if (clienttype(self) != CLIENTTYPE_BOT)
2376                 return;
2377         if(self.netname_freeme)
2378                 strunzone(self.netname_freeme);
2379         self.netname_freeme = string_null;
2380 }
2381
2382 void bot_clientconnect()
2383 {
2384         if (clienttype(self) != CLIENTTYPE_BOT)
2385                 return;
2386         self.bot_preferredcolors = self.clientcolors;
2387         self.bot_nextthink = time - random();
2388         self.lag_func = bot_lagfunc;
2389         self.isbot = TRUE;
2390         self.createdtime = self.nextthink;
2391         JoinBestTeam(self, FALSE, TRUE);
2392         havocbot_setupbot();
2393         self.bot_mouseskill=random()-0.5;
2394         self.bot_thinkskill=random()-0.5;
2395         self.bot_predictionskill=random()-0.5;
2396         self.bot_offsetskill=random()-0.5;
2397 };
2398
2399 entity bot_spawn()
2400 {
2401         local entity oldself, bot;
2402         bot = spawnclient();
2403         if (bot)
2404         {
2405                 currentbots = currentbots + 1;
2406                 oldself = self;
2407                 self = bot;
2408                 bot_setnameandstuff();
2409                 ClientConnect();
2410                 PutClientInServer();
2411                 self = oldself;
2412         }
2413         return bot;
2414 };
2415
2416 void CheckAllowedTeams(entity for_whom); void GetTeamCounts(entity other); float c1, c2, c3, c4;
2417 void bot_removefromlargestteam()
2418 {
2419         local float besttime, bestcount, thiscount;
2420         local entity best, head;
2421         CheckAllowedTeams(world);
2422         GetTeamCounts(world);
2423         head = findchainfloat(isbot, TRUE);
2424         if (!head)
2425                 return;
2426         best = head;
2427         besttime = head.createdtime;
2428         bestcount = 0;
2429         while (head)
2430         {
2431                 if(head.team == COLOR_TEAM1)
2432                         thiscount = c1;
2433                 else if(head.team == COLOR_TEAM2)
2434                         thiscount = c2;
2435                 else if(head.team == COLOR_TEAM3)
2436                         thiscount = c3;
2437                 else if(head.team == COLOR_TEAM4)
2438                         thiscount = c4;
2439                 else
2440                         thiscount = 0;
2441                 if (thiscount > bestcount)
2442                 {
2443                         bestcount = thiscount;
2444                         besttime = head.createdtime;
2445                         best = head;
2446                 }
2447                 else if (thiscount == bestcount && besttime < head.createdtime)
2448                 {
2449                         besttime = head.createdtime;
2450                         best = head;
2451                 }
2452                 head = head.chain;
2453         }
2454         currentbots = currentbots - 1;
2455         dropclient(best);
2456 };
2457
2458 void bot_removenewest()
2459 {
2460         local float besttime;
2461         local entity best, head;
2462
2463         if(teams_matter)
2464         {
2465                 bot_removefromlargestteam();
2466                 return;
2467         }
2468
2469         head = findchainfloat(isbot, TRUE);
2470         if (!head)
2471                 return;
2472         best = head;
2473         besttime = head.createdtime;
2474         while (head)
2475         {
2476                 if (besttime < head.createdtime)
2477                 {
2478                         besttime = head.createdtime;
2479                         best = head;
2480                 }
2481                 head = head.chain;
2482         }
2483         currentbots = currentbots - 1;
2484         dropclient(best);
2485 };
2486
2487 float botframe_waypointeditorlightningtime;
2488 void botframe_showwaypointlinks()
2489 {
2490         local entity player, head, w;
2491         if (time < botframe_waypointeditorlightningtime)
2492                 return;
2493         botframe_waypointeditorlightningtime = time + 0.5;
2494         player = find(world, classname, "player");
2495         while (player)
2496         {
2497                 if (!player.isbot)
2498                 if (player.flags & FL_ONGROUND || player.waterlevel > WATERLEVEL_NONE)
2499                 {
2500                         //navigation_testtracewalk = TRUE;
2501                         head = navigation_findnearestwaypoint(player, FALSE);
2502                         //navigation_testtracewalk = FALSE;
2503                         if (head)
2504                         {
2505                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
2506                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
2507                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
2508                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
2509                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
2510                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
2511                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
2512                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
2513                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
2514                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
2515                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
2516                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
2517                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
2518                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
2519                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
2520                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
2521                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
2522                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
2523                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
2524                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
2525                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
2526                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
2527                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
2528                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
2529                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
2530                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
2531                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
2532                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
2533                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
2534                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
2535                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
2536                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
2537                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
2538                         }
2539                 }
2540                 player = find(player, classname, "player");
2541         }
2542 };
2543
2544 entity botframe_dangerwaypoint;
2545 void botframe_updatedangerousobjects(float maxupdate)
2546 {
2547         local entity head, bot_dodgelist;
2548         local vector m1, m2, v;
2549         local float c, d, danger;
2550         c = 0;
2551         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
2552         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2553         while (botframe_dangerwaypoint != world)
2554         {
2555                 danger = 0;
2556                 m1 = botframe_dangerwaypoint.mins;
2557                 m2 = botframe_dangerwaypoint.maxs;
2558                 head = bot_dodgelist;
2559                 while (head)
2560                 {
2561                         v = head.origin;
2562                         v_x = bound(m1_x, v_x, m2_x);
2563                         v_y = bound(m1_y, v_y, m2_y);
2564                         v_z = bound(m1_z, v_z, m2_z);
2565                         d = head.bot_dodgerating - vlen(head.origin - v);
2566                         if (d > 0)
2567                         {
2568                                 traceline(head.origin, v, TRUE, world);
2569                                 if (trace_fraction == 1)
2570                                         danger = danger + d;
2571                         }
2572                         head = head.chain;
2573                 }
2574                 botframe_dangerwaypoint.dmg = danger;
2575                 c = c + 1;
2576                 if (c >= maxupdate)
2577                         break;
2578                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
2579         }
2580 };
2581
2582
2583 float botframe_spawnedwaypoints;
2584 float botframe_nextthink;
2585 float botframe_nextdangertime;
2586
2587 float autoskill_nextthink;
2588 .float totalfrags_lastcheck;
2589 void autoskill(float factor)
2590 {
2591         float bestbot;
2592         float bestplayer;
2593         entity head;
2594
2595         bestbot = -1;
2596         bestplayer = -1;
2597         FOR_EACH_PLAYER(head)
2598         {
2599                 if(clienttype(head) == CLIENTTYPE_REAL)
2600                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
2601                 else
2602                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
2603         }
2604
2605         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
2606         dprint("best bot got ", ftos(bestbot), "; ");
2607         if(bestbot < 0 || bestplayer < 0)
2608         {
2609                 dprint("not doing anything\n");
2610                 // don't return, let it reset all counters below
2611         }
2612         else if(bestbot <= bestplayer * factor - 2)
2613         {
2614                 if(cvar("skill") < 17)
2615                 {
2616                         dprint("2 frags difference, increasing skill\n");
2617                         cvar_set("skill", ftos(cvar("skill") + 1));
2618                         bprint("^2SKILL UP!^7 Now at level ", ftos(cvar("skill")), "\n");
2619                 }
2620         }
2621         else if(bestbot >= bestplayer * factor + 2)
2622         {
2623                 if(cvar("skill") > 0)
2624                 {
2625                         dprint("2 frags difference, decreasing skill\n");
2626                         cvar_set("skill", ftos(cvar("skill") - 1));
2627                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(cvar("skill")), "\n");
2628                 }
2629         }
2630         else
2631         {
2632                 dprint("not doing anything\n");
2633                 return;
2634                 // don't reset counters, wait for them to accumulate
2635         }
2636
2637         FOR_EACH_PLAYER(head)
2638                 head.totalfrags_lastcheck = head.totalfrags;
2639 }
2640
2641 float bot_cvar_nextthink;
2642 void bot_serverframe()
2643 {
2644         float realplayers, bots, activerealplayers;
2645         entity head;
2646
2647         if (intermission_running)
2648                 return;
2649
2650         if (time < 2)
2651                 return;
2652
2653         if(time > autoskill_nextthink)
2654         {
2655                 float a;
2656                 a = cvar("skill_auto");
2657                 if(a)
2658                         autoskill(a);
2659                 autoskill_nextthink = time + 5;
2660         }
2661
2662         activerealplayers = 0;
2663         realplayers = 0;
2664
2665         FOR_EACH_REALCLIENT(head)
2666         {
2667                 if(head.classname == "player" || g_lms || g_arena)
2668                         ++activerealplayers;
2669                 ++realplayers;
2670         }
2671
2672         // add/remove bots if needed to make sure there are at least
2673         // minplayers+bot_number, or remove all bots if no one is playing
2674         // But don't remove bots immediately on level change, as the real players
2675         // usually haven't rejoined yet
2676         bots_would_leave = FALSE;
2677         if (realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5))
2678         {
2679                 float realminplayers, minplayers;
2680                 realminplayers = cvar("minplayers");
2681                 minplayers = max(0, floor(realminplayers));
2682
2683                 float realminbots, minbots;
2684                 if(cvar("bot_vs_human"))
2685                         realminbots = ceil(fabs(cvar("bot_vs_human")) * activerealplayers);
2686                 else
2687                         realminbots = cvar("bot_number");
2688                 minbots = max(0, floor(realminbots));
2689
2690                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
2691                 if(bots > minbots)
2692                         bots_would_leave = TRUE;
2693         }
2694         else
2695         {
2696                 // if there are no players, remove bots
2697                 bots = 0;
2698         }
2699
2700         bot_ignore_bots = cvar("bot_ignore_bots");
2701
2702         // only add one bot per frame to avoid utter chaos
2703         if(time > botframe_nextthink)
2704         {
2705                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
2706                 while (currentbots < bots)
2707                 {
2708                         if (bot_spawn() == world)
2709                         {
2710                                 bprint("Can not add bot, server full.\n");
2711                                 botframe_nextthink = time + 10;
2712                                 break;
2713                         }
2714                 }
2715                 while (currentbots > bots)
2716                         bot_removenewest();
2717         }
2718
2719         if(botframe_spawnedwaypoints)
2720         {
2721                 if(cvar("waypoint_benchmark"))
2722                         localcmd("quit\n");
2723         }
2724
2725         if (currentbots > 0 || cvar("g_waypointeditor"))
2726         if (botframe_spawnedwaypoints)
2727         {
2728                 if(!botframe_cachedwaypointlinks)
2729                 {
2730                         // TODO: Make this check cleaner
2731                         local entity wp = findchain(classname, "waypoint");
2732                         if(time - wp.nextthink > 10)
2733                                 waypoint_save_links();
2734                 }
2735         }
2736         else
2737         {
2738                 botframe_spawnedwaypoints = TRUE;
2739                 waypoint_loadall();
2740                 if(!waypoint_load_links())
2741                         waypoint_schedulerelinkall();
2742         }
2743
2744         if (bot_list)
2745         {
2746                 // cycle the goal token from one bot to the next each frame
2747                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
2748                 //  frame, which causes choppy framerates)
2749                 if (bot_strategytoken_taken)
2750                 {
2751                         bot_strategytoken_taken = FALSE;
2752                         if (bot_strategytoken)
2753                                 bot_strategytoken = bot_strategytoken.nextbot;
2754                         if (!bot_strategytoken)
2755                                 bot_strategytoken = bot_list;
2756                 }
2757
2758                 if (botframe_nextdangertime < time)
2759                 {
2760                         local float interval;
2761                         interval = cvar("bot_ai_dangerdetectioninterval");
2762                         if (botframe_nextdangertime < time - interval * 1.5)
2763                                 botframe_nextdangertime = time;
2764                         botframe_nextdangertime = botframe_nextdangertime + interval;
2765                         botframe_updatedangerousobjects(cvar("bot_ai_dangerdetectionupdates"));
2766                 }
2767         }
2768
2769         if (cvar("g_waypointeditor"))
2770                 botframe_showwaypointlinks();
2771
2772         if(time > bot_cvar_nextthink)
2773         {
2774                 if(currentbots>1)
2775                         bot_custom_weapon_priority_setup();
2776                 bot_cvar_nextthink = time + 5;
2777         }
2778 };