new gib types: alien and robot_shiny, and blood types, depending on playermodel
[divverent/nexuiz.git] / data / qcsrc / menu / nexuiz / playermodel.c
1 #ifdef INTERFACE
2 CLASS(NexuizPlayerModelSelector) EXTENDS(NexuizImage)
3         METHOD(NexuizPlayerModelSelector, configureNexuizPlayerModelSelector, void(entity))
4         METHOD(NexuizPlayerModelSelector, loadCvars, void(entity))
5         METHOD(NexuizPlayerModelSelector, saveCvars, void(entity))
6         METHOD(NexuizPlayerModelSelector, draw, void(entity))
7         METHOD(NexuizPlayerModelSelector, resizeNotify, void(entity, vector, vector, vector, vector))
8         ATTRIB(NexuizPlayerModelSelector, currentModel, string, string_null)
9         ATTRIB(NexuizPlayerModelSelector, currentSkin, float, 0)
10         ATTRIB(NexuizPlayerModelSelector, currentModelName, string, string_null)
11         ATTRIB(NexuizPlayerModelSelector, currentModelTitle, string, string_null)
12         ATTRIB(NexuizPlayerModelSelector, currentModelTxtName, string, string_null)
13         ATTRIB(NexuizPlayerModelSelector, currentModelDescription, string, string_null)
14         METHOD(NexuizPlayerModelSelector, go, void(entity, float))
15         ATTRIB(NexuizPlayerModelSelector, origin, vector, '0 0 0')
16         ATTRIB(NexuizPlayerModelSelector, size, vector, '0 0 0')
17         ATTRIB(NexuizPlayerModelSelector, realFontSize, vector, '0 0 0')
18         ATTRIB(NexuizPlayerModelSelector, fontSize, float, SKINFONTSIZE_NORMAL)
19         ATTRIB(NexuizPlayerModelSelector, titleFontSize, float, SKINFONTSIZE_TITLE)
20 ENDCLASS(NexuizPlayerModelSelector)
21 entity makeNexuizPlayerModelSelector();
22 void PlayerModelSelector_Next_Click(entity btn, entity me);
23 void PlayerModelSelector_Prev_Click(entity btn, entity me);
24 #endif
25
26 #ifdef IMPLEMENTATION
27 entity makeNexuizPlayerModelSelector()
28 {
29         entity me;
30         me = spawnNexuizPlayerModelSelector();
31         me.configureNexuizPlayerModelSelector(me);
32         return me;
33 }
34
35 void configureNexuizPlayerModelSelectorNexuizPlayerModelSelector(entity me)
36 {
37         me.configureNexuizImage(me, string_null, 263.0/360.0);
38         me.loadCvars(me);
39 }
40
41 void loadCvarsNexuizPlayerModelSelector(entity me)
42 {
43         float glob, i, fh;
44         string fn;
45         string nm, t, l;
46
47         if(me.currentModel)
48                 strunzone(me.currentModel);
49         if(me.currentModelTitle)
50                 strunzone(me.currentModelTitle);
51         if(me.currentModelName)
52                 strunzone(me.currentModelName);
53         if(me.currentModelTxtName)
54                 strunzone(me.currentModelTxtName);
55         if(me.currentModelDescription)
56                 strunzone(me.currentModelDescription);
57         me.currentSkin = cvar("_cl_playerskin");
58         me.currentModel = strzone(cvar_string("_cl_playermodel"));
59         me.currentModelName = string_null;
60         me.currentModelDescription = string_null;
61         me.currentModelTitle = string_null;
62         me.currentModelTxtName = string_null;
63
64         // lookup model name
65         glob = search_begin("models/player/*.txt", TRUE, TRUE);
66         if(glob < 0)
67                 return;
68         for(i = 0; i < search_getsize(glob); ++i)
69         {
70                 fn = search_getfilename(glob, i);
71                 fh = fopen(fn, FILE_READ);
72                 if(fh < 0)
73                         continue;
74                 t = fgets(fh);
75                 nm = fgets(fh);
76                 if(stof(fgets(fh)) == me.currentSkin)
77                 if(fgets(fh) == me.currentModel)
78                 {
79                         me.currentModelName = strzone(strcat("/", nm));
80                         me.currentModelTxtName = strzone(fn);
81                         me.currentModelTitle = strzone(t);
82                         me.currentModelDescription = "";
83                         fgets(fh); // Skip species
84                         while((l = fgets(fh)))
85                         {
86                                 if(me.currentModelDescription != "")
87                                         me.currentModelDescription = strcat(me.currentModelDescription, "\n");
88                                 me.currentModelDescription = strcat(me.currentModelDescription, l);
89                         }
90                         me.currentModelDescription = strzone(me.currentModelDescription);
91                         fclose(fh);
92                         break;
93                 }
94                 fclose(fh);
95         }
96         search_end(glob);
97 }
98
99 void goNexuizPlayerModelSelector(entity me, float d)
100 {
101         float glob, i, fh;
102         string l;
103
104         glob = search_begin("models/player/*.txt", TRUE, TRUE);
105         if(glob < 0)
106                 return;
107         for(i = 0; i < search_getsize(glob); ++i)
108                 if(search_getfilename(glob, i) == me.currentModelTxtName)
109                         break;
110         // now i is search_getsize(glob) if not found, and the right index if found.
111         if(i == search_getsize(glob))
112         {
113                 if(d < 0)
114                         i = search_getsize(glob) - 1;
115                 else
116                         i = 0;
117         }
118         else
119         {
120                 i = mod(i + d + search_getsize(glob), search_getsize(glob));
121         }
122
123         if(me.currentModel)
124                 strunzone(me.currentModel);
125         if(me.currentModelTitle)
126                 strunzone(me.currentModelTitle);
127         if(me.currentModelName)
128                 strunzone(me.currentModelName);
129         if(me.currentModelTxtName)
130                 strunzone(me.currentModelTxtName);
131         if(me.currentModelDescription)
132                 strunzone(me.currentModelDescription);
133
134         // select model #i!
135         me.currentModelTxtName = strzone(search_getfilename(glob, i));
136         fh = fopen(me.currentModelTxtName, FILE_READ);
137         search_end(glob);
138         if(fh < 0)
139                 return;
140         me.currentModelTitle = strzone(fgets(fh));
141         me.currentModelName = strzone(strcat("/", fgets(fh)));
142         me.currentSkin = stof(fgets(fh));
143         me.currentModel = strzone(fgets(fh));
144         me.currentModelDescription = "";
145         fgets(fh); // Skip species
146         while((l = fgets(fh)))
147         {
148                 if(me.currentModelDescription != "")
149                         me.currentModelDescription = strcat(me.currentModelDescription, "\n");
150                 me.currentModelDescription = strcat(me.currentModelDescription, l);
151         }
152         me.currentModelDescription = strzone(me.currentModelDescription);
153         fclose(fh);
154 }
155
156 void PlayerModelSelector_Next_Click(entity btn, entity me)
157 {
158         me.go(me, +1);
159         me.saveCvars(me);
160 }
161
162 void PlayerModelSelector_Prev_Click(entity btn, entity me)
163 {
164         me.go(me, -1);
165         me.saveCvars(me);
166 }
167
168 void saveCvarsNexuizPlayerModelSelector(entity me)
169 {
170         // TODO rather set the _cl ones and apply later?
171         localcmd(strcat("playermodel ", me.currentModel, "\nplayerskin ", ftos(me.currentSkin), "\n"));
172 }
173
174 void drawNexuizPlayerModelSelector(entity me)
175 {
176         float i, n;
177         vector o;
178
179         me.src = me.currentModelName;
180         drawImage(me);
181         me.src = string_null;
182
183         // draw text on the image, handle \n in the description
184         draw_CenterText('0.5 0 0', me.currentModelTitle, me.realFontSize * (me.titleFontSize / me.fontSize), SKINCOLOR_MODELTITLE, SKINALPHA_MODELTITLE, FALSE);
185
186         o = '0.5 1 0' - eY * me.realFontSize_y * ((n = tokenizebyseparator(me.currentModelDescription, "\n")) + 0.5);
187         for(i = 0; i < n; ++i)
188         {
189                 draw_CenterText(o, argv(i), me.realFontSize, '1 1 1', 1, FALSE);
190                 o += eY * me.realFontSize_y;
191         }
192 }
193
194 void resizeNotifyNexuizPlayerModelSelector(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
195 {
196         resizeNotifyImage(me, relOrigin, relSize, absOrigin, absSize);
197         me.realFontSize_y = me.fontSize / absSize_y;
198         me.realFontSize_x = me.fontSize / absSize_x;
199 }
200 #endif