data/qcsrc/menu/nexuiz/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMapList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizMapList, configureNexuizMapList, void(entity))
   4         ATTRIB(NexuizMapList, rowsPerItem, float, 4)
   5         METHOD(NexuizMapList, draw, void(entity))
   6         METHOD(NexuizMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizMapList, refilter, void(entity))
  10         METHOD(NexuizMapList, keyDown, float(entity, float, float, float))
  11
  12         ATTRIB(NexuizMapList, realFontSize, vector, '0 0 0')
  13         ATTRIB(NexuizMapList, columnPreviewOrigin, float, 0)
  14         ATTRIB(NexuizMapList, columnPreviewSize, float, 0)
  15         ATTRIB(NexuizMapList, columnNameOrigin, float, 0)
  16         ATTRIB(NexuizMapList, columnNameSize, float, 0)
  17         ATTRIB(NexuizMapList, checkMarkOrigin, vector, '0 0 0')
  18         ATTRIB(NexuizMapList, checkMarkSize, vector, '0 0 0')
  19         ATTRIB(NexuizMapList, realUpperMargin1, float, 0)
  20         ATTRIB(NexuizMapList, realUpperMargin2, float, 0)
  21
  22         ATTRIB(NexuizMapList, lastClickedMap, float, -1)
  23         ATTRIB(NexuizMapList, lastClickedTime, float, 0)
  24
  25         ATTRIB(NexuizMapList, lastGametype, float, 0)
  26         ATTRIB(NexuizMapList, lastFeatures, float, 0)
  27
  28         ATTRIB(NexuizMapList, origin, vector, '0 0 0')
  29         ATTRIB(NexuizMapList, itemAbsSize, vector, '0 0 0')
  30
  31         ATTRIB(NexuizMapList, g_maplistCache, string, string_null)
  32         METHOD(NexuizMapList, g_maplistCacheToggle, void(entity, float))
  33         METHOD(NexuizMapList, g_maplistCacheQuery, float(entity, float))
  34
  35         ATTRIB(NexuizMapList, startButton, entity, NULL)
  36
  37         ATTRIB(NexuizMapList, cvarName, string, "dummy")
  38         METHOD(NexuizMapList, loadCvars, void(entity))
  39
  40         ATTRIB(NexuizMapList, typeToSearchString, string, string_null)
  41         ATTRIB(NexuizMapList, typeToSearchTime, float, 0)
  42
  43         METHOD(NexuizMapList, destroy, void(entity))
  44 ENDCLASS(NexuizMapList)
  45 entity makeNexuizMapList();
  46 void MapList_All(entity btn, entity me);
  47 void MapList_None(entity btn, entity me);
  48 void MapList_LoadMap(entity btn, entity me);
  49 #endif
  50
  51 #ifdef IMPLEMENTATION
  52 void destroyNexuizMapList(entity me)
  53 {
  54         MapInfo_Shutdown();
  55 }
  56
  57 entity makeNexuizMapList()
  58 {
  59         entity me;
  60         me = spawnNexuizMapList();
  61         me.configureNexuizMapList(me);
  62         return me;
  63 }
  64
  65 void configureNexuizMapListNexuizMapList(entity me)
  66 {
  67         me.configureNexuizListBox(me);
  68         me.refilter(me);
  69 }
  70
  71 void loadCvarsNexuizMapList(entity me)
  72 {
  73         me.refilter(me);
  74 }
  75
  76 float g_maplistCacheQueryNexuizMapList(entity me, float i)
  77 {
  78         return stof(substring(me.g_maplistCache, i, 1));
  79 }
  80 void g_maplistCacheToggleNexuizMapList(entity me, float i)
  81 {
  82         string a, b, c, s, bspname;
  83         float n;
  84         s = me.g_maplistCache;
  85         if not(s)
  86                 return;
  87         b = substring(s, i, 1);
  88         if(b == "0")
  89                 b = "1";
  90         else if(b == "1")
  91                 b = "0";
  92         else
  93                 return; // nothing happens
  94         a = substring(s, 0, i);
  95         c = substring(s, i+1, strlen(s) - (i+1));
  96         strunzone(s);
  97         me.g_maplistCache = strzone(strcat(a, b, c));
  98         // TODO also update the actual cvar
  99         if not((bspname = MapInfo_BSPName_ByID(i)))
 100                 return;
 101         if(b == "1")
 102                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
 103         else
 104         {
 105                 s = "";
 106                 n = tokenize_sane(cvar_string("g_maplist"));
 107                 for(i = 0; i < n; ++i)
 108                         if(argv(i) != bspname)
 109                                 s = strcat(s, " ", argv(i));
 110                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 111         }
 112 }
 113
 114 void drawNexuizMapList(entity me)
 115 {
 116         if(me.startButton)
 117                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 118         drawListBox(me);
 119 }
 120
 121 void resizeNotifyNexuizMapList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 122 {
 123         me.origin = absOrigin;
 124         me.itemAbsSize = '0 0 0';
 125         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 126
 127         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 128         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 129         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 130         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 131
 132         me.columnPreviewOrigin = 0;
 133         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 134         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 135         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 136
 137         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 138         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 139 }
 140
 141 void clickListBoxItemNexuizMapList(entity me, float i, vector where)
 142 {
 143         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 144         {
 145                 if(where_x >= 0)
 146                         me.g_maplistCacheToggle(me, i);
 147         }
 148         if(where_x >= me.columnNameOrigin)
 149                 if(where_x <= 1)
 150                         {
 151                                 if(i == me.lastClickedMap)
 152                                         if(time < me.lastClickedTime + 0.3)
 153                                         {
 154                                                 // DOUBLE CLICK!
 155                                                 // pop up map info screen
 156                                                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
 157                                                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 158                                                 return;
 159                                         }
 160                                 me.lastClickedMap = i;
 161                                 me.lastClickedTime = time;
 162                         }
 163 }
 164
 165 void drawListBoxItemNexuizMapList(entity me, float i, vector absSize, float isSelected)
 166 {
 167         // layout: Ping, Map name, Map name, NP, TP, MP
 168         string s;
 169         float p;
 170         float theAlpha;
 171         float included;
 172
 173         if(!MapInfo_Get_ByID(i))
 174                 return;
 175
 176         included = me.g_maplistCacheQuery(me, i);
 177         if(included || isSelected)
 178                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 179         else
 180                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 181
 182         if(isSelected)
 183                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 184         else if(included)
 185                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 186
 187         s = ftos(p);
 188         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 189         if(included)
 190                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 191         s = draw_TextShortenToWidth(strcat(MapInfo_Map_bspname, ": ", MapInfo_Map_title), me.columnNameSize / me.realFontSize_x, 0);
 192         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 193         s = draw_TextShortenToWidth(MapInfo_Map_author, me.columnNameSize / me.realFontSize_x, 0);
 194         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 195
 196         MapInfo_ClearTemps();
 197 }
 198
 199 void refilterNexuizMapList(entity me)
 200 {
 201         float i, j, n;
 202         string s;
 203         float gt, f;
 204         gt = MapInfo_CurrentGametype();
 205         f = MapInfo_CurrentFeatures();
 206         MapInfo_FilterGametype(gt, f, 0);
 207         me.nItems = MapInfo_count;
 208         for(i = 0; i < MapInfo_count; ++i)
 209                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 210         if(me.g_maplistCache)
 211                 strunzone(me.g_maplistCache);
 212         s = "0";
 213         for(i = 1; i < MapInfo_count; i *= 2)
 214                 s = strcat(s, s);
 215         n = tokenize_sane(cvar_string("g_maplist"));
 216         for(i = 0; i < n; ++i)
 217         {
 218                 j = MapInfo_FindName(argv(i));
 219                 if(j >= 0)
 220                         s = strcat(
 221                                 substring(s, 0, j),
 222                                 "1",
 223                                 substring(s, j+1, MapInfo_count - (j+1))
 224                         );
 225         }
 226         me.g_maplistCache = strzone(s);
 227         if(gt != me.lastGametype || f != me.lastFeatures)
 228         {
 229                 me.lastGametype = gt;
 230                 me.lastFeatures = f;
 231                 me.setSelected(me, 0);
 232         }
 233 }
 234
 235 void MapList_All(entity btn, entity me)
 236 {
 237         float i;
 238         string s;
 239         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0); // all
 240         s = "";
 241         for(i = 0; i < MapInfo_count; ++i)
 242                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 243         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 244         me.refilter(me);
 245 }
 246
 247 void MapList_None(entity btn, entity me)
 248 {
 249         cvar_set("g_maplist", "");
 250         me.refilter(me);
 251 }
 252
 253 void MapList_LoadMap(entity btn, entity me)
 254 {
 255         string m;
 256         float i;
 257
 258         i = me.selectedItem;
 259
 260         if(btn.parent.instanceOfNexuizMapInfoDialog)
 261         {
 262                 i = btn.parent.currentMapIndex;
 263                 Dialog_Close(btn, btn.parent);
 264         }
 265
 266         if(i >= me.nItems || i < 0)
 267                 return;
 268
 269         m = MapInfo_BSPName_ByID(i);
 270         if not(m)
 271         {
 272                 print("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n");
 273                 return;
 274         }
 275         if(MapInfo_CheckMap(m))
 276         {
 277                 localcmd("\ndisconnect\nwait\nmaxplayers $menu_maxplayers\ng_maplist_shufflenow\nhostname \"", strdecolorize(cvar_string("_cl_name")), "'s Nexuiz server\"\n");
 278                 MapInfo_LoadMap(m);
 279         }
 280         else
 281         {
 282                 print("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n");
 283                 me.refilter(me);
 284         }
 285 }
 286
 287 float keyDownNexuizMapList(entity me, float scan, float ascii, float shift)
 288 {
 289         string ch, save;
 290         if(scan == K_ENTER)
 291         {
 292                 // pop up map info screen
 293                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
 294                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 295         }
 296         else if(scan == K_SPACE)
 297         {
 298                 me.g_maplistCacheToggle(me, me.selectedItem);
 299         }
 300         else if(ascii == 43) // +
 301         {
 302                 if not(me.g_maplistCacheQuery(me, me.selectedItem))
 303                         me.g_maplistCacheToggle(me, me.selectedItem);
 304         }
 305         else if(ascii == 45) // -
 306         {
 307                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 308                         me.g_maplistCacheToggle(me, me.selectedItem);
 309         }
 310         else if(scan == K_BACKSPACE)
 311         {
 312                 if(time < me.typeToSearchTime)
 313                 {
 314                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 315                         if(me.typeToSearchString)
 316                                 strunzone(me.typeToSearchString);
 317                         me.typeToSearchString = strzone(save);
 318                         me.typeToSearchTime = time + 0.5;
 319                         if(strlen(me.typeToSearchString))
 320                         {
 321                                 MapInfo_FindName(me.typeToSearchString);
 322                                 if(MapInfo_FindName_firstResult >= 0)
 323                                         me.setSelected(me, MapInfo_FindName_firstResult);
 324                         }
 325                 }
 326         }
 327         else if(ascii >= 32 && ascii != 127)
 328         {
 329                 ch = chr(ascii);
 330                 if(time > me.typeToSearchTime)
 331                         save = ch;
 332                 else
 333                         save = strcat(me.typeToSearchString, ch);
 334                 if(me.typeToSearchString)
 335                         strunzone(me.typeToSearchString);
 336                 me.typeToSearchString = strzone(save);
 337                 me.typeToSearchTime = time + 0.5;
 338                 MapInfo_FindName(me.typeToSearchString);
 339                 if(MapInfo_FindName_firstResult >= 0)
 340                         me.setSelected(me, MapInfo_FindName_firstResult);
 341         }
 342         else
 343                 return keyDownListBox(me, scan, ascii, shift);
 344         return 1;
 345 }
 346
 347 #endif